lib/Target/Mips/MipsCallingConv.td

   1 //===-- MipsCallingConv.td - Calling Conventions for Mips --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 // This describes the calling conventions for Mips architecture.
  10 //===----------------------------------------------------------------------===//
  11
  12 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  13 class CCIfSubtarget<string F, CCAction A, string Invert = "">
  14     : CCIf<!strconcat(Invert,
  15                       "static_cast<const MipsSubtarget&>"
  16                         "(State.getMachineFunction().getSubtarget()).",
  17                       F),
  18            A>;
  19
  20 // The inverse of CCIfSubtarget
  21 class CCIfSubtargetNot<string F, CCAction A> : CCIfSubtarget<F, A, "!">;
  22
  23 //===----------------------------------------------------------------------===//
  24 // Mips O32 Calling Convention
  25 //===----------------------------------------------------------------------===//
  26
  27 // Only the return rules are defined here for O32. The rules for argument
  28 // passing are defined in MipsISelLowering.cpp.
  29 def RetCC_MipsO32 : CallingConv<[
  30   // i32 are returned in registers V0, V1, A0, A1
  31   CCIfType<[i32], CCAssignToReg<[V0, V1, A0, A1]>>,
  32
  33   // f32 are returned in registers F0, F2
  34   CCIfType<[f32], CCAssignToReg<[F0, F2]>>,
  35
  36   // f64 arguments are returned in D0_64 and D2_64 in FP64bit mode or
  37   // in D0 and D1 in FP32bit mode.
  38   CCIfType<[f64], CCIfSubtarget<"isFP64bit()", CCAssignToReg<[D0_64, D2_64]>>>,
  39   CCIfType<[f64], CCIfSubtargetNot<"isFP64bit()", CCAssignToReg<[D0, D1]>>>
  40 ]>;
  41
  42 //===----------------------------------------------------------------------===//
  43 // Mips N32/64 Calling Convention
  44 //===----------------------------------------------------------------------===//
  45
  46 def CC_MipsN : CallingConv<[
  47   // Promote i8/i16 arguments to i32.
  48   CCIfType<[i8, i16], CCPromoteToType<i32>>,
  49
  50   // Integer arguments are passed in integer registers.
  51   CCIfType<[i32], CCAssignToRegWithShadow<[A0, A1, A2, A3,
  52                                            T0, T1, T2, T3],
  53                                           [F12, F13, F14, F15,
  54                                            F16, F17, F18, F19]>>,
  55
  56   CCIfType<[i64], CCAssignToRegWithShadow<[A0_64, A1_64, A2_64, A3_64,
  57                                            T0_64, T1_64, T2_64, T3_64],
  58                                           [D12_64, D13_64, D14_64, D15_64,
  59                                            D16_64, D17_64, D18_64, D19_64]>>,
  60
  61   // f32 arguments are passed in single precision FP registers.
  62   CCIfType<[f32], CCAssignToRegWithShadow<[F12, F13, F14, F15,
  63                                            F16, F17, F18, F19],
  64                                           [A0_64, A1_64, A2_64, A3_64,
  65                                            T0_64, T1_64, T2_64, T3_64]>>,
  66
  67   // f64 arguments are passed in double precision FP registers.
  68   CCIfType<[f64], CCAssignToRegWithShadow<[D12_64, D13_64, D14_64, D15_64,
  69                                            D16_64, D17_64, D18_64, D19_64],
  70                                           [A0_64, A1_64, A2_64, A3_64,
  71                                            T0_64, T1_64, T2_64, T3_64]>>,
  72
  73   // All stack parameter slots become 64-bit doublewords and are 8-byte aligned.
  74   CCIfType<[i32, f32], CCAssignToStack<4, 8>>,
  75   CCIfType<[i64, f64], CCAssignToStack<8, 8>>
  76 ]>;
  77
  78 // N32/64 variable arguments.
  79 // All arguments are passed in integer registers.
  80 def CC_MipsN_VarArg : CallingConv<[
  81   // Promote i8/i16 arguments to i32.
  82   CCIfType<[i8, i16], CCPromoteToType<i32>>,
  83
  84   CCIfType<[i32, f32], CCAssignToReg<[A0, A1, A2, A3, T0, T1, T2, T3]>>,
  85
  86   CCIfType<[i64, f64], CCAssignToReg<[A0_64, A1_64, A2_64, A3_64,
  87                                       T0_64, T1_64, T2_64, T3_64]>>,
  88
  89   // All stack parameter slots become 64-bit doublewords and are 8-byte aligned.
  90   CCIfType<[i32, f32], CCAssignToStack<4, 8>>,
  91   CCIfType<[i64, f64], CCAssignToStack<8, 8>>
  92 ]>;
  93
  94 def RetCC_MipsN : CallingConv<[
  95   // Aggregate returns are positioned at the lowest address in the slot for
  96   // both little and big-endian targets. When passing in registers, this
  97   // requires that big-endian targets shift the value into the upper bits.
  98   CCIfSubtarget<"isLittle()",
  99       CCIfType<[i8, i16, i32], CCIfInReg<CCPromoteToType<i64>>>>,
 100   CCIfSubtargetNot<"isLittle()",
 101       CCIfType<[i8, i16, i32], CCIfInReg<CCPromoteToUpperBitsInType<i64>>>>,
 102
 103   // i32 are returned in registers V0, V1
 104   CCIfType<[i32], CCAssignToReg<[V0, V1]>>,
 105
 106   // i64 are returned in registers V0_64, V1_64
 107   CCIfType<[i64], CCAssignToReg<[V0_64, V1_64]>>,
 108
 109   // f32 are returned in registers F0, F2
 110   CCIfType<[f32], CCAssignToReg<[F0, F2]>>,
 111
 112   // f64 are returned in registers D0, D2
 113   CCIfType<[f64], CCAssignToReg<[D0_64, D2_64]>>
 114 ]>;
 115
 116 // For soft-float, f128 values are returned in A0_64 rather than V1_64.
 117 def RetCC_F128SoftFloat : CallingConv<[
 118   CCAssignToReg<[V0_64, A0_64]>
 119 ]>;
 120
 121 // For hard-float, f128 values are returned as a pair of f64's rather than a
 122 // pair of i64's.
 123 def RetCC_F128HardFloat : CallingConv<[
 124   CCBitConvertToType<f64>,
 125   CCAssignToReg<[D0_64, D2_64]>
 126 ]>;
 127
 128 // Handle F128 specially since we can't identify the original type during the
 129 // tablegen-erated code.
 130 def RetCC_F128 : CallingConv<[
 131   CCIfSubtarget<"abiUsesSoftFloat()",
 132       CCIfType<[i64], CCDelegateTo<RetCC_F128SoftFloat>>>,
 133   CCIfSubtargetNot<"abiUsesSoftFloat()",
 134       CCIfType<[i64], CCDelegateTo<RetCC_F128HardFloat>>>
 135 ]>;
 136
 137 //===----------------------------------------------------------------------===//
 138 // Mips EABI Calling Convention
 139 //===----------------------------------------------------------------------===//
 140
 141 def CC_MipsEABI : CallingConv<[
 142   // Promote i8/i16 arguments to i32.
 143   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 144
 145   // Integer arguments are passed in integer registers.
 146   CCIfType<[i32], CCAssignToReg<[A0, A1, A2, A3, T0, T1, T2, T3]>>,
 147
 148   // Single fp arguments are passed in pairs within 32-bit mode
 149   CCIfType<[f32], CCIfSubtarget<"isSingleFloat()",
 150                   CCAssignToReg<[F12, F13, F14, F15, F16, F17, F18, F19]>>>,
 151
 152   CCIfType<[f32], CCIfSubtargetNot<"isSingleFloat()",
 153                   CCAssignToReg<[F12, F14, F16, F18]>>>,
 154
 155   // The first 4 double fp arguments are passed in single fp registers.
 156   CCIfType<[f64], CCIfSubtargetNot<"isSingleFloat()",
 157                   CCAssignToReg<[D6, D7, D8, D9]>>>,
 158
 159   // Integer values get stored in stack slots that are 4 bytes in
 160   // size and 4-byte aligned.
 161   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 162
 163   // Integer values get stored in stack slots that are 8 bytes in
 164   // size and 8-byte aligned.
 165   CCIfType<[f64], CCIfSubtargetNot<"isSingleFloat()", CCAssignToStack<8, 8>>>
 166 ]>;
 167
 168 def RetCC_MipsEABI : CallingConv<[
 169   // i32 are returned in registers V0, V1
 170   CCIfType<[i32], CCAssignToReg<[V0, V1]>>,
 171
 172   // f32 are returned in registers F0, F1
 173   CCIfType<[f32], CCAssignToReg<[F0, F1]>>,
 174
 175   // f64 are returned in register D0
 176   CCIfType<[f64], CCIfSubtargetNot<"isSingleFloat()", CCAssignToReg<[D0]>>>
 177 ]>;
 178
 179 //===----------------------------------------------------------------------===//
 180 // Mips FastCC Calling Convention
 181 //===----------------------------------------------------------------------===//
 182 def CC_MipsO32_FastCC : CallingConv<[
 183   // f64 arguments are passed in double-precision floating pointer registers.
 184   CCIfType<[f64], CCIfSubtargetNot<"isFP64bit()",
 185                                    CCAssignToReg<[D0, D1, D2, D3, D4, D5, D6,
 186                                                   D7, D8, D9]>>>,
 187   CCIfType<[f64], CCIfSubtarget<"isFP64bit()", CCIfSubtarget<"useOddSPReg()",
 188                                 CCAssignToReg<[D0_64, D1_64, D2_64, D3_64,
 189                                                D4_64, D5_64, D6_64, D7_64,
 190                                                D8_64, D9_64, D10_64, D11_64,
 191                                                D12_64, D13_64, D14_64, D15_64,
 192                                                D16_64, D17_64, D18_64,
 193                                                D19_64]>>>>,
 194   CCIfType<[f64], CCIfSubtarget<"isFP64bit()", CCIfSubtarget<"noOddSPReg()",
 195                                 CCAssignToReg<[D0_64, D2_64, D4_64, D6_64,
 196                                                D8_64, D10_64, D12_64, D14_64,
 197                                                D16_64, D18_64]>>>>,
 198
 199   // Stack parameter slots for f64 are 64-bit doublewords and 8-byte aligned.
 200   CCIfType<[f64], CCAssignToStack<8, 8>>
 201 ]>;
 202
 203 def CC_MipsN_FastCC : CallingConv<[
 204   // Integer arguments are passed in integer registers.
 205   CCIfType<[i64], CCAssignToReg<[A0_64, A1_64, A2_64, A3_64, T0_64, T1_64,
 206                                  T2_64, T3_64, T4_64, T5_64, T6_64, T7_64,
 207                                  T8_64, V1_64]>>,
 208
 209   // f64 arguments are passed in double-precision floating pointer registers.
 210   CCIfType<[f64], CCAssignToReg<[D0_64, D1_64, D2_64, D3_64, D4_64, D5_64,
 211                                  D6_64, D7_64, D8_64, D9_64, D10_64, D11_64,
 212                                  D12_64, D13_64, D14_64, D15_64, D16_64, D17_64,
 213                                  D18_64, D19_64]>>,
 214
 215   // Stack parameter slots for i64 and f64 are 64-bit doublewords and
 216   // 8-byte aligned.
 217   CCIfType<[i64, f64], CCAssignToStack<8, 8>>
 218 ]>;
 219
 220 def CC_Mips_FastCC : CallingConv<[
 221   // Handles byval parameters.
 222   CCIfByVal<CCPassByVal<4, 4>>,
 223
 224   // Promote i8/i16 arguments to i32.
 225   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 226
 227   // Integer arguments are passed in integer registers. All scratch registers,
 228   // except for AT, V0 and T9, are available to be used as argument registers.
 229   CCIfType<[i32], CCIfSubtargetNot<"isTargetNaCl()",
 230       CCAssignToReg<[A0, A1, A2, A3, T0, T1, T2, T3, T4, T5, T6, T7, T8, V1]>>>,
 231
 232   // In NaCl, T6, T7 and T8 are reserved and not available as argument
 233   // registers for fastcc.  T6 contains the mask for sandboxing control flow
 234   // (indirect jumps and calls).  T7 contains the mask for sandboxing memory
 235   // accesses (loads and stores).  T8 contains the thread pointer.
 236   CCIfType<[i32], CCIfSubtarget<"isTargetNaCl()",
 237       CCAssignToReg<[A0, A1, A2, A3, T0, T1, T2, T3, T4, T5, V1]>>>,
 238
 239   // f32 arguments are passed in single-precision floating pointer registers.
 240   CCIfType<[f32], CCIfSubtarget<"useOddSPReg()",
 241       CCAssignToReg<[F0, F1, F2, F3, F4, F5, F6, F7, F8, F9, F10, F11, F12, F13,
 242                      F14, F15, F16, F17, F18, F19]>>>,
 243
 244   // Don't use odd numbered single-precision registers for -mno-odd-spreg.
 245   CCIfType<[f32], CCIfSubtarget<"noOddSPReg()",
 246       CCAssignToReg<[F0, F2, F4, F6, F8, F10, F12, F14, F16, F18]>>>,
 247
 248   // Stack parameter slots for i32 and f32 are 32-bit words and 4-byte aligned.
 249   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 250
 251   CCIfSubtarget<"isABI_EABI()", CCDelegateTo<CC_MipsEABI>>,
 252   CCIfSubtarget<"isABI_O32()", CCDelegateTo<CC_MipsO32_FastCC>>,
 253   CCDelegateTo<CC_MipsN_FastCC>
 254 ]>;
 255
 256 //==
 257
 258 def CC_Mips16RetHelper : CallingConv<[
 259   // Integer arguments are passed in integer registers.
 260   CCIfType<[i32], CCAssignToReg<[V0, V1, A0, A1]>>
 261 ]>;
 262
 263 //===----------------------------------------------------------------------===//
 264 // Mips Calling Convention Dispatch
 265 //===----------------------------------------------------------------------===//
 266
 267 def RetCC_Mips : CallingConv<[
 268   CCIfSubtarget<"isABI_EABI()", CCDelegateTo<RetCC_MipsEABI>>,
 269   CCIfSubtarget<"isABI_N32()", CCDelegateTo<RetCC_MipsN>>,
 270   CCIfSubtarget<"isABI_N64()", CCDelegateTo<RetCC_MipsN>>,
 271   CCDelegateTo<RetCC_MipsO32>
 272 ]>;
 273
 274 //===----------------------------------------------------------------------===//
 275 // Callee-saved register lists.
 276 //===----------------------------------------------------------------------===//
 277
 278 def CSR_SingleFloatOnly : CalleeSavedRegs<(add (sequence "F%u", 31, 20), RA, FP,
 279                                                (sequence "S%u", 7, 0))>;
 280
 281 def CSR_O32_FPXX : CalleeSavedRegs<(add (sequence "D%u", 15, 10), RA, FP,
 282                                         (sequence "S%u", 7, 0))> {
 283   let OtherPreserved = (add (decimate (sequence "F%u", 30, 20), 2));
 284 }
 285
 286 def CSR_O32 : CalleeSavedRegs<(add (sequence "D%u", 15, 10), RA, FP,
 287                                    (sequence "S%u", 7, 0))>;
 288
 289 def CSR_O32_FP64 :
 290   CalleeSavedRegs<(add (decimate (sequence "D%u_64", 30, 20), 2), RA, FP,
 291                        (sequence "S%u", 7, 0))>;
 292
 293 def CSR_N32 : CalleeSavedRegs<(add D20_64, D22_64, D24_64, D26_64, D28_64,
 294                                    D30_64, RA_64, FP_64, GP_64,
 295                                    (sequence "S%u_64", 7, 0))>;
 296
 297 def CSR_N64 : CalleeSavedRegs<(add (sequence "D%u_64", 31, 24), RA_64, FP_64,
 298                                    GP_64, (sequence "S%u_64", 7, 0))>;
 299
 300 def CSR_Mips16RetHelper :
 301   CalleeSavedRegs<(add V0, V1, FP,
 302                    (sequence "A%u", 3, 0), (sequence "S%u", 7, 0),
 303                    (sequence "D%u", 15, 10))>;