lib/Target/ARM/ARM.td

   1 //===-- ARM.td - Describe the ARM Target Machine -----------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //
  11 //===----------------------------------------------------------------------===//
  12
  13 //===----------------------------------------------------------------------===//
  14 // Target-independent interfaces which we are implementing
  15 //===----------------------------------------------------------------------===//
  16
  17 include "llvm/Target/Target.td"
  18
  19 //===----------------------------------------------------------------------===//
  20 // ARM Subtarget state.
  21 //
  22
  23 def ModeThumb  : SubtargetFeature<"thumb-mode", "InThumbMode", "true",
  24                                   "Thumb mode">;
  25
  26 //===----------------------------------------------------------------------===//
  27 // ARM Subtarget features.
  28 //
  29
  30 def FeatureVFP2 : SubtargetFeature<"vfp2", "HasVFPv2", "true",
  31                                    "Enable VFP2 instructions">;
  32 def FeatureVFP3 : SubtargetFeature<"vfp3", "HasVFPv3", "true",
  33                                    "Enable VFP3 instructions",
  34                                    [FeatureVFP2]>;
  35 def FeatureVFP4 : SubtargetFeature<"vfp4", "HasVFPv4", "true",
  36                                    "Enable VFP4 instructions",
  37                                    [FeatureVFP3]>;
  38 def FeatureNEON : SubtargetFeature<"neon", "HasNEON", "true",
  39                                    "Enable NEON instructions",
  40                                    [FeatureVFP3]>;
  41 def FeatureThumb2 : SubtargetFeature<"thumb2", "HasThumb2", "true",
  42                                      "Enable Thumb2 instructions">;
  43 def FeatureNoARM  : SubtargetFeature<"noarm", "NoARM", "true",
  44                                      "Does not support ARM mode execution">;
  45 def FeatureFP16   : SubtargetFeature<"fp16", "HasFP16", "true",
  46                                      "Enable half-precision floating point">;
  47 def FeatureD16    : SubtargetFeature<"d16", "HasD16", "true",
  48                                      "Restrict VFP3 to 16 double registers">;
  49 def FeatureHWDiv  : SubtargetFeature<"hwdiv", "HasHardwareDivide", "true",
  50                                      "Enable divide instructions">;
  51 def FeatureT2XtPk : SubtargetFeature<"t2xtpk", "HasT2ExtractPack", "true",
  52                                  "Enable Thumb2 extract and pack instructions">;
  53 def FeatureDB     : SubtargetFeature<"db", "HasDataBarrier", "true",
  54                                    "Has data barrier (dmb / dsb) instructions">;
  55 def FeatureSlowFPBrcc : SubtargetFeature<"slow-fp-brcc", "SlowFPBrcc", "true",
  56                                          "FP compare + branch is slow">;
  57 def FeatureVFPOnlySP : SubtargetFeature<"fp-only-sp", "FPOnlySP", "true",
  58                           "Floating point unit supports single precision only">;
  59
  60 // Some processors have FP multiply-accumulate instructions that don't
  61 // play nicely with other VFP / NEON instructions, and it's generally better
  62 // to just not use them.
  63 def FeatureHasSlowFPVMLx : SubtargetFeature<"slowfpvmlx", "SlowFPVMLx", "true",
  64                                          "Disable VFP / NEON MAC instructions">;
  65
  66 // Cortex-A8 / A9 Advanced SIMD has multiplier accumulator forwarding.
  67 def FeatureVMLxForwarding : SubtargetFeature<"vmlx-forwarding",
  68                                        "HasVMLxForwarding", "true",
  69                                        "Has multiplier accumulator forwarding">;
  70
  71 // Some processors benefit from using NEON instructions for scalar
  72 // single-precision FP operations.
  73 def FeatureNEONForFP : SubtargetFeature<"neonfp", "UseNEONForSinglePrecisionFP",
  74                                         "true",
  75                                         "Use NEON for single precision FP">;
  76
  77 // Disable 32-bit to 16-bit narrowing for experimentation.
  78 def FeaturePref32BitThumb : SubtargetFeature<"32bit", "Pref32BitThumb", "true",
  79                                              "Prefer 32-bit Thumb instrs">;
  80
  81 /// Some instructions update CPSR partially, which can add false dependency for
  82 /// out-of-order implementation, e.g. Cortex-A9, unless each individual bit is
  83 /// mapped to a separate physical register. Avoid partial CPSR update for these
  84 /// processors.
  85 def FeatureAvoidPartialCPSR : SubtargetFeature<"avoid-partial-cpsr",
  86                                                "AvoidCPSRPartialUpdate", "true",
  87                                  "Avoid CPSR partial update for OOO execution">;
  88
  89 // Some processors perform return stack prediction. CodeGen should avoid issue
  90 // "normal" call instructions to callees which do not return.
  91 def FeatureHasRAS : SubtargetFeature<"ras", "HasRAS", "true",
  92                                      "Has return address stack">;
  93
  94 /// Some M architectures don't have the DSP extension (v7E-M vs. v7M)
  95 def FeatureDSPThumb2 : SubtargetFeature<"t2dsp", "Thumb2DSP", "true",
  96                                  "Supports v7 DSP instructions in Thumb2">;
  97
  98 // Multiprocessing extension.
  99 def FeatureMP : SubtargetFeature<"mp", "HasMPExtension", "true",
 100                                  "Supports Multiprocessing extension">;
 101
 102 // M-series ISA?
 103 def FeatureMClass : SubtargetFeature<"mclass", "IsMClass", "true",
 104                                      "Is microcontroller profile ('M' series)">;
 105
 106 // ARM ISAs.
 107 def HasV4TOps   : SubtargetFeature<"v4t", "HasV4TOps", "true",
 108                                    "Support ARM v4T instructions">;
 109 def HasV5TOps   : SubtargetFeature<"v5t", "HasV5TOps", "true",
 110                                    "Support ARM v5T instructions",
 111                                    [HasV4TOps]>;
 112 def HasV5TEOps  : SubtargetFeature<"v5te", "HasV5TEOps", "true",
 113                              "Support ARM v5TE, v5TEj, and v5TExp instructions",
 114                                    [HasV5TOps]>;
 115 def HasV6Ops    : SubtargetFeature<"v6", "HasV6Ops", "true",
 116                                    "Support ARM v6 instructions",
 117                                    [HasV5TEOps]>;
 118 def HasV6T2Ops  : SubtargetFeature<"v6t2", "HasV6T2Ops", "true",
 119                                    "Support ARM v6t2 instructions",
 120                                    [HasV6Ops, FeatureThumb2]>;
 121 def HasV7Ops    : SubtargetFeature<"v7", "HasV7Ops", "true",
 122                                    "Support ARM v7 instructions",
 123                                    [HasV6T2Ops]>;
 124
 125 //===----------------------------------------------------------------------===//
 126 // ARM Processors supported.
 127 //
 128
 129 include "ARMSchedule.td"
 130
 131 // ARM processor families.
 132 def ProcA8      : SubtargetFeature<"a8", "ARMProcFamily", "CortexA8",
 133                                    "Cortex-A8 ARM processors",
 134                                    [FeatureSlowFPBrcc, FeatureNEONForFP,
 135                                     FeatureHasSlowFPVMLx, FeatureVMLxForwarding,
 136                                     FeatureT2XtPk]>;
 137 def ProcA9      : SubtargetFeature<"a9", "ARMProcFamily", "CortexA9",
 138                                    "Cortex-A9 ARM processors",
 139                                    [FeatureVMLxForwarding,
 140                                     FeatureT2XtPk, FeatureFP16,
 141                                     FeatureAvoidPartialCPSR]>;
 142 // FIXME: It has not been determined if A15 has these features.
 143 def ProcA15      : SubtargetFeature<"a15", "ARMProcFamily", "CortexA15",
 144                                    "Cortex-A15 ARM processors",
 145                                    [FeatureVMLxForwarding,
 146                                     FeatureT2XtPk, FeatureFP16,
 147                                     FeatureAvoidPartialCPSR]>;
 148
 149 class ProcNoItin<string Name, list<SubtargetFeature> Features>
 150  : Processor<Name, NoItineraries, Features>;
 151
 152 // V4 Processors.
 153 def : ProcNoItin<"generic",         []>;
 154 def : ProcNoItin<"arm8",            []>;
 155 def : ProcNoItin<"arm810",          []>;
 156 def : ProcNoItin<"strongarm",       []>;
 157 def : ProcNoItin<"strongarm110",    []>;
 158 def : ProcNoItin<"strongarm1100",   []>;
 159 def : ProcNoItin<"strongarm1110",   []>;
 160
 161 // V4T Processors.
 162 def : ProcNoItin<"arm7tdmi",        [HasV4TOps]>;
 163 def : ProcNoItin<"arm7tdmi-s",      [HasV4TOps]>;
 164 def : ProcNoItin<"arm710t",         [HasV4TOps]>;
 165 def : ProcNoItin<"arm720t",         [HasV4TOps]>;
 166 def : ProcNoItin<"arm9",            [HasV4TOps]>;
 167 def : ProcNoItin<"arm9tdmi",        [HasV4TOps]>;
 168 def : ProcNoItin<"arm920",          [HasV4TOps]>;
 169 def : ProcNoItin<"arm920t",         [HasV4TOps]>;
 170 def : ProcNoItin<"arm922t",         [HasV4TOps]>;
 171 def : ProcNoItin<"arm940t",         [HasV4TOps]>;
 172 def : ProcNoItin<"ep9312",          [HasV4TOps]>;
 173
 174 // V5T Processors.
 175 def : ProcNoItin<"arm10tdmi",       [HasV5TOps]>;
 176 def : ProcNoItin<"arm1020t",        [HasV5TOps]>;
 177
 178 // V5TE Processors.
 179 def : ProcNoItin<"arm9e",           [HasV5TEOps]>;
 180 def : ProcNoItin<"arm926ej-s",      [HasV5TEOps]>;
 181 def : ProcNoItin<"arm946e-s",       [HasV5TEOps]>;
 182 def : ProcNoItin<"arm966e-s",       [HasV5TEOps]>;
 183 def : ProcNoItin<"arm968e-s",       [HasV5TEOps]>;
 184 def : ProcNoItin<"arm10e",          [HasV5TEOps]>;
 185 def : ProcNoItin<"arm1020e",        [HasV5TEOps]>;
 186 def : ProcNoItin<"arm1022e",        [HasV5TEOps]>;
 187 def : ProcNoItin<"xscale",          [HasV5TEOps]>;
 188 def : ProcNoItin<"iwmmxt",          [HasV5TEOps]>;
 189
 190 // V6 Processors.
 191 def : Processor<"arm1136j-s",       ARMV6Itineraries, [HasV6Ops]>;
 192 def : Processor<"arm1136jf-s",      ARMV6Itineraries, [HasV6Ops, FeatureVFP2,
 193                                                        FeatureHasSlowFPVMLx]>;
 194 def : Processor<"arm1176jz-s",      ARMV6Itineraries, [HasV6Ops]>;
 195 def : Processor<"arm1176jzf-s",     ARMV6Itineraries, [HasV6Ops, FeatureVFP2,
 196                                                        FeatureHasSlowFPVMLx]>;
 197 def : Processor<"mpcorenovfp",      ARMV6Itineraries, [HasV6Ops]>;
 198 def : Processor<"mpcore",           ARMV6Itineraries, [HasV6Ops, FeatureVFP2,
 199                                                        FeatureHasSlowFPVMLx]>;
 200
 201 // V6M Processors.
 202 def : Processor<"cortex-m0",        ARMV6Itineraries, [HasV6Ops, FeatureNoARM,
 203                                                        FeatureDB, FeatureMClass]>;
 204
 205 // V6T2 Processors.
 206 def : Processor<"arm1156t2-s",      ARMV6Itineraries, [HasV6T2Ops,
 207                                                        FeatureDSPThumb2]>;
 208 def : Processor<"arm1156t2f-s",     ARMV6Itineraries, [HasV6T2Ops, FeatureVFP2,
 209                                                        FeatureHasSlowFPVMLx,
 210                                                        FeatureDSPThumb2]>;
 211
 212 // V7a Processors.
 213 def : ProcessorModel<"cortex-a8",   CortexA8Model,
 214                                     [ProcA8, HasV7Ops, FeatureNEON, FeatureDB,
 215                                      FeatureDSPThumb2, FeatureHasRAS]>;
 216 def : ProcessorModel<"cortex-a9",   CortexA9Model,
 217                                     [ProcA9, HasV7Ops, FeatureNEON, FeatureDB,
 218                                      FeatureDSPThumb2, FeatureHasRAS]>;
 219 def : ProcessorModel<"cortex-a9-mp", CortexA9Model,
 220                                     [ProcA9, HasV7Ops, FeatureNEON, FeatureDB,
 221                                      FeatureDSPThumb2, FeatureMP,
 222                                      FeatureHasRAS]>;
 223 // FIXME: A15 has currently the same ProcessorModel as A9.
 224 def : ProcessorModel<"cortex-a15",   CortexA9Model,
 225                                     [ProcA15, HasV7Ops, FeatureNEON, FeatureDB,
 226                                      FeatureDSPThumb2, FeatureHasRAS]>;
 227
 228 // V7M Processors.
 229 def : ProcNoItin<"cortex-m3",       [HasV7Ops,
 230                                      FeatureThumb2, FeatureNoARM, FeatureDB,
 231                                      FeatureHWDiv, FeatureMClass]>;
 232
 233 // V7EM Processors.
 234 def : ProcNoItin<"cortex-m4",       [HasV7Ops,
 235                                      FeatureThumb2, FeatureNoARM, FeatureDB,
 236                                      FeatureHWDiv, FeatureDSPThumb2,
 237                                      FeatureT2XtPk, FeatureVFP4,
 238                                      FeatureVFPOnlySP, FeatureMClass]>;
 239
 240 //===----------------------------------------------------------------------===//
 241 // Register File Description
 242 //===----------------------------------------------------------------------===//
 243
 244 include "ARMRegisterInfo.td"
 245
 246 include "ARMCallingConv.td"
 247
 248 //===----------------------------------------------------------------------===//
 249 // Instruction Descriptions
 250 //===----------------------------------------------------------------------===//
 251
 252 include "ARMInstrInfo.td"
 253
 254 def ARMInstrInfo : InstrInfo;
 255
 256
 257 //===----------------------------------------------------------------------===//
 258 // Assembly printer
 259 //===----------------------------------------------------------------------===//
 260 // ARM Uses the MC printer for asm output, so make sure the TableGen
 261 // AsmWriter bits get associated with the correct class.
 262 def ARMAsmWriter : AsmWriter {
 263   string AsmWriterClassName  = "InstPrinter";
 264   bit isMCAsmWriter = 1;
 265 }
 266
 267 //===----------------------------------------------------------------------===//
 268 // Declare the target which we are implementing
 269 //===----------------------------------------------------------------------===//
 270
 271 def ARM : Target {
 272   // Pull in Instruction Info:
 273   let InstructionSet = ARMInstrInfo;
 274
 275   let AssemblyWriters = [ARMAsmWriter];
 276 }