include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 // IntrNoduplicate - Calls to this intrinsic cannot be duplicated.
  73 // Parallels the noduplicate attribute on LLVM IR functions.
  74 def IntrNoDuplicate : IntrinsicProperty;
  75
  76 //===----------------------------------------------------------------------===//
  77 // Types used by intrinsics.
  78 //===----------------------------------------------------------------------===//
  79
  80 class LLVMType<ValueType vt> {
  81   ValueType VT = vt;
  82 }
  83
  84 class LLVMQualPointerType<LLVMType elty, int addrspace>
  85   : LLVMType<iPTR>{
  86   LLVMType ElTy = elty;
  87   int AddrSpace = addrspace;
  88 }
  89
  90 class LLVMPointerType<LLVMType elty>
  91   : LLVMQualPointerType<elty, 0>;
  92
  93 class LLVMAnyPointerType<LLVMType elty>
  94   : LLVMType<iPTRAny>{
  95   LLVMType ElTy = elty;
  96 }
  97
  98 // Match the type of another intrinsic parameter.  Number is an index into the
  99 // list of overloaded types for the intrinsic, excluding all the fixed types.
 100 // The Number value must refer to a previously listed type.  For example:
 101 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
 102 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
 103 // refers to the first overloaded type, which is the 2nd argument.
 104 class LLVMMatchType<int num>
 105   : LLVMType<OtherVT>{
 106   int Number = num;
 107 }
 108
 109 // Match the type of another intrinsic parameter that is expected to be based on
 110 // an integral type (i.e. either iN or <N x iM>), but change the scalar size to
 111 // be twice as wide or half as wide as the other type.  This is only useful when
 112 // the intrinsic is overloaded, so the matched type should be declared as iAny.
 113 class LLVMExtendedType<int num> : LLVMMatchType<num>;
 114 class LLVMTruncatedType<int num> : LLVMMatchType<num>;
 115
 116 // Match the type of another intrinsic parameter that is expected to be a
 117 // vector type, but change the element count to be half as many
 118 class LLVMHalfElementsVectorType<int num> : LLVMMatchType<num>;
 119
 120 def llvm_void_ty       : LLVMType<isVoid>;
 121 def llvm_anyint_ty     : LLVMType<iAny>;
 122 def llvm_anyfloat_ty   : LLVMType<fAny>;
 123 def llvm_anyvector_ty  : LLVMType<vAny>;
 124 def llvm_i1_ty         : LLVMType<i1>;
 125 def llvm_i8_ty         : LLVMType<i8>;
 126 def llvm_i16_ty        : LLVMType<i16>;
 127 def llvm_i32_ty        : LLVMType<i32>;
 128 def llvm_i64_ty        : LLVMType<i64>;
 129 def llvm_half_ty       : LLVMType<f16>;
 130 def llvm_float_ty      : LLVMType<f32>;
 131 def llvm_double_ty     : LLVMType<f64>;
 132 def llvm_f80_ty        : LLVMType<f80>;
 133 def llvm_f128_ty       : LLVMType<f128>;
 134 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 135 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 136 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 137 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 138 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 139 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 140 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 141
 142 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 143 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 144
 145 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 146 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 147 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 148 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 149 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 150 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 151 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 152 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 153 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 154 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 155 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 156 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 157 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 158
 159 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 160 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 161 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 162 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 163 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 164 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 165
 166 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 167 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 168 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 169 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 170 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 171 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 172 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 173 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 174 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 175 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 176
 177 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 178 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 179 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 180 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 181 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 182 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 183 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 184 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 185 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 186 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 187 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 188 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 189
 190 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 191
 192
 193 //===----------------------------------------------------------------------===//
 194 // Intrinsic Definitions.
 195 //===----------------------------------------------------------------------===//
 196
 197 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 198 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 199 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 200 // example, llvm.bswap.i16 -> int_bswap_i16.
 201 //
 202 //  * RetTypes is a list containing the return types expected for the
 203 //    intrinsic.
 204 //  * ParamTypes is a list containing the parameter types expected for the
 205 //    intrinsic.
 206 //  * Properties can be set to describe the behavior of the intrinsic.
 207 //
 208 class SDPatternOperator;
 209 class Intrinsic<list<LLVMType> ret_types,
 210                 list<LLVMType> param_types = [],
 211                 list<IntrinsicProperty> properties = [],
 212                 string name = ""> : SDPatternOperator {
 213   string LLVMName = name;
 214   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 215   list<LLVMType> RetTypes = ret_types;
 216   list<LLVMType> ParamTypes = param_types;
 217   list<IntrinsicProperty> Properties = properties;
 218
 219   bit isTarget = 0;
 220 }
 221
 222 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 223 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 224 /// support.
 225 class GCCBuiltin<string name> {
 226   string GCCBuiltinName = name;
 227 }
 228
 229 class MSBuiltin<string name> {
 230   string MSBuiltinName = name;
 231 }
 232
 233
 234 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 235 //
 236
 237 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 238 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 239                             "llvm.va_copy">;
 240 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 241
 242 //===------------------- Garbage Collection Intrinsics --------------------===//
 243 //
 244 def int_gcroot  : Intrinsic<[],
 245                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 246 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 247                             [llvm_ptr_ty, llvm_ptrptr_ty],
 248                             [IntrReadArgMem]>;
 249 def int_gcwrite : Intrinsic<[],
 250                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 251                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 252
 253 //===--------------------- Code Generator Intrinsics ----------------------===//
 254 //
 255 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 256 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 257 def int_read_register  : Intrinsic<[llvm_anyint_ty], [llvm_metadata_ty],
 258                                    [IntrNoMem], "llvm.read_register">;
 259 def int_write_register : Intrinsic<[], [llvm_metadata_ty, llvm_anyint_ty],
 260                                    [], "llvm.write_register">;
 261
 262 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 263 // model their dependencies on allocas.
 264 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 265                         GCCBuiltin<"__builtin_stack_save">;
 266 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 267                         GCCBuiltin<"__builtin_stack_restore">;
 268
 269 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 270 // however it does conveniently prevent the prefetch from being reordered
 271 // with respect to nearby accesses to the same memory.
 272 def int_prefetch      : Intrinsic<[],
 273                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 274                                    llvm_i32_ty],
 275                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 276 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 277
 278 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 279
 280 // The assume intrinsic is marked as arbitrarily writing so that proper
 281 // control dependencies will be maintained.
 282 def int_assume        : Intrinsic<[], [llvm_i1_ty], []>;
 283
 284 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 285 // guard to the correct place on the stack frame.
 286 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 287 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 288                                         [IntrReadWriteArgMem]>;
 289
 290 //===------------------- Standard C Library Intrinsics --------------------===//
 291 //
 292
 293 def int_memcpy  : Intrinsic<[],
 294                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 295                               llvm_i32_ty, llvm_i1_ty],
 296                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 297                              ReadOnly<1>]>;
 298 def int_memmove : Intrinsic<[],
 299                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 300                              llvm_i32_ty, llvm_i1_ty],
 301                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 302                              ReadOnly<1>]>;
 303 def int_memset  : Intrinsic<[],
 304                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 305                              llvm_i32_ty, llvm_i1_ty],
 306                             [IntrReadWriteArgMem, NoCapture<0>]>;
 307
 308 let Properties = [IntrNoMem] in {
 309   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 310                            [LLVMMatchType<0>, LLVMMatchType<0>,
 311                             LLVMMatchType<0>]>;
 312   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 313                               [LLVMMatchType<0>, LLVMMatchType<0>,
 314                                LLVMMatchType<0>]>;
 315
 316   // These functions do not read memory, but are sensitive to the
 317   // rounding mode. LLVM purposely does not model changes to the FP
 318   // environment so they can be treated as readnone.
 319   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 320   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 321   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 322   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 323   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 324                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 325   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 326   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 327   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 328   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 329   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 330   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 331   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 332                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 333   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 334   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 335   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 336   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 337   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 338   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 339 }
 340
 341 // NOTE: these are internal interfaces.
 342 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 343 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 344 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 345 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 346
 347 // Internal interface for object size checking
 348 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 349                                [IntrNoMem]>,
 350                                GCCBuiltin<"__builtin_object_size">;
 351
 352 //===------------------------- Expect Intrinsics --------------------------===//
 353 //
 354 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 355                                               LLVMMatchType<0>], [IntrNoMem]>;
 356
 357 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 358 //
 359
 360 // None of these intrinsics accesses memory at all.
 361 let Properties = [IntrNoMem] in {
 362   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 363   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 364   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 365   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 366 }
 367
 368 //===------------------------ Debugger Intrinsics -------------------------===//
 369 //
 370
 371 // None of these intrinsics accesses memory at all...but that doesn't mean the
 372 // optimizers can change them aggressively.  Special handling needed in a few
 373 // places.
 374 let Properties = [IntrNoMem] in {
 375   def int_dbg_declare      : Intrinsic<[],
 376                                        [llvm_metadata_ty,
 377                                        llvm_metadata_ty,
 378                                        llvm_metadata_ty]>;
 379   def int_dbg_value        : Intrinsic<[],
 380                                        [llvm_metadata_ty, llvm_i64_ty,
 381                                         llvm_metadata_ty,
 382                                         llvm_metadata_ty]>;
 383 }
 384
 385 //===------------------ Exception Handling Intrinsics----------------------===//
 386 //
 387
 388 // The result of eh.typeid.for depends on the enclosing function, but inside a
 389 // given function it is 'const' and may be CSE'd etc.
 390 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 391
 392 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 393 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 394
 395 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 396 // callee-saved registers to be saved and restored (regardless of whether they
 397 // are used) in the calling function. It is used by libgcc_eh.
 398 def int_eh_unwind_init: Intrinsic<[]>,
 399                         GCCBuiltin<"__builtin_unwind_init">;
 400
 401 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 402
 403 let Properties = [IntrNoMem] in {
 404   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 405   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 406 }
 407 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 408 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 409 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 410
 411 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 412 //
 413 def int_var_annotation : Intrinsic<[],
 414                                    [llvm_ptr_ty, llvm_ptr_ty,
 415                                     llvm_ptr_ty, llvm_i32_ty],
 416                                    [], "llvm.var.annotation">;
 417 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 418                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 419                                     llvm_i32_ty],
 420                                    [], "llvm.ptr.annotation">;
 421 def int_annotation : Intrinsic<[llvm_anyint_ty],
 422                                [LLVMMatchType<0>, llvm_ptr_ty,
 423                                 llvm_ptr_ty, llvm_i32_ty],
 424                                [], "llvm.annotation">;
 425
 426 //===------------------------ Trampoline Intrinsics -----------------------===//
 427 //
 428 def int_init_trampoline : Intrinsic<[],
 429                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 430                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 431                                    GCCBuiltin<"__builtin_init_trampoline">;
 432
 433 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 434                                       [IntrReadArgMem]>,
 435                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 436
 437 //===------------------------ Overflow Intrinsics -------------------------===//
 438 //
 439
 440 // Expose the carry flag from add operations on two integrals.
 441 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 442                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 443                                        [IntrNoMem]>;
 444 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 445                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 446                                        [IntrNoMem]>;
 447
 448 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 449                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 450                                        [IntrNoMem]>;
 451 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 452                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 453                                        [IntrNoMem]>;
 454
 455 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 456                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 457                                        [IntrNoMem]>;
 458 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 459                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 460                                        [IntrNoMem]>;
 461
 462 //===------------------------- Memory Use Markers -------------------------===//
 463 //
 464 def int_lifetime_start  : Intrinsic<[],
 465                                     [llvm_i64_ty, llvm_ptr_ty],
 466                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 467 def int_lifetime_end    : Intrinsic<[],
 468                                     [llvm_i64_ty, llvm_ptr_ty],
 469                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 470 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 471                                     [llvm_i64_ty, llvm_ptr_ty],
 472                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 473 def int_invariant_end   : Intrinsic<[],
 474                                     [llvm_descriptor_ty, llvm_i64_ty,
 475                                      llvm_ptr_ty],
 476                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 477
 478 //===------------------------ Stackmap Intrinsics -------------------------===//
 479 //
 480 def int_experimental_stackmap : Intrinsic<[],
 481                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty],
 482                                   [Throws]>;
 483 def int_experimental_patchpoint_void : Intrinsic<[],
 484                                                  [llvm_i64_ty, llvm_i32_ty,
 485                                                   llvm_ptr_ty, llvm_i32_ty,
 486                                                   llvm_vararg_ty]>;
 487 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 488                                                 [llvm_i64_ty, llvm_i32_ty,
 489                                                  llvm_ptr_ty, llvm_i32_ty,
 490                                                  llvm_vararg_ty]>;
 491
 492 //===-------------------------- Other Intrinsics --------------------------===//
 493 //
 494 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 495                      GCCBuiltin<"__builtin_flt_rounds">;
 496 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 497                GCCBuiltin<"__builtin_trap">;
 498 def int_debugtrap : Intrinsic<[]>,
 499                     GCCBuiltin<"__builtin_debugtrap">;
 500
 501 // NOP: calls/invokes to this intrinsic are removed by codegen
 502 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 503
 504 // Intrisics to support half precision floating point format
 505 let Properties = [IntrNoMem] in {
 506 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_anyfloat_ty]>;
 507 def int_convert_from_fp16 : Intrinsic<[llvm_anyfloat_ty], [llvm_i16_ty]>;
 508 }
 509
 510 // These convert intrinsics are to support various conversions between
 511 // various types with rounding and saturation. NOTE: avoid using these
 512 // intrinsics as they might be removed sometime in the future and
 513 // most targets don't support them.
 514 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 515                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 516 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 517                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 518 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 519                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 520 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 521                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 522 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 523                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 524 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 525                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 526 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 527                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 528 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 529                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 530 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 531                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 532
 533 // Clear cache intrinsic, default to ignore (ie. emit nothing)
 534 // maps to void __clear_cache() on supporting platforms
 535 def int_clear_cache : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 536                                 [], "llvm.clear_cache">;
 537
 538 //===----------------------------------------------------------------------===//
 539 // Target-specific intrinsics
 540 //===----------------------------------------------------------------------===//
 541
 542 include "llvm/IR/IntrinsicsPowerPC.td"
 543 include "llvm/IR/IntrinsicsX86.td"
 544 include "llvm/IR/IntrinsicsARM.td"
 545 include "llvm/IR/IntrinsicsAArch64.td"
 546 include "llvm/IR/IntrinsicsXCore.td"
 547 include "llvm/IR/IntrinsicsHexagon.td"
 548 include "llvm/IR/IntrinsicsNVVM.td"
 549 include "llvm/IR/IntrinsicsMips.td"
 550 include "llvm/IR/IntrinsicsR600.td"