lib/Target/PowerPC/PPCInstrFormats.td

   1 //===- PowerPCInstrFormats.td - PowerPC Instruction Formats --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //
  12 // PowerPC instruction formats
  13
  14 class I<bits<6> opcode, dag OOL, dag IOL, string asmstr, InstrItinClass itin>
  15         : Instruction {
  16   field bits<32> Inst;
  17   field bits<32> SoftFail = 0;
  18   let Size = 4;
  19
  20   bit PPC64 = 0;  // Default value, override with isPPC64
  21
  22   let Namespace = "PPC";
  23   let Inst{0-5} = opcode;
  24   let OutOperandList = OOL;
  25   let InOperandList = IOL;
  26   let AsmString = asmstr;
  27   let Itinerary = itin;
  28
  29   bits<1> PPC970_First = 0;
  30   bits<1> PPC970_Single = 0;
  31   bits<1> PPC970_Cracked = 0;
  32   bits<3> PPC970_Unit = 0;
  33
  34   /// These fields correspond to the fields in PPCInstrInfo.h.  Any changes to
  35   /// these must be reflected there!  See comments there for what these are.
  36   let TSFlags{0}   = PPC970_First;
  37   let TSFlags{1}   = PPC970_Single;
  38   let TSFlags{2}   = PPC970_Cracked;
  39   let TSFlags{5-3} = PPC970_Unit;
  40
  41   // Fields used for relation models.
  42   string BaseName = "";
  43
  44   // For cases where multiple instruction definitions really represent the
  45   // same underlying instruction but with one definition for 64-bit arguments
  46   // and one for 32-bit arguments, this bit breaks the degeneracy between
  47   // the two forms and allows TableGen to generate mapping tables.
  48   bit Interpretation64Bit = 0;
  49 }
  50
  51 class PPC970_DGroup_First   { bits<1> PPC970_First = 1;  }
  52 class PPC970_DGroup_Single  { bits<1> PPC970_Single = 1; }
  53 class PPC970_DGroup_Cracked { bits<1> PPC970_Cracked = 1; }
  54 class PPC970_MicroCode;
  55
  56 class PPC970_Unit_Pseudo   { bits<3> PPC970_Unit = 0;   }
  57 class PPC970_Unit_FXU      { bits<3> PPC970_Unit = 1;   }
  58 class PPC970_Unit_LSU      { bits<3> PPC970_Unit = 2;   }
  59 class PPC970_Unit_FPU      { bits<3> PPC970_Unit = 3;   }
  60 class PPC970_Unit_CRU      { bits<3> PPC970_Unit = 4;   }
  61 class PPC970_Unit_VALU     { bits<3> PPC970_Unit = 5;   }
  62 class PPC970_Unit_VPERM    { bits<3> PPC970_Unit = 6;   }
  63 class PPC970_Unit_BRU      { bits<3> PPC970_Unit = 7;   }
  64
  65 // Two joined instructions; used to emit two adjacent instructions as one.
  66 // The itinerary from the first instruction is used for scheduling and
  67 // classification.
  68 class I2<bits<6> opcode1, bits<6> opcode2, dag OOL, dag IOL, string asmstr,
  69          InstrItinClass itin>
  70         : Instruction {
  71   field bits<64> Inst;
  72   field bits<64> SoftFail = 0;
  73   let Size = 8;
  74
  75   bit PPC64 = 0;  // Default value, override with isPPC64
  76
  77   let Namespace = "PPC";
  78   let Inst{0-5} = opcode1;
  79   let Inst{32-37} = opcode2;
  80   let OutOperandList = OOL;
  81   let InOperandList = IOL;
  82   let AsmString = asmstr;
  83   let Itinerary = itin;
  84
  85   bits<1> PPC970_First = 0;
  86   bits<1> PPC970_Single = 0;
  87   bits<1> PPC970_Cracked = 0;
  88   bits<3> PPC970_Unit = 0;
  89
  90   /// These fields correspond to the fields in PPCInstrInfo.h.  Any changes to
  91   /// these must be reflected there!  See comments there for what these are.
  92   let TSFlags{0}   = PPC970_First;
  93   let TSFlags{1}   = PPC970_Single;
  94   let TSFlags{2}   = PPC970_Cracked;
  95   let TSFlags{5-3} = PPC970_Unit;
  96
  97   // Fields used for relation models.
  98   string BaseName = "";
  99   bit Interpretation64Bit = 0;
 100 }
 101
 102 // 1.7.1 I-Form
 103 class IForm<bits<6> opcode, bit aa, bit lk, dag OOL, dag IOL, string asmstr,
 104             InstrItinClass itin, list<dag> pattern>
 105          : I<opcode, OOL, IOL, asmstr, itin> {
 106   let Pattern = pattern;
 107   bits<24> LI;
 108
 109   let Inst{6-29}  = LI;
 110   let Inst{30}    = aa;
 111   let Inst{31}    = lk;
 112 }
 113
 114 // 1.7.2 B-Form
 115 class BForm<bits<6> opcode, bit aa, bit lk, dag OOL, dag IOL, string asmstr>
 116   : I<opcode, OOL, IOL, asmstr, IIC_BrB> {
 117   bits<7> BIBO;  // 2 bits of BI and 5 bits of BO.
 118   bits<3>  CR;
 119   bits<14> BD;
 120
 121   bits<5> BI;
 122   let BI{0-1} = BIBO{5-6};
 123   let BI{2-4} = CR{0-2};
 124
 125   let Inst{6-10}  = BIBO{4-0};
 126   let Inst{11-15} = BI;
 127   let Inst{16-29} = BD;
 128   let Inst{30}    = aa;
 129   let Inst{31}    = lk;
 130 }
 131
 132 class BForm_1<bits<6> opcode, bits<5> bo, bit aa, bit lk, dag OOL, dag IOL,
 133              string asmstr>
 134   : BForm<opcode, aa, lk, OOL, IOL, asmstr> {
 135   let BIBO{4-0} = bo;
 136   let BIBO{6-5} = 0;
 137   let CR = 0;
 138 }
 139
 140 class BForm_2<bits<6> opcode, bits<5> bo, bits<5> bi, bit aa, bit lk,
 141               dag OOL, dag IOL, string asmstr>
 142   : I<opcode, OOL, IOL, asmstr, IIC_BrB> {
 143   bits<14> BD;
 144
 145   let Inst{6-10}  = bo;
 146   let Inst{11-15} = bi;
 147   let Inst{16-29} = BD;
 148   let Inst{30}    = aa;
 149   let Inst{31}    = lk;
 150 }
 151
 152 class BForm_3<bits<6> opcode, bit aa, bit lk,
 153               dag OOL, dag IOL, string asmstr>
 154   : I<opcode, OOL, IOL, asmstr, IIC_BrB> {
 155   bits<5> BO;
 156   bits<5> BI;
 157   bits<14> BD;
 158
 159   let Inst{6-10}  = BO;
 160   let Inst{11-15} = BI;
 161   let Inst{16-29} = BD;
 162   let Inst{30}    = aa;
 163   let Inst{31}    = lk;
 164 }
 165
 166 class BForm_4<bits<6> opcode, bits<5> bo, bit aa, bit lk,
 167               dag OOL, dag IOL, string asmstr>
 168   : I<opcode, OOL, IOL, asmstr, IIC_BrB> {
 169   bits<5> BI;
 170   bits<14> BD;
 171
 172   let Inst{6-10}  = bo;
 173   let Inst{11-15} = BI;
 174   let Inst{16-29} = BD;
 175   let Inst{30}    = aa;
 176   let Inst{31}    = lk;
 177 }
 178
 179 // 1.7.3 SC-Form
 180 class SCForm<bits<6> opcode, bits<1> xo,
 181                      dag OOL, dag IOL, string asmstr, InstrItinClass itin,
 182                      list<dag> pattern>
 183   : I<opcode, OOL, IOL, asmstr, itin> {
 184   bits<7>  LEV;
 185
 186   let Pattern = pattern;
 187
 188   let Inst{20-26} = LEV;
 189   let Inst{30}    = xo;
 190 }
 191
 192 // 1.7.4 D-Form
 193 class DForm_base<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 194                  InstrItinClass itin, list<dag> pattern>
 195   : I<opcode, OOL, IOL, asmstr, itin> {
 196   bits<5>  A;
 197   bits<5>  B;
 198   bits<16> C;
 199
 200   let Pattern = pattern;
 201
 202   let Inst{6-10}  = A;
 203   let Inst{11-15} = B;
 204   let Inst{16-31} = C;
 205 }
 206
 207 class DForm_1<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 208               InstrItinClass itin, list<dag> pattern>
 209   : I<opcode, OOL, IOL, asmstr, itin> {
 210   bits<5>  A;
 211   bits<21> Addr;
 212
 213   let Pattern = pattern;
 214
 215   let Inst{6-10}  = A;
 216   let Inst{11-15} = Addr{20-16}; // Base Reg
 217   let Inst{16-31} = Addr{15-0};  // Displacement
 218 }
 219
 220 class DForm_1a<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 221                InstrItinClass itin, list<dag> pattern>
 222   : I<opcode, OOL, IOL, asmstr, itin> {
 223   bits<5>  A;
 224   bits<16> C;
 225   bits<5>  B;
 226
 227   let Pattern = pattern;
 228
 229   let Inst{6-10}  = A;
 230   let Inst{11-15} = B;
 231   let Inst{16-31} = C;
 232 }
 233
 234
 235 class DForm_2<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 236               InstrItinClass itin, list<dag> pattern>
 237   : DForm_base<opcode, OOL, IOL, asmstr, itin, pattern> {
 238
 239   // Even though ADDICo does not really have an RC bit, provide
 240   // the declaration of one here so that isDOT has something to set.
 241   bit RC = 0;
 242 }
 243
 244 class DForm_2_r0<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 245                  InstrItinClass itin, list<dag> pattern>
 246   : I<opcode, OOL, IOL, asmstr, itin> {
 247   bits<5>  A;
 248   bits<16> B;
 249
 250   let Pattern = pattern;
 251
 252   let Inst{6-10}  = A;
 253   let Inst{11-15} = 0;
 254   let Inst{16-31} = B;
 255 }
 256
 257 class DForm_4<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 258               InstrItinClass itin, list<dag> pattern>
 259   : I<opcode, OOL, IOL, asmstr, itin> {
 260   bits<5>  B;
 261   bits<5>  A;
 262   bits<16> C;
 263
 264   let Pattern = pattern;
 265
 266   let Inst{6-10}  = A;
 267   let Inst{11-15} = B;
 268   let Inst{16-31} = C;
 269 }
 270
 271 class DForm_4_zero<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 272                    InstrItinClass itin, list<dag> pattern>
 273   : DForm_1<opcode, OOL, IOL, asmstr, itin, pattern> {
 274   let A = 0;
 275   let Addr = 0;
 276 }
 277
 278 class DForm_4_fixedreg_zero<bits<6> opcode, bits<5> R, dag OOL, dag IOL,
 279                             string asmstr, InstrItinClass itin,
 280                             list<dag> pattern>
 281   : DForm_4<opcode, OOL, IOL, asmstr, itin, pattern> {
 282   let A = R;
 283   let B = R;
 284   let C = 0;
 285 }
 286
 287 class IForm_and_DForm_1<bits<6> opcode1, bit aa, bit lk, bits<6> opcode2,
 288             dag OOL, dag IOL, string asmstr,
 289             InstrItinClass itin, list<dag> pattern>
 290          : I2<opcode1, opcode2, OOL, IOL, asmstr, itin> {
 291   bits<5>  A;
 292   bits<21> Addr;
 293
 294   let Pattern = pattern;
 295   bits<24> LI;
 296
 297   let Inst{6-29}  = LI;
 298   let Inst{30}    = aa;
 299   let Inst{31}    = lk;
 300
 301   let Inst{38-42}  = A;
 302   let Inst{43-47} = Addr{20-16}; // Base Reg
 303   let Inst{48-63} = Addr{15-0};  // Displacement
 304 }
 305
 306 // This is used to emit BL8+NOP.
 307 class IForm_and_DForm_4_zero<bits<6> opcode1, bit aa, bit lk, bits<6> opcode2,
 308             dag OOL, dag IOL, string asmstr,
 309             InstrItinClass itin, list<dag> pattern>
 310          :  IForm_and_DForm_1<opcode1, aa, lk, opcode2,
 311                               OOL, IOL, asmstr, itin, pattern> {
 312   let A = 0;
 313   let Addr = 0;
 314 }
 315
 316 class DForm_5<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 317               InstrItinClass itin>
 318   : I<opcode, OOL, IOL, asmstr, itin> {
 319   bits<3>  BF;
 320   bits<1>  L;
 321   bits<5>  RA;
 322   bits<16> I;
 323
 324   let Inst{6-8}   = BF;
 325   let Inst{9}     = 0;
 326   let Inst{10}    = L;
 327   let Inst{11-15} = RA;
 328   let Inst{16-31} = I;
 329 }
 330
 331 class DForm_5_ext<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 332                   InstrItinClass itin>
 333   : DForm_5<opcode, OOL, IOL, asmstr, itin> {
 334   let L = PPC64;
 335 }
 336
 337 class DForm_6<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 338               InstrItinClass itin>
 339   : DForm_5<opcode, OOL, IOL, asmstr, itin>;
 340
 341 class DForm_6_ext<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 342                   InstrItinClass itin>
 343   : DForm_6<opcode, OOL, IOL, asmstr, itin> {
 344   let L = PPC64;
 345 }
 346
 347
 348 // 1.7.5 DS-Form
 349 class DSForm_1<bits<6> opcode, bits<2> xo, dag OOL, dag IOL, string asmstr,
 350                InstrItinClass itin, list<dag> pattern>
 351          : I<opcode, OOL, IOL, asmstr, itin> {
 352   bits<5>  RST;
 353   bits<19> DS_RA;
 354
 355   let Pattern = pattern;
 356
 357   let Inst{6-10}  = RST;
 358   let Inst{11-15} = DS_RA{18-14};  // Register #
 359   let Inst{16-29} = DS_RA{13-0};   // Displacement.
 360   let Inst{30-31} = xo;
 361 }
 362
 363
 364 // 1.7.6 X-Form
 365 class XForm_base_r3xo<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 366                       InstrItinClass itin, list<dag> pattern>
 367   : I<opcode, OOL, IOL, asmstr, itin> {
 368   bits<5> RST;
 369   bits<5> A;
 370   bits<5> B;
 371
 372   let Pattern = pattern;
 373
 374   bit RC = 0;    // set by isDOT
 375
 376   let Inst{6-10}  = RST;
 377   let Inst{11-15} = A;
 378   let Inst{16-20} = B;
 379   let Inst{21-30} = xo;
 380   let Inst{31}    = RC;
 381 }
 382
 383 class XForm_tlb<bits<10> xo, dag OOL, dag IOL, string asmstr,
 384                 InstrItinClass itin> : XForm_base_r3xo<31, xo, OOL, IOL, asmstr, itin, []> {
 385   let RST = 0;
 386 }
 387
 388 // This is the same as XForm_base_r3xo, but the first two operands are swapped
 389 // when code is emitted.
 390 class XForm_base_r3xo_swapped
 391         <bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 392         InstrItinClass itin>
 393   : I<opcode, OOL, IOL, asmstr, itin> {
 394   bits<5> A;
 395   bits<5> RST;
 396   bits<5> B;
 397
 398   bit RC = 0;    // set by isDOT
 399
 400   let Inst{6-10}  = RST;
 401   let Inst{11-15} = A;
 402   let Inst{16-20} = B;
 403   let Inst{21-30} = xo;
 404   let Inst{31}    = RC;
 405 }
 406
 407
 408 class XForm_1<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 409               InstrItinClass itin, list<dag> pattern>
 410   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern>;
 411
 412 class XForm_1a<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 413               InstrItinClass itin, list<dag> pattern>
 414   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 415   let RST = 0;
 416 }
 417
 418 class XForm_rs<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 419               InstrItinClass itin, list<dag> pattern>
 420   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 421   let A = 0;
 422   let B = 0;
 423 }
 424
 425 class XForm_6<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 426               InstrItinClass itin, list<dag> pattern>
 427   : XForm_base_r3xo_swapped<opcode, xo, OOL, IOL, asmstr, itin> {
 428   let Pattern = pattern;
 429 }
 430
 431 class XForm_8<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 432               InstrItinClass itin, list<dag> pattern>
 433   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern>;
 434
 435 class XForm_10<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 436                InstrItinClass itin, list<dag> pattern>
 437   : XForm_base_r3xo_swapped<opcode, xo, OOL, IOL, asmstr, itin> {
 438     let Pattern = pattern;
 439 }
 440
 441 class XForm_11<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 442                InstrItinClass itin, list<dag> pattern>
 443   : XForm_base_r3xo_swapped<opcode, xo, OOL, IOL, asmstr, itin> {
 444   let B = 0;
 445   let Pattern = pattern;
 446 }
 447
 448 class XForm_16<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 449                InstrItinClass itin>
 450          : I<opcode, OOL, IOL, asmstr, itin> {
 451   bits<3> BF;
 452   bits<1> L;
 453   bits<5> RA;
 454   bits<5> RB;
 455
 456   let Inst{6-8}   = BF;
 457   let Inst{9}     = 0;
 458   let Inst{10}    = L;
 459   let Inst{11-15} = RA;
 460   let Inst{16-20} = RB;
 461   let Inst{21-30} = xo;
 462   let Inst{31}    = 0;
 463 }
 464
 465 class XForm_sr<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 466                 InstrItinClass itin>
 467          : I<opcode, OOL, IOL, asmstr, itin> {
 468   bits<5> RS;
 469   bits<4> SR;
 470
 471   let Inst{6-10} = RS;
 472   let Inst{12-15} = SR;
 473   let Inst{21-30} = xo;
 474 }
 475
 476 class XForm_mbar<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 477                 InstrItinClass itin>
 478          : I<opcode, OOL, IOL, asmstr, itin> {
 479   bits<5> MO;
 480
 481   let Inst{6-10} = MO;
 482   let Inst{21-30} = xo;
 483 }
 484
 485 class XForm_srin<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 486                 InstrItinClass itin>
 487          : I<opcode, OOL, IOL, asmstr, itin> {
 488   bits<5> RS;
 489   bits<5> RB;
 490
 491   let Inst{6-10} = RS;
 492   let Inst{16-20} = RB;
 493   let Inst{21-30} = xo;
 494 }
 495
 496 class XForm_mtmsr<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 497                 InstrItinClass itin>
 498          : I<opcode, OOL, IOL, asmstr, itin> {
 499   bits<5> RS;
 500   bits<1> L;
 501
 502   let Inst{6-10} = RS;
 503   let Inst{15} = L;
 504   let Inst{21-30} = xo;
 505 }
 506
 507 class XForm_16_ext<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 508                    InstrItinClass itin>
 509   : XForm_16<opcode, xo, OOL, IOL, asmstr, itin> {
 510   let L = PPC64;
 511 }
 512
 513 class XForm_17<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 514                InstrItinClass itin>
 515          : I<opcode, OOL, IOL, asmstr, itin> {
 516   bits<3> BF;
 517   bits<5> FRA;
 518   bits<5> FRB;
 519
 520   let Inst{6-8}   = BF;
 521   let Inst{9-10}  = 0;
 522   let Inst{11-15} = FRA;
 523   let Inst{16-20} = FRB;
 524   let Inst{21-30} = xo;
 525   let Inst{31}    = 0;
 526 }
 527
 528 class XForm_24<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 529                InstrItinClass itin, list<dag> pattern>
 530   : I<opcode, OOL, IOL, asmstr, itin> {
 531   let Pattern = pattern;
 532   let Inst{6-10}  = 31;
 533   let Inst{11-15} = 0;
 534   let Inst{16-20} = 0;
 535   let Inst{21-30} = xo;
 536   let Inst{31}    = 0;
 537 }
 538
 539 class XForm_24_sync<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 540                string asmstr, InstrItinClass itin, list<dag> pattern>
 541   : I<opcode, OOL, IOL, asmstr, itin> {
 542   bits<2> L;
 543
 544   let Pattern = pattern;
 545   let Inst{6-8}   = 0;
 546   let Inst{9-10}  = L;
 547   let Inst{11-15} = 0;
 548   let Inst{16-20} = 0;
 549   let Inst{21-30} = xo;
 550   let Inst{31}    = 0;
 551 }
 552
 553 class XForm_24_eieio<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 554                string asmstr, InstrItinClass itin, list<dag> pattern>
 555   : XForm_24_sync<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 556   let L = 0;
 557 }
 558
 559 class XForm_25<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 560                InstrItinClass itin, list<dag> pattern>
 561   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 562 }
 563
 564 class XForm_26<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 565                InstrItinClass itin, list<dag> pattern>
 566   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 567   let A = 0;
 568 }
 569
 570 class XForm_28<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 571                InstrItinClass itin, list<dag> pattern>
 572   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 573 }
 574
 575 // This is used for MFFS, MTFSB0, MTFSB1.  42 is arbitrary; this series of
 576 // numbers presumably relates to some document, but I haven't found it.
 577 class XForm_42<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 578               InstrItinClass itin, list<dag> pattern>
 579   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 580   let Pattern = pattern;
 581
 582   bit RC = 0;    // set by isDOT
 583
 584   let Inst{6-10}  = RST;
 585   let Inst{11-20} = 0;
 586   let Inst{21-30} = xo;
 587   let Inst{31}    = RC;
 588 }
 589 class XForm_43<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 590               InstrItinClass itin, list<dag> pattern>
 591   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 592   let Pattern = pattern;
 593   bits<5> FM;
 594
 595   bit RC = 0;    // set by isDOT
 596
 597   let Inst{6-10}  = FM;
 598   let Inst{11-20} = 0;
 599   let Inst{21-30} = xo;
 600   let Inst{31}    = RC;
 601 }
 602
 603 class XForm_0<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 604               InstrItinClass itin, list<dag> pattern>
 605   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 606   let RST = 0;
 607   let A = 0;
 608   let B = 0;
 609 }
 610
 611 class XForm_16b<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 612               InstrItinClass itin, list<dag> pattern>
 613   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 614   let RST = 0;
 615   let A = 0;
 616 }
 617
 618 // XX*-Form (VSX)
 619 class XX1Form<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 620               InstrItinClass itin, list<dag> pattern>
 621   : I<opcode, OOL, IOL, asmstr, itin> {
 622   bits<6> XT;
 623   bits<5> A;
 624   bits<5> B;
 625
 626   let Pattern = pattern;
 627
 628   let Inst{6-10}  = XT{4-0};
 629   let Inst{11-15} = A;
 630   let Inst{16-20} = B;
 631   let Inst{21-30} = xo;
 632   let Inst{31}    = XT{5};
 633 }
 634
 635 class XX2Form<bits<6> opcode, bits<9> xo, dag OOL, dag IOL, string asmstr,
 636               InstrItinClass itin, list<dag> pattern>
 637   : I<opcode, OOL, IOL, asmstr, itin> {
 638   bits<6> XT;
 639   bits<6> XB;
 640
 641   let Pattern = pattern;
 642
 643   let Inst{6-10}  = XT{4-0};
 644   let Inst{11-15} = 0;
 645   let Inst{16-20} = XB{4-0};
 646   let Inst{21-29} = xo;
 647   let Inst{30}    = XB{5};
 648   let Inst{31}    = XT{5};
 649 }
 650
 651 class XX2Form_1<bits<6> opcode, bits<9> xo, dag OOL, dag IOL, string asmstr,
 652                 InstrItinClass itin, list<dag> pattern>
 653   : I<opcode, OOL, IOL, asmstr, itin> {
 654   bits<3> CR;
 655   bits<6> XB;
 656
 657   let Pattern = pattern;
 658
 659   let Inst{6-8}   = CR;
 660   let Inst{9-15}  = 0;
 661   let Inst{16-20} = XB{4-0};
 662   let Inst{21-29} = xo;
 663   let Inst{30}    = XB{5};
 664   let Inst{31}    = 0;
 665 }
 666
 667 class XX2Form_2<bits<6> opcode, bits<9> xo, dag OOL, dag IOL, string asmstr,
 668                 InstrItinClass itin, list<dag> pattern>
 669   : I<opcode, OOL, IOL, asmstr, itin> {
 670   bits<6> XT;
 671   bits<6> XB;
 672   bits<2> D;
 673
 674   let Pattern = pattern;
 675
 676   let Inst{6-10}  = XT{4-0};
 677   let Inst{11-13} = 0;
 678   let Inst{14-15} = D;
 679   let Inst{16-20} = XB{4-0};
 680   let Inst{21-29} = xo;
 681   let Inst{30}    = XB{5};
 682   let Inst{31}    = XT{5};
 683 }
 684
 685 class XX3Form<bits<6> opcode, bits<8> xo, dag OOL, dag IOL, string asmstr,
 686               InstrItinClass itin, list<dag> pattern>
 687   : I<opcode, OOL, IOL, asmstr, itin> {
 688   bits<6> XT;
 689   bits<6> XA;
 690   bits<6> XB;
 691
 692   let Pattern = pattern;
 693
 694   let Inst{6-10}  = XT{4-0};
 695   let Inst{11-15} = XA{4-0};
 696   let Inst{16-20} = XB{4-0};
 697   let Inst{21-28} = xo;
 698   let Inst{29}    = XA{5};
 699   let Inst{30}    = XB{5};
 700   let Inst{31}    = XT{5};
 701 }
 702
 703 class XX3Form_1<bits<6> opcode, bits<8> xo, dag OOL, dag IOL, string asmstr,
 704                 InstrItinClass itin, list<dag> pattern>
 705   : I<opcode, OOL, IOL, asmstr, itin> {
 706   bits<3> CR;
 707   bits<6> XA;
 708   bits<6> XB;
 709
 710   let Pattern = pattern;
 711
 712   let Inst{6-8}   = CR;
 713   let Inst{9-10}  = 0;
 714   let Inst{11-15} = XA{4-0};
 715   let Inst{16-20} = XB{4-0};
 716   let Inst{21-28} = xo;
 717   let Inst{29}    = XA{5};
 718   let Inst{30}    = XB{5};
 719   let Inst{31}    = 0;
 720 }
 721
 722 class XX3Form_2<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
 723                 InstrItinClass itin, list<dag> pattern>
 724   : I<opcode, OOL, IOL, asmstr, itin> {
 725   bits<6> XT;
 726   bits<6> XA;
 727   bits<6> XB;
 728   bits<2> D;
 729
 730   let Pattern = pattern;
 731
 732   let Inst{6-10}  = XT{4-0};
 733   let Inst{11-15} = XA{4-0};
 734   let Inst{16-20} = XB{4-0};
 735   let Inst{21}    = 0;
 736   let Inst{22-23} = D;
 737   let Inst{24-28} = xo;
 738   let Inst{29}    = XA{5};
 739   let Inst{30}    = XB{5};
 740   let Inst{31}    = XT{5};
 741 }
 742
 743 class XX3Form_Rc<bits<6> opcode, bits<7> xo, dag OOL, dag IOL, string asmstr,
 744               InstrItinClass itin, list<dag> pattern>
 745   : I<opcode, OOL, IOL, asmstr, itin> {
 746   bits<6> XT;
 747   bits<6> XA;
 748   bits<6> XB;
 749
 750   let Pattern = pattern;
 751
 752   bit RC = 0;    // set by isDOT
 753
 754   let Inst{6-10}  = XT{4-0};
 755   let Inst{11-15} = XA{4-0};
 756   let Inst{16-20} = XB{4-0};
 757   let Inst{21}    = RC;
 758   let Inst{22-28} = xo;
 759   let Inst{29}    = XA{5};
 760   let Inst{30}    = XB{5};
 761   let Inst{31}    = XT{5};
 762 }
 763
 764 class XX4Form<bits<6> opcode, bits<2> xo, dag OOL, dag IOL, string asmstr,
 765               InstrItinClass itin, list<dag> pattern>
 766   : I<opcode, OOL, IOL, asmstr, itin> {
 767   bits<6> XT;
 768   bits<6> XA;
 769   bits<6> XB;
 770   bits<6> XC;
 771
 772   let Pattern = pattern;
 773
 774   let Inst{6-10}  = XT{4-0};
 775   let Inst{11-15} = XA{4-0};
 776   let Inst{16-20} = XB{4-0};
 777   let Inst{21-25} = XC{4-0};
 778   let Inst{26-27} = xo;
 779   let Inst{28}    = XC{5};
 780   let Inst{29}    = XA{5};
 781   let Inst{30}    = XB{5};
 782   let Inst{31}    = XT{5};
 783 }
 784
 785 // DCB_Form - Form X instruction, used for dcb* instructions.
 786 class DCB_Form<bits<10> xo, bits<5> immfield, dag OOL, dag IOL, string asmstr,
 787                       InstrItinClass itin, list<dag> pattern>
 788   : I<31, OOL, IOL, asmstr, itin> {
 789   bits<5> A;
 790   bits<5> B;
 791
 792   let Pattern = pattern;
 793
 794   let Inst{6-10}  = immfield;
 795   let Inst{11-15} = A;
 796   let Inst{16-20} = B;
 797   let Inst{21-30} = xo;
 798   let Inst{31}    = 0;
 799 }
 800
 801
 802 // DSS_Form - Form X instruction, used for altivec dss* instructions.
 803 class DSS_Form<bits<1> T, bits<10> xo, dag OOL, dag IOL, string asmstr,
 804                       InstrItinClass itin, list<dag> pattern>
 805   : I<31, OOL, IOL, asmstr, itin> {
 806   bits<2> STRM;
 807   bits<5> A;
 808   bits<5> B;
 809
 810   let Pattern = pattern;
 811
 812   let Inst{6}     = T;
 813   let Inst{7-8}   = 0;
 814   let Inst{9-10}  = STRM;
 815   let Inst{11-15} = A;
 816   let Inst{16-20} = B;
 817   let Inst{21-30} = xo;
 818   let Inst{31}    = 0;
 819 }
 820
 821 // 1.7.7 XL-Form
 822 class XLForm_1<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 823                InstrItinClass itin, list<dag> pattern>
 824     : I<opcode, OOL, IOL, asmstr, itin> {
 825   bits<5> CRD;
 826   bits<5> CRA;
 827   bits<5> CRB;
 828
 829   let Pattern = pattern;
 830
 831   let Inst{6-10}  = CRD;
 832   let Inst{11-15} = CRA;
 833   let Inst{16-20} = CRB;
 834   let Inst{21-30} = xo;
 835   let Inst{31}    = 0;
 836 }
 837
 838 class XLForm_1_ext<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 839                InstrItinClass itin, list<dag> pattern>
 840     : I<opcode, OOL, IOL, asmstr, itin> {
 841   bits<5> CRD;
 842
 843   let Pattern = pattern;
 844
 845   let Inst{6-10}  = CRD;
 846   let Inst{11-15} = CRD;
 847   let Inst{16-20} = CRD;
 848   let Inst{21-30} = xo;
 849   let Inst{31}    = 0;
 850 }
 851
 852 class XLForm_2<bits<6> opcode, bits<10> xo, bit lk, dag OOL, dag IOL, string asmstr,
 853                InstrItinClass itin, list<dag> pattern>
 854     : I<opcode, OOL, IOL, asmstr, itin> {
 855   bits<5> BO;
 856   bits<5> BI;
 857   bits<2> BH;
 858
 859   let Pattern = pattern;
 860
 861   let Inst{6-10}  = BO;
 862   let Inst{11-15} = BI;
 863   let Inst{16-18} = 0;
 864   let Inst{19-20} = BH;
 865   let Inst{21-30} = xo;
 866   let Inst{31}    = lk;
 867 }
 868
 869 class XLForm_2_br<bits<6> opcode, bits<10> xo, bit lk,
 870                   dag OOL, dag IOL, string asmstr, InstrItinClass itin, list<dag> pattern>
 871   : XLForm_2<opcode, xo, lk, OOL, IOL, asmstr, itin, pattern> {
 872   bits<7> BIBO;  // 2 bits of BI and 5 bits of BO.
 873   bits<3>  CR;
 874
 875   let BO = BIBO{4-0};
 876   let BI{0-1} = BIBO{5-6};
 877   let BI{2-4} = CR{0-2};
 878   let BH = 0;
 879 }
 880
 881 class XLForm_2_br2<bits<6> opcode, bits<10> xo, bits<5> bo, bit lk,
 882                    dag OOL, dag IOL, string asmstr, InstrItinClass itin, list<dag> pattern>
 883   : XLForm_2<opcode, xo, lk, OOL, IOL, asmstr, itin, pattern> {
 884   let BO = bo;
 885   let BH = 0;
 886 }
 887
 888 class XLForm_2_ext<bits<6> opcode, bits<10> xo, bits<5> bo,  bits<5> bi, bit lk,
 889                   dag OOL, dag IOL, string asmstr, InstrItinClass itin, list<dag> pattern>
 890   : XLForm_2<opcode, xo, lk, OOL, IOL, asmstr, itin, pattern> {
 891   let BO = bo;
 892   let BI = bi;
 893   let BH = 0;
 894 }
 895
 896 class XLForm_3<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 897                InstrItinClass itin>
 898          : I<opcode, OOL, IOL, asmstr, itin> {
 899   bits<3> BF;
 900   bits<3> BFA;
 901
 902   let Inst{6-8}   = BF;
 903   let Inst{9-10}  = 0;
 904   let Inst{11-13} = BFA;
 905   let Inst{14-15} = 0;
 906   let Inst{16-20} = 0;
 907   let Inst{21-30} = xo;
 908   let Inst{31}    = 0;
 909 }
 910
 911 // 1.7.8 XFX-Form
 912 class XFXForm_1<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 913                 InstrItinClass itin>
 914          : I<opcode, OOL, IOL, asmstr, itin> {
 915   bits<5>  RT;
 916   bits<10> SPR;
 917
 918   let Inst{6-10}  = RT;
 919   let Inst{11}    = SPR{4};
 920   let Inst{12}    = SPR{3};
 921   let Inst{13}    = SPR{2};
 922   let Inst{14}    = SPR{1};
 923   let Inst{15}    = SPR{0};
 924   let Inst{16}    = SPR{9};
 925   let Inst{17}    = SPR{8};
 926   let Inst{18}    = SPR{7};
 927   let Inst{19}    = SPR{6};
 928   let Inst{20}    = SPR{5};
 929   let Inst{21-30} = xo;
 930   let Inst{31}    = 0;
 931 }
 932
 933 class XFXForm_1_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 934                    dag OOL, dag IOL, string asmstr, InstrItinClass itin>
 935   : XFXForm_1<opcode, xo, OOL, IOL, asmstr, itin> {
 936   let SPR = spr;
 937 }
 938
 939 class XFXForm_3<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 940                 InstrItinClass itin>
 941          : I<opcode, OOL, IOL, asmstr, itin> {
 942   bits<5>  RT;
 943
 944   let Inst{6-10}  = RT;
 945   let Inst{11-20} = 0;
 946   let Inst{21-30} = xo;
 947   let Inst{31}    = 0;
 948 }
 949
 950 class XFXForm_5<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 951                 InstrItinClass itin>
 952   : I<opcode, OOL, IOL, asmstr, itin> {
 953   bits<8>  FXM;
 954   bits<5>  rS;
 955
 956   let Inst{6-10}  = rS;
 957   let Inst{11}    = 0;
 958   let Inst{12-19} = FXM;
 959   let Inst{20}    = 0;
 960   let Inst{21-30} = xo;
 961   let Inst{31}    = 0;
 962 }
 963
 964 class XFXForm_5a<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 965                  InstrItinClass itin>
 966   : I<opcode, OOL, IOL, asmstr, itin> {
 967   bits<5>  ST;
 968   bits<8>  FXM;
 969
 970   let Inst{6-10}  = ST;
 971   let Inst{11}    = 1;
 972   let Inst{12-19} = FXM;
 973   let Inst{20}    = 0;
 974   let Inst{21-30} = xo;
 975   let Inst{31}    = 0;
 976 }
 977
 978 class XFXForm_7<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 979                 InstrItinClass itin>
 980   : XFXForm_1<opcode, xo, OOL, IOL, asmstr, itin>;
 981
 982 class XFXForm_7_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 983                     dag OOL, dag IOL, string asmstr, InstrItinClass itin>
 984   : XFXForm_7<opcode, xo, OOL, IOL, asmstr, itin> {
 985   let SPR = spr;
 986 }
 987
 988 // XFL-Form - MTFSF
 989 // This is probably 1.7.9, but I don't have the reference that uses this
 990 // numbering scheme...
 991 class XFLForm<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 992               InstrItinClass itin, list<dag>pattern>
 993   : I<opcode, OOL, IOL, asmstr, itin> {
 994   bits<8> FM;
 995   bits<5> rT;
 996
 997   bit RC = 0;    // set by isDOT
 998   let Pattern = pattern;
 999
1000   let Inst{6} = 0;
1001   let Inst{7-14}  = FM;
1002   let Inst{15} = 0;
1003   let Inst{16-20} = rT;
1004   let Inst{21-30} = xo;
1005   let Inst{31}    = RC;
1006 }
1007
1008 // 1.7.10 XS-Form - SRADI.
1009 class XSForm_1<bits<6> opcode, bits<9> xo, dag OOL, dag IOL, string asmstr,
1010                InstrItinClass itin, list<dag> pattern>
1011          : I<opcode, OOL, IOL, asmstr, itin> {
1012   bits<5> A;
1013   bits<5> RS;
1014   bits<6> SH;
1015
1016   bit RC = 0;    // set by isDOT
1017   let Pattern = pattern;
1018
1019   let Inst{6-10}  = RS;
1020   let Inst{11-15} = A;
1021   let Inst{16-20} = SH{4,3,2,1,0};
1022   let Inst{21-29} = xo;
1023   let Inst{30}    = SH{5};
1024   let Inst{31}    = RC;
1025 }
1026
1027 // 1.7.11 XO-Form
1028 class XOForm_1<bits<6> opcode, bits<9> xo, bit oe, dag OOL, dag IOL, string asmstr,
1029                InstrItinClass itin, list<dag> pattern>
1030          : I<opcode, OOL, IOL, asmstr, itin> {
1031   bits<5> RT;
1032   bits<5> RA;
1033   bits<5> RB;
1034
1035   let Pattern = pattern;
1036
1037   bit RC = 0;    // set by isDOT
1038
1039   let Inst{6-10}  = RT;
1040   let Inst{11-15} = RA;
1041   let Inst{16-20} = RB;
1042   let Inst{21}    = oe;
1043   let Inst{22-30} = xo;
1044   let Inst{31}    = RC;
1045 }
1046
1047 class XOForm_3<bits<6> opcode, bits<9> xo, bit oe,
1048                dag OOL, dag IOL, string asmstr, InstrItinClass itin, list<dag> pattern>
1049   : XOForm_1<opcode, xo, oe, OOL, IOL, asmstr, itin, pattern> {
1050   let RB = 0;
1051 }
1052
1053 // 1.7.12 A-Form
1054 class AForm_1<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
1055               InstrItinClass itin, list<dag> pattern>
1056          : I<opcode, OOL, IOL, asmstr, itin> {
1057   bits<5> FRT;
1058   bits<5> FRA;
1059   bits<5> FRC;
1060   bits<5> FRB;
1061
1062   let Pattern = pattern;
1063
1064   bit RC = 0;    // set by isDOT
1065
1066   let Inst{6-10}  = FRT;
1067   let Inst{11-15} = FRA;
1068   let Inst{16-20} = FRB;
1069   let Inst{21-25} = FRC;
1070   let Inst{26-30} = xo;
1071   let Inst{31}    = RC;
1072 }
1073
1074 class AForm_2<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
1075               InstrItinClass itin, list<dag> pattern>
1076   : AForm_1<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
1077   let FRC = 0;
1078 }
1079
1080 class AForm_3<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
1081               InstrItinClass itin, list<dag> pattern>
1082   : AForm_1<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
1083   let FRB = 0;
1084 }
1085
1086 class AForm_4<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
1087               InstrItinClass itin, list<dag> pattern>
1088          : I<opcode, OOL, IOL, asmstr, itin> {
1089   bits<5> RT;
1090   bits<5> RA;
1091   bits<5> RB;
1092   bits<5> COND;
1093
1094   let Pattern = pattern;
1095
1096   let Inst{6-10}  = RT;
1097   let Inst{11-15} = RA;
1098   let Inst{16-20} = RB;
1099   let Inst{21-25} = COND;
1100   let Inst{26-30} = xo;
1101   let Inst{31}    = 0;
1102 }
1103
1104 // 1.7.13 M-Form
1105 class MForm_1<bits<6> opcode, dag OOL, dag IOL, string asmstr,
1106               InstrItinClass itin, list<dag> pattern>
1107     : I<opcode, OOL, IOL, asmstr, itin> {
1108   bits<5> RA;
1109   bits<5> RS;
1110   bits<5> RB;
1111   bits<5> MB;
1112   bits<5> ME;
1113
1114   let Pattern = pattern;
1115
1116   bit RC = 0;    // set by isDOT
1117
1118   let Inst{6-10}  = RS;
1119   let Inst{11-15} = RA;
1120   let Inst{16-20} = RB;
1121   let Inst{21-25} = MB;
1122   let Inst{26-30} = ME;
1123   let Inst{31}    = RC;
1124 }
1125
1126 class MForm_2<bits<6> opcode, dag OOL, dag IOL, string asmstr,
1127               InstrItinClass itin, list<dag> pattern>
1128   : MForm_1<opcode, OOL, IOL, asmstr, itin, pattern> {
1129 }
1130
1131 // 1.7.14 MD-Form
1132 class MDForm_1<bits<6> opcode, bits<3> xo, dag OOL, dag IOL, string asmstr,
1133                InstrItinClass itin, list<dag> pattern>
1134     : I<opcode, OOL, IOL, asmstr, itin> {
1135   bits<5> RA;
1136   bits<5> RS;
1137   bits<6> SH;
1138   bits<6> MBE;
1139
1140   let Pattern = pattern;
1141
1142   bit RC = 0;    // set by isDOT
1143
1144   let Inst{6-10}  = RS;
1145   let Inst{11-15} = RA;
1146   let Inst{16-20} = SH{4,3,2,1,0};
1147   let Inst{21-26} = MBE{4,3,2,1,0,5};
1148   let Inst{27-29} = xo;
1149   let Inst{30}    = SH{5};
1150   let Inst{31}    = RC;
1151 }
1152
1153 class MDSForm_1<bits<6> opcode, bits<4> xo, dag OOL, dag IOL, string asmstr,
1154                 InstrItinClass itin, list<dag> pattern>
1155     : I<opcode, OOL, IOL, asmstr, itin> {
1156   bits<5> RA;
1157   bits<5> RS;
1158   bits<5> RB;
1159   bits<6> MBE;
1160
1161   let Pattern = pattern;
1162
1163   bit RC = 0;    // set by isDOT
1164
1165   let Inst{6-10}  = RS;
1166   let Inst{11-15} = RA;
1167   let Inst{16-20} = RB;
1168   let Inst{21-26} = MBE{4,3,2,1,0,5};
1169   let Inst{27-30} = xo;
1170   let Inst{31}    = RC;
1171 }
1172
1173
1174 // E-1 VA-Form
1175
1176 // VAForm_1 - DACB ordering.
1177 class VAForm_1<bits<6> xo, dag OOL, dag IOL, string asmstr,
1178                InstrItinClass itin, list<dag> pattern>
1179     : I<4, OOL, IOL, asmstr, itin> {
1180   bits<5> VD;
1181   bits<5> VA;
1182   bits<5> VC;
1183   bits<5> VB;
1184
1185   let Pattern = pattern;
1186
1187   let Inst{6-10}  = VD;
1188   let Inst{11-15} = VA;
1189   let Inst{16-20} = VB;
1190   let Inst{21-25} = VC;
1191   let Inst{26-31} = xo;
1192 }
1193
1194 // VAForm_1a - DABC ordering.
1195 class VAForm_1a<bits<6> xo, dag OOL, dag IOL, string asmstr,
1196                 InstrItinClass itin, list<dag> pattern>
1197     : I<4, OOL, IOL, asmstr, itin> {
1198   bits<5> VD;
1199   bits<5> VA;
1200   bits<5> VB;
1201   bits<5> VC;
1202
1203   let Pattern = pattern;
1204
1205   let Inst{6-10}  = VD;
1206   let Inst{11-15} = VA;
1207   let Inst{16-20} = VB;
1208   let Inst{21-25} = VC;
1209   let Inst{26-31} = xo;
1210 }
1211
1212 class VAForm_2<bits<6> xo, dag OOL, dag IOL, string asmstr,
1213                InstrItinClass itin, list<dag> pattern>
1214     : I<4, OOL, IOL, asmstr, itin> {
1215   bits<5> VD;
1216   bits<5> VA;
1217   bits<5> VB;
1218   bits<4> SH;
1219
1220   let Pattern = pattern;
1221
1222   let Inst{6-10}  = VD;
1223   let Inst{11-15} = VA;
1224   let Inst{16-20} = VB;
1225   let Inst{21}    = 0;
1226   let Inst{22-25} = SH;
1227   let Inst{26-31} = xo;
1228 }
1229
1230 // E-2 VX-Form
1231 class VXForm_1<bits<11> xo, dag OOL, dag IOL, string asmstr,
1232                InstrItinClass itin, list<dag> pattern>
1233     : I<4, OOL, IOL, asmstr, itin> {
1234   bits<5> VD;
1235   bits<5> VA;
1236   bits<5> VB;
1237
1238   let Pattern = pattern;
1239
1240   let Inst{6-10}  = VD;
1241   let Inst{11-15} = VA;
1242   let Inst{16-20} = VB;
1243   let Inst{21-31} = xo;
1244 }
1245
1246 class VXForm_setzero<bits<11> xo, dag OOL, dag IOL, string asmstr,
1247                InstrItinClass itin, list<dag> pattern>
1248     : VXForm_1<xo, OOL, IOL, asmstr, itin, pattern> {
1249   let VA = VD;
1250   let VB = VD;
1251 }
1252
1253
1254 class VXForm_2<bits<11> xo, dag OOL, dag IOL, string asmstr,
1255                InstrItinClass itin, list<dag> pattern>
1256     : I<4, OOL, IOL, asmstr, itin> {
1257   bits<5> VD;
1258   bits<5> VB;
1259
1260   let Pattern = pattern;
1261
1262   let Inst{6-10}  = VD;
1263   let Inst{11-15} = 0;
1264   let Inst{16-20} = VB;
1265   let Inst{21-31} = xo;
1266 }
1267
1268 class VXForm_3<bits<11> xo, dag OOL, dag IOL, string asmstr,
1269                InstrItinClass itin, list<dag> pattern>
1270     : I<4, OOL, IOL, asmstr, itin> {
1271   bits<5> VD;
1272   bits<5> IMM;
1273
1274   let Pattern = pattern;
1275
1276   let Inst{6-10}  = VD;
1277   let Inst{11-15} = IMM;
1278   let Inst{16-20} = 0;
1279   let Inst{21-31} = xo;
1280 }
1281
1282 /// VXForm_4 - VX instructions with "VD,0,0" register fields, like mfvscr.
1283 class VXForm_4<bits<11> xo, dag OOL, dag IOL, string asmstr,
1284                InstrItinClass itin, list<dag> pattern>
1285     : I<4, OOL, IOL, asmstr, itin> {
1286   bits<5> VD;
1287
1288   let Pattern = pattern;
1289
1290   let Inst{6-10}  = VD;
1291   let Inst{11-15} = 0;
1292   let Inst{16-20} = 0;
1293   let Inst{21-31} = xo;
1294 }
1295
1296 /// VXForm_5 - VX instructions with "0,0,VB" register fields, like mtvscr.
1297 class VXForm_5<bits<11> xo, dag OOL, dag IOL, string asmstr,
1298                InstrItinClass itin, list<dag> pattern>
1299     : I<4, OOL, IOL, asmstr, itin> {
1300   bits<5> VB;
1301
1302   let Pattern = pattern;
1303
1304   let Inst{6-10}  = 0;
1305   let Inst{11-15} = 0;
1306   let Inst{16-20} = VB;
1307   let Inst{21-31} = xo;
1308 }
1309
1310 // E-4 VXR-Form
1311 class VXRForm_1<bits<10> xo, dag OOL, dag IOL, string asmstr,
1312                InstrItinClass itin, list<dag> pattern>
1313     : I<4, OOL, IOL, asmstr, itin> {
1314   bits<5> VD;
1315   bits<5> VA;
1316   bits<5> VB;
1317   bit RC = 0;
1318
1319   let Pattern = pattern;
1320
1321   let Inst{6-10}  = VD;
1322   let Inst{11-15} = VA;
1323   let Inst{16-20} = VB;
1324   let Inst{21}    = RC;
1325   let Inst{22-31} = xo;
1326 }
1327
1328 //===----------------------------------------------------------------------===//
1329 class Pseudo<dag OOL, dag IOL, string asmstr, list<dag> pattern>
1330     : I<0, OOL, IOL, asmstr, NoItinerary> {
1331   let isCodeGenOnly = 1;
1332   let PPC64 = 0;
1333   let Pattern = pattern;
1334   let Inst{31-0} = 0;
1335 }