include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 // IntrNoduplicate - Calls to this intrinsic cannot be duplicated.
  73 // Parallels the noduplicate attribute on LLVM IR functions.
  74 def IntrNoDuplicate : IntrinsicProperty;
  75
  76 // IntrConvergent - Calls to this intrinsic are convergent and may not be made
  77 // control-dependent on any additional values.
  78 // Parallels the convergent attribute on LLVM IR functions.
  79 def IntrConvergent : IntrinsicProperty;
  80
  81 //===----------------------------------------------------------------------===//
  82 // Types used by intrinsics.
  83 //===----------------------------------------------------------------------===//
  84
  85 class LLVMType<ValueType vt> {
  86   ValueType VT = vt;
  87 }
  88
  89 class LLVMQualPointerType<LLVMType elty, int addrspace>
  90   : LLVMType<iPTR>{
  91   LLVMType ElTy = elty;
  92   int AddrSpace = addrspace;
  93 }
  94
  95 class LLVMPointerType<LLVMType elty>
  96   : LLVMQualPointerType<elty, 0>;
  97
  98 class LLVMAnyPointerType<LLVMType elty>
  99   : LLVMType<iPTRAny>{
 100   LLVMType ElTy = elty;
 101 }
 102
 103 // Match the type of another intrinsic parameter.  Number is an index into the
 104 // list of overloaded types for the intrinsic, excluding all the fixed types.
 105 // The Number value must refer to a previously listed type.  For example:
 106 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
 107 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
 108 // refers to the first overloaded type, which is the 2nd argument.
 109 class LLVMMatchType<int num>
 110   : LLVMType<OtherVT>{
 111   int Number = num;
 112 }
 113
 114 // Match the type of another intrinsic parameter that is expected to be based on
 115 // an integral type (i.e. either iN or <N x iM>), but change the scalar size to
 116 // be twice as wide or half as wide as the other type.  This is only useful when
 117 // the intrinsic is overloaded, so the matched type should be declared as iAny.
 118 class LLVMExtendedType<int num> : LLVMMatchType<num>;
 119 class LLVMTruncatedType<int num> : LLVMMatchType<num>;
 120 class LLVMVectorSameWidth<int num, LLVMType elty>
 121   : LLVMMatchType<num> {
 122   ValueType ElTy = elty.VT;
 123 }
 124 class LLVMPointerTo<int num> : LLVMMatchType<num>;
 125 class LLVMVectorOfPointersToElt<int num> : LLVMMatchType<num>;
 126
 127 // Match the type of another intrinsic parameter that is expected to be a
 128 // vector type, but change the element count to be half as many
 129 class LLVMHalfElementsVectorType<int num> : LLVMMatchType<num>;
 130
 131 def llvm_void_ty       : LLVMType<isVoid>;
 132 def llvm_any_ty        : LLVMType<Any>;
 133 def llvm_anyint_ty     : LLVMType<iAny>;
 134 def llvm_anyfloat_ty   : LLVMType<fAny>;
 135 def llvm_anyvector_ty  : LLVMType<vAny>;
 136 def llvm_i1_ty         : LLVMType<i1>;
 137 def llvm_i8_ty         : LLVMType<i8>;
 138 def llvm_i16_ty        : LLVMType<i16>;
 139 def llvm_i32_ty        : LLVMType<i32>;
 140 def llvm_i64_ty        : LLVMType<i64>;
 141 def llvm_half_ty       : LLVMType<f16>;
 142 def llvm_float_ty      : LLVMType<f32>;
 143 def llvm_double_ty     : LLVMType<f64>;
 144 def llvm_f80_ty        : LLVMType<f80>;
 145 def llvm_f128_ty       : LLVMType<f128>;
 146 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 147 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 148 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 149 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 150 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 151 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 152 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 153 def llvm_token_ty      : LLVMType<token>;                         // token
 154
 155 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 156 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 157
 158 def llvm_v2i1_ty       : LLVMType<v2i1>;     //   2 x i1
 159 def llvm_v4i1_ty       : LLVMType<v4i1>;     //   4 x i1
 160 def llvm_v8i1_ty       : LLVMType<v8i1>;     //   8 x i1
 161 def llvm_v16i1_ty      : LLVMType<v16i1>;    //  16 x i1
 162 def llvm_v32i1_ty      : LLVMType<v32i1>;    //  32 x i1
 163 def llvm_v64i1_ty      : LLVMType<v64i1>;    //  64 x i1
 164 def llvm_v512i1_ty     : LLVMType<v512i1>;   // 512 x i1
 165 def llvm_v1024i1_ty    : LLVMType<v1024i1>;  //1024 x i1
 166
 167 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 168 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 169 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 170 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 171 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 172 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 173 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 174 def llvm_v128i8_ty     : LLVMType<v128i8>;   //128 x i8
 175 def llvm_v256i8_ty     : LLVMType<v256i8>;   //256 x i8
 176
 177 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 178 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 179 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 180 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 181 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 182 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 183 def llvm_v64i16_ty     : LLVMType<v64i16>;   // 64 x i16
 184 def llvm_v128i16_ty    : LLVMType<v128i16>;  //128 x i16
 185
 186 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 187 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 188 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 189 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 190 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 191 def llvm_v32i32_ty     : LLVMType<v32i32>;   // 32 x i32
 192 def llvm_v64i32_ty     : LLVMType<v64i32>;   // 64 x i32
 193
 194 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 195 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 196 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 197 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 198 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 199 def llvm_v32i64_ty     : LLVMType<v32i64>;   // 32 x i64
 200
 201 def llvm_v1i128_ty     : LLVMType<v1i128>;   //  1 x i128
 202
 203 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 204 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 205 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 206 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 207 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 208 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 209 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 210 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 211 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 212 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 213 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 214 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 215
 216 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 217
 218
 219 //===----------------------------------------------------------------------===//
 220 // Intrinsic Definitions.
 221 //===----------------------------------------------------------------------===//
 222
 223 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 224 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 225 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 226 // example, llvm.bswap.i16 -> int_bswap_i16.
 227 //
 228 //  * RetTypes is a list containing the return types expected for the
 229 //    intrinsic.
 230 //  * ParamTypes is a list containing the parameter types expected for the
 231 //    intrinsic.
 232 //  * Properties can be set to describe the behavior of the intrinsic.
 233 //
 234 class SDPatternOperator;
 235 class Intrinsic<list<LLVMType> ret_types,
 236                 list<LLVMType> param_types = [],
 237                 list<IntrinsicProperty> properties = [],
 238                 string name = ""> : SDPatternOperator {
 239   string LLVMName = name;
 240   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 241   list<LLVMType> RetTypes = ret_types;
 242   list<LLVMType> ParamTypes = param_types;
 243   list<IntrinsicProperty> Properties = properties;
 244
 245   bit isTarget = 0;
 246 }
 247
 248 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 249 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 250 /// support.
 251 class GCCBuiltin<string name> {
 252   string GCCBuiltinName = name;
 253 }
 254
 255 class MSBuiltin<string name> {
 256   string MSBuiltinName = name;
 257 }
 258
 259
 260 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 261 //
 262
 263 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 264 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 265                             "llvm.va_copy">;
 266 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 267
 268 //===------------------- Garbage Collection Intrinsics --------------------===//
 269 //
 270 def int_gcroot  : Intrinsic<[],
 271                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 272 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 273                             [llvm_ptr_ty, llvm_ptrptr_ty],
 274                             [IntrReadArgMem]>;
 275 def int_gcwrite : Intrinsic<[],
 276                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 277                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 278
 279 //===--------------------- Code Generator Intrinsics ----------------------===//
 280 //
 281 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 282 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 283 def int_read_register  : Intrinsic<[llvm_anyint_ty], [llvm_metadata_ty],
 284                                    [IntrReadMem], "llvm.read_register">;
 285 def int_write_register : Intrinsic<[], [llvm_metadata_ty, llvm_anyint_ty],
 286                                    [], "llvm.write_register">;
 287
 288 // Gets the address of the local variable area. This is typically a copy of the
 289 // stack, frame, or base pointer depending on the type of prologue.
 290 def int_localaddress : Intrinsic<[llvm_ptr_ty], [], [IntrNoMem]>;
 291
 292 // Escapes local variables to allow access from other functions.
 293 def int_localescape : Intrinsic<[], [llvm_vararg_ty]>;
 294
 295 // Given a function and the localaddress of a parent frame, returns a pointer
 296 // to an escaped allocation indicated by the index.
 297 def int_localrecover : Intrinsic<[llvm_ptr_ty],
 298                                  [llvm_ptr_ty, llvm_ptr_ty, llvm_i32_ty],
 299                                  [IntrNoMem]>;
 300 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 301 // model their dependencies on allocas.
 302 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 303                         GCCBuiltin<"__builtin_stack_save">;
 304 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 305                         GCCBuiltin<"__builtin_stack_restore">;
 306
 307 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 308 // however it does conveniently prevent the prefetch from being reordered
 309 // with respect to nearby accesses to the same memory.
 310 def int_prefetch      : Intrinsic<[],
 311                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 312                                    llvm_i32_ty],
 313                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 314 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 315
 316 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 317
 318 // The assume intrinsic is marked as arbitrarily writing so that proper
 319 // control dependencies will be maintained.
 320 def int_assume        : Intrinsic<[], [llvm_i1_ty], []>;
 321
 322 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 323 // guard to the correct place on the stack frame.
 324 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 325 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 326                                         [IntrReadWriteArgMem]>;
 327
 328 // A counter increment for instrumentation based profiling.
 329 def int_instrprof_increment : Intrinsic<[],
 330                                         [llvm_ptr_ty, llvm_i64_ty,
 331                                          llvm_i32_ty, llvm_i32_ty],
 332                                         []>;
 333
 334 // A call to profile runtime for value profiling of target expressions
 335 // through instrumentation based profiling.
 336 def int_instrprof_value_profile : Intrinsic<[],
 337                                             [llvm_ptr_ty, llvm_i64_ty,
 338                                              llvm_i64_ty, llvm_i32_ty,
 339                                              llvm_i32_ty],
 340                                             []>;
 341
 342 //===------------------- Standard C Library Intrinsics --------------------===//
 343 //
 344
 345 def int_memcpy  : Intrinsic<[],
 346                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 347                               llvm_i32_ty, llvm_i1_ty],
 348                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 349                              ReadOnly<1>]>;
 350 def int_memmove : Intrinsic<[],
 351                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 352                              llvm_i32_ty, llvm_i1_ty],
 353                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 354                              ReadOnly<1>]>;
 355 def int_memset  : Intrinsic<[],
 356                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 357                              llvm_i32_ty, llvm_i1_ty],
 358                             [IntrReadWriteArgMem, NoCapture<0>]>;
 359
 360 let Properties = [IntrNoMem] in {
 361   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 362                            [LLVMMatchType<0>, LLVMMatchType<0>,
 363                             LLVMMatchType<0>]>;
 364   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 365                               [LLVMMatchType<0>, LLVMMatchType<0>,
 366                                LLVMMatchType<0>]>;
 367
 368   // These functions do not read memory, but are sensitive to the
 369   // rounding mode. LLVM purposely does not model changes to the FP
 370   // environment so they can be treated as readnone.
 371   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 372   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 373   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 374   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 375   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 376                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 377   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 378   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 379   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 380   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 381   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 382   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 383   def int_minnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 384   def int_maxnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 385   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 386                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 387   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 388   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 389   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 390   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 391   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 392   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 393   def int_canonicalize : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>],
 394                                    [IntrNoMem]>;
 395 }
 396
 397 // NOTE: these are internal interfaces.
 398 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 399 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 400 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 401 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 402
 403 // Internal interface for object size checking
 404 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 405                                [IntrNoMem]>,
 406                                GCCBuiltin<"__builtin_object_size">;
 407
 408 //===------------------------- Expect Intrinsics --------------------------===//
 409 //
 410 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 411                                               LLVMMatchType<0>], [IntrNoMem]>;
 412
 413 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 414 //
 415
 416 // None of these intrinsics accesses memory at all.
 417 let Properties = [IntrNoMem] in {
 418   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 419   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 420   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 421   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 422   def int_bitreverse : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 423 }
 424
 425 //===------------------------ Debugger Intrinsics -------------------------===//
 426 //
 427
 428 // None of these intrinsics accesses memory at all...but that doesn't mean the
 429 // optimizers can change them aggressively.  Special handling needed in a few
 430 // places.
 431 let Properties = [IntrNoMem] in {
 432   def int_dbg_declare      : Intrinsic<[],
 433                                        [llvm_metadata_ty,
 434                                        llvm_metadata_ty,
 435                                        llvm_metadata_ty]>;
 436   def int_dbg_value        : Intrinsic<[],
 437                                        [llvm_metadata_ty, llvm_i64_ty,
 438                                         llvm_metadata_ty,
 439                                         llvm_metadata_ty]>;
 440 }
 441
 442 //===------------------ Exception Handling Intrinsics----------------------===//
 443 //
 444
 445 // The result of eh.typeid.for depends on the enclosing function, but inside a
 446 // given function it is 'const' and may be CSE'd etc.
 447 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 448
 449 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 450 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 451
 452 // eh.exceptionpointer returns the pointer to the exception caught by
 453 // the given `catchpad`.
 454 def int_eh_exceptionpointer : Intrinsic<[llvm_anyptr_ty], [llvm_token_ty],
 455                                         [IntrNoMem]>;
 456
 457 // Gets the exception code from a catchpad token. Only used on some platforms.
 458 def int_eh_exceptioncode : Intrinsic<[llvm_i32_ty], [llvm_token_ty], [IntrNoMem]>;
 459
 460 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 461 // callee-saved registers to be saved and restored (regardless of whether they
 462 // are used) in the calling function. It is used by libgcc_eh.
 463 def int_eh_unwind_init: Intrinsic<[]>,
 464                         GCCBuiltin<"__builtin_unwind_init">;
 465
 466 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 467
 468 let Properties = [IntrNoMem] in {
 469   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 470   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 471 }
 472 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 473 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 474 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 475 def int_eh_sjlj_setup_dispatch  : Intrinsic<[], []>;
 476
 477 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 478 //
 479 def int_var_annotation : Intrinsic<[],
 480                                    [llvm_ptr_ty, llvm_ptr_ty,
 481                                     llvm_ptr_ty, llvm_i32_ty],
 482                                    [], "llvm.var.annotation">;
 483 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 484                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 485                                     llvm_i32_ty],
 486                                    [], "llvm.ptr.annotation">;
 487 def int_annotation : Intrinsic<[llvm_anyint_ty],
 488                                [LLVMMatchType<0>, llvm_ptr_ty,
 489                                 llvm_ptr_ty, llvm_i32_ty],
 490                                [], "llvm.annotation">;
 491
 492 //===------------------------ Trampoline Intrinsics -----------------------===//
 493 //
 494 def int_init_trampoline : Intrinsic<[],
 495                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 496                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 497                                    GCCBuiltin<"__builtin_init_trampoline">;
 498
 499 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 500                                       [IntrReadArgMem]>,
 501                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 502
 503 //===------------------------ Overflow Intrinsics -------------------------===//
 504 //
 505
 506 // Expose the carry flag from add operations on two integrals.
 507 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 508                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 509                                        [IntrNoMem]>;
 510 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 511                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 512                                        [IntrNoMem]>;
 513
 514 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 515                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 516                                        [IntrNoMem]>;
 517 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 518                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 519                                        [IntrNoMem]>;
 520
 521 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 522                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 523                                        [IntrNoMem]>;
 524 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 525                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 526                                        [IntrNoMem]>;
 527
 528 //===------------------------- Memory Use Markers -------------------------===//
 529 //
 530 def int_lifetime_start  : Intrinsic<[],
 531                                     [llvm_i64_ty, llvm_ptr_ty],
 532                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 533 def int_lifetime_end    : Intrinsic<[],
 534                                     [llvm_i64_ty, llvm_ptr_ty],
 535                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 536 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 537                                     [llvm_i64_ty, llvm_ptr_ty],
 538                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 539 def int_invariant_end   : Intrinsic<[],
 540                                     [llvm_descriptor_ty, llvm_i64_ty,
 541                                      llvm_ptr_ty],
 542                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 543
 544 def int_invariant_group_barrier : Intrinsic<[llvm_ptr_ty],
 545                                             [llvm_ptr_ty],
 546                                             [IntrNoMem]>;
 547
 548 //===------------------------ Stackmap Intrinsics -------------------------===//
 549 //
 550 def int_experimental_stackmap : Intrinsic<[],
 551                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty],
 552                                   [Throws]>;
 553 def int_experimental_patchpoint_void : Intrinsic<[],
 554                                                  [llvm_i64_ty, llvm_i32_ty,
 555                                                   llvm_ptr_ty, llvm_i32_ty,
 556                                                   llvm_vararg_ty],
 557                                                   [Throws]>;
 558 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 559                                                 [llvm_i64_ty, llvm_i32_ty,
 560                                                  llvm_ptr_ty, llvm_i32_ty,
 561                                                  llvm_vararg_ty],
 562                                                  [Throws]>;
 563
 564
 565 //===------------------------ Garbage Collection Intrinsics ---------------===//
 566 // These are documented in docs/Statepoint.rst
 567
 568 def int_experimental_gc_statepoint : Intrinsic<[llvm_i32_ty],
 569                                [llvm_i64_ty, llvm_i32_ty,
 570                                 llvm_anyptr_ty, llvm_i32_ty,
 571                                 llvm_i32_ty, llvm_vararg_ty],
 572                                 [Throws]>;
 573
 574 def int_experimental_gc_result   : Intrinsic<[llvm_any_ty], [llvm_i32_ty],
 575                                              [IntrReadMem]>;
 576 def int_experimental_gc_relocate : Intrinsic<[llvm_anyptr_ty],
 577                                 [llvm_i32_ty, llvm_i32_ty, llvm_i32_ty],
 578                                 [IntrReadMem]>;
 579
 580 // Deprecated: will be removed in a couple of weeks
 581 def int_experimental_gc_result_int : Intrinsic<[llvm_anyint_ty], [llvm_i32_ty]>;
 582 def int_experimental_gc_result_float : Intrinsic<[llvm_anyfloat_ty],
 583                                                  [llvm_i32_ty]>;
 584 def int_experimental_gc_result_ptr : Intrinsic<[llvm_anyptr_ty], [llvm_i32_ty]>;
 585
 586 //===-------------------------- Other Intrinsics --------------------------===//
 587 //
 588 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 589                      GCCBuiltin<"__builtin_flt_rounds">;
 590 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 591                GCCBuiltin<"__builtin_trap">;
 592 def int_debugtrap : Intrinsic<[]>,
 593                     GCCBuiltin<"__builtin_debugtrap">;
 594
 595 // NOP: calls/invokes to this intrinsic are removed by codegen
 596 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 597
 598 // Intrisics to support half precision floating point format
 599 let Properties = [IntrNoMem] in {
 600 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_anyfloat_ty]>;
 601 def int_convert_from_fp16 : Intrinsic<[llvm_anyfloat_ty], [llvm_i16_ty]>;
 602 }
 603
 604 // These convert intrinsics are to support various conversions between
 605 // various types with rounding and saturation. NOTE: avoid using these
 606 // intrinsics as they might be removed sometime in the future and
 607 // most targets don't support them.
 608 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 609                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 610 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 611                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 612 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 613                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 614 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 615                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 616 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 617                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 618 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 619                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 620 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 621                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 622 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 623                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 624 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 625                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 626
 627 // Clear cache intrinsic, default to ignore (ie. emit nothing)
 628 // maps to void __clear_cache() on supporting platforms
 629 def int_clear_cache : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 630                                 [], "llvm.clear_cache">;
 631
 632 // Calculate the Absolute Differences of the two input vectors.
 633 def int_sabsdiff : Intrinsic<[llvm_anyvector_ty],
 634                         [ LLVMMatchType<0>, LLVMMatchType<0> ], [IntrNoMem]>;
 635 def int_uabsdiff : Intrinsic<[llvm_anyvector_ty],
 636                         [ LLVMMatchType<0>, LLVMMatchType<0> ], [IntrNoMem]>;
 637
 638 //===-------------------------- Masked Intrinsics -------------------------===//
 639 //
 640 def int_masked_store : Intrinsic<[], [llvm_anyvector_ty, LLVMPointerTo<0>,
 641                                       llvm_i32_ty,
 642                                       LLVMVectorSameWidth<0, llvm_i1_ty>],
 643                                  [IntrReadWriteArgMem]>;
 644
 645 def int_masked_load  : Intrinsic<[llvm_anyvector_ty],
 646                                  [LLVMPointerTo<0>, llvm_i32_ty,
 647                                   LLVMVectorSameWidth<0, llvm_i1_ty>, LLVMMatchType<0>],
 648                                  [IntrReadArgMem]>;
 649
 650 def int_masked_gather: Intrinsic<[llvm_anyvector_ty],
 651                                  [LLVMVectorOfPointersToElt<0>, llvm_i32_ty,
 652                                   LLVMVectorSameWidth<0, llvm_i1_ty>,
 653                                   LLVMMatchType<0>],
 654                                  [IntrReadArgMem]>;
 655
 656 def int_masked_scatter: Intrinsic<[],
 657                                   [llvm_anyvector_ty,
 658                                    LLVMVectorOfPointersToElt<0>, llvm_i32_ty,
 659                                    LLVMVectorSameWidth<0, llvm_i1_ty>],
 660                                   [IntrReadWriteArgMem]>;
 661
 662 // Intrinsics to support bit sets.
 663 def int_bitset_test : Intrinsic<[llvm_i1_ty], [llvm_ptr_ty, llvm_metadata_ty],
 664                                 [IntrNoMem]>;
 665
 666 //===----------------------------------------------------------------------===//
 667 // Target-specific intrinsics
 668 //===----------------------------------------------------------------------===//
 669
 670 include "llvm/IR/IntrinsicsPowerPC.td"
 671 include "llvm/IR/IntrinsicsX86.td"
 672 include "llvm/IR/IntrinsicsARM.td"
 673 include "llvm/IR/IntrinsicsAArch64.td"
 674 include "llvm/IR/IntrinsicsXCore.td"
 675 include "llvm/IR/IntrinsicsHexagon.td"
 676 include "llvm/IR/IntrinsicsNVVM.td"
 677 include "llvm/IR/IntrinsicsMips.td"
 678 include "llvm/IR/IntrinsicsAMDGPU.td"
 679 include "llvm/IR/IntrinsicsBPF.td"
 680 include "llvm/IR/IntrinsicsSystemZ.td"
 681 include "llvm/IR/IntrinsicsWebAssembly.td"