lib/Target/ARM/ARMInstrInfo.td

   1 //===- ARMInstrInfo.td - Target Description for ARM Target -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the ARM instructions in TableGen format.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // ARM specific DAG Nodes.
  16 //
  17
  18 // Type profiles.
  19 def SDT_ARMCallSeqStart : SDCallSeqStart<[ SDTCisVT<0, i32> ]>;
  20 def SDT_ARMCallSeqEnd   : SDCallSeqEnd<[ SDTCisVT<0, i32>, SDTCisVT<1, i32> ]>;
  21 def SDT_ARMStructByVal : SDTypeProfile<0, 4,
  22                                        [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
  23                                         SDTCisVT<2, i32>, SDTCisVT<3, i32>]>;
  24
  25 def SDT_ARMSaveCallPC : SDTypeProfile<0, 1, []>;
  26
  27 def SDT_ARMcall    : SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>;
  28
  29 def SDT_ARMCMov    : SDTypeProfile<1, 3,
  30                                    [SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>,
  31                                     SDTCisVT<3, i32>]>;
  32
  33 def SDT_ARMBrcond  : SDTypeProfile<0, 2,
  34                                    [SDTCisVT<0, OtherVT>, SDTCisVT<1, i32>]>;
  35
  36 def SDT_ARMBrJT    : SDTypeProfile<0, 3,
  37                                   [SDTCisPtrTy<0>, SDTCisVT<1, i32>,
  38                                    SDTCisVT<2, i32>]>;
  39
  40 def SDT_ARMBr2JT   : SDTypeProfile<0, 4,
  41                                   [SDTCisPtrTy<0>, SDTCisVT<1, i32>,
  42                                    SDTCisVT<2, i32>, SDTCisVT<3, i32>]>;
  43
  44 def SDT_ARMBCC_i64 : SDTypeProfile<0, 6,
  45                                   [SDTCisVT<0, i32>,
  46                                    SDTCisVT<1, i32>, SDTCisVT<2, i32>,
  47                                    SDTCisVT<3, i32>, SDTCisVT<4, i32>,
  48                                    SDTCisVT<5, OtherVT>]>;
  49
  50 def SDT_ARMAnd     : SDTypeProfile<1, 2,
  51                                    [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
  52                                     SDTCisVT<2, i32>]>;
  53
  54 def SDT_ARMCmp     : SDTypeProfile<0, 2, [SDTCisSameAs<0, 1>]>;
  55
  56 def SDT_ARMPICAdd  : SDTypeProfile<1, 2, [SDTCisSameAs<0, 1>,
  57                                           SDTCisPtrTy<1>, SDTCisVT<2, i32>]>;
  58
  59 def SDT_ARMThreadPointer : SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;
  60 def SDT_ARMEH_SJLJ_Setjmp : SDTypeProfile<1, 2, [SDTCisInt<0>, SDTCisPtrTy<1>,
  61                                                  SDTCisInt<2>]>;
  62 def SDT_ARMEH_SJLJ_Longjmp: SDTypeProfile<0, 2, [SDTCisPtrTy<0>, SDTCisInt<1>]>;
  63
  64 def SDT_ARMMEMBARRIER     : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
  65
  66 def SDT_ARMPREFETCH : SDTypeProfile<0, 3, [SDTCisPtrTy<0>, SDTCisSameAs<1, 2>,
  67                                            SDTCisInt<1>]>;
  68
  69 def SDT_ARMTCRET : SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>;
  70
  71 def SDT_ARMBFI : SDTypeProfile<1, 3, [SDTCisVT<0, i32>, SDTCisVT<1, i32>,
  72                                       SDTCisVT<2, i32>, SDTCisVT<3, i32>]>;
  73
  74 def SDT_ARMVMAXNM : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisFP<1>, SDTCisFP<2>]>;
  75 def SDT_ARMVMINNM : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisFP<1>, SDTCisFP<2>]>;
  76
  77 def SDTBinaryArithWithFlags : SDTypeProfile<2, 2,
  78                                             [SDTCisSameAs<0, 2>,
  79                                              SDTCisSameAs<0, 3>,
  80                                              SDTCisInt<0>, SDTCisVT<1, i32>]>;
  81
  82 // SDTBinaryArithWithFlagsInOut - RES1, CPSR = op LHS, RHS, CPSR
  83 def SDTBinaryArithWithFlagsInOut : SDTypeProfile<2, 3,
  84                                             [SDTCisSameAs<0, 2>,
  85                                              SDTCisSameAs<0, 3>,
  86                                              SDTCisInt<0>,
  87                                              SDTCisVT<1, i32>,
  88                                              SDTCisVT<4, i32>]>;
  89
  90 def SDT_ARM64bitmlal : SDTypeProfile<2,4, [ SDTCisVT<0, i32>, SDTCisVT<1, i32>,
  91                                         SDTCisVT<2, i32>, SDTCisVT<3, i32>,
  92                                         SDTCisVT<4, i32>, SDTCisVT<5, i32> ] >;
  93 def ARMUmlal         : SDNode<"ARMISD::UMLAL", SDT_ARM64bitmlal>;
  94 def ARMSmlal         : SDNode<"ARMISD::SMLAL", SDT_ARM64bitmlal>;
  95
  96 // Node definitions.
  97 def ARMWrapper       : SDNode<"ARMISD::Wrapper",     SDTIntUnaryOp>;
  98 def ARMWrapperPIC    : SDNode<"ARMISD::WrapperPIC",  SDTIntUnaryOp>;
  99 def ARMWrapperJT     : SDNode<"ARMISD::WrapperJT",   SDTIntBinOp>;
 100
 101 def ARMcallseq_start : SDNode<"ISD::CALLSEQ_START", SDT_ARMCallSeqStart,
 102                               [SDNPHasChain, SDNPSideEffect, SDNPOutGlue]>;
 103 def ARMcallseq_end   : SDNode<"ISD::CALLSEQ_END",   SDT_ARMCallSeqEnd,
 104                               [SDNPHasChain, SDNPSideEffect,
 105                                SDNPOptInGlue, SDNPOutGlue]>;
 106 def ARMcopystructbyval : SDNode<"ARMISD::COPY_STRUCT_BYVAL" ,
 107                                 SDT_ARMStructByVal,
 108                                 [SDNPHasChain, SDNPInGlue, SDNPOutGlue,
 109                                  SDNPMayStore, SDNPMayLoad]>;
 110
 111 def ARMcall          : SDNode<"ARMISD::CALL", SDT_ARMcall,
 112                               [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 113                                SDNPVariadic]>;
 114 def ARMcall_pred    : SDNode<"ARMISD::CALL_PRED", SDT_ARMcall,
 115                               [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 116                                SDNPVariadic]>;
 117 def ARMcall_nolink   : SDNode<"ARMISD::CALL_NOLINK", SDT_ARMcall,
 118                               [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 119                                SDNPVariadic]>;
 120
 121 def ARMretflag       : SDNode<"ARMISD::RET_FLAG", SDTNone,
 122                               [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
 123 def ARMintretflag    : SDNode<"ARMISD::INTRET_FLAG", SDT_ARMcall,
 124                               [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
 125 def ARMcmov          : SDNode<"ARMISD::CMOV", SDT_ARMCMov,
 126                               [SDNPInGlue]>;
 127
 128 def ARMbrcond        : SDNode<"ARMISD::BRCOND", SDT_ARMBrcond,
 129                               [SDNPHasChain, SDNPInGlue, SDNPOutGlue]>;
 130
 131 def ARMbrjt          : SDNode<"ARMISD::BR_JT", SDT_ARMBrJT,
 132                               [SDNPHasChain]>;
 133 def ARMbr2jt         : SDNode<"ARMISD::BR2_JT", SDT_ARMBr2JT,
 134                               [SDNPHasChain]>;
 135
 136 def ARMBcci64        : SDNode<"ARMISD::BCC_i64", SDT_ARMBCC_i64,
 137                               [SDNPHasChain]>;
 138
 139 def ARMcmp           : SDNode<"ARMISD::CMP", SDT_ARMCmp,
 140                               [SDNPOutGlue]>;
 141
 142 def ARMcmn           : SDNode<"ARMISD::CMN", SDT_ARMCmp,
 143                               [SDNPOutGlue]>;
 144
 145 def ARMcmpZ          : SDNode<"ARMISD::CMPZ", SDT_ARMCmp,
 146                               [SDNPOutGlue, SDNPCommutative]>;
 147
 148 def ARMpic_add       : SDNode<"ARMISD::PIC_ADD", SDT_ARMPICAdd>;
 149
 150 def ARMsrl_flag      : SDNode<"ARMISD::SRL_FLAG", SDTIntUnaryOp, [SDNPOutGlue]>;
 151 def ARMsra_flag      : SDNode<"ARMISD::SRA_FLAG", SDTIntUnaryOp, [SDNPOutGlue]>;
 152 def ARMrrx           : SDNode<"ARMISD::RRX"     , SDTIntUnaryOp, [SDNPInGlue ]>;
 153
 154 def ARMaddc          : SDNode<"ARMISD::ADDC",  SDTBinaryArithWithFlags,
 155                               [SDNPCommutative]>;
 156 def ARMsubc          : SDNode<"ARMISD::SUBC",  SDTBinaryArithWithFlags>;
 157 def ARMadde          : SDNode<"ARMISD::ADDE",  SDTBinaryArithWithFlagsInOut>;
 158 def ARMsube          : SDNode<"ARMISD::SUBE",  SDTBinaryArithWithFlagsInOut>;
 159
 160 def ARMthread_pointer: SDNode<"ARMISD::THREAD_POINTER", SDT_ARMThreadPointer>;
 161 def ARMeh_sjlj_setjmp: SDNode<"ARMISD::EH_SJLJ_SETJMP",
 162                                SDT_ARMEH_SJLJ_Setjmp,
 163                                [SDNPHasChain, SDNPSideEffect]>;
 164 def ARMeh_sjlj_longjmp: SDNode<"ARMISD::EH_SJLJ_LONGJMP",
 165                                SDT_ARMEH_SJLJ_Longjmp,
 166                                [SDNPHasChain, SDNPSideEffect]>;
 167
 168 def ARMMemBarrierMCR  : SDNode<"ARMISD::MEMBARRIER_MCR", SDT_ARMMEMBARRIER,
 169                                [SDNPHasChain, SDNPSideEffect]>;
 170 def ARMPreload        : SDNode<"ARMISD::PRELOAD", SDT_ARMPREFETCH,
 171                                [SDNPHasChain, SDNPMayLoad, SDNPMayStore]>;
 172
 173 def ARMrbit          : SDNode<"ARMISD::RBIT", SDTIntUnaryOp>;
 174
 175 def ARMtcret         : SDNode<"ARMISD::TC_RETURN", SDT_ARMTCRET,
 176                         [SDNPHasChain,  SDNPOptInGlue, SDNPVariadic]>;
 177
 178 def ARMbfi           : SDNode<"ARMISD::BFI", SDT_ARMBFI>;
 179
 180 def ARMvmaxnm        : SDNode<"ARMISD::VMAXNM", SDT_ARMVMAXNM, []>;
 181 def ARMvminnm        : SDNode<"ARMISD::VMINNM", SDT_ARMVMINNM, []>;
 182
 183 //===----------------------------------------------------------------------===//
 184 // ARM Instruction Predicate Definitions.
 185 //
 186 def HasV4T           : Predicate<"Subtarget->hasV4TOps()">,
 187                                  AssemblerPredicate<"HasV4TOps", "armv4t">;
 188 def NoV4T            : Predicate<"!Subtarget->hasV4TOps()">;
 189 def HasV5T           : Predicate<"Subtarget->hasV5TOps()">,
 190                                  AssemblerPredicate<"HasV5TOps", "armv5t">;
 191 def HasV5TE          : Predicate<"Subtarget->hasV5TEOps()">,
 192                                  AssemblerPredicate<"HasV5TEOps", "armv5te">;
 193 def HasV6            : Predicate<"Subtarget->hasV6Ops()">,
 194                                  AssemblerPredicate<"HasV6Ops", "armv6">;
 195 def NoV6             : Predicate<"!Subtarget->hasV6Ops()">;
 196 def HasV6M           : Predicate<"Subtarget->hasV6MOps()">,
 197                                  AssemblerPredicate<"HasV6MOps",
 198                                                     "armv6m or armv6t2">;
 199 def HasV6T2          : Predicate<"Subtarget->hasV6T2Ops()">,
 200                                  AssemblerPredicate<"HasV6T2Ops", "armv6t2">;
 201 def NoV6T2           : Predicate<"!Subtarget->hasV6T2Ops()">;
 202 def HasV7            : Predicate<"Subtarget->hasV7Ops()">,
 203                                  AssemblerPredicate<"HasV7Ops", "armv7">;
 204 def HasV8            : Predicate<"Subtarget->hasV8Ops()">,
 205                                  AssemblerPredicate<"HasV8Ops", "armv8">;
 206 def PreV8            : Predicate<"!Subtarget->hasV8Ops()">,
 207                                  AssemblerPredicate<"!HasV8Ops", "armv7 or earlier">;
 208 def NoVFP            : Predicate<"!Subtarget->hasVFP2()">;
 209 def HasVFP2          : Predicate<"Subtarget->hasVFP2()">,
 210                                  AssemblerPredicate<"FeatureVFP2", "VFP2">;
 211 def HasVFP3          : Predicate<"Subtarget->hasVFP3()">,
 212                                  AssemblerPredicate<"FeatureVFP3", "VFP3">;
 213 def HasVFP4          : Predicate<"Subtarget->hasVFP4()">,
 214                                  AssemblerPredicate<"FeatureVFP4", "VFP4">;
 215 def HasDPVFP         : Predicate<"!Subtarget->isFPOnlySP()">,
 216                                  AssemblerPredicate<"!FeatureVFPOnlySP",
 217                                                     "double precision VFP">;
 218 def HasFPARMv8       : Predicate<"Subtarget->hasFPARMv8()">,
 219                                  AssemblerPredicate<"FeatureFPARMv8", "FPARMv8">;
 220 def HasNEON          : Predicate<"Subtarget->hasNEON()">,
 221                                  AssemblerPredicate<"FeatureNEON", "NEON">;
 222 def HasCrypto        : Predicate<"Subtarget->hasCrypto()">,
 223                                  AssemblerPredicate<"FeatureCrypto", "crypto">;
 224 def HasCRC           : Predicate<"Subtarget->hasCRC()">,
 225                                  AssemblerPredicate<"FeatureCRC", "crc">;
 226 def HasFP16          : Predicate<"Subtarget->hasFP16()">,
 227                                  AssemblerPredicate<"FeatureFP16","half-float">;
 228 def HasDivide        : Predicate<"Subtarget->hasDivide()">,
 229                                  AssemblerPredicate<"FeatureHWDiv", "divide in THUMB">;
 230 def HasDivideInARM   : Predicate<"Subtarget->hasDivideInARMMode()">,
 231                                  AssemblerPredicate<"FeatureHWDivARM", "divide in ARM">;
 232 def HasT2ExtractPack : Predicate<"Subtarget->hasT2ExtractPack()">,
 233                                  AssemblerPredicate<"FeatureT2XtPk",
 234                                                      "pack/extract">;
 235 def HasThumb2DSP     : Predicate<"Subtarget->hasThumb2DSP()">,
 236                                  AssemblerPredicate<"FeatureDSPThumb2",
 237                                                     "thumb2-dsp">;
 238 def HasDB            : Predicate<"Subtarget->hasDataBarrier()">,
 239                                  AssemblerPredicate<"FeatureDB",
 240                                                     "data-barriers">;
 241 def HasMP            : Predicate<"Subtarget->hasMPExtension()">,
 242                                  AssemblerPredicate<"FeatureMP",
 243                                                     "mp-extensions">;
 244 def HasVirtualization: Predicate<"false">,
 245                                  AssemblerPredicate<"FeatureVirtualization",
 246                                                    "virtualization-extensions">;
 247 def HasTrustZone     : Predicate<"Subtarget->hasTrustZone()">,
 248                                  AssemblerPredicate<"FeatureTrustZone",
 249                                                     "TrustZone">;
 250 def HasZCZ           : Predicate<"Subtarget->hasZeroCycleZeroing()">;
 251 def UseNEONForFP     : Predicate<"Subtarget->useNEONForSinglePrecisionFP()">;
 252 def DontUseNEONForFP : Predicate<"!Subtarget->useNEONForSinglePrecisionFP()">;
 253 def IsThumb          : Predicate<"Subtarget->isThumb()">,
 254                                  AssemblerPredicate<"ModeThumb", "thumb">;
 255 def IsThumb1Only     : Predicate<"Subtarget->isThumb1Only()">;
 256 def IsThumb2         : Predicate<"Subtarget->isThumb2()">,
 257                                  AssemblerPredicate<"ModeThumb,FeatureThumb2",
 258                                                     "thumb2">;
 259 def IsMClass         : Predicate<"Subtarget->isMClass()">,
 260                                  AssemblerPredicate<"FeatureMClass", "armv*m">;
 261 def IsNotMClass      : Predicate<"!Subtarget->isMClass()">,
 262                                  AssemblerPredicate<"!FeatureMClass",
 263                                                     "!armv*m">;
 264 def IsARM            : Predicate<"!Subtarget->isThumb()">,
 265                                  AssemblerPredicate<"!ModeThumb", "arm-mode">;
 266 def IsIOS            : Predicate<"Subtarget->isTargetIOS()">;
 267 def IsNotIOS         : Predicate<"!Subtarget->isTargetIOS()">;
 268 def IsMachO          : Predicate<"Subtarget->isTargetMachO()">;
 269 def IsNotMachO       : Predicate<"!Subtarget->isTargetMachO()">;
 270 def IsNaCl           : Predicate<"Subtarget->isTargetNaCl()">;
 271 def UseNaClTrap      : Predicate<"Subtarget->useNaClTrap()">,
 272                                  AssemblerPredicate<"FeatureNaClTrap", "NaCl">;
 273 def DontUseNaClTrap  : Predicate<"!Subtarget->useNaClTrap()">;
 274
 275 // FIXME: Eventually this will be just "hasV6T2Ops".
 276 def UseMovt          : Predicate<"Subtarget->useMovt(*MF)">;
 277 def DontUseMovt      : Predicate<"!Subtarget->useMovt(*MF)">;
 278 def UseFPVMLx        : Predicate<"Subtarget->useFPVMLx()">;
 279 def UseMulOps        : Predicate<"Subtarget->useMulOps()">;
 280
 281 // Prefer fused MAC for fp mul + add over fp VMLA / VMLS if they are available.
 282 // But only select them if more precision in FP computation is allowed.
 283 // Do not use them for Darwin platforms.
 284 def UseFusedMAC      : Predicate<"(TM.Options.AllowFPOpFusion =="
 285                                  " FPOpFusion::Fast && "
 286                                  " Subtarget->hasVFP4()) && "
 287                                  "!Subtarget->isTargetDarwin()">;
 288 def DontUseFusedMAC  : Predicate<"!(TM.Options.AllowFPOpFusion =="
 289                                  " FPOpFusion::Fast &&"
 290                                  " Subtarget->hasVFP4()) || "
 291                                  "Subtarget->isTargetDarwin()">;
 292
 293 // VGETLNi32 is microcoded on Swift - prefer VMOV.
 294 def HasFastVGETLNi32 : Predicate<"!Subtarget->isSwift()">;
 295 def HasSlowVGETLNi32 : Predicate<"Subtarget->isSwift()">;
 296
 297 // VDUP.32 is microcoded on Swift - prefer VMOV.
 298 def HasFastVDUP32 : Predicate<"!Subtarget->isSwift()">;
 299 def HasSlowVDUP32 : Predicate<"Subtarget->isSwift()">;
 300
 301 // Cortex-A9 prefers VMOVSR to VMOVDRR even when using NEON for scalar FP, as
 302 // this allows more effective execution domain optimization. See
 303 // setExecutionDomain().
 304 def UseVMOVSR : Predicate<"Subtarget->isCortexA9() || !Subtarget->useNEONForSinglePrecisionFP()">;
 305 def DontUseVMOVSR : Predicate<"!Subtarget->isCortexA9() && Subtarget->useNEONForSinglePrecisionFP()">;
 306
 307 def IsLE             : Predicate<"getTargetLowering()->isLittleEndian()">;
 308 def IsBE             : Predicate<"getTargetLowering()->isBigEndian()">;
 309
 310 //===----------------------------------------------------------------------===//
 311 // ARM Flag Definitions.
 312
 313 class RegConstraint<string C> {
 314   string Constraints = C;
 315 }
 316
 317 //===----------------------------------------------------------------------===//
 318 //  ARM specific transformation functions and pattern fragments.
 319 //
 320
 321 // imm_neg_XFORM - Return the negation of an i32 immediate value.
 322 def imm_neg_XFORM : SDNodeXForm<imm, [{
 323   return CurDAG->getTargetConstant(-(int)N->getZExtValue(), MVT::i32);
 324 }]>;
 325
 326 // imm_not_XFORM - Return the complement of a i32 immediate value.
 327 def imm_not_XFORM : SDNodeXForm<imm, [{
 328   return CurDAG->getTargetConstant(~(int)N->getZExtValue(), MVT::i32);
 329 }]>;
 330
 331 /// imm16_31 predicate - True if the 32-bit immediate is in the range [16,31].
 332 def imm16_31 : ImmLeaf<i32, [{
 333   return (int32_t)Imm >= 16 && (int32_t)Imm < 32;
 334 }]>;
 335
 336 def so_imm_neg_asmoperand : AsmOperandClass { let Name = "ARMSOImmNeg"; }
 337 def so_imm_neg : Operand<i32>, PatLeaf<(imm), [{
 338     unsigned Value = -(unsigned)N->getZExtValue();
 339     return Value && ARM_AM::getSOImmVal(Value) != -1;
 340   }], imm_neg_XFORM> {
 341   let ParserMatchClass = so_imm_neg_asmoperand;
 342 }
 343
 344 // Note: this pattern doesn't require an encoder method and such, as it's
 345 // only used on aliases (Pat<> and InstAlias<>). The actual encoding
 346 // is handled by the destination instructions, which use so_imm.
 347 def so_imm_not_asmoperand : AsmOperandClass { let Name = "ARMSOImmNot"; }
 348 def so_imm_not : Operand<i32>, PatLeaf<(imm), [{
 349     return ARM_AM::getSOImmVal(~(uint32_t)N->getZExtValue()) != -1;
 350   }], imm_not_XFORM> {
 351   let ParserMatchClass = so_imm_not_asmoperand;
 352 }
 353
 354 // sext_16_node predicate - True if the SDNode is sign-extended 16 or more bits.
 355 def sext_16_node : PatLeaf<(i32 GPR:$a), [{
 356   return CurDAG->ComputeNumSignBits(SDValue(N,0)) >= 17;
 357 }]>;
 358
 359 /// Split a 32-bit immediate into two 16 bit parts.
 360 def hi16 : SDNodeXForm<imm, [{
 361   return CurDAG->getTargetConstant((uint32_t)N->getZExtValue() >> 16, MVT::i32);
 362 }]>;
 363
 364 def lo16AllZero : PatLeaf<(i32 imm), [{
 365   // Returns true if all low 16-bits are 0.
 366   return (((uint32_t)N->getZExtValue()) & 0xFFFFUL) == 0;
 367 }], hi16>;
 368
 369 class BinOpWithFlagFrag<dag res> :
 370       PatFrag<(ops node:$LHS, node:$RHS, node:$FLAG), res>;
 371 class BinOpFrag<dag res> : PatFrag<(ops node:$LHS, node:$RHS), res>;
 372 class UnOpFrag <dag res> : PatFrag<(ops node:$Src), res>;
 373
 374 // An 'and' node with a single use.
 375 def and_su : PatFrag<(ops node:$lhs, node:$rhs), (and node:$lhs, node:$rhs), [{
 376   return N->hasOneUse();
 377 }]>;
 378
 379 // An 'xor' node with a single use.
 380 def xor_su : PatFrag<(ops node:$lhs, node:$rhs), (xor node:$lhs, node:$rhs), [{
 381   return N->hasOneUse();
 382 }]>;
 383
 384 // An 'fmul' node with a single use.
 385 def fmul_su : PatFrag<(ops node:$lhs, node:$rhs), (fmul node:$lhs, node:$rhs),[{
 386   return N->hasOneUse();
 387 }]>;
 388
 389 // An 'fadd' node which checks for single non-hazardous use.
 390 def fadd_mlx : PatFrag<(ops node:$lhs, node:$rhs),(fadd node:$lhs, node:$rhs),[{
 391   return hasNoVMLxHazardUse(N);
 392 }]>;
 393
 394 // An 'fsub' node which checks for single non-hazardous use.
 395 def fsub_mlx : PatFrag<(ops node:$lhs, node:$rhs),(fsub node:$lhs, node:$rhs),[{
 396   return hasNoVMLxHazardUse(N);
 397 }]>;
 398
 399 //===----------------------------------------------------------------------===//
 400 // Operand Definitions.
 401 //
 402
 403 // Immediate operands with a shared generic asm render method.
 404 class ImmAsmOperand : AsmOperandClass { let RenderMethod = "addImmOperands"; }
 405
 406 // Branch target.
 407 // FIXME: rename brtarget to t2_brtarget
 408 def brtarget : Operand<OtherVT> {
 409   let EncoderMethod = "getBranchTargetOpValue";
 410   let OperandType = "OPERAND_PCREL";
 411   let DecoderMethod = "DecodeT2BROperand";
 412 }
 413
 414 // FIXME: get rid of this one?
 415 def uncondbrtarget : Operand<OtherVT> {
 416   let EncoderMethod = "getUnconditionalBranchTargetOpValue";
 417   let OperandType = "OPERAND_PCREL";
 418 }
 419
 420 // Branch target for ARM. Handles conditional/unconditional
 421 def br_target : Operand<OtherVT> {
 422   let EncoderMethod = "getARMBranchTargetOpValue";
 423   let OperandType = "OPERAND_PCREL";
 424 }
 425
 426 // Call target.
 427 // FIXME: rename bltarget to t2_bl_target?
 428 def bltarget : Operand<i32> {
 429   // Encoded the same as branch targets.
 430   let EncoderMethod = "getBranchTargetOpValue";
 431   let OperandType = "OPERAND_PCREL";
 432 }
 433
 434 // Call target for ARM. Handles conditional/unconditional
 435 // FIXME: rename bl_target to t2_bltarget?
 436 def bl_target : Operand<i32> {
 437   let EncoderMethod = "getARMBLTargetOpValue";
 438   let OperandType = "OPERAND_PCREL";
 439 }
 440
 441 def blx_target : Operand<i32> {
 442   let EncoderMethod = "getARMBLXTargetOpValue";
 443   let OperandType = "OPERAND_PCREL";
 444 }
 445
 446 // A list of registers separated by comma. Used by load/store multiple.
 447 def RegListAsmOperand : AsmOperandClass { let Name = "RegList"; }
 448 def reglist : Operand<i32> {
 449   let EncoderMethod = "getRegisterListOpValue";
 450   let ParserMatchClass = RegListAsmOperand;
 451   let PrintMethod = "printRegisterList";
 452   let DecoderMethod = "DecodeRegListOperand";
 453 }
 454
 455 def GPRPairOp : RegisterOperand<GPRPair, "printGPRPairOperand">;
 456
 457 def DPRRegListAsmOperand : AsmOperandClass { let Name = "DPRRegList"; }
 458 def dpr_reglist : Operand<i32> {
 459   let EncoderMethod = "getRegisterListOpValue";
 460   let ParserMatchClass = DPRRegListAsmOperand;
 461   let PrintMethod = "printRegisterList";
 462   let DecoderMethod = "DecodeDPRRegListOperand";
 463 }
 464
 465 def SPRRegListAsmOperand : AsmOperandClass { let Name = "SPRRegList"; }
 466 def spr_reglist : Operand<i32> {
 467   let EncoderMethod = "getRegisterListOpValue";
 468   let ParserMatchClass = SPRRegListAsmOperand;
 469   let PrintMethod = "printRegisterList";
 470   let DecoderMethod = "DecodeSPRRegListOperand";
 471 }
 472
 473 // An operand for the CONSTPOOL_ENTRY pseudo-instruction.
 474 def cpinst_operand : Operand<i32> {
 475   let PrintMethod = "printCPInstOperand";
 476 }
 477
 478 // Local PC labels.
 479 def pclabel : Operand<i32> {
 480   let PrintMethod = "printPCLabel";
 481 }
 482
 483 // ADR instruction labels.
 484 def AdrLabelAsmOperand : AsmOperandClass { let Name = "AdrLabel"; }
 485 def adrlabel : Operand<i32> {
 486   let EncoderMethod = "getAdrLabelOpValue";
 487   let ParserMatchClass = AdrLabelAsmOperand;
 488   let PrintMethod = "printAdrLabelOperand<0>";
 489 }
 490
 491 def neon_vcvt_imm32 : Operand<i32> {
 492   let EncoderMethod = "getNEONVcvtImm32OpValue";
 493   let DecoderMethod = "DecodeVCVTImmOperand";
 494 }
 495
 496 // rot_imm: An integer that encodes a rotate amount. Must be 8, 16, or 24.
 497 def rot_imm_XFORM: SDNodeXForm<imm, [{
 498   switch (N->getZExtValue()){
 499   default: llvm_unreachable(nullptr);
 500   case 0:  return CurDAG->getTargetConstant(0, MVT::i32);
 501   case 8:  return CurDAG->getTargetConstant(1, MVT::i32);
 502   case 16: return CurDAG->getTargetConstant(2, MVT::i32);
 503   case 24: return CurDAG->getTargetConstant(3, MVT::i32);
 504   }
 505 }]>;
 506 def RotImmAsmOperand : AsmOperandClass {
 507   let Name = "RotImm";
 508   let ParserMethod = "parseRotImm";
 509 }
 510 def rot_imm : Operand<i32>, PatLeaf<(i32 imm), [{
 511     int32_t v = N->getZExtValue();
 512     return v == 8 || v == 16 || v == 24; }],
 513     rot_imm_XFORM> {
 514   let PrintMethod = "printRotImmOperand";
 515   let ParserMatchClass = RotImmAsmOperand;
 516 }
 517
 518 // shift_imm: An integer that encodes a shift amount and the type of shift
 519 // (asr or lsl). The 6-bit immediate encodes as:
 520 //    {5}     0 ==> lsl
 521 //            1     asr
 522 //    {4-0}   imm5 shift amount.
 523 //            asr #32 encoded as imm5 == 0.
 524 def ShifterImmAsmOperand : AsmOperandClass {
 525   let Name = "ShifterImm";
 526   let ParserMethod = "parseShifterImm";
 527 }
 528 def shift_imm : Operand<i32> {
 529   let PrintMethod = "printShiftImmOperand";
 530   let ParserMatchClass = ShifterImmAsmOperand;
 531 }
 532
 533 // shifter_operand operands: so_reg_reg, so_reg_imm, and so_imm.
 534 def ShiftedRegAsmOperand : AsmOperandClass { let Name = "RegShiftedReg"; }
 535 def so_reg_reg : Operand<i32>,  // reg reg imm
 536                  ComplexPattern<i32, 3, "SelectRegShifterOperand",
 537                                 [shl, srl, sra, rotr]> {
 538   let EncoderMethod = "getSORegRegOpValue";
 539   let PrintMethod = "printSORegRegOperand";
 540   let DecoderMethod = "DecodeSORegRegOperand";
 541   let ParserMatchClass = ShiftedRegAsmOperand;
 542   let MIOperandInfo = (ops GPRnopc, GPRnopc, i32imm);
 543 }
 544
 545 def ShiftedImmAsmOperand : AsmOperandClass { let Name = "RegShiftedImm"; }
 546 def so_reg_imm : Operand<i32>, // reg imm
 547                  ComplexPattern<i32, 2, "SelectImmShifterOperand",
 548                                 [shl, srl, sra, rotr]> {
 549   let EncoderMethod = "getSORegImmOpValue";
 550   let PrintMethod = "printSORegImmOperand";
 551   let DecoderMethod = "DecodeSORegImmOperand";
 552   let ParserMatchClass = ShiftedImmAsmOperand;
 553   let MIOperandInfo = (ops GPR, i32imm);
 554 }
 555
 556 // FIXME: Does this need to be distinct from so_reg?
 557 def shift_so_reg_reg : Operand<i32>,    // reg reg imm
 558                    ComplexPattern<i32, 3, "SelectShiftRegShifterOperand",
 559                                   [shl,srl,sra,rotr]> {
 560   let EncoderMethod = "getSORegRegOpValue";
 561   let PrintMethod = "printSORegRegOperand";
 562   let DecoderMethod = "DecodeSORegRegOperand";
 563   let ParserMatchClass = ShiftedRegAsmOperand;
 564   let MIOperandInfo = (ops GPR, GPR, i32imm);
 565 }
 566
 567 // FIXME: Does this need to be distinct from so_reg?
 568 def shift_so_reg_imm : Operand<i32>,    // reg reg imm
 569                    ComplexPattern<i32, 2, "SelectShiftImmShifterOperand",
 570                                   [shl,srl,sra,rotr]> {
 571   let EncoderMethod = "getSORegImmOpValue";
 572   let PrintMethod = "printSORegImmOperand";
 573   let DecoderMethod = "DecodeSORegImmOperand";
 574   let ParserMatchClass = ShiftedImmAsmOperand;
 575   let MIOperandInfo = (ops GPR, i32imm);
 576 }
 577
 578
 579 // so_imm - Match a 32-bit shifter_operand immediate operand, which is an
 580 // 8-bit immediate rotated by an arbitrary number of bits.
 581 def SOImmAsmOperand: ImmAsmOperand { let Name = "ARMSOImm"; }
 582 def so_imm : Operand<i32>, ImmLeaf<i32, [{
 583     return ARM_AM::getSOImmVal(Imm) != -1;
 584   }]> {
 585   let EncoderMethod = "getSOImmOpValue";
 586   let ParserMatchClass = SOImmAsmOperand;
 587   let DecoderMethod = "DecodeSOImmOperand";
 588 }
 589
 590 // Break so_imm's up into two pieces.  This handles immediates with up to 16
 591 // bits set in them.  This uses so_imm2part to match and so_imm2part_[12] to
 592 // get the first/second pieces.
 593 def so_imm2part : PatLeaf<(imm), [{
 594       return ARM_AM::isSOImmTwoPartVal((unsigned)N->getZExtValue());
 595 }]>;
 596
 597 /// arm_i32imm - True for +V6T2, or true only if so_imm2part is true.
 598 ///
 599 def arm_i32imm : PatLeaf<(imm), [{
 600   if (Subtarget->useMovt(*MF))
 601     return true;
 602   return ARM_AM::isSOImmTwoPartVal((unsigned)N->getZExtValue());
 603 }]>;
 604
 605 /// imm0_1 predicate - Immediate in the range [0,1].
 606 def Imm0_1AsmOperand: ImmAsmOperand { let Name = "Imm0_1"; }
 607 def imm0_1 : Operand<i32> { let ParserMatchClass = Imm0_1AsmOperand; }
 608
 609 /// imm0_3 predicate - Immediate in the range [0,3].
 610 def Imm0_3AsmOperand: ImmAsmOperand { let Name = "Imm0_3"; }
 611 def imm0_3 : Operand<i32> { let ParserMatchClass = Imm0_3AsmOperand; }
 612
 613 /// imm0_7 predicate - Immediate in the range [0,7].
 614 def Imm0_7AsmOperand: ImmAsmOperand { let Name = "Imm0_7"; }
 615 def imm0_7 : Operand<i32>, ImmLeaf<i32, [{
 616   return Imm >= 0 && Imm < 8;
 617 }]> {
 618   let ParserMatchClass = Imm0_7AsmOperand;
 619 }
 620
 621 /// imm8 predicate - Immediate is exactly 8.
 622 def Imm8AsmOperand: ImmAsmOperand { let Name = "Imm8"; }
 623 def imm8 : Operand<i32>, ImmLeaf<i32, [{ return Imm == 8; }]> {
 624   let ParserMatchClass = Imm8AsmOperand;
 625 }
 626
 627 /// imm16 predicate - Immediate is exactly 16.
 628 def Imm16AsmOperand: ImmAsmOperand { let Name = "Imm16"; }
 629 def imm16 : Operand<i32>, ImmLeaf<i32, [{ return Imm == 16; }]> {
 630   let ParserMatchClass = Imm16AsmOperand;
 631 }
 632
 633 /// imm32 predicate - Immediate is exactly 32.
 634 def Imm32AsmOperand: ImmAsmOperand { let Name = "Imm32"; }
 635 def imm32 : Operand<i32>, ImmLeaf<i32, [{ return Imm == 32; }]> {
 636   let ParserMatchClass = Imm32AsmOperand;
 637 }
 638
 639 def imm8_or_16 : ImmLeaf<i32, [{ return Imm == 8 || Imm == 16;}]>;
 640
 641 /// imm1_7 predicate - Immediate in the range [1,7].
 642 def Imm1_7AsmOperand: ImmAsmOperand { let Name = "Imm1_7"; }
 643 def imm1_7 : Operand<i32>, ImmLeaf<i32, [{ return Imm > 0 && Imm < 8; }]> {
 644   let ParserMatchClass = Imm1_7AsmOperand;
 645 }
 646
 647 /// imm1_15 predicate - Immediate in the range [1,15].
 648 def Imm1_15AsmOperand: ImmAsmOperand { let Name = "Imm1_15"; }
 649 def imm1_15 : Operand<i32>, ImmLeaf<i32, [{ return Imm > 0 && Imm < 16; }]> {
 650   let ParserMatchClass = Imm1_15AsmOperand;
 651 }
 652
 653 /// imm1_31 predicate - Immediate in the range [1,31].
 654 def Imm1_31AsmOperand: ImmAsmOperand { let Name = "Imm1_31"; }
 655 def imm1_31 : Operand<i32>, ImmLeaf<i32, [{ return Imm > 0 && Imm < 32; }]> {
 656   let ParserMatchClass = Imm1_31AsmOperand;
 657 }
 658
 659 /// imm0_15 predicate - Immediate in the range [0,15].
 660 def Imm0_15AsmOperand: ImmAsmOperand {
 661   let Name = "Imm0_15";
 662   let DiagnosticType = "ImmRange0_15";
 663 }
 664 def imm0_15 : Operand<i32>, ImmLeaf<i32, [{
 665   return Imm >= 0 && Imm < 16;
 666 }]> {
 667   let ParserMatchClass = Imm0_15AsmOperand;
 668 }
 669
 670 /// imm0_31 predicate - True if the 32-bit immediate is in the range [0,31].
 671 def Imm0_31AsmOperand: ImmAsmOperand { let Name = "Imm0_31"; }
 672 def imm0_31 : Operand<i32>, ImmLeaf<i32, [{
 673   return Imm >= 0 && Imm < 32;
 674 }]> {
 675   let ParserMatchClass = Imm0_31AsmOperand;
 676 }
 677
 678 /// imm0_32 predicate - True if the 32-bit immediate is in the range [0,32].
 679 def Imm0_32AsmOperand: ImmAsmOperand { let Name = "Imm0_32"; }
 680 def imm0_32 : Operand<i32>, ImmLeaf<i32, [{
 681   return Imm >= 0 && Imm < 32;
 682 }]> {
 683   let ParserMatchClass = Imm0_32AsmOperand;
 684 }
 685
 686 /// imm0_63 predicate - True if the 32-bit immediate is in the range [0,63].
 687 def Imm0_63AsmOperand: ImmAsmOperand { let Name = "Imm0_63"; }
 688 def imm0_63 : Operand<i32>, ImmLeaf<i32, [{
 689   return Imm >= 0 && Imm < 64;
 690 }]> {
 691   let ParserMatchClass = Imm0_63AsmOperand;
 692 }
 693
 694 /// imm0_239 predicate - Immediate in the range [0,239].
 695 def Imm0_239AsmOperand : ImmAsmOperand {
 696   let Name = "Imm0_239";
 697   let DiagnosticType = "ImmRange0_239";
 698 }
 699 def imm0_239 : Operand<i32>, ImmLeaf<i32, [{ return Imm >= 0 && Imm < 240; }]> {
 700   let ParserMatchClass = Imm0_239AsmOperand;
 701 }
 702
 703 /// imm0_255 predicate - Immediate in the range [0,255].
 704 def Imm0_255AsmOperand : ImmAsmOperand { let Name = "Imm0_255"; }
 705 def imm0_255 : Operand<i32>, ImmLeaf<i32, [{ return Imm >= 0 && Imm < 256; }]> {
 706   let ParserMatchClass = Imm0_255AsmOperand;
 707 }
 708
 709 /// imm0_65535 - An immediate is in the range [0.65535].
 710 def Imm0_65535AsmOperand: ImmAsmOperand { let Name = "Imm0_65535"; }
 711 def imm0_65535 : Operand<i32>, ImmLeaf<i32, [{
 712   return Imm >= 0 && Imm < 65536;
 713 }]> {
 714   let ParserMatchClass = Imm0_65535AsmOperand;
 715 }
 716
 717 // imm0_65535_neg - An immediate whose negative value is in the range [0.65535].
 718 def imm0_65535_neg : Operand<i32>, ImmLeaf<i32, [{
 719   return -Imm >= 0 && -Imm < 65536;
 720 }]>;
 721
 722 // imm0_65535_expr - For movt/movw - 16-bit immediate that can also reference
 723 // a relocatable expression.
 724 //
 725 // FIXME: This really needs a Thumb version separate from the ARM version.
 726 // While the range is the same, and can thus use the same match class,
 727 // the encoding is different so it should have a different encoder method.
 728 def Imm0_65535ExprAsmOperand: ImmAsmOperand { let Name = "Imm0_65535Expr"; }
 729 def imm0_65535_expr : Operand<i32> {
 730   let EncoderMethod = "getHiLo16ImmOpValue";
 731   let ParserMatchClass = Imm0_65535ExprAsmOperand;
 732 }
 733
 734 def Imm256_65535ExprAsmOperand: ImmAsmOperand { let Name = "Imm256_65535Expr"; }
 735 def imm256_65535_expr : Operand<i32> {
 736   let ParserMatchClass = Imm256_65535ExprAsmOperand;
 737 }
 738
 739 /// imm24b - True if the 32-bit immediate is encodable in 24 bits.
 740 def Imm24bitAsmOperand: ImmAsmOperand { let Name = "Imm24bit"; }
 741 def imm24b : Operand<i32>, ImmLeaf<i32, [{
 742   return Imm >= 0 && Imm <= 0xffffff;
 743 }]> {
 744   let ParserMatchClass = Imm24bitAsmOperand;
 745 }
 746
 747
 748 /// bf_inv_mask_imm predicate - An AND mask to clear an arbitrary width bitfield
 749 /// e.g., 0xf000ffff
 750 def BitfieldAsmOperand : AsmOperandClass {
 751   let Name = "Bitfield";
 752   let ParserMethod = "parseBitfield";
 753 }
 754
 755 def bf_inv_mask_imm : Operand<i32>,
 756                       PatLeaf<(imm), [{
 757   return ARM::isBitFieldInvertedMask(N->getZExtValue());
 758 }] > {
 759   let EncoderMethod = "getBitfieldInvertedMaskOpValue";
 760   let PrintMethod = "printBitfieldInvMaskImmOperand";
 761   let DecoderMethod = "DecodeBitfieldMaskOperand";
 762   let ParserMatchClass = BitfieldAsmOperand;
 763 }
 764
 765 def imm1_32_XFORM: SDNodeXForm<imm, [{
 766   return CurDAG->getTargetConstant((int)N->getZExtValue() - 1, MVT::i32);
 767 }]>;
 768 def Imm1_32AsmOperand: AsmOperandClass { let Name = "Imm1_32"; }
 769 def imm1_32 : Operand<i32>, PatLeaf<(imm), [{
 770    uint64_t Imm = N->getZExtValue();
 771    return Imm > 0 && Imm <= 32;
 772  }],
 773     imm1_32_XFORM> {
 774   let PrintMethod = "printImmPlusOneOperand";
 775   let ParserMatchClass = Imm1_32AsmOperand;
 776 }
 777
 778 def imm1_16_XFORM: SDNodeXForm<imm, [{
 779   return CurDAG->getTargetConstant((int)N->getZExtValue() - 1, MVT::i32);
 780 }]>;
 781 def Imm1_16AsmOperand: AsmOperandClass { let Name = "Imm1_16"; }
 782 def imm1_16 : Operand<i32>, PatLeaf<(imm), [{ return Imm > 0 && Imm <= 16; }],
 783     imm1_16_XFORM> {
 784   let PrintMethod = "printImmPlusOneOperand";
 785   let ParserMatchClass = Imm1_16AsmOperand;
 786 }
 787
 788 // Define ARM specific addressing modes.
 789 // addrmode_imm12 := reg +/- imm12
 790 //
 791 def MemImm12OffsetAsmOperand : AsmOperandClass { let Name = "MemImm12Offset"; }
 792 class AddrMode_Imm12 : Operand<i32>,
 793                      ComplexPattern<i32, 2, "SelectAddrModeImm12", []> {
 794   // 12-bit immediate operand. Note that instructions using this encode
 795   // #0 and #-0 differently. We flag #-0 as the magic value INT32_MIN. All other
 796   // immediate values are as normal.
 797
 798   let EncoderMethod = "getAddrModeImm12OpValue";
 799   let DecoderMethod = "DecodeAddrModeImm12Operand";
 800   let ParserMatchClass = MemImm12OffsetAsmOperand;
 801   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 802 }
 803
 804 def addrmode_imm12 : AddrMode_Imm12 {
 805   let PrintMethod = "printAddrModeImm12Operand<false>";
 806 }
 807
 808 def addrmode_imm12_pre : AddrMode_Imm12 {
 809   let PrintMethod = "printAddrModeImm12Operand<true>";
 810 }
 811
 812 // ldst_so_reg := reg +/- reg shop imm
 813 //
 814 def MemRegOffsetAsmOperand : AsmOperandClass { let Name = "MemRegOffset"; }
 815 def ldst_so_reg : Operand<i32>,
 816                   ComplexPattern<i32, 3, "SelectLdStSOReg", []> {
 817   let EncoderMethod = "getLdStSORegOpValue";
 818   // FIXME: Simplify the printer
 819   let PrintMethod = "printAddrMode2Operand";
 820   let DecoderMethod = "DecodeSORegMemOperand";
 821   let ParserMatchClass = MemRegOffsetAsmOperand;
 822   let MIOperandInfo = (ops GPR:$base, GPRnopc:$offsreg, i32imm:$shift);
 823 }
 824
 825 // postidx_imm8 := +/- [0,255]
 826 //
 827 // 9 bit value:
 828 //  {8}       1 is imm8 is non-negative. 0 otherwise.
 829 //  {7-0}     [0,255] imm8 value.
 830 def PostIdxImm8AsmOperand : AsmOperandClass { let Name = "PostIdxImm8"; }
 831 def postidx_imm8 : Operand<i32> {
 832   let PrintMethod = "printPostIdxImm8Operand";
 833   let ParserMatchClass = PostIdxImm8AsmOperand;
 834   let MIOperandInfo = (ops i32imm);
 835 }
 836
 837 // postidx_imm8s4 := +/- [0,1020]
 838 //
 839 // 9 bit value:
 840 //  {8}       1 is imm8 is non-negative. 0 otherwise.
 841 //  {7-0}     [0,255] imm8 value, scaled by 4.
 842 def PostIdxImm8s4AsmOperand : AsmOperandClass { let Name = "PostIdxImm8s4"; }
 843 def postidx_imm8s4 : Operand<i32> {
 844   let PrintMethod = "printPostIdxImm8s4Operand";
 845   let ParserMatchClass = PostIdxImm8s4AsmOperand;
 846   let MIOperandInfo = (ops i32imm);
 847 }
 848
 849
 850 // postidx_reg := +/- reg
 851 //
 852 def PostIdxRegAsmOperand : AsmOperandClass {
 853   let Name = "PostIdxReg";
 854   let ParserMethod = "parsePostIdxReg";
 855 }
 856 def postidx_reg : Operand<i32> {
 857   let EncoderMethod = "getPostIdxRegOpValue";
 858   let DecoderMethod = "DecodePostIdxReg";
 859   let PrintMethod = "printPostIdxRegOperand";
 860   let ParserMatchClass = PostIdxRegAsmOperand;
 861   let MIOperandInfo = (ops GPRnopc, i32imm);
 862 }
 863
 864
 865 // addrmode2 := reg +/- imm12
 866 //           := reg +/- reg shop imm
 867 //
 868 // FIXME: addrmode2 should be refactored the rest of the way to always
 869 // use explicit imm vs. reg versions above (addrmode_imm12 and ldst_so_reg).
 870 def AddrMode2AsmOperand : AsmOperandClass { let Name = "AddrMode2"; }
 871 def addrmode2 : Operand<i32>,
 872                 ComplexPattern<i32, 3, "SelectAddrMode2", []> {
 873   let EncoderMethod = "getAddrMode2OpValue";
 874   let PrintMethod = "printAddrMode2Operand";
 875   let ParserMatchClass = AddrMode2AsmOperand;
 876   let MIOperandInfo = (ops GPR:$base, GPR:$offsreg, i32imm:$offsimm);
 877 }
 878
 879 def PostIdxRegShiftedAsmOperand : AsmOperandClass {
 880   let Name = "PostIdxRegShifted";
 881   let ParserMethod = "parsePostIdxReg";
 882 }
 883 def am2offset_reg : Operand<i32>,
 884                 ComplexPattern<i32, 2, "SelectAddrMode2OffsetReg",
 885                 [], [SDNPWantRoot]> {
 886   let EncoderMethod = "getAddrMode2OffsetOpValue";
 887   let PrintMethod = "printAddrMode2OffsetOperand";
 888   // When using this for assembly, it's always as a post-index offset.
 889   let ParserMatchClass = PostIdxRegShiftedAsmOperand;
 890   let MIOperandInfo = (ops GPRnopc, i32imm);
 891 }
 892
 893 // FIXME: am2offset_imm should only need the immediate, not the GPR. Having
 894 // the GPR is purely vestigal at this point.
 895 def AM2OffsetImmAsmOperand : AsmOperandClass { let Name = "AM2OffsetImm"; }
 896 def am2offset_imm : Operand<i32>,
 897                 ComplexPattern<i32, 2, "SelectAddrMode2OffsetImm",
 898                 [], [SDNPWantRoot]> {
 899   let EncoderMethod = "getAddrMode2OffsetOpValue";
 900   let PrintMethod = "printAddrMode2OffsetOperand";
 901   let ParserMatchClass = AM2OffsetImmAsmOperand;
 902   let MIOperandInfo = (ops GPRnopc, i32imm);
 903 }
 904
 905
 906 // addrmode3 := reg +/- reg
 907 // addrmode3 := reg +/- imm8
 908 //
 909 // FIXME: split into imm vs. reg versions.
 910 def AddrMode3AsmOperand : AsmOperandClass { let Name = "AddrMode3"; }
 911 class AddrMode3 : Operand<i32>,
 912                   ComplexPattern<i32, 3, "SelectAddrMode3", []> {
 913   let EncoderMethod = "getAddrMode3OpValue";
 914   let ParserMatchClass = AddrMode3AsmOperand;
 915   let MIOperandInfo = (ops GPR:$base, GPR:$offsreg, i32imm:$offsimm);
 916 }
 917
 918 def addrmode3 : AddrMode3
 919 {
 920   let PrintMethod = "printAddrMode3Operand<false>";
 921 }
 922
 923 def addrmode3_pre : AddrMode3
 924 {
 925   let PrintMethod = "printAddrMode3Operand<true>";
 926 }
 927
 928 // FIXME: split into imm vs. reg versions.
 929 // FIXME: parser method to handle +/- register.
 930 def AM3OffsetAsmOperand : AsmOperandClass {
 931   let Name = "AM3Offset";
 932   let ParserMethod = "parseAM3Offset";
 933 }
 934 def am3offset : Operand<i32>,
 935                 ComplexPattern<i32, 2, "SelectAddrMode3Offset",
 936                                [], [SDNPWantRoot]> {
 937   let EncoderMethod = "getAddrMode3OffsetOpValue";
 938   let PrintMethod = "printAddrMode3OffsetOperand";
 939   let ParserMatchClass = AM3OffsetAsmOperand;
 940   let MIOperandInfo = (ops GPR, i32imm);
 941 }
 942
 943 // ldstm_mode := {ia, ib, da, db}
 944 //
 945 def ldstm_mode : OptionalDefOperand<OtherVT, (ops i32), (ops (i32 1))> {
 946   let EncoderMethod = "getLdStmModeOpValue";
 947   let PrintMethod = "printLdStmModeOperand";
 948 }
 949
 950 // addrmode5 := reg +/- imm8*4
 951 //
 952 def AddrMode5AsmOperand : AsmOperandClass { let Name = "AddrMode5"; }
 953 class AddrMode5 : Operand<i32>,
 954                   ComplexPattern<i32, 2, "SelectAddrMode5", []> {
 955   let EncoderMethod = "getAddrMode5OpValue";
 956   let DecoderMethod = "DecodeAddrMode5Operand";
 957   let ParserMatchClass = AddrMode5AsmOperand;
 958   let MIOperandInfo = (ops GPR:$base, i32imm);
 959 }
 960
 961 def addrmode5 : AddrMode5 {
 962    let PrintMethod = "printAddrMode5Operand<false>";
 963 }
 964
 965 def addrmode5_pre : AddrMode5 {
 966    let PrintMethod = "printAddrMode5Operand<true>";
 967 }
 968
 969 // addrmode6 := reg with optional alignment
 970 //
 971 def AddrMode6AsmOperand : AsmOperandClass { let Name = "AlignedMemory"; }
 972 def addrmode6 : Operand<i32>,
 973                 ComplexPattern<i32, 2, "SelectAddrMode6", [], [SDNPWantParent]>{
 974   let PrintMethod = "printAddrMode6Operand";
 975   let MIOperandInfo = (ops GPR:$addr, i32imm:$align);
 976   let EncoderMethod = "getAddrMode6AddressOpValue";
 977   let DecoderMethod = "DecodeAddrMode6Operand";
 978   let ParserMatchClass = AddrMode6AsmOperand;
 979 }
 980
 981 def am6offset : Operand<i32>,
 982                 ComplexPattern<i32, 1, "SelectAddrMode6Offset",
 983                                [], [SDNPWantRoot]> {
 984   let PrintMethod = "printAddrMode6OffsetOperand";
 985   let MIOperandInfo = (ops GPR);
 986   let EncoderMethod = "getAddrMode6OffsetOpValue";
 987   let DecoderMethod = "DecodeGPRRegisterClass";
 988 }
 989
 990 // Special version of addrmode6 to handle alignment encoding for VST1/VLD1
 991 // (single element from one lane) for size 32.
 992 def addrmode6oneL32 : Operand<i32>,
 993                 ComplexPattern<i32, 2, "SelectAddrMode6", [], [SDNPWantParent]>{
 994   let PrintMethod = "printAddrMode6Operand";
 995   let MIOperandInfo = (ops GPR:$addr, i32imm);
 996   let EncoderMethod = "getAddrMode6OneLane32AddressOpValue";
 997 }
 998
 999 // Base class for addrmode6 with specific alignment restrictions.
1000 class AddrMode6Align : Operand<i32>,
1001                 ComplexPattern<i32, 2, "SelectAddrMode6", [], [SDNPWantParent]>{
1002   let PrintMethod = "printAddrMode6Operand";
1003   let MIOperandInfo = (ops GPR:$addr, i32imm:$align);
1004   let EncoderMethod = "getAddrMode6AddressOpValue";
1005   let DecoderMethod = "DecodeAddrMode6Operand";
1006 }
1007
1008 // Special version of addrmode6 to handle no allowed alignment encoding for
1009 // VLD/VST instructions and checking the alignment is not specified.
1010 def AddrMode6AlignNoneAsmOperand : AsmOperandClass {
1011   let Name = "AlignedMemoryNone";
1012   let DiagnosticType = "AlignedMemoryRequiresNone";
1013 }
1014 def addrmode6alignNone : AddrMode6Align {
1015   // The alignment specifier can only be omitted.
1016   let ParserMatchClass = AddrMode6AlignNoneAsmOperand;
1017 }
1018
1019 // Special version of addrmode6 to handle 16-bit alignment encoding for
1020 // VLD/VST instructions and checking the alignment value.
1021 def AddrMode6Align16AsmOperand : AsmOperandClass {
1022   let Name = "AlignedMemory16";
1023   let DiagnosticType = "AlignedMemoryRequires16";
1024 }
1025 def addrmode6align16 : AddrMode6Align {
1026   // The alignment specifier can only be 16 or omitted.
1027   let ParserMatchClass = AddrMode6Align16AsmOperand;
1028 }
1029
1030 // Special version of addrmode6 to handle 32-bit alignment encoding for
1031 // VLD/VST instructions and checking the alignment value.
1032 def AddrMode6Align32AsmOperand : AsmOperandClass {
1033   let Name = "AlignedMemory32";
1034   let DiagnosticType = "AlignedMemoryRequires32";
1035 }
1036 def addrmode6align32 : AddrMode6Align {
1037   // The alignment specifier can only be 32 or omitted.
1038   let ParserMatchClass = AddrMode6Align32AsmOperand;
1039 }
1040
1041 // Special version of addrmode6 to handle 64-bit alignment encoding for
1042 // VLD/VST instructions and checking the alignment value.
1043 def AddrMode6Align64AsmOperand : AsmOperandClass {
1044   let Name = "AlignedMemory64";
1045   let DiagnosticType = "AlignedMemoryRequires64";
1046 }
1047 def addrmode6align64 : AddrMode6Align {
1048   // The alignment specifier can only be 64 or omitted.
1049   let ParserMatchClass = AddrMode6Align64AsmOperand;
1050 }
1051
1052 // Special version of addrmode6 to handle 64-bit or 128-bit alignment encoding
1053 // for VLD/VST instructions and checking the alignment value.
1054 def AddrMode6Align64or128AsmOperand : AsmOperandClass {
1055   let Name = "AlignedMemory64or128";
1056   let DiagnosticType = "AlignedMemoryRequires64or128";
1057 }
1058 def addrmode6align64or128 : AddrMode6Align {
1059   // The alignment specifier can only be 64, 128 or omitted.
1060   let ParserMatchClass = AddrMode6Align64or128AsmOperand;
1061 }
1062
1063 // Special version of addrmode6 to handle 64-bit, 128-bit or 256-bit alignment
1064 // encoding for VLD/VST instructions and checking the alignment value.
1065 def AddrMode6Align64or128or256AsmOperand : AsmOperandClass {
1066   let Name = "AlignedMemory64or128or256";
1067   let DiagnosticType = "AlignedMemoryRequires64or128or256";
1068 }
1069 def addrmode6align64or128or256 : AddrMode6Align {
1070   // The alignment specifier can only be 64, 128, 256 or omitted.
1071   let ParserMatchClass = AddrMode6Align64or128or256AsmOperand;
1072 }
1073
1074 // Special version of addrmode6 to handle alignment encoding for VLD-dup
1075 // instructions, specifically VLD4-dup.
1076 def addrmode6dup : Operand<i32>,
1077                 ComplexPattern<i32, 2, "SelectAddrMode6", [], [SDNPWantParent]>{
1078   let PrintMethod = "printAddrMode6Operand";
1079   let MIOperandInfo = (ops GPR:$addr, i32imm);
1080   let EncoderMethod = "getAddrMode6DupAddressOpValue";
1081   // FIXME: This is close, but not quite right. The alignment specifier is
1082   // different.
1083   let ParserMatchClass = AddrMode6AsmOperand;
1084 }
1085
1086 // Base class for addrmode6dup with specific alignment restrictions.
1087 class AddrMode6DupAlign : Operand<i32>,
1088                 ComplexPattern<i32, 2, "SelectAddrMode6", [], [SDNPWantParent]>{
1089   let PrintMethod = "printAddrMode6Operand";
1090   let MIOperandInfo = (ops GPR:$addr, i32imm);
1091   let EncoderMethod = "getAddrMode6DupAddressOpValue";
1092 }
1093
1094 // Special version of addrmode6 to handle no allowed alignment encoding for
1095 // VLD-dup instruction and checking the alignment is not specified.
1096 def AddrMode6dupAlignNoneAsmOperand : AsmOperandClass {
1097   let Name = "DupAlignedMemoryNone";
1098   let DiagnosticType = "DupAlignedMemoryRequiresNone";
1099 }
1100 def addrmode6dupalignNone : AddrMode6DupAlign {
1101   // The alignment specifier can only be omitted.
1102   let ParserMatchClass = AddrMode6dupAlignNoneAsmOperand;
1103 }
1104
1105 // Special version of addrmode6 to handle 16-bit alignment encoding for VLD-dup
1106 // instruction and checking the alignment value.
1107 def AddrMode6dupAlign16AsmOperand : AsmOperandClass {
1108   let Name = "DupAlignedMemory16";
1109   let DiagnosticType = "DupAlignedMemoryRequires16";
1110 }
1111 def addrmode6dupalign16 : AddrMode6DupAlign {
1112   // The alignment specifier can only be 16 or omitted.
1113   let ParserMatchClass = AddrMode6dupAlign16AsmOperand;
1114 }
1115
1116 // Special version of addrmode6 to handle 32-bit alignment encoding for VLD-dup
1117 // instruction and checking the alignment value.
1118 def AddrMode6dupAlign32AsmOperand : AsmOperandClass {
1119   let Name = "DupAlignedMemory32";
1120   let DiagnosticType = "DupAlignedMemoryRequires32";
1121 }
1122 def addrmode6dupalign32 : AddrMode6DupAlign {
1123   // The alignment specifier can only be 32 or omitted.
1124   let ParserMatchClass = AddrMode6dupAlign32AsmOperand;
1125 }
1126
1127 // Special version of addrmode6 to handle 64-bit alignment encoding for VLD
1128 // instructions and checking the alignment value.
1129 def AddrMode6dupAlign64AsmOperand : AsmOperandClass {
1130   let Name = "DupAlignedMemory64";
1131   let DiagnosticType = "DupAlignedMemoryRequires64";
1132 }
1133 def addrmode6dupalign64 : AddrMode6DupAlign {
1134   // The alignment specifier can only be 64 or omitted.
1135   let ParserMatchClass = AddrMode6dupAlign64AsmOperand;
1136 }
1137
1138 // Special version of addrmode6 to handle 64-bit or 128-bit alignment encoding
1139 // for VLD instructions and checking the alignment value.
1140 def AddrMode6dupAlign64or128AsmOperand : AsmOperandClass {
1141   let Name = "DupAlignedMemory64or128";
1142   let DiagnosticType = "DupAlignedMemoryRequires64or128";
1143 }
1144 def addrmode6dupalign64or128 : AddrMode6DupAlign {
1145   // The alignment specifier can only be 64, 128 or omitted.
1146   let ParserMatchClass = AddrMode6dupAlign64or128AsmOperand;
1147 }
1148
1149 // addrmodepc := pc + reg
1150 //
1151 def addrmodepc : Operand<i32>,
1152                  ComplexPattern<i32, 2, "SelectAddrModePC", []> {
1153   let PrintMethod = "printAddrModePCOperand";
1154   let MIOperandInfo = (ops GPR, i32imm);
1155 }
1156
1157 // addr_offset_none := reg
1158 //
1159 def MemNoOffsetAsmOperand : AsmOperandClass { let Name = "MemNoOffset"; }
1160 def addr_offset_none : Operand<i32>,
1161                        ComplexPattern<i32, 1, "SelectAddrOffsetNone", []> {
1162   let PrintMethod = "printAddrMode7Operand";
1163   let DecoderMethod = "DecodeAddrMode7Operand";
1164   let ParserMatchClass = MemNoOffsetAsmOperand;
1165   let MIOperandInfo = (ops GPR:$base);
1166 }
1167
1168 def nohash_imm : Operand<i32> {
1169   let PrintMethod = "printNoHashImmediate";
1170 }
1171
1172 def CoprocNumAsmOperand : AsmOperandClass {
1173   let Name = "CoprocNum";
1174   let ParserMethod = "parseCoprocNumOperand";
1175 }
1176 def p_imm : Operand<i32> {
1177   let PrintMethod = "printPImmediate";
1178   let ParserMatchClass = CoprocNumAsmOperand;
1179   let DecoderMethod = "DecodeCoprocessor";
1180 }
1181
1182 def CoprocRegAsmOperand : AsmOperandClass {
1183   let Name = "CoprocReg";
1184   let ParserMethod = "parseCoprocRegOperand";
1185 }
1186 def c_imm : Operand<i32> {
1187   let PrintMethod = "printCImmediate";
1188   let ParserMatchClass = CoprocRegAsmOperand;
1189 }
1190 def CoprocOptionAsmOperand : AsmOperandClass {
1191   let Name = "CoprocOption";
1192   let ParserMethod = "parseCoprocOptionOperand";
1193 }
1194 def coproc_option_imm : Operand<i32> {
1195   let PrintMethod = "printCoprocOptionImm";
1196   let ParserMatchClass = CoprocOptionAsmOperand;
1197 }
1198
1199 //===----------------------------------------------------------------------===//
1200
1201 include "ARMInstrFormats.td"
1202
1203 //===----------------------------------------------------------------------===//
1204 // Multiclass helpers...
1205 //
1206
1207 /// AsI1_bin_irs - Defines a set of (op r, {so_imm|r|so_reg}) patterns for a
1208 /// binop that produces a value.
1209 let TwoOperandAliasConstraint = "$Rn = $Rd" in
1210 multiclass AsI1_bin_irs<bits<4> opcod, string opc,
1211                      InstrItinClass iii, InstrItinClass iir, InstrItinClass iis,
1212                         PatFrag opnode, bit Commutable = 0> {
1213   // The register-immediate version is re-materializable. This is useful
1214   // in particular for taking the address of a local.
1215   let isReMaterializable = 1 in {
1216   def ri : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, so_imm:$imm), DPFrm,
1217                iii, opc, "\t$Rd, $Rn, $imm",
1218                [(set GPR:$Rd, (opnode GPR:$Rn, so_imm:$imm))]>,
1219            Sched<[WriteALU, ReadALU]> {
1220     bits<4> Rd;
1221     bits<4> Rn;
1222     bits<12> imm;
1223     let Inst{25} = 1;
1224     let Inst{19-16} = Rn;
1225     let Inst{15-12} = Rd;
1226     let Inst{11-0} = imm;
1227   }
1228   }
1229   def rr : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm), DPFrm,
1230                iir, opc, "\t$Rd, $Rn, $Rm",
1231                [(set GPR:$Rd, (opnode GPR:$Rn, GPR:$Rm))]>,
1232            Sched<[WriteALU, ReadALU, ReadALU]> {
1233     bits<4> Rd;
1234     bits<4> Rn;
1235     bits<4> Rm;
1236     let Inst{25} = 0;
1237     let isCommutable = Commutable;
1238     let Inst{19-16} = Rn;
1239     let Inst{15-12} = Rd;
1240     let Inst{11-4} = 0b00000000;
1241     let Inst{3-0} = Rm;
1242   }
1243
1244   def rsi : AsI1<opcod, (outs GPR:$Rd),
1245                (ins GPR:$Rn, so_reg_imm:$shift), DPSoRegImmFrm,
1246                iis, opc, "\t$Rd, $Rn, $shift",
1247                [(set GPR:$Rd, (opnode GPR:$Rn, so_reg_imm:$shift))]>,
1248             Sched<[WriteALUsi, ReadALU]> {
1249     bits<4> Rd;
1250     bits<4> Rn;
1251     bits<12> shift;
1252     let Inst{25} = 0;
1253     let Inst{19-16} = Rn;
1254     let Inst{15-12} = Rd;
1255     let Inst{11-5} = shift{11-5};
1256     let Inst{4} = 0;
1257     let Inst{3-0} = shift{3-0};
1258   }
1259
1260   def rsr : AsI1<opcod, (outs GPR:$Rd),
1261                (ins GPR:$Rn, so_reg_reg:$shift), DPSoRegRegFrm,
1262                iis, opc, "\t$Rd, $Rn, $shift",
1263                [(set GPR:$Rd, (opnode GPR:$Rn, so_reg_reg:$shift))]>,
1264             Sched<[WriteALUsr, ReadALUsr]> {
1265     bits<4> Rd;
1266     bits<4> Rn;
1267     bits<12> shift;
1268     let Inst{25} = 0;
1269     let Inst{19-16} = Rn;
1270     let Inst{15-12} = Rd;
1271     let Inst{11-8} = shift{11-8};
1272     let Inst{7} = 0;
1273     let Inst{6-5} = shift{6-5};
1274     let Inst{4} = 1;
1275     let Inst{3-0} = shift{3-0};
1276   }
1277 }
1278
1279 /// AsI1_rbin_irs - Same as AsI1_bin_irs except the order of operands are
1280 /// reversed.  The 'rr' form is only defined for the disassembler; for codegen
1281 /// it is equivalent to the AsI1_bin_irs counterpart.
1282 let TwoOperandAliasConstraint = "$Rn = $Rd" in
1283 multiclass AsI1_rbin_irs<bits<4> opcod, string opc,
1284                      InstrItinClass iii, InstrItinClass iir, InstrItinClass iis,
1285                         PatFrag opnode, bit Commutable = 0> {
1286   // The register-immediate version is re-materializable. This is useful
1287   // in particular for taking the address of a local.
1288   let isReMaterializable = 1 in {
1289   def ri : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, so_imm:$imm), DPFrm,
1290                iii, opc, "\t$Rd, $Rn, $imm",
1291                [(set GPR:$Rd, (opnode so_imm:$imm, GPR:$Rn))]>,
1292            Sched<[WriteALU, ReadALU]> {
1293     bits<4> Rd;
1294     bits<4> Rn;
1295     bits<12> imm;
1296     let Inst{25} = 1;
1297     let Inst{19-16} = Rn;
1298     let Inst{15-12} = Rd;
1299     let Inst{11-0} = imm;
1300   }
1301   }
1302   def rr : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm), DPFrm,
1303                iir, opc, "\t$Rd, $Rn, $Rm",
1304                [/* pattern left blank */]>,
1305            Sched<[WriteALU, ReadALU, ReadALU]> {
1306     bits<4> Rd;
1307     bits<4> Rn;
1308     bits<4> Rm;
1309     let Inst{11-4} = 0b00000000;
1310     let Inst{25} = 0;
1311     let Inst{3-0} = Rm;
1312     let Inst{15-12} = Rd;
1313     let Inst{19-16} = Rn;
1314   }
1315
1316   def rsi : AsI1<opcod, (outs GPR:$Rd),
1317                (ins GPR:$Rn, so_reg_imm:$shift), DPSoRegImmFrm,
1318                iis, opc, "\t$Rd, $Rn, $shift",
1319                [(set GPR:$Rd, (opnode so_reg_imm:$shift, GPR:$Rn))]>,
1320             Sched<[WriteALUsi, ReadALU]> {
1321     bits<4> Rd;
1322     bits<4> Rn;
1323     bits<12> shift;
1324     let Inst{25} = 0;
1325     let Inst{19-16} = Rn;
1326     let Inst{15-12} = Rd;
1327     let Inst{11-5} = shift{11-5};
1328     let Inst{4} = 0;
1329     let Inst{3-0} = shift{3-0};
1330   }
1331
1332   def rsr : AsI1<opcod, (outs GPR:$Rd),
1333                (ins GPR:$Rn, so_reg_reg:$shift), DPSoRegRegFrm,
1334                iis, opc, "\t$Rd, $Rn, $shift",
1335                [(set GPR:$Rd, (opnode so_reg_reg:$shift, GPR:$Rn))]>,
1336             Sched<[WriteALUsr, ReadALUsr]> {
1337     bits<4> Rd;
1338     bits<4> Rn;
1339     bits<12> shift;
1340     let Inst{25} = 0;
1341     let Inst{19-16} = Rn;
1342     let Inst{15-12} = Rd;
1343     let Inst{11-8} = shift{11-8};
1344     let Inst{7} = 0;
1345     let Inst{6-5} = shift{6-5};
1346     let Inst{4} = 1;
1347     let Inst{3-0} = shift{3-0};
1348   }
1349 }
1350
1351 /// AsI1_bin_s_irs - Same as AsI1_bin_irs except it sets the 's' bit by default.
1352 ///
1353 /// These opcodes will be converted to the real non-S opcodes by
1354 /// AdjustInstrPostInstrSelection after giving them an optional CPSR operand.
1355 let hasPostISelHook = 1, Defs = [CPSR] in {
1356 multiclass AsI1_bin_s_irs<InstrItinClass iii, InstrItinClass iir,
1357                           InstrItinClass iis, PatFrag opnode,
1358                           bit Commutable = 0> {
1359   def ri : ARMPseudoInst<(outs GPR:$Rd), (ins GPR:$Rn, so_imm:$imm, pred:$p),
1360                          4, iii,
1361                          [(set GPR:$Rd, CPSR, (opnode GPR:$Rn, so_imm:$imm))]>,
1362                          Sched<[WriteALU, ReadALU]>;
1363
1364   def rr : ARMPseudoInst<(outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm, pred:$p),
1365                          4, iir,
1366                          [(set GPR:$Rd, CPSR, (opnode GPR:$Rn, GPR:$Rm))]>,
1367                          Sched<[WriteALU, ReadALU, ReadALU]> {
1368     let isCommutable = Commutable;
1369   }
1370   def rsi : ARMPseudoInst<(outs GPR:$Rd),
1371                           (ins GPR:$Rn, so_reg_imm:$shift, pred:$p),
1372                           4, iis,
1373                           [(set GPR:$Rd, CPSR, (opnode GPR:$Rn,
1374                                                 so_reg_imm:$shift))]>,
1375                           Sched<[WriteALUsi, ReadALU]>;
1376
1377   def rsr : ARMPseudoInst<(outs GPR:$Rd),
1378                           (ins GPR:$Rn, so_reg_reg:$shift, pred:$p),
1379                           4, iis,
1380                           [(set GPR:$Rd, CPSR, (opnode GPR:$Rn,
1381                                                 so_reg_reg:$shift))]>,
1382                           Sched<[WriteALUSsr, ReadALUsr]>;
1383 }
1384 }
1385
1386 /// AsI1_rbin_s_is - Same as AsI1_bin_s_irs, except selection DAG
1387 /// operands are reversed.
1388 let hasPostISelHook = 1, Defs = [CPSR] in {
1389 multiclass AsI1_rbin_s_is<InstrItinClass iii, InstrItinClass iir,
1390                           InstrItinClass iis, PatFrag opnode,
1391                           bit Commutable = 0> {
1392   def ri : ARMPseudoInst<(outs GPR:$Rd), (ins GPR:$Rn, so_imm:$imm, pred:$p),
1393                          4, iii,
1394                          [(set GPR:$Rd, CPSR, (opnode so_imm:$imm, GPR:$Rn))]>,
1395            Sched<[WriteALU, ReadALU]>;
1396
1397   def rsi : ARMPseudoInst<(outs GPR:$Rd),
1398                           (ins GPR:$Rn, so_reg_imm:$shift, pred:$p),
1399                           4, iis,
1400                           [(set GPR:$Rd, CPSR, (opnode so_reg_imm:$shift,
1401                                              GPR:$Rn))]>,
1402             Sched<[WriteALUsi, ReadALU]>;
1403
1404   def rsr : ARMPseudoInst<(outs GPR:$Rd),
1405                           (ins GPR:$Rn, so_reg_reg:$shift, pred:$p),
1406                           4, iis,
1407                           [(set GPR:$Rd, CPSR, (opnode so_reg_reg:$shift,
1408                                              GPR:$Rn))]>,
1409             Sched<[WriteALUSsr, ReadALUsr]>;
1410 }
1411 }
1412
1413 /// AI1_cmp_irs - Defines a set of (op r, {so_imm|r|so_reg}) cmp / test
1414 /// patterns. Similar to AsI1_bin_irs except the instruction does not produce
1415 /// a explicit result, only implicitly set CPSR.
1416 let isCompare = 1, Defs = [CPSR] in {
1417 multiclass AI1_cmp_irs<bits<4> opcod, string opc,
1418                      InstrItinClass iii, InstrItinClass iir, InstrItinClass iis,
1419                        PatFrag opnode, bit Commutable = 0> {
1420   def ri : AI1<opcod, (outs), (ins GPR:$Rn, so_imm:$imm), DPFrm, iii,
1421                opc, "\t$Rn, $imm",
1422                [(opnode GPR:$Rn, so_imm:$imm)]>,
1423            Sched<[WriteCMP, ReadALU]> {
1424     bits<4> Rn;
1425     bits<12> imm;
1426     let Inst{25} = 1;
1427     let Inst{20} = 1;
1428     let Inst{19-16} = Rn;
1429     let Inst{15-12} = 0b0000;
1430     let Inst{11-0} = imm;
1431
1432     let Unpredictable{15-12} = 0b1111;
1433   }
1434   def rr : AI1<opcod, (outs), (ins GPR:$Rn, GPR:$Rm), DPFrm, iir,
1435                opc, "\t$Rn, $Rm",
1436                [(opnode GPR:$Rn, GPR:$Rm)]>,
1437            Sched<[WriteCMP, ReadALU, ReadALU]> {
1438     bits<4> Rn;
1439     bits<4> Rm;
1440     let isCommutable = Commutable;
1441     let Inst{25} = 0;
1442     let Inst{20} = 1;
1443     let Inst{19-16} = Rn;
1444     let Inst{15-12} = 0b0000;
1445     let Inst{11-4} = 0b00000000;
1446     let Inst{3-0} = Rm;
1447
1448     let Unpredictable{15-12} = 0b1111;
1449   }
1450   def rsi : AI1<opcod, (outs),
1451                (ins GPR:$Rn, so_reg_imm:$shift), DPSoRegImmFrm, iis,
1452                opc, "\t$Rn, $shift",
1453                [(opnode GPR:$Rn, so_reg_imm:$shift)]>,
1454             Sched<[WriteCMPsi, ReadALU]> {
1455     bits<4> Rn;
1456     bits<12> shift;
1457     let Inst{25} = 0;
1458     let Inst{20} = 1;
1459     let Inst{19-16} = Rn;
1460     let Inst{15-12} = 0b0000;
1461     let Inst{11-5} = shift{11-5};
1462     let Inst{4} = 0;
1463     let Inst{3-0} = shift{3-0};
1464
1465     let Unpredictable{15-12} = 0b1111;
1466   }
1467   def rsr : AI1<opcod, (outs),
1468                (ins GPRnopc:$Rn, so_reg_reg:$shift), DPSoRegRegFrm, iis,
1469                opc, "\t$Rn, $shift",
1470                [(opnode GPRnopc:$Rn, so_reg_reg:$shift)]>,
1471             Sched<[WriteCMPsr, ReadALU]> {
1472     bits<4> Rn;
1473     bits<12> shift;
1474     let Inst{25} = 0;
1475     let Inst{20} = 1;
1476     let Inst{19-16} = Rn;
1477     let Inst{15-12} = 0b0000;
1478     let Inst{11-8} = shift{11-8};
1479     let Inst{7} = 0;
1480     let Inst{6-5} = shift{6-5};
1481     let Inst{4} = 1;
1482     let Inst{3-0} = shift{3-0};
1483
1484     let Unpredictable{15-12} = 0b1111;
1485   }
1486
1487 }
1488 }
1489
1490 /// AI_ext_rrot - A unary operation with two forms: one whose operand is a
1491 /// register and one whose operand is a register rotated by 8/16/24.
1492 /// FIXME: Remove the 'r' variant. Its rot_imm is zero.
1493 class AI_ext_rrot<bits<8> opcod, string opc, PatFrag opnode>
1494   : AExtI<opcod, (outs GPRnopc:$Rd), (ins GPRnopc:$Rm, rot_imm:$rot),
1495           IIC_iEXTr, opc, "\t$Rd, $Rm$rot",
1496           [(set GPRnopc:$Rd, (opnode (rotr GPRnopc:$Rm, rot_imm:$rot)))]>,
1497        Requires<[IsARM, HasV6]>, Sched<[WriteALUsi]> {
1498   bits<4> Rd;
1499   bits<4> Rm;
1500   bits<2> rot;
1501   let Inst{19-16} = 0b1111;
1502   let Inst{15-12} = Rd;
1503   let Inst{11-10} = rot;
1504   let Inst{3-0}   = Rm;
1505 }
1506
1507 class AI_ext_rrot_np<bits<8> opcod, string opc>
1508   : AExtI<opcod, (outs GPRnopc:$Rd), (ins GPRnopc:$Rm, rot_imm:$rot),
1509           IIC_iEXTr, opc, "\t$Rd, $Rm$rot", []>,
1510        Requires<[IsARM, HasV6]>, Sched<[WriteALUsi]> {
1511   bits<2> rot;
1512   let Inst{19-16} = 0b1111;
1513   let Inst{11-10} = rot;
1514  }
1515
1516 /// AI_exta_rrot - A binary operation with two forms: one whose operand is a
1517 /// register and one whose operand is a register rotated by 8/16/24.
1518 class AI_exta_rrot<bits<8> opcod, string opc, PatFrag opnode>
1519   : AExtI<opcod, (outs GPRnopc:$Rd), (ins GPR:$Rn, GPRnopc:$Rm, rot_imm:$rot),
1520           IIC_iEXTAr, opc, "\t$Rd, $Rn, $Rm$rot",
1521           [(set GPRnopc:$Rd, (opnode GPR:$Rn,
1522                                      (rotr GPRnopc:$Rm, rot_imm:$rot)))]>,
1523         Requires<[IsARM, HasV6]>, Sched<[WriteALUsr]> {
1524   bits<4> Rd;
1525   bits<4> Rm;
1526   bits<4> Rn;
1527   bits<2> rot;
1528   let Inst{19-16} = Rn;
1529   let Inst{15-12} = Rd;
1530   let Inst{11-10} = rot;
1531   let Inst{9-4}   = 0b000111;
1532   let Inst{3-0}   = Rm;
1533 }
1534
1535 class AI_exta_rrot_np<bits<8> opcod, string opc>
1536   : AExtI<opcod, (outs GPRnopc:$Rd), (ins GPR:$Rn, GPRnopc:$Rm, rot_imm:$rot),
1537           IIC_iEXTAr, opc, "\t$Rd, $Rn, $Rm$rot", []>,
1538        Requires<[IsARM, HasV6]>, Sched<[WriteALUsr]> {
1539   bits<4> Rn;
1540   bits<2> rot;
1541   let Inst{19-16} = Rn;
1542   let Inst{11-10} = rot;
1543 }
1544
1545 /// AI1_adde_sube_irs - Define instructions and patterns for adde and sube.
1546 let TwoOperandAliasConstraint = "$Rn = $Rd" in
1547 multiclass AI1_adde_sube_irs<bits<4> opcod, string opc, PatFrag opnode,
1548                              bit Commutable = 0> {
1549   let hasPostISelHook = 1, Defs = [CPSR], Uses = [CPSR] in {
1550   def ri : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, so_imm:$imm),
1551                 DPFrm, IIC_iALUi, opc, "\t$Rd, $Rn, $imm",
1552                [(set GPR:$Rd, CPSR, (opnode GPR:$Rn, so_imm:$imm, CPSR))]>,
1553                Requires<[IsARM]>,
1554            Sched<[WriteALU, ReadALU]> {
1555     bits<4> Rd;
1556     bits<4> Rn;
1557     bits<12> imm;
1558     let Inst{25} = 1;
1559     let Inst{15-12} = Rd;
1560     let Inst{19-16} = Rn;
1561     let Inst{11-0} = imm;
1562   }
1563   def rr : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
1564                 DPFrm, IIC_iALUr, opc, "\t$Rd, $Rn, $Rm",
1565                [(set GPR:$Rd, CPSR, (opnode GPR:$Rn, GPR:$Rm, CPSR))]>,
1566                Requires<[IsARM]>,
1567            Sched<[WriteALU, ReadALU, ReadALU]> {
1568     bits<4> Rd;
1569     bits<4> Rn;
1570     bits<4> Rm;
1571     let Inst{11-4} = 0b00000000;
1572     let Inst{25} = 0;
1573     let isCommutable = Commutable;
1574     let Inst{3-0} = Rm;
1575     let Inst{15-12} = Rd;
1576     let Inst{19-16} = Rn;
1577   }
1578   def rsi : AsI1<opcod, (outs GPR:$Rd),
1579                 (ins GPR:$Rn, so_reg_imm:$shift),
1580                 DPSoRegImmFrm, IIC_iALUsr, opc, "\t$Rd, $Rn, $shift",
1581               [(set GPR:$Rd, CPSR, (opnode GPR:$Rn, so_reg_imm:$shift, CPSR))]>,
1582                Requires<[IsARM]>,
1583             Sched<[WriteALUsi, ReadALU]> {
1584     bits<4> Rd;
1585     bits<4> Rn;
1586     bits<12> shift;
1587     let Inst{25} = 0;
1588     let Inst{19-16} = Rn;
1589     let Inst{15-12} = Rd;
1590     let Inst{11-5} = shift{11-5};
1591     let Inst{4} = 0;
1592     let Inst{3-0} = shift{3-0};
1593   }
1594   def rsr : AsI1<opcod, (outs GPRnopc:$Rd),
1595                 (ins GPRnopc:$Rn, so_reg_reg:$shift),
1596                 DPSoRegRegFrm, IIC_iALUsr, opc, "\t$Rd, $Rn, $shift",
1597               [(set GPRnopc:$Rd, CPSR,
1598                     (opnode GPRnopc:$Rn, so_reg_reg:$shift, CPSR))]>,
1599                Requires<[IsARM]>,
1600             Sched<[WriteALUsr, ReadALUsr]> {
1601     bits<4> Rd;
1602     bits<4> Rn;
1603     bits<12> shift;
1604     let Inst{25} = 0;
1605     let Inst{19-16} = Rn;
1606     let Inst{15-12} = Rd;
1607     let Inst{11-8} = shift{11-8};
1608     let Inst{7} = 0;
1609     let Inst{6-5} = shift{6-5};
1610     let Inst{4} = 1;
1611     let Inst{3-0} = shift{3-0};
1612   }
1613   }
1614 }
1615
1616 /// AI1_rsc_irs - Define instructions and patterns for rsc
1617 let TwoOperandAliasConstraint = "$Rn = $Rd" in
1618 multiclass AI1_rsc_irs<bits<4> opcod, string opc, PatFrag opnode> {
1619   let hasPostISelHook = 1, Defs = [CPSR], Uses = [CPSR] in {
1620   def ri : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, so_imm:$imm),
1621                 DPFrm, IIC_iALUi, opc, "\t$Rd, $Rn, $imm",
1622                [(set GPR:$Rd, CPSR, (opnode so_imm:$imm, GPR:$Rn, CPSR))]>,
1623                Requires<[IsARM]>,
1624            Sched<[WriteALU, ReadALU]> {
1625     bits<4> Rd;
1626     bits<4> Rn;
1627     bits<12> imm;
1628     let Inst{25} = 1;
1629     let Inst{15-12} = Rd;
1630     let Inst{19-16} = Rn;
1631     let Inst{11-0} = imm;
1632   }
1633   def rr : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
1634                 DPFrm, IIC_iALUr, opc, "\t$Rd, $Rn, $Rm",
1635                [/* pattern left blank */]>,
1636            Sched<[WriteALU, ReadALU, ReadALU]> {
1637     bits<4> Rd;
1638     bits<4> Rn;
1639     bits<4> Rm;
1640     let Inst{11-4} = 0b00000000;
1641     let Inst{25} = 0;
1642     let Inst{3-0} = Rm;
1643     let Inst{15-12} = Rd;
1644     let Inst{19-16} = Rn;
1645   }
1646   def rsi : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, so_reg_imm:$shift),
1647                 DPSoRegImmFrm, IIC_iALUsr, opc, "\t$Rd, $Rn, $shift",
1648               [(set GPR:$Rd, CPSR, (opnode so_reg_imm:$shift, GPR:$Rn, CPSR))]>,
1649                Requires<[IsARM]>,
1650             Sched<[WriteALUsi, ReadALU]> {
1651     bits<4> Rd;
1652     bits<4> Rn;
1653     bits<12> shift;
1654     let Inst{25} = 0;
1655     let Inst{19-16} = Rn;
1656     let Inst{15-12} = Rd;
1657     let Inst{11-5} = shift{11-5};
1658     let Inst{4} = 0;
1659     let Inst{3-0} = shift{3-0};
1660   }
1661   def rsr : AsI1<opcod, (outs GPR:$Rd), (ins GPR:$Rn, so_reg_reg:$shift),
1662                 DPSoRegRegFrm, IIC_iALUsr, opc, "\t$Rd, $Rn, $shift",
1663               [(set GPR:$Rd, CPSR, (opnode so_reg_reg:$shift, GPR:$Rn, CPSR))]>,
1664                Requires<[IsARM]>,
1665             Sched<[WriteALUsr, ReadALUsr]> {
1666     bits<4> Rd;
1667     bits<4> Rn;
1668     bits<12> shift;
1669     let Inst{25} = 0;
1670     let Inst{19-16} = Rn;
1671     let Inst{15-12} = Rd;
1672     let Inst{11-8} = shift{11-8};
1673     let Inst{7} = 0;
1674     let Inst{6-5} = shift{6-5};
1675     let Inst{4} = 1;
1676     let Inst{3-0} = shift{3-0};
1677   }
1678   }
1679 }
1680
1681 let canFoldAsLoad = 1, isReMaterializable = 1 in {
1682 multiclass AI_ldr1<bit isByte, string opc, InstrItinClass iii,
1683            InstrItinClass iir, PatFrag opnode> {
1684   // Note: We use the complex addrmode_imm12 rather than just an input
1685   // GPR and a constrained immediate so that we can use this to match
1686   // frame index references and avoid matching constant pool references.
1687   def i12: AI2ldst<0b010, 1, isByte, (outs GPR:$Rt), (ins addrmode_imm12:$addr),
1688                    AddrMode_i12, LdFrm, iii, opc, "\t$Rt, $addr",
1689                   [(set GPR:$Rt, (opnode addrmode_imm12:$addr))]> {
1690     bits<4>  Rt;
1691     bits<17> addr;
1692     let Inst{23}    = addr{12};     // U (add = ('U' == 1))
1693     let Inst{19-16} = addr{16-13};  // Rn
1694     let Inst{15-12} = Rt;
1695     let Inst{11-0}  = addr{11-0};   // imm12
1696   }
1697   def rs : AI2ldst<0b011, 1, isByte, (outs GPR:$Rt), (ins ldst_so_reg:$shift),
1698                   AddrModeNone, LdFrm, iir, opc, "\t$Rt, $shift",
1699                  [(set GPR:$Rt, (opnode ldst_so_reg:$shift))]> {
1700     bits<4>  Rt;
1701     bits<17> shift;
1702     let shift{4}    = 0;            // Inst{4} = 0
1703     let Inst{23}    = shift{12};    // U (add = ('U' == 1))
1704     let Inst{19-16} = shift{16-13}; // Rn
1705     let Inst{15-12} = Rt;
1706     let Inst{11-0}  = shift{11-0};
1707   }
1708 }
1709 }
1710
1711 let canFoldAsLoad = 1, isReMaterializable = 1 in {
1712 multiclass AI_ldr1nopc<bit isByte, string opc, InstrItinClass iii,
1713            InstrItinClass iir, PatFrag opnode> {
1714   // Note: We use the complex addrmode_imm12 rather than just an input
1715   // GPR and a constrained immediate so that we can use this to match
1716   // frame index references and avoid matching constant pool references.
1717   def i12: AI2ldst<0b010, 1, isByte, (outs GPRnopc:$Rt),
1718                    (ins addrmode_imm12:$addr),
1719                    AddrMode_i12, LdFrm, iii, opc, "\t$Rt, $addr",
1720                    [(set GPRnopc:$Rt, (opnode addrmode_imm12:$addr))]> {
1721     bits<4>  Rt;
1722     bits<17> addr;
1723     let Inst{23}    = addr{12};     // U (add = ('U' == 1))
1724     let Inst{19-16} = addr{16-13};  // Rn
1725     let Inst{15-12} = Rt;
1726     let Inst{11-0}  = addr{11-0};   // imm12
1727   }
1728   def rs : AI2ldst<0b011, 1, isByte, (outs GPRnopc:$Rt),
1729                    (ins ldst_so_reg:$shift),
1730                    AddrModeNone, LdFrm, iir, opc, "\t$Rt, $shift",
1731                    [(set GPRnopc:$Rt, (opnode ldst_so_reg:$shift))]> {
1732     bits<4>  Rt;
1733     bits<17> shift;
1734     let shift{4}    = 0;            // Inst{4} = 0
1735     let Inst{23}    = shift{12};    // U (add = ('U' == 1))
1736     let Inst{19-16} = shift{16-13}; // Rn
1737     let Inst{15-12} = Rt;
1738     let Inst{11-0}  = shift{11-0};
1739   }
1740 }
1741 }
1742
1743
1744 multiclass AI_str1<bit isByte, string opc, InstrItinClass iii,
1745            InstrItinClass iir, PatFrag opnode> {
1746   // Note: We use the complex addrmode_imm12 rather than just an input
1747   // GPR and a constrained immediate so that we can use this to match
1748   // frame index references and avoid matching constant pool references.
1749   def i12 : AI2ldst<0b010, 0, isByte, (outs),
1750                    (ins GPR:$Rt, addrmode_imm12:$addr),
1751                    AddrMode_i12, StFrm, iii, opc, "\t$Rt, $addr",
1752                   [(opnode GPR:$Rt, addrmode_imm12:$addr)]> {
1753     bits<4> Rt;
1754     bits<17> addr;
1755     let Inst{23}    = addr{12};     // U (add = ('U' == 1))
1756     let Inst{19-16} = addr{16-13};  // Rn
1757     let Inst{15-12} = Rt;
1758     let Inst{11-0}  = addr{11-0};   // imm12
1759   }
1760   def rs : AI2ldst<0b011, 0, isByte, (outs), (ins GPR:$Rt, ldst_so_reg:$shift),
1761                   AddrModeNone, StFrm, iir, opc, "\t$Rt, $shift",
1762                  [(opnode GPR:$Rt, ldst_so_reg:$shift)]> {
1763     bits<4> Rt;
1764     bits<17> shift;
1765     let shift{4}    = 0;            // Inst{4} = 0
1766     let Inst{23}    = shift{12};    // U (add = ('U' == 1))
1767     let Inst{19-16} = shift{16-13}; // Rn
1768     let Inst{15-12} = Rt;
1769     let Inst{11-0}  = shift{11-0};
1770   }
1771 }
1772
1773 multiclass AI_str1nopc<bit isByte, string opc, InstrItinClass iii,
1774            InstrItinClass iir, PatFrag opnode> {
1775   // Note: We use the complex addrmode_imm12 rather than just an input
1776   // GPR and a constrained immediate so that we can use this to match
1777   // frame index references and avoid matching constant pool references.
1778   def i12 : AI2ldst<0b010, 0, isByte, (outs),
1779                    (ins GPRnopc:$Rt, addrmode_imm12:$addr),
1780                    AddrMode_i12, StFrm, iii, opc, "\t$Rt, $addr",
1781                   [(opnode GPRnopc:$Rt, addrmode_imm12:$addr)]> {
1782     bits<4> Rt;
1783     bits<17> addr;
1784     let Inst{23}    = addr{12};     // U (add = ('U' == 1))
1785     let Inst{19-16} = addr{16-13};  // Rn
1786     let Inst{15-12} = Rt;
1787     let Inst{11-0}  = addr{11-0};   // imm12
1788   }
1789   def rs : AI2ldst<0b011, 0, isByte, (outs),
1790                    (ins GPRnopc:$Rt, ldst_so_reg:$shift),
1791                    AddrModeNone, StFrm, iir, opc, "\t$Rt, $shift",
1792                    [(opnode GPRnopc:$Rt, ldst_so_reg:$shift)]> {
1793     bits<4> Rt;
1794     bits<17> shift;
1795     let shift{4}    = 0;            // Inst{4} = 0
1796     let Inst{23}    = shift{12};    // U (add = ('U' == 1))
1797     let Inst{19-16} = shift{16-13}; // Rn
1798     let Inst{15-12} = Rt;
1799     let Inst{11-0}  = shift{11-0};
1800   }
1801 }
1802
1803
1804 //===----------------------------------------------------------------------===//
1805 // Instructions
1806 //===----------------------------------------------------------------------===//
1807
1808 //===----------------------------------------------------------------------===//
1809 //  Miscellaneous Instructions.
1810 //
1811
1812 /// CONSTPOOL_ENTRY - This instruction represents a floating constant pool in
1813 /// the function.  The first operand is the ID# for this instruction, the second
1814 /// is the index into the MachineConstantPool that this is, the third is the
1815 /// size in bytes of this constant pool entry.
1816 let hasSideEffects = 0, isNotDuplicable = 1 in
1817 def CONSTPOOL_ENTRY :
1818 PseudoInst<(outs), (ins cpinst_operand:$instid, cpinst_operand:$cpidx,
1819                     i32imm:$size), NoItinerary, []>;
1820
1821 // FIXME: Marking these as hasSideEffects is necessary to prevent machine DCE
1822 // from removing one half of the matched pairs. That breaks PEI, which assumes
1823 // these will always be in pairs, and asserts if it finds otherwise. Better way?
1824 let Defs = [SP], Uses = [SP], hasSideEffects = 1 in {
1825 def ADJCALLSTACKUP :
1826 PseudoInst<(outs), (ins i32imm:$amt1, i32imm:$amt2, pred:$p), NoItinerary,
1827            [(ARMcallseq_end timm:$amt1, timm:$amt2)]>;
1828
1829 def ADJCALLSTACKDOWN :
1830 PseudoInst<(outs), (ins i32imm:$amt, pred:$p), NoItinerary,
1831            [(ARMcallseq_start timm:$amt)]>;
1832 }
1833
1834 def HINT : AI<(outs), (ins imm0_239:$imm), MiscFrm, NoItinerary,
1835               "hint", "\t$imm", [(int_arm_hint imm0_239:$imm)]>,
1836            Requires<[IsARM, HasV6]> {
1837   bits<8> imm;
1838   let Inst{27-8} = 0b00110010000011110000;
1839   let Inst{7-0} = imm;
1840 }
1841
1842 def : InstAlias<"nop$p", (HINT 0, pred:$p)>, Requires<[IsARM, HasV6T2]>;
1843 def : InstAlias<"yield$p", (HINT 1, pred:$p)>, Requires<[IsARM, HasV6T2]>;
1844 def : InstAlias<"wfe$p", (HINT 2, pred:$p)>, Requires<[IsARM, HasV6T2]>;
1845 def : InstAlias<"wfi$p", (HINT 3, pred:$p)>, Requires<[IsARM, HasV6T2]>;
1846 def : InstAlias<"sev$p", (HINT 4, pred:$p)>, Requires<[IsARM, HasV6T2]>;
1847 def : InstAlias<"sevl$p", (HINT 5, pred:$p)>, Requires<[IsARM, HasV8]>;
1848
1849 def SEL : AI<(outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm), DPFrm, NoItinerary, "sel",
1850              "\t$Rd, $Rn, $Rm", []>, Requires<[IsARM, HasV6]> {
1851   bits<4> Rd;
1852   bits<4> Rn;
1853   bits<4> Rm;
1854   let Inst{3-0} = Rm;
1855   let Inst{15-12} = Rd;
1856   let Inst{19-16} = Rn;
1857   let Inst{27-20} = 0b01101000;
1858   let Inst{7-4} = 0b1011;
1859   let Inst{11-8} = 0b1111;
1860   let Unpredictable{11-8} = 0b1111;
1861 }
1862
1863 // The 16-bit operand $val can be used by a debugger to store more information
1864 // about the breakpoint.
1865 def BKPT : AInoP<(outs), (ins imm0_65535:$val), MiscFrm, NoItinerary,
1866                  "bkpt", "\t$val", []>, Requires<[IsARM]> {
1867   bits<16> val;
1868   let Inst{3-0} = val{3-0};
1869   let Inst{19-8} = val{15-4};
1870   let Inst{27-20} = 0b00010010;
1871   let Inst{31-28} = 0xe; // AL
1872   let Inst{7-4} = 0b0111;
1873 }
1874 // default immediate for breakpoint mnemonic
1875 def : InstAlias<"bkpt", (BKPT 0)>, Requires<[IsARM]>;
1876
1877 def HLT : AInoP<(outs), (ins imm0_65535:$val), MiscFrm, NoItinerary,
1878                  "hlt", "\t$val", []>, Requires<[IsARM, HasV8]> {
1879   bits<16> val;
1880   let Inst{3-0} = val{3-0};
1881   let Inst{19-8} = val{15-4};
1882   let Inst{27-20} = 0b00010000;
1883   let Inst{31-28} = 0xe; // AL
1884   let Inst{7-4} = 0b0111;
1885 }
1886
1887 // Change Processor State
1888 // FIXME: We should use InstAlias to handle the optional operands.
1889 class CPS<dag iops, string asm_ops>
1890   : AXI<(outs), iops, MiscFrm, NoItinerary, !strconcat("cps", asm_ops),
1891         []>, Requires<[IsARM]> {
1892   bits<2> imod;
1893   bits<3> iflags;
1894   bits<5> mode;
1895   bit M;
1896
1897   let Inst{31-28} = 0b1111;
1898   let Inst{27-20} = 0b00010000;
1899   let Inst{19-18} = imod;
1900   let Inst{17}    = M; // Enabled if mode is set;
1901   let Inst{16-9}  = 0b00000000;
1902   let Inst{8-6}   = iflags;
1903   let Inst{5}     = 0;
1904   let Inst{4-0}   = mode;
1905 }
1906
1907 let DecoderMethod = "DecodeCPSInstruction" in {
1908 let M = 1 in
1909   def CPS3p : CPS<(ins imod_op:$imod, iflags_op:$iflags, imm0_31:$mode),
1910                   "$imod\t$iflags, $mode">;
1911 let mode = 0, M = 0 in
1912   def CPS2p : CPS<(ins imod_op:$imod, iflags_op:$iflags), "$imod\t$iflags">;
1913
1914 let imod = 0, iflags = 0, M = 1 in
1915   def CPS1p : CPS<(ins imm0_31:$mode), "\t$mode">;
1916 }
1917
1918 // Preload signals the memory system of possible future data/instruction access.
1919 multiclass APreLoad<bits<1> read, bits<1> data, string opc> {
1920
1921   def i12 : AXIM<(outs), (ins addrmode_imm12:$addr), AddrMode_i12, MiscFrm,
1922                 IIC_Preload, !strconcat(opc, "\t$addr"),
1923                 [(ARMPreload addrmode_imm12:$addr, (i32 read), (i32 data))]>,
1924                 Sched<[WritePreLd]> {
1925     bits<4> Rt;
1926     bits<17> addr;
1927     let Inst{31-26} = 0b111101;
1928     let Inst{25} = 0; // 0 for immediate form
1929     let Inst{24} = data;
1930     let Inst{23} = addr{12};        // U (add = ('U' == 1))
1931     let Inst{22} = read;
1932     let Inst{21-20} = 0b01;
1933     let Inst{19-16} = addr{16-13};  // Rn
1934     let Inst{15-12} = 0b1111;
1935     let Inst{11-0}  = addr{11-0};   // imm12
1936   }
1937
1938   def rs : AXI<(outs), (ins ldst_so_reg:$shift), MiscFrm, IIC_Preload,
1939                !strconcat(opc, "\t$shift"),
1940                [(ARMPreload ldst_so_reg:$shift, (i32 read), (i32 data))]>,
1941                Sched<[WritePreLd]> {
1942     bits<17> shift;
1943     let Inst{31-26} = 0b111101;
1944     let Inst{25} = 1; // 1 for register form
1945     let Inst{24} = data;
1946     let Inst{23} = shift{12};    // U (add = ('U' == 1))
1947     let Inst{22} = read;
1948     let Inst{21-20} = 0b01;
1949     let Inst{19-16} = shift{16-13}; // Rn
1950     let Inst{15-12} = 0b1111;
1951     let Inst{11-0}  = shift{11-0};
1952     let Inst{4} = 0;
1953   }
1954 }
1955
1956 defm PLD  : APreLoad<1, 1, "pld">,  Requires<[IsARM]>;
1957 defm PLDW : APreLoad<0, 1, "pldw">, Requires<[IsARM,HasV7,HasMP]>;
1958 defm PLI  : APreLoad<1, 0, "pli">,  Requires<[IsARM,HasV7]>;
1959
1960 def SETEND : AXI<(outs), (ins setend_op:$end), MiscFrm, NoItinerary,
1961                  "setend\t$end", []>, Requires<[IsARM]>, Deprecated<HasV8Ops> {
1962   bits<1> end;
1963   let Inst{31-10} = 0b1111000100000001000000;
1964   let Inst{9} = end;
1965   let Inst{8-0} = 0;
1966 }
1967
1968 def DBG : AI<(outs), (ins imm0_15:$opt), MiscFrm, NoItinerary, "dbg", "\t$opt",
1969              [(int_arm_dbg imm0_15:$opt)]>, Requires<[IsARM, HasV7]> {
1970   bits<4> opt;
1971   let Inst{27-4} = 0b001100100000111100001111;
1972   let Inst{3-0} = opt;
1973 }
1974
1975 // A8.8.247  UDF - Undefined (Encoding A1)
1976 def UDF : AInoP<(outs), (ins imm0_65535:$imm16), MiscFrm, NoItinerary,
1977                 "udf", "\t$imm16", [(int_arm_undefined imm0_65535:$imm16)]> {
1978   bits<16> imm16;
1979   let Inst{31-28} = 0b1110; // AL
1980   let Inst{27-25} = 0b011;
1981   let Inst{24-20} = 0b11111;
1982   let Inst{19-8} = imm16{15-4};
1983   let Inst{7-4} = 0b1111;
1984   let Inst{3-0} = imm16{3-0};
1985 }
1986
1987 /*
1988  * A5.4 Permanently UNDEFINED instructions.
1989  *
1990  * For most targets use UDF #65006, for which the OS will generate SIGTRAP.
1991  * Other UDF encodings generate SIGILL.
1992  *
1993  * NaCl's OS instead chooses an ARM UDF encoding that's also a UDF in Thumb.
1994  * Encoding A1:
1995  *  1110 0111 1111 iiii iiii iiii 1111 iiii
1996  * Encoding T1:
1997  *  1101 1110 iiii iiii
1998  * It uses the following encoding:
1999  *  1110 0111 1111 1110 1101 1110 1111 0000
2000  *  - In ARM: UDF #60896;
2001  *  - In Thumb: UDF #254 followed by a branch-to-self.
2002  */
2003 let isBarrier = 1, isTerminator = 1 in
2004 def TRAPNaCl : AXI<(outs), (ins), MiscFrm, NoItinerary,
2005                "trap", [(trap)]>,
2006            Requires<[IsARM,UseNaClTrap]> {
2007   let Inst = 0xe7fedef0;
2008 }
2009 let isBarrier = 1, isTerminator = 1 in
2010 def TRAP : AXI<(outs), (ins), MiscFrm, NoItinerary,
2011                "trap", [(trap)]>,
2012            Requires<[IsARM,DontUseNaClTrap]> {
2013   let Inst = 0xe7ffdefe;
2014 }
2015
2016 // Address computation and loads and stores in PIC mode.
2017 let isNotDuplicable = 1 in {
2018 def PICADD  : ARMPseudoInst<(outs GPR:$dst), (ins GPR:$a, pclabel:$cp, pred:$p),
2019                             4, IIC_iALUr,
2020                             [(set GPR:$dst, (ARMpic_add GPR:$a, imm:$cp))]>,
2021                             Sched<[WriteALU, ReadALU]>;
2022
2023 let AddedComplexity = 10 in {
2024 def PICLDR  : ARMPseudoInst<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
2025                             4, IIC_iLoad_r,
2026                             [(set GPR:$dst, (load addrmodepc:$addr))]>;
2027
2028 def PICLDRH : ARMPseudoInst<(outs GPR:$Rt), (ins addrmodepc:$addr, pred:$p),
2029                             4, IIC_iLoad_bh_r,
2030                             [(set GPR:$Rt, (zextloadi16 addrmodepc:$addr))]>;
2031
2032 def PICLDRB : ARMPseudoInst<(outs GPR:$Rt), (ins addrmodepc:$addr, pred:$p),
2033                             4, IIC_iLoad_bh_r,
2034                             [(set GPR:$Rt, (zextloadi8 addrmodepc:$addr))]>;
2035
2036 def PICLDRSH : ARMPseudoInst<(outs GPR:$Rt), (ins addrmodepc:$addr, pred:$p),
2037                             4, IIC_iLoad_bh_r,
2038                             [(set GPR:$Rt, (sextloadi16 addrmodepc:$addr))]>;
2039
2040 def PICLDRSB : ARMPseudoInst<(outs GPR:$Rt), (ins addrmodepc:$addr, pred:$p),
2041                             4, IIC_iLoad_bh_r,
2042                             [(set GPR:$Rt, (sextloadi8 addrmodepc:$addr))]>;
2043 }
2044 let AddedComplexity = 10 in {
2045 def PICSTR  : ARMPseudoInst<(outs), (ins GPR:$src, addrmodepc:$addr, pred:$p),
2046       4, IIC_iStore_r, [(store GPR:$src, addrmodepc:$addr)]>;
2047
2048 def PICSTRH : ARMPseudoInst<(outs), (ins GPR:$src, addrmodepc:$addr, pred:$p),
2049       4, IIC_iStore_bh_r, [(truncstorei16 GPR:$src,
2050                                                    addrmodepc:$addr)]>;
2051
2052 def PICSTRB : ARMPseudoInst<(outs), (ins GPR:$src, addrmodepc:$addr, pred:$p),
2053       4, IIC_iStore_bh_r, [(truncstorei8 GPR:$src, addrmodepc:$addr)]>;
2054 }
2055 } // isNotDuplicable = 1
2056
2057
2058 // LEApcrel - Load a pc-relative address into a register without offending the
2059 // assembler.
2060 let hasSideEffects = 0, isReMaterializable = 1 in
2061 // The 'adr' mnemonic encodes differently if the label is before or after
2062 // the instruction. The {24-21} opcode bits are set by the fixup, as we don't
2063 // know until then which form of the instruction will be used.
2064 def ADR : AI1<{0,?,?,0}, (outs GPR:$Rd), (ins adrlabel:$label),
2065                  MiscFrm, IIC_iALUi, "adr", "\t$Rd, $label", []>,
2066                  Sched<[WriteALU, ReadALU]> {
2067   bits<4> Rd;
2068   bits<14> label;
2069   let Inst{27-25} = 0b001;
2070   let Inst{24} = 0;
2071   let Inst{23-22} = label{13-12};
2072   let Inst{21} = 0;
2073   let Inst{20} = 0;
2074   let Inst{19-16} = 0b1111;
2075   let Inst{15-12} = Rd;
2076   let Inst{11-0} = label{11-0};
2077 }
2078
2079 let hasSideEffects = 1 in {
2080 def LEApcrel : ARMPseudoInst<(outs GPR:$Rd), (ins i32imm:$label, pred:$p),
2081                     4, IIC_iALUi, []>, Sched<[WriteALU, ReadALU]>;
2082
2083 def LEApcrelJT : ARMPseudoInst<(outs GPR:$Rd),
2084                       (ins i32imm:$label, nohash_imm:$id, pred:$p),
2085                       4, IIC_iALUi, []>, Sched<[WriteALU, ReadALU]>;
2086 }
2087
2088 //===----------------------------------------------------------------------===//
2089 //  Control Flow Instructions.
2090 //
2091
2092 let isReturn = 1, isTerminator = 1, isBarrier = 1 in {
2093   // ARMV4T and above
2094   def BX_RET : AI<(outs), (ins), BrMiscFrm, IIC_Br,
2095                   "bx", "\tlr", [(ARMretflag)]>,
2096                Requires<[IsARM, HasV4T]>, Sched<[WriteBr]> {
2097     let Inst{27-0}  = 0b0001001011111111111100011110;
2098   }
2099
2100   // ARMV4 only
2101   def MOVPCLR : AI<(outs), (ins), BrMiscFrm, IIC_Br,
2102                   "mov", "\tpc, lr", [(ARMretflag)]>,
2103                Requires<[IsARM, NoV4T]>, Sched<[WriteBr]> {
2104     let Inst{27-0} = 0b0001101000001111000000001110;
2105   }
2106
2107   // Exception return: N.b. doesn't set CPSR as far as we're concerned (it sets
2108   // the user-space one).
2109   def SUBS_PC_LR : ARMPseudoInst<(outs), (ins i32imm:$offset, pred:$p),
2110                                  4, IIC_Br,
2111                                  [(ARMintretflag imm:$offset)]>;
2112 }
2113
2114 // Indirect branches
2115 let isBranch = 1, isTerminator = 1, isBarrier = 1, isIndirectBranch = 1 in {
2116   // ARMV4T and above
2117   def BX : AXI<(outs), (ins GPR:$dst), BrMiscFrm, IIC_Br, "bx\t$dst",
2118                   [(brind GPR:$dst)]>,
2119               Requires<[IsARM, HasV4T]>, Sched<[WriteBr]> {
2120     bits<4> dst;
2121     let Inst{31-4} = 0b1110000100101111111111110001;
2122     let Inst{3-0}  = dst;
2123   }
2124
2125   def BX_pred : AI<(outs), (ins GPR:$dst), BrMiscFrm, IIC_Br,
2126                   "bx", "\t$dst", [/* pattern left blank */]>,
2127               Requires<[IsARM, HasV4T]>, Sched<[WriteBr]> {
2128     bits<4> dst;
2129     let Inst{27-4} = 0b000100101111111111110001;
2130     let Inst{3-0}  = dst;
2131   }
2132 }
2133
2134 // SP is marked as a use to prevent stack-pointer assignments that appear
2135 // immediately before calls from potentially appearing dead.
2136 let isCall = 1,
2137   // FIXME:  Do we really need a non-predicated version? If so, it should
2138   // at least be a pseudo instruction expanding to the predicated version
2139   // at MC lowering time.
2140   Defs = [LR], Uses = [SP] in {
2141   def BL  : ABXI<0b1011, (outs), (ins bl_target:$func),
2142                 IIC_Br, "bl\t$func",
2143                 [(ARMcall tglobaladdr:$func)]>,
2144             Requires<[IsARM]>, Sched<[WriteBrL]> {
2145     let Inst{31-28} = 0b1110;
2146     bits<24> func;
2147     let Inst{23-0} = func;
2148     let DecoderMethod = "DecodeBranchImmInstruction";
2149   }
2150
2151   def BL_pred : ABI<0b1011, (outs), (ins bl_target:$func),
2152                    IIC_Br, "bl", "\t$func",
2153                    [(ARMcall_pred tglobaladdr:$func)]>,
2154                 Requires<[IsARM]>, Sched<[WriteBrL]> {
2155     bits<24> func;
2156     let Inst{23-0} = func;
2157     let DecoderMethod = "DecodeBranchImmInstruction";
2158   }
2159
2160   // ARMv5T and above
2161   def BLX : AXI<(outs), (ins GPR:$func), BrMiscFrm,
2162                 IIC_Br, "blx\t$func",
2163                 [(ARMcall GPR:$func)]>,
2164             Requires<[IsARM, HasV5T]>, Sched<[WriteBrL]> {
2165     bits<4> func;
2166     let Inst{31-4} = 0b1110000100101111111111110011;
2167     let Inst{3-0}  = func;
2168   }
2169
2170   def BLX_pred : AI<(outs), (ins GPR:$func), BrMiscFrm,
2171                     IIC_Br, "blx", "\t$func",
2172                     [(ARMcall_pred GPR:$func)]>,
2173                  Requires<[IsARM, HasV5T]>, Sched<[WriteBrL]> {
2174     bits<4> func;
2175     let Inst{27-4} = 0b000100101111111111110011;
2176     let Inst{3-0}  = func;
2177   }
2178
2179   // ARMv4T
2180   // Note: Restrict $func to the tGPR regclass to prevent it being in LR.
2181   def BX_CALL : ARMPseudoInst<(outs), (ins tGPR:$func),
2182                    8, IIC_Br, [(ARMcall_nolink tGPR:$func)]>,
2183                    Requires<[IsARM, HasV4T]>, Sched<[WriteBr]>;
2184
2185   // ARMv4
2186   def BMOVPCRX_CALL : ARMPseudoInst<(outs), (ins tGPR:$func),
2187                    8, IIC_Br, [(ARMcall_nolink tGPR:$func)]>,
2188                    Requires<[IsARM, NoV4T]>, Sched<[WriteBr]>;
2189
2190   // mov lr, pc; b if callee is marked noreturn to avoid confusing the
2191   // return stack predictor.
2192   def BMOVPCB_CALL : ARMPseudoInst<(outs), (ins bl_target:$func),
2193                                8, IIC_Br, [(ARMcall_nolink tglobaladdr:$func)]>,
2194                       Requires<[IsARM]>, Sched<[WriteBr]>;
2195 }
2196
2197 let isBranch = 1, isTerminator = 1 in {
2198   // FIXME: should be able to write a pattern for ARMBrcond, but can't use
2199   // a two-value operand where a dag node expects two operands. :(
2200   def Bcc : ABI<0b1010, (outs), (ins br_target:$target),
2201                IIC_Br, "b", "\t$target",
2202                [/*(ARMbrcond bb:$target, imm:$cc, CCR:$ccr)*/]>,
2203                Sched<[WriteBr]>  {
2204     bits<24> target;
2205     let Inst{23-0} = target;
2206     let DecoderMethod = "DecodeBranchImmInstruction";
2207   }
2208
2209   let isBarrier = 1 in {
2210     // B is "predicable" since it's just a Bcc with an 'always' condition.
2211     let isPredicable = 1 in
2212     // FIXME: We shouldn't need this pseudo at all. Just using Bcc directly
2213     // should be sufficient.
2214     // FIXME: Is B really a Barrier? That doesn't seem right.
2215     def B : ARMPseudoExpand<(outs), (ins br_target:$target), 4, IIC_Br,
2216                 [(br bb:$target)], (Bcc br_target:$target, (ops 14, zero_reg))>,
2217                 Sched<[WriteBr]>;
2218
2219     let isNotDuplicable = 1, isIndirectBranch = 1 in {
2220     def BR_JTr : ARMPseudoInst<(outs),
2221                       (ins GPR:$target, i32imm:$jt, i32imm:$id),
2222                       0, IIC_Br,
2223                       [(ARMbrjt GPR:$target, tjumptable:$jt, imm:$id)]>,
2224                       Sched<[WriteBr]>;
2225     // FIXME: This shouldn't use the generic "addrmode2," but rather be split
2226     // into i12 and rs suffixed versions.
2227     def BR_JTm : ARMPseudoInst<(outs),
2228                      (ins addrmode2:$target, i32imm:$jt, i32imm:$id),
2229                      0, IIC_Br,
2230                      [(ARMbrjt (i32 (load addrmode2:$target)), tjumptable:$jt,
2231                        imm:$id)]>, Sched<[WriteBrTbl]>;
2232     def BR_JTadd : ARMPseudoInst<(outs),
2233                    (ins GPR:$target, GPR:$idx, i32imm:$jt, i32imm:$id),
2234                    0, IIC_Br,
2235                    [(ARMbrjt (add GPR:$target, GPR:$idx), tjumptable:$jt,
2236                      imm:$id)]>, Sched<[WriteBrTbl]>;
2237     } // isNotDuplicable = 1, isIndirectBranch = 1
2238   } // isBarrier = 1
2239
2240 }
2241
2242 // BLX (immediate)
2243 def BLXi : AXI<(outs), (ins blx_target:$target), BrMiscFrm, NoItinerary,
2244                "blx\t$target", []>,
2245            Requires<[IsARM, HasV5T]>, Sched<[WriteBrL]> {
2246   let Inst{31-25} = 0b1111101;
2247   bits<25> target;
2248   let Inst{23-0} = target{24-1};
2249   let Inst{24} = target{0};
2250 }
2251
2252 // Branch and Exchange Jazelle
2253 def BXJ : ABI<0b0001, (outs), (ins GPR:$func), NoItinerary, "bxj", "\t$func",
2254               [/* pattern left blank */]>, Sched<[WriteBr]> {
2255   bits<4> func;
2256   let Inst{23-20} = 0b0010;
2257   let Inst{19-8} = 0xfff;
2258   let Inst{7-4} = 0b0010;
2259   let Inst{3-0} = func;
2260 }
2261
2262 // Tail calls.
2263
2264 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [SP] in {
2265   def TCRETURNdi : PseudoInst<(outs), (ins i32imm:$dst), IIC_Br, []>,
2266                    Sched<[WriteBr]>;
2267
2268   def TCRETURNri : PseudoInst<(outs), (ins tcGPR:$dst), IIC_Br, []>,
2269                    Sched<[WriteBr]>;
2270
2271   def TAILJMPd : ARMPseudoExpand<(outs), (ins br_target:$dst),
2272                                  4, IIC_Br, [],
2273                                  (Bcc br_target:$dst, (ops 14, zero_reg))>,
2274                                  Requires<[IsARM]>, Sched<[WriteBr]>;
2275
2276   def TAILJMPr : ARMPseudoExpand<(outs), (ins tcGPR:$dst),
2277                                  4, IIC_Br, [],
2278                                  (BX GPR:$dst)>, Sched<[WriteBr]>,
2279                                  Requires<[IsARM]>;
2280 }
2281
2282 // Secure Monitor Call is a system instruction.
2283 def SMC : ABI<0b0001, (outs), (ins imm0_15:$opt), NoItinerary, "smc", "\t$opt",
2284               []>, Requires<[IsARM, HasTrustZone]> {
2285   bits<4> opt;
2286   let Inst{23-4} = 0b01100000000000000111;
2287   let Inst{3-0} = opt;
2288 }
2289
2290 // Supervisor Call (Software Interrupt)
2291 let isCall = 1, Uses = [SP] in {
2292 def SVC : ABI<0b1111, (outs), (ins imm24b:$svc), IIC_Br, "svc", "\t$svc", []>,
2293           Sched<[WriteBr]> {
2294   bits<24> svc;
2295   let Inst{23-0} = svc;
2296 }
2297 }
2298
2299 // Store Return State
2300 class SRSI<bit wb, string asm>
2301   : XI<(outs), (ins imm0_31:$mode), AddrModeNone, 4, IndexModeNone, BrFrm,
2302        NoItinerary, asm, "", []> {
2303   bits<5> mode;
2304   let Inst{31-28} = 0b1111;
2305   let Inst{27-25} = 0b100;
2306   let Inst{22} = 1;
2307   let Inst{21} = wb;
2308   let Inst{20} = 0;
2309   let Inst{19-16} = 0b1101;  // SP
2310   let Inst{15-5} = 0b00000101000;
2311   let Inst{4-0} = mode;
2312 }
2313
2314 def SRSDA : SRSI<0, "srsda\tsp, $mode"> {
2315   let Inst{24-23} = 0;
2316 }
2317 def SRSDA_UPD : SRSI<1, "srsda\tsp!, $mode"> {
2318   let Inst{24-23} = 0;
2319 }
2320 def SRSDB : SRSI<0, "srsdb\tsp, $mode"> {
2321   let Inst{24-23} = 0b10;
2322 }
2323 def SRSDB_UPD : SRSI<1, "srsdb\tsp!, $mode"> {
2324   let Inst{24-23} = 0b10;
2325 }
2326 def SRSIA : SRSI<0, "srsia\tsp, $mode"> {
2327   let Inst{24-23} = 0b01;
2328 }
2329 def SRSIA_UPD : SRSI<1, "srsia\tsp!, $mode"> {
2330   let Inst{24-23} = 0b01;
2331 }
2332 def SRSIB : SRSI<0, "srsib\tsp, $mode"> {
2333   let Inst{24-23} = 0b11;
2334 }
2335 def SRSIB_UPD : SRSI<1, "srsib\tsp!, $mode"> {
2336   let Inst{24-23} = 0b11;
2337 }
2338
2339 def : ARMInstAlias<"srsda $mode", (SRSDA imm0_31:$mode)>;
2340 def : ARMInstAlias<"srsda $mode!", (SRSDA_UPD imm0_31:$mode)>;
2341
2342 def : ARMInstAlias<"srsdb $mode", (SRSDB imm0_31:$mode)>;
2343 def : ARMInstAlias<"srsdb $mode!", (SRSDB_UPD imm0_31:$mode)>;
2344
2345 def : ARMInstAlias<"srsia $mode", (SRSIA imm0_31:$mode)>;
2346 def : ARMInstAlias<"srsia $mode!", (SRSIA_UPD imm0_31:$mode)>;
2347
2348 def : ARMInstAlias<"srsib $mode", (SRSIB imm0_31:$mode)>;
2349 def : ARMInstAlias<"srsib $mode!", (SRSIB_UPD imm0_31:$mode)>;
2350
2351 // Return From Exception
2352 class RFEI<bit wb, string asm>
2353   : XI<(outs), (ins GPR:$Rn), AddrModeNone, 4, IndexModeNone, BrFrm,
2354        NoItinerary, asm, "", []> {
2355   bits<4> Rn;
2356   let Inst{31-28} = 0b1111;
2357   let Inst{27-25} = 0b100;
2358   let Inst{22} = 0;
2359   let Inst{21} = wb;
2360   let Inst{20} = 1;
2361   let Inst{19-16} = Rn;
2362   let Inst{15-0} = 0xa00;
2363 }
2364
2365 def RFEDA : RFEI<0, "rfeda\t$Rn"> {
2366   let Inst{24-23} = 0;
2367 }
2368 def RFEDA_UPD : RFEI<1, "rfeda\t$Rn!"> {
2369   let Inst{24-23} = 0;
2370 }
2371 def RFEDB : RFEI<0, "rfedb\t$Rn"> {
2372   let Inst{24-23} = 0b10;
2373 }
2374 def RFEDB_UPD : RFEI<1, "rfedb\t$Rn!"> {
2375   let Inst{24-23} = 0b10;
2376 }
2377 def RFEIA : RFEI<0, "rfeia\t$Rn"> {
2378   let Inst{24-23} = 0b01;
2379 }
2380 def RFEIA_UPD : RFEI<1, "rfeia\t$Rn!"> {
2381   let Inst{24-23} = 0b01;
2382 }
2383 def RFEIB : RFEI<0, "rfeib\t$Rn"> {
2384   let Inst{24-23} = 0b11;
2385 }
2386 def RFEIB_UPD : RFEI<1, "rfeib\t$Rn!"> {
2387   let Inst{24-23} = 0b11;
2388 }
2389
2390 //===----------------------------------------------------------------------===//
2391 //  Load / Store Instructions.
2392 //
2393
2394 // Load
2395
2396
2397 defm LDR  : AI_ldr1<0, "ldr", IIC_iLoad_r, IIC_iLoad_si,
2398                     UnOpFrag<(load node:$Src)>>;
2399 defm LDRB : AI_ldr1nopc<1, "ldrb", IIC_iLoad_bh_r, IIC_iLoad_bh_si,
2400                     UnOpFrag<(zextloadi8 node:$Src)>>;
2401 defm STR  : AI_str1<0, "str", IIC_iStore_r, IIC_iStore_si,
2402                    BinOpFrag<(store node:$LHS, node:$RHS)>>;
2403 defm STRB : AI_str1nopc<1, "strb", IIC_iStore_bh_r, IIC_iStore_bh_si,
2404                    BinOpFrag<(truncstorei8 node:$LHS, node:$RHS)>>;
2405
2406 // Special LDR for loads from non-pc-relative constpools.
2407 let canFoldAsLoad = 1, mayLoad = 1, hasSideEffects = 0,
2408     isReMaterializable = 1, isCodeGenOnly = 1 in
2409 def LDRcp : AI2ldst<0b010, 1, 0, (outs GPR:$Rt), (ins addrmode_imm12:$addr),
2410                  AddrMode_i12, LdFrm, IIC_iLoad_r, "ldr", "\t$Rt, $addr",
2411                  []> {
2412   bits<4> Rt;
2413   bits<17> addr;
2414   let Inst{23}    = addr{12};     // U (add = ('U' == 1))
2415   let Inst{19-16} = 0b1111;
2416   let Inst{15-12} = Rt;
2417   let Inst{11-0}  = addr{11-0};   // imm12
2418 }
2419
2420 // Loads with zero extension
2421 def LDRH  : AI3ld<0b1011, 1, (outs GPR:$Rt), (ins addrmode3:$addr), LdMiscFrm,
2422                   IIC_iLoad_bh_r, "ldrh", "\t$Rt, $addr",
2423                   [(set GPR:$Rt, (zextloadi16 addrmode3:$addr))]>;
2424
2425 // Loads with sign extension
2426 def LDRSH : AI3ld<0b1111, 1, (outs GPR:$Rt), (ins addrmode3:$addr), LdMiscFrm,
2427                    IIC_iLoad_bh_r, "ldrsh", "\t$Rt, $addr",
2428                    [(set GPR:$Rt, (sextloadi16 addrmode3:$addr))]>;
2429
2430 def LDRSB : AI3ld<0b1101, 1, (outs GPR:$Rt), (ins addrmode3:$addr), LdMiscFrm,
2431                    IIC_iLoad_bh_r, "ldrsb", "\t$Rt, $addr",
2432                    [(set GPR:$Rt, (sextloadi8 addrmode3:$addr))]>;
2433
2434 let mayLoad = 1, hasSideEffects = 0, hasExtraDefRegAllocReq = 1 in {
2435   // Load doubleword
2436   def LDRD : AI3ld<0b1101, 0, (outs GPR:$Rt, GPR:$Rt2), (ins addrmode3:$addr),
2437                    LdMiscFrm, IIC_iLoad_d_r, "ldrd", "\t$Rt, $Rt2, $addr", []>,
2438              Requires<[IsARM, HasV5TE]>;
2439 }
2440
2441 def LDA : AIldracq<0b00, (outs GPR:$Rt), (ins addr_offset_none:$addr),
2442                     NoItinerary, "lda", "\t$Rt, $addr", []>;
2443 def LDAB : AIldracq<0b10, (outs GPR:$Rt), (ins addr_offset_none:$addr),
2444                     NoItinerary, "ldab", "\t$Rt, $addr", []>;
2445 def LDAH : AIldracq<0b11, (outs GPR:$Rt), (ins addr_offset_none:$addr),
2446                     NoItinerary, "ldah", "\t$Rt, $addr", []>;
2447
2448 // Indexed loads
2449 multiclass AI2_ldridx<bit isByte, string opc,
2450                       InstrItinClass iii, InstrItinClass iir> {
2451   def _PRE_IMM  : AI2ldstidx<1, isByte, 1, (outs GPR:$Rt, GPR:$Rn_wb),
2452                       (ins addrmode_imm12_pre:$addr), IndexModePre, LdFrm, iii,
2453                       opc, "\t$Rt, $addr!", "$addr.base = $Rn_wb", []> {
2454     bits<17> addr;
2455     let Inst{25} = 0;
2456     let Inst{23} = addr{12};
2457     let Inst{19-16} = addr{16-13};
2458     let Inst{11-0} = addr{11-0};
2459     let DecoderMethod = "DecodeLDRPreImm";
2460   }
2461
2462   def _PRE_REG  : AI2ldstidx<1, isByte, 1, (outs GPR:$Rt, GPR:$Rn_wb),
2463                       (ins ldst_so_reg:$addr), IndexModePre, LdFrm, iir,
2464                       opc, "\t$Rt, $addr!", "$addr.base = $Rn_wb", []> {
2465     bits<17> addr;
2466     let Inst{25} = 1;
2467     let Inst{23} = addr{12};
2468     let Inst{19-16} = addr{16-13};
2469     let Inst{11-0} = addr{11-0};
2470     let Inst{4} = 0;
2471     let DecoderMethod = "DecodeLDRPreReg";
2472   }
2473
2474   def _POST_REG : AI2ldstidx<1, isByte, 0, (outs GPR:$Rt, GPR:$Rn_wb),
2475                        (ins addr_offset_none:$addr, am2offset_reg:$offset),
2476                        IndexModePost, LdFrm, iir,
2477                        opc, "\t$Rt, $addr, $offset",
2478                        "$addr.base = $Rn_wb", []> {
2479      // {12}     isAdd
2480      // {11-0}   imm12/Rm
2481      bits<14> offset;
2482      bits<4> addr;
2483      let Inst{25} = 1;
2484      let Inst{23} = offset{12};
2485      let Inst{19-16} = addr;
2486      let Inst{11-0} = offset{11-0};
2487      let Inst{4} = 0;
2488
2489     let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2490    }
2491
2492    def _POST_IMM : AI2ldstidx<1, isByte, 0, (outs GPR:$Rt, GPR:$Rn_wb),
2493                        (ins addr_offset_none:$addr, am2offset_imm:$offset),
2494                       IndexModePost, LdFrm, iii,
2495                       opc, "\t$Rt, $addr, $offset",
2496                       "$addr.base = $Rn_wb", []> {
2497     // {12}     isAdd
2498     // {11-0}   imm12/Rm
2499     bits<14> offset;
2500     bits<4> addr;
2501     let Inst{25} = 0;
2502     let Inst{23} = offset{12};
2503     let Inst{19-16} = addr;
2504     let Inst{11-0} = offset{11-0};
2505
2506     let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2507   }
2508
2509 }
2510
2511 let mayLoad = 1, hasSideEffects = 0 in {
2512 // FIXME: for LDR_PRE_REG etc. the itineray should be either IIC_iLoad_ru or
2513 // IIC_iLoad_siu depending on whether it the offset register is shifted.
2514 defm LDR  : AI2_ldridx<0, "ldr", IIC_iLoad_iu, IIC_iLoad_ru>;
2515 defm LDRB : AI2_ldridx<1, "ldrb", IIC_iLoad_bh_iu, IIC_iLoad_bh_ru>;
2516 }
2517
2518 multiclass AI3_ldridx<bits<4> op, string opc, InstrItinClass itin> {
2519   def _PRE  : AI3ldstidx<op, 1, 1, (outs GPR:$Rt, GPR:$Rn_wb),
2520                         (ins addrmode3_pre:$addr), IndexModePre,
2521                         LdMiscFrm, itin,
2522                         opc, "\t$Rt, $addr!", "$addr.base = $Rn_wb", []> {
2523     bits<14> addr;
2524     let Inst{23}    = addr{8};      // U bit
2525     let Inst{22}    = addr{13};     // 1 == imm8, 0 == Rm
2526     let Inst{19-16} = addr{12-9};   // Rn
2527     let Inst{11-8}  = addr{7-4};    // imm7_4/zero
2528     let Inst{3-0}   = addr{3-0};    // imm3_0/Rm
2529     let DecoderMethod = "DecodeAddrMode3Instruction";
2530   }
2531   def _POST : AI3ldstidx<op, 1, 0, (outs GPR:$Rt, GPR:$Rn_wb),
2532                         (ins addr_offset_none:$addr, am3offset:$offset),
2533                         IndexModePost, LdMiscFrm, itin,
2534                         opc, "\t$Rt, $addr, $offset", "$addr.base = $Rn_wb",
2535                         []> {
2536     bits<10> offset;
2537     bits<4> addr;
2538     let Inst{23}    = offset{8};      // U bit
2539     let Inst{22}    = offset{9};      // 1 == imm8, 0 == Rm
2540     let Inst{19-16} = addr;
2541     let Inst{11-8}  = offset{7-4};    // imm7_4/zero
2542     let Inst{3-0}   = offset{3-0};    // imm3_0/Rm
2543     let DecoderMethod = "DecodeAddrMode3Instruction";
2544   }
2545 }
2546
2547 let mayLoad = 1, hasSideEffects = 0 in {
2548 defm LDRH  : AI3_ldridx<0b1011, "ldrh", IIC_iLoad_bh_ru>;
2549 defm LDRSH : AI3_ldridx<0b1111, "ldrsh", IIC_iLoad_bh_ru>;
2550 defm LDRSB : AI3_ldridx<0b1101, "ldrsb", IIC_iLoad_bh_ru>;
2551 let hasExtraDefRegAllocReq = 1 in {
2552 def LDRD_PRE : AI3ldstidx<0b1101, 0, 1, (outs GPR:$Rt, GPR:$Rt2, GPR:$Rn_wb),
2553                           (ins addrmode3_pre:$addr), IndexModePre,
2554                           LdMiscFrm, IIC_iLoad_d_ru,
2555                           "ldrd", "\t$Rt, $Rt2, $addr!",
2556                           "$addr.base = $Rn_wb", []> {
2557   bits<14> addr;
2558   let Inst{23}    = addr{8};      // U bit
2559   let Inst{22}    = addr{13};     // 1 == imm8, 0 == Rm
2560   let Inst{19-16} = addr{12-9};   // Rn
2561   let Inst{11-8}  = addr{7-4};    // imm7_4/zero
2562   let Inst{3-0}   = addr{3-0};    // imm3_0/Rm
2563   let DecoderMethod = "DecodeAddrMode3Instruction";
2564 }
2565 def LDRD_POST: AI3ldstidx<0b1101, 0, 0, (outs GPR:$Rt, GPR:$Rt2, GPR:$Rn_wb),
2566                           (ins addr_offset_none:$addr, am3offset:$offset),
2567                           IndexModePost, LdMiscFrm, IIC_iLoad_d_ru,
2568                           "ldrd", "\t$Rt, $Rt2, $addr, $offset",
2569                           "$addr.base = $Rn_wb", []> {
2570   bits<10> offset;
2571   bits<4> addr;
2572   let Inst{23}    = offset{8};      // U bit
2573   let Inst{22}    = offset{9};      // 1 == imm8, 0 == Rm
2574   let Inst{19-16} = addr;
2575   let Inst{11-8}  = offset{7-4};    // imm7_4/zero
2576   let Inst{3-0}   = offset{3-0};    // imm3_0/Rm
2577   let DecoderMethod = "DecodeAddrMode3Instruction";
2578 }
2579 } // hasExtraDefRegAllocReq = 1
2580 } // mayLoad = 1, hasSideEffects = 0
2581
2582 // LDRT, LDRBT, LDRSBT, LDRHT, LDRSHT.
2583 let mayLoad = 1, hasSideEffects = 0 in {
2584 def LDRT_POST_REG : AI2ldstidx<1, 0, 0, (outs GPR:$Rt, GPR:$Rn_wb),
2585                     (ins addr_offset_none:$addr, am2offset_reg:$offset),
2586                     IndexModePost, LdFrm, IIC_iLoad_ru,
2587                     "ldrt", "\t$Rt, $addr, $offset",
2588                     "$addr.base = $Rn_wb", []> {
2589   // {12}     isAdd
2590   // {11-0}   imm12/Rm
2591   bits<14> offset;
2592   bits<4> addr;
2593   let Inst{25} = 1;
2594   let Inst{23} = offset{12};
2595   let Inst{21} = 1; // overwrite
2596   let Inst{19-16} = addr;
2597   let Inst{11-5} = offset{11-5};
2598   let Inst{4} = 0;
2599   let Inst{3-0} = offset{3-0};
2600   let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2601 }
2602
2603 def LDRT_POST_IMM
2604   : AI2ldstidx<1, 0, 0, (outs GPR:$Rt, GPR:$Rn_wb),
2605                (ins addr_offset_none:$addr, am2offset_imm:$offset),
2606                IndexModePost, LdFrm, IIC_iLoad_ru,
2607                "ldrt", "\t$Rt, $addr, $offset", "$addr.base = $Rn_wb", []> {
2608   // {12}     isAdd
2609   // {11-0}   imm12/Rm
2610   bits<14> offset;
2611   bits<4> addr;
2612   let Inst{25} = 0;
2613   let Inst{23} = offset{12};
2614   let Inst{21} = 1; // overwrite
2615   let Inst{19-16} = addr;
2616   let Inst{11-0} = offset{11-0};
2617   let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2618 }
2619
2620 def LDRBT_POST_REG : AI2ldstidx<1, 1, 0, (outs GPR:$Rt, GPR:$Rn_wb),
2621                      (ins addr_offset_none:$addr, am2offset_reg:$offset),
2622                      IndexModePost, LdFrm, IIC_iLoad_bh_ru,
2623                      "ldrbt", "\t$Rt, $addr, $offset",
2624                      "$addr.base = $Rn_wb", []> {
2625   // {12}     isAdd
2626   // {11-0}   imm12/Rm
2627   bits<14> offset;
2628   bits<4> addr;
2629   let Inst{25} = 1;
2630   let Inst{23} = offset{12};
2631   let Inst{21} = 1; // overwrite
2632   let Inst{19-16} = addr;
2633   let Inst{11-5} = offset{11-5};
2634   let Inst{4} = 0;
2635   let Inst{3-0} = offset{3-0};
2636   let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2637 }
2638
2639 def LDRBT_POST_IMM
2640   : AI2ldstidx<1, 1, 0, (outs GPR:$Rt, GPR:$Rn_wb),
2641                (ins addr_offset_none:$addr, am2offset_imm:$offset),
2642                IndexModePost, LdFrm, IIC_iLoad_bh_ru,
2643                "ldrbt", "\t$Rt, $addr, $offset", "$addr.base = $Rn_wb", []> {
2644   // {12}     isAdd
2645   // {11-0}   imm12/Rm
2646   bits<14> offset;
2647   bits<4> addr;
2648   let Inst{25} = 0;
2649   let Inst{23} = offset{12};
2650   let Inst{21} = 1; // overwrite
2651   let Inst{19-16} = addr;
2652   let Inst{11-0} = offset{11-0};
2653   let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2654 }
2655
2656 multiclass AI3ldrT<bits<4> op, string opc> {
2657   def i : AI3ldstidxT<op, 1, (outs GPR:$Rt, GPR:$base_wb),
2658                       (ins addr_offset_none:$addr, postidx_imm8:$offset),
2659                       IndexModePost, LdMiscFrm, IIC_iLoad_bh_ru, opc,
2660                       "\t$Rt, $addr, $offset", "$addr.base = $base_wb", []> {
2661     bits<9> offset;
2662     let Inst{23} = offset{8};
2663     let Inst{22} = 1;
2664     let Inst{11-8} = offset{7-4};
2665     let Inst{3-0} = offset{3-0};
2666   }
2667   def r : AI3ldstidxT<op, 1, (outs GPRnopc:$Rt, GPRnopc:$base_wb),
2668                       (ins addr_offset_none:$addr, postidx_reg:$Rm),
2669                       IndexModePost, LdMiscFrm, IIC_iLoad_bh_ru, opc,
2670                       "\t$Rt, $addr, $Rm", "$addr.base = $base_wb", []> {
2671     bits<5> Rm;
2672     let Inst{23} = Rm{4};
2673     let Inst{22} = 0;
2674     let Inst{11-8} = 0;
2675     let Unpredictable{11-8} = 0b1111;
2676     let Inst{3-0} = Rm{3-0};
2677     let DecoderMethod = "DecodeLDR";
2678   }
2679 }
2680
2681 defm LDRSBT : AI3ldrT<0b1101, "ldrsbt">;
2682 defm LDRHT  : AI3ldrT<0b1011, "ldrht">;
2683 defm LDRSHT : AI3ldrT<0b1111, "ldrsht">;
2684 }
2685
2686 def LDRT_POST
2687   : ARMAsmPseudo<"ldrt${q} $Rt, $addr", (ins addr_offset_none:$addr, pred:$q),
2688                  (outs GPR:$Rt)>;
2689
2690 def LDRBT_POST
2691   : ARMAsmPseudo<"ldrbt${q} $Rt, $addr", (ins addr_offset_none:$addr, pred:$q),
2692                  (outs GPR:$Rt)>;
2693
2694 // Store
2695
2696 // Stores with truncate
2697 def STRH : AI3str<0b1011, (outs), (ins GPR:$Rt, addrmode3:$addr), StMiscFrm,
2698                IIC_iStore_bh_r, "strh", "\t$Rt, $addr",
2699                [(truncstorei16 GPR:$Rt, addrmode3:$addr)]>;
2700
2701 // Store doubleword
2702 let mayStore = 1, hasSideEffects = 0, hasExtraSrcRegAllocReq = 1 in {
2703   def STRD : AI3str<0b1111, (outs), (ins GPR:$Rt, GPR:$Rt2, addrmode3:$addr),
2704                     StMiscFrm, IIC_iStore_d_r, "strd", "\t$Rt, $Rt2, $addr", []>,
2705              Requires<[IsARM, HasV5TE]> {
2706     let Inst{21} = 0;
2707   }
2708 }
2709
2710 // Indexed stores
2711 multiclass AI2_stridx<bit isByte, string opc,
2712                       InstrItinClass iii, InstrItinClass iir> {
2713   def _PRE_IMM : AI2ldstidx<0, isByte, 1, (outs GPR:$Rn_wb),
2714                             (ins GPR:$Rt, addrmode_imm12_pre:$addr), IndexModePre,
2715                             StFrm, iii,
2716                             opc, "\t$Rt, $addr!",
2717                             "$addr.base = $Rn_wb,@earlyclobber $Rn_wb", []> {
2718     bits<17> addr;
2719     let Inst{25} = 0;
2720     let Inst{23}    = addr{12};     // U (add = ('U' == 1))
2721     let Inst{19-16} = addr{16-13};  // Rn
2722     let Inst{11-0}  = addr{11-0};   // imm12
2723     let DecoderMethod = "DecodeSTRPreImm";
2724   }
2725
2726   def _PRE_REG  : AI2ldstidx<0, isByte, 1, (outs GPR:$Rn_wb),
2727                       (ins GPR:$Rt, ldst_so_reg:$addr),
2728                       IndexModePre, StFrm, iir,
2729                       opc, "\t$Rt, $addr!",
2730                       "$addr.base = $Rn_wb,@earlyclobber $Rn_wb", []> {
2731     bits<17> addr;
2732     let Inst{25} = 1;
2733     let Inst{23}    = addr{12};    // U (add = ('U' == 1))
2734     let Inst{19-16} = addr{16-13}; // Rn
2735     let Inst{11-0}  = addr{11-0};
2736     let Inst{4}     = 0;           // Inst{4} = 0
2737     let DecoderMethod = "DecodeSTRPreReg";
2738   }
2739   def _POST_REG : AI2ldstidx<0, isByte, 0, (outs GPR:$Rn_wb),
2740                 (ins GPR:$Rt, addr_offset_none:$addr, am2offset_reg:$offset),
2741                 IndexModePost, StFrm, iir,
2742                 opc, "\t$Rt, $addr, $offset",
2743                 "$addr.base = $Rn_wb,@earlyclobber $Rn_wb", []> {
2744      // {12}     isAdd
2745      // {11-0}   imm12/Rm
2746      bits<14> offset;
2747      bits<4> addr;
2748      let Inst{25} = 1;
2749      let Inst{23} = offset{12};
2750      let Inst{19-16} = addr;
2751      let Inst{11-0} = offset{11-0};
2752      let Inst{4} = 0;
2753
2754     let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2755    }
2756
2757    def _POST_IMM : AI2ldstidx<0, isByte, 0, (outs GPR:$Rn_wb),
2758                 (ins GPR:$Rt, addr_offset_none:$addr, am2offset_imm:$offset),
2759                 IndexModePost, StFrm, iii,
2760                 opc, "\t$Rt, $addr, $offset",
2761                 "$addr.base = $Rn_wb,@earlyclobber $Rn_wb", []> {
2762     // {12}     isAdd
2763     // {11-0}   imm12/Rm
2764     bits<14> offset;
2765     bits<4> addr;
2766     let Inst{25} = 0;
2767     let Inst{23} = offset{12};
2768     let Inst{19-16} = addr;
2769     let Inst{11-0} = offset{11-0};
2770
2771     let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2772   }
2773 }
2774
2775 let mayStore = 1, hasSideEffects = 0 in {
2776 // FIXME: for STR_PRE_REG etc. the itineray should be either IIC_iStore_ru or
2777 // IIC_iStore_siu depending on whether it the offset register is shifted.
2778 defm STR  : AI2_stridx<0, "str", IIC_iStore_iu, IIC_iStore_ru>;
2779 defm STRB : AI2_stridx<1, "strb", IIC_iStore_bh_iu, IIC_iStore_bh_ru>;
2780 }
2781
2782 def : ARMPat<(post_store GPR:$Rt, addr_offset_none:$addr,
2783                          am2offset_reg:$offset),
2784              (STR_POST_REG GPR:$Rt, addr_offset_none:$addr,
2785                            am2offset_reg:$offset)>;
2786 def : ARMPat<(post_store GPR:$Rt, addr_offset_none:$addr,
2787                          am2offset_imm:$offset),
2788              (STR_POST_IMM GPR:$Rt, addr_offset_none:$addr,
2789                            am2offset_imm:$offset)>;
2790 def : ARMPat<(post_truncsti8 GPR:$Rt, addr_offset_none:$addr,
2791                              am2offset_reg:$offset),
2792              (STRB_POST_REG GPR:$Rt, addr_offset_none:$addr,
2793                             am2offset_reg:$offset)>;
2794 def : ARMPat<(post_truncsti8 GPR:$Rt, addr_offset_none:$addr,
2795                              am2offset_imm:$offset),
2796              (STRB_POST_IMM GPR:$Rt, addr_offset_none:$addr,
2797                             am2offset_imm:$offset)>;
2798
2799 // Pseudo-instructions for pattern matching the pre-indexed stores. We can't
2800 // put the patterns on the instruction definitions directly as ISel wants
2801 // the address base and offset to be separate operands, not a single
2802 // complex operand like we represent the instructions themselves. The
2803 // pseudos map between the two.
2804 let usesCustomInserter = 1,
2805     Constraints = "$Rn = $Rn_wb,@earlyclobber $Rn_wb" in {
2806 def STRi_preidx: ARMPseudoInst<(outs GPR:$Rn_wb),
2807                (ins GPR:$Rt, GPR:$Rn, am2offset_imm:$offset, pred:$p),
2808                4, IIC_iStore_ru,
2809             [(set GPR:$Rn_wb,
2810                   (pre_store GPR:$Rt, GPR:$Rn, am2offset_imm:$offset))]>;
2811 def STRr_preidx: ARMPseudoInst<(outs GPR:$Rn_wb),
2812                (ins GPR:$Rt, GPR:$Rn, am2offset_reg:$offset, pred:$p),
2813                4, IIC_iStore_ru,
2814             [(set GPR:$Rn_wb,
2815                   (pre_store GPR:$Rt, GPR:$Rn, am2offset_reg:$offset))]>;
2816 def STRBi_preidx: ARMPseudoInst<(outs GPR:$Rn_wb),
2817                (ins GPR:$Rt, GPR:$Rn, am2offset_imm:$offset, pred:$p),
2818                4, IIC_iStore_ru,
2819             [(set GPR:$Rn_wb,
2820                   (pre_truncsti8 GPR:$Rt, GPR:$Rn, am2offset_imm:$offset))]>;
2821 def STRBr_preidx: ARMPseudoInst<(outs GPR:$Rn_wb),
2822                (ins GPR:$Rt, GPR:$Rn, am2offset_reg:$offset, pred:$p),
2823                4, IIC_iStore_ru,
2824             [(set GPR:$Rn_wb,
2825                   (pre_truncsti8 GPR:$Rt, GPR:$Rn, am2offset_reg:$offset))]>;
2826 def STRH_preidx: ARMPseudoInst<(outs GPR:$Rn_wb),
2827                (ins GPR:$Rt, GPR:$Rn, am3offset:$offset, pred:$p),
2828                4, IIC_iStore_ru,
2829             [(set GPR:$Rn_wb,
2830                   (pre_truncsti16 GPR:$Rt, GPR:$Rn, am3offset:$offset))]>;
2831 }
2832
2833
2834
2835 def STRH_PRE  : AI3ldstidx<0b1011, 0, 1, (outs GPR:$Rn_wb),
2836                            (ins GPR:$Rt, addrmode3_pre:$addr), IndexModePre,
2837                            StMiscFrm, IIC_iStore_bh_ru,
2838                            "strh", "\t$Rt, $addr!",
2839                            "$addr.base = $Rn_wb,@earlyclobber $Rn_wb", []> {
2840   bits<14> addr;
2841   let Inst{23}    = addr{8};      // U bit
2842   let Inst{22}    = addr{13};     // 1 == imm8, 0 == Rm
2843   let Inst{19-16} = addr{12-9};   // Rn
2844   let Inst{11-8}  = addr{7-4};    // imm7_4/zero
2845   let Inst{3-0}   = addr{3-0};    // imm3_0/Rm
2846   let DecoderMethod = "DecodeAddrMode3Instruction";
2847 }
2848
2849 def STRH_POST : AI3ldstidx<0b1011, 0, 0, (outs GPR:$Rn_wb),
2850                        (ins GPR:$Rt, addr_offset_none:$addr, am3offset:$offset),
2851                        IndexModePost, StMiscFrm, IIC_iStore_bh_ru,
2852                        "strh", "\t$Rt, $addr, $offset",
2853                        "$addr.base = $Rn_wb,@earlyclobber $Rn_wb",
2854                    [(set GPR:$Rn_wb, (post_truncsti16 GPR:$Rt,
2855                                                       addr_offset_none:$addr,
2856                                                       am3offset:$offset))]> {
2857   bits<10> offset;
2858   bits<4> addr;
2859   let Inst{23}    = offset{8};      // U bit
2860   let Inst{22}    = offset{9};      // 1 == imm8, 0 == Rm
2861   let Inst{19-16} = addr;
2862   let Inst{11-8}  = offset{7-4};    // imm7_4/zero
2863   let Inst{3-0}   = offset{3-0};    // imm3_0/Rm
2864   let DecoderMethod = "DecodeAddrMode3Instruction";
2865 }
2866
2867 let mayStore = 1, hasSideEffects = 0, hasExtraSrcRegAllocReq = 1 in {
2868 def STRD_PRE : AI3ldstidx<0b1111, 0, 1, (outs GPR:$Rn_wb),
2869                           (ins GPR:$Rt, GPR:$Rt2, addrmode3_pre:$addr),
2870                           IndexModePre, StMiscFrm, IIC_iStore_d_ru,
2871                           "strd", "\t$Rt, $Rt2, $addr!",
2872                           "$addr.base = $Rn_wb", []> {
2873   bits<14> addr;
2874   let Inst{23}    = addr{8};      // U bit
2875   let Inst{22}    = addr{13};     // 1 == imm8, 0 == Rm
2876   let Inst{19-16} = addr{12-9};   // Rn
2877   let Inst{11-8}  = addr{7-4};    // imm7_4/zero
2878   let Inst{3-0}   = addr{3-0};    // imm3_0/Rm
2879   let DecoderMethod = "DecodeAddrMode3Instruction";
2880 }
2881
2882 def STRD_POST: AI3ldstidx<0b1111, 0, 0, (outs GPR:$Rn_wb),
2883                           (ins GPR:$Rt, GPR:$Rt2, addr_offset_none:$addr,
2884                                am3offset:$offset),
2885                           IndexModePost, StMiscFrm, IIC_iStore_d_ru,
2886                           "strd", "\t$Rt, $Rt2, $addr, $offset",
2887                           "$addr.base = $Rn_wb", []> {
2888   bits<10> offset;
2889   bits<4> addr;
2890   let Inst{23}    = offset{8};      // U bit
2891   let Inst{22}    = offset{9};      // 1 == imm8, 0 == Rm
2892   let Inst{19-16} = addr;
2893   let Inst{11-8}  = offset{7-4};    // imm7_4/zero
2894   let Inst{3-0}   = offset{3-0};    // imm3_0/Rm
2895   let DecoderMethod = "DecodeAddrMode3Instruction";
2896 }
2897 } // mayStore = 1, hasSideEffects = 0, hasExtraSrcRegAllocReq = 1
2898
2899 // STRT, STRBT, and STRHT
2900
2901 def STRBT_POST_REG : AI2ldstidx<0, 1, 0, (outs GPR:$Rn_wb),
2902                    (ins GPR:$Rt, addr_offset_none:$addr, am2offset_reg:$offset),
2903                    IndexModePost, StFrm, IIC_iStore_bh_ru,
2904                    "strbt", "\t$Rt, $addr, $offset",
2905                    "$addr.base = $Rn_wb", []> {
2906   // {12}     isAdd
2907   // {11-0}   imm12/Rm
2908   bits<14> offset;
2909   bits<4> addr;
2910   let Inst{25} = 1;
2911   let Inst{23} = offset{12};
2912   let Inst{21} = 1; // overwrite
2913   let Inst{19-16} = addr;
2914   let Inst{11-5} = offset{11-5};
2915   let Inst{4} = 0;
2916   let Inst{3-0} = offset{3-0};
2917   let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2918 }
2919
2920 def STRBT_POST_IMM
2921   : AI2ldstidx<0, 1, 0, (outs GPR:$Rn_wb),
2922                (ins GPR:$Rt, addr_offset_none:$addr, am2offset_imm:$offset),
2923                IndexModePost, StFrm, IIC_iStore_bh_ru,
2924                "strbt", "\t$Rt, $addr, $offset", "$addr.base = $Rn_wb", []> {
2925   // {12}     isAdd
2926   // {11-0}   imm12/Rm
2927   bits<14> offset;
2928   bits<4> addr;
2929   let Inst{25} = 0;
2930   let Inst{23} = offset{12};
2931   let Inst{21} = 1; // overwrite
2932   let Inst{19-16} = addr;
2933   let Inst{11-0} = offset{11-0};
2934   let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2935 }
2936
2937 def STRBT_POST
2938   : ARMAsmPseudo<"strbt${q} $Rt, $addr",
2939                  (ins GPR:$Rt, addr_offset_none:$addr, pred:$q)>;
2940
2941 let mayStore = 1, hasSideEffects = 0 in {
2942 def STRT_POST_REG : AI2ldstidx<0, 0, 0, (outs GPR:$Rn_wb),
2943                    (ins GPR:$Rt, addr_offset_none:$addr, am2offset_reg:$offset),
2944                    IndexModePost, StFrm, IIC_iStore_ru,
2945                    "strt", "\t$Rt, $addr, $offset",
2946                    "$addr.base = $Rn_wb", []> {
2947   // {12}     isAdd
2948   // {11-0}   imm12/Rm
2949   bits<14> offset;
2950   bits<4> addr;
2951   let Inst{25} = 1;
2952   let Inst{23} = offset{12};
2953   let Inst{21} = 1; // overwrite
2954   let Inst{19-16} = addr;
2955   let Inst{11-5} = offset{11-5};
2956   let Inst{4} = 0;
2957   let Inst{3-0} = offset{3-0};
2958   let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2959 }
2960
2961 def STRT_POST_IMM
2962   : AI2ldstidx<0, 0, 0, (outs GPR:$Rn_wb),
2963                (ins GPR:$Rt, addr_offset_none:$addr, am2offset_imm:$offset),
2964                IndexModePost, StFrm, IIC_iStore_ru,
2965                "strt", "\t$Rt, $addr, $offset", "$addr.base = $Rn_wb", []> {
2966   // {12}     isAdd
2967   // {11-0}   imm12/Rm
2968   bits<14> offset;
2969   bits<4> addr;
2970   let Inst{25} = 0;
2971   let Inst{23} = offset{12};
2972   let Inst{21} = 1; // overwrite
2973   let Inst{19-16} = addr;
2974   let Inst{11-0} = offset{11-0};
2975   let DecoderMethod = "DecodeAddrMode2IdxInstruction";
2976 }
2977 }
2978
2979 def STRT_POST
2980   : ARMAsmPseudo<"strt${q} $Rt, $addr",
2981                  (ins GPR:$Rt, addr_offset_none:$addr, pred:$q)>;
2982
2983 multiclass AI3strT<bits<4> op, string opc> {
2984   def i : AI3ldstidxT<op, 0, (outs GPR:$base_wb),
2985                     (ins GPR:$Rt, addr_offset_none:$addr, postidx_imm8:$offset),
2986                     IndexModePost, StMiscFrm, IIC_iStore_bh_ru, opc,
2987                     "\t$Rt, $addr, $offset", "$addr.base = $base_wb", []> {
2988     bits<9> offset;
2989     let Inst{23} = offset{8};
2990     let Inst{22} = 1;
2991     let Inst{11-8} = offset{7-4};
2992     let Inst{3-0} = offset{3-0};
2993   }
2994   def r : AI3ldstidxT<op, 0, (outs GPR:$base_wb),
2995                       (ins GPR:$Rt, addr_offset_none:$addr, postidx_reg:$Rm),
2996                       IndexModePost, StMiscFrm, IIC_iStore_bh_ru, opc,
2997                       "\t$Rt, $addr, $Rm", "$addr.base = $base_wb", []> {
2998     bits<5> Rm;
2999     let Inst{23} = Rm{4};
3000     let Inst{22} = 0;
3001     let Inst{11-8} = 0;
3002     let Inst{3-0} = Rm{3-0};
3003   }
3004 }
3005
3006
3007 defm STRHT : AI3strT<0b1011, "strht">;
3008
3009 def STL : AIstrrel<0b00, (outs), (ins GPR:$Rt, addr_offset_none:$addr),
3010                    NoItinerary, "stl", "\t$Rt, $addr", []>;
3011 def STLB : AIstrrel<0b10, (outs), (ins GPR:$Rt, addr_offset_none:$addr),
3012                     NoItinerary, "stlb", "\t$Rt, $addr", []>;
3013 def STLH : AIstrrel<0b11, (outs), (ins GPR:$Rt, addr_offset_none:$addr),
3014                     NoItinerary, "stlh", "\t$Rt, $addr", []>;
3015
3016 //===----------------------------------------------------------------------===//
3017 //  Load / store multiple Instructions.
3018 //
3019
3020 multiclass arm_ldst_mult<string asm, string sfx, bit L_bit, bit P_bit, Format f,
3021                          InstrItinClass itin, InstrItinClass itin_upd> {
3022   // IA is the default, so no need for an explicit suffix on the
3023   // mnemonic here. Without it is the canonical spelling.
3024   def IA :
3025     AXI4<(outs), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
3026          IndexModeNone, f, itin,
3027          !strconcat(asm, "${p}\t$Rn, $regs", sfx), "", []> {
3028     let Inst{24-23} = 0b01;       // Increment After
3029     let Inst{22}    = P_bit;
3030     let Inst{21}    = 0;          // No writeback
3031     let Inst{20}    = L_bit;
3032   }
3033   def IA_UPD :
3034     AXI4<(outs GPR:$wb), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
3035          IndexModeUpd, f, itin_upd,
3036          !strconcat(asm, "${p}\t$Rn!, $regs", sfx), "$Rn = $wb", []> {
3037     let Inst{24-23} = 0b01;       // Increment After
3038     let Inst{22}    = P_bit;
3039     let Inst{21}    = 1;          // Writeback
3040     let Inst{20}    = L_bit;
3041
3042     let DecoderMethod = "DecodeMemMultipleWritebackInstruction";
3043   }
3044   def DA :
3045     AXI4<(outs), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
3046          IndexModeNone, f, itin,
3047          !strconcat(asm, "da${p}\t$Rn, $regs", sfx), "", []> {
3048     let Inst{24-23} = 0b00;       // Decrement After
3049     let Inst{22}    = P_bit;
3050     let Inst{21}    = 0;          // No writeback
3051     let Inst{20}    = L_bit;
3052   }
3053   def DA_UPD :
3054     AXI4<(outs GPR:$wb), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
3055          IndexModeUpd, f, itin_upd,
3056          !strconcat(asm, "da${p}\t$Rn!, $regs", sfx), "$Rn = $wb", []> {
3057     let Inst{24-23} = 0b00;       // Decrement After
3058     let Inst{22}    = P_bit;
3059     let Inst{21}    = 1;          // Writeback
3060     let Inst{20}    = L_bit;
3061
3062     let DecoderMethod = "DecodeMemMultipleWritebackInstruction";
3063   }
3064   def DB :
3065     AXI4<(outs), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
3066          IndexModeNone, f, itin,
3067          !strconcat(asm, "db${p}\t$Rn, $regs", sfx), "", []> {
3068     let Inst{24-23} = 0b10;       // Decrement Before
3069     let Inst{22}    = P_bit;
3070     let Inst{21}    = 0;          // No writeback
3071     let Inst{20}    = L_bit;
3072   }
3073   def DB_UPD :
3074     AXI4<(outs GPR:$wb), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
3075          IndexModeUpd, f, itin_upd,
3076          !strconcat(asm, "db${p}\t$Rn!, $regs", sfx), "$Rn = $wb", []> {
3077     let Inst{24-23} = 0b10;       // Decrement Before
3078     let Inst{22}    = P_bit;
3079     let Inst{21}    = 1;          // Writeback
3080     let Inst{20}    = L_bit;
3081
3082     let DecoderMethod = "DecodeMemMultipleWritebackInstruction";
3083   }
3084   def IB :
3085     AXI4<(outs), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
3086          IndexModeNone, f, itin,
3087          !strconcat(asm, "ib${p}\t$Rn, $regs", sfx), "", []> {
3088     let Inst{24-23} = 0b11;       // Increment Before
3089     let Inst{22}    = P_bit;
3090     let Inst{21}    = 0;          // No writeback
3091     let Inst{20}    = L_bit;
3092   }
3093   def IB_UPD :
3094     AXI4<(outs GPR:$wb), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
3095          IndexModeUpd, f, itin_upd,
3096          !strconcat(asm, "ib${p}\t$Rn!, $regs", sfx), "$Rn = $wb", []> {
3097     let Inst{24-23} = 0b11;       // Increment Before
3098     let Inst{22}    = P_bit;
3099     let Inst{21}    = 1;          // Writeback
3100     let Inst{20}    = L_bit;
3101
3102     let DecoderMethod = "DecodeMemMultipleWritebackInstruction";
3103   }
3104 }
3105
3106 let hasSideEffects = 0 in {
3107
3108 let mayLoad = 1, hasExtraDefRegAllocReq = 1 in
3109 defm LDM : arm_ldst_mult<"ldm", "", 1, 0, LdStMulFrm, IIC_iLoad_m,
3110                          IIC_iLoad_mu>;
3111
3112 let mayStore = 1, hasExtraSrcRegAllocReq = 1 in
3113 defm STM : arm_ldst_mult<"stm", "", 0, 0, LdStMulFrm, IIC_iStore_m,
3114                          IIC_iStore_mu>;
3115
3116 } // hasSideEffects
3117
3118 // FIXME: remove when we have a way to marking a MI with these properties.
3119 // FIXME: Should pc be an implicit operand like PICADD, etc?
3120 let isReturn = 1, isTerminator = 1, isBarrier = 1, mayLoad = 1,
3121     hasExtraDefRegAllocReq = 1, isCodeGenOnly = 1 in
3122 def LDMIA_RET : ARMPseudoExpand<(outs GPR:$wb), (ins GPR:$Rn, pred:$p,
3123                                                  reglist:$regs, variable_ops),
3124                      4, IIC_iLoad_mBr, [],
3125                      (LDMIA_UPD GPR:$wb, GPR:$Rn, pred:$p, reglist:$regs)>,
3126       RegConstraint<"$Rn = $wb">;
3127
3128 let mayLoad = 1, hasExtraDefRegAllocReq = 1 in
3129 defm sysLDM : arm_ldst_mult<"ldm", " ^", 1, 1, LdStMulFrm, IIC_iLoad_m,
3130                                IIC_iLoad_mu>;
3131
3132 let mayStore = 1, hasExtraSrcRegAllocReq = 1 in
3133 defm sysSTM : arm_ldst_mult<"stm", " ^", 0, 1, LdStMulFrm, IIC_iStore_m,
3134                                IIC_iStore_mu>;
3135
3136
3137
3138 //===----------------------------------------------------------------------===//
3139 //  Move Instructions.
3140 //
3141
3142 let hasSideEffects = 0 in
3143 def MOVr : AsI1<0b1101, (outs GPR:$Rd), (ins GPR:$Rm), DPFrm, IIC_iMOVr,
3144                 "mov", "\t$Rd, $Rm", []>, UnaryDP, Sched<[WriteALU]> {
3145   bits<4> Rd;
3146   bits<4> Rm;
3147
3148   let Inst{19-16} = 0b0000;
3149   let Inst{11-4} = 0b00000000;
3150   let Inst{25} = 0;
3151   let Inst{3-0} = Rm;
3152   let Inst{15-12} = Rd;
3153 }
3154
3155 // A version for the smaller set of tail call registers.
3156 let hasSideEffects = 0 in
3157 def MOVr_TC : AsI1<0b1101, (outs tcGPR:$Rd), (ins tcGPR:$Rm), DPFrm,
3158                 IIC_iMOVr, "mov", "\t$Rd, $Rm", []>, UnaryDP, Sched<[WriteALU]> {
3159   bits<4> Rd;
3160   bits<4> Rm;
3161
3162   let Inst{11-4} = 0b00000000;
3163   let Inst{25} = 0;
3164   let Inst{3-0} = Rm;
3165   let Inst{15-12} = Rd;
3166 }
3167
3168 def MOVsr : AsI1<0b1101, (outs GPRnopc:$Rd), (ins shift_so_reg_reg:$src),
3169                 DPSoRegRegFrm, IIC_iMOVsr,
3170                 "mov", "\t$Rd, $src",
3171                 [(set GPRnopc:$Rd, shift_so_reg_reg:$src)]>, UnaryDP,
3172                 Sched<[WriteALU]> {
3173   bits<4> Rd;
3174   bits<12> src;
3175   let Inst{15-12} = Rd;
3176   let Inst{19-16} = 0b0000;
3177   let Inst{11-8} = src{11-8};
3178   let Inst{7} = 0;
3179   let Inst{6-5} = src{6-5};
3180   let Inst{4} = 1;
3181   let Inst{3-0} = src{3-0};
3182   let Inst{25} = 0;
3183 }
3184
3185 def MOVsi : AsI1<0b1101, (outs GPR:$Rd), (ins shift_so_reg_imm:$src),
3186                 DPSoRegImmFrm, IIC_iMOVsr,
3187                 "mov", "\t$Rd, $src", [(set GPR:$Rd, shift_so_reg_imm:$src)]>,
3188                 UnaryDP, Sched<[WriteALU]> {
3189   bits<4> Rd;
3190   bits<12> src;
3191   let Inst{15-12} = Rd;
3192   let Inst{19-16} = 0b0000;
3193   let Inst{11-5} = src{11-5};
3194   let Inst{4} = 0;
3195   let Inst{3-0} = src{3-0};
3196   let Inst{25} = 0;
3197 }
3198
3199 let isReMaterializable = 1, isAsCheapAsAMove = 1, isMoveImm = 1 in
3200 def MOVi : AsI1<0b1101, (outs GPR:$Rd), (ins so_imm:$imm), DPFrm, IIC_iMOVi,
3201                 "mov", "\t$Rd, $imm", [(set GPR:$Rd, so_imm:$imm)]>, UnaryDP,
3202                 Sched<[WriteALU]> {
3203   bits<4> Rd;
3204   bits<12> imm;
3205   let Inst{25} = 1;
3206   let Inst{15-12} = Rd;
3207   let Inst{19-16} = 0b0000;
3208   let Inst{11-0} = imm;
3209 }
3210
3211 let isReMaterializable = 1, isAsCheapAsAMove = 1, isMoveImm = 1 in
3212 def MOVi16 : AI1<0b1000, (outs GPR:$Rd), (ins imm0_65535_expr:$imm),
3213                  DPFrm, IIC_iMOVi,
3214                  "movw", "\t$Rd, $imm",
3215                  [(set GPR:$Rd, imm0_65535:$imm)]>,
3216                  Requires<[IsARM, HasV6T2]>, UnaryDP, Sched<[WriteALU]> {
3217   bits<4> Rd;
3218   bits<16> imm;
3219   let Inst{15-12} = Rd;
3220   let Inst{11-0}  = imm{11-0};
3221   let Inst{19-16} = imm{15-12};
3222   let Inst{20} = 0;
3223   let Inst{25} = 1;
3224   let DecoderMethod = "DecodeArmMOVTWInstruction";
3225 }
3226
3227 def : InstAlias<"mov${p} $Rd, $imm",
3228                 (MOVi16 GPR:$Rd, imm0_65535_expr:$imm, pred:$p)>,
3229         Requires<[IsARM]>;
3230
3231 def MOVi16_ga_pcrel : PseudoInst<(outs GPR:$Rd),
3232                                 (ins i32imm:$addr, pclabel:$id), IIC_iMOVi, []>,
3233                       Sched<[WriteALU]>;
3234
3235 let Constraints = "$src = $Rd" in {
3236 def MOVTi16 : AI1<0b1010, (outs GPRnopc:$Rd),
3237                   (ins GPR:$src, imm0_65535_expr:$imm),
3238                   DPFrm, IIC_iMOVi,
3239                   "movt", "\t$Rd, $imm",
3240                   [(set GPRnopc:$Rd,
3241                         (or (and GPR:$src, 0xffff),
3242                             lo16AllZero:$imm))]>, UnaryDP,
3243                   Requires<[IsARM, HasV6T2]>, Sched<[WriteALU]> {
3244   bits<4> Rd;
3245   bits<16> imm;
3246   let Inst{15-12} = Rd;
3247   let Inst{11-0}  = imm{11-0};
3248   let Inst{19-16} = imm{15-12};
3249   let Inst{20} = 0;
3250   let Inst{25} = 1;
3251   let DecoderMethod = "DecodeArmMOVTWInstruction";
3252 }
3253
3254 def MOVTi16_ga_pcrel : PseudoInst<(outs GPR:$Rd),
3255                       (ins GPR:$src, i32imm:$addr, pclabel:$id), IIC_iMOVi, []>,
3256                       Sched<[WriteALU]>;
3257
3258 } // Constraints
3259
3260 def : ARMPat<(or GPR:$src, 0xffff0000), (MOVTi16 GPR:$src, 0xffff)>,
3261       Requires<[IsARM, HasV6T2]>;
3262
3263 let Uses = [CPSR] in
3264 def RRX: PseudoInst<(outs GPR:$Rd), (ins GPR:$Rm), IIC_iMOVsi,
3265                     [(set GPR:$Rd, (ARMrrx GPR:$Rm))]>, UnaryDP,
3266                     Requires<[IsARM]>, Sched<[WriteALU]>;
3267
3268 // These aren't really mov instructions, but we have to define them this way
3269 // due to flag operands.
3270
3271 let Defs = [CPSR] in {
3272 def MOVsrl_flag : PseudoInst<(outs GPR:$dst), (ins GPR:$src), IIC_iMOVsi,
3273                       [(set GPR:$dst, (ARMsrl_flag GPR:$src))]>, UnaryDP,
3274                       Sched<[WriteALU]>, Requires<[IsARM]>;
3275 def MOVsra_flag : PseudoInst<(outs GPR:$dst), (ins GPR:$src), IIC_iMOVsi,
3276                       [(set GPR:$dst, (ARMsra_flag GPR:$src))]>, UnaryDP,
3277                       Sched<[WriteALU]>, Requires<[IsARM]>;
3278 }
3279
3280 //===----------------------------------------------------------------------===//
3281 //  Extend Instructions.
3282 //
3283
3284 // Sign extenders
3285
3286 def SXTB  : AI_ext_rrot<0b01101010,
3287                          "sxtb", UnOpFrag<(sext_inreg node:$Src, i8)>>;
3288 def SXTH  : AI_ext_rrot<0b01101011,
3289                          "sxth", UnOpFrag<(sext_inreg node:$Src, i16)>>;
3290
3291 def SXTAB : AI_exta_rrot<0b01101010,
3292                "sxtab", BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS, i8))>>;
3293 def SXTAH : AI_exta_rrot<0b01101011,
3294                "sxtah", BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS,i16))>>;
3295
3296 def SXTB16  : AI_ext_rrot_np<0b01101000, "sxtb16">;
3297
3298 def SXTAB16 : AI_exta_rrot_np<0b01101000, "sxtab16">;
3299
3300 // Zero extenders
3301
3302 let AddedComplexity = 16 in {
3303 def UXTB   : AI_ext_rrot<0b01101110,
3304                           "uxtb"  , UnOpFrag<(and node:$Src, 0x000000FF)>>;
3305 def UXTH   : AI_ext_rrot<0b01101111,
3306                           "uxth"  , UnOpFrag<(and node:$Src, 0x0000FFFF)>>;
3307 def UXTB16 : AI_ext_rrot<0b01101100,
3308                           "uxtb16", UnOpFrag<(and node:$Src, 0x00FF00FF)>>;
3309
3310 // FIXME: This pattern incorrectly assumes the shl operator is a rotate.
3311 //        The transformation should probably be done as a combiner action
3312 //        instead so we can include a check for masking back in the upper
3313 //        eight bits of the source into the lower eight bits of the result.
3314 //def : ARMV6Pat<(and (shl GPR:$Src, (i32 8)), 0xFF00FF),
3315 //               (UXTB16r_rot GPR:$Src, 3)>;
3316 def : ARMV6Pat<(and (srl GPR:$Src, (i32 8)), 0xFF00FF),
3317                (UXTB16 GPR:$Src, 1)>;
3318
3319 def UXTAB : AI_exta_rrot<0b01101110, "uxtab",
3320                         BinOpFrag<(add node:$LHS, (and node:$RHS, 0x00FF))>>;
3321 def UXTAH : AI_exta_rrot<0b01101111, "uxtah",
3322                         BinOpFrag<(add node:$LHS, (and node:$RHS, 0xFFFF))>>;
3323 }
3324
3325 // This isn't safe in general, the add is two 16-bit units, not a 32-bit add.
3326 def UXTAB16 : AI_exta_rrot_np<0b01101100, "uxtab16">;
3327
3328
3329 def SBFX  : I<(outs GPRnopc:$Rd),
3330               (ins GPRnopc:$Rn, imm0_31:$lsb, imm1_32:$width),
3331                AddrMode1, 4, IndexModeNone, DPFrm, IIC_iUNAsi,
3332                "sbfx", "\t$Rd, $Rn, $lsb, $width", "", []>,
3333                Requires<[IsARM, HasV6T2]> {
3334   bits<4> Rd;
3335   bits<4> Rn;
3336   bits<5> lsb;
3337   bits<5> width;
3338   let Inst{27-21} = 0b0111101;
3339   let Inst{6-4}   = 0b101;
3340   let Inst{20-16} = width;
3341   let Inst{15-12} = Rd;
3342   let Inst{11-7}  = lsb;
3343   let Inst{3-0}   = Rn;
3344 }
3345
3346 def UBFX  : I<(outs GPRnopc:$Rd),
3347               (ins GPRnopc:$Rn, imm0_31:$lsb, imm1_32:$width),
3348                AddrMode1, 4, IndexModeNone, DPFrm, IIC_iUNAsi,
3349                "ubfx", "\t$Rd, $Rn, $lsb, $width", "", []>,
3350                Requires<[IsARM, HasV6T2]> {
3351   bits<4> Rd;
3352   bits<4> Rn;
3353   bits<5> lsb;
3354   bits<5> width;
3355   let Inst{27-21} = 0b0111111;
3356   let Inst{6-4}   = 0b101;
3357   let Inst{20-16} = width;
3358   let Inst{15-12} = Rd;
3359   let Inst{11-7}  = lsb;
3360   let Inst{3-0}   = Rn;
3361 }
3362
3363 //===----------------------------------------------------------------------===//
3364 //  Arithmetic Instructions.
3365 //
3366
3367 defm ADD  : AsI1_bin_irs<0b0100, "add",
3368                          IIC_iALUi, IIC_iALUr, IIC_iALUsr,
3369                          BinOpFrag<(add  node:$LHS, node:$RHS)>, 1>;
3370 defm SUB  : AsI1_bin_irs<0b0010, "sub",
3371                          IIC_iALUi, IIC_iALUr, IIC_iALUsr,
3372                          BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
3373
3374 // ADD and SUB with 's' bit set.
3375 //
3376 // Currently, ADDS/SUBS are pseudo opcodes that exist only in the
3377 // selection DAG. They are "lowered" to real ADD/SUB opcodes by
3378 // AdjustInstrPostInstrSelection where we determine whether or not to
3379 // set the "s" bit based on CPSR liveness.
3380 //
3381 // FIXME: Eliminate ADDS/SUBS pseudo opcodes after adding tablegen
3382 // support for an optional CPSR definition that corresponds to the DAG
3383 // node's second value. We can then eliminate the implicit def of CPSR.
3384 defm ADDS : AsI1_bin_s_irs<IIC_iALUi, IIC_iALUr, IIC_iALUsr,
3385                            BinOpFrag<(ARMaddc node:$LHS, node:$RHS)>, 1>;
3386 defm SUBS : AsI1_bin_s_irs<IIC_iALUi, IIC_iALUr, IIC_iALUsr,
3387                            BinOpFrag<(ARMsubc node:$LHS, node:$RHS)>>;
3388
3389 defm ADC : AI1_adde_sube_irs<0b0101, "adc",
3390               BinOpWithFlagFrag<(ARMadde node:$LHS, node:$RHS, node:$FLAG)>, 1>;
3391 defm SBC : AI1_adde_sube_irs<0b0110, "sbc",
3392               BinOpWithFlagFrag<(ARMsube node:$LHS, node:$RHS, node:$FLAG)>>;
3393
3394 defm RSB  : AsI1_rbin_irs<0b0011, "rsb",
3395                           IIC_iALUi, IIC_iALUr, IIC_iALUsr,
3396                           BinOpFrag<(sub node:$LHS, node:$RHS)>>;
3397
3398 // FIXME: Eliminate them if we can write def : Pat patterns which defines
3399 // CPSR and the implicit def of CPSR is not needed.
3400 defm RSBS : AsI1_rbin_s_is<IIC_iALUi, IIC_iALUr, IIC_iALUsr,
3401                            BinOpFrag<(ARMsubc node:$LHS, node:$RHS)>>;
3402
3403 defm RSC : AI1_rsc_irs<0b0111, "rsc",
3404                 BinOpWithFlagFrag<(ARMsube node:$LHS, node:$RHS, node:$FLAG)>>;
3405
3406 // (sub X, imm) gets canonicalized to (add X, -imm).  Match this form.
3407 // The assume-no-carry-in form uses the negation of the input since add/sub
3408 // assume opposite meanings of the carry flag (i.e., carry == !borrow).
3409 // See the definition of AddWithCarry() in the ARM ARM A2.2.1 for the gory
3410 // details.
3411 def : ARMPat<(add     GPR:$src, so_imm_neg:$imm),
3412              (SUBri   GPR:$src, so_imm_neg:$imm)>;
3413 def : ARMPat<(ARMaddc GPR:$src, so_imm_neg:$imm),
3414              (SUBSri  GPR:$src, so_imm_neg:$imm)>;
3415
3416 def : ARMPat<(add     GPR:$src, imm0_65535_neg:$imm),
3417              (SUBrr   GPR:$src, (MOVi16 (imm_neg_XFORM imm:$imm)))>,
3418              Requires<[IsARM, HasV6T2]>;
3419 def : ARMPat<(ARMaddc GPR:$src, imm0_65535_neg:$imm),
3420              (SUBSrr  GPR:$src, (MOVi16 (imm_neg_XFORM imm:$imm)))>,
3421              Requires<[IsARM, HasV6T2]>;
3422
3423 // The with-carry-in form matches bitwise not instead of the negation.
3424 // Effectively, the inverse interpretation of the carry flag already accounts
3425 // for part of the negation.
3426 def : ARMPat<(ARMadde GPR:$src, so_imm_not:$imm, CPSR),
3427              (SBCri   GPR:$src, so_imm_not:$imm)>;
3428 def : ARMPat<(ARMadde GPR:$src, imm0_65535_neg:$imm, CPSR),
3429              (SBCrr   GPR:$src, (MOVi16 (imm_not_XFORM imm:$imm)))>,
3430              Requires<[IsARM, HasV6T2]>;
3431
3432 // Note: These are implemented in C++ code, because they have to generate
3433 // ADD/SUBrs instructions, which use a complex pattern that a xform function
3434 // cannot produce.
3435 // (mul X, 2^n+1) -> (add (X << n), X)
3436 // (mul X, 2^n-1) -> (rsb X, (X << n))
3437
3438 // ARM Arithmetic Instruction
3439 // GPR:$dst = GPR:$a op GPR:$b
3440 class AAI<bits<8> op27_20, bits<8> op11_4, string opc,
3441           list<dag> pattern = [],
3442           dag iops = (ins GPRnopc:$Rn, GPRnopc:$Rm),
3443           string asm = "\t$Rd, $Rn, $Rm">
3444   : AI<(outs GPRnopc:$Rd), iops, DPFrm, IIC_iALUr, opc, asm, pattern>,
3445     Sched<[WriteALU, ReadALU, ReadALU]> {
3446   bits<4> Rn;
3447   bits<4> Rd;
3448   bits<4> Rm;
3449   let Inst{27-20} = op27_20;
3450   let Inst{11-4} = op11_4;
3451   let Inst{19-16} = Rn;
3452   let Inst{15-12} = Rd;
3453   let Inst{3-0}   = Rm;
3454
3455   let Unpredictable{11-8} = 0b1111;
3456 }
3457
3458 // Saturating add/subtract
3459
3460 let DecoderMethod = "DecodeQADDInstruction" in
3461 def QADD    : AAI<0b00010000, 0b00000101, "qadd",
3462                   [(set GPRnopc:$Rd, (int_arm_qadd GPRnopc:$Rm, GPRnopc:$Rn))],
3463                   (ins GPRnopc:$Rm, GPRnopc:$Rn), "\t$Rd, $Rm, $Rn">;
3464
3465 def QSUB    : AAI<0b00010010, 0b00000101, "qsub",
3466                   [(set GPRnopc:$Rd, (int_arm_qsub GPRnopc:$Rm, GPRnopc:$Rn))],
3467                   (ins GPRnopc:$Rm, GPRnopc:$Rn), "\t$Rd, $Rm, $Rn">;
3468 def QDADD   : AAI<0b00010100, 0b00000101, "qdadd", [],
3469                   (ins GPRnopc:$Rm, GPRnopc:$Rn),
3470                   "\t$Rd, $Rm, $Rn">;
3471 def QDSUB   : AAI<0b00010110, 0b00000101, "qdsub", [],
3472                   (ins GPRnopc:$Rm, GPRnopc:$Rn),
3473                   "\t$Rd, $Rm, $Rn">;
3474
3475 def QADD16  : AAI<0b01100010, 0b11110001, "qadd16">;
3476 def QADD8   : AAI<0b01100010, 0b11111001, "qadd8">;
3477 def QASX    : AAI<0b01100010, 0b11110011, "qasx">;
3478 def QSAX    : AAI<0b01100010, 0b11110101, "qsax">;
3479 def QSUB16  : AAI<0b01100010, 0b11110111, "qsub16">;
3480 def QSUB8   : AAI<0b01100010, 0b11111111, "qsub8">;
3481 def UQADD16 : AAI<0b01100110, 0b11110001, "uqadd16">;
3482 def UQADD8  : AAI<0b01100110, 0b11111001, "uqadd8">;
3483 def UQASX   : AAI<0b01100110, 0b11110011, "uqasx">;
3484 def UQSAX   : AAI<0b01100110, 0b11110101, "uqsax">;
3485 def UQSUB16 : AAI<0b01100110, 0b11110111, "uqsub16">;
3486 def UQSUB8  : AAI<0b01100110, 0b11111111, "uqsub8">;
3487
3488 // Signed/Unsigned add/subtract
3489
3490 def SASX   : AAI<0b01100001, 0b11110011, "sasx">;
3491 def SADD16 : AAI<0b01100001, 0b11110001, "sadd16">;
3492 def SADD8  : AAI<0b01100001, 0b11111001, "sadd8">;
3493 def SSAX   : AAI<0b01100001, 0b11110101, "ssax">;
3494 def SSUB16 : AAI<0b01100001, 0b11110111, "ssub16">;
3495 def SSUB8  : AAI<0b01100001, 0b11111111, "ssub8">;
3496 def UASX   : AAI<0b01100101, 0b11110011, "uasx">;
3497 def UADD16 : AAI<0b01100101, 0b11110001, "uadd16">;
3498 def UADD8  : AAI<0b01100101, 0b11111001, "uadd8">;
3499 def USAX   : AAI<0b01100101, 0b11110101, "usax">;
3500 def USUB16 : AAI<0b01100101, 0b11110111, "usub16">;
3501 def USUB8  : AAI<0b01100101, 0b11111111, "usub8">;
3502
3503 // Signed/Unsigned halving add/subtract
3504
3505 def SHASX   : AAI<0b01100011, 0b11110011, "shasx">;
3506 def SHADD16 : AAI<0b01100011, 0b11110001, "shadd16">;
3507 def SHADD8  : AAI<0b01100011, 0b11111001, "shadd8">;
3508 def SHSAX   : AAI<0b01100011, 0b11110101, "shsax">;
3509 def SHSUB16 : AAI<0b01100011, 0b11110111, "shsub16">;
3510 def SHSUB8  : AAI<0b01100011, 0b11111111, "shsub8">;
3511 def UHASX   : AAI<0b01100111, 0b11110011, "uhasx">;
3512 def UHADD16 : AAI<0b01100111, 0b11110001, "uhadd16">;
3513 def UHADD8  : AAI<0b01100111, 0b11111001, "uhadd8">;
3514 def UHSAX   : AAI<0b01100111, 0b11110101, "uhsax">;
3515 def UHSUB16 : AAI<0b01100111, 0b11110111, "uhsub16">;
3516 def UHSUB8  : AAI<0b01100111, 0b11111111, "uhsub8">;
3517
3518 // Unsigned Sum of Absolute Differences [and Accumulate].
3519
3520 def USAD8  : AI<(outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
3521                 MulFrm /* for convenience */, NoItinerary, "usad8",
3522                 "\t$Rd, $Rn, $Rm", []>,
3523              Requires<[IsARM, HasV6]>, Sched<[WriteALU, ReadALU, ReadALU]> {
3524   bits<4> Rd;
3525   bits<4> Rn;
3526   bits<4> Rm;
3527   let Inst{27-20} = 0b01111000;
3528   let Inst{15-12} = 0b1111;
3529   let Inst{7-4} = 0b0001;
3530   let Inst{19-16} = Rd;
3531   let Inst{11-8} = Rm;
3532   let Inst{3-0} = Rn;
3533 }
3534 def USADA8 : AI<(outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm, GPR:$Ra),
3535                 MulFrm /* for convenience */, NoItinerary, "usada8",
3536                 "\t$Rd, $Rn, $Rm, $Ra", []>,
3537              Requires<[IsARM, HasV6]>, Sched<[WriteALU, ReadALU, ReadALU]>{
3538   bits<4> Rd;
3539   bits<4> Rn;
3540   bits<4> Rm;
3541   bits<4> Ra;
3542   let Inst{27-20} = 0b01111000;
3543   let Inst{7-4} = 0b0001;
3544   let Inst{19-16} = Rd;
3545   let Inst{15-12} = Ra;
3546   let Inst{11-8} = Rm;
3547   let Inst{3-0} = Rn;
3548 }
3549
3550 // Signed/Unsigned saturate
3551
3552 def SSAT : AI<(outs GPRnopc:$Rd),
3553               (ins imm1_32:$sat_imm, GPRnopc:$Rn, shift_imm:$sh),
3554               SatFrm, NoItinerary, "ssat", "\t$Rd, $sat_imm, $Rn$sh", []> {
3555   bits<4> Rd;
3556   bits<5> sat_imm;
3557   bits<4> Rn;
3558   bits<8> sh;
3559   let Inst{27-21} = 0b0110101;
3560   let Inst{5-4} = 0b01;
3561   let Inst{20-16} = sat_imm;
3562   let Inst{15-12} = Rd;
3563   let Inst{11-7} = sh{4-0};
3564   let Inst{6} = sh{5};
3565   let Inst{3-0} = Rn;
3566 }
3567
3568 def SSAT16 : AI<(outs GPRnopc:$Rd),
3569                 (ins imm1_16:$sat_imm, GPRnopc:$Rn), SatFrm,
3570                 NoItinerary, "ssat16", "\t$Rd, $sat_imm, $Rn", []> {
3571   bits<4> Rd;
3572   bits<4> sat_imm;
3573   bits<4> Rn;
3574   let Inst{27-20} = 0b01101010;
3575   let Inst{11-4} = 0b11110011;
3576   let Inst{15-12} = Rd;
3577   let Inst{19-16} = sat_imm;
3578   let Inst{3-0} = Rn;
3579 }
3580
3581 def USAT : AI<(outs GPRnopc:$Rd),
3582               (ins imm0_31:$sat_imm, GPRnopc:$Rn, shift_imm:$sh),
3583               SatFrm, NoItinerary, "usat", "\t$Rd, $sat_imm, $Rn$sh", []> {
3584   bits<4> Rd;
3585   bits<5> sat_imm;
3586   bits<4> Rn;
3587   bits<8> sh;
3588   let Inst{27-21} = 0b0110111;
3589   let Inst{5-4} = 0b01;
3590   let Inst{15-12} = Rd;
3591   let Inst{11-7} = sh{4-0};
3592   let Inst{6} = sh{5};
3593   let Inst{20-16} = sat_imm;
3594   let Inst{3-0} = Rn;
3595 }
3596
3597 def USAT16 : AI<(outs GPRnopc:$Rd),
3598                 (ins imm0_15:$sat_imm, GPRnopc:$Rn), SatFrm,
3599                 NoItinerary, "usat16", "\t$Rd, $sat_imm, $Rn", []> {
3600   bits<4> Rd;
3601   bits<4> sat_imm;
3602   bits<4> Rn;
3603   let Inst{27-20} = 0b01101110;
3604   let Inst{11-4} = 0b11110011;
3605   let Inst{15-12} = Rd;
3606   let Inst{19-16} = sat_imm;
3607   let Inst{3-0} = Rn;
3608 }
3609
3610 def : ARMV6Pat<(int_arm_ssat GPRnopc:$a, imm:$pos),
3611                (SSAT imm:$pos, GPRnopc:$a, 0)>;
3612 def : ARMV6Pat<(int_arm_usat GPRnopc:$a, imm:$pos),
3613                (USAT imm:$pos, GPRnopc:$a, 0)>;
3614
3615 //===----------------------------------------------------------------------===//
3616 //  Bitwise Instructions.
3617 //
3618
3619 defm AND   : AsI1_bin_irs<0b0000, "and",
3620                           IIC_iBITi, IIC_iBITr, IIC_iBITsr,
3621                           BinOpFrag<(and node:$LHS, node:$RHS)>, 1>;
3622 defm ORR   : AsI1_bin_irs<0b1100, "orr",
3623                           IIC_iBITi, IIC_iBITr, IIC_iBITsr,
3624                           BinOpFrag<(or  node:$LHS, node:$RHS)>, 1>;
3625 defm EOR   : AsI1_bin_irs<0b0001, "eor",
3626                           IIC_iBITi, IIC_iBITr, IIC_iBITsr,
3627                           BinOpFrag<(xor node:$LHS, node:$RHS)>, 1>;
3628 defm BIC   : AsI1_bin_irs<0b1110, "bic",
3629                           IIC_iBITi, IIC_iBITr, IIC_iBITsr,
3630                           BinOpFrag<(and node:$LHS, (not node:$RHS))>>;
3631
3632 // FIXME: bf_inv_mask_imm should be two operands, the lsb and the msb, just
3633 // like in the actual instruction encoding. The complexity of mapping the mask
3634 // to the lsb/msb pair should be handled by ISel, not encapsulated in the
3635 // instruction description.
3636 def BFC    : I<(outs GPR:$Rd), (ins GPR:$src, bf_inv_mask_imm:$imm),
3637                AddrMode1, 4, IndexModeNone, DPFrm, IIC_iUNAsi,
3638                "bfc", "\t$Rd, $imm", "$src = $Rd",
3639                [(set GPR:$Rd, (and GPR:$src, bf_inv_mask_imm:$imm))]>,
3640                Requires<[IsARM, HasV6T2]> {
3641   bits<4> Rd;
3642   bits<10> imm;
3643   let Inst{27-21} = 0b0111110;
3644   let Inst{6-0}   = 0b0011111;
3645   let Inst{15-12} = Rd;
3646   let Inst{11-7}  = imm{4-0}; // lsb
3647   let Inst{20-16} = imm{9-5}; // msb
3648 }
3649
3650 // A8.6.18  BFI - Bitfield insert (Encoding A1)
3651 def BFI:I<(outs GPRnopc:$Rd), (ins GPRnopc:$src, GPR:$Rn, bf_inv_mask_imm:$imm),
3652           AddrMode1, 4, IndexModeNone, DPFrm, IIC_iUNAsi,
3653           "bfi", "\t$Rd, $Rn, $imm", "$src = $Rd",
3654           [(set GPRnopc:$Rd, (ARMbfi GPRnopc:$src, GPR:$Rn,
3655                            bf_inv_mask_imm:$imm))]>,
3656           Requires<[IsARM, HasV6T2]> {
3657   bits<4> Rd;
3658   bits<4> Rn;
3659   bits<10> imm;
3660   let Inst{27-21} = 0b0111110;
3661   let Inst{6-4}   = 0b001; // Rn: Inst{3-0} != 15
3662   let Inst{15-12} = Rd;
3663   let Inst{11-7}  = imm{4-0}; // lsb
3664   let Inst{20-16} = imm{9-5}; // width
3665   let Inst{3-0}   = Rn;
3666 }
3667
3668 def  MVNr  : AsI1<0b1111, (outs GPR:$Rd), (ins GPR:$Rm), DPFrm, IIC_iMVNr,
3669                   "mvn", "\t$Rd, $Rm",
3670                   [(set GPR:$Rd, (not GPR:$Rm))]>, UnaryDP, Sched<[WriteALU]> {
3671   bits<4> Rd;
3672   bits<4> Rm;
3673   let Inst{25} = 0;
3674   let Inst{19-16} = 0b0000;
3675   let Inst{11-4} = 0b00000000;
3676   let Inst{15-12} = Rd;
3677   let Inst{3-0} = Rm;
3678 }
3679 def  MVNsi  : AsI1<0b1111, (outs GPR:$Rd), (ins so_reg_imm:$shift),
3680                   DPSoRegImmFrm, IIC_iMVNsr, "mvn", "\t$Rd, $shift",
3681                   [(set GPR:$Rd, (not so_reg_imm:$shift))]>, UnaryDP,
3682                   Sched<[WriteALU]> {
3683   bits<4> Rd;
3684   bits<12> shift;
3685   let Inst{25} = 0;
3686   let Inst{19-16} = 0b0000;
3687   let Inst{15-12} = Rd;
3688   let Inst{11-5} = shift{11-5};
3689   let Inst{4} = 0;
3690   let Inst{3-0} = shift{3-0};
3691 }
3692 def  MVNsr  : AsI1<0b1111, (outs GPR:$Rd), (ins so_reg_reg:$shift),
3693                   DPSoRegRegFrm, IIC_iMVNsr, "mvn", "\t$Rd, $shift",
3694                   [(set GPR:$Rd, (not so_reg_reg:$shift))]>, UnaryDP,
3695                   Sched<[WriteALU]> {
3696   bits<4> Rd;
3697   bits<12> shift;
3698   let Inst{25} = 0;
3699   let Inst{19-16} = 0b0000;
3700   let Inst{15-12} = Rd;
3701   let Inst{11-8} = shift{11-8};
3702   let Inst{7} = 0;
3703   let Inst{6-5} = shift{6-5};
3704   let Inst{4} = 1;
3705   let Inst{3-0} = shift{3-0};
3706 }
3707 let isReMaterializable = 1, isAsCheapAsAMove = 1, isMoveImm = 1 in
3708 def  MVNi  : AsI1<0b1111, (outs GPR:$Rd), (ins so_imm:$imm), DPFrm,
3709                   IIC_iMVNi, "mvn", "\t$Rd, $imm",
3710                   [(set GPR:$Rd, so_imm_not:$imm)]>,UnaryDP, Sched<[WriteALU]> {
3711   bits<4> Rd;
3712   bits<12> imm;
3713   let Inst{25} = 1;
3714   let Inst{19-16} = 0b0000;
3715   let Inst{15-12} = Rd;
3716   let Inst{11-0} = imm;
3717 }
3718
3719 def : ARMPat<(and   GPR:$src, so_imm_not:$imm),
3720              (BICri GPR:$src, so_imm_not:$imm)>;
3721
3722 //===----------------------------------------------------------------------===//
3723 //  Multiply Instructions.
3724 //
3725 class AsMul1I32<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
3726              string opc, string asm, list<dag> pattern>
3727   : AsMul1I<opcod, oops, iops, itin, opc, asm, pattern> {
3728   bits<4> Rd;
3729   bits<4> Rm;
3730   bits<4> Rn;
3731   let Inst{19-16} = Rd;
3732   let Inst{11-8}  = Rm;
3733   let Inst{3-0}   = Rn;
3734 }
3735 class AsMul1I64<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
3736              string opc, string asm, list<dag> pattern>
3737   : AsMul1I<opcod, oops, iops, itin, opc, asm, pattern> {
3738   bits<4> RdLo;
3739   bits<4> RdHi;
3740   bits<4> Rm;
3741   bits<4> Rn;
3742   let Inst{19-16} = RdHi;
3743   let Inst{15-12} = RdLo;
3744   let Inst{11-8}  = Rm;
3745   let Inst{3-0}   = Rn;
3746 }
3747 class AsMla1I64<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
3748              string opc, string asm, list<dag> pattern>
3749   : AsMul1I<opcod, oops, iops, itin, opc, asm, pattern> {
3750   bits<4> RdLo;
3751   bits<4> RdHi;
3752   bits<4> Rm;
3753   bits<4> Rn;
3754   let Inst{19-16} = RdHi;
3755   let Inst{15-12} = RdLo;
3756   let Inst{11-8}  = Rm;
3757   let Inst{3-0}   = Rn;
3758 }
3759
3760 // FIXME: The v5 pseudos are only necessary for the additional Constraint
3761 //        property. Remove them when it's possible to add those properties
3762 //        on an individual MachineInstr, not just an instruction description.
3763 let isCommutable = 1, TwoOperandAliasConstraint = "$Rn = $Rd" in {
3764 def MUL : AsMul1I32<0b0000000, (outs GPRnopc:$Rd),
3765                     (ins GPRnopc:$Rn, GPRnopc:$Rm),
3766                     IIC_iMUL32, "mul", "\t$Rd, $Rn, $Rm",
3767                   [(set GPRnopc:$Rd, (mul GPRnopc:$Rn, GPRnopc:$Rm))]>,
3768                   Requires<[IsARM, HasV6]> {
3769   let Inst{15-12} = 0b0000;
3770   let Unpredictable{15-12} = 0b1111;
3771 }
3772
3773 let Constraints = "@earlyclobber $Rd" in
3774 def MULv5: ARMPseudoExpand<(outs GPRnopc:$Rd), (ins GPRnopc:$Rn, GPRnopc:$Rm,
3775                                                     pred:$p, cc_out:$s),
3776                            4, IIC_iMUL32,
3777                [(set GPRnopc:$Rd, (mul GPRnopc:$Rn, GPRnopc:$Rm))],
3778                (MUL GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, pred:$p, cc_out:$s)>,
3779                Requires<[IsARM, NoV6, UseMulOps]>;
3780 }
3781
3782 def MLA  : AsMul1I32<0b0000001, (outs GPRnopc:$Rd),
3783                      (ins GPRnopc:$Rn, GPRnopc:$Rm, GPRnopc:$Ra),
3784                      IIC_iMAC32, "mla", "\t$Rd, $Rn, $Rm, $Ra",
3785         [(set GPRnopc:$Rd, (add (mul GPRnopc:$Rn, GPRnopc:$Rm), GPRnopc:$Ra))]>,
3786                      Requires<[IsARM, HasV6, UseMulOps]> {
3787   bits<4> Ra;
3788   let Inst{15-12} = Ra;
3789 }
3790
3791 let Constraints = "@earlyclobber $Rd" in
3792 def MLAv5: ARMPseudoExpand<(outs GPRnopc:$Rd),
3793                            (ins GPRnopc:$Rn, GPRnopc:$Rm, GPRnopc:$Ra,
3794                             pred:$p, cc_out:$s), 4, IIC_iMAC32,
3795          [(set GPRnopc:$Rd, (add (mul GPRnopc:$Rn, GPRnopc:$Rm), GPRnopc:$Ra))],
3796   (MLA GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, GPRnopc:$Ra, pred:$p, cc_out:$s)>,
3797                            Requires<[IsARM, NoV6]>;
3798
3799 def MLS  : AMul1I<0b0000011, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm, GPR:$Ra),
3800                    IIC_iMAC32, "mls", "\t$Rd, $Rn, $Rm, $Ra",
3801                    [(set GPR:$Rd, (sub GPR:$Ra, (mul GPR:$Rn, GPR:$Rm)))]>,
3802                    Requires<[IsARM, HasV6T2, UseMulOps]> {
3803   bits<4> Rd;
3804   bits<4> Rm;
3805   bits<4> Rn;
3806   bits<4> Ra;
3807   let Inst{19-16} = Rd;
3808   let Inst{15-12} = Ra;
3809   let Inst{11-8}  = Rm;
3810   let Inst{3-0}   = Rn;
3811 }
3812
3813 // Extra precision multiplies with low / high results
3814 let hasSideEffects = 0 in {
3815 let isCommutable = 1 in {
3816 def SMULL : AsMul1I64<0b0000110, (outs GPR:$RdLo, GPR:$RdHi),
3817                                  (ins GPR:$Rn, GPR:$Rm), IIC_iMUL64,
3818                     "smull", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
3819                     Requires<[IsARM, HasV6]>;
3820
3821 def UMULL : AsMul1I64<0b0000100, (outs GPR:$RdLo, GPR:$RdHi),
3822                                  (ins GPR:$Rn, GPR:$Rm), IIC_iMUL64,
3823                     "umull", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
3824                     Requires<[IsARM, HasV6]>;
3825
3826 let Constraints = "@earlyclobber $RdLo,@earlyclobber $RdHi" in {
3827 def SMULLv5 : ARMPseudoExpand<(outs GPR:$RdLo, GPR:$RdHi),
3828                             (ins GPR:$Rn, GPR:$Rm, pred:$p, cc_out:$s),
3829                             4, IIC_iMUL64, [],
3830           (SMULL GPR:$RdLo, GPR:$RdHi, GPR:$Rn, GPR:$Rm, pred:$p, cc_out:$s)>,
3831                            Requires<[IsARM, NoV6]>;
3832
3833 def UMULLv5 : ARMPseudoExpand<(outs GPR:$RdLo, GPR:$RdHi),
3834                             (ins GPR:$Rn, GPR:$Rm, pred:$p, cc_out:$s),
3835                             4, IIC_iMUL64, [],
3836           (UMULL GPR:$RdLo, GPR:$RdHi, GPR:$Rn, GPR:$Rm, pred:$p, cc_out:$s)>,
3837                            Requires<[IsARM, NoV6]>;
3838 }
3839 }
3840
3841 // Multiply + accumulate
3842 def SMLAL : AsMla1I64<0b0000111, (outs GPR:$RdLo, GPR:$RdHi),
3843                         (ins GPR:$Rn, GPR:$Rm, GPR:$RLo, GPR:$RHi), IIC_iMAC64,
3844                     "smlal", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
3845          RegConstraint<"$RLo = $RdLo, $RHi = $RdHi">, Requires<[IsARM, HasV6]>;
3846 def UMLAL : AsMla1I64<0b0000101, (outs GPR:$RdLo, GPR:$RdHi),
3847                         (ins GPR:$Rn, GPR:$Rm, GPR:$RLo, GPR:$RHi), IIC_iMAC64,
3848                     "umlal", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
3849          RegConstraint<"$RLo = $RdLo, $RHi = $RdHi">, Requires<[IsARM, HasV6]>;
3850
3851 def UMAAL : AMul1I <0b0000010, (outs GPR:$RdLo, GPR:$RdHi),
3852                                (ins GPR:$Rn, GPR:$Rm), IIC_iMAC64,
3853                     "umaal", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
3854                     Requires<[IsARM, HasV6]> {
3855   bits<4> RdLo;
3856   bits<4> RdHi;
3857   bits<4> Rm;
3858   bits<4> Rn;
3859   let Inst{19-16} = RdHi;
3860   let Inst{15-12} = RdLo;
3861   let Inst{11-8}  = Rm;
3862   let Inst{3-0}   = Rn;
3863 }
3864
3865 let Constraints =
3866     "@earlyclobber $RdLo,@earlyclobber $RdHi,$RLo = $RdLo,$RHi = $RdHi" in {
3867 def SMLALv5 : ARMPseudoExpand<(outs GPR:$RdLo, GPR:$RdHi),
3868                 (ins GPR:$Rn, GPR:$Rm, GPR:$RLo, GPR:$RHi, pred:$p, cc_out:$s),
3869                               4, IIC_iMAC64, [],
3870              (SMLAL GPR:$RdLo, GPR:$RdHi, GPR:$Rn, GPR:$Rm, GPR:$RLo, GPR:$RHi,
3871                            pred:$p, cc_out:$s)>,
3872                            Requires<[IsARM, NoV6]>;
3873 def UMLALv5 : ARMPseudoExpand<(outs GPR:$RdLo, GPR:$RdHi),
3874                 (ins GPR:$Rn, GPR:$Rm, GPR:$RLo, GPR:$RHi, pred:$p, cc_out:$s),
3875                               4, IIC_iMAC64, [],
3876              (UMLAL GPR:$RdLo, GPR:$RdHi, GPR:$Rn, GPR:$Rm, GPR:$RLo, GPR:$RHi,
3877                            pred:$p, cc_out:$s)>,
3878                            Requires<[IsARM, NoV6]>;
3879 }
3880
3881 } // hasSideEffects
3882
3883 // Most significant word multiply
3884 def SMMUL : AMul2I <0b0111010, 0b0001, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
3885                IIC_iMUL32, "smmul", "\t$Rd, $Rn, $Rm",
3886                [(set GPR:$Rd, (mulhs GPR:$Rn, GPR:$Rm))]>,
3887             Requires<[IsARM, HasV6]> {
3888   let Inst{15-12} = 0b1111;
3889 }
3890
3891 def SMMULR : AMul2I <0b0111010, 0b0011, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
3892                IIC_iMUL32, "smmulr", "\t$Rd, $Rn, $Rm", []>,
3893             Requires<[IsARM, HasV6]> {
3894   let Inst{15-12} = 0b1111;
3895 }
3896
3897 def SMMLA : AMul2Ia <0b0111010, 0b0001, (outs GPR:$Rd),
3898                (ins GPR:$Rn, GPR:$Rm, GPR:$Ra),
3899                IIC_iMAC32, "smmla", "\t$Rd, $Rn, $Rm, $Ra",
3900                [(set GPR:$Rd, (add (mulhs GPR:$Rn, GPR:$Rm), GPR:$Ra))]>,
3901             Requires<[IsARM, HasV6, UseMulOps]>;
3902
3903 def SMMLAR : AMul2Ia <0b0111010, 0b0011, (outs GPR:$Rd),
3904                (ins GPR:$Rn, GPR:$Rm, GPR:$Ra),
3905                IIC_iMAC32, "smmlar", "\t$Rd, $Rn, $Rm, $Ra", []>,
3906             Requires<[IsARM, HasV6]>;
3907
3908 def SMMLS : AMul2Ia <0b0111010, 0b1101, (outs GPR:$Rd),
3909                (ins GPR:$Rn, GPR:$Rm, GPR:$Ra),
3910                IIC_iMAC32, "smmls", "\t$Rd, $Rn, $Rm, $Ra", []>,
3911             Requires<[IsARM, HasV6, UseMulOps]>;
3912
3913 def SMMLSR : AMul2Ia <0b0111010, 0b1111, (outs GPR:$Rd),
3914                (ins GPR:$Rn, GPR:$Rm, GPR:$Ra),
3915                IIC_iMAC32, "smmlsr", "\t$Rd, $Rn, $Rm, $Ra", []>,
3916             Requires<[IsARM, HasV6]>;
3917
3918 multiclass AI_smul<string opc, PatFrag opnode> {
3919   def BB : AMulxyI<0b0001011, 0b00, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
3920               IIC_iMUL16, !strconcat(opc, "bb"), "\t$Rd, $Rn, $Rm",
3921               [(set GPR:$Rd, (opnode (sext_inreg GPR:$Rn, i16),
3922                                       (sext_inreg GPR:$Rm, i16)))]>,
3923            Requires<[IsARM, HasV5TE]>;
3924
3925   def BT : AMulxyI<0b0001011, 0b10, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
3926               IIC_iMUL16, !strconcat(opc, "bt"), "\t$Rd, $Rn, $Rm",
3927               [(set GPR:$Rd, (opnode (sext_inreg GPR:$Rn, i16),
3928                                       (sra GPR:$Rm, (i32 16))))]>,
3929            Requires<[IsARM, HasV5TE]>;
3930
3931   def TB : AMulxyI<0b0001011, 0b01, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
3932               IIC_iMUL16, !strconcat(opc, "tb"), "\t$Rd, $Rn, $Rm",
3933               [(set GPR:$Rd, (opnode (sra GPR:$Rn, (i32 16)),
3934                                       (sext_inreg GPR:$Rm, i16)))]>,
3935            Requires<[IsARM, HasV5TE]>;
3936
3937   def TT : AMulxyI<0b0001011, 0b11, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
3938               IIC_iMUL16, !strconcat(opc, "tt"), "\t$Rd, $Rn, $Rm",
3939               [(set GPR:$Rd, (opnode (sra GPR:$Rn, (i32 16)),
3940                                       (sra GPR:$Rm, (i32 16))))]>,
3941             Requires<[IsARM, HasV5TE]>;
3942
3943   def WB : AMulxyI<0b0001001, 0b01, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
3944               IIC_iMUL16, !strconcat(opc, "wb"), "\t$Rd, $Rn, $Rm",
3945               []>,
3946            Requires<[IsARM, HasV5TE]>;
3947
3948   def WT : AMulxyI<0b0001001, 0b11, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
3949               IIC_iMUL16, !strconcat(opc, "wt"), "\t$Rd, $Rn, $Rm",
3950               []>,
3951             Requires<[IsARM, HasV5TE]>;
3952 }
3953
3954
3955 multiclass AI_smla<string opc, PatFrag opnode> {
3956   let DecoderMethod = "DecodeSMLAInstruction" in {
3957   def BB : AMulxyIa<0b0001000, 0b00, (outs GPRnopc:$Rd),
3958               (ins GPRnopc:$Rn, GPRnopc:$Rm, GPR:$Ra),
3959               IIC_iMAC16, !strconcat(opc, "bb"), "\t$Rd, $Rn, $Rm, $Ra",
3960               [(set GPRnopc:$Rd, (add GPR:$Ra,
3961                                (opnode (sext_inreg GPRnopc:$Rn, i16),
3962                                        (sext_inreg GPRnopc:$Rm, i16))))]>,
3963            Requires<[IsARM, HasV5TE, UseMulOps]>;
3964
3965   def BT : AMulxyIa<0b0001000, 0b10, (outs GPRnopc:$Rd),
3966               (ins GPRnopc:$Rn, GPRnopc:$Rm, GPR:$Ra),
3967               IIC_iMAC16, !strconcat(opc, "bt"), "\t$Rd, $Rn, $Rm, $Ra",
3968               [(set GPRnopc:$Rd,
3969                     (add GPR:$Ra, (opnode (sext_inreg GPRnopc:$Rn, i16),
3970                                           (sra GPRnopc:$Rm, (i32 16)))))]>,
3971            Requires<[IsARM, HasV5TE, UseMulOps]>;
3972
3973   def TB : AMulxyIa<0b0001000, 0b01, (outs GPRnopc:$Rd),
3974               (ins GPRnopc:$Rn, GPRnopc:$Rm, GPR:$Ra),
3975               IIC_iMAC16, !strconcat(opc, "tb"), "\t$Rd, $Rn, $Rm, $Ra",
3976               [(set GPRnopc:$Rd,
3977                     (add GPR:$Ra, (opnode (sra GPRnopc:$Rn, (i32 16)),
3978                                           (sext_inreg GPRnopc:$Rm, i16))))]>,
3979            Requires<[IsARM, HasV5TE, UseMulOps]>;
3980
3981   def TT : AMulxyIa<0b0001000, 0b11, (outs GPRnopc:$Rd),
3982               (ins GPRnopc:$Rn, GPRnopc:$Rm, GPR:$Ra),
3983               IIC_iMAC16, !strconcat(opc, "tt"), "\t$Rd, $Rn, $Rm, $Ra",
3984              [(set GPRnopc:$Rd,
3985                    (add GPR:$Ra, (opnode (sra GPRnopc:$Rn, (i32 16)),
3986                                          (sra GPRnopc:$Rm, (i32 16)))))]>,
3987             Requires<[IsARM, HasV5TE, UseMulOps]>;
3988
3989   def WB : AMulxyIa<0b0001001, 0b00, (outs GPRnopc:$Rd),
3990               (ins GPRnopc:$Rn, GPRnopc:$Rm, GPR:$Ra),
3991               IIC_iMAC16, !strconcat(opc, "wb"), "\t$Rd, $Rn, $Rm, $Ra",
3992               []>,
3993            Requires<[IsARM, HasV5TE, UseMulOps]>;
3994
3995   def WT : AMulxyIa<0b0001001, 0b10, (outs GPRnopc:$Rd),
3996               (ins GPRnopc:$Rn, GPRnopc:$Rm, GPR:$Ra),
3997               IIC_iMAC16, !strconcat(opc, "wt"), "\t$Rd, $Rn, $Rm, $Ra",
3998               []>,
3999             Requires<[IsARM, HasV5TE, UseMulOps]>;
4000   }
4001 }
4002
4003 defm SMUL : AI_smul<"smul", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
4004 defm SMLA : AI_smla<"smla", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
4005
4006 // Halfword multiply accumulate long: SMLAL<x><y>.
4007 def SMLALBB : AMulxyI64<0b0001010, 0b00, (outs GPRnopc:$RdLo, GPRnopc:$RdHi),
4008                       (ins GPRnopc:$Rn, GPRnopc:$Rm),
4009                       IIC_iMAC64, "smlalbb", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
4010               Requires<[IsARM, HasV5TE]>;
4011
4012 def SMLALBT : AMulxyI64<0b0001010, 0b10, (outs GPRnopc:$RdLo, GPRnopc:$RdHi),
4013                       (ins GPRnopc:$Rn, GPRnopc:$Rm),
4014                       IIC_iMAC64, "smlalbt", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
4015               Requires<[IsARM, HasV5TE]>;
4016
4017 def SMLALTB : AMulxyI64<0b0001010, 0b01, (outs GPRnopc:$RdLo, GPRnopc:$RdHi),
4018                       (ins GPRnopc:$Rn, GPRnopc:$Rm),
4019                       IIC_iMAC64, "smlaltb", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
4020               Requires<[IsARM, HasV5TE]>;
4021
4022 def SMLALTT : AMulxyI64<0b0001010, 0b11, (outs GPRnopc:$RdLo, GPRnopc:$RdHi),
4023                       (ins GPRnopc:$Rn, GPRnopc:$Rm),
4024                       IIC_iMAC64, "smlaltt", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
4025               Requires<[IsARM, HasV5TE]>;
4026
4027 // Helper class for AI_smld.
4028 class AMulDualIbase<bit long, bit sub, bit swap, dag oops, dag iops,
4029                     InstrItinClass itin, string opc, string asm>
4030   : AI<oops, iops, MulFrm, itin, opc, asm, []>, Requires<[IsARM, HasV6]> {
4031   bits<4> Rn;
4032   bits<4> Rm;
4033   let Inst{27-23} = 0b01110;
4034   let Inst{22}    = long;
4035   let Inst{21-20} = 0b00;
4036   let Inst{11-8}  = Rm;
4037   let Inst{7}     = 0;
4038   let Inst{6}     = sub;
4039   let Inst{5}     = swap;
4040   let Inst{4}     = 1;
4041   let Inst{3-0}   = Rn;
4042 }
4043 class AMulDualI<bit long, bit sub, bit swap, dag oops, dag iops,
4044                 InstrItinClass itin, string opc, string asm>
4045   : AMulDualIbase<long, sub, swap, oops, iops, itin, opc, asm> {
4046   bits<4> Rd;
4047   let Inst{15-12} = 0b1111;
4048   let Inst{19-16} = Rd;
4049 }
4050 class AMulDualIa<bit long, bit sub, bit swap, dag oops, dag iops,
4051                 InstrItinClass itin, string opc, string asm>
4052   : AMulDualIbase<long, sub, swap, oops, iops, itin, opc, asm> {
4053   bits<4> Ra;
4054   bits<4> Rd;
4055   let Inst{19-16} = Rd;
4056   let Inst{15-12} = Ra;
4057 }
4058 class AMulDualI64<bit long, bit sub, bit swap, dag oops, dag iops,
4059                   InstrItinClass itin, string opc, string asm>
4060   : AMulDualIbase<long, sub, swap, oops, iops, itin, opc, asm> {
4061   bits<4> RdLo;
4062   bits<4> RdHi;
4063   let Inst{19-16} = RdHi;
4064   let Inst{15-12} = RdLo;
4065 }
4066
4067 multiclass AI_smld<bit sub, string opc> {
4068
4069   def D : AMulDualIa<0, sub, 0, (outs GPRnopc:$Rd),
4070                   (ins GPRnopc:$Rn, GPRnopc:$Rm, GPR:$Ra),
4071                   NoItinerary, !strconcat(opc, "d"), "\t$Rd, $Rn, $Rm, $Ra">;
4072
4073   def DX: AMulDualIa<0, sub, 1, (outs GPRnopc:$Rd),
4074                   (ins GPRnopc:$Rn, GPRnopc:$Rm, GPR:$Ra),
4075                   NoItinerary, !strconcat(opc, "dx"), "\t$Rd, $Rn, $Rm, $Ra">;
4076
4077   def LD: AMulDualI64<1, sub, 0, (outs GPRnopc:$RdLo, GPRnopc:$RdHi),
4078                   (ins GPRnopc:$Rn, GPRnopc:$Rm), NoItinerary,
4079                   !strconcat(opc, "ld"), "\t$RdLo, $RdHi, $Rn, $Rm">;
4080
4081   def LDX : AMulDualI64<1, sub, 1, (outs GPRnopc:$RdLo, GPRnopc:$RdHi),
4082                   (ins GPRnopc:$Rn, GPRnopc:$Rm), NoItinerary,
4083                   !strconcat(opc, "ldx"),"\t$RdLo, $RdHi, $Rn, $Rm">;
4084
4085 }
4086
4087 defm SMLA : AI_smld<0, "smla">;
4088 defm SMLS : AI_smld<1, "smls">;
4089
4090 multiclass AI_sdml<bit sub, string opc> {
4091
4092   def D:AMulDualI<0, sub, 0, (outs GPRnopc:$Rd), (ins GPRnopc:$Rn, GPRnopc:$Rm),
4093                   NoItinerary, !strconcat(opc, "d"), "\t$Rd, $Rn, $Rm">;
4094   def DX:AMulDualI<0, sub, 1, (outs GPRnopc:$Rd),(ins GPRnopc:$Rn, GPRnopc:$Rm),
4095                   NoItinerary, !strconcat(opc, "dx"), "\t$Rd, $Rn, $Rm">;
4096 }
4097
4098 defm SMUA : AI_sdml<0, "smua">;
4099 defm SMUS : AI_sdml<1, "smus">;
4100
4101 //===----------------------------------------------------------------------===//
4102 //  Division Instructions (ARMv7-A with virtualization extension)
4103 //
4104 def SDIV : ADivA1I<0b001, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm), IIC_iDIV,
4105                    "sdiv", "\t$Rd, $Rn, $Rm",
4106                    [(set GPR:$Rd, (sdiv GPR:$Rn, GPR:$Rm))]>,
4107            Requires<[IsARM, HasDivideInARM]>;
4108
4109 def UDIV : ADivA1I<0b011, (outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm), IIC_iDIV,
4110                    "udiv", "\t$Rd, $Rn, $Rm",
4111                    [(set GPR:$Rd, (udiv GPR:$Rn, GPR:$Rm))]>,
4112            Requires<[IsARM, HasDivideInARM]>;
4113
4114 //===----------------------------------------------------------------------===//
4115 //  Misc. Arithmetic Instructions.
4116 //
4117
4118 def CLZ  : AMiscA1I<0b00010110, 0b0001, (outs GPR:$Rd), (ins GPR:$Rm),
4119               IIC_iUNAr, "clz", "\t$Rd, $Rm",
4120               [(set GPR:$Rd, (ctlz GPR:$Rm))]>, Requires<[IsARM, HasV5T]>,
4121            Sched<[WriteALU]>;
4122
4123 def RBIT : AMiscA1I<0b01101111, 0b0011, (outs GPR:$Rd), (ins GPR:$Rm),
4124               IIC_iUNAr, "rbit", "\t$Rd, $Rm",
4125               [(set GPR:$Rd, (ARMrbit GPR:$Rm))]>,
4126            Requires<[IsARM, HasV6T2]>,
4127            Sched<[WriteALU]>;
4128
4129 def REV  : AMiscA1I<0b01101011, 0b0011, (outs GPR:$Rd), (ins GPR:$Rm),
4130               IIC_iUNAr, "rev", "\t$Rd, $Rm",
4131               [(set GPR:$Rd, (bswap GPR:$Rm))]>, Requires<[IsARM, HasV6]>,
4132            Sched<[WriteALU]>;
4133
4134 let AddedComplexity = 5 in
4135 def REV16 : AMiscA1I<0b01101011, 0b1011, (outs GPR:$Rd), (ins GPR:$Rm),
4136                IIC_iUNAr, "rev16", "\t$Rd, $Rm",
4137                [(set GPR:$Rd, (rotr (bswap GPR:$Rm), (i32 16)))]>,
4138                Requires<[IsARM, HasV6]>,
4139            Sched<[WriteALU]>;
4140
4141 def : ARMV6Pat<(srl (bswap (extloadi16 addrmode3:$addr)), (i32 16)),
4142               (REV16 (LDRH addrmode3:$addr))>;
4143 def : ARMV6Pat<(truncstorei16 (srl (bswap GPR:$Rn), (i32 16)), addrmode3:$addr),
4144                (STRH (REV16 GPR:$Rn), addrmode3:$addr)>;
4145
4146 let AddedComplexity = 5 in
4147 def REVSH : AMiscA1I<0b01101111, 0b1011, (outs GPR:$Rd), (ins GPR:$Rm),
4148                IIC_iUNAr, "revsh", "\t$Rd, $Rm",
4149                [(set GPR:$Rd, (sra (bswap GPR:$Rm), (i32 16)))]>,
4150                Requires<[IsARM, HasV6]>,
4151            Sched<[WriteALU]>;
4152
4153 def : ARMV6Pat<(or (sra (shl GPR:$Rm, (i32 24)), (i32 16)),
4154                    (and (srl GPR:$Rm, (i32 8)), 0xFF)),
4155                (REVSH GPR:$Rm)>;
4156
4157 def PKHBT : APKHI<0b01101000, 0, (outs GPRnopc:$Rd),
4158                               (ins GPRnopc:$Rn, GPRnopc:$Rm, pkh_lsl_amt:$sh),
4159                IIC_iALUsi, "pkhbt", "\t$Rd, $Rn, $Rm$sh",
4160                [(set GPRnopc:$Rd, (or (and GPRnopc:$Rn, 0xFFFF),
4161                                       (and (shl GPRnopc:$Rm, pkh_lsl_amt:$sh),
4162                                            0xFFFF0000)))]>,
4163                Requires<[IsARM, HasV6]>,
4164            Sched<[WriteALUsi, ReadALU]>;
4165
4166 // Alternate cases for PKHBT where identities eliminate some nodes.
4167 def : ARMV6Pat<(or (and GPRnopc:$Rn, 0xFFFF), (and GPRnopc:$Rm, 0xFFFF0000)),
4168                (PKHBT GPRnopc:$Rn, GPRnopc:$Rm, 0)>;
4169 def : ARMV6Pat<(or (and GPRnopc:$Rn, 0xFFFF), (shl GPRnopc:$Rm, imm16_31:$sh)),
4170                (PKHBT GPRnopc:$Rn, GPRnopc:$Rm, imm16_31:$sh)>;
4171
4172 // Note: Shifts of 1-15 bits will be transformed to srl instead of sra and
4173 // will match the pattern below.
4174 def PKHTB : APKHI<0b01101000, 1, (outs GPRnopc:$Rd),
4175                               (ins GPRnopc:$Rn, GPRnopc:$Rm, pkh_asr_amt:$sh),
4176                IIC_iBITsi, "pkhtb", "\t$Rd, $Rn, $Rm$sh",
4177                [(set GPRnopc:$Rd, (or (and GPRnopc:$Rn, 0xFFFF0000),
4178                                       (and (sra GPRnopc:$Rm, pkh_asr_amt:$sh),
4179                                            0xFFFF)))]>,
4180                Requires<[IsARM, HasV6]>,
4181            Sched<[WriteALUsi, ReadALU]>;
4182
4183 // Alternate cases for PKHTB where identities eliminate some nodes.  Note that
4184 // a shift amount of 0 is *not legal* here, it is PKHBT instead.
4185 // We also can not replace a srl (17..31) by an arithmetic shift we would use in
4186 // pkhtb src1, src2, asr (17..31).
4187 def : ARMV6Pat<(or (and GPRnopc:$src1, 0xFFFF0000),
4188                    (srl GPRnopc:$src2, imm16:$sh)),
4189                (PKHTB GPRnopc:$src1, GPRnopc:$src2, imm16:$sh)>;
4190 def : ARMV6Pat<(or (and GPRnopc:$src1, 0xFFFF0000),
4191                    (sra GPRnopc:$src2, imm16_31:$sh)),
4192                (PKHTB GPRnopc:$src1, GPRnopc:$src2, imm16_31:$sh)>;
4193 def : ARMV6Pat<(or (and GPRnopc:$src1, 0xFFFF0000),
4194                    (and (srl GPRnopc:$src2, imm1_15:$sh), 0xFFFF)),
4195                (PKHTB GPRnopc:$src1, GPRnopc:$src2, imm1_15:$sh)>;
4196
4197 //===----------------------------------------------------------------------===//
4198 // CRC Instructions
4199 //
4200 // Polynomials:
4201 // + CRC32{B,H,W}       0x04C11DB7
4202 // + CRC32C{B,H,W}      0x1EDC6F41
4203 //
4204
4205 class AI_crc32<bit C, bits<2> sz, string suffix, SDPatternOperator builtin>
4206   : AInoP<(outs GPRnopc:$Rd), (ins GPRnopc:$Rn, GPRnopc:$Rm), MiscFrm, NoItinerary,
4207                !strconcat("crc32", suffix), "\t$Rd, $Rn, $Rm",
4208                [(set GPRnopc:$Rd, (builtin GPRnopc:$Rn, GPRnopc:$Rm))]>,
4209                Requires<[IsARM, HasV8, HasCRC]> {
4210   bits<4> Rd;
4211   bits<4> Rn;
4212   bits<4> Rm;
4213
4214   let Inst{31-28} = 0b1110;
4215   let Inst{27-23} = 0b00010;
4216   let Inst{22-21} = sz;
4217   let Inst{20}    = 0;
4218   let Inst{19-16} = Rn;
4219   let Inst{15-12} = Rd;
4220   let Inst{11-10} = 0b00;
4221   let Inst{9}     = C;
4222   let Inst{8}     = 0;
4223   let Inst{7-4}   = 0b0100;
4224   let Inst{3-0}   = Rm;
4225
4226   let Unpredictable{11-8} = 0b1101;
4227 }
4228
4229 def CRC32B  : AI_crc32<0, 0b00, "b", int_arm_crc32b>;
4230 def CRC32CB : AI_crc32<1, 0b00, "cb", int_arm_crc32cb>;
4231 def CRC32H  : AI_crc32<0, 0b01, "h", int_arm_crc32h>;
4232 def CRC32CH : AI_crc32<1, 0b01, "ch", int_arm_crc32ch>;
4233 def CRC32W  : AI_crc32<0, 0b10, "w", int_arm_crc32w>;
4234 def CRC32CW : AI_crc32<1, 0b10, "cw", int_arm_crc32cw>;
4235
4236 //===----------------------------------------------------------------------===//
4237 //  Comparison Instructions...
4238 //
4239
4240 defm CMP  : AI1_cmp_irs<0b1010, "cmp",
4241                         IIC_iCMPi, IIC_iCMPr, IIC_iCMPsr,
4242                         BinOpFrag<(ARMcmp node:$LHS, node:$RHS)>>;
4243
4244 // ARMcmpZ can re-use the above instruction definitions.
4245 def : ARMPat<(ARMcmpZ GPR:$src, so_imm:$imm),
4246              (CMPri   GPR:$src, so_imm:$imm)>;
4247 def : ARMPat<(ARMcmpZ GPR:$src, GPR:$rhs),
4248              (CMPrr   GPR:$src, GPR:$rhs)>;
4249 def : ARMPat<(ARMcmpZ GPR:$src, so_reg_imm:$rhs),
4250              (CMPrsi   GPR:$src, so_reg_imm:$rhs)>;
4251 def : ARMPat<(ARMcmpZ GPR:$src, so_reg_reg:$rhs),
4252              (CMPrsr   GPR:$src, so_reg_reg:$rhs)>;
4253
4254 // CMN register-integer
4255 let isCompare = 1, Defs = [CPSR] in {
4256 def CMNri : AI1<0b1011, (outs), (ins GPR:$Rn, so_imm:$imm), DPFrm, IIC_iCMPi,
4257                 "cmn", "\t$Rn, $imm",
4258                 [(ARMcmn GPR:$Rn, so_imm:$imm)]>,
4259                 Sched<[WriteCMP, ReadALU]> {
4260   bits<4> Rn;
4261   bits<12> imm;
4262   let Inst{25} = 1;
4263   let Inst{20} = 1;
4264   let Inst{19-16} = Rn;
4265   let Inst{15-12} = 0b0000;
4266   let Inst{11-0} = imm;
4267
4268   let Unpredictable{15-12} = 0b1111;
4269 }
4270
4271 // CMN register-register/shift
4272 def CMNzrr : AI1<0b1011, (outs), (ins GPR:$Rn, GPR:$Rm), DPFrm, IIC_iCMPr,
4273                  "cmn", "\t$Rn, $Rm",
4274                  [(BinOpFrag<(ARMcmpZ node:$LHS,(ineg node:$RHS))>
4275                    GPR:$Rn, GPR:$Rm)]>, Sched<[WriteCMP, ReadALU, ReadALU]> {
4276   bits<4> Rn;
4277   bits<4> Rm;
4278   let isCommutable = 1;
4279   let Inst{25} = 0;
4280   let Inst{20} = 1;
4281   let Inst{19-16} = Rn;
4282   let Inst{15-12} = 0b0000;
4283   let Inst{11-4} = 0b00000000;
4284   let Inst{3-0} = Rm;
4285
4286   let Unpredictable{15-12} = 0b1111;
4287 }
4288
4289 def CMNzrsi : AI1<0b1011, (outs),
4290                   (ins GPR:$Rn, so_reg_imm:$shift), DPSoRegImmFrm, IIC_iCMPsr,
4291                   "cmn", "\t$Rn, $shift",
4292                   [(BinOpFrag<(ARMcmpZ node:$LHS,(ineg node:$RHS))>
4293                     GPR:$Rn, so_reg_imm:$shift)]>,
4294                     Sched<[WriteCMPsi, ReadALU]> {
4295   bits<4> Rn;
4296   bits<12> shift;
4297   let Inst{25} = 0;
4298   let Inst{20} = 1;
4299   let Inst{19-16} = Rn;
4300   let Inst{15-12} = 0b0000;
4301   let Inst{11-5} = shift{11-5};
4302   let Inst{4} = 0;
4303   let Inst{3-0} = shift{3-0};
4304
4305   let Unpredictable{15-12} = 0b1111;
4306 }
4307
4308 def CMNzrsr : AI1<0b1011, (outs),
4309                   (ins GPRnopc:$Rn, so_reg_reg:$shift), DPSoRegRegFrm, IIC_iCMPsr,
4310                   "cmn", "\t$Rn, $shift",
4311                   [(BinOpFrag<(ARMcmpZ node:$LHS,(ineg node:$RHS))>
4312                     GPRnopc:$Rn, so_reg_reg:$shift)]>,
4313                     Sched<[WriteCMPsr, ReadALU]> {
4314   bits<4> Rn;
4315   bits<12> shift;
4316   let Inst{25} = 0;
4317   let Inst{20} = 1;
4318   let Inst{19-16} = Rn;
4319   let Inst{15-12} = 0b0000;
4320   let Inst{11-8} = shift{11-8};
4321   let Inst{7} = 0;
4322   let Inst{6-5} = shift{6-5};
4323   let Inst{4} = 1;
4324   let Inst{3-0} = shift{3-0};
4325
4326   let Unpredictable{15-12} = 0b1111;
4327 }
4328
4329 }
4330
4331 def : ARMPat<(ARMcmp  GPR:$src, so_imm_neg:$imm),
4332              (CMNri   GPR:$src, so_imm_neg:$imm)>;
4333
4334 def : ARMPat<(ARMcmpZ GPR:$src, so_imm_neg:$imm),
4335              (CMNri   GPR:$src, so_imm_neg:$imm)>;
4336
4337 // Note that TST/TEQ don't set all the same flags that CMP does!
4338 defm TST  : AI1_cmp_irs<0b1000, "tst",
4339                         IIC_iTSTi, IIC_iTSTr, IIC_iTSTsr,
4340                       BinOpFrag<(ARMcmpZ (and_su node:$LHS, node:$RHS), 0)>, 1>;
4341 defm TEQ  : AI1_cmp_irs<0b1001, "teq",
4342                         IIC_iTSTi, IIC_iTSTr, IIC_iTSTsr,
4343                       BinOpFrag<(ARMcmpZ (xor_su node:$LHS, node:$RHS), 0)>, 1>;
4344
4345 // Pseudo i64 compares for some floating point compares.
4346 let usesCustomInserter = 1, isBranch = 1, isTerminator = 1,
4347     Defs = [CPSR] in {
4348 def BCCi64 : PseudoInst<(outs),
4349     (ins i32imm:$cc, GPR:$lhs1, GPR:$lhs2, GPR:$rhs1, GPR:$rhs2, brtarget:$dst),
4350      IIC_Br,
4351     [(ARMBcci64 imm:$cc, GPR:$lhs1, GPR:$lhs2, GPR:$rhs1, GPR:$rhs2, bb:$dst)]>,
4352     Sched<[WriteBr]>;
4353
4354 def BCCZi64 : PseudoInst<(outs),
4355      (ins i32imm:$cc, GPR:$lhs1, GPR:$lhs2, brtarget:$dst), IIC_Br,
4356     [(ARMBcci64 imm:$cc, GPR:$lhs1, GPR:$lhs2, 0, 0, bb:$dst)]>,
4357     Sched<[WriteBr]>;
4358 } // usesCustomInserter
4359
4360
4361 // Conditional moves
4362 let hasSideEffects = 0 in {
4363
4364 let isCommutable = 1, isSelect = 1 in
4365 def MOVCCr : ARMPseudoInst<(outs GPR:$Rd),
4366                            (ins GPR:$false, GPR:$Rm, cmovpred:$p),
4367                            4, IIC_iCMOVr,
4368                            [(set GPR:$Rd, (ARMcmov GPR:$false, GPR:$Rm,
4369                                                    cmovpred:$p))]>,
4370              RegConstraint<"$false = $Rd">, Sched<[WriteALU]>;
4371
4372 def MOVCCsi : ARMPseudoInst<(outs GPR:$Rd),
4373                             (ins GPR:$false, so_reg_imm:$shift, cmovpred:$p),
4374                             4, IIC_iCMOVsr,
4375                             [(set GPR:$Rd,
4376                                   (ARMcmov GPR:$false, so_reg_imm:$shift,
4377                                            cmovpred:$p))]>,
4378       RegConstraint<"$false = $Rd">, Sched<[WriteALU]>;
4379 def MOVCCsr : ARMPseudoInst<(outs GPR:$Rd),
4380                             (ins GPR:$false, so_reg_reg:$shift, cmovpred:$p),
4381                            4, IIC_iCMOVsr,
4382   [(set GPR:$Rd, (ARMcmov GPR:$false, so_reg_reg:$shift,
4383                             cmovpred:$p))]>,
4384       RegConstraint<"$false = $Rd">, Sched<[WriteALU]>;
4385
4386
4387 let isMoveImm = 1 in
4388 def MOVCCi16
4389     : ARMPseudoInst<(outs GPR:$Rd),
4390                     (ins GPR:$false, imm0_65535_expr:$imm, cmovpred:$p),
4391                     4, IIC_iMOVi,
4392                     [(set GPR:$Rd, (ARMcmov GPR:$false, imm0_65535:$imm,
4393                                             cmovpred:$p))]>,
4394       RegConstraint<"$false = $Rd">, Requires<[IsARM, HasV6T2]>,
4395       Sched<[WriteALU]>;
4396
4397 let isMoveImm = 1 in
4398 def MOVCCi : ARMPseudoInst<(outs GPR:$Rd),
4399                            (ins GPR:$false, so_imm:$imm, cmovpred:$p),
4400                            4, IIC_iCMOVi,
4401                            [(set GPR:$Rd, (ARMcmov GPR:$false, so_imm:$imm,
4402                                                    cmovpred:$p))]>,
4403       RegConstraint<"$false = $Rd">, Sched<[WriteALU]>;
4404
4405 // Two instruction predicate mov immediate.
4406 let isMoveImm = 1 in
4407 def MOVCCi32imm
4408     : ARMPseudoInst<(outs GPR:$Rd),
4409                     (ins GPR:$false, i32imm:$src, cmovpred:$p),
4410                     8, IIC_iCMOVix2,
4411                     [(set GPR:$Rd, (ARMcmov GPR:$false, imm:$src,
4412                                             cmovpred:$p))]>,
4413       RegConstraint<"$false = $Rd">, Requires<[IsARM, HasV6T2]>;
4414
4415 let isMoveImm = 1 in
4416 def MVNCCi : ARMPseudoInst<(outs GPR:$Rd),
4417                            (ins GPR:$false, so_imm:$imm, cmovpred:$p),
4418                            4, IIC_iCMOVi,
4419                            [(set GPR:$Rd, (ARMcmov GPR:$false, so_imm_not:$imm,
4420                                                    cmovpred:$p))]>,
4421                 RegConstraint<"$false = $Rd">, Sched<[WriteALU]>;
4422
4423 } // hasSideEffects
4424
4425
4426 //===----------------------------------------------------------------------===//
4427 // Atomic operations intrinsics
4428 //
4429
4430 def MemBarrierOptOperand : AsmOperandClass {
4431   let Name = "MemBarrierOpt";
4432   let ParserMethod = "parseMemBarrierOptOperand";
4433 }
4434 def memb_opt : Operand<i32> {
4435   let PrintMethod = "printMemBOption";
4436   let ParserMatchClass = MemBarrierOptOperand;
4437   let DecoderMethod = "DecodeMemBarrierOption";
4438 }
4439
4440 def InstSyncBarrierOptOperand : AsmOperandClass {
4441   let Name = "InstSyncBarrierOpt";
4442   let ParserMethod = "parseInstSyncBarrierOptOperand";
4443 }
4444 def instsyncb_opt : Operand<i32> {
4445   let PrintMethod = "printInstSyncBOption";
4446   let ParserMatchClass = InstSyncBarrierOptOperand;
4447   let DecoderMethod = "DecodeInstSyncBarrierOption";
4448 }
4449
4450 // Memory barriers protect the atomic sequences
4451 let hasSideEffects = 1 in {
4452 def DMB : AInoP<(outs), (ins memb_opt:$opt), MiscFrm, NoItinerary,
4453                 "dmb", "\t$opt", [(int_arm_dmb (i32 imm0_15:$opt))]>,
4454                 Requires<[IsARM, HasDB]> {
4455   bits<4> opt;
4456   let Inst{31-4} = 0xf57ff05;
4457   let Inst{3-0} = opt;
4458 }
4459
4460 def DSB : AInoP<(outs), (ins memb_opt:$opt), MiscFrm, NoItinerary,
4461                 "dsb", "\t$opt", [(int_arm_dsb (i32 imm0_15:$opt))]>,
4462                 Requires<[IsARM, HasDB]> {
4463   bits<4> opt;
4464   let Inst{31-4} = 0xf57ff04;
4465   let Inst{3-0} = opt;
4466 }
4467
4468 // ISB has only full system option
4469 def ISB : AInoP<(outs), (ins instsyncb_opt:$opt), MiscFrm, NoItinerary,
4470                 "isb", "\t$opt", [(int_arm_isb (i32 imm0_15:$opt))]>,
4471                 Requires<[IsARM, HasDB]> {
4472   bits<4> opt;
4473   let Inst{31-4} = 0xf57ff06;
4474   let Inst{3-0} = opt;
4475 }
4476 }
4477
4478 let usesCustomInserter = 1, Defs = [CPSR] in {
4479
4480 // Pseudo instruction that combines movs + predicated rsbmi
4481 // to implement integer ABS
4482   def ABS : ARMPseudoInst<(outs GPR:$dst), (ins GPR:$src), 8, NoItinerary, []>;
4483 }
4484
4485 let usesCustomInserter = 1 in {
4486     def COPY_STRUCT_BYVAL_I32 : PseudoInst<
4487       (outs), (ins GPR:$dst, GPR:$src, i32imm:$size, i32imm:$alignment),
4488       NoItinerary,
4489       [(ARMcopystructbyval GPR:$dst, GPR:$src, imm:$size, imm:$alignment)]>;
4490 }
4491
4492 def ldrex_1 : PatFrag<(ops node:$ptr), (int_arm_ldrex node:$ptr), [{
4493   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i8;
4494 }]>;
4495
4496 def ldrex_2 : PatFrag<(ops node:$ptr), (int_arm_ldrex node:$ptr), [{
4497   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i16;
4498 }]>;
4499
4500 def ldrex_4 : PatFrag<(ops node:$ptr), (int_arm_ldrex node:$ptr), [{
4501   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i32;
4502 }]>;
4503
4504 def strex_1 : PatFrag<(ops node:$val, node:$ptr),
4505                       (int_arm_strex node:$val, node:$ptr), [{
4506   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i8;
4507 }]>;
4508
4509 def strex_2 : PatFrag<(ops node:$val, node:$ptr),
4510                       (int_arm_strex node:$val, node:$ptr), [{
4511   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i16;
4512 }]>;
4513
4514 def strex_4 : PatFrag<(ops node:$val, node:$ptr),
4515                       (int_arm_strex node:$val, node:$ptr), [{
4516   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i32;
4517 }]>;
4518
4519 def ldaex_1 : PatFrag<(ops node:$ptr), (int_arm_ldaex node:$ptr), [{
4520   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i8;
4521 }]>;
4522
4523 def ldaex_2 : PatFrag<(ops node:$ptr), (int_arm_ldaex node:$ptr), [{
4524   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i16;
4525 }]>;
4526
4527 def ldaex_4 : PatFrag<(ops node:$ptr), (int_arm_ldaex node:$ptr), [{
4528   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i32;
4529 }]>;
4530
4531 def stlex_1 : PatFrag<(ops node:$val, node:$ptr),
4532                       (int_arm_stlex node:$val, node:$ptr), [{
4533   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i8;
4534 }]>;
4535
4536 def stlex_2 : PatFrag<(ops node:$val, node:$ptr),
4537                       (int_arm_stlex node:$val, node:$ptr), [{
4538   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i16;
4539 }]>;
4540
4541 def stlex_4 : PatFrag<(ops node:$val, node:$ptr),
4542                       (int_arm_stlex node:$val, node:$ptr), [{
4543   return cast<MemIntrinsicSDNode>(N)->getMemoryVT() == MVT::i32;
4544 }]>;
4545
4546 let mayLoad = 1 in {
4547 def LDREXB : AIldrex<0b10, (outs GPR:$Rt), (ins addr_offset_none:$addr),
4548                      NoItinerary, "ldrexb", "\t$Rt, $addr",
4549                      [(set GPR:$Rt, (ldrex_1 addr_offset_none:$addr))]>;
4550 def LDREXH : AIldrex<0b11, (outs GPR:$Rt), (ins addr_offset_none:$addr),
4551                      NoItinerary, "ldrexh", "\t$Rt, $addr",
4552                      [(set GPR:$Rt, (ldrex_2 addr_offset_none:$addr))]>;
4553 def LDREX  : AIldrex<0b00, (outs GPR:$Rt), (ins addr_offset_none:$addr),
4554                      NoItinerary, "ldrex", "\t$Rt, $addr",
4555                      [(set GPR:$Rt, (ldrex_4 addr_offset_none:$addr))]>;
4556 let hasExtraDefRegAllocReq = 1 in
4557 def LDREXD : AIldrex<0b01, (outs GPRPairOp:$Rt),(ins addr_offset_none:$addr),
4558                       NoItinerary, "ldrexd", "\t$Rt, $addr", []> {
4559   let DecoderMethod = "DecodeDoubleRegLoad";
4560 }
4561
4562 def LDAEXB : AIldaex<0b10, (outs GPR:$Rt), (ins addr_offset_none:$addr),
4563                      NoItinerary, "ldaexb", "\t$Rt, $addr",
4564                      [(set GPR:$Rt, (ldaex_1 addr_offset_none:$addr))]>;
4565 def LDAEXH : AIldaex<0b11, (outs GPR:$Rt), (ins addr_offset_none:$addr),
4566                      NoItinerary, "ldaexh", "\t$Rt, $addr",
4567                     [(set GPR:$Rt, (ldaex_2 addr_offset_none:$addr))]>;
4568 def LDAEX  : AIldaex<0b00, (outs GPR:$Rt), (ins addr_offset_none:$addr),
4569                      NoItinerary, "ldaex", "\t$Rt, $addr",
4570                     [(set GPR:$Rt, (ldaex_4 addr_offset_none:$addr))]>;
4571 let hasExtraDefRegAllocReq = 1 in
4572 def LDAEXD : AIldaex<0b01, (outs GPRPairOp:$Rt),(ins addr_offset_none:$addr),
4573                       NoItinerary, "ldaexd", "\t$Rt, $addr", []> {
4574   let DecoderMethod = "DecodeDoubleRegLoad";
4575 }
4576 }
4577
4578 let mayStore = 1, Constraints = "@earlyclobber $Rd" in {
4579 def STREXB: AIstrex<0b10, (outs GPR:$Rd), (ins GPR:$Rt, addr_offset_none:$addr),
4580                     NoItinerary, "strexb", "\t$Rd, $Rt, $addr",
4581                     [(set GPR:$Rd, (strex_1 GPR:$Rt,
4582                                             addr_offset_none:$addr))]>;
4583 def STREXH: AIstrex<0b11, (outs GPR:$Rd), (ins GPR:$Rt, addr_offset_none:$addr),
4584                     NoItinerary, "strexh", "\t$Rd, $Rt, $addr",
4585                     [(set GPR:$Rd, (strex_2 GPR:$Rt,
4586                                             addr_offset_none:$addr))]>;
4587 def STREX : AIstrex<0b00, (outs GPR:$Rd), (ins GPR:$Rt, addr_offset_none:$addr),
4588                     NoItinerary, "strex", "\t$Rd, $Rt, $addr",
4589                     [(set GPR:$Rd, (strex_4 GPR:$Rt,
4590                                             addr_offset_none:$addr))]>;
4591 let hasExtraSrcRegAllocReq = 1 in
4592 def STREXD : AIstrex<0b01, (outs GPR:$Rd),
4593                     (ins GPRPairOp:$Rt, addr_offset_none:$addr),
4594                     NoItinerary, "strexd", "\t$Rd, $Rt, $addr", []> {
4595   let DecoderMethod = "DecodeDoubleRegStore";
4596 }
4597 def STLEXB: AIstlex<0b10, (outs GPR:$Rd), (ins GPR:$Rt, addr_offset_none:$addr),
4598                     NoItinerary, "stlexb", "\t$Rd, $Rt, $addr",
4599                     [(set GPR:$Rd,
4600                           (stlex_1 GPR:$Rt, addr_offset_none:$addr))]>;
4601 def STLEXH: AIstlex<0b11, (outs GPR:$Rd), (ins GPR:$Rt, addr_offset_none:$addr),
4602                     NoItinerary, "stlexh", "\t$Rd, $Rt, $addr",
4603                     [(set GPR:$Rd,
4604                           (stlex_2 GPR:$Rt, addr_offset_none:$addr))]>;
4605 def STLEX : AIstlex<0b00, (outs GPR:$Rd), (ins GPR:$Rt, addr_offset_none:$addr),
4606                     NoItinerary, "stlex", "\t$Rd, $Rt, $addr",
4607                     [(set GPR:$Rd,
4608                           (stlex_4 GPR:$Rt, addr_offset_none:$addr))]>;
4609 let hasExtraSrcRegAllocReq = 1 in
4610 def STLEXD : AIstlex<0b01, (outs GPR:$Rd),
4611                     (ins GPRPairOp:$Rt, addr_offset_none:$addr),
4612                     NoItinerary, "stlexd", "\t$Rd, $Rt, $addr", []> {
4613   let DecoderMethod = "DecodeDoubleRegStore";
4614 }
4615 }
4616
4617 def CLREX : AXI<(outs), (ins), MiscFrm, NoItinerary, "clrex",
4618                 [(int_arm_clrex)]>,
4619             Requires<[IsARM, HasV7]>  {
4620   let Inst{31-0} = 0b11110101011111111111000000011111;
4621 }
4622
4623 def : ARMPat<(strex_1 (and GPR:$Rt, 0xff), addr_offset_none:$addr),
4624              (STREXB GPR:$Rt, addr_offset_none:$addr)>;
4625 def : ARMPat<(strex_2 (and GPR:$Rt, 0xffff), addr_offset_none:$addr),
4626              (STREXH GPR:$Rt, addr_offset_none:$addr)>;
4627
4628 def : ARMPat<(stlex_1 (and GPR:$Rt, 0xff), addr_offset_none:$addr),
4629              (STLEXB GPR:$Rt, addr_offset_none:$addr)>;
4630 def : ARMPat<(stlex_2 (and GPR:$Rt, 0xffff), addr_offset_none:$addr),
4631              (STLEXH GPR:$Rt, addr_offset_none:$addr)>;
4632
4633 class acquiring_load<PatFrag base>
4634   : PatFrag<(ops node:$ptr), (base node:$ptr), [{
4635   AtomicOrdering Ordering = cast<AtomicSDNode>(N)->getOrdering();
4636   return isAtLeastAcquire(Ordering);
4637 }]>;
4638
4639 def atomic_load_acquire_8  : acquiring_load<atomic_load_8>;
4640 def atomic_load_acquire_16 : acquiring_load<atomic_load_16>;
4641 def atomic_load_acquire_32 : acquiring_load<atomic_load_32>;
4642
4643 class releasing_store<PatFrag base>
4644   : PatFrag<(ops node:$ptr, node:$val), (base node:$ptr, node:$val), [{
4645   AtomicOrdering Ordering = cast<AtomicSDNode>(N)->getOrdering();
4646   return isAtLeastRelease(Ordering);
4647 }]>;
4648
4649 def atomic_store_release_8  : releasing_store<atomic_store_8>;
4650 def atomic_store_release_16 : releasing_store<atomic_store_16>;
4651 def atomic_store_release_32 : releasing_store<atomic_store_32>;
4652
4653 let AddedComplexity = 8 in {
4654   def : ARMPat<(atomic_load_acquire_8 addr_offset_none:$addr),  (LDAB addr_offset_none:$addr)>;
4655   def : ARMPat<(atomic_load_acquire_16 addr_offset_none:$addr), (LDAH addr_offset_none:$addr)>;
4656   def : ARMPat<(atomic_load_acquire_32 addr_offset_none:$addr), (LDA  addr_offset_none:$addr)>;
4657   def : ARMPat<(atomic_store_release_8 addr_offset_none:$addr, GPR:$val),  (STLB GPR:$val, addr_offset_none:$addr)>;
4658   def : ARMPat<(atomic_store_release_16 addr_offset_none:$addr, GPR:$val), (STLH GPR:$val, addr_offset_none:$addr)>;
4659   def : ARMPat<(atomic_store_release_32 addr_offset_none:$addr, GPR:$val), (STL  GPR:$val, addr_offset_none:$addr)>;
4660 }
4661
4662 // SWP/SWPB are deprecated in V6/V7.
4663 let mayLoad = 1, mayStore = 1 in {
4664 def SWP : AIswp<0, (outs GPRnopc:$Rt),
4665                 (ins GPRnopc:$Rt2, addr_offset_none:$addr), "swp", []>,
4666                 Requires<[PreV8]>;
4667 def SWPB: AIswp<1, (outs GPRnopc:$Rt),
4668                 (ins GPRnopc:$Rt2, addr_offset_none:$addr), "swpb", []>,
4669                 Requires<[PreV8]>;
4670 }
4671
4672 //===----------------------------------------------------------------------===//
4673 // Coprocessor Instructions.
4674 //
4675
4676 def CDP : ABI<0b1110, (outs), (ins p_imm:$cop, imm0_15:$opc1,
4677             c_imm:$CRd, c_imm:$CRn, c_imm:$CRm, imm0_7:$opc2),
4678             NoItinerary, "cdp", "\t$cop, $opc1, $CRd, $CRn, $CRm, $opc2",
4679             [(int_arm_cdp imm:$cop, imm:$opc1, imm:$CRd, imm:$CRn,
4680                           imm:$CRm, imm:$opc2)]>,
4681             Requires<[PreV8]> {
4682   bits<4> opc1;
4683   bits<4> CRn;
4684   bits<4> CRd;
4685   bits<4> cop;
4686   bits<3> opc2;
4687   bits<4> CRm;
4688
4689   let Inst{3-0}   = CRm;
4690   let Inst{4}     = 0;
4691   let Inst{7-5}   = opc2;
4692   let Inst{11-8}  = cop;
4693   let Inst{15-12} = CRd;
4694   let Inst{19-16} = CRn;
4695   let Inst{23-20} = opc1;
4696 }
4697
4698 def CDP2 : ABXI<0b1110, (outs), (ins p_imm:$cop, imm0_15:$opc1,
4699                c_imm:$CRd, c_imm:$CRn, c_imm:$CRm, imm0_7:$opc2),
4700                NoItinerary, "cdp2\t$cop, $opc1, $CRd, $CRn, $CRm, $opc2",
4701                [(int_arm_cdp2 imm:$cop, imm:$opc1, imm:$CRd, imm:$CRn,
4702                               imm:$CRm, imm:$opc2)]>,
4703                Requires<[PreV8]> {
4704   let Inst{31-28} = 0b1111;
4705   bits<4> opc1;
4706   bits<4> CRn;
4707   bits<4> CRd;
4708   bits<4> cop;
4709   bits<3> opc2;
4710   bits<4> CRm;
4711
4712   let Inst{3-0}   = CRm;
4713   let Inst{4}     = 0;
4714   let Inst{7-5}   = opc2;
4715   let Inst{11-8}  = cop;
4716   let Inst{15-12} = CRd;
4717   let Inst{19-16} = CRn;
4718   let Inst{23-20} = opc1;
4719 }
4720
4721 class ACI<dag oops, dag iops, string opc, string asm,
4722           IndexMode im = IndexModeNone>
4723   : I<oops, iops, AddrModeNone, 4, im, BrFrm, NoItinerary,
4724       opc, asm, "", []> {
4725   let Inst{27-25} = 0b110;
4726 }
4727 class ACInoP<dag oops, dag iops, string opc, string asm,
4728           IndexMode im = IndexModeNone>
4729   : InoP<oops, iops, AddrModeNone, 4, im, BrFrm, NoItinerary,
4730          opc, asm, "", []> {
4731   let Inst{31-28} = 0b1111;
4732   let Inst{27-25} = 0b110;
4733 }
4734 multiclass LdStCop<bit load, bit Dbit, string asm> {
4735   def _OFFSET : ACI<(outs), (ins p_imm:$cop, c_imm:$CRd, addrmode5:$addr),
4736                     asm, "\t$cop, $CRd, $addr"> {
4737     bits<13> addr;
4738     bits<4> cop;
4739     bits<4> CRd;
4740     let Inst{24} = 1; // P = 1
4741     let Inst{23} = addr{8};
4742     let Inst{22} = Dbit;
4743     let Inst{21} = 0; // W = 0
4744     let Inst{20} = load;
4745     let Inst{19-16} = addr{12-9};
4746     let Inst{15-12} = CRd;
4747     let Inst{11-8} = cop;
4748     let Inst{7-0} = addr{7-0};
4749     let DecoderMethod = "DecodeCopMemInstruction";
4750   }
4751   def _PRE : ACI<(outs), (ins p_imm:$cop, c_imm:$CRd, addrmode5_pre:$addr),
4752                  asm, "\t$cop, $CRd, $addr!", IndexModePre> {
4753     bits<13> addr;
4754     bits<4> cop;
4755     bits<4> CRd;
4756     let Inst{24} = 1; // P = 1
4757     let Inst{23} = addr{8};
4758     let Inst{22} = Dbit;
4759     let Inst{21} = 1; // W = 1
4760     let Inst{20} = load;
4761     let Inst{19-16} = addr{12-9};
4762     let Inst{15-12} = CRd;
4763     let Inst{11-8} = cop;
4764     let Inst{7-0} = addr{7-0};
4765     let DecoderMethod = "DecodeCopMemInstruction";
4766   }
4767   def _POST: ACI<(outs), (ins p_imm:$cop, c_imm:$CRd, addr_offset_none:$addr,
4768                               postidx_imm8s4:$offset),
4769                  asm, "\t$cop, $CRd, $addr, $offset", IndexModePost> {
4770     bits<9> offset;
4771     bits<4> addr;
4772     bits<4> cop;
4773     bits<4> CRd;
4774     let Inst{24} = 0; // P = 0
4775     let Inst{23} = offset{8};
4776     let Inst{22} = Dbit;
4777     let Inst{21} = 1; // W = 1
4778     let Inst{20} = load;
4779     let Inst{19-16} = addr;
4780     let Inst{15-12} = CRd;
4781     let Inst{11-8} = cop;
4782     let Inst{7-0} = offset{7-0};
4783     let DecoderMethod = "DecodeCopMemInstruction";
4784   }
4785   def _OPTION : ACI<(outs),
4786                     (ins p_imm:$cop, c_imm:$CRd, addr_offset_none:$addr,
4787                          coproc_option_imm:$option),
4788       asm, "\t$cop, $CRd, $addr, $option"> {
4789     bits<8> option;
4790     bits<4> addr;
4791     bits<4> cop;
4792     bits<4> CRd;
4793     let Inst{24} = 0; // P = 0
4794     let Inst{23} = 1; // U = 1
4795     let Inst{22} = Dbit;
4796     let Inst{21} = 0; // W = 0
4797     let Inst{20} = load;
4798     let Inst{19-16} = addr;
4799     let Inst{15-12} = CRd;
4800     let Inst{11-8} = cop;
4801     let Inst{7-0} = option;
4802     let DecoderMethod = "DecodeCopMemInstruction";
4803   }
4804 }
4805 multiclass LdSt2Cop<bit load, bit Dbit, string asm> {
4806   def _OFFSET : ACInoP<(outs), (ins p_imm:$cop, c_imm:$CRd, addrmode5:$addr),
4807                        asm, "\t$cop, $CRd, $addr"> {
4808     bits<13> addr;
4809     bits<4> cop;
4810     bits<4> CRd;
4811     let Inst{24} = 1; // P = 1
4812     let Inst{23} = addr{8};
4813     let Inst{22} = Dbit;
4814     let Inst{21} = 0; // W = 0
4815     let Inst{20} = load;
4816     let Inst{19-16} = addr{12-9};
4817     let Inst{15-12} = CRd;
4818     let Inst{11-8} = cop;
4819     let Inst{7-0} = addr{7-0};
4820     let DecoderMethod = "DecodeCopMemInstruction";
4821   }
4822   def _PRE : ACInoP<(outs), (ins p_imm:$cop, c_imm:$CRd, addrmode5_pre:$addr),
4823                     asm, "\t$cop, $CRd, $addr!", IndexModePre> {
4824     bits<13> addr;
4825     bits<4> cop;
4826     bits<4> CRd;
4827     let Inst{24} = 1; // P = 1
4828     let Inst{23} = addr{8};
4829     let Inst{22} = Dbit;
4830     let Inst{21} = 1; // W = 1
4831     let Inst{20} = load;
4832     let Inst{19-16} = addr{12-9};
4833     let Inst{15-12} = CRd;
4834     let Inst{11-8} = cop;
4835     let Inst{7-0} = addr{7-0};
4836     let DecoderMethod = "DecodeCopMemInstruction";
4837   }
4838   def _POST: ACInoP<(outs), (ins p_imm:$cop, c_imm:$CRd, addr_offset_none:$addr,
4839                                  postidx_imm8s4:$offset),
4840                  asm, "\t$cop, $CRd, $addr, $offset", IndexModePost> {
4841     bits<9> offset;
4842     bits<4> addr;
4843     bits<4> cop;
4844     bits<4> CRd;
4845     let Inst{24} = 0; // P = 0
4846     let Inst{23} = offset{8};
4847     let Inst{22} = Dbit;
4848     let Inst{21} = 1; // W = 1
4849     let Inst{20} = load;
4850     let Inst{19-16} = addr;
4851     let Inst{15-12} = CRd;
4852     let Inst{11-8} = cop;
4853     let Inst{7-0} = offset{7-0};
4854     let DecoderMethod = "DecodeCopMemInstruction";
4855   }
4856   def _OPTION : ACInoP<(outs),
4857                        (ins p_imm:$cop, c_imm:$CRd, addr_offset_none:$addr,
4858                             coproc_option_imm:$option),
4859       asm, "\t$cop, $CRd, $addr, $option"> {
4860     bits<8> option;
4861     bits<4> addr;
4862     bits<4> cop;
4863     bits<4> CRd;
4864     let Inst{24} = 0; // P = 0
4865     let Inst{23} = 1; // U = 1
4866     let Inst{22} = Dbit;
4867     let Inst{21} = 0; // W = 0
4868     let Inst{20} = load;
4869     let Inst{19-16} = addr;
4870     let Inst{15-12} = CRd;
4871     let Inst{11-8} = cop;
4872     let Inst{7-0} = option;
4873     let DecoderMethod = "DecodeCopMemInstruction";
4874   }
4875 }
4876
4877 defm LDC   : LdStCop <1, 0, "ldc">;
4878 defm LDCL  : LdStCop <1, 1, "ldcl">;
4879 defm STC   : LdStCop <0, 0, "stc">;
4880 defm STCL  : LdStCop <0, 1, "stcl">;
4881 defm LDC2  : LdSt2Cop<1, 0, "ldc2">, Requires<[PreV8]>;
4882 defm LDC2L : LdSt2Cop<1, 1, "ldc2l">, Requires<[PreV8]>;
4883 defm STC2  : LdSt2Cop<0, 0, "stc2">, Requires<[PreV8]>;
4884 defm STC2L : LdSt2Cop<0, 1, "stc2l">, Requires<[PreV8]>;
4885
4886 //===----------------------------------------------------------------------===//
4887 // Move between coprocessor and ARM core register.
4888 //
4889
4890 class MovRCopro<string opc, bit direction, dag oops, dag iops,
4891                 list<dag> pattern>
4892   : ABI<0b1110, oops, iops, NoItinerary, opc,
4893         "\t$cop, $opc1, $Rt, $CRn, $CRm, $opc2", pattern> {
4894   let Inst{20} = direction;
4895   let Inst{4} = 1;
4896
4897   bits<4> Rt;
4898   bits<4> cop;
4899   bits<3> opc1;
4900   bits<3> opc2;
4901   bits<4> CRm;
4902   bits<4> CRn;
4903
4904   let Inst{15-12} = Rt;
4905   let Inst{11-8}  = cop;
4906   let Inst{23-21} = opc1;
4907   let Inst{7-5}   = opc2;
4908   let Inst{3-0}   = CRm;
4909   let Inst{19-16} = CRn;
4910 }
4911
4912 def MCR : MovRCopro<"mcr", 0 /* from ARM core register to coprocessor */,
4913                     (outs),
4914                     (ins p_imm:$cop, imm0_7:$opc1, GPR:$Rt, c_imm:$CRn,
4915                          c_imm:$CRm, imm0_7:$opc2),
4916                     [(int_arm_mcr imm:$cop, imm:$opc1, GPR:$Rt, imm:$CRn,
4917                                   imm:$CRm, imm:$opc2)]>,
4918                     ComplexDeprecationPredicate<"MCR">;
4919 def : ARMInstAlias<"mcr${p} $cop, $opc1, $Rt, $CRn, $CRm",
4920                    (MCR p_imm:$cop, imm0_7:$opc1, GPR:$Rt, c_imm:$CRn,
4921                         c_imm:$CRm, 0, pred:$p)>;
4922 def MRC : MovRCopro<"mrc", 1 /* from coprocessor to ARM core register */,
4923                     (outs GPRwithAPSR:$Rt),
4924                     (ins p_imm:$cop, imm0_7:$opc1, c_imm:$CRn, c_imm:$CRm,
4925                          imm0_7:$opc2), []>;
4926 def : ARMInstAlias<"mrc${p} $cop, $opc1, $Rt, $CRn, $CRm",
4927                    (MRC GPRwithAPSR:$Rt, p_imm:$cop, imm0_7:$opc1, c_imm:$CRn,
4928                         c_imm:$CRm, 0, pred:$p)>;
4929
4930 def : ARMPat<(int_arm_mrc imm:$cop, imm:$opc1, imm:$CRn, imm:$CRm, imm:$opc2),
4931              (MRC imm:$cop, imm:$opc1, imm:$CRn, imm:$CRm, imm:$opc2)>;
4932
4933 class MovRCopro2<string opc, bit direction, dag oops, dag iops,
4934                  list<dag> pattern>
4935   : ABXI<0b1110, oops, iops, NoItinerary,
4936          !strconcat(opc, "\t$cop, $opc1, $Rt, $CRn, $CRm, $opc2"), pattern> {
4937   let Inst{31-24} = 0b11111110;
4938   let Inst{20} = direction;
4939   let Inst{4} = 1;
4940
4941   bits<4> Rt;
4942   bits<4> cop;
4943   bits<3> opc1;
4944   bits<3> opc2;
4945   bits<4> CRm;
4946   bits<4> CRn;
4947
4948   let Inst{15-12} = Rt;
4949   let Inst{11-8}  = cop;
4950   let Inst{23-21} = opc1;
4951   let Inst{7-5}   = opc2;
4952   let Inst{3-0}   = CRm;
4953   let Inst{19-16} = CRn;
4954 }
4955
4956 def MCR2 : MovRCopro2<"mcr2", 0 /* from ARM core register to coprocessor */,
4957                       (outs),
4958                       (ins p_imm:$cop, imm0_7:$opc1, GPR:$Rt, c_imm:$CRn,
4959                            c_imm:$CRm, imm0_7:$opc2),
4960                       [(int_arm_mcr2 imm:$cop, imm:$opc1, GPR:$Rt, imm:$CRn,
4961                                      imm:$CRm, imm:$opc2)]>,
4962                       Requires<[PreV8]>;
4963 def : ARMInstAlias<"mcr2 $cop, $opc1, $Rt, $CRn, $CRm",
4964                    (MCR2 p_imm:$cop, imm0_7:$opc1, GPR:$Rt, c_imm:$CRn,
4965                          c_imm:$CRm, 0)>;
4966 def MRC2 : MovRCopro2<"mrc2", 1 /* from coprocessor to ARM core register */,
4967                       (outs GPRwithAPSR:$Rt),
4968                       (ins p_imm:$cop, imm0_7:$opc1, c_imm:$CRn, c_imm:$CRm,
4969                            imm0_7:$opc2), []>,
4970                       Requires<[PreV8]>;
4971 def : ARMInstAlias<"mrc2 $cop, $opc1, $Rt, $CRn, $CRm",
4972                    (MRC2 GPRwithAPSR:$Rt, p_imm:$cop, imm0_7:$opc1, c_imm:$CRn,
4973                          c_imm:$CRm, 0)>;
4974
4975 def : ARMV5TPat<(int_arm_mrc2 imm:$cop, imm:$opc1, imm:$CRn,
4976                               imm:$CRm, imm:$opc2),
4977                 (MRC2 imm:$cop, imm:$opc1, imm:$CRn, imm:$CRm, imm:$opc2)>;
4978
4979 class MovRRCopro<string opc, bit direction, list<dag> pattern = []>
4980   : ABI<0b1100, (outs), (ins p_imm:$cop, imm0_15:$opc1,
4981         GPRnopc:$Rt, GPRnopc:$Rt2, c_imm:$CRm),
4982         NoItinerary, opc, "\t$cop, $opc1, $Rt, $Rt2, $CRm", pattern> {
4983   let Inst{23-21} = 0b010;
4984   let Inst{20} = direction;
4985
4986   bits<4> Rt;
4987   bits<4> Rt2;
4988   bits<4> cop;
4989   bits<4> opc1;
4990   bits<4> CRm;
4991
4992   let Inst{15-12} = Rt;
4993   let Inst{19-16} = Rt2;
4994   let Inst{11-8}  = cop;
4995   let Inst{7-4}   = opc1;
4996   let Inst{3-0}   = CRm;
4997 }
4998
4999 def MCRR : MovRRCopro<"mcrr", 0 /* from ARM core register to coprocessor */,
5000                       [(int_arm_mcrr imm:$cop, imm:$opc1, GPRnopc:$Rt,
5001                                      GPRnopc:$Rt2, imm:$CRm)]>;
5002 def MRRC : MovRRCopro<"mrrc", 1 /* from coprocessor to ARM core register */>;
5003
5004 class MovRRCopro2<string opc, bit direction, list<dag> pattern = []>
5005   : ABXI<0b1100, (outs), (ins p_imm:$cop, imm0_15:$opc1,
5006          GPRnopc:$Rt, GPRnopc:$Rt2, c_imm:$CRm), NoItinerary,
5007          !strconcat(opc, "\t$cop, $opc1, $Rt, $Rt2, $CRm"), pattern>,
5008     Requires<[PreV8]> {
5009   let Inst{31-28} = 0b1111;
5010   let Inst{23-21} = 0b010;
5011   let Inst{20} = direction;
5012
5013   bits<4> Rt;
5014   bits<4> Rt2;
5015   bits<4> cop;
5016   bits<4> opc1;
5017   bits<4> CRm;
5018
5019   let Inst{15-12} = Rt;
5020   let Inst{19-16} = Rt2;
5021   let Inst{11-8}  = cop;
5022   let Inst{7-4}   = opc1;
5023   let Inst{3-0}   = CRm;
5024
5025   let DecoderMethod = "DecodeMRRC2";
5026 }
5027
5028 def MCRR2 : MovRRCopro2<"mcrr2", 0 /* from ARM core register to coprocessor */,
5029                         [(int_arm_mcrr2 imm:$cop, imm:$opc1, GPRnopc:$Rt,
5030                                         GPRnopc:$Rt2, imm:$CRm)]>;
5031 def MRRC2 : MovRRCopro2<"mrrc2", 1 /* from coprocessor to ARM core register */>;
5032
5033 //===----------------------------------------------------------------------===//
5034 // Move between special register and ARM core register
5035 //
5036
5037 // Move to ARM core register from Special Register
5038 def MRS : ABI<0b0001, (outs GPRnopc:$Rd), (ins), NoItinerary,
5039               "mrs", "\t$Rd, apsr", []> {
5040   bits<4> Rd;
5041   let Inst{23-16} = 0b00001111;
5042   let Unpredictable{19-17} = 0b111;
5043
5044   let Inst{15-12} = Rd;
5045
5046   let Inst{11-0} = 0b000000000000;
5047   let Unpredictable{11-0} = 0b110100001111;
5048 }
5049
5050 def : InstAlias<"mrs${p} $Rd, cpsr", (MRS GPRnopc:$Rd, pred:$p)>,
5051          Requires<[IsARM]>;
5052
5053 // The MRSsys instruction is the MRS instruction from the ARM ARM,
5054 // section B9.3.9, with the R bit set to 1.
5055 def MRSsys : ABI<0b0001, (outs GPRnopc:$Rd), (ins), NoItinerary,
5056                  "mrs", "\t$Rd, spsr", []> {
5057   bits<4> Rd;
5058   let Inst{23-16} = 0b01001111;
5059   let Unpredictable{19-16} = 0b1111;
5060
5061   let Inst{15-12} = Rd;
5062
5063   let Inst{11-0} = 0b000000000000;
5064   let Unpredictable{11-0} = 0b110100001111;
5065 }
5066
5067 // However, the MRS (banked register) system instruction (ARMv7VE) *does* have a
5068 // separate encoding (distinguished by bit 5.
5069 def MRSbanked : ABI<0b0001, (outs GPRnopc:$Rd), (ins banked_reg:$banked),
5070                     NoItinerary, "mrs", "\t$Rd, $banked", []>,
5071                 Requires<[IsARM, HasVirtualization]> {
5072   bits<6> banked;
5073   bits<4> Rd;
5074
5075   let Inst{23} = 0;
5076   let Inst{22} = banked{5}; // R bit
5077   let Inst{21-20} = 0b10;
5078   let Inst{19-16} = banked{3-0};
5079   let Inst{15-12} = Rd;
5080   let Inst{11-9} = 0b001;
5081   let Inst{8} = banked{4};
5082   let Inst{7-0} = 0b00000000;
5083 }
5084
5085 // Move from ARM core register to Special Register
5086 //
5087 // No need to have both system and application versions of MSR (immediate) or
5088 // MSR (register), the encodings are the same and the assembly parser has no way
5089 // to distinguish between them. The mask operand contains the special register
5090 // (R Bit) in bit 4 and bits 3-0 contains the mask with the fields to be
5091 // accessed in the special register.
5092 def MSR : ABI<0b0001, (outs), (ins msr_mask:$mask, GPR:$Rn), NoItinerary,
5093               "msr", "\t$mask, $Rn", []> {
5094   bits<5> mask;
5095   bits<4> Rn;
5096
5097   let Inst{23} = 0;
5098   let Inst{22} = mask{4}; // R bit
5099   let Inst{21-20} = 0b10;
5100   let Inst{19-16} = mask{3-0};
5101   let Inst{15-12} = 0b1111;
5102   let Inst{11-4} = 0b00000000;
5103   let Inst{3-0} = Rn;
5104 }
5105
5106 def MSRi : ABI<0b0011, (outs), (ins msr_mask:$mask,  so_imm:$a), NoItinerary,
5107                "msr", "\t$mask, $a", []> {
5108   bits<5> mask;
5109   bits<12> a;
5110
5111   let Inst{23} = 0;
5112   let Inst{22} = mask{4}; // R bit
5113   let Inst{21-20} = 0b10;
5114   let Inst{19-16} = mask{3-0};
5115   let Inst{15-12} = 0b1111;
5116   let Inst{11-0} = a;
5117 }
5118
5119 // However, the MSR (banked register) system instruction (ARMv7VE) *does* have a
5120 // separate encoding (distinguished by bit 5.
5121 def MSRbanked : ABI<0b0001, (outs), (ins banked_reg:$banked, GPRnopc:$Rn),
5122                     NoItinerary, "msr", "\t$banked, $Rn", []>,
5123                 Requires<[IsARM, HasVirtualization]> {
5124   bits<6> banked;
5125   bits<4> Rn;
5126
5127   let Inst{23} = 0;
5128   let Inst{22} = banked{5}; // R bit
5129   let Inst{21-20} = 0b10;
5130   let Inst{19-16} = banked{3-0};
5131   let Inst{15-12} = 0b1111;
5132   let Inst{11-9} = 0b001;
5133   let Inst{8} = banked{4};
5134   let Inst{7-4} = 0b0000;
5135   let Inst{3-0} = Rn;
5136 }
5137
5138 // Dynamic stack allocation yields a _chkstk for Windows targets.  These calls
5139 // are needed to probe the stack when allocating more than
5140 // 4k bytes in one go. Touching the stack at 4K increments is necessary to
5141 // ensure that the guard pages used by the OS virtual memory manager are
5142 // allocated in correct sequence.
5143 // The main point of having separate instruction are extra unmodelled effects
5144 // (compared to ordinary calls) like stack pointer change.
5145
5146 def win__chkstk : SDNode<"ARMISD::WIN__CHKSTK", SDTNone,
5147                       [SDNPHasChain, SDNPSideEffect]>;
5148 let usesCustomInserter = 1, Uses = [R4], Defs = [R4, SP] in
5149   def WIN__CHKSTK : PseudoInst<(outs), (ins), NoItinerary, [(win__chkstk)]>;
5150
5151 //===----------------------------------------------------------------------===//
5152 // TLS Instructions
5153 //
5154
5155 // __aeabi_read_tp preserves the registers r1-r3.
5156 // This is a pseudo inst so that we can get the encoding right,
5157 // complete with fixup for the aeabi_read_tp function.
5158 // TPsoft is valid for ARM mode only, in case of Thumb mode a tTPsoft pattern
5159 // is defined in "ARMInstrThumb.td".
5160 let isCall = 1,
5161   Defs = [R0, R12, LR, CPSR], Uses = [SP] in {
5162   def TPsoft : ARMPseudoInst<(outs), (ins), 4, IIC_Br,
5163                [(set R0, ARMthread_pointer)]>, Sched<[WriteBr]>;
5164 }
5165
5166 //===----------------------------------------------------------------------===//
5167 // SJLJ Exception handling intrinsics
5168 //   eh_sjlj_setjmp() is an instruction sequence to store the return
5169 //   address and save #0 in R0 for the non-longjmp case.
5170 //   Since by its nature we may be coming from some other function to get
5171 //   here, and we're using the stack frame for the containing function to
5172 //   save/restore registers, we can't keep anything live in regs across
5173 //   the eh_sjlj_setjmp(), else it will almost certainly have been tromped upon
5174 //   when we get here from a longjmp(). We force everything out of registers
5175 //   except for our own input by listing the relevant registers in Defs. By
5176 //   doing so, we also cause the prologue/epilogue code to actively preserve
5177 //   all of the callee-saved resgisters, which is exactly what we want.
5178 //   A constant value is passed in $val, and we use the location as a scratch.
5179 //
5180 // These are pseudo-instructions and are lowered to individual MC-insts, so
5181 // no encoding information is necessary.
5182 let Defs =
5183   [ R0,  R1,  R2,  R3,  R4,  R5,  R6,  R7,  R8,  R9,  R10, R11, R12, LR, CPSR,
5184     Q0, Q1, Q2, Q3, Q4, Q5, Q6, Q7, Q8, Q9, Q10, Q11, Q12, Q13, Q14, Q15 ],
5185   hasSideEffects = 1, isBarrier = 1, usesCustomInserter = 1 in {
5186   def Int_eh_sjlj_setjmp : PseudoInst<(outs), (ins GPR:$src, GPR:$val),
5187                                NoItinerary,
5188                          [(set R0, (ARMeh_sjlj_setjmp GPR:$src, GPR:$val))]>,
5189                            Requires<[IsARM, HasVFP2]>;
5190 }
5191
5192 let Defs =
5193   [ R0,  R1,  R2,  R3,  R4,  R5,  R6,  R7,  R8,  R9,  R10, R11, R12, LR, CPSR ],
5194   hasSideEffects = 1, isBarrier = 1, usesCustomInserter = 1 in {
5195   def Int_eh_sjlj_setjmp_nofp : PseudoInst<(outs), (ins GPR:$src, GPR:$val),
5196                                    NoItinerary,
5197                          [(set R0, (ARMeh_sjlj_setjmp GPR:$src, GPR:$val))]>,
5198                                 Requires<[IsARM, NoVFP]>;
5199 }
5200
5201 // FIXME: Non-IOS version(s)
5202 let isBarrier = 1, hasSideEffects = 1, isTerminator = 1,
5203     Defs = [ R7, LR, SP ] in {
5204 def Int_eh_sjlj_longjmp : PseudoInst<(outs), (ins GPR:$src, GPR:$scratch),
5205                              NoItinerary,
5206                          [(ARMeh_sjlj_longjmp GPR:$src, GPR:$scratch)]>,
5207                                 Requires<[IsARM, IsIOS]>;
5208 }
5209
5210 // eh.sjlj.dispatchsetup pseudo-instruction.
5211 // This pseudo is used for both ARM and Thumb. Any differences are handled when
5212 // the pseudo is expanded (which happens before any passes that need the
5213 // instruction size).
5214 let isBarrier = 1 in
5215 def Int_eh_sjlj_dispatchsetup : PseudoInst<(outs), (ins), NoItinerary, []>;
5216
5217
5218 //===----------------------------------------------------------------------===//
5219 // Non-Instruction Patterns
5220 //
5221
5222 // ARMv4 indirect branch using (MOVr PC, dst)
5223 let isBranch = 1, isTerminator = 1, isBarrier = 1, isIndirectBranch = 1 in
5224   def MOVPCRX : ARMPseudoExpand<(outs), (ins GPR:$dst),
5225                     4, IIC_Br, [(brind GPR:$dst)],
5226                     (MOVr PC, GPR:$dst, (ops 14, zero_reg), zero_reg)>,
5227                   Requires<[IsARM, NoV4T]>, Sched<[WriteBr]>;
5228
5229 // Large immediate handling.
5230
5231 // 32-bit immediate using two piece so_imms or movw + movt.
5232 // This is a single pseudo instruction, the benefit is that it can be remat'd
5233 // as a single unit instead of having to handle reg inputs.
5234 // FIXME: Remove this when we can do generalized remat.
5235 let isReMaterializable = 1, isMoveImm = 1 in
5236 def MOVi32imm : PseudoInst<(outs GPR:$dst), (ins i32imm:$src), IIC_iMOVix2,
5237                            [(set GPR:$dst, (arm_i32imm:$src))]>,
5238                            Requires<[IsARM]>;
5239
5240 def LDRLIT_ga_abs : PseudoInst<(outs GPR:$dst), (ins i32imm:$src), IIC_iLoad_i,
5241                                [(set GPR:$dst, (ARMWrapper tglobaladdr:$src))]>,
5242                     Requires<[IsARM, DontUseMovt]>;
5243
5244 // Pseudo instruction that combines movw + movt + add pc (if PIC).
5245 // It also makes it possible to rematerialize the instructions.
5246 // FIXME: Remove this when we can do generalized remat and when machine licm
5247 // can properly the instructions.
5248 let isReMaterializable = 1 in {
5249 def MOV_ga_pcrel : PseudoInst<(outs GPR:$dst), (ins i32imm:$addr),
5250                               IIC_iMOVix2addpc,
5251                         [(set GPR:$dst, (ARMWrapperPIC tglobaladdr:$addr))]>,
5252                         Requires<[IsARM, UseMovt]>;
5253
5254 def LDRLIT_ga_pcrel : PseudoInst<(outs GPR:$dst), (ins i32imm:$addr),
5255                                  IIC_iLoadiALU,
5256                                  [(set GPR:$dst,
5257                                        (ARMWrapperPIC tglobaladdr:$addr))]>,
5258                       Requires<[IsARM, DontUseMovt]>;
5259
5260 def LDRLIT_ga_pcrel_ldr : PseudoInst<(outs GPR:$dst), (ins i32imm:$addr),
5261                               NoItinerary,
5262                               [(set GPR:$dst,
5263                                     (load (ARMWrapperPIC tglobaladdr:$addr)))]>,
5264                           Requires<[IsARM, DontUseMovt]>;
5265
5266 let AddedComplexity = 10 in
5267 def MOV_ga_pcrel_ldr : PseudoInst<(outs GPR:$dst), (ins i32imm:$addr),
5268                                 IIC_iMOVix2ld,
5269                     [(set GPR:$dst, (load (ARMWrapperPIC tglobaladdr:$addr)))]>,
5270                     Requires<[IsARM, UseMovt]>;
5271 } // isReMaterializable
5272
5273 // ConstantPool, GlobalAddress, and JumpTable
5274 def : ARMPat<(ARMWrapper  tconstpool  :$dst), (LEApcrel tconstpool  :$dst)>;
5275 def : ARMPat<(ARMWrapper  tglobaladdr :$dst), (MOVi32imm tglobaladdr :$dst)>,
5276             Requires<[IsARM, UseMovt]>;
5277 def : ARMPat<(ARMWrapperJT tjumptable:$dst, imm:$id),
5278              (LEApcrelJT tjumptable:$dst, imm:$id)>;
5279
5280 // TODO: add,sub,and, 3-instr forms?
5281
5282 // Tail calls. These patterns also apply to Thumb mode.
5283 def : Pat<(ARMtcret tcGPR:$dst), (TCRETURNri tcGPR:$dst)>;
5284 def : Pat<(ARMtcret (i32 tglobaladdr:$dst)), (TCRETURNdi texternalsym:$dst)>;
5285 def : Pat<(ARMtcret (i32 texternalsym:$dst)), (TCRETURNdi texternalsym:$dst)>;
5286
5287 // Direct calls
5288 def : ARMPat<(ARMcall texternalsym:$func), (BL texternalsym:$func)>;
5289 def : ARMPat<(ARMcall_nolink texternalsym:$func),
5290              (BMOVPCB_CALL texternalsym:$func)>;
5291
5292 // zextload i1 -> zextload i8
5293 def : ARMPat<(zextloadi1 addrmode_imm12:$addr), (LDRBi12 addrmode_imm12:$addr)>;
5294 def : ARMPat<(zextloadi1 ldst_so_reg:$addr),    (LDRBrs ldst_so_reg:$addr)>;
5295
5296 // extload -> zextload
5297 def : ARMPat<(extloadi1 addrmode_imm12:$addr),  (LDRBi12 addrmode_imm12:$addr)>;
5298 def : ARMPat<(extloadi1 ldst_so_reg:$addr),     (LDRBrs ldst_so_reg:$addr)>;
5299 def : ARMPat<(extloadi8 addrmode_imm12:$addr),  (LDRBi12 addrmode_imm12:$addr)>;
5300 def : ARMPat<(extloadi8 ldst_so_reg:$addr),     (LDRBrs ldst_so_reg:$addr)>;
5301
5302 def : ARMPat<(extloadi16 addrmode3:$addr),  (LDRH addrmode3:$addr)>;
5303
5304 def : ARMPat<(extloadi8  addrmodepc:$addr), (PICLDRB addrmodepc:$addr)>;
5305 def : ARMPat<(extloadi16 addrmodepc:$addr), (PICLDRH addrmodepc:$addr)>;
5306
5307 // smul* and smla*
5308 def : ARMV5TEPat<(mul (sra (shl GPR:$a, (i32 16)), (i32 16)),
5309                       (sra (shl GPR:$b, (i32 16)), (i32 16))),
5310                  (SMULBB GPR:$a, GPR:$b)>;
5311 def : ARMV5TEPat<(mul sext_16_node:$a, sext_16_node:$b),
5312                  (SMULBB GPR:$a, GPR:$b)>;
5313 def : ARMV5TEPat<(mul (sra (shl GPR:$a, (i32 16)), (i32 16)),
5314                       (sra GPR:$b, (i32 16))),
5315                  (SMULBT GPR:$a, GPR:$b)>;
5316 def : ARMV5TEPat<(mul sext_16_node:$a, (sra GPR:$b, (i32 16))),
5317                  (SMULBT GPR:$a, GPR:$b)>;
5318 def : ARMV5TEPat<(mul (sra GPR:$a, (i32 16)),
5319                       (sra (shl GPR:$b, (i32 16)), (i32 16))),
5320                  (SMULTB GPR:$a, GPR:$b)>;
5321 def : ARMV5TEPat<(mul (sra GPR:$a, (i32 16)), sext_16_node:$b),
5322                 (SMULTB GPR:$a, GPR:$b)>;
5323
5324 def : ARMV5MOPat<(add GPR:$acc,
5325                       (mul (sra (shl GPR:$a, (i32 16)), (i32 16)),
5326                            (sra (shl GPR:$b, (i32 16)), (i32 16)))),
5327                  (SMLABB GPR:$a, GPR:$b, GPR:$acc)>;
5328 def : ARMV5MOPat<(add GPR:$acc,
5329                       (mul sext_16_node:$a, sext_16_node:$b)),
5330                  (SMLABB GPR:$a, GPR:$b, GPR:$acc)>;
5331 def : ARMV5MOPat<(add GPR:$acc,
5332                       (mul (sra (shl GPR:$a, (i32 16)), (i32 16)),
5333                            (sra GPR:$b, (i32 16)))),
5334                  (SMLABT GPR:$a, GPR:$b, GPR:$acc)>;
5335 def : ARMV5MOPat<(add GPR:$acc,
5336                       (mul sext_16_node:$a, (sra GPR:$b, (i32 16)))),
5337                  (SMLABT GPR:$a, GPR:$b, GPR:$acc)>;
5338 def : ARMV5MOPat<(add GPR:$acc,
5339                       (mul (sra GPR:$a, (i32 16)),
5340                            (sra (shl GPR:$b, (i32 16)), (i32 16)))),
5341                  (SMLATB GPR:$a, GPR:$b, GPR:$acc)>;
5342 def : ARMV5MOPat<(add GPR:$acc,
5343                       (mul (sra GPR:$a, (i32 16)), sext_16_node:$b)),
5344                  (SMLATB GPR:$a, GPR:$b, GPR:$acc)>;
5345
5346
5347 // Pre-v7 uses MCR for synchronization barriers.
5348 def : ARMPat<(ARMMemBarrierMCR GPR:$zero), (MCR 15, 0, GPR:$zero, 7, 10, 5)>,
5349          Requires<[IsARM, HasV6]>;
5350
5351 // SXT/UXT with no rotate
5352 let AddedComplexity = 16 in {
5353 def : ARMV6Pat<(and GPR:$Src, 0x000000FF), (UXTB GPR:$Src, 0)>;
5354 def : ARMV6Pat<(and GPR:$Src, 0x0000FFFF), (UXTH GPR:$Src, 0)>;
5355 def : ARMV6Pat<(and GPR:$Src, 0x00FF00FF), (UXTB16 GPR:$Src, 0)>;
5356 def : ARMV6Pat<(add GPR:$Rn, (and GPR:$Rm, 0x00FF)),
5357                (UXTAB GPR:$Rn, GPR:$Rm, 0)>;
5358 def : ARMV6Pat<(add GPR:$Rn, (and GPR:$Rm, 0xFFFF)),
5359                (UXTAH GPR:$Rn, GPR:$Rm, 0)>;
5360 }
5361
5362 def : ARMV6Pat<(sext_inreg GPR:$Src, i8),  (SXTB GPR:$Src, 0)>;
5363 def : ARMV6Pat<(sext_inreg GPR:$Src, i16), (SXTH GPR:$Src, 0)>;
5364
5365 def : ARMV6Pat<(add GPR:$Rn, (sext_inreg GPRnopc:$Rm, i8)),
5366                (SXTAB GPR:$Rn, GPRnopc:$Rm, 0)>;
5367 def : ARMV6Pat<(add GPR:$Rn, (sext_inreg GPRnopc:$Rm, i16)),
5368                (SXTAH GPR:$Rn, GPRnopc:$Rm, 0)>;
5369
5370 // Atomic load/store patterns
5371 def : ARMPat<(atomic_load_8 ldst_so_reg:$src),
5372              (LDRBrs ldst_so_reg:$src)>;
5373 def : ARMPat<(atomic_load_8 addrmode_imm12:$src),
5374              (LDRBi12 addrmode_imm12:$src)>;
5375 def : ARMPat<(atomic_load_16 addrmode3:$src),
5376              (LDRH addrmode3:$src)>;
5377 def : ARMPat<(atomic_load_32 ldst_so_reg:$src),
5378              (LDRrs ldst_so_reg:$src)>;
5379 def : ARMPat<(atomic_load_32 addrmode_imm12:$src),
5380              (LDRi12 addrmode_imm12:$src)>;
5381 def : ARMPat<(atomic_store_8 ldst_so_reg:$ptr, GPR:$val),
5382              (STRBrs GPR:$val, ldst_so_reg:$ptr)>;
5383 def : ARMPat<(atomic_store_8 addrmode_imm12:$ptr, GPR:$val),
5384              (STRBi12 GPR:$val, addrmode_imm12:$ptr)>;
5385 def : ARMPat<(atomic_store_16 addrmode3:$ptr, GPR:$val),
5386              (STRH GPR:$val, addrmode3:$ptr)>;
5387 def : ARMPat<(atomic_store_32 ldst_so_reg:$ptr, GPR:$val),
5388              (STRrs GPR:$val, ldst_so_reg:$ptr)>;
5389 def : ARMPat<(atomic_store_32 addrmode_imm12:$ptr, GPR:$val),
5390              (STRi12 GPR:$val, addrmode_imm12:$ptr)>;
5391
5392
5393 //===----------------------------------------------------------------------===//
5394 // Thumb Support
5395 //
5396
5397 include "ARMInstrThumb.td"
5398
5399 //===----------------------------------------------------------------------===//
5400 // Thumb2 Support
5401 //
5402
5403 include "ARMInstrThumb2.td"
5404
5405 //===----------------------------------------------------------------------===//
5406 // Floating Point Support
5407 //
5408
5409 include "ARMInstrVFP.td"
5410
5411 //===----------------------------------------------------------------------===//
5412 // Advanced SIMD (NEON) Support
5413 //
5414
5415 include "ARMInstrNEON.td"
5416
5417 //===----------------------------------------------------------------------===//
5418 // Assembler aliases
5419 //
5420
5421 // Memory barriers
5422 def : InstAlias<"dmb", (DMB 0xf)>, Requires<[IsARM, HasDB]>;
5423 def : InstAlias<"dsb", (DSB 0xf)>, Requires<[IsARM, HasDB]>;
5424 def : InstAlias<"isb", (ISB 0xf)>, Requires<[IsARM, HasDB]>;
5425
5426 // System instructions
5427 def : MnemonicAlias<"swi", "svc">;
5428
5429 // Load / Store Multiple
5430 def : MnemonicAlias<"ldmfd", "ldm">;
5431 def : MnemonicAlias<"ldmia", "ldm">;
5432 def : MnemonicAlias<"ldmea", "ldmdb">;
5433 def : MnemonicAlias<"stmfd", "stmdb">;
5434 def : MnemonicAlias<"stmia", "stm">;
5435 def : MnemonicAlias<"stmea", "stm">;
5436
5437 // PKHBT/PKHTB with default shift amount. PKHTB is equivalent to PKHBT when the
5438 // shift amount is zero (i.e., unspecified).
5439 def : InstAlias<"pkhbt${p} $Rd, $Rn, $Rm",
5440                 (PKHBT GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, 0, pred:$p)>,
5441         Requires<[IsARM, HasV6]>;
5442 def : InstAlias<"pkhtb${p} $Rd, $Rn, $Rm",
5443                 (PKHBT GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, 0, pred:$p)>,
5444         Requires<[IsARM, HasV6]>;
5445
5446 // PUSH/POP aliases for STM/LDM
5447 def : ARMInstAlias<"push${p} $regs", (STMDB_UPD SP, pred:$p, reglist:$regs)>;
5448 def : ARMInstAlias<"pop${p} $regs", (LDMIA_UPD SP, pred:$p, reglist:$regs)>;
5449
5450 // SSAT/USAT optional shift operand.
5451 def : ARMInstAlias<"ssat${p} $Rd, $sat_imm, $Rn",
5452                 (SSAT GPRnopc:$Rd, imm1_32:$sat_imm, GPRnopc:$Rn, 0, pred:$p)>;
5453 def : ARMInstAlias<"usat${p} $Rd, $sat_imm, $Rn",
5454                 (USAT GPRnopc:$Rd, imm0_31:$sat_imm, GPRnopc:$Rn, 0, pred:$p)>;
5455
5456
5457 // Extend instruction optional rotate operand.
5458 def : ARMInstAlias<"sxtab${p} $Rd, $Rn, $Rm",
5459                 (SXTAB GPRnopc:$Rd, GPR:$Rn, GPRnopc:$Rm, 0, pred:$p)>;
5460 def : ARMInstAlias<"sxtah${p} $Rd, $Rn, $Rm",
5461                 (SXTAH GPRnopc:$Rd, GPR:$Rn, GPRnopc:$Rm, 0, pred:$p)>;
5462 def : ARMInstAlias<"sxtab16${p} $Rd, $Rn, $Rm",
5463                 (SXTAB16 GPRnopc:$Rd, GPR:$Rn, GPRnopc:$Rm, 0, pred:$p)>;
5464 def : ARMInstAlias<"sxtb${p} $Rd, $Rm",
5465                 (SXTB GPRnopc:$Rd, GPRnopc:$Rm, 0, pred:$p)>;
5466 def : ARMInstAlias<"sxtb16${p} $Rd, $Rm",
5467                 (SXTB16 GPRnopc:$Rd, GPRnopc:$Rm, 0, pred:$p)>;
5468 def : ARMInstAlias<"sxth${p} $Rd, $Rm",
5469                 (SXTH GPRnopc:$Rd, GPRnopc:$Rm, 0, pred:$p)>;
5470
5471 def : ARMInstAlias<"uxtab${p} $Rd, $Rn, $Rm",
5472                 (UXTAB GPRnopc:$Rd, GPR:$Rn, GPRnopc:$Rm, 0, pred:$p)>;
5473 def : ARMInstAlias<"uxtah${p} $Rd, $Rn, $Rm",
5474                 (UXTAH GPRnopc:$Rd, GPR:$Rn, GPRnopc:$Rm, 0, pred:$p)>;
5475 def : ARMInstAlias<"uxtab16${p} $Rd, $Rn, $Rm",
5476                 (UXTAB16 GPRnopc:$Rd, GPR:$Rn, GPRnopc:$Rm, 0, pred:$p)>;
5477 def : ARMInstAlias<"uxtb${p} $Rd, $Rm",
5478                 (UXTB GPRnopc:$Rd, GPRnopc:$Rm, 0, pred:$p)>;
5479 def : ARMInstAlias<"uxtb16${p} $Rd, $Rm",
5480                 (UXTB16 GPRnopc:$Rd, GPRnopc:$Rm, 0, pred:$p)>;
5481 def : ARMInstAlias<"uxth${p} $Rd, $Rm",
5482                 (UXTH GPRnopc:$Rd, GPRnopc:$Rm, 0, pred:$p)>;
5483
5484
5485 // RFE aliases
5486 def : MnemonicAlias<"rfefa", "rfeda">;
5487 def : MnemonicAlias<"rfeea", "rfedb">;
5488 def : MnemonicAlias<"rfefd", "rfeia">;
5489 def : MnemonicAlias<"rfeed", "rfeib">;
5490 def : MnemonicAlias<"rfe", "rfeia">;
5491
5492 // SRS aliases
5493 def : MnemonicAlias<"srsfa", "srsib">;
5494 def : MnemonicAlias<"srsea", "srsia">;
5495 def : MnemonicAlias<"srsfd", "srsdb">;
5496 def : MnemonicAlias<"srsed", "srsda">;
5497 def : MnemonicAlias<"srs", "srsia">;
5498
5499 // QSAX == QSUBADDX
5500 def : MnemonicAlias<"qsubaddx", "qsax">;
5501 // SASX == SADDSUBX
5502 def : MnemonicAlias<"saddsubx", "sasx">;
5503 // SHASX == SHADDSUBX
5504 def : MnemonicAlias<"shaddsubx", "shasx">;
5505 // SHSAX == SHSUBADDX
5506 def : MnemonicAlias<"shsubaddx", "shsax">;
5507 // SSAX == SSUBADDX
5508 def : MnemonicAlias<"ssubaddx", "ssax">;
5509 // UASX == UADDSUBX
5510 def : MnemonicAlias<"uaddsubx", "uasx">;
5511 // UHASX == UHADDSUBX
5512 def : MnemonicAlias<"uhaddsubx", "uhasx">;
5513 // UHSAX == UHSUBADDX
5514 def : MnemonicAlias<"uhsubaddx", "uhsax">;
5515 // UQASX == UQADDSUBX
5516 def : MnemonicAlias<"uqaddsubx", "uqasx">;
5517 // UQSAX == UQSUBADDX
5518 def : MnemonicAlias<"uqsubaddx", "uqsax">;
5519 // USAX == USUBADDX
5520 def : MnemonicAlias<"usubaddx", "usax">;
5521
5522 // "mov Rd, so_imm_not" can be handled via "mvn" in assembly, just like
5523 // for isel.
5524 def : ARMInstAlias<"mov${s}${p} $Rd, $imm",
5525                    (MVNi rGPR:$Rd, so_imm_not:$imm, pred:$p, cc_out:$s)>;
5526 def : ARMInstAlias<"mvn${s}${p} $Rd, $imm",
5527                    (MOVi rGPR:$Rd, so_imm_not:$imm, pred:$p, cc_out:$s)>;
5528 // Same for AND <--> BIC
5529 def : ARMInstAlias<"bic${s}${p} $Rd, $Rn, $imm",
5530                    (ANDri rGPR:$Rd, rGPR:$Rn, so_imm_not:$imm,
5531                           pred:$p, cc_out:$s)>;
5532 def : ARMInstAlias<"bic${s}${p} $Rdn, $imm",
5533                    (ANDri rGPR:$Rdn, rGPR:$Rdn, so_imm_not:$imm,
5534                           pred:$p, cc_out:$s)>;
5535 def : ARMInstAlias<"and${s}${p} $Rd, $Rn, $imm",
5536                    (BICri rGPR:$Rd, rGPR:$Rn, so_imm_not:$imm,
5537                           pred:$p, cc_out:$s)>;
5538 def : ARMInstAlias<"and${s}${p} $Rdn, $imm",
5539                    (BICri rGPR:$Rdn, rGPR:$Rdn, so_imm_not:$imm,
5540                           pred:$p, cc_out:$s)>;
5541
5542 // Likewise, "add Rd, so_imm_neg" -> sub
5543 def : ARMInstAlias<"add${s}${p} $Rd, $Rn, $imm",
5544                  (SUBri GPR:$Rd, GPR:$Rn, so_imm_neg:$imm, pred:$p, cc_out:$s)>;
5545 def : ARMInstAlias<"add${s}${p} $Rd, $imm",
5546                  (SUBri GPR:$Rd, GPR:$Rd, so_imm_neg:$imm, pred:$p, cc_out:$s)>;
5547 // Same for CMP <--> CMN via so_imm_neg
5548 def : ARMInstAlias<"cmp${p} $Rd, $imm",
5549                    (CMNri rGPR:$Rd, so_imm_neg:$imm, pred:$p)>;
5550 def : ARMInstAlias<"cmn${p} $Rd, $imm",
5551                    (CMPri rGPR:$Rd, so_imm_neg:$imm, pred:$p)>;
5552
5553 // The shifter forms of the MOV instruction are aliased to the ASR, LSL,
5554 // LSR, ROR, and RRX instructions.
5555 // FIXME: We need C++ parser hooks to map the alias to the MOV
5556 //        encoding. It seems we should be able to do that sort of thing
5557 //        in tblgen, but it could get ugly.
5558 let TwoOperandAliasConstraint = "$Rm = $Rd" in {
5559 def ASRi : ARMAsmPseudo<"asr${s}${p} $Rd, $Rm, $imm",
5560                         (ins GPR:$Rd, GPR:$Rm, imm0_32:$imm, pred:$p,
5561                              cc_out:$s)>;
5562 def LSRi : ARMAsmPseudo<"lsr${s}${p} $Rd, $Rm, $imm",
5563                         (ins GPR:$Rd, GPR:$Rm, imm0_32:$imm, pred:$p,
5564                              cc_out:$s)>;
5565 def LSLi : ARMAsmPseudo<"lsl${s}${p} $Rd, $Rm, $imm",
5566                         (ins GPR:$Rd, GPR:$Rm, imm0_31:$imm, pred:$p,
5567                              cc_out:$s)>;
5568 def RORi : ARMAsmPseudo<"ror${s}${p} $Rd, $Rm, $imm",
5569                         (ins GPR:$Rd, GPR:$Rm, imm0_31:$imm, pred:$p,
5570                              cc_out:$s)>;
5571 }
5572 def RRXi : ARMAsmPseudo<"rrx${s}${p} $Rd, $Rm",
5573                         (ins GPR:$Rd, GPR:$Rm, pred:$p, cc_out:$s)>;
5574 let TwoOperandAliasConstraint = "$Rn = $Rd" in {
5575 def ASRr : ARMAsmPseudo<"asr${s}${p} $Rd, $Rn, $Rm",
5576                         (ins GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, pred:$p,
5577                              cc_out:$s)>;
5578 def LSRr : ARMAsmPseudo<"lsr${s}${p} $Rd, $Rn, $Rm",
5579                         (ins GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, pred:$p,
5580                              cc_out:$s)>;
5581 def LSLr : ARMAsmPseudo<"lsl${s}${p} $Rd, $Rn, $Rm",
5582                         (ins GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, pred:$p,
5583                              cc_out:$s)>;
5584 def RORr : ARMAsmPseudo<"ror${s}${p} $Rd, $Rn, $Rm",
5585                         (ins GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, pred:$p,
5586                              cc_out:$s)>;
5587 }
5588
5589 // "neg" is and alias for "rsb rd, rn, #0"
5590 def : ARMInstAlias<"neg${s}${p} $Rd, $Rm",
5591                    (RSBri GPR:$Rd, GPR:$Rm, 0, pred:$p, cc_out:$s)>;
5592
5593 // Pre-v6, 'mov r0, r0' was used as a NOP encoding.
5594 def : InstAlias<"nop${p}", (MOVr R0, R0, pred:$p, zero_reg)>,
5595          Requires<[IsARM, NoV6]>;
5596
5597 // MUL/UMLAL/SMLAL/UMULL/SMULL are available on all arches, but
5598 // the instruction definitions need difference constraints pre-v6.
5599 // Use these aliases for the assembly parsing on pre-v6.
5600 def : InstAlias<"mul${s}${p} $Rd, $Rn, $Rm",
5601             (MUL GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, pred:$p, cc_out:$s)>,
5602          Requires<[IsARM, NoV6]>;
5603 def : InstAlias<"mla${s}${p} $Rd, $Rn, $Rm, $Ra",
5604             (MLA GPRnopc:$Rd, GPRnopc:$Rn, GPRnopc:$Rm, GPRnopc:$Ra,
5605              pred:$p, cc_out:$s)>,
5606          Requires<[IsARM, NoV6]>;
5607 def : InstAlias<"smlal${s}${p} $RdLo, $RdHi, $Rn, $Rm",
5608             (SMLAL GPR:$RdLo, GPR:$RdHi, GPR:$Rn, GPR:$Rm, pred:$p, cc_out:$s)>,
5609          Requires<[IsARM, NoV6]>;
5610 def : InstAlias<"umlal${s}${p} $RdLo, $RdHi, $Rn, $Rm",
5611             (UMLAL GPR:$RdLo, GPR:$RdHi, GPR:$Rn, GPR:$Rm, pred:$p, cc_out:$s)>,
5612          Requires<[IsARM, NoV6]>;
5613 def : InstAlias<"smull${s}${p} $RdLo, $RdHi, $Rn, $Rm",
5614             (SMULL GPR:$RdLo, GPR:$RdHi, GPR:$Rn, GPR:$Rm, pred:$p, cc_out:$s)>,
5615          Requires<[IsARM, NoV6]>;
5616 def : InstAlias<"umull${s}${p} $RdLo, $RdHi, $Rn, $Rm",
5617             (UMULL GPR:$RdLo, GPR:$RdHi, GPR:$Rn, GPR:$Rm, pred:$p, cc_out:$s)>,
5618          Requires<[IsARM, NoV6]>;
5619
5620 // 'it' blocks in ARM mode just validate the predicates. The IT itself
5621 // is discarded.
5622 def ITasm : ARMAsmPseudo<"it$mask $cc", (ins it_pred:$cc, it_mask:$mask)>,
5623          ComplexDeprecationPredicate<"IT">;
5624
5625 let mayLoad = 1, mayStore =1, hasSideEffects = 1 in
5626 def SPACE : PseudoInst<(outs GPR:$Rd), (ins i32imm:$size, GPR:$Rn),
5627                        NoItinerary,
5628                        [(set GPR:$Rd, (int_arm_space imm:$size, GPR:$Rn))]>;