include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 // IntrNoduplicate - Calls to this intrinsic cannot be duplicated.
  73 // Parallels the noduplicate attribute on LLVM IR functions.
  74 def IntrNoDuplicate : IntrinsicProperty;
  75
  76 // IntrConvergent - Calls to this intrinsic are convergent and may only be
  77 // moved to control equivalent blocks.
  78 // Parallels the convergent attribute on LLVM IR functions.
  79 def IntrConvergent : IntrinsicProperty;
  80
  81 //===----------------------------------------------------------------------===//
  82 // Types used by intrinsics.
  83 //===----------------------------------------------------------------------===//
  84
  85 class LLVMType<ValueType vt> {
  86   ValueType VT = vt;
  87 }
  88
  89 class LLVMQualPointerType<LLVMType elty, int addrspace>
  90   : LLVMType<iPTR>{
  91   LLVMType ElTy = elty;
  92   int AddrSpace = addrspace;
  93 }
  94
  95 class LLVMPointerType<LLVMType elty>
  96   : LLVMQualPointerType<elty, 0>;
  97
  98 class LLVMAnyPointerType<LLVMType elty>
  99   : LLVMType<iPTRAny>{
 100   LLVMType ElTy = elty;
 101 }
 102
 103 // Match the type of another intrinsic parameter.  Number is an index into the
 104 // list of overloaded types for the intrinsic, excluding all the fixed types.
 105 // The Number value must refer to a previously listed type.  For example:
 106 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
 107 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
 108 // refers to the first overloaded type, which is the 2nd argument.
 109 class LLVMMatchType<int num>
 110   : LLVMType<OtherVT>{
 111   int Number = num;
 112 }
 113
 114 // Match the type of another intrinsic parameter that is expected to be based on
 115 // an integral type (i.e. either iN or <N x iM>), but change the scalar size to
 116 // be twice as wide or half as wide as the other type.  This is only useful when
 117 // the intrinsic is overloaded, so the matched type should be declared as iAny.
 118 class LLVMExtendedType<int num> : LLVMMatchType<num>;
 119 class LLVMTruncatedType<int num> : LLVMMatchType<num>;
 120 class LLVMVectorSameWidth<int num, LLVMType elty>
 121   : LLVMMatchType<num> {
 122   ValueType ElTy = elty.VT;
 123 }
 124 class LLVMPointerTo<int num> : LLVMMatchType<num>;
 125 class LLVMVectorOfPointersToElt<int num> : LLVMMatchType<num>;
 126
 127 // Match the type of another intrinsic parameter that is expected to be a
 128 // vector type, but change the element count to be half as many
 129 class LLVMHalfElementsVectorType<int num> : LLVMMatchType<num>;
 130
 131 def llvm_void_ty       : LLVMType<isVoid>;
 132 def llvm_any_ty        : LLVMType<Any>;
 133 def llvm_anyint_ty     : LLVMType<iAny>;
 134 def llvm_anyfloat_ty   : LLVMType<fAny>;
 135 def llvm_anyvector_ty  : LLVMType<vAny>;
 136 def llvm_i1_ty         : LLVMType<i1>;
 137 def llvm_i8_ty         : LLVMType<i8>;
 138 def llvm_i16_ty        : LLVMType<i16>;
 139 def llvm_i32_ty        : LLVMType<i32>;
 140 def llvm_i64_ty        : LLVMType<i64>;
 141 def llvm_half_ty       : LLVMType<f16>;
 142 def llvm_float_ty      : LLVMType<f32>;
 143 def llvm_double_ty     : LLVMType<f64>;
 144 def llvm_f80_ty        : LLVMType<f80>;
 145 def llvm_f128_ty       : LLVMType<f128>;
 146 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 147 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 148 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 149 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 150 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 151 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 152 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 153 def llvm_token_ty      : LLVMType<token>;                         // token
 154
 155 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 156 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 157
 158 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 159 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 160 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 161 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 162 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 163 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 164 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 165 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 166 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 167 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 168 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 169 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 170 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 171
 172 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 173 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 174 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 175 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 176 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 177 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 178
 179 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 180 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 181 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 182 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 183 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 184 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 185 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 186 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 187 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 188 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 189
 190 def llvm_v1i128_ty     : LLVMType<v1i128>;   //  1 x i128
 191
 192 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 193 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 194 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 195 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 196 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 197 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 198 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 199 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 200 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 201 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 202 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 203 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 204
 205 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 206
 207
 208 //===----------------------------------------------------------------------===//
 209 // Intrinsic Definitions.
 210 //===----------------------------------------------------------------------===//
 211
 212 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 213 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 214 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 215 // example, llvm.bswap.i16 -> int_bswap_i16.
 216 //
 217 //  * RetTypes is a list containing the return types expected for the
 218 //    intrinsic.
 219 //  * ParamTypes is a list containing the parameter types expected for the
 220 //    intrinsic.
 221 //  * Properties can be set to describe the behavior of the intrinsic.
 222 //
 223 class SDPatternOperator;
 224 class Intrinsic<list<LLVMType> ret_types,
 225                 list<LLVMType> param_types = [],
 226                 list<IntrinsicProperty> properties = [],
 227                 string name = ""> : SDPatternOperator {
 228   string LLVMName = name;
 229   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 230   list<LLVMType> RetTypes = ret_types;
 231   list<LLVMType> ParamTypes = param_types;
 232   list<IntrinsicProperty> Properties = properties;
 233
 234   bit isTarget = 0;
 235 }
 236
 237 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 238 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 239 /// support.
 240 class GCCBuiltin<string name> {
 241   string GCCBuiltinName = name;
 242 }
 243
 244 class MSBuiltin<string name> {
 245   string MSBuiltinName = name;
 246 }
 247
 248
 249 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 250 //
 251
 252 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 253 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 254                             "llvm.va_copy">;
 255 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 256
 257 //===------------------- Garbage Collection Intrinsics --------------------===//
 258 //
 259 def int_gcroot  : Intrinsic<[],
 260                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 261 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 262                             [llvm_ptr_ty, llvm_ptrptr_ty],
 263                             [IntrReadArgMem]>;
 264 def int_gcwrite : Intrinsic<[],
 265                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 266                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 267
 268 //===--------------------- Code Generator Intrinsics ----------------------===//
 269 //
 270 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 271 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 272 def int_read_register  : Intrinsic<[llvm_anyint_ty], [llvm_metadata_ty],
 273                                    [IntrReadMem], "llvm.read_register">;
 274 def int_write_register : Intrinsic<[], [llvm_metadata_ty, llvm_anyint_ty],
 275                                    [], "llvm.write_register">;
 276
 277 // Gets the address of the local variable area. This is typically a copy of the
 278 // stack, frame, or base pointer depending on the type of prologue.
 279 def int_localaddress : Intrinsic<[llvm_ptr_ty], [], [IntrNoMem]>;
 280
 281 // Escapes local variables to allow access from other functions.
 282 def int_localescape : Intrinsic<[], [llvm_vararg_ty]>;
 283
 284 // Given a function and the localaddress of a parent frame, returns a pointer
 285 // to an escaped allocation indicated by the index.
 286 def int_localrecover : Intrinsic<[llvm_ptr_ty],
 287                                  [llvm_ptr_ty, llvm_ptr_ty, llvm_i32_ty],
 288                                  [IntrNoMem]>;
 289 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 290 // model their dependencies on allocas.
 291 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 292                         GCCBuiltin<"__builtin_stack_save">;
 293 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 294                         GCCBuiltin<"__builtin_stack_restore">;
 295
 296 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 297 // however it does conveniently prevent the prefetch from being reordered
 298 // with respect to nearby accesses to the same memory.
 299 def int_prefetch      : Intrinsic<[],
 300                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 301                                    llvm_i32_ty],
 302                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 303 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 304
 305 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 306
 307 // The assume intrinsic is marked as arbitrarily writing so that proper
 308 // control dependencies will be maintained.
 309 def int_assume        : Intrinsic<[], [llvm_i1_ty], []>;
 310
 311 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 312 // guard to the correct place on the stack frame.
 313 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 314 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 315                                         [IntrReadWriteArgMem]>;
 316
 317 // A counter increment for instrumentation based profiling.
 318 def int_instrprof_increment : Intrinsic<[],
 319                                         [llvm_ptr_ty, llvm_i64_ty,
 320                                          llvm_i32_ty, llvm_i32_ty],
 321                                         []>;
 322
 323 //===------------------- Standard C Library Intrinsics --------------------===//
 324 //
 325
 326 def int_memcpy  : Intrinsic<[],
 327                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 328                               llvm_i32_ty, llvm_i1_ty],
 329                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 330                              ReadOnly<1>]>;
 331 def int_memmove : Intrinsic<[],
 332                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 333                              llvm_i32_ty, llvm_i1_ty],
 334                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 335                              ReadOnly<1>]>;
 336 def int_memset  : Intrinsic<[],
 337                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 338                              llvm_i32_ty, llvm_i1_ty],
 339                             [IntrReadWriteArgMem, NoCapture<0>]>;
 340
 341 let Properties = [IntrNoMem] in {
 342   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 343                            [LLVMMatchType<0>, LLVMMatchType<0>,
 344                             LLVMMatchType<0>]>;
 345   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 346                               [LLVMMatchType<0>, LLVMMatchType<0>,
 347                                LLVMMatchType<0>]>;
 348
 349   // These functions do not read memory, but are sensitive to the
 350   // rounding mode. LLVM purposely does not model changes to the FP
 351   // environment so they can be treated as readnone.
 352   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 353   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 354   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 355   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 356   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 357                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 358   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 359   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 360   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 361   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 362   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 363   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 364   def int_minnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 365   def int_maxnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 366   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 367                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 368   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 369   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 370   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 371   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 372   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 373   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 374   def int_canonicalize : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>],
 375                                    [IntrNoMem]>;
 376 }
 377
 378 // NOTE: these are internal interfaces.
 379 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 380 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 381 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 382 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 383
 384 // Internal interface for object size checking
 385 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 386                                [IntrNoMem]>,
 387                                GCCBuiltin<"__builtin_object_size">;
 388
 389 //===------------------------- Expect Intrinsics --------------------------===//
 390 //
 391 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 392                                               LLVMMatchType<0>], [IntrNoMem]>;
 393
 394 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 395 //
 396
 397 // None of these intrinsics accesses memory at all.
 398 let Properties = [IntrNoMem] in {
 399   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 400   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 401   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 402   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 403 }
 404
 405 //===------------------------ Debugger Intrinsics -------------------------===//
 406 //
 407
 408 // None of these intrinsics accesses memory at all...but that doesn't mean the
 409 // optimizers can change them aggressively.  Special handling needed in a few
 410 // places.
 411 let Properties = [IntrNoMem] in {
 412   def int_dbg_declare      : Intrinsic<[],
 413                                        [llvm_metadata_ty,
 414                                        llvm_metadata_ty,
 415                                        llvm_metadata_ty]>;
 416   def int_dbg_value        : Intrinsic<[],
 417                                        [llvm_metadata_ty, llvm_i64_ty,
 418                                         llvm_metadata_ty,
 419                                         llvm_metadata_ty]>;
 420 }
 421
 422 //===------------------ Exception Handling Intrinsics----------------------===//
 423 //
 424
 425 // The result of eh.typeid.for depends on the enclosing function, but inside a
 426 // given function it is 'const' and may be CSE'd etc.
 427 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 428
 429 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 430 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 431
 432 // eh.begincatch takes a pointer returned by a landingpad instruction and
 433 // copies the exception object into the memory pointed to by the second
 434 // parameter. If the second parameter is null, no copy occurs.
 435 def int_eh_begincatch : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 436                                   [NoCapture<0>, NoCapture<1>]>;
 437 def int_eh_endcatch : Intrinsic<[], []>;
 438
 439 // Represents the list of actions to take when an exception is thrown.
 440 def int_eh_actions : Intrinsic<[llvm_ptr_ty], [llvm_vararg_ty], []>;
 441
 442 def int_eh_exceptioncode : Intrinsic<[llvm_i32_ty], [], [IntrReadMem]>;
 443
 444 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 445 // callee-saved registers to be saved and restored (regardless of whether they
 446 // are used) in the calling function. It is used by libgcc_eh.
 447 def int_eh_unwind_init: Intrinsic<[]>,
 448                         GCCBuiltin<"__builtin_unwind_init">;
 449
 450 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 451
 452 let Properties = [IntrNoMem] in {
 453   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 454   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 455 }
 456 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 457 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 458 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 459 def int_eh_sjlj_setup_dispatch  : Intrinsic<[], []>;
 460
 461 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 462 //
 463 def int_var_annotation : Intrinsic<[],
 464                                    [llvm_ptr_ty, llvm_ptr_ty,
 465                                     llvm_ptr_ty, llvm_i32_ty],
 466                                    [], "llvm.var.annotation">;
 467 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 468                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 469                                     llvm_i32_ty],
 470                                    [], "llvm.ptr.annotation">;
 471 def int_annotation : Intrinsic<[llvm_anyint_ty],
 472                                [LLVMMatchType<0>, llvm_ptr_ty,
 473                                 llvm_ptr_ty, llvm_i32_ty],
 474                                [], "llvm.annotation">;
 475
 476 //===------------------------ Trampoline Intrinsics -----------------------===//
 477 //
 478 def int_init_trampoline : Intrinsic<[],
 479                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 480                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 481                                    GCCBuiltin<"__builtin_init_trampoline">;
 482
 483 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 484                                       [IntrReadArgMem]>,
 485                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 486
 487 //===------------------------ Overflow Intrinsics -------------------------===//
 488 //
 489
 490 // Expose the carry flag from add operations on two integrals.
 491 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 492                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 493                                        [IntrNoMem]>;
 494 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 495                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 496                                        [IntrNoMem]>;
 497
 498 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 499                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 500                                        [IntrNoMem]>;
 501 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 502                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 503                                        [IntrNoMem]>;
 504
 505 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 506                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 507                                        [IntrNoMem]>;
 508 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 509                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 510                                        [IntrNoMem]>;
 511
 512 //===------------------------- Memory Use Markers -------------------------===//
 513 //
 514 def int_lifetime_start  : Intrinsic<[],
 515                                     [llvm_i64_ty, llvm_ptr_ty],
 516                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 517 def int_lifetime_end    : Intrinsic<[],
 518                                     [llvm_i64_ty, llvm_ptr_ty],
 519                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 520 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 521                                     [llvm_i64_ty, llvm_ptr_ty],
 522                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 523 def int_invariant_end   : Intrinsic<[],
 524                                     [llvm_descriptor_ty, llvm_i64_ty,
 525                                      llvm_ptr_ty],
 526                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 527
 528 //===------------------------ Stackmap Intrinsics -------------------------===//
 529 //
 530 def int_experimental_stackmap : Intrinsic<[],
 531                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty],
 532                                   [Throws]>;
 533 def int_experimental_patchpoint_void : Intrinsic<[],
 534                                                  [llvm_i64_ty, llvm_i32_ty,
 535                                                   llvm_ptr_ty, llvm_i32_ty,
 536                                                   llvm_vararg_ty],
 537                                                   [Throws]>;
 538 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 539                                                 [llvm_i64_ty, llvm_i32_ty,
 540                                                  llvm_ptr_ty, llvm_i32_ty,
 541                                                  llvm_vararg_ty],
 542                                                  [Throws]>;
 543
 544
 545 //===------------------------ Garbage Collection Intrinsics ---------------===//
 546 // These are documented in docs/Statepoint.rst
 547
 548 def int_experimental_gc_statepoint : Intrinsic<[llvm_i32_ty],
 549                                [llvm_i64_ty, llvm_i32_ty,
 550                                 llvm_anyptr_ty, llvm_i32_ty,
 551                                 llvm_i32_ty, llvm_vararg_ty],
 552                                 [Throws]>;
 553
 554 def int_experimental_gc_result   : Intrinsic<[llvm_any_ty], [llvm_i32_ty]>;
 555 def int_experimental_gc_relocate : Intrinsic<[llvm_anyptr_ty],
 556                                 [llvm_i32_ty, llvm_i32_ty, llvm_i32_ty]>;
 557
 558 // Deprecated: will be removed in a couple of weeks
 559 def int_experimental_gc_result_int : Intrinsic<[llvm_anyint_ty], [llvm_i32_ty]>;
 560 def int_experimental_gc_result_float : Intrinsic<[llvm_anyfloat_ty],
 561                                                  [llvm_i32_ty]>;
 562 def int_experimental_gc_result_ptr : Intrinsic<[llvm_anyptr_ty], [llvm_i32_ty]>;
 563
 564 //===-------------------------- Other Intrinsics --------------------------===//
 565 //
 566 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 567                      GCCBuiltin<"__builtin_flt_rounds">;
 568 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 569                GCCBuiltin<"__builtin_trap">;
 570 def int_debugtrap : Intrinsic<[]>,
 571                     GCCBuiltin<"__builtin_debugtrap">;
 572
 573 // NOP: calls/invokes to this intrinsic are removed by codegen
 574 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 575
 576 // Intrisics to support half precision floating point format
 577 let Properties = [IntrNoMem] in {
 578 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_anyfloat_ty]>;
 579 def int_convert_from_fp16 : Intrinsic<[llvm_anyfloat_ty], [llvm_i16_ty]>;
 580 }
 581
 582 // These convert intrinsics are to support various conversions between
 583 // various types with rounding and saturation. NOTE: avoid using these
 584 // intrinsics as they might be removed sometime in the future and
 585 // most targets don't support them.
 586 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 587                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 588 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 589                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 590 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 591                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 592 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 593                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 594 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 595                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 596 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 597                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 598 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 599                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 600 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 601                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 602 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 603                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 604
 605 // Clear cache intrinsic, default to ignore (ie. emit nothing)
 606 // maps to void __clear_cache() on supporting platforms
 607 def int_clear_cache : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 608                                 [], "llvm.clear_cache">;
 609
 610 // Calculate the Absolute Differences of the two input vectors.
 611 def int_sabsdiff : Intrinsic<[llvm_anyvector_ty],
 612                         [ LLVMMatchType<0>, LLVMMatchType<0> ], [IntrNoMem]>;
 613 def int_uabsdiff : Intrinsic<[llvm_anyvector_ty],
 614                         [ LLVMMatchType<0>, LLVMMatchType<0> ], [IntrNoMem]>;
 615
 616 //===-------------------------- Masked Intrinsics -------------------------===//
 617 //
 618 def int_masked_store : Intrinsic<[], [llvm_anyvector_ty, LLVMPointerTo<0>,
 619                                       llvm_i32_ty,
 620                                       LLVMVectorSameWidth<0, llvm_i1_ty>],
 621                                  [IntrReadWriteArgMem]>;
 622
 623 def int_masked_load  : Intrinsic<[llvm_anyvector_ty],
 624                                  [LLVMPointerTo<0>, llvm_i32_ty,
 625                                   LLVMVectorSameWidth<0, llvm_i1_ty>, LLVMMatchType<0>],
 626                                  [IntrReadArgMem]>;
 627
 628 def int_masked_gather: Intrinsic<[llvm_anyvector_ty],
 629                                  [LLVMVectorOfPointersToElt<0>, llvm_i32_ty,
 630                                   LLVMVectorSameWidth<0, llvm_i1_ty>,
 631                                   LLVMMatchType<0>],
 632                                  [IntrReadArgMem]>;
 633
 634 def int_masked_scatter: Intrinsic<[],
 635                                   [llvm_anyvector_ty,
 636                                    LLVMVectorOfPointersToElt<0>, llvm_i32_ty,
 637                                    LLVMVectorSameWidth<0, llvm_i1_ty>],
 638                                   [IntrReadWriteArgMem]>;
 639
 640 // Intrinsics to support bit sets.
 641 def int_bitset_test : Intrinsic<[llvm_i1_ty], [llvm_ptr_ty, llvm_metadata_ty],
 642                                 [IntrNoMem]>;
 643
 644 //===----------------------------------------------------------------------===//
 645 // Target-specific intrinsics
 646 //===----------------------------------------------------------------------===//
 647
 648 include "llvm/IR/IntrinsicsPowerPC.td"
 649 include "llvm/IR/IntrinsicsX86.td"
 650 include "llvm/IR/IntrinsicsARM.td"
 651 include "llvm/IR/IntrinsicsAArch64.td"
 652 include "llvm/IR/IntrinsicsXCore.td"
 653 include "llvm/IR/IntrinsicsHexagon.td"
 654 include "llvm/IR/IntrinsicsNVVM.td"
 655 include "llvm/IR/IntrinsicsMips.td"
 656 include "llvm/IR/IntrinsicsAMDGPU.td"
 657 include "llvm/IR/IntrinsicsBPF.td"
 658 include "llvm/IR/IntrinsicsSystemZ.td"
 659 include "llvm/IR/IntrinsicsWebAssembly.td"