include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 //===----------------------------------------------------------------------===//
  59 // Types used by intrinsics.
  60 //===----------------------------------------------------------------------===//
  61
  62 class LLVMType<ValueType vt> {
  63   ValueType VT = vt;
  64 }
  65
  66 class LLVMPointerType<LLVMType elty>
  67   : LLVMType<iPTR>{
  68   LLVMType ElTy = elty;
  69 }
  70
  71 class LLVMAnyPointerType<LLVMType elty>
  72   : LLVMType<iPTRAny>{
  73   LLVMType ElTy = elty;
  74 }
  75
  76 // Match the type of another intrinsic parameter.  Number is an index into the
  77 // list of overloaded types for the intrinsic, excluding all the fixed types.
  78 // The Number value must refer to a previously listed type.  For example:
  79 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  80 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  81 // refers to the first overloaded type, which is the 2nd argument.
  82 class LLVMMatchType<int num>
  83   : LLVMType<OtherVT>{
  84   int Number = num;
  85 }
  86
  87 // Match the type of another intrinsic parameter that is expected to be
  88 // an integral vector type, but change the element size to be twice as wide
  89 // or half as wide as the other type.  This is only useful when the intrinsic
  90 // is overloaded, so the matched type should be declared as iAny.
  91 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  92 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  93
  94 def llvm_void_ty       : LLVMType<isVoid>;
  95 def llvm_anyint_ty     : LLVMType<iAny>;
  96 def llvm_anyfloat_ty   : LLVMType<fAny>;
  97 def llvm_anyvector_ty  : LLVMType<vAny>;
  98 def llvm_i1_ty         : LLVMType<i1>;
  99 def llvm_i8_ty         : LLVMType<i8>;
 100 def llvm_i16_ty        : LLVMType<i16>;
 101 def llvm_i32_ty        : LLVMType<i32>;
 102 def llvm_i64_ty        : LLVMType<i64>;
 103 def llvm_float_ty      : LLVMType<f32>;
 104 def llvm_double_ty     : LLVMType<f64>;
 105 def llvm_f80_ty        : LLVMType<f80>;
 106 def llvm_f128_ty       : LLVMType<f128>;
 107 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 108 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 109 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 110 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 111 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 112 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 113 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 114
 115 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 116 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 117
 118 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 119 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 120 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 121 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 122 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 123 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 124 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 125 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 126 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 127 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 128 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 129 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 130 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 131 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 132 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 133
 134 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 135 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 136 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 137 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 138 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 139
 140 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 141
 142
 143 //===----------------------------------------------------------------------===//
 144 // Intrinsic Definitions.
 145 //===----------------------------------------------------------------------===//
 146
 147 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 148 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 149 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 150 // example, llvm.bswap.i16 -> int_bswap_i16.
 151 //
 152 //  * RetTypes is a list containing the return types expected for the
 153 //    intrinsic.
 154 //  * ParamTypes is a list containing the parameter types expected for the
 155 //    intrinsic.
 156 //  * Properties can be set to describe the behavior of the intrinsic.
 157 //
 158 class Intrinsic<list<LLVMType> ret_types,
 159                 list<LLVMType> param_types = [],
 160                 list<IntrinsicProperty> properties = [],
 161                 string name = ""> {
 162   string LLVMName = name;
 163   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 164   list<LLVMType> RetTypes = ret_types;
 165   list<LLVMType> ParamTypes = param_types;
 166   list<IntrinsicProperty> Properties = properties;
 167
 168   bit isTarget = 0;
 169 }
 170
 171 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 172 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 173 /// support.
 174 class GCCBuiltin<string name> {
 175   string GCCBuiltinName = name;
 176 }
 177
 178
 179 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 180 //
 181
 182 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 183 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 184                             "llvm.va_copy">;
 185 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 186
 187 //===------------------- Garbage Collection Intrinsics --------------------===//
 188 //
 189 def int_gcroot  : Intrinsic<[],
 190                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 191 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 192                             [llvm_ptr_ty, llvm_ptrptr_ty],
 193                             [IntrReadArgMem]>;
 194 def int_gcwrite : Intrinsic<[],
 195                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 196                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 197
 198 //===--------------------- Code Generator Intrinsics ----------------------===//
 199 //
 200 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 201 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 202
 203 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 204 // model their dependencies on allocas.
 205 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 206                         GCCBuiltin<"__builtin_stack_save">;
 207 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 208                         GCCBuiltin<"__builtin_stack_restore">;
 209
 210 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 211 // however it does conveniently prevent the prefetch from being reordered
 212 // with respect to nearby accesses to the same memory.
 213 def int_prefetch      : Intrinsic<[],
 214                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 215                                    llvm_i32_ty],
 216                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 217 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 218
 219 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 220
 221 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 222 // guard to the correct place on the stack frame.
 223 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 224
 225 //===------------------- Standard C Library Intrinsics --------------------===//
 226 //
 227
 228 def int_memcpy  : Intrinsic<[],
 229                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 230                               llvm_i32_ty, llvm_i1_ty],
 231                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 232 def int_memmove : Intrinsic<[],
 233                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 234                              llvm_i32_ty, llvm_i1_ty],
 235                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 236 def int_memset  : Intrinsic<[],
 237                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 238                              llvm_i32_ty, llvm_i1_ty],
 239                             [IntrReadWriteArgMem, NoCapture<0>]>;
 240
 241 // These functions do not actually read memory, but they are sensitive to the
 242 // rounding mode.  This needs to be modelled separately; in the meantime
 243 // declaring them as reading memory is conservatively correct.
 244 let Properties = [IntrReadMem] in {
 245   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 246   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 247   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 248   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 249   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 250                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 251   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 252   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 253   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 254   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 255   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 256 }
 257
 258 let Properties = [IntrNoMem] in {
 259   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 260                          [LLVMMatchType<0>, LLVMMatchType<0>,
 261                           LLVMMatchType<0>]>;
 262 }
 263
 264 // NOTE: these are internal interfaces.
 265 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 266 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 267 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 268 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 269
 270 // Internal interface for object size checking
 271 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 272                                [IntrNoMem]>,
 273                                GCCBuiltin<"__builtin_object_size">;
 274
 275 //===------------------------- Expect Intrinsics --------------------------===//
 276 //
 277 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 278                                               LLVMMatchType<0>], [IntrNoMem]>;
 279
 280 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 281 //
 282
 283 // None of these intrinsics accesses memory at all.
 284 let Properties = [IntrNoMem] in {
 285   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 286   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 287   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 288   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 289 }
 290
 291 //===------------------------ Debugger Intrinsics -------------------------===//
 292 //
 293
 294 // None of these intrinsics accesses memory at all...but that doesn't mean the
 295 // optimizers can change them aggressively.  Special handling needed in a few
 296 // places.
 297 let Properties = [IntrNoMem] in {
 298   def int_dbg_declare      : Intrinsic<[],
 299                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 300   def int_dbg_value        : Intrinsic<[],
 301                                        [llvm_metadata_ty, llvm_i64_ty,
 302                                         llvm_metadata_ty]>;
 303 }
 304
 305 //===------------------ Exception Handling Intrinsics----------------------===//
 306 //
 307 def int_eh_exception : Intrinsic<[llvm_ptr_ty], [], [IntrReadMem]>;
 308 def int_eh_selector  : Intrinsic<[llvm_i32_ty],
 309                                  [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 310 def int_eh_resume    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [Throws]>;
 311
 312 // The result of eh.typeid.for depends on the enclosing function, but inside a
 313 // given function it is 'const' and may be CSE'd etc.
 314 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 315
 316 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 317 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 318
 319 def int_eh_unwind_init: Intrinsic<[]>,
 320                         GCCBuiltin<"__builtin_unwind_init">;
 321
 322 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 323
 324 let Properties = [IntrNoMem] in {
 325   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 326   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 327   def int_eh_sjlj_functioncontext  : Intrinsic<[], [llvm_ptr_ty]>;
 328 }
 329 def int_eh_sjlj_dispatch_setup : Intrinsic<[], [llvm_i32_ty]>;
 330 def int_eh_sjlj_setjmp         : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 331 def int_eh_sjlj_longjmp        : Intrinsic<[], [llvm_ptr_ty]>;
 332
 333 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 334 //
 335 def int_var_annotation : Intrinsic<[],
 336                                    [llvm_ptr_ty, llvm_ptr_ty,
 337                                     llvm_ptr_ty, llvm_i32_ty],
 338                                    [], "llvm.var.annotation">;
 339 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 340                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 341                                     llvm_i32_ty],
 342                                    [], "llvm.ptr.annotation">;
 343 def int_annotation : Intrinsic<[llvm_anyint_ty],
 344                                [LLVMMatchType<0>, llvm_ptr_ty,
 345                                 llvm_ptr_ty, llvm_i32_ty],
 346                                [], "llvm.annotation">;
 347
 348 //===------------------------ Trampoline Intrinsics -----------------------===//
 349 //
 350 def int_init_trampoline : Intrinsic<[],
 351                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 352                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 353                                    GCCBuiltin<"__builtin_init_trampoline">;
 354
 355 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 356                                       [IntrReadArgMem]>,
 357                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 358
 359 //===------------------------ Overflow Intrinsics -------------------------===//
 360 //
 361
 362 // Expose the carry flag from add operations on two integrals.
 363 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 364                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 365                                        [IntrNoMem]>;
 366 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 367                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 368                                        [IntrNoMem]>;
 369
 370 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 371                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 372                                        [IntrNoMem]>;
 373 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 374                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 375                                        [IntrNoMem]>;
 376
 377 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 378                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 379                                        [IntrNoMem]>;
 380 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 381                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 382                                        [IntrNoMem]>;
 383
 384 //===------------------------- Atomic Intrinsics --------------------------===//
 385 //
 386 def int_memory_barrier : Intrinsic<[],
 387                                    [llvm_i1_ty, llvm_i1_ty,
 388                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 389                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 390
 391 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 392                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 393                                      LLVMMatchType<0>, LLVMMatchType<0>],
 394                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 395                            GCCBuiltin<"__sync_val_compare_and_swap">;
 396 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 397                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 398                                      LLVMMatchType<0>],
 399                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 400                            GCCBuiltin<"__sync_fetch_and_add">;
 401 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 402                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 403                                      LLVMMatchType<0>],
 404                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 405                            GCCBuiltin<"__sync_lock_test_and_set">;
 406 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 407                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 408                                      LLVMMatchType<0>],
 409                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 410                            GCCBuiltin<"__sync_fetch_and_sub">;
 411 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 412                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 413                                      LLVMMatchType<0>],
 414                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 415                            GCCBuiltin<"__sync_fetch_and_and">;
 416 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 417                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 418                                       LLVMMatchType<0>],
 419                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 420                            GCCBuiltin<"__sync_fetch_and_or">;
 421 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 422                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 423                                      LLVMMatchType<0>],
 424                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 425                            GCCBuiltin<"__sync_fetch_and_xor">;
 426 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 427                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 428                                       LLVMMatchType<0>],
 429                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 430                            GCCBuiltin<"__sync_fetch_and_nand">;
 431 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 432                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 433                                       LLVMMatchType<0>],
 434                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 435                            GCCBuiltin<"__sync_fetch_and_min">;
 436 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 437                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 438                                       LLVMMatchType<0>],
 439                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 440                            GCCBuiltin<"__sync_fetch_and_max">;
 441 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 442                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 443                                       LLVMMatchType<0>],
 444                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 445                            GCCBuiltin<"__sync_fetch_and_umin">;
 446 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 447                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 448                                       LLVMMatchType<0>],
 449                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 450                            GCCBuiltin<"__sync_fetch_and_umax">;
 451
 452 //===------------------------- Memory Use Markers -------------------------===//
 453 //
 454 def int_lifetime_start  : Intrinsic<[],
 455                                     [llvm_i64_ty, llvm_ptr_ty],
 456                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 457 def int_lifetime_end    : Intrinsic<[],
 458                                     [llvm_i64_ty, llvm_ptr_ty],
 459                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 460 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 461                                     [llvm_i64_ty, llvm_ptr_ty],
 462                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 463 def int_invariant_end   : Intrinsic<[],
 464                                     [llvm_descriptor_ty, llvm_i64_ty,
 465                                      llvm_ptr_ty],
 466                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 467
 468 //===-------------------------- Other Intrinsics --------------------------===//
 469 //
 470 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 471                      GCCBuiltin<"__builtin_flt_rounds">;
 472 def int_trap : Intrinsic<[]>,
 473                GCCBuiltin<"__builtin_trap">;
 474
 475 // Intrisics to support half precision floating point format
 476 let Properties = [IntrNoMem] in {
 477 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 478                             GCCBuiltin<"__gnu_f2h_ieee">;
 479 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 480                             GCCBuiltin<"__gnu_h2f_ieee">;
 481 }
 482
 483 // These convert intrinsics are to support various conversions between
 484 // various types with rounding and saturation. NOTE: avoid using these
 485 // intrinsics as they might be removed sometime in the future and
 486 // most targets don't support them.
 487 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 488                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 489 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 490                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 491 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 492                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 493 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 494                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 495 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 496                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 497 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 498                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 499 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 500                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 501 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 502                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 503 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 504                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 505
 506 //===----------------------------------------------------------------------===//
 507 // Target-specific intrinsics
 508 //===----------------------------------------------------------------------===//
 509
 510 include "llvm/IntrinsicsPowerPC.td"
 511 include "llvm/IntrinsicsX86.td"
 512 include "llvm/IntrinsicsARM.td"
 513 include "llvm/IntrinsicsCellSPU.td"
 514 include "llvm/IntrinsicsAlpha.td"
 515 include "llvm/IntrinsicsXCore.td"
 516 include "llvm/IntrinsicsPTX.td"