Polish atomic pointers
[oota-llvm.git] / docs / LangRef.rst
1 ==============================
2 LLVM Language Reference Manual
3 ==============================
4
5 .. contents::
6    :local:
7    :depth: 4
8
9 Abstract
10 ========
11
12 This document is a reference manual for the LLVM assembly language. LLVM
13 is a Static Single Assignment (SSA) based representation that provides
14 type safety, low-level operations, flexibility, and the capability of
15 representing 'all' high-level languages cleanly. It is the common code
16 representation used throughout all phases of the LLVM compilation
17 strategy.
18
19 Introduction
20 ============
21
22 The LLVM code representation is designed to be used in three different
23 forms: as an in-memory compiler IR, as an on-disk bitcode representation
24 (suitable for fast loading by a Just-In-Time compiler), and as a human
25 readable assembly language representation. This allows LLVM to provide a
26 powerful intermediate representation for efficient compiler
27 transformations and analysis, while providing a natural means to debug
28 and visualize the transformations. The three different forms of LLVM are
29 all equivalent. This document describes the human readable
30 representation and notation.
31
32 The LLVM representation aims to be light-weight and low-level while
33 being expressive, typed, and extensible at the same time. It aims to be
34 a "universal IR" of sorts, by being at a low enough level that
35 high-level ideas may be cleanly mapped to it (similar to how
36 microprocessors are "universal IR's", allowing many source languages to
37 be mapped to them). By providing type information, LLVM can be used as
38 the target of optimizations: for example, through pointer analysis, it
39 can be proven that a C automatic variable is never accessed outside of
40 the current function, allowing it to be promoted to a simple SSA value
41 instead of a memory location.
42
43 .. _wellformed:
44
45 Well-Formedness
46 ---------------
47
48 It is important to note that this document describes 'well formed' LLVM
49 assembly language. There is a difference between what the parser accepts
50 and what is considered 'well formed'. For example, the following
51 instruction is syntactically okay, but not well formed:
52
53 .. code-block:: llvm
54
55     %x = add i32 1, %x
56
57 because the definition of ``%x`` does not dominate all of its uses. The
58 LLVM infrastructure provides a verification pass that may be used to
59 verify that an LLVM module is well formed. This pass is automatically
60 run by the parser after parsing input assembly and by the optimizer
61 before it outputs bitcode. The violations pointed out by the verifier
62 pass indicate bugs in transformation passes or input to the parser.
63
64 .. _identifiers:
65
66 Identifiers
67 ===========
68
69 LLVM identifiers come in two basic types: global and local. Global
70 identifiers (functions, global variables) begin with the ``'@'``
71 character. Local identifiers (register names, types) begin with the
72 ``'%'`` character. Additionally, there are three different formats for
73 identifiers, for different purposes:
74
75 #. Named values are represented as a string of characters with their
76    prefix. For example, ``%foo``, ``@DivisionByZero``,
77    ``%a.really.long.identifier``. The actual regular expression used is
78    '``[%@][-a-zA-Z$._][-a-zA-Z$._0-9]*``'. Identifiers that require other
79    characters in their names can be surrounded with quotes. Special
80    characters may be escaped using ``"\xx"`` where ``xx`` is the ASCII
81    code for the character in hexadecimal. In this way, any character can
82    be used in a name value, even quotes themselves. The ``"\01"`` prefix
83    can be used on global variables to suppress mangling.
84 #. Unnamed values are represented as an unsigned numeric value with
85    their prefix. For example, ``%12``, ``@2``, ``%44``.
86 #. Constants, which are described in the section Constants_ below.
87
88 LLVM requires that values start with a prefix for two reasons: Compilers
89 don't need to worry about name clashes with reserved words, and the set
90 of reserved words may be expanded in the future without penalty.
91 Additionally, unnamed identifiers allow a compiler to quickly come up
92 with a temporary variable without having to avoid symbol table
93 conflicts.
94
95 Reserved words in LLVM are very similar to reserved words in other
96 languages. There are keywords for different opcodes ('``add``',
97 '``bitcast``', '``ret``', etc...), for primitive type names ('``void``',
98 '``i32``', etc...), and others. These reserved words cannot conflict
99 with variable names, because none of them start with a prefix character
100 (``'%'`` or ``'@'``).
101
102 Here is an example of LLVM code to multiply the integer variable
103 '``%X``' by 8:
104
105 The easy way:
106
107 .. code-block:: llvm
108
109     %result = mul i32 %X, 8
110
111 After strength reduction:
112
113 .. code-block:: llvm
114
115     %result = shl i32 %X, 3
116
117 And the hard way:
118
119 .. code-block:: llvm
120
121     %0 = add i32 %X, %X           ; yields i32:%0
122     %1 = add i32 %0, %0           ; yields i32:%1
123     %result = add i32 %1, %1
124
125 This last way of multiplying ``%X`` by 8 illustrates several important
126 lexical features of LLVM:
127
128 #. Comments are delimited with a '``;``' and go until the end of line.
129 #. Unnamed temporaries are created when the result of a computation is
130    not assigned to a named value.
131 #. Unnamed temporaries are numbered sequentially (using a per-function
132    incrementing counter, starting with 0). Note that basic blocks and unnamed
133    function parameters are included in this numbering. For example, if the
134    entry basic block is not given a label name and all function parameters are
135    named, then it will get number 0.
136
137 It also shows a convention that we follow in this document. When
138 demonstrating instructions, we will follow an instruction with a comment
139 that defines the type and name of value produced.
140
141 High Level Structure
142 ====================
143
144 Module Structure
145 ----------------
146
147 LLVM programs are composed of ``Module``'s, each of which is a
148 translation unit of the input programs. Each module consists of
149 functions, global variables, and symbol table entries. Modules may be
150 combined together with the LLVM linker, which merges function (and
151 global variable) definitions, resolves forward declarations, and merges
152 symbol table entries. Here is an example of the "hello world" module:
153
154 .. code-block:: llvm
155
156     ; Declare the string constant as a global constant.
157     @.str = private unnamed_addr constant [13 x i8] c"hello world\0A\00"
158
159     ; External declaration of the puts function
160     declare i32 @puts(i8* nocapture) nounwind
161
162     ; Definition of main function
163     define i32 @main() {   ; i32()*
164       ; Convert [13 x i8]* to i8  *...
165       %cast210 = getelementptr [13 x i8], [13 x i8]* @.str, i64 0, i64 0
166
167       ; Call puts function to write out the string to stdout.
168       call i32 @puts(i8* %cast210)
169       ret i32 0
170     }
171
172     ; Named metadata
173     !0 = !{i32 42, null, !"string"}
174     !foo = !{!0}
175
176 This example is made up of a :ref:`global variable <globalvars>` named
177 "``.str``", an external declaration of the "``puts``" function, a
178 :ref:`function definition <functionstructure>` for "``main``" and
179 :ref:`named metadata <namedmetadatastructure>` "``foo``".
180
181 In general, a module is made up of a list of global values (where both
182 functions and global variables are global values). Global values are
183 represented by a pointer to a memory location (in this case, a pointer
184 to an array of char, and a pointer to a function), and have one of the
185 following :ref:`linkage types <linkage>`.
186
187 .. _linkage:
188
189 Linkage Types
190 -------------
191
192 All Global Variables and Functions have one of the following types of
193 linkage:
194
195 ``private``
196     Global values with "``private``" linkage are only directly
197     accessible by objects in the current module. In particular, linking
198     code into a module with an private global value may cause the
199     private to be renamed as necessary to avoid collisions. Because the
200     symbol is private to the module, all references can be updated. This
201     doesn't show up in any symbol table in the object file.
202 ``internal``
203     Similar to private, but the value shows as a local symbol
204     (``STB_LOCAL`` in the case of ELF) in the object file. This
205     corresponds to the notion of the '``static``' keyword in C.
206 ``available_externally``
207     Globals with "``available_externally``" linkage are never emitted into
208     the object file corresponding to the LLVM module. From the linker's
209     perspective, an ``available_externally`` global is equivalent to
210     an external declaration. They exist to allow inlining and other
211     optimizations to take place given knowledge of the definition of the
212     global, which is known to be somewhere outside the module. Globals
213     with ``available_externally`` linkage are allowed to be discarded at
214     will, and allow inlining and other optimizations. This linkage type is
215     only allowed on definitions, not declarations.
216 ``linkonce``
217     Globals with "``linkonce``" linkage are merged with other globals of
218     the same name when linkage occurs. This can be used to implement
219     some forms of inline functions, templates, or other code which must
220     be generated in each translation unit that uses it, but where the
221     body may be overridden with a more definitive definition later.
222     Unreferenced ``linkonce`` globals are allowed to be discarded. Note
223     that ``linkonce`` linkage does not actually allow the optimizer to
224     inline the body of this function into callers because it doesn't
225     know if this definition of the function is the definitive definition
226     within the program or whether it will be overridden by a stronger
227     definition. To enable inlining and other optimizations, use
228     "``linkonce_odr``" linkage.
229 ``weak``
230     "``weak``" linkage has the same merging semantics as ``linkonce``
231     linkage, except that unreferenced globals with ``weak`` linkage may
232     not be discarded. This is used for globals that are declared "weak"
233     in C source code.
234 ``common``
235     "``common``" linkage is most similar to "``weak``" linkage, but they
236     are used for tentative definitions in C, such as "``int X;``" at
237     global scope. Symbols with "``common``" linkage are merged in the
238     same way as ``weak symbols``, and they may not be deleted if
239     unreferenced. ``common`` symbols may not have an explicit section,
240     must have a zero initializer, and may not be marked
241     ':ref:`constant <globalvars>`'. Functions and aliases may not have
242     common linkage.
243
244 .. _linkage_appending:
245
246 ``appending``
247     "``appending``" linkage may only be applied to global variables of
248     pointer to array type. When two global variables with appending
249     linkage are linked together, the two global arrays are appended
250     together. This is the LLVM, typesafe, equivalent of having the
251     system linker append together "sections" with identical names when
252     .o files are linked.
253 ``extern_weak``
254     The semantics of this linkage follow the ELF object file model: the
255     symbol is weak until linked, if not linked, the symbol becomes null
256     instead of being an undefined reference.
257 ``linkonce_odr``, ``weak_odr``
258     Some languages allow differing globals to be merged, such as two
259     functions with different semantics. Other languages, such as
260     ``C++``, ensure that only equivalent globals are ever merged (the
261     "one definition rule" --- "ODR"). Such languages can use the
262     ``linkonce_odr`` and ``weak_odr`` linkage types to indicate that the
263     global will only be merged with equivalent globals. These linkage
264     types are otherwise the same as their non-``odr`` versions.
265 ``external``
266     If none of the above identifiers are used, the global is externally
267     visible, meaning that it participates in linkage and can be used to
268     resolve external symbol references.
269
270 It is illegal for a function *declaration* to have any linkage type
271 other than ``external`` or ``extern_weak``.
272
273 .. _callingconv:
274
275 Calling Conventions
276 -------------------
277
278 LLVM :ref:`functions <functionstructure>`, :ref:`calls <i_call>` and
279 :ref:`invokes <i_invoke>` can all have an optional calling convention
280 specified for the call. The calling convention of any pair of dynamic
281 caller/callee must match, or the behavior of the program is undefined.
282 The following calling conventions are supported by LLVM, and more may be
283 added in the future:
284
285 "``ccc``" - The C calling convention
286     This calling convention (the default if no other calling convention
287     is specified) matches the target C calling conventions. This calling
288     convention supports varargs function calls and tolerates some
289     mismatch in the declared prototype and implemented declaration of
290     the function (as does normal C).
291 "``fastcc``" - The fast calling convention
292     This calling convention attempts to make calls as fast as possible
293     (e.g. by passing things in registers). This calling convention
294     allows the target to use whatever tricks it wants to produce fast
295     code for the target, without having to conform to an externally
296     specified ABI (Application Binary Interface). `Tail calls can only
297     be optimized when this, the GHC or the HiPE convention is
298     used. <CodeGenerator.html#id80>`_ This calling convention does not
299     support varargs and requires the prototype of all callees to exactly
300     match the prototype of the function definition.
301 "``coldcc``" - The cold calling convention
302     This calling convention attempts to make code in the caller as
303     efficient as possible under the assumption that the call is not
304     commonly executed. As such, these calls often preserve all registers
305     so that the call does not break any live ranges in the caller side.
306     This calling convention does not support varargs and requires the
307     prototype of all callees to exactly match the prototype of the
308     function definition. Furthermore the inliner doesn't consider such function
309     calls for inlining.
310 "``cc 10``" - GHC convention
311     This calling convention has been implemented specifically for use by
312     the `Glasgow Haskell Compiler (GHC) <http://www.haskell.org/ghc>`_.
313     It passes everything in registers, going to extremes to achieve this
314     by disabling callee save registers. This calling convention should
315     not be used lightly but only for specific situations such as an
316     alternative to the *register pinning* performance technique often
317     used when implementing functional programming languages. At the
318     moment only X86 supports this convention and it has the following
319     limitations:
320
321     -  On *X86-32* only supports up to 4 bit type parameters. No
322        floating point types are supported.
323     -  On *X86-64* only supports up to 10 bit type parameters and 6
324        floating point parameters.
325
326     This calling convention supports `tail call
327     optimization <CodeGenerator.html#id80>`_ but requires both the
328     caller and callee are using it.
329 "``cc 11``" - The HiPE calling convention
330     This calling convention has been implemented specifically for use by
331     the `High-Performance Erlang
332     (HiPE) <http://www.it.uu.se/research/group/hipe/>`_ compiler, *the*
333     native code compiler of the `Ericsson's Open Source Erlang/OTP
334     system <http://www.erlang.org/download.shtml>`_. It uses more
335     registers for argument passing than the ordinary C calling
336     convention and defines no callee-saved registers. The calling
337     convention properly supports `tail call
338     optimization <CodeGenerator.html#id80>`_ but requires that both the
339     caller and the callee use it. It uses a *register pinning*
340     mechanism, similar to GHC's convention, for keeping frequently
341     accessed runtime components pinned to specific hardware registers.
342     At the moment only X86 supports this convention (both 32 and 64
343     bit).
344 "``webkit_jscc``" - WebKit's JavaScript calling convention
345     This calling convention has been implemented for `WebKit FTL JIT
346     <https://trac.webkit.org/wiki/FTLJIT>`_. It passes arguments on the
347     stack right to left (as cdecl does), and returns a value in the
348     platform's customary return register.
349 "``anyregcc``" - Dynamic calling convention for code patching
350     This is a special convention that supports patching an arbitrary code
351     sequence in place of a call site. This convention forces the call
352     arguments into registers but allows them to be dynamically
353     allocated. This can currently only be used with calls to
354     llvm.experimental.patchpoint because only this intrinsic records
355     the location of its arguments in a side table. See :doc:`StackMaps`.
356 "``preserve_mostcc``" - The `PreserveMost` calling convention
357     This calling convention attempts to make the code in the caller as
358     unintrusive as possible. This convention behaves identically to the `C`
359     calling convention on how arguments and return values are passed, but it
360     uses a different set of caller/callee-saved registers. This alleviates the
361     burden of saving and recovering a large register set before and after the
362     call in the caller. If the arguments are passed in callee-saved registers,
363     then they will be preserved by the callee across the call. This doesn't
364     apply for values returned in callee-saved registers.
365
366     - On X86-64 the callee preserves all general purpose registers, except for
367       R11. R11 can be used as a scratch register. Floating-point registers
368       (XMMs/YMMs) are not preserved and need to be saved by the caller.
369
370     The idea behind this convention is to support calls to runtime functions
371     that have a hot path and a cold path. The hot path is usually a small piece
372     of code that doesn't use many registers. The cold path might need to call out to
373     another function and therefore only needs to preserve the caller-saved
374     registers, which haven't already been saved by the caller. The
375     `PreserveMost` calling convention is very similar to the `cold` calling
376     convention in terms of caller/callee-saved registers, but they are used for
377     different types of function calls. `coldcc` is for function calls that are
378     rarely executed, whereas `preserve_mostcc` function calls are intended to be
379     on the hot path and definitely executed a lot. Furthermore `preserve_mostcc`
380     doesn't prevent the inliner from inlining the function call.
381
382     This calling convention will be used by a future version of the ObjectiveC
383     runtime and should therefore still be considered experimental at this time.
384     Although this convention was created to optimize certain runtime calls to
385     the ObjectiveC runtime, it is not limited to this runtime and might be used
386     by other runtimes in the future too. The current implementation only
387     supports X86-64, but the intention is to support more architectures in the
388     future.
389 "``preserve_allcc``" - The `PreserveAll` calling convention
390     This calling convention attempts to make the code in the caller even less
391     intrusive than the `PreserveMost` calling convention. This calling
392     convention also behaves identical to the `C` calling convention on how
393     arguments and return values are passed, but it uses a different set of
394     caller/callee-saved registers. This removes the burden of saving and
395     recovering a large register set before and after the call in the caller. If
396     the arguments are passed in callee-saved registers, then they will be
397     preserved by the callee across the call. This doesn't apply for values
398     returned in callee-saved registers.
399
400     - On X86-64 the callee preserves all general purpose registers, except for
401       R11. R11 can be used as a scratch register. Furthermore it also preserves
402       all floating-point registers (XMMs/YMMs).
403
404     The idea behind this convention is to support calls to runtime functions
405     that don't need to call out to any other functions.
406
407     This calling convention, like the `PreserveMost` calling convention, will be
408     used by a future version of the ObjectiveC runtime and should be considered
409     experimental at this time.
410 "``cxx_fast_tlscc``" - The `CXX_FAST_TLS` calling convention for access functions
411     Clang generates an access function to access C++-style TLS. The access
412     function generally has an entry block, an exit block and an initialization
413     block that is run at the first time. The entry and exit blocks can access
414     a few TLS IR variables, each access will be lowered to a platform-specific
415     sequence.
416
417     This calling convention aims to minimize overhead in the caller by
418     preserving as many registers as possible (all the registers that are
419     perserved on the fast path, composed of the entry and exit blocks).
420
421     This calling convention behaves identical to the `C` calling convention on
422     how arguments and return values are passed, but it uses a different set of
423     caller/callee-saved registers.
424
425     Given that each platform has its own lowering sequence, hence its own set
426     of preserved registers, we can't use the existing `PreserveMost`.
427
428     - On X86-64 the callee preserves all general purpose registers, except for
429       RDI and RAX.
430 "``cc <n>``" - Numbered convention
431     Any calling convention may be specified by number, allowing
432     target-specific calling conventions to be used. Target specific
433     calling conventions start at 64.
434
435 More calling conventions can be added/defined on an as-needed basis, to
436 support Pascal conventions or any other well-known target-independent
437 convention.
438
439 .. _visibilitystyles:
440
441 Visibility Styles
442 -----------------
443
444 All Global Variables and Functions have one of the following visibility
445 styles:
446
447 "``default``" - Default style
448     On targets that use the ELF object file format, default visibility
449     means that the declaration is visible to other modules and, in
450     shared libraries, means that the declared entity may be overridden.
451     On Darwin, default visibility means that the declaration is visible
452     to other modules. Default visibility corresponds to "external
453     linkage" in the language.
454 "``hidden``" - Hidden style
455     Two declarations of an object with hidden visibility refer to the
456     same object if they are in the same shared object. Usually, hidden
457     visibility indicates that the symbol will not be placed into the
458     dynamic symbol table, so no other module (executable or shared
459     library) can reference it directly.
460 "``protected``" - Protected style
461     On ELF, protected visibility indicates that the symbol will be
462     placed in the dynamic symbol table, but that references within the
463     defining module will bind to the local symbol. That is, the symbol
464     cannot be overridden by another module.
465
466 A symbol with ``internal`` or ``private`` linkage must have ``default``
467 visibility.
468
469 .. _dllstorageclass:
470
471 DLL Storage Classes
472 -------------------
473
474 All Global Variables, Functions and Aliases can have one of the following
475 DLL storage class:
476
477 ``dllimport``
478     "``dllimport``" causes the compiler to reference a function or variable via
479     a global pointer to a pointer that is set up by the DLL exporting the
480     symbol. On Microsoft Windows targets, the pointer name is formed by
481     combining ``__imp_`` and the function or variable name.
482 ``dllexport``
483     "``dllexport``" causes the compiler to provide a global pointer to a pointer
484     in a DLL, so that it can be referenced with the ``dllimport`` attribute. On
485     Microsoft Windows targets, the pointer name is formed by combining
486     ``__imp_`` and the function or variable name. Since this storage class
487     exists for defining a dll interface, the compiler, assembler and linker know
488     it is externally referenced and must refrain from deleting the symbol.
489
490 .. _tls_model:
491
492 Thread Local Storage Models
493 ---------------------------
494
495 A variable may be defined as ``thread_local``, which means that it will
496 not be shared by threads (each thread will have a separated copy of the
497 variable). Not all targets support thread-local variables. Optionally, a
498 TLS model may be specified:
499
500 ``localdynamic``
501     For variables that are only used within the current shared library.
502 ``initialexec``
503     For variables in modules that will not be loaded dynamically.
504 ``localexec``
505     For variables defined in the executable and only used within it.
506
507 If no explicit model is given, the "general dynamic" model is used.
508
509 The models correspond to the ELF TLS models; see `ELF Handling For
510 Thread-Local Storage <http://people.redhat.com/drepper/tls.pdf>`_ for
511 more information on under which circumstances the different models may
512 be used. The target may choose a different TLS model if the specified
513 model is not supported, or if a better choice of model can be made.
514
515 A model can also be specified in an alias, but then it only governs how
516 the alias is accessed. It will not have any effect in the aliasee.
517
518 For platforms without linker support of ELF TLS model, the -femulated-tls
519 flag can be used to generate GCC compatible emulated TLS code.
520
521 .. _namedtypes:
522
523 Structure Types
524 ---------------
525
526 LLVM IR allows you to specify both "identified" and "literal" :ref:`structure
527 types <t_struct>`. Literal types are uniqued structurally, but identified types
528 are never uniqued. An :ref:`opaque structural type <t_opaque>` can also be used
529 to forward declare a type that is not yet available.
530
531 An example of an identified structure specification is:
532
533 .. code-block:: llvm
534
535     %mytype = type { %mytype*, i32 }
536
537 Prior to the LLVM 3.0 release, identified types were structurally uniqued. Only
538 literal types are uniqued in recent versions of LLVM.
539
540 .. _globalvars:
541
542 Global Variables
543 ----------------
544
545 Global variables define regions of memory allocated at compilation time
546 instead of run-time.
547
548 Global variable definitions must be initialized.
549
550 Global variables in other translation units can also be declared, in which
551 case they don't have an initializer.
552
553 Either global variable definitions or declarations may have an explicit section
554 to be placed in and may have an optional explicit alignment specified.
555
556 A variable may be defined as a global ``constant``, which indicates that
557 the contents of the variable will **never** be modified (enabling better
558 optimization, allowing the global data to be placed in the read-only
559 section of an executable, etc). Note that variables that need runtime
560 initialization cannot be marked ``constant`` as there is a store to the
561 variable.
562
563 LLVM explicitly allows *declarations* of global variables to be marked
564 constant, even if the final definition of the global is not. This
565 capability can be used to enable slightly better optimization of the
566 program, but requires the language definition to guarantee that
567 optimizations based on the 'constantness' are valid for the translation
568 units that do not include the definition.
569
570 As SSA values, global variables define pointer values that are in scope
571 (i.e. they dominate) all basic blocks in the program. Global variables
572 always define a pointer to their "content" type because they describe a
573 region of memory, and all memory objects in LLVM are accessed through
574 pointers.
575
576 Global variables can be marked with ``unnamed_addr`` which indicates
577 that the address is not significant, only the content. Constants marked
578 like this can be merged with other constants if they have the same
579 initializer. Note that a constant with significant address *can* be
580 merged with a ``unnamed_addr`` constant, the result being a constant
581 whose address is significant.
582
583 A global variable may be declared to reside in a target-specific
584 numbered address space. For targets that support them, address spaces
585 may affect how optimizations are performed and/or what target
586 instructions are used to access the variable. The default address space
587 is zero. The address space qualifier must precede any other attributes.
588
589 LLVM allows an explicit section to be specified for globals. If the
590 target supports it, it will emit globals to the section specified.
591 Additionally, the global can placed in a comdat if the target has the necessary
592 support.
593
594 By default, global initializers are optimized by assuming that global
595 variables defined within the module are not modified from their
596 initial values before the start of the global initializer. This is
597 true even for variables potentially accessible from outside the
598 module, including those with external linkage or appearing in
599 ``@llvm.used`` or dllexported variables. This assumption may be suppressed
600 by marking the variable with ``externally_initialized``.
601
602 An explicit alignment may be specified for a global, which must be a
603 power of 2. If not present, or if the alignment is set to zero, the
604 alignment of the global is set by the target to whatever it feels
605 convenient. If an explicit alignment is specified, the global is forced
606 to have exactly that alignment. Targets and optimizers are not allowed
607 to over-align the global if the global has an assigned section. In this
608 case, the extra alignment could be observable: for example, code could
609 assume that the globals are densely packed in their section and try to
610 iterate over them as an array, alignment padding would break this
611 iteration. The maximum alignment is ``1 << 29``.
612
613 Globals can also have a :ref:`DLL storage class <dllstorageclass>`.
614
615 Variables and aliases can have a
616 :ref:`Thread Local Storage Model <tls_model>`.
617
618 Syntax::
619
620     [@<GlobalVarName> =] [Linkage] [Visibility] [DLLStorageClass] [ThreadLocal]
621                          [unnamed_addr] [AddrSpace] [ExternallyInitialized]
622                          <global | constant> <Type> [<InitializerConstant>]
623                          [, section "name"] [, comdat [($name)]]
624                          [, align <Alignment>]
625
626 For example, the following defines a global in a numbered address space
627 with an initializer, section, and alignment:
628
629 .. code-block:: llvm
630
631     @G = addrspace(5) constant float 1.0, section "foo", align 4
632
633 The following example just declares a global variable
634
635 .. code-block:: llvm
636
637    @G = external global i32
638
639 The following example defines a thread-local global with the
640 ``initialexec`` TLS model:
641
642 .. code-block:: llvm
643
644     @G = thread_local(initialexec) global i32 0, align 4
645
646 .. _functionstructure:
647
648 Functions
649 ---------
650
651 LLVM function definitions consist of the "``define``" keyword, an
652 optional :ref:`linkage type <linkage>`, an optional :ref:`visibility
653 style <visibility>`, an optional :ref:`DLL storage class <dllstorageclass>`,
654 an optional :ref:`calling convention <callingconv>`,
655 an optional ``unnamed_addr`` attribute, a return type, an optional
656 :ref:`parameter attribute <paramattrs>` for the return type, a function
657 name, a (possibly empty) argument list (each with optional :ref:`parameter
658 attributes <paramattrs>`), optional :ref:`function attributes <fnattrs>`,
659 an optional section, an optional alignment,
660 an optional :ref:`comdat <langref_comdats>`,
661 an optional :ref:`garbage collector name <gc>`, an optional :ref:`prefix <prefixdata>`,
662 an optional :ref:`prologue <prologuedata>`,
663 an optional :ref:`personality <personalityfn>`,
664 an optional list of attached :ref:`metadata <metadata>`,
665 an opening curly brace, a list of basic blocks, and a closing curly brace.
666
667 LLVM function declarations consist of the "``declare``" keyword, an
668 optional :ref:`linkage type <linkage>`, an optional :ref:`visibility
669 style <visibility>`, an optional :ref:`DLL storage class <dllstorageclass>`,
670 an optional :ref:`calling convention <callingconv>`,
671 an optional ``unnamed_addr`` attribute, a return type, an optional
672 :ref:`parameter attribute <paramattrs>` for the return type, a function
673 name, a possibly empty list of arguments, an optional alignment, an optional
674 :ref:`garbage collector name <gc>`, an optional :ref:`prefix <prefixdata>`,
675 and an optional :ref:`prologue <prologuedata>`.
676
677 A function definition contains a list of basic blocks, forming the CFG (Control
678 Flow Graph) for the function. Each basic block may optionally start with a label
679 (giving the basic block a symbol table entry), contains a list of instructions,
680 and ends with a :ref:`terminator <terminators>` instruction (such as a branch or
681 function return). If an explicit label is not provided, a block is assigned an
682 implicit numbered label, using the next value from the same counter as used for
683 unnamed temporaries (:ref:`see above<identifiers>`). For example, if a function
684 entry block does not have an explicit label, it will be assigned label "%0",
685 then the first unnamed temporary in that block will be "%1", etc.
686
687 The first basic block in a function is special in two ways: it is
688 immediately executed on entrance to the function, and it is not allowed
689 to have predecessor basic blocks (i.e. there can not be any branches to
690 the entry block of a function). Because the block can have no
691 predecessors, it also cannot have any :ref:`PHI nodes <i_phi>`.
692
693 LLVM allows an explicit section to be specified for functions. If the
694 target supports it, it will emit functions to the section specified.
695 Additionally, the function can be placed in a COMDAT.
696
697 An explicit alignment may be specified for a function. If not present,
698 or if the alignment is set to zero, the alignment of the function is set
699 by the target to whatever it feels convenient. If an explicit alignment
700 is specified, the function is forced to have at least that much
701 alignment. All alignments must be a power of 2.
702
703 If the ``unnamed_addr`` attribute is given, the address is known to not
704 be significant and two identical functions can be merged.
705
706 Syntax::
707
708     define [linkage] [visibility] [DLLStorageClass]
709            [cconv] [ret attrs]
710            <ResultType> @<FunctionName> ([argument list])
711            [unnamed_addr] [fn Attrs] [section "name"] [comdat [($name)]]
712            [align N] [gc] [prefix Constant] [prologue Constant]
713            [personality Constant] (!name !N)* { ... }
714
715 The argument list is a comma separated sequence of arguments where each
716 argument is of the following form:
717
718 Syntax::
719
720    <type> [parameter Attrs] [name]
721
722
723 .. _langref_aliases:
724
725 Aliases
726 -------
727
728 Aliases, unlike function or variables, don't create any new data. They
729 are just a new symbol and metadata for an existing position.
730
731 Aliases have a name and an aliasee that is either a global value or a
732 constant expression.
733
734 Aliases may have an optional :ref:`linkage type <linkage>`, an optional
735 :ref:`visibility style <visibility>`, an optional :ref:`DLL storage class
736 <dllstorageclass>` and an optional :ref:`tls model <tls_model>`.
737
738 Syntax::
739
740     @<Name> = [Linkage] [Visibility] [DLLStorageClass] [ThreadLocal] [unnamed_addr] alias <AliaseeTy>, <AliaseeTy>* @<Aliasee>
741
742 The linkage must be one of ``private``, ``internal``, ``linkonce``, ``weak``,
743 ``linkonce_odr``, ``weak_odr``, ``external``. Note that some system linkers
744 might not correctly handle dropping a weak symbol that is aliased.
745
746 Aliases that are not ``unnamed_addr`` are guaranteed to have the same address as
747 the aliasee expression. ``unnamed_addr`` ones are only guaranteed to point
748 to the same content.
749
750 Since aliases are only a second name, some restrictions apply, of which
751 some can only be checked when producing an object file:
752
753 * The expression defining the aliasee must be computable at assembly
754   time. Since it is just a name, no relocations can be used.
755
756 * No alias in the expression can be weak as the possibility of the
757   intermediate alias being overridden cannot be represented in an
758   object file.
759
760 * No global value in the expression can be a declaration, since that
761   would require a relocation, which is not possible.
762
763 .. _langref_comdats:
764
765 Comdats
766 -------
767
768 Comdat IR provides access to COFF and ELF object file COMDAT functionality.
769
770 Comdats have a name which represents the COMDAT key. All global objects that
771 specify this key will only end up in the final object file if the linker chooses
772 that key over some other key. Aliases are placed in the same COMDAT that their
773 aliasee computes to, if any.
774
775 Comdats have a selection kind to provide input on how the linker should
776 choose between keys in two different object files.
777
778 Syntax::
779
780     $<Name> = comdat SelectionKind
781
782 The selection kind must be one of the following:
783
784 ``any``
785     The linker may choose any COMDAT key, the choice is arbitrary.
786 ``exactmatch``
787     The linker may choose any COMDAT key but the sections must contain the
788     same data.
789 ``largest``
790     The linker will choose the section containing the largest COMDAT key.
791 ``noduplicates``
792     The linker requires that only section with this COMDAT key exist.
793 ``samesize``
794     The linker may choose any COMDAT key but the sections must contain the
795     same amount of data.
796
797 Note that the Mach-O platform doesn't support COMDATs and ELF only supports
798 ``any`` as a selection kind.
799
800 Here is an example of a COMDAT group where a function will only be selected if
801 the COMDAT key's section is the largest:
802
803 .. code-block:: llvm
804
805    $foo = comdat largest
806    @foo = global i32 2, comdat($foo)
807
808    define void @bar() comdat($foo) {
809      ret void
810    }
811
812 As a syntactic sugar the ``$name`` can be omitted if the name is the same as
813 the global name:
814
815 .. code-block:: llvm
816
817   $foo = comdat any
818   @foo = global i32 2, comdat
819
820
821 In a COFF object file, this will create a COMDAT section with selection kind
822 ``IMAGE_COMDAT_SELECT_LARGEST`` containing the contents of the ``@foo`` symbol
823 and another COMDAT section with selection kind
824 ``IMAGE_COMDAT_SELECT_ASSOCIATIVE`` which is associated with the first COMDAT
825 section and contains the contents of the ``@bar`` symbol.
826
827 There are some restrictions on the properties of the global object.
828 It, or an alias to it, must have the same name as the COMDAT group when
829 targeting COFF.
830 The contents and size of this object may be used during link-time to determine
831 which COMDAT groups get selected depending on the selection kind.
832 Because the name of the object must match the name of the COMDAT group, the
833 linkage of the global object must not be local; local symbols can get renamed
834 if a collision occurs in the symbol table.
835
836 The combined use of COMDATS and section attributes may yield surprising results.
837 For example:
838
839 .. code-block:: llvm
840
841    $foo = comdat any
842    $bar = comdat any
843    @g1 = global i32 42, section "sec", comdat($foo)
844    @g2 = global i32 42, section "sec", comdat($bar)
845
846 From the object file perspective, this requires the creation of two sections
847 with the same name. This is necessary because both globals belong to different
848 COMDAT groups and COMDATs, at the object file level, are represented by
849 sections.
850
851 Note that certain IR constructs like global variables and functions may
852 create COMDATs in the object file in addition to any which are specified using
853 COMDAT IR. This arises when the code generator is configured to emit globals
854 in individual sections (e.g. when `-data-sections` or `-function-sections`
855 is supplied to `llc`).
856
857 .. _namedmetadatastructure:
858
859 Named Metadata
860 --------------
861
862 Named metadata is a collection of metadata. :ref:`Metadata
863 nodes <metadata>` (but not metadata strings) are the only valid
864 operands for a named metadata.
865
866 #. Named metadata are represented as a string of characters with the
867    metadata prefix. The rules for metadata names are the same as for
868    identifiers, but quoted names are not allowed. ``"\xx"`` type escapes
869    are still valid, which allows any character to be part of a name.
870
871 Syntax::
872
873     ; Some unnamed metadata nodes, which are referenced by the named metadata.
874     !0 = !{!"zero"}
875     !1 = !{!"one"}
876     !2 = !{!"two"}
877     ; A named metadata.
878     !name = !{!0, !1, !2}
879
880 .. _paramattrs:
881
882 Parameter Attributes
883 --------------------
884
885 The return type and each parameter of a function type may have a set of
886 *parameter attributes* associated with them. Parameter attributes are
887 used to communicate additional information about the result or
888 parameters of a function. Parameter attributes are considered to be part
889 of the function, not of the function type, so functions with different
890 parameter attributes can have the same function type.
891
892 Parameter attributes are simple keywords that follow the type specified.
893 If multiple parameter attributes are needed, they are space separated.
894 For example:
895
896 .. code-block:: llvm
897
898     declare i32 @printf(i8* noalias nocapture, ...)
899     declare i32 @atoi(i8 zeroext)
900     declare signext i8 @returns_signed_char()
901
902 Note that any attributes for the function result (``nounwind``,
903 ``readonly``) come immediately after the argument list.
904
905 Currently, only the following parameter attributes are defined:
906
907 ``zeroext``
908     This indicates to the code generator that the parameter or return
909     value should be zero-extended to the extent required by the target's
910     ABI (which is usually 32-bits, but is 8-bits for a i1 on x86-64) by
911     the caller (for a parameter) or the callee (for a return value).
912 ``signext``
913     This indicates to the code generator that the parameter or return
914     value should be sign-extended to the extent required by the target's
915     ABI (which is usually 32-bits) by the caller (for a parameter) or
916     the callee (for a return value).
917 ``inreg``
918     This indicates that this parameter or return value should be treated
919     in a special target-dependent fashion while emitting code for
920     a function call or return (usually, by putting it in a register as
921     opposed to memory, though some targets use it to distinguish between
922     two different kinds of registers). Use of this attribute is
923     target-specific.
924 ``byval``
925     This indicates that the pointer parameter should really be passed by
926     value to the function. The attribute implies that a hidden copy of
927     the pointee is made between the caller and the callee, so the callee
928     is unable to modify the value in the caller. This attribute is only
929     valid on LLVM pointer arguments. It is generally used to pass
930     structs and arrays by value, but is also valid on pointers to
931     scalars. The copy is considered to belong to the caller not the
932     callee (for example, ``readonly`` functions should not write to
933     ``byval`` parameters). This is not a valid attribute for return
934     values.
935
936     The byval attribute also supports specifying an alignment with the
937     align attribute. It indicates the alignment of the stack slot to
938     form and the known alignment of the pointer specified to the call
939     site. If the alignment is not specified, then the code generator
940     makes a target-specific assumption.
941
942 .. _attr_inalloca:
943
944 ``inalloca``
945
946     The ``inalloca`` argument attribute allows the caller to take the
947     address of outgoing stack arguments. An ``inalloca`` argument must
948     be a pointer to stack memory produced by an ``alloca`` instruction.
949     The alloca, or argument allocation, must also be tagged with the
950     inalloca keyword. Only the last argument may have the ``inalloca``
951     attribute, and that argument is guaranteed to be passed in memory.
952
953     An argument allocation may be used by a call at most once because
954     the call may deallocate it. The ``inalloca`` attribute cannot be
955     used in conjunction with other attributes that affect argument
956     storage, like ``inreg``, ``nest``, ``sret``, or ``byval``. The
957     ``inalloca`` attribute also disables LLVM's implicit lowering of
958     large aggregate return values, which means that frontend authors
959     must lower them with ``sret`` pointers.
960
961     When the call site is reached, the argument allocation must have
962     been the most recent stack allocation that is still live, or the
963     results are undefined. It is possible to allocate additional stack
964     space after an argument allocation and before its call site, but it
965     must be cleared off with :ref:`llvm.stackrestore
966     <int_stackrestore>`.
967
968     See :doc:`InAlloca` for more information on how to use this
969     attribute.
970
971 ``sret``
972     This indicates that the pointer parameter specifies the address of a
973     structure that is the return value of the function in the source
974     program. This pointer must be guaranteed by the caller to be valid:
975     loads and stores to the structure may be assumed by the callee
976     not to trap and to be properly aligned. This may only be applied to
977     the first parameter. This is not a valid attribute for return
978     values.
979
980 ``align <n>``
981     This indicates that the pointer value may be assumed by the optimizer to
982     have the specified alignment.
983
984     Note that this attribute has additional semantics when combined with the
985     ``byval`` attribute.
986
987 .. _noalias:
988
989 ``noalias``
990     This indicates that objects accessed via pointer values
991     :ref:`based <pointeraliasing>` on the argument or return value are not also
992     accessed, during the execution of the function, via pointer values not
993     *based* on the argument or return value. The attribute on a return value
994     also has additional semantics described below. The caller shares the
995     responsibility with the callee for ensuring that these requirements are met.
996     For further details, please see the discussion of the NoAlias response in
997     :ref:`alias analysis <Must, May, or No>`.
998
999     Note that this definition of ``noalias`` is intentionally similar
1000     to the definition of ``restrict`` in C99 for function arguments.
1001
1002     For function return values, C99's ``restrict`` is not meaningful,
1003     while LLVM's ``noalias`` is. Furthermore, the semantics of the ``noalias``
1004     attribute on return values are stronger than the semantics of the attribute
1005     when used on function arguments. On function return values, the ``noalias``
1006     attribute indicates that the function acts like a system memory allocation
1007     function, returning a pointer to allocated storage disjoint from the
1008     storage for any other object accessible to the caller.
1009
1010 ``nocapture``
1011     This indicates that the callee does not make any copies of the
1012     pointer that outlive the callee itself. This is not a valid
1013     attribute for return values.
1014
1015 .. _nest:
1016
1017 ``nest``
1018     This indicates that the pointer parameter can be excised using the
1019     :ref:`trampoline intrinsics <int_trampoline>`. This is not a valid
1020     attribute for return values and can only be applied to one parameter.
1021
1022 ``returned``
1023     This indicates that the function always returns the argument as its return
1024     value. This is an optimization hint to the code generator when generating
1025     the caller, allowing tail call optimization and omission of register saves
1026     and restores in some cases; it is not checked or enforced when generating
1027     the callee. The parameter and the function return type must be valid
1028     operands for the :ref:`bitcast instruction <i_bitcast>`. This is not a
1029     valid attribute for return values and can only be applied to one parameter.
1030
1031 ``nonnull``
1032     This indicates that the parameter or return pointer is not null. This
1033     attribute may only be applied to pointer typed parameters. This is not
1034     checked or enforced by LLVM, the caller must ensure that the pointer
1035     passed in is non-null, or the callee must ensure that the returned pointer
1036     is non-null.
1037
1038 ``dereferenceable(<n>)``
1039     This indicates that the parameter or return pointer is dereferenceable. This
1040     attribute may only be applied to pointer typed parameters. A pointer that
1041     is dereferenceable can be loaded from speculatively without a risk of
1042     trapping. The number of bytes known to be dereferenceable must be provided
1043     in parentheses. It is legal for the number of bytes to be less than the
1044     size of the pointee type. The ``nonnull`` attribute does not imply
1045     dereferenceability (consider a pointer to one element past the end of an
1046     array), however ``dereferenceable(<n>)`` does imply ``nonnull`` in
1047     ``addrspace(0)`` (which is the default address space).
1048
1049 ``dereferenceable_or_null(<n>)``
1050     This indicates that the parameter or return value isn't both
1051     non-null and non-dereferenceable (up to ``<n>`` bytes) at the same
1052     time. All non-null pointers tagged with
1053     ``dereferenceable_or_null(<n>)`` are ``dereferenceable(<n>)``.
1054     For address space 0 ``dereferenceable_or_null(<n>)`` implies that
1055     a pointer is exactly one of ``dereferenceable(<n>)`` or ``null``,
1056     and in other address spaces ``dereferenceable_or_null(<n>)``
1057     implies that a pointer is at least one of ``dereferenceable(<n>)``
1058     or ``null`` (i.e. it may be both ``null`` and
1059     ``dereferenceable(<n>)``). This attribute may only be applied to
1060     pointer typed parameters.
1061
1062 .. _gc:
1063
1064 Garbage Collector Strategy Names
1065 --------------------------------
1066
1067 Each function may specify a garbage collector strategy name, which is simply a
1068 string:
1069
1070 .. code-block:: llvm
1071
1072     define void @f() gc "name" { ... }
1073
1074 The supported values of *name* includes those :ref:`built in to LLVM
1075 <builtin-gc-strategies>` and any provided by loaded plugins. Specifying a GC
1076 strategy will cause the compiler to alter its output in order to support the
1077 named garbage collection algorithm. Note that LLVM itself does not contain a
1078 garbage collector, this functionality is restricted to generating machine code
1079 which can interoperate with a collector provided externally.
1080
1081 .. _prefixdata:
1082
1083 Prefix Data
1084 -----------
1085
1086 Prefix data is data associated with a function which the code
1087 generator will emit immediately before the function's entrypoint.
1088 The purpose of this feature is to allow frontends to associate
1089 language-specific runtime metadata with specific functions and make it
1090 available through the function pointer while still allowing the
1091 function pointer to be called.
1092
1093 To access the data for a given function, a program may bitcast the
1094 function pointer to a pointer to the constant's type and dereference
1095 index -1. This implies that the IR symbol points just past the end of
1096 the prefix data. For instance, take the example of a function annotated
1097 with a single ``i32``,
1098
1099 .. code-block:: llvm
1100
1101     define void @f() prefix i32 123 { ... }
1102
1103 The prefix data can be referenced as,
1104
1105 .. code-block:: llvm
1106
1107     %0 = bitcast void* () @f to i32*
1108     %a = getelementptr inbounds i32, i32* %0, i32 -1
1109     %b = load i32, i32* %a
1110
1111 Prefix data is laid out as if it were an initializer for a global variable
1112 of the prefix data's type. The function will be placed such that the
1113 beginning of the prefix data is aligned. This means that if the size
1114 of the prefix data is not a multiple of the alignment size, the
1115 function's entrypoint will not be aligned. If alignment of the
1116 function's entrypoint is desired, padding must be added to the prefix
1117 data.
1118
1119 A function may have prefix data but no body. This has similar semantics
1120 to the ``available_externally`` linkage in that the data may be used by the
1121 optimizers but will not be emitted in the object file.
1122
1123 .. _prologuedata:
1124
1125 Prologue Data
1126 -------------
1127
1128 The ``prologue`` attribute allows arbitrary code (encoded as bytes) to
1129 be inserted prior to the function body. This can be used for enabling
1130 function hot-patching and instrumentation.
1131
1132 To maintain the semantics of ordinary function calls, the prologue data must
1133 have a particular format. Specifically, it must begin with a sequence of
1134 bytes which decode to a sequence of machine instructions, valid for the
1135 module's target, which transfer control to the point immediately succeeding
1136 the prologue data, without performing any other visible action. This allows
1137 the inliner and other passes to reason about the semantics of the function
1138 definition without needing to reason about the prologue data. Obviously this
1139 makes the format of the prologue data highly target dependent.
1140
1141 A trivial example of valid prologue data for the x86 architecture is ``i8 144``,
1142 which encodes the ``nop`` instruction:
1143
1144 .. code-block:: llvm
1145
1146     define void @f() prologue i8 144 { ... }
1147
1148 Generally prologue data can be formed by encoding a relative branch instruction
1149 which skips the metadata, as in this example of valid prologue data for the
1150 x86_64 architecture, where the first two bytes encode ``jmp .+10``:
1151
1152 .. code-block:: llvm
1153
1154     %0 = type <{ i8, i8, i8* }>
1155
1156     define void @f() prologue %0 <{ i8 235, i8 8, i8* @md}> { ... }
1157
1158 A function may have prologue data but no body. This has similar semantics
1159 to the ``available_externally`` linkage in that the data may be used by the
1160 optimizers but will not be emitted in the object file.
1161
1162 .. _personalityfn:
1163
1164 Personality Function
1165 --------------------
1166
1167 The ``personality`` attribute permits functions to specify what function
1168 to use for exception handling.
1169
1170 .. _attrgrp:
1171
1172 Attribute Groups
1173 ----------------
1174
1175 Attribute groups are groups of attributes that are referenced by objects within
1176 the IR. They are important for keeping ``.ll`` files readable, because a lot of
1177 functions will use the same set of attributes. In the degenerative case of a
1178 ``.ll`` file that corresponds to a single ``.c`` file, the single attribute
1179 group will capture the important command line flags used to build that file.
1180
1181 An attribute group is a module-level object. To use an attribute group, an
1182 object references the attribute group's ID (e.g. ``#37``). An object may refer
1183 to more than one attribute group. In that situation, the attributes from the
1184 different groups are merged.
1185
1186 Here is an example of attribute groups for a function that should always be
1187 inlined, has a stack alignment of 4, and which shouldn't use SSE instructions:
1188
1189 .. code-block:: llvm
1190
1191    ; Target-independent attributes:
1192    attributes #0 = { alwaysinline alignstack=4 }
1193
1194    ; Target-dependent attributes:
1195    attributes #1 = { "no-sse" }
1196
1197    ; Function @f has attributes: alwaysinline, alignstack=4, and "no-sse".
1198    define void @f() #0 #1 { ... }
1199
1200 .. _fnattrs:
1201
1202 Function Attributes
1203 -------------------
1204
1205 Function attributes are set to communicate additional information about
1206 a function. Function attributes are considered to be part of the
1207 function, not of the function type, so functions with different function
1208 attributes can have the same function type.
1209
1210 Function attributes are simple keywords that follow the type specified.
1211 If multiple attributes are needed, they are space separated. For
1212 example:
1213
1214 .. code-block:: llvm
1215
1216     define void @f() noinline { ... }
1217     define void @f() alwaysinline { ... }
1218     define void @f() alwaysinline optsize { ... }
1219     define void @f() optsize { ... }
1220
1221 ``alignstack(<n>)``
1222     This attribute indicates that, when emitting the prologue and
1223     epilogue, the backend should forcibly align the stack pointer.
1224     Specify the desired alignment, which must be a power of two, in
1225     parentheses.
1226 ``alwaysinline``
1227     This attribute indicates that the inliner should attempt to inline
1228     this function into callers whenever possible, ignoring any active
1229     inlining size threshold for this caller.
1230 ``builtin``
1231     This indicates that the callee function at a call site should be
1232     recognized as a built-in function, even though the function's declaration
1233     uses the ``nobuiltin`` attribute. This is only valid at call sites for
1234     direct calls to functions that are declared with the ``nobuiltin``
1235     attribute.
1236 ``cold``
1237     This attribute indicates that this function is rarely called. When
1238     computing edge weights, basic blocks post-dominated by a cold
1239     function call are also considered to be cold; and, thus, given low
1240     weight.
1241 ``convergent``
1242     This attribute indicates that the callee is dependent on a convergent
1243     thread execution pattern under certain parallel execution models.
1244     Transformations that are execution model agnostic may not make the execution
1245     of a convergent operation control dependent on any additional values.
1246 ``inaccessiblememonly``
1247     This attribute indicates that the function may only access memory that
1248     is not accessible by the module being compiled. This is a weaker form
1249     of ``readnone``.
1250 ``inaccessiblemem_or_argmemonly``
1251     This attribute indicates that the function may only access memory that is
1252     either not accessible by the module being compiled, or is pointed to
1253     by its pointer arguments. This is a weaker form of  ``argmemonly``
1254 ``inlinehint``
1255     This attribute indicates that the source code contained a hint that
1256     inlining this function is desirable (such as the "inline" keyword in
1257     C/C++). It is just a hint; it imposes no requirements on the
1258     inliner.
1259 ``jumptable``
1260     This attribute indicates that the function should be added to a
1261     jump-instruction table at code-generation time, and that all address-taken
1262     references to this function should be replaced with a reference to the
1263     appropriate jump-instruction-table function pointer. Note that this creates
1264     a new pointer for the original function, which means that code that depends
1265     on function-pointer identity can break. So, any function annotated with
1266     ``jumptable`` must also be ``unnamed_addr``.
1267 ``minsize``
1268     This attribute suggests that optimization passes and code generator
1269     passes make choices that keep the code size of this function as small
1270     as possible and perform optimizations that may sacrifice runtime
1271     performance in order to minimize the size of the generated code.
1272 ``naked``
1273     This attribute disables prologue / epilogue emission for the
1274     function. This can have very system-specific consequences.
1275 ``nobuiltin``
1276     This indicates that the callee function at a call site is not recognized as
1277     a built-in function. LLVM will retain the original call and not replace it
1278     with equivalent code based on the semantics of the built-in function, unless
1279     the call site uses the ``builtin`` attribute. This is valid at call sites
1280     and on function declarations and definitions.
1281 ``noduplicate``
1282     This attribute indicates that calls to the function cannot be
1283     duplicated. A call to a ``noduplicate`` function may be moved
1284     within its parent function, but may not be duplicated within
1285     its parent function.
1286
1287     A function containing a ``noduplicate`` call may still
1288     be an inlining candidate, provided that the call is not
1289     duplicated by inlining. That implies that the function has
1290     internal linkage and only has one call site, so the original
1291     call is dead after inlining.
1292 ``noimplicitfloat``
1293     This attributes disables implicit floating point instructions.
1294 ``noinline``
1295     This attribute indicates that the inliner should never inline this
1296     function in any situation. This attribute may not be used together
1297     with the ``alwaysinline`` attribute.
1298 ``nonlazybind``
1299     This attribute suppresses lazy symbol binding for the function. This
1300     may make calls to the function faster, at the cost of extra program
1301     startup time if the function is not called during program startup.
1302 ``noredzone``
1303     This attribute indicates that the code generator should not use a
1304     red zone, even if the target-specific ABI normally permits it.
1305 ``noreturn``
1306     This function attribute indicates that the function never returns
1307     normally. This produces undefined behavior at runtime if the
1308     function ever does dynamically return.
1309 ``norecurse``
1310     This function attribute indicates that the function does not call itself
1311     either directly or indirectly down any possible call path. This produces
1312     undefined behavior at runtime if the function ever does recurse.
1313 ``nounwind``
1314     This function attribute indicates that the function never raises an
1315     exception. If the function does raise an exception, its runtime
1316     behavior is undefined. However, functions marked nounwind may still
1317     trap or generate asynchronous exceptions. Exception handling schemes
1318     that are recognized by LLVM to handle asynchronous exceptions, such
1319     as SEH, will still provide their implementation defined semantics.
1320 ``optnone``
1321     This function attribute indicates that most optimization passes will skip
1322     this function, with the exception of interprocedural optimization passes.
1323     Code generation defaults to the "fast" instruction selector.
1324     This attribute cannot be used together with the ``alwaysinline``
1325     attribute; this attribute is also incompatible
1326     with the ``minsize`` attribute and the ``optsize`` attribute.
1327
1328     This attribute requires the ``noinline`` attribute to be specified on
1329     the function as well, so the function is never inlined into any caller.
1330     Only functions with the ``alwaysinline`` attribute are valid
1331     candidates for inlining into the body of this function.
1332 ``optsize``
1333     This attribute suggests that optimization passes and code generator
1334     passes make choices that keep the code size of this function low,
1335     and otherwise do optimizations specifically to reduce code size as
1336     long as they do not significantly impact runtime performance.
1337 ``readnone``
1338     On a function, this attribute indicates that the function computes its
1339     result (or decides to unwind an exception) based strictly on its arguments,
1340     without dereferencing any pointer arguments or otherwise accessing
1341     any mutable state (e.g. memory, control registers, etc) visible to
1342     caller functions. It does not write through any pointer arguments
1343     (including ``byval`` arguments) and never changes any state visible
1344     to callers. This means that it cannot unwind exceptions by calling
1345     the ``C++`` exception throwing methods.
1346
1347     On an argument, this attribute indicates that the function does not
1348     dereference that pointer argument, even though it may read or write the
1349     memory that the pointer points to if accessed through other pointers.
1350 ``readonly``
1351     On a function, this attribute indicates that the function does not write
1352     through any pointer arguments (including ``byval`` arguments) or otherwise
1353     modify any state (e.g. memory, control registers, etc) visible to
1354     caller functions. It may dereference pointer arguments and read
1355     state that may be set in the caller. A readonly function always
1356     returns the same value (or unwinds an exception identically) when
1357     called with the same set of arguments and global state. It cannot
1358     unwind an exception by calling the ``C++`` exception throwing
1359     methods.
1360
1361     On an argument, this attribute indicates that the function does not write
1362     through this pointer argument, even though it may write to the memory that
1363     the pointer points to.
1364 ``argmemonly``
1365     This attribute indicates that the only memory accesses inside function are
1366     loads and stores from objects pointed to by its pointer-typed arguments,
1367     with arbitrary offsets. Or in other words, all memory operations in the
1368     function can refer to memory only using pointers based on its function
1369     arguments.
1370     Note that ``argmemonly`` can be used together with ``readonly`` attribute
1371     in order to specify that function reads only from its arguments.
1372 ``returns_twice``
1373     This attribute indicates that this function can return twice. The C
1374     ``setjmp`` is an example of such a function. The compiler disables
1375     some optimizations (like tail calls) in the caller of these
1376     functions.
1377 ``safestack``
1378     This attribute indicates that
1379     `SafeStack <http://clang.llvm.org/docs/SafeStack.html>`_
1380     protection is enabled for this function.
1381
1382     If a function that has a ``safestack`` attribute is inlined into a
1383     function that doesn't have a ``safestack`` attribute or which has an
1384     ``ssp``, ``sspstrong`` or ``sspreq`` attribute, then the resulting
1385     function will have a ``safestack`` attribute.
1386 ``sanitize_address``
1387     This attribute indicates that AddressSanitizer checks
1388     (dynamic address safety analysis) are enabled for this function.
1389 ``sanitize_memory``
1390     This attribute indicates that MemorySanitizer checks (dynamic detection
1391     of accesses to uninitialized memory) are enabled for this function.
1392 ``sanitize_thread``
1393     This attribute indicates that ThreadSanitizer checks
1394     (dynamic thread safety analysis) are enabled for this function.
1395 ``ssp``
1396     This attribute indicates that the function should emit a stack
1397     smashing protector. It is in the form of a "canary" --- a random value
1398     placed on the stack before the local variables that's checked upon
1399     return from the function to see if it has been overwritten. A
1400     heuristic is used to determine if a function needs stack protectors
1401     or not. The heuristic used will enable protectors for functions with:
1402
1403     - Character arrays larger than ``ssp-buffer-size`` (default 8).
1404     - Aggregates containing character arrays larger than ``ssp-buffer-size``.
1405     - Calls to alloca() with variable sizes or constant sizes greater than
1406       ``ssp-buffer-size``.
1407
1408     Variables that are identified as requiring a protector will be arranged
1409     on the stack such that they are adjacent to the stack protector guard.
1410
1411     If a function that has an ``ssp`` attribute is inlined into a
1412     function that doesn't have an ``ssp`` attribute, then the resulting
1413     function will have an ``ssp`` attribute.
1414 ``sspreq``
1415     This attribute indicates that the function should *always* emit a
1416     stack smashing protector. This overrides the ``ssp`` function
1417     attribute.
1418
1419     Variables that are identified as requiring a protector will be arranged
1420     on the stack such that they are adjacent to the stack protector guard.
1421     The specific layout rules are:
1422
1423     #. Large arrays and structures containing large arrays
1424        (``>= ssp-buffer-size``) are closest to the stack protector.
1425     #. Small arrays and structures containing small arrays
1426        (``< ssp-buffer-size``) are 2nd closest to the protector.
1427     #. Variables that have had their address taken are 3rd closest to the
1428        protector.
1429
1430     If a function that has an ``sspreq`` attribute is inlined into a
1431     function that doesn't have an ``sspreq`` attribute or which has an
1432     ``ssp`` or ``sspstrong`` attribute, then the resulting function will have
1433     an ``sspreq`` attribute.
1434 ``sspstrong``
1435     This attribute indicates that the function should emit a stack smashing
1436     protector. This attribute causes a strong heuristic to be used when
1437     determining if a function needs stack protectors. The strong heuristic
1438     will enable protectors for functions with:
1439
1440     - Arrays of any size and type
1441     - Aggregates containing an array of any size and type.
1442     - Calls to alloca().
1443     - Local variables that have had their address taken.
1444
1445     Variables that are identified as requiring a protector will be arranged
1446     on the stack such that they are adjacent to the stack protector guard.
1447     The specific layout rules are:
1448
1449     #. Large arrays and structures containing large arrays
1450        (``>= ssp-buffer-size``) are closest to the stack protector.
1451     #. Small arrays and structures containing small arrays
1452        (``< ssp-buffer-size``) are 2nd closest to the protector.
1453     #. Variables that have had their address taken are 3rd closest to the
1454        protector.
1455
1456     This overrides the ``ssp`` function attribute.
1457
1458     If a function that has an ``sspstrong`` attribute is inlined into a
1459     function that doesn't have an ``sspstrong`` attribute, then the
1460     resulting function will have an ``sspstrong`` attribute.
1461 ``"thunk"``
1462     This attribute indicates that the function will delegate to some other
1463     function with a tail call. The prototype of a thunk should not be used for
1464     optimization purposes. The caller is expected to cast the thunk prototype to
1465     match the thunk target prototype.
1466 ``uwtable``
1467     This attribute indicates that the ABI being targeted requires that
1468     an unwind table entry be produced for this function even if we can
1469     show that no exceptions passes by it. This is normally the case for
1470     the ELF x86-64 abi, but it can be disabled for some compilation
1471     units.
1472
1473
1474 .. _opbundles:
1475
1476 Operand Bundles
1477 ---------------
1478
1479 Note: operand bundles are a work in progress, and they should be
1480 considered experimental at this time.
1481
1482 Operand bundles are tagged sets of SSA values that can be associated
1483 with certain LLVM instructions (currently only ``call`` s and
1484 ``invoke`` s).  In a way they are like metadata, but dropping them is
1485 incorrect and will change program semantics.
1486
1487 Syntax::
1488
1489     operand bundle set ::= '[' operand bundle (, operand bundle )* ']'
1490     operand bundle ::= tag '(' [ bundle operand ] (, bundle operand )* ')'
1491     bundle operand ::= SSA value
1492     tag ::= string constant
1493
1494 Operand bundles are **not** part of a function's signature, and a
1495 given function may be called from multiple places with different kinds
1496 of operand bundles.  This reflects the fact that the operand bundles
1497 are conceptually a part of the ``call`` (or ``invoke``), not the
1498 callee being dispatched to.
1499
1500 Operand bundles are a generic mechanism intended to support
1501 runtime-introspection-like functionality for managed languages.  While
1502 the exact semantics of an operand bundle depend on the bundle tag,
1503 there are certain limitations to how much the presence of an operand
1504 bundle can influence the semantics of a program.  These restrictions
1505 are described as the semantics of an "unknown" operand bundle.  As
1506 long as the behavior of an operand bundle is describable within these
1507 restrictions, LLVM does not need to have special knowledge of the
1508 operand bundle to not miscompile programs containing it.
1509
1510 - The bundle operands for an unknown operand bundle escape in unknown
1511   ways before control is transferred to the callee or invokee.
1512 - Calls and invokes with operand bundles have unknown read / write
1513   effect on the heap on entry and exit (even if the call target is
1514   ``readnone`` or ``readonly``), unless they're overriden with
1515   callsite specific attributes.
1516 - An operand bundle at a call site cannot change the implementation
1517   of the called function.  Inter-procedural optimizations work as
1518   usual as long as they take into account the first two properties.
1519
1520 More specific types of operand bundles are described below.
1521
1522 Deoptimization Operand Bundles
1523 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
1524
1525 Deoptimization operand bundles are characterized by the ``"deopt"``
1526 operand bundle tag.  These operand bundles represent an alternate
1527 "safe" continuation for the call site they're attached to, and can be
1528 used by a suitable runtime to deoptimize the compiled frame at the
1529 specified call site.  There can be at most one ``"deopt"`` operand
1530 bundle attached to a call site.  Exact details of deoptimization is
1531 out of scope for the language reference, but it usually involves
1532 rewriting a compiled frame into a set of interpreted frames.
1533
1534 From the compiler's perspective, deoptimization operand bundles make
1535 the call sites they're attached to at least ``readonly``.  They read
1536 through all of their pointer typed operands (even if they're not
1537 otherwise escaped) and the entire visible heap.  Deoptimization
1538 operand bundles do not capture their operands except during
1539 deoptimization, in which case control will not be returned to the
1540 compiled frame.
1541
1542 The inliner knows how to inline through calls that have deoptimization
1543 operand bundles.  Just like inlining through a normal call site
1544 involves composing the normal and exceptional continuations, inlining
1545 through a call site with a deoptimization operand bundle needs to
1546 appropriately compose the "safe" deoptimization continuation.  The
1547 inliner does this by prepending the parent's deoptimization
1548 continuation to every deoptimization continuation in the inlined body.
1549 E.g. inlining ``@f`` into ``@g`` in the following example
1550
1551 .. code-block:: llvm
1552
1553     define void @f() {
1554       call void @x()  ;; no deopt state
1555       call void @y() [ "deopt"(i32 10) ]
1556       call void @y() [ "deopt"(i32 10), "unknown"(i8* null) ]
1557       ret void
1558     }
1559
1560     define void @g() {
1561       call void @f() [ "deopt"(i32 20) ]
1562       ret void
1563     }
1564
1565 will result in
1566
1567 .. code-block:: llvm
1568
1569     define void @g() {
1570       call void @x()  ;; still no deopt state
1571       call void @y() [ "deopt"(i32 20, i32 10) ]
1572       call void @y() [ "deopt"(i32 20, i32 10), "unknown"(i8* null) ]
1573       ret void
1574     }
1575
1576 It is the frontend's responsibility to structure or encode the
1577 deoptimization state in a way that syntactically prepending the
1578 caller's deoptimization state to the callee's deoptimization state is
1579 semantically equivalent to composing the caller's deoptimization
1580 continuation after the callee's deoptimization continuation.
1581
1582 Funclet Operand Bundles
1583 ^^^^^^^^^^^^^^^^^^^^^^^
1584
1585 Funclet operand bundles are characterized by the ``"funclet"``
1586 operand bundle tag.  These operand bundles indicate that a call site
1587 is within a particular funclet.  There can be at most one
1588 ``"funclet"`` operand bundle attached to a call site and it must have
1589 exactly one bundle operand.
1590
1591 .. _moduleasm:
1592
1593 Module-Level Inline Assembly
1594 ----------------------------
1595
1596 Modules may contain "module-level inline asm" blocks, which corresponds
1597 to the GCC "file scope inline asm" blocks. These blocks are internally
1598 concatenated by LLVM and treated as a single unit, but may be separated
1599 in the ``.ll`` file if desired. The syntax is very simple:
1600
1601 .. code-block:: llvm
1602
1603     module asm "inline asm code goes here"
1604     module asm "more can go here"
1605
1606 The strings can contain any character by escaping non-printable
1607 characters. The escape sequence used is simply "\\xx" where "xx" is the
1608 two digit hex code for the number.
1609
1610 Note that the assembly string *must* be parseable by LLVM's integrated assembler
1611 (unless it is disabled), even when emitting a ``.s`` file.
1612
1613 .. _langref_datalayout:
1614
1615 Data Layout
1616 -----------
1617
1618 A module may specify a target specific data layout string that specifies
1619 how data is to be laid out in memory. The syntax for the data layout is
1620 simply:
1621
1622 .. code-block:: llvm
1623
1624     target datalayout = "layout specification"
1625
1626 The *layout specification* consists of a list of specifications
1627 separated by the minus sign character ('-'). Each specification starts
1628 with a letter and may include other information after the letter to
1629 define some aspect of the data layout. The specifications accepted are
1630 as follows:
1631
1632 ``E``
1633     Specifies that the target lays out data in big-endian form. That is,
1634     the bits with the most significance have the lowest address
1635     location.
1636 ``e``
1637     Specifies that the target lays out data in little-endian form. That
1638     is, the bits with the least significance have the lowest address
1639     location.
1640 ``S<size>``
1641     Specifies the natural alignment of the stack in bits. Alignment
1642     promotion of stack variables is limited to the natural stack
1643     alignment to avoid dynamic stack realignment. The stack alignment
1644     must be a multiple of 8-bits. If omitted, the natural stack
1645     alignment defaults to "unspecified", which does not prevent any
1646     alignment promotions.
1647 ``p[n]:<size>:<abi>:<pref>``
1648     This specifies the *size* of a pointer and its ``<abi>`` and
1649     ``<pref>``\erred alignments for address space ``n``. All sizes are in
1650     bits. The address space, ``n``, is optional, and if not specified,
1651     denotes the default address space 0. The value of ``n`` must be
1652     in the range [1,2^23).
1653 ``i<size>:<abi>:<pref>``
1654     This specifies the alignment for an integer type of a given bit
1655     ``<size>``. The value of ``<size>`` must be in the range [1,2^23).
1656 ``v<size>:<abi>:<pref>``
1657     This specifies the alignment for a vector type of a given bit
1658     ``<size>``.
1659 ``f<size>:<abi>:<pref>``
1660     This specifies the alignment for a floating point type of a given bit
1661     ``<size>``. Only values of ``<size>`` that are supported by the target
1662     will work. 32 (float) and 64 (double) are supported on all targets; 80
1663     or 128 (different flavors of long double) are also supported on some
1664     targets.
1665 ``a:<abi>:<pref>``
1666     This specifies the alignment for an object of aggregate type.
1667 ``m:<mangling>``
1668     If present, specifies that llvm names are mangled in the output. The
1669     options are
1670
1671     * ``e``: ELF mangling: Private symbols get a ``.L`` prefix.
1672     * ``m``: Mips mangling: Private symbols get a ``$`` prefix.
1673     * ``o``: Mach-O mangling: Private symbols get ``L`` prefix. Other
1674       symbols get a ``_`` prefix.
1675     * ``w``: Windows COFF prefix:  Similar to Mach-O, but stdcall and fastcall
1676       functions also get a suffix based on the frame size.
1677     * ``x``: Windows x86 COFF prefix:  Similar to Windows COFF, but use a ``_``
1678       prefix for ``__cdecl`` functions.
1679 ``n<size1>:<size2>:<size3>...``
1680     This specifies a set of native integer widths for the target CPU in
1681     bits. For example, it might contain ``n32`` for 32-bit PowerPC,
1682     ``n32:64`` for PowerPC 64, or ``n8:16:32:64`` for X86-64. Elements of
1683     this set are considered to support most general arithmetic operations
1684     efficiently.
1685
1686 On every specification that takes a ``<abi>:<pref>``, specifying the
1687 ``<pref>`` alignment is optional. If omitted, the preceding ``:``
1688 should be omitted too and ``<pref>`` will be equal to ``<abi>``.
1689
1690 When constructing the data layout for a given target, LLVM starts with a
1691 default set of specifications which are then (possibly) overridden by
1692 the specifications in the ``datalayout`` keyword. The default
1693 specifications are given in this list:
1694
1695 -  ``E`` - big endian
1696 -  ``p:64:64:64`` - 64-bit pointers with 64-bit alignment.
1697 -  ``p[n]:64:64:64`` - Other address spaces are assumed to be the
1698    same as the default address space.
1699 -  ``S0`` - natural stack alignment is unspecified
1700 -  ``i1:8:8`` - i1 is 8-bit (byte) aligned
1701 -  ``i8:8:8`` - i8 is 8-bit (byte) aligned
1702 -  ``i16:16:16`` - i16 is 16-bit aligned
1703 -  ``i32:32:32`` - i32 is 32-bit aligned
1704 -  ``i64:32:64`` - i64 has ABI alignment of 32-bits but preferred
1705    alignment of 64-bits
1706 -  ``f16:16:16`` - half is 16-bit aligned
1707 -  ``f32:32:32`` - float is 32-bit aligned
1708 -  ``f64:64:64`` - double is 64-bit aligned
1709 -  ``f128:128:128`` - quad is 128-bit aligned
1710 -  ``v64:64:64`` - 64-bit vector is 64-bit aligned
1711 -  ``v128:128:128`` - 128-bit vector is 128-bit aligned
1712 -  ``a:0:64`` - aggregates are 64-bit aligned
1713
1714 When LLVM is determining the alignment for a given type, it uses the
1715 following rules:
1716
1717 #. If the type sought is an exact match for one of the specifications,
1718    that specification is used.
1719 #. If no match is found, and the type sought is an integer type, then
1720    the smallest integer type that is larger than the bitwidth of the
1721    sought type is used. If none of the specifications are larger than
1722    the bitwidth then the largest integer type is used. For example,
1723    given the default specifications above, the i7 type will use the
1724    alignment of i8 (next largest) while both i65 and i256 will use the
1725    alignment of i64 (largest specified).
1726 #. If no match is found, and the type sought is a vector type, then the
1727    largest vector type that is smaller than the sought vector type will
1728    be used as a fall back. This happens because <128 x double> can be
1729    implemented in terms of 64 <2 x double>, for example.
1730
1731 The function of the data layout string may not be what you expect.
1732 Notably, this is not a specification from the frontend of what alignment
1733 the code generator should use.
1734
1735 Instead, if specified, the target data layout is required to match what
1736 the ultimate *code generator* expects. This string is used by the
1737 mid-level optimizers to improve code, and this only works if it matches
1738 what the ultimate code generator uses. There is no way to generate IR
1739 that does not embed this target-specific detail into the IR. If you
1740 don't specify the string, the default specifications will be used to
1741 generate a Data Layout and the optimization phases will operate
1742 accordingly and introduce target specificity into the IR with respect to
1743 these default specifications.
1744
1745 .. _langref_triple:
1746
1747 Target Triple
1748 -------------
1749
1750 A module may specify a target triple string that describes the target
1751 host. The syntax for the target triple is simply:
1752
1753 .. code-block:: llvm
1754
1755     target triple = "x86_64-apple-macosx10.7.0"
1756
1757 The *target triple* string consists of a series of identifiers delimited
1758 by the minus sign character ('-'). The canonical forms are:
1759
1760 ::
1761
1762     ARCHITECTURE-VENDOR-OPERATING_SYSTEM
1763     ARCHITECTURE-VENDOR-OPERATING_SYSTEM-ENVIRONMENT
1764
1765 This information is passed along to the backend so that it generates
1766 code for the proper architecture. It's possible to override this on the
1767 command line with the ``-mtriple`` command line option.
1768
1769 .. _pointeraliasing:
1770
1771 Pointer Aliasing Rules
1772 ----------------------
1773
1774 Any memory access must be done through a pointer value associated with
1775 an address range of the memory access, otherwise the behavior is
1776 undefined. Pointer values are associated with address ranges according
1777 to the following rules:
1778
1779 -  A pointer value is associated with the addresses associated with any
1780    value it is *based* on.
1781 -  An address of a global variable is associated with the address range
1782    of the variable's storage.
1783 -  The result value of an allocation instruction is associated with the
1784    address range of the allocated storage.
1785 -  A null pointer in the default address-space is associated with no
1786    address.
1787 -  An integer constant other than zero or a pointer value returned from
1788    a function not defined within LLVM may be associated with address
1789    ranges allocated through mechanisms other than those provided by
1790    LLVM. Such ranges shall not overlap with any ranges of addresses
1791    allocated by mechanisms provided by LLVM.
1792
1793 A pointer value is *based* on another pointer value according to the
1794 following rules:
1795
1796 -  A pointer value formed from a ``getelementptr`` operation is *based*
1797    on the first value operand of the ``getelementptr``.
1798 -  The result value of a ``bitcast`` is *based* on the operand of the
1799    ``bitcast``.
1800 -  A pointer value formed by an ``inttoptr`` is *based* on all pointer
1801    values that contribute (directly or indirectly) to the computation of
1802    the pointer's value.
1803 -  The "*based* on" relationship is transitive.
1804
1805 Note that this definition of *"based"* is intentionally similar to the
1806 definition of *"based"* in C99, though it is slightly weaker.
1807
1808 LLVM IR does not associate types with memory. The result type of a
1809 ``load`` merely indicates the size and alignment of the memory from
1810 which to load, as well as the interpretation of the value. The first
1811 operand type of a ``store`` similarly only indicates the size and
1812 alignment of the store.
1813
1814 Consequently, type-based alias analysis, aka TBAA, aka
1815 ``-fstrict-aliasing``, is not applicable to general unadorned LLVM IR.
1816 :ref:`Metadata <metadata>` may be used to encode additional information
1817 which specialized optimization passes may use to implement type-based
1818 alias analysis.
1819
1820 .. _volatile:
1821
1822 Volatile Memory Accesses
1823 ------------------------
1824
1825 Certain memory accesses, such as :ref:`load <i_load>`'s,
1826 :ref:`store <i_store>`'s, and :ref:`llvm.memcpy <int_memcpy>`'s may be
1827 marked ``volatile``. The optimizers must not change the number of
1828 volatile operations or change their order of execution relative to other
1829 volatile operations. The optimizers *may* change the order of volatile
1830 operations relative to non-volatile operations. This is not Java's
1831 "volatile" and has no cross-thread synchronization behavior.
1832
1833 IR-level volatile loads and stores cannot safely be optimized into
1834 llvm.memcpy or llvm.memmove intrinsics even when those intrinsics are
1835 flagged volatile. Likewise, the backend should never split or merge
1836 target-legal volatile load/store instructions.
1837
1838 .. admonition:: Rationale
1839
1840  Platforms may rely on volatile loads and stores of natively supported
1841  data width to be executed as single instruction. For example, in C
1842  this holds for an l-value of volatile primitive type with native
1843  hardware support, but not necessarily for aggregate types. The
1844  frontend upholds these expectations, which are intentionally
1845  unspecified in the IR. The rules above ensure that IR transformations
1846  do not violate the frontend's contract with the language.
1847
1848 .. _memmodel:
1849
1850 Memory Model for Concurrent Operations
1851 --------------------------------------
1852
1853 The LLVM IR does not define any way to start parallel threads of
1854 execution or to register signal handlers. Nonetheless, there are
1855 platform-specific ways to create them, and we define LLVM IR's behavior
1856 in their presence. This model is inspired by the C++0x memory model.
1857
1858 For a more informal introduction to this model, see the :doc:`Atomics`.
1859
1860 We define a *happens-before* partial order as the least partial order
1861 that
1862
1863 -  Is a superset of single-thread program order, and
1864 -  When a *synchronizes-with* ``b``, includes an edge from ``a`` to
1865    ``b``. *Synchronizes-with* pairs are introduced by platform-specific
1866    techniques, like pthread locks, thread creation, thread joining,
1867    etc., and by atomic instructions. (See also :ref:`Atomic Memory Ordering
1868    Constraints <ordering>`).
1869
1870 Note that program order does not introduce *happens-before* edges
1871 between a thread and signals executing inside that thread.
1872
1873 Every (defined) read operation (load instructions, memcpy, atomic
1874 loads/read-modify-writes, etc.) R reads a series of bytes written by
1875 (defined) write operations (store instructions, atomic
1876 stores/read-modify-writes, memcpy, etc.). For the purposes of this
1877 section, initialized globals are considered to have a write of the
1878 initializer which is atomic and happens before any other read or write
1879 of the memory in question. For each byte of a read R, R\ :sub:`byte`
1880 may see any write to the same byte, except:
1881
1882 -  If write\ :sub:`1`  happens before write\ :sub:`2`, and
1883    write\ :sub:`2` happens before R\ :sub:`byte`, then
1884    R\ :sub:`byte` does not see write\ :sub:`1`.
1885 -  If R\ :sub:`byte` happens before write\ :sub:`3`, then
1886    R\ :sub:`byte` does not see write\ :sub:`3`.
1887
1888 Given that definition, R\ :sub:`byte` is defined as follows:
1889
1890 -  If R is volatile, the result is target-dependent. (Volatile is
1891    supposed to give guarantees which can support ``sig_atomic_t`` in
1892    C/C++, and may be used for accesses to addresses that do not behave
1893    like normal memory. It does not generally provide cross-thread
1894    synchronization.)
1895 -  Otherwise, if there is no write to the same byte that happens before
1896    R\ :sub:`byte`, R\ :sub:`byte` returns ``undef`` for that byte.
1897 -  Otherwise, if R\ :sub:`byte` may see exactly one write,
1898    R\ :sub:`byte` returns the value written by that write.
1899 -  Otherwise, if R is atomic, and all the writes R\ :sub:`byte` may
1900    see are atomic, it chooses one of the values written. See the :ref:`Atomic
1901    Memory Ordering Constraints <ordering>` section for additional
1902    constraints on how the choice is made.
1903 -  Otherwise R\ :sub:`byte` returns ``undef``.
1904
1905 R returns the value composed of the series of bytes it read. This
1906 implies that some bytes within the value may be ``undef`` **without**
1907 the entire value being ``undef``. Note that this only defines the
1908 semantics of the operation; it doesn't mean that targets will emit more
1909 than one instruction to read the series of bytes.
1910
1911 Note that in cases where none of the atomic intrinsics are used, this
1912 model places only one restriction on IR transformations on top of what
1913 is required for single-threaded execution: introducing a store to a byte
1914 which might not otherwise be stored is not allowed in general.
1915 (Specifically, in the case where another thread might write to and read
1916 from an address, introducing a store can change a load that may see
1917 exactly one write into a load that may see multiple writes.)
1918
1919 .. _ordering:
1920
1921 Atomic Memory Ordering Constraints
1922 ----------------------------------
1923
1924 Atomic instructions (:ref:`cmpxchg <i_cmpxchg>`,
1925 :ref:`atomicrmw <i_atomicrmw>`, :ref:`fence <i_fence>`,
1926 :ref:`atomic load <i_load>`, and :ref:`atomic store <i_store>`) take
1927 ordering parameters that determine which other atomic instructions on
1928 the same address they *synchronize with*. These semantics are borrowed
1929 from Java and C++0x, but are somewhat more colloquial. If these
1930 descriptions aren't precise enough, check those specs (see spec
1931 references in the :doc:`atomics guide <Atomics>`).
1932 :ref:`fence <i_fence>` instructions treat these orderings somewhat
1933 differently since they don't take an address. See that instruction's
1934 documentation for details.
1935
1936 For a simpler introduction to the ordering constraints, see the
1937 :doc:`Atomics`.
1938
1939 ``unordered``
1940     The set of values that can be read is governed by the happens-before
1941     partial order. A value cannot be read unless some operation wrote
1942     it. This is intended to provide a guarantee strong enough to model
1943     Java's non-volatile shared variables. This ordering cannot be
1944     specified for read-modify-write operations; it is not strong enough
1945     to make them atomic in any interesting way.
1946 ``monotonic``
1947     In addition to the guarantees of ``unordered``, there is a single
1948     total order for modifications by ``monotonic`` operations on each
1949     address. All modification orders must be compatible with the
1950     happens-before order. There is no guarantee that the modification
1951     orders can be combined to a global total order for the whole program
1952     (and this often will not be possible). The read in an atomic
1953     read-modify-write operation (:ref:`cmpxchg <i_cmpxchg>` and
1954     :ref:`atomicrmw <i_atomicrmw>`) reads the value in the modification
1955     order immediately before the value it writes. If one atomic read
1956     happens before another atomic read of the same address, the later
1957     read must see the same value or a later value in the address's
1958     modification order. This disallows reordering of ``monotonic`` (or
1959     stronger) operations on the same address. If an address is written
1960     ``monotonic``-ally by one thread, and other threads ``monotonic``-ally
1961     read that address repeatedly, the other threads must eventually see
1962     the write. This corresponds to the C++0x/C1x
1963     ``memory_order_relaxed``.
1964 ``acquire``
1965     In addition to the guarantees of ``monotonic``, a
1966     *synchronizes-with* edge may be formed with a ``release`` operation.
1967     This is intended to model C++'s ``memory_order_acquire``.
1968 ``release``
1969     In addition to the guarantees of ``monotonic``, if this operation
1970     writes a value which is subsequently read by an ``acquire``
1971     operation, it *synchronizes-with* that operation. (This isn't a
1972     complete description; see the C++0x definition of a release
1973     sequence.) This corresponds to the C++0x/C1x
1974     ``memory_order_release``.
1975 ``acq_rel`` (acquire+release)
1976     Acts as both an ``acquire`` and ``release`` operation on its
1977     address. This corresponds to the C++0x/C1x ``memory_order_acq_rel``.
1978 ``seq_cst`` (sequentially consistent)
1979     In addition to the guarantees of ``acq_rel`` (``acquire`` for an
1980     operation that only reads, ``release`` for an operation that only
1981     writes), there is a global total order on all
1982     sequentially-consistent operations on all addresses, which is
1983     consistent with the *happens-before* partial order and with the
1984     modification orders of all the affected addresses. Each
1985     sequentially-consistent read sees the last preceding write to the
1986     same address in this global order. This corresponds to the C++0x/C1x
1987     ``memory_order_seq_cst`` and Java volatile.
1988
1989 .. _singlethread:
1990
1991 If an atomic operation is marked ``singlethread``, it only *synchronizes
1992 with* or participates in modification and seq\_cst total orderings with
1993 other operations running in the same thread (for example, in signal
1994 handlers).
1995
1996 .. _fastmath:
1997
1998 Fast-Math Flags
1999 ---------------
2000
2001 LLVM IR floating-point binary ops (:ref:`fadd <i_fadd>`,
2002 :ref:`fsub <i_fsub>`, :ref:`fmul <i_fmul>`, :ref:`fdiv <i_fdiv>`,
2003 :ref:`frem <i_frem>`, :ref:`fcmp <i_fcmp>`) have the following flags that can
2004 be set to enable otherwise unsafe floating point operations
2005
2006 ``nnan``
2007    No NaNs - Allow optimizations to assume the arguments and result are not
2008    NaN. Such optimizations are required to retain defined behavior over
2009    NaNs, but the value of the result is undefined.
2010
2011 ``ninf``
2012    No Infs - Allow optimizations to assume the arguments and result are not
2013    +/-Inf. Such optimizations are required to retain defined behavior over
2014    +/-Inf, but the value of the result is undefined.
2015
2016 ``nsz``
2017    No Signed Zeros - Allow optimizations to treat the sign of a zero
2018    argument or result as insignificant.
2019
2020 ``arcp``
2021    Allow Reciprocal - Allow optimizations to use the reciprocal of an
2022    argument rather than perform division.
2023
2024 ``fast``
2025    Fast - Allow algebraically equivalent transformations that may
2026    dramatically change results in floating point (e.g. reassociate). This
2027    flag implies all the others.
2028
2029 .. _uselistorder:
2030
2031 Use-list Order Directives
2032 -------------------------
2033
2034 Use-list directives encode the in-memory order of each use-list, allowing the
2035 order to be recreated. ``<order-indexes>`` is a comma-separated list of
2036 indexes that are assigned to the referenced value's uses. The referenced
2037 value's use-list is immediately sorted by these indexes.
2038
2039 Use-list directives may appear at function scope or global scope. They are not
2040 instructions, and have no effect on the semantics of the IR. When they're at
2041 function scope, they must appear after the terminator of the final basic block.
2042
2043 If basic blocks have their address taken via ``blockaddress()`` expressions,
2044 ``uselistorder_bb`` can be used to reorder their use-lists from outside their
2045 function's scope.
2046
2047 :Syntax:
2048
2049 ::
2050
2051     uselistorder <ty> <value>, { <order-indexes> }
2052     uselistorder_bb @function, %block { <order-indexes> }
2053
2054 :Examples:
2055
2056 ::
2057
2058     define void @foo(i32 %arg1, i32 %arg2) {
2059     entry:
2060       ; ... instructions ...
2061     bb:
2062       ; ... instructions ...
2063
2064       ; At function scope.
2065       uselistorder i32 %arg1, { 1, 0, 2 }
2066       uselistorder label %bb, { 1, 0 }
2067     }
2068
2069     ; At global scope.
2070     uselistorder i32* @global, { 1, 2, 0 }
2071     uselistorder i32 7, { 1, 0 }
2072     uselistorder i32 (i32) @bar, { 1, 0 }
2073     uselistorder_bb @foo, %bb, { 5, 1, 3, 2, 0, 4 }
2074
2075 .. _typesystem:
2076
2077 Type System
2078 ===========
2079
2080 The LLVM type system is one of the most important features of the
2081 intermediate representation. Being typed enables a number of
2082 optimizations to be performed on the intermediate representation
2083 directly, without having to do extra analyses on the side before the
2084 transformation. A strong type system makes it easier to read the
2085 generated code and enables novel analyses and transformations that are
2086 not feasible to perform on normal three address code representations.
2087
2088 .. _t_void:
2089
2090 Void Type
2091 ---------
2092
2093 :Overview:
2094
2095
2096 The void type does not represent any value and has no size.
2097
2098 :Syntax:
2099
2100
2101 ::
2102
2103       void
2104
2105
2106 .. _t_function:
2107
2108 Function Type
2109 -------------
2110
2111 :Overview:
2112
2113
2114 The function type can be thought of as a function signature. It consists of a
2115 return type and a list of formal parameter types. The return type of a function
2116 type is a void type or first class type --- except for :ref:`label <t_label>`
2117 and :ref:`metadata <t_metadata>` types.
2118
2119 :Syntax:
2120
2121 ::
2122
2123       <returntype> (<parameter list>)
2124
2125 ...where '``<parameter list>``' is a comma-separated list of type
2126 specifiers. Optionally, the parameter list may include a type ``...``, which
2127 indicates that the function takes a variable number of arguments. Variable
2128 argument functions can access their arguments with the :ref:`variable argument
2129 handling intrinsic <int_varargs>` functions. '``<returntype>``' is any type
2130 except :ref:`label <t_label>` and :ref:`metadata <t_metadata>`.
2131
2132 :Examples:
2133
2134 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2135 | ``i32 (i32)``                   | function taking an ``i32``, returning an ``i32``                                                                                                                    |
2136 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2137 | ``float (i16, i32 *) *``        | :ref:`Pointer <t_pointer>` to a function that takes an ``i16`` and a :ref:`pointer <t_pointer>` to ``i32``, returning ``float``.                                    |
2138 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2139 | ``i32 (i8*, ...)``              | A vararg function that takes at least one :ref:`pointer <t_pointer>` to ``i8`` (char in C), which returns an integer. This is the signature for ``printf`` in LLVM. |
2140 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2141 | ``{i32, i32} (i32)``            | A function taking an ``i32``, returning a :ref:`structure <t_struct>` containing two ``i32`` values                                                                 |
2142 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2143
2144 .. _t_firstclass:
2145
2146 First Class Types
2147 -----------------
2148
2149 The :ref:`first class <t_firstclass>` types are perhaps the most important.
2150 Values of these types are the only ones which can be produced by
2151 instructions.
2152
2153 .. _t_single_value:
2154
2155 Single Value Types
2156 ^^^^^^^^^^^^^^^^^^
2157
2158 These are the types that are valid in registers from CodeGen's perspective.
2159
2160 .. _t_integer:
2161
2162 Integer Type
2163 """"""""""""
2164
2165 :Overview:
2166
2167 The integer type is a very simple type that simply specifies an
2168 arbitrary bit width for the integer type desired. Any bit width from 1
2169 bit to 2\ :sup:`23`\ -1 (about 8 million) can be specified.
2170
2171 :Syntax:
2172
2173 ::
2174
2175       iN
2176
2177 The number of bits the integer will occupy is specified by the ``N``
2178 value.
2179
2180 Examples:
2181 *********
2182
2183 +----------------+------------------------------------------------+
2184 | ``i1``         | a single-bit integer.                          |
2185 +----------------+------------------------------------------------+
2186 | ``i32``        | a 32-bit integer.                              |
2187 +----------------+------------------------------------------------+
2188 | ``i1942652``   | a really big integer of over 1 million bits.   |
2189 +----------------+------------------------------------------------+
2190
2191 .. _t_floating:
2192
2193 Floating Point Types
2194 """"""""""""""""""""
2195
2196 .. list-table::
2197    :header-rows: 1
2198
2199    * - Type
2200      - Description
2201
2202    * - ``half``
2203      - 16-bit floating point value
2204
2205    * - ``float``
2206      - 32-bit floating point value
2207
2208    * - ``double``
2209      - 64-bit floating point value
2210
2211    * - ``fp128``
2212      - 128-bit floating point value (112-bit mantissa)
2213
2214    * - ``x86_fp80``
2215      -  80-bit floating point value (X87)
2216
2217    * - ``ppc_fp128``
2218      - 128-bit floating point value (two 64-bits)
2219
2220 X86_mmx Type
2221 """"""""""""
2222
2223 :Overview:
2224
2225 The x86_mmx type represents a value held in an MMX register on an x86
2226 machine. The operations allowed on it are quite limited: parameters and
2227 return values, load and store, and bitcast. User-specified MMX
2228 instructions are represented as intrinsic or asm calls with arguments
2229 and/or results of this type. There are no arrays, vectors or constants
2230 of this type.
2231
2232 :Syntax:
2233
2234 ::
2235
2236       x86_mmx
2237
2238
2239 .. _t_pointer:
2240
2241 Pointer Type
2242 """"""""""""
2243
2244 :Overview:
2245
2246 The pointer type is used to specify memory locations. Pointers are
2247 commonly used to reference objects in memory.
2248
2249 Pointer types may have an optional address space attribute defining the
2250 numbered address space where the pointed-to object resides. The default
2251 address space is number zero. The semantics of non-zero address spaces
2252 are target-specific.
2253
2254 Note that LLVM does not permit pointers to void (``void*``) nor does it
2255 permit pointers to labels (``label*``). Use ``i8*`` instead.
2256
2257 :Syntax:
2258
2259 ::
2260
2261       <type> *
2262
2263 :Examples:
2264
2265 +-------------------------+--------------------------------------------------------------------------------------------------------------+
2266 | ``[4 x i32]*``          | A :ref:`pointer <t_pointer>` to :ref:`array <t_array>` of four ``i32`` values.                               |
2267 +-------------------------+--------------------------------------------------------------------------------------------------------------+
2268 | ``i32 (i32*) *``        | A :ref:`pointer <t_pointer>` to a :ref:`function <t_function>` that takes an ``i32*``, returning an ``i32``. |
2269 +-------------------------+--------------------------------------------------------------------------------------------------------------+
2270 | ``i32 addrspace(5)*``   | A :ref:`pointer <t_pointer>` to an ``i32`` value that resides in address space #5.                           |
2271 +-------------------------+--------------------------------------------------------------------------------------------------------------+
2272
2273 .. _t_vector:
2274
2275 Vector Type
2276 """""""""""
2277
2278 :Overview:
2279
2280 A vector type is a simple derived type that represents a vector of
2281 elements. Vector types are used when multiple primitive data are
2282 operated in parallel using a single instruction (SIMD). A vector type
2283 requires a size (number of elements) and an underlying primitive data
2284 type. Vector types are considered :ref:`first class <t_firstclass>`.
2285
2286 :Syntax:
2287
2288 ::
2289
2290       < <# elements> x <elementtype> >
2291
2292 The number of elements is a constant integer value larger than 0;
2293 elementtype may be any integer, floating point or pointer type. Vectors
2294 of size zero are not allowed.
2295
2296 :Examples:
2297
2298 +-------------------+--------------------------------------------------+
2299 | ``<4 x i32>``     | Vector of 4 32-bit integer values.               |
2300 +-------------------+--------------------------------------------------+
2301 | ``<8 x float>``   | Vector of 8 32-bit floating-point values.        |
2302 +-------------------+--------------------------------------------------+
2303 | ``<2 x i64>``     | Vector of 2 64-bit integer values.               |
2304 +-------------------+--------------------------------------------------+
2305 | ``<4 x i64*>``    | Vector of 4 pointers to 64-bit integer values.   |
2306 +-------------------+--------------------------------------------------+
2307
2308 .. _t_label:
2309
2310 Label Type
2311 ^^^^^^^^^^
2312
2313 :Overview:
2314
2315 The label type represents code labels.
2316
2317 :Syntax:
2318
2319 ::
2320
2321       label
2322
2323 .. _t_token:
2324
2325 Token Type
2326 ^^^^^^^^^^
2327
2328 :Overview:
2329
2330 The token type is used when a value is associated with an instruction
2331 but all uses of the value must not attempt to introspect or obscure it.
2332 As such, it is not appropriate to have a :ref:`phi <i_phi>` or
2333 :ref:`select <i_select>` of type token.
2334
2335 :Syntax:
2336
2337 ::
2338
2339       token
2340
2341
2342
2343 .. _t_metadata:
2344
2345 Metadata Type
2346 ^^^^^^^^^^^^^
2347
2348 :Overview:
2349
2350 The metadata type represents embedded metadata. No derived types may be
2351 created from metadata except for :ref:`function <t_function>` arguments.
2352
2353 :Syntax:
2354
2355 ::
2356
2357       metadata
2358
2359 .. _t_aggregate:
2360
2361 Aggregate Types
2362 ^^^^^^^^^^^^^^^
2363
2364 Aggregate Types are a subset of derived types that can contain multiple
2365 member types. :ref:`Arrays <t_array>` and :ref:`structs <t_struct>` are
2366 aggregate types. :ref:`Vectors <t_vector>` are not considered to be
2367 aggregate types.
2368
2369 .. _t_array:
2370
2371 Array Type
2372 """"""""""
2373
2374 :Overview:
2375
2376 The array type is a very simple derived type that arranges elements
2377 sequentially in memory. The array type requires a size (number of
2378 elements) and an underlying data type.
2379
2380 :Syntax:
2381
2382 ::
2383
2384       [<# elements> x <elementtype>]
2385
2386 The number of elements is a constant integer value; ``elementtype`` may
2387 be any type with a size.
2388
2389 :Examples:
2390
2391 +------------------+--------------------------------------+
2392 | ``[40 x i32]``   | Array of 40 32-bit integer values.   |
2393 +------------------+--------------------------------------+
2394 | ``[41 x i32]``   | Array of 41 32-bit integer values.   |
2395 +------------------+--------------------------------------+
2396 | ``[4 x i8]``     | Array of 4 8-bit integer values.     |
2397 +------------------+--------------------------------------+
2398
2399 Here are some examples of multidimensional arrays:
2400
2401 +-----------------------------+----------------------------------------------------------+
2402 | ``[3 x [4 x i32]]``         | 3x4 array of 32-bit integer values.                      |
2403 +-----------------------------+----------------------------------------------------------+
2404 | ``[12 x [10 x float]]``     | 12x10 array of single precision floating point values.   |
2405 +-----------------------------+----------------------------------------------------------+
2406 | ``[2 x [3 x [4 x i16]]]``   | 2x3x4 array of 16-bit integer values.                    |
2407 +-----------------------------+----------------------------------------------------------+
2408
2409 There is no restriction on indexing beyond the end of the array implied
2410 by a static type (though there are restrictions on indexing beyond the
2411 bounds of an allocated object in some cases). This means that
2412 single-dimension 'variable sized array' addressing can be implemented in
2413 LLVM with a zero length array type. An implementation of 'pascal style
2414 arrays' in LLVM could use the type "``{ i32, [0 x float]}``", for
2415 example.
2416
2417 .. _t_struct:
2418
2419 Structure Type
2420 """"""""""""""
2421
2422 :Overview:
2423
2424 The structure type is used to represent a collection of data members
2425 together in memory. The elements of a structure may be any type that has
2426 a size.
2427
2428 Structures in memory are accessed using '``load``' and '``store``' by
2429 getting a pointer to a field with the '``getelementptr``' instruction.
2430 Structures in registers are accessed using the '``extractvalue``' and
2431 '``insertvalue``' instructions.
2432
2433 Structures may optionally be "packed" structures, which indicate that
2434 the alignment of the struct is one byte, and that there is no padding
2435 between the elements. In non-packed structs, padding between field types
2436 is inserted as defined by the DataLayout string in the module, which is
2437 required to match what the underlying code generator expects.
2438
2439 Structures can either be "literal" or "identified". A literal structure
2440 is defined inline with other types (e.g. ``{i32, i32}*``) whereas
2441 identified types are always defined at the top level with a name.
2442 Literal types are uniqued by their contents and can never be recursive
2443 or opaque since there is no way to write one. Identified types can be
2444 recursive, can be opaqued, and are never uniqued.
2445
2446 :Syntax:
2447
2448 ::
2449
2450       %T1 = type { <type list> }     ; Identified normal struct type
2451       %T2 = type <{ <type list> }>   ; Identified packed struct type
2452
2453 :Examples:
2454
2455 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2456 | ``{ i32, i32, i32 }``        | A triple of three ``i32`` values                                                                                                                                                      |
2457 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2458 | ``{ float, i32 (i32) * }``   | A pair, where the first element is a ``float`` and the second element is a :ref:`pointer <t_pointer>` to a :ref:`function <t_function>` that takes an ``i32``, returning an ``i32``.  |
2459 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2460 | ``<{ i8, i32 }>``            | A packed struct known to be 5 bytes in size.                                                                                                                                          |
2461 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2462
2463 .. _t_opaque:
2464
2465 Opaque Structure Types
2466 """"""""""""""""""""""
2467
2468 :Overview:
2469
2470 Opaque structure types are used to represent named structure types that
2471 do not have a body specified. This corresponds (for example) to the C
2472 notion of a forward declared structure.
2473
2474 :Syntax:
2475
2476 ::
2477
2478       %X = type opaque
2479       %52 = type opaque
2480
2481 :Examples:
2482
2483 +--------------+-------------------+
2484 | ``opaque``   | An opaque type.   |
2485 +--------------+-------------------+
2486
2487 .. _constants:
2488
2489 Constants
2490 =========
2491
2492 LLVM has several different basic types of constants. This section
2493 describes them all and their syntax.
2494
2495 Simple Constants
2496 ----------------
2497
2498 **Boolean constants**
2499     The two strings '``true``' and '``false``' are both valid constants
2500     of the ``i1`` type.
2501 **Integer constants**
2502     Standard integers (such as '4') are constants of the
2503     :ref:`integer <t_integer>` type. Negative numbers may be used with
2504     integer types.
2505 **Floating point constants**
2506     Floating point constants use standard decimal notation (e.g.
2507     123.421), exponential notation (e.g. 1.23421e+2), or a more precise
2508     hexadecimal notation (see below). The assembler requires the exact
2509     decimal value of a floating-point constant. For example, the
2510     assembler accepts 1.25 but rejects 1.3 because 1.3 is a repeating
2511     decimal in binary. Floating point constants must have a :ref:`floating
2512     point <t_floating>` type.
2513 **Null pointer constants**
2514     The identifier '``null``' is recognized as a null pointer constant
2515     and must be of :ref:`pointer type <t_pointer>`.
2516 **Token constants**
2517     The identifier '``none``' is recognized as an empty token constant
2518     and must be of :ref:`token type <t_token>`.
2519
2520 The one non-intuitive notation for constants is the hexadecimal form of
2521 floating point constants. For example, the form
2522 '``double    0x432ff973cafa8000``' is equivalent to (but harder to read
2523 than) '``double 4.5e+15``'. The only time hexadecimal floating point
2524 constants are required (and the only time that they are generated by the
2525 disassembler) is when a floating point constant must be emitted but it
2526 cannot be represented as a decimal floating point number in a reasonable
2527 number of digits. For example, NaN's, infinities, and other special
2528 values are represented in their IEEE hexadecimal format so that assembly
2529 and disassembly do not cause any bits to change in the constants.
2530
2531 When using the hexadecimal form, constants of types half, float, and
2532 double are represented using the 16-digit form shown above (which
2533 matches the IEEE754 representation for double); half and float values
2534 must, however, be exactly representable as IEEE 754 half and single
2535 precision, respectively. Hexadecimal format is always used for long
2536 double, and there are three forms of long double. The 80-bit format used
2537 by x86 is represented as ``0xK`` followed by 20 hexadecimal digits. The
2538 128-bit format used by PowerPC (two adjacent doubles) is represented by
2539 ``0xM`` followed by 32 hexadecimal digits. The IEEE 128-bit format is
2540 represented by ``0xL`` followed by 32 hexadecimal digits. Long doubles
2541 will only work if they match the long double format on your target.
2542 The IEEE 16-bit format (half precision) is represented by ``0xH``
2543 followed by 4 hexadecimal digits. All hexadecimal formats are big-endian
2544 (sign bit at the left).
2545
2546 There are no constants of type x86_mmx.
2547
2548 .. _complexconstants:
2549
2550 Complex Constants
2551 -----------------
2552
2553 Complex constants are a (potentially recursive) combination of simple
2554 constants and smaller complex constants.
2555
2556 **Structure constants**
2557     Structure constants are represented with notation similar to
2558     structure type definitions (a comma separated list of elements,
2559     surrounded by braces (``{}``)). For example:
2560     "``{ i32 4, float 17.0, i32* @G }``", where "``@G``" is declared as
2561     "``@G = external global i32``". Structure constants must have
2562     :ref:`structure type <t_struct>`, and the number and types of elements
2563     must match those specified by the type.
2564 **Array constants**
2565     Array constants are represented with notation similar to array type
2566     definitions (a comma separated list of elements, surrounded by
2567     square brackets (``[]``)). For example:
2568     "``[ i32 42, i32 11, i32 74 ]``". Array constants must have
2569     :ref:`array type <t_array>`, and the number and types of elements must
2570     match those specified by the type. As a special case, character array
2571     constants may also be represented as a double-quoted string using the ``c``
2572     prefix. For example: "``c"Hello World\0A\00"``".
2573 **Vector constants**
2574     Vector constants are represented with notation similar to vector
2575     type definitions (a comma separated list of elements, surrounded by
2576     less-than/greater-than's (``<>``)). For example:
2577     "``< i32 42, i32 11, i32 74, i32 100 >``". Vector constants
2578     must have :ref:`vector type <t_vector>`, and the number and types of
2579     elements must match those specified by the type.
2580 **Zero initialization**
2581     The string '``zeroinitializer``' can be used to zero initialize a
2582     value to zero of *any* type, including scalar and
2583     :ref:`aggregate <t_aggregate>` types. This is often used to avoid
2584     having to print large zero initializers (e.g. for large arrays) and
2585     is always exactly equivalent to using explicit zero initializers.
2586 **Metadata node**
2587     A metadata node is a constant tuple without types. For example:
2588     "``!{!0, !{!2, !0}, !"test"}``". Metadata can reference constant values,
2589     for example: "``!{!0, i32 0, i8* @global, i64 (i64)* @function, !"str"}``".
2590     Unlike other typed constants that are meant to be interpreted as part of
2591     the instruction stream, metadata is a place to attach additional
2592     information such as debug info.
2593
2594 Global Variable and Function Addresses
2595 --------------------------------------
2596
2597 The addresses of :ref:`global variables <globalvars>` and
2598 :ref:`functions <functionstructure>` are always implicitly valid
2599 (link-time) constants. These constants are explicitly referenced when
2600 the :ref:`identifier for the global <identifiers>` is used and always have
2601 :ref:`pointer <t_pointer>` type. For example, the following is a legal LLVM
2602 file:
2603
2604 .. code-block:: llvm
2605
2606     @X = global i32 17
2607     @Y = global i32 42
2608     @Z = global [2 x i32*] [ i32* @X, i32* @Y ]
2609
2610 .. _undefvalues:
2611
2612 Undefined Values
2613 ----------------
2614
2615 The string '``undef``' can be used anywhere a constant is expected, and
2616 indicates that the user of the value may receive an unspecified
2617 bit-pattern. Undefined values may be of any type (other than '``label``'
2618 or '``void``') and be used anywhere a constant is permitted.
2619
2620 Undefined values are useful because they indicate to the compiler that
2621 the program is well defined no matter what value is used. This gives the
2622 compiler more freedom to optimize. Here are some examples of
2623 (potentially surprising) transformations that are valid (in pseudo IR):
2624
2625 .. code-block:: llvm
2626
2627       %A = add %X, undef
2628       %B = sub %X, undef
2629       %C = xor %X, undef
2630     Safe:
2631       %A = undef
2632       %B = undef
2633       %C = undef
2634
2635 This is safe because all of the output bits are affected by the undef
2636 bits. Any output bit can have a zero or one depending on the input bits.
2637
2638 .. code-block:: llvm
2639
2640       %A = or %X, undef
2641       %B = and %X, undef
2642     Safe:
2643       %A = -1
2644       %B = 0
2645     Unsafe:
2646       %A = undef
2647       %B = undef
2648
2649 These logical operations have bits that are not always affected by the
2650 input. For example, if ``%X`` has a zero bit, then the output of the
2651 '``and``' operation will always be a zero for that bit, no matter what
2652 the corresponding bit from the '``undef``' is. As such, it is unsafe to
2653 optimize or assume that the result of the '``and``' is '``undef``'.
2654 However, it is safe to assume that all bits of the '``undef``' could be
2655 0, and optimize the '``and``' to 0. Likewise, it is safe to assume that
2656 all the bits of the '``undef``' operand to the '``or``' could be set,
2657 allowing the '``or``' to be folded to -1.
2658
2659 .. code-block:: llvm
2660
2661       %A = select undef, %X, %Y
2662       %B = select undef, 42, %Y
2663       %C = select %X, %Y, undef
2664     Safe:
2665       %A = %X     (or %Y)
2666       %B = 42     (or %Y)
2667       %C = %Y
2668     Unsafe:
2669       %A = undef
2670       %B = undef
2671       %C = undef
2672
2673 This set of examples shows that undefined '``select``' (and conditional
2674 branch) conditions can go *either way*, but they have to come from one
2675 of the two operands. In the ``%A`` example, if ``%X`` and ``%Y`` were
2676 both known to have a clear low bit, then ``%A`` would have to have a
2677 cleared low bit. However, in the ``%C`` example, the optimizer is
2678 allowed to assume that the '``undef``' operand could be the same as
2679 ``%Y``, allowing the whole '``select``' to be eliminated.
2680
2681 .. code-block:: llvm
2682
2683       %A = xor undef, undef
2684
2685       %B = undef
2686       %C = xor %B, %B
2687
2688       %D = undef
2689       %E = icmp slt %D, 4
2690       %F = icmp gte %D, 4
2691
2692     Safe:
2693       %A = undef
2694       %B = undef
2695       %C = undef
2696       %D = undef
2697       %E = undef
2698       %F = undef
2699
2700 This example points out that two '``undef``' operands are not
2701 necessarily the same. This can be surprising to people (and also matches
2702 C semantics) where they assume that "``X^X``" is always zero, even if
2703 ``X`` is undefined. This isn't true for a number of reasons, but the
2704 short answer is that an '``undef``' "variable" can arbitrarily change
2705 its value over its "live range". This is true because the variable
2706 doesn't actually *have a live range*. Instead, the value is logically
2707 read from arbitrary registers that happen to be around when needed, so
2708 the value is not necessarily consistent over time. In fact, ``%A`` and
2709 ``%C`` need to have the same semantics or the core LLVM "replace all
2710 uses with" concept would not hold.
2711
2712 .. code-block:: llvm
2713
2714       %A = fdiv undef, %X
2715       %B = fdiv %X, undef
2716     Safe:
2717       %A = undef
2718     b: unreachable
2719
2720 These examples show the crucial difference between an *undefined value*
2721 and *undefined behavior*. An undefined value (like '``undef``') is
2722 allowed to have an arbitrary bit-pattern. This means that the ``%A``
2723 operation can be constant folded to '``undef``', because the '``undef``'
2724 could be an SNaN, and ``fdiv`` is not (currently) defined on SNaN's.
2725 However, in the second example, we can make a more aggressive
2726 assumption: because the ``undef`` is allowed to be an arbitrary value,
2727 we are allowed to assume that it could be zero. Since a divide by zero
2728 has *undefined behavior*, we are allowed to assume that the operation
2729 does not execute at all. This allows us to delete the divide and all
2730 code after it. Because the undefined operation "can't happen", the
2731 optimizer can assume that it occurs in dead code.
2732
2733 .. code-block:: llvm
2734
2735     a:  store undef -> %X
2736     b:  store %X -> undef
2737     Safe:
2738     a: <deleted>
2739     b: unreachable
2740
2741 These examples reiterate the ``fdiv`` example: a store *of* an undefined
2742 value can be assumed to not have any effect; we can assume that the
2743 value is overwritten with bits that happen to match what was already
2744 there. However, a store *to* an undefined location could clobber
2745 arbitrary memory, therefore, it has undefined behavior.
2746
2747 .. _poisonvalues:
2748
2749 Poison Values
2750 -------------
2751
2752 Poison values are similar to :ref:`undef values <undefvalues>`, however
2753 they also represent the fact that an instruction or constant expression
2754 that cannot evoke side effects has nevertheless detected a condition
2755 that results in undefined behavior.
2756
2757 There is currently no way of representing a poison value in the IR; they
2758 only exist when produced by operations such as :ref:`add <i_add>` with
2759 the ``nsw`` flag.
2760
2761 Poison value behavior is defined in terms of value *dependence*:
2762
2763 -  Values other than :ref:`phi <i_phi>` nodes depend on their operands.
2764 -  :ref:`Phi <i_phi>` nodes depend on the operand corresponding to
2765    their dynamic predecessor basic block.
2766 -  Function arguments depend on the corresponding actual argument values
2767    in the dynamic callers of their functions.
2768 -  :ref:`Call <i_call>` instructions depend on the :ref:`ret <i_ret>`
2769    instructions that dynamically transfer control back to them.
2770 -  :ref:`Invoke <i_invoke>` instructions depend on the
2771    :ref:`ret <i_ret>`, :ref:`resume <i_resume>`, or exception-throwing
2772    call instructions that dynamically transfer control back to them.
2773 -  Non-volatile loads and stores depend on the most recent stores to all
2774    of the referenced memory addresses, following the order in the IR
2775    (including loads and stores implied by intrinsics such as
2776    :ref:`@llvm.memcpy <int_memcpy>`.)
2777 -  An instruction with externally visible side effects depends on the
2778    most recent preceding instruction with externally visible side
2779    effects, following the order in the IR. (This includes :ref:`volatile
2780    operations <volatile>`.)
2781 -  An instruction *control-depends* on a :ref:`terminator
2782    instruction <terminators>` if the terminator instruction has
2783    multiple successors and the instruction is always executed when
2784    control transfers to one of the successors, and may not be executed
2785    when control is transferred to another.
2786 -  Additionally, an instruction also *control-depends* on a terminator
2787    instruction if the set of instructions it otherwise depends on would
2788    be different if the terminator had transferred control to a different
2789    successor.
2790 -  Dependence is transitive.
2791
2792 Poison values have the same behavior as :ref:`undef values <undefvalues>`,
2793 with the additional effect that any instruction that has a *dependence*
2794 on a poison value has undefined behavior.
2795
2796 Here are some examples:
2797
2798 .. code-block:: llvm
2799
2800     entry:
2801       %poison = sub nuw i32 0, 1           ; Results in a poison value.
2802       %still_poison = and i32 %poison, 0   ; 0, but also poison.
2803       %poison_yet_again = getelementptr i32, i32* @h, i32 %still_poison
2804       store i32 0, i32* %poison_yet_again  ; memory at @h[0] is poisoned
2805
2806       store i32 %poison, i32* @g           ; Poison value stored to memory.
2807       %poison2 = load i32, i32* @g         ; Poison value loaded back from memory.
2808
2809       store volatile i32 %poison, i32* @g  ; External observation; undefined behavior.
2810
2811       %narrowaddr = bitcast i32* @g to i16*
2812       %wideaddr = bitcast i32* @g to i64*
2813       %poison3 = load i16, i16* %narrowaddr ; Returns a poison value.
2814       %poison4 = load i64, i64* %wideaddr  ; Returns a poison value.
2815
2816       %cmp = icmp slt i32 %poison, 0       ; Returns a poison value.
2817       br i1 %cmp, label %true, label %end  ; Branch to either destination.
2818
2819     true:
2820       store volatile i32 0, i32* @g        ; This is control-dependent on %cmp, so
2821                                            ; it has undefined behavior.
2822       br label %end
2823
2824     end:
2825       %p = phi i32 [ 0, %entry ], [ 1, %true ]
2826                                            ; Both edges into this PHI are
2827                                            ; control-dependent on %cmp, so this
2828                                            ; always results in a poison value.
2829
2830       store volatile i32 0, i32* @g        ; This would depend on the store in %true
2831                                            ; if %cmp is true, or the store in %entry
2832                                            ; otherwise, so this is undefined behavior.
2833
2834       br i1 %cmp, label %second_true, label %second_end
2835                                            ; The same branch again, but this time the
2836                                            ; true block doesn't have side effects.
2837
2838     second_true:
2839       ; No side effects!
2840       ret void
2841
2842     second_end:
2843       store volatile i32 0, i32* @g        ; This time, the instruction always depends
2844                                            ; on the store in %end. Also, it is
2845                                            ; control-equivalent to %end, so this is
2846                                            ; well-defined (ignoring earlier undefined
2847                                            ; behavior in this example).
2848
2849 .. _blockaddress:
2850
2851 Addresses of Basic Blocks
2852 -------------------------
2853
2854 ``blockaddress(@function, %block)``
2855
2856 The '``blockaddress``' constant computes the address of the specified
2857 basic block in the specified function, and always has an ``i8*`` type.
2858 Taking the address of the entry block is illegal.
2859
2860 This value only has defined behavior when used as an operand to the
2861 ':ref:`indirectbr <i_indirectbr>`' instruction, or for comparisons
2862 against null. Pointer equality tests between labels addresses results in
2863 undefined behavior --- though, again, comparison against null is ok, and
2864 no label is equal to the null pointer. This may be passed around as an
2865 opaque pointer sized value as long as the bits are not inspected. This
2866 allows ``ptrtoint`` and arithmetic to be performed on these values so
2867 long as the original value is reconstituted before the ``indirectbr``
2868 instruction.
2869
2870 Finally, some targets may provide defined semantics when using the value
2871 as the operand to an inline assembly, but that is target specific.
2872
2873 .. _constantexprs:
2874
2875 Constant Expressions
2876 --------------------
2877
2878 Constant expressions are used to allow expressions involving other
2879 constants to be used as constants. Constant expressions may be of any
2880 :ref:`first class <t_firstclass>` type and may involve any LLVM operation
2881 that does not have side effects (e.g. load and call are not supported).
2882 The following is the syntax for constant expressions:
2883
2884 ``trunc (CST to TYPE)``
2885     Truncate a constant to another type. The bit size of CST must be
2886     larger than the bit size of TYPE. Both types must be integers.
2887 ``zext (CST to TYPE)``
2888     Zero extend a constant to another type. The bit size of CST must be
2889     smaller than the bit size of TYPE. Both types must be integers.
2890 ``sext (CST to TYPE)``
2891     Sign extend a constant to another type. The bit size of CST must be
2892     smaller than the bit size of TYPE. Both types must be integers.
2893 ``fptrunc (CST to TYPE)``
2894     Truncate a floating point constant to another floating point type.
2895     The size of CST must be larger than the size of TYPE. Both types
2896     must be floating point.
2897 ``fpext (CST to TYPE)``
2898     Floating point extend a constant to another type. The size of CST
2899     must be smaller or equal to the size of TYPE. Both types must be
2900     floating point.
2901 ``fptoui (CST to TYPE)``
2902     Convert a floating point constant to the corresponding unsigned
2903     integer constant. TYPE must be a scalar or vector integer type. CST
2904     must be of scalar or vector floating point type. Both CST and TYPE
2905     must be scalars, or vectors of the same number of elements. If the
2906     value won't fit in the integer type, the results are undefined.
2907 ``fptosi (CST to TYPE)``
2908     Convert a floating point constant to the corresponding signed
2909     integer constant. TYPE must be a scalar or vector integer type. CST
2910     must be of scalar or vector floating point type. Both CST and TYPE
2911     must be scalars, or vectors of the same number of elements. If the
2912     value won't fit in the integer type, the results are undefined.
2913 ``uitofp (CST to TYPE)``
2914     Convert an unsigned integer constant to the corresponding floating
2915     point constant. TYPE must be a scalar or vector floating point type.
2916     CST must be of scalar or vector integer type. Both CST and TYPE must
2917     be scalars, or vectors of the same number of elements. If the value
2918     won't fit in the floating point type, the results are undefined.
2919 ``sitofp (CST to TYPE)``
2920     Convert a signed integer constant to the corresponding floating
2921     point constant. TYPE must be a scalar or vector floating point type.
2922     CST must be of scalar or vector integer type. Both CST and TYPE must
2923     be scalars, or vectors of the same number of elements. If the value
2924     won't fit in the floating point type, the results are undefined.
2925 ``ptrtoint (CST to TYPE)``
2926     Convert a pointer typed constant to the corresponding integer
2927     constant. ``TYPE`` must be an integer type. ``CST`` must be of
2928     pointer type. The ``CST`` value is zero extended, truncated, or
2929     unchanged to make it fit in ``TYPE``.
2930 ``inttoptr (CST to TYPE)``
2931     Convert an integer constant to a pointer constant. TYPE must be a
2932     pointer type. CST must be of integer type. The CST value is zero
2933     extended, truncated, or unchanged to make it fit in a pointer size.
2934     This one is *really* dangerous!
2935 ``bitcast (CST to TYPE)``
2936     Convert a constant, CST, to another TYPE. The constraints of the
2937     operands are the same as those for the :ref:`bitcast
2938     instruction <i_bitcast>`.
2939 ``addrspacecast (CST to TYPE)``
2940     Convert a constant pointer or constant vector of pointer, CST, to another
2941     TYPE in a different address space. The constraints of the operands are the
2942     same as those for the :ref:`addrspacecast instruction <i_addrspacecast>`.
2943 ``getelementptr (TY, CSTPTR, IDX0, IDX1, ...)``, ``getelementptr inbounds (TY, CSTPTR, IDX0, IDX1, ...)``
2944     Perform the :ref:`getelementptr operation <i_getelementptr>` on
2945     constants. As with the :ref:`getelementptr <i_getelementptr>`
2946     instruction, the index list may have zero or more indexes, which are
2947     required to make sense for the type of "pointer to TY".
2948 ``select (COND, VAL1, VAL2)``
2949     Perform the :ref:`select operation <i_select>` on constants.
2950 ``icmp COND (VAL1, VAL2)``
2951     Performs the :ref:`icmp operation <i_icmp>` on constants.
2952 ``fcmp COND (VAL1, VAL2)``
2953     Performs the :ref:`fcmp operation <i_fcmp>` on constants.
2954 ``extractelement (VAL, IDX)``
2955     Perform the :ref:`extractelement operation <i_extractelement>` on
2956     constants.
2957 ``insertelement (VAL, ELT, IDX)``
2958     Perform the :ref:`insertelement operation <i_insertelement>` on
2959     constants.
2960 ``shufflevector (VEC1, VEC2, IDXMASK)``
2961     Perform the :ref:`shufflevector operation <i_shufflevector>` on
2962     constants.
2963 ``extractvalue (VAL, IDX0, IDX1, ...)``
2964     Perform the :ref:`extractvalue operation <i_extractvalue>` on
2965     constants. The index list is interpreted in a similar manner as
2966     indices in a ':ref:`getelementptr <i_getelementptr>`' operation. At
2967     least one index value must be specified.
2968 ``insertvalue (VAL, ELT, IDX0, IDX1, ...)``
2969     Perform the :ref:`insertvalue operation <i_insertvalue>` on constants.
2970     The index list is interpreted in a similar manner as indices in a
2971     ':ref:`getelementptr <i_getelementptr>`' operation. At least one index
2972     value must be specified.
2973 ``OPCODE (LHS, RHS)``
2974     Perform the specified operation of the LHS and RHS constants. OPCODE
2975     may be any of the :ref:`binary <binaryops>` or :ref:`bitwise
2976     binary <bitwiseops>` operations. The constraints on operands are
2977     the same as those for the corresponding instruction (e.g. no bitwise
2978     operations on floating point values are allowed).
2979
2980 Other Values
2981 ============
2982
2983 .. _inlineasmexprs:
2984
2985 Inline Assembler Expressions
2986 ----------------------------
2987
2988 LLVM supports inline assembler expressions (as opposed to :ref:`Module-Level
2989 Inline Assembly <moduleasm>`) through the use of a special value. This value
2990 represents the inline assembler as a template string (containing the
2991 instructions to emit), a list of operand constraints (stored as a string), a
2992 flag that indicates whether or not the inline asm expression has side effects,
2993 and a flag indicating whether the function containing the asm needs to align its
2994 stack conservatively.
2995
2996 The template string supports argument substitution of the operands using "``$``"
2997 followed by a number, to indicate substitution of the given register/memory
2998 location, as specified by the constraint string. "``${NUM:MODIFIER}``" may also
2999 be used, where ``MODIFIER`` is a target-specific annotation for how to print the
3000 operand (See :ref:`inline-asm-modifiers`).
3001
3002 A literal "``$``" may be included by using "``$$``" in the template. To include
3003 other special characters into the output, the usual "``\XX``" escapes may be
3004 used, just as in other strings. Note that after template substitution, the
3005 resulting assembly string is parsed by LLVM's integrated assembler unless it is
3006 disabled -- even when emitting a ``.s`` file -- and thus must contain assembly
3007 syntax known to LLVM.
3008
3009 LLVM's support for inline asm is modeled closely on the requirements of Clang's
3010 GCC-compatible inline-asm support. Thus, the feature-set and the constraint and
3011 modifier codes listed here are similar or identical to those in GCC's inline asm
3012 support. However, to be clear, the syntax of the template and constraint strings
3013 described here is *not* the same as the syntax accepted by GCC and Clang, and,
3014 while most constraint letters are passed through as-is by Clang, some get
3015 translated to other codes when converting from the C source to the LLVM
3016 assembly.
3017
3018 An example inline assembler expression is:
3019
3020 .. code-block:: llvm
3021
3022     i32 (i32) asm "bswap $0", "=r,r"
3023
3024 Inline assembler expressions may **only** be used as the callee operand
3025 of a :ref:`call <i_call>` or an :ref:`invoke <i_invoke>` instruction.
3026 Thus, typically we have:
3027
3028 .. code-block:: llvm
3029
3030     %X = call i32 asm "bswap $0", "=r,r"(i32 %Y)
3031
3032 Inline asms with side effects not visible in the constraint list must be
3033 marked as having side effects. This is done through the use of the
3034 '``sideeffect``' keyword, like so:
3035
3036 .. code-block:: llvm
3037
3038     call void asm sideeffect "eieio", ""()
3039
3040 In some cases inline asms will contain code that will not work unless
3041 the stack is aligned in some way, such as calls or SSE instructions on
3042 x86, yet will not contain code that does that alignment within the asm.
3043 The compiler should make conservative assumptions about what the asm
3044 might contain and should generate its usual stack alignment code in the
3045 prologue if the '``alignstack``' keyword is present:
3046
3047 .. code-block:: llvm
3048
3049     call void asm alignstack "eieio", ""()
3050
3051 Inline asms also support using non-standard assembly dialects. The
3052 assumed dialect is ATT. When the '``inteldialect``' keyword is present,
3053 the inline asm is using the Intel dialect. Currently, ATT and Intel are
3054 the only supported dialects. An example is:
3055
3056 .. code-block:: llvm
3057
3058     call void asm inteldialect "eieio", ""()
3059
3060 If multiple keywords appear the '``sideeffect``' keyword must come
3061 first, the '``alignstack``' keyword second and the '``inteldialect``'
3062 keyword last.
3063
3064 Inline Asm Constraint String
3065 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
3066
3067 The constraint list is a comma-separated string, each element containing one or
3068 more constraint codes.
3069
3070 For each element in the constraint list an appropriate register or memory
3071 operand will be chosen, and it will be made available to assembly template
3072 string expansion as ``$0`` for the first constraint in the list, ``$1`` for the
3073 second, etc.
3074
3075 There are three different types of constraints, which are distinguished by a
3076 prefix symbol in front of the constraint code: Output, Input, and Clobber. The
3077 constraints must always be given in that order: outputs first, then inputs, then
3078 clobbers. They cannot be intermingled.
3079
3080 There are also three different categories of constraint codes:
3081
3082 - Register constraint. This is either a register class, or a fixed physical
3083   register. This kind of constraint will allocate a register, and if necessary,
3084   bitcast the argument or result to the appropriate type.
3085 - Memory constraint. This kind of constraint is for use with an instruction
3086   taking a memory operand. Different constraints allow for different addressing
3087   modes used by the target.
3088 - Immediate value constraint. This kind of constraint is for an integer or other
3089   immediate value which can be rendered directly into an instruction. The
3090   various target-specific constraints allow the selection of a value in the
3091   proper range for the instruction you wish to use it with.
3092
3093 Output constraints
3094 """"""""""""""""""
3095
3096 Output constraints are specified by an "``=``" prefix (e.g. "``=r``"). This
3097 indicates that the assembly will write to this operand, and the operand will
3098 then be made available as a return value of the ``asm`` expression. Output
3099 constraints do not consume an argument from the call instruction. (Except, see
3100 below about indirect outputs).
3101
3102 Normally, it is expected that no output locations are written to by the assembly
3103 expression until *all* of the inputs have been read. As such, LLVM may assign
3104 the same register to an output and an input. If this is not safe (e.g. if the
3105 assembly contains two instructions, where the first writes to one output, and
3106 the second reads an input and writes to a second output), then the "``&``"
3107 modifier must be used (e.g. "``=&r``") to specify that the output is an
3108 "early-clobber" output. Marking an ouput as "early-clobber" ensures that LLVM
3109 will not use the same register for any inputs (other than an input tied to this
3110 output).
3111
3112 Input constraints
3113 """""""""""""""""
3114
3115 Input constraints do not have a prefix -- just the constraint codes. Each input
3116 constraint will consume one argument from the call instruction. It is not
3117 permitted for the asm to write to any input register or memory location (unless
3118 that input is tied to an output). Note also that multiple inputs may all be
3119 assigned to the same register, if LLVM can determine that they necessarily all
3120 contain the same value.
3121
3122 Instead of providing a Constraint Code, input constraints may also "tie"
3123 themselves to an output constraint, by providing an integer as the constraint
3124 string. Tied inputs still consume an argument from the call instruction, and
3125 take up a position in the asm template numbering as is usual -- they will simply
3126 be constrained to always use the same register as the output they've been tied
3127 to. For example, a constraint string of "``=r,0``" says to assign a register for
3128 output, and use that register as an input as well (it being the 0'th
3129 constraint).
3130
3131 It is permitted to tie an input to an "early-clobber" output. In that case, no
3132 *other* input may share the same register as the input tied to the early-clobber
3133 (even when the other input has the same value).
3134
3135 You may only tie an input to an output which has a register constraint, not a
3136 memory constraint. Only a single input may be tied to an output.
3137
3138 There is also an "interesting" feature which deserves a bit of explanation: if a
3139 register class constraint allocates a register which is too small for the value
3140 type operand provided as input, the input value will be split into multiple
3141 registers, and all of them passed to the inline asm.
3142
3143 However, this feature is often not as useful as you might think.
3144
3145 Firstly, the registers are *not* guaranteed to be consecutive. So, on those
3146 architectures that have instructions which operate on multiple consecutive
3147 instructions, this is not an appropriate way to support them. (e.g. the 32-bit
3148 SparcV8 has a 64-bit load, which instruction takes a single 32-bit register. The
3149 hardware then loads into both the named register, and the next register. This
3150 feature of inline asm would not be useful to support that.)
3151
3152 A few of the targets provide a template string modifier allowing explicit access
3153 to the second register of a two-register operand (e.g. MIPS ``L``, ``M``, and
3154 ``D``). On such an architecture, you can actually access the second allocated
3155 register (yet, still, not any subsequent ones). But, in that case, you're still
3156 probably better off simply splitting the value into two separate operands, for
3157 clarity. (e.g. see the description of the ``A`` constraint on X86, which,
3158 despite existing only for use with this feature, is not really a good idea to
3159 use)
3160
3161 Indirect inputs and outputs
3162 """""""""""""""""""""""""""
3163
3164 Indirect output or input constraints can be specified by the "``*``" modifier
3165 (which goes after the "``=``" in case of an output). This indicates that the asm
3166 will write to or read from the contents of an *address* provided as an input
3167 argument. (Note that in this way, indirect outputs act more like an *input* than
3168 an output: just like an input, they consume an argument of the call expression,
3169 rather than producing a return value. An indirect output constraint is an
3170 "output" only in that the asm is expected to write to the contents of the input
3171 memory location, instead of just read from it).
3172
3173 This is most typically used for memory constraint, e.g. "``=*m``", to pass the
3174 address of a variable as a value.
3175
3176 It is also possible to use an indirect *register* constraint, but only on output
3177 (e.g. "``=*r``"). This will cause LLVM to allocate a register for an output
3178 value normally, and then, separately emit a store to the address provided as
3179 input, after the provided inline asm. (It's not clear what value this
3180 functionality provides, compared to writing the store explicitly after the asm
3181 statement, and it can only produce worse code, since it bypasses many
3182 optimization passes. I would recommend not using it.)
3183
3184
3185 Clobber constraints
3186 """""""""""""""""""
3187
3188 A clobber constraint is indicated by a "``~``" prefix. A clobber does not
3189 consume an input operand, nor generate an output. Clobbers cannot use any of the
3190 general constraint code letters -- they may use only explicit register
3191 constraints, e.g. "``~{eax}``". The one exception is that a clobber string of
3192 "``~{memory}``" indicates that the assembly writes to arbitrary undeclared
3193 memory locations -- not only the memory pointed to by a declared indirect
3194 output.
3195
3196
3197 Constraint Codes
3198 """"""""""""""""
3199 After a potential prefix comes constraint code, or codes.
3200
3201 A Constraint Code is either a single letter (e.g. "``r``"), a "``^``" character
3202 followed by two letters (e.g. "``^wc``"), or "``{``" register-name "``}``"
3203 (e.g. "``{eax}``").
3204
3205 The one and two letter constraint codes are typically chosen to be the same as
3206 GCC's constraint codes.
3207
3208 A single constraint may include one or more than constraint code in it, leaving
3209 it up to LLVM to choose which one to use. This is included mainly for
3210 compatibility with the translation of GCC inline asm coming from clang.
3211
3212 There are two ways to specify alternatives, and either or both may be used in an
3213 inline asm constraint list:
3214
3215 1) Append the codes to each other, making a constraint code set. E.g. "``im``"
3216    or "``{eax}m``". This means "choose any of the options in the set". The
3217    choice of constraint is made independently for each constraint in the
3218    constraint list.
3219
3220 2) Use "``|``" between constraint code sets, creating alternatives. Every
3221    constraint in the constraint list must have the same number of alternative
3222    sets. With this syntax, the same alternative in *all* of the items in the
3223    constraint list will be chosen together.
3224
3225 Putting those together, you might have a two operand constraint string like
3226 ``"rm|r,ri|rm"``. This indicates that if operand 0 is ``r`` or ``m``, then
3227 operand 1 may be one of ``r`` or ``i``. If operand 0 is ``r``, then operand 1
3228 may be one of ``r`` or ``m``. But, operand 0 and 1 cannot both be of type m.
3229
3230 However, the use of either of the alternatives features is *NOT* recommended, as
3231 LLVM is not able to make an intelligent choice about which one to use. (At the
3232 point it currently needs to choose, not enough information is available to do so
3233 in a smart way.) Thus, it simply tries to make a choice that's most likely to
3234 compile, not one that will be optimal performance. (e.g., given "``rm``", it'll
3235 always choose to use memory, not registers). And, if given multiple registers,
3236 or multiple register classes, it will simply choose the first one. (In fact, it
3237 doesn't currently even ensure explicitly specified physical registers are
3238 unique, so specifying multiple physical registers as alternatives, like
3239 ``{r11}{r12},{r11}{r12}``, will assign r11 to both operands, not at all what was
3240 intended.)
3241
3242 Supported Constraint Code List
3243 """"""""""""""""""""""""""""""
3244
3245 The constraint codes are, in general, expected to behave the same way they do in
3246 GCC. LLVM's support is often implemented on an 'as-needed' basis, to support C
3247 inline asm code which was supported by GCC. A mismatch in behavior between LLVM
3248 and GCC likely indicates a bug in LLVM.
3249
3250 Some constraint codes are typically supported by all targets:
3251
3252 - ``r``: A register in the target's general purpose register class.
3253 - ``m``: A memory address operand. It is target-specific what addressing modes
3254   are supported, typical examples are register, or register + register offset,
3255   or register + immediate offset (of some target-specific size).
3256 - ``i``: An integer constant (of target-specific width). Allows either a simple
3257   immediate, or a relocatable value.
3258 - ``n``: An integer constant -- *not* including relocatable values.
3259 - ``s``: An integer constant, but allowing *only* relocatable values.
3260 - ``X``: Allows an operand of any kind, no constraint whatsoever. Typically
3261   useful to pass a label for an asm branch or call.
3262
3263   .. FIXME: but that surely isn't actually okay to jump out of an asm
3264      block without telling llvm about the control transfer???)
3265
3266 - ``{register-name}``: Requires exactly the named physical register.
3267
3268 Other constraints are target-specific:
3269
3270 AArch64:
3271
3272 - ``z``: An immediate integer 0. Outputs ``WZR`` or ``XZR``, as appropriate.
3273 - ``I``: An immediate integer valid for an ``ADD`` or ``SUB`` instruction,
3274   i.e. 0 to 4095 with optional shift by 12.
3275 - ``J``: An immediate integer that, when negated, is valid for an ``ADD`` or
3276   ``SUB`` instruction, i.e. -1 to -4095 with optional left shift by 12.
3277 - ``K``: An immediate integer that is valid for the 'bitmask immediate 32' of a
3278   logical instruction like ``AND``, ``EOR``, or ``ORR`` with a 32-bit register.
3279 - ``L``: An immediate integer that is valid for the 'bitmask immediate 64' of a
3280   logical instruction like ``AND``, ``EOR``, or ``ORR`` with a 64-bit register.
3281 - ``M``: An immediate integer for use with the ``MOV`` assembly alias on a
3282   32-bit register. This is a superset of ``K``: in addition to the bitmask
3283   immediate, also allows immediate integers which can be loaded with a single
3284   ``MOVZ`` or ``MOVL`` instruction.
3285 - ``N``: An immediate integer for use with the ``MOV`` assembly alias on a
3286   64-bit register. This is a superset of ``L``.
3287 - ``Q``: Memory address operand must be in a single register (no
3288   offsets). (However, LLVM currently does this for the ``m`` constraint as
3289   well.)
3290 - ``r``: A 32 or 64-bit integer register (W* or X*).
3291 - ``w``: A 32, 64, or 128-bit floating-point/SIMD register.
3292 - ``x``: A lower 128-bit floating-point/SIMD register (``V0`` to ``V15``).
3293
3294 AMDGPU:
3295
3296 - ``r``: A 32 or 64-bit integer register.
3297 - ``[0-9]v``: The 32-bit VGPR register, number 0-9.
3298 - ``[0-9]s``: The 32-bit SGPR register, number 0-9.
3299
3300
3301 All ARM modes:
3302
3303 - ``Q``, ``Um``, ``Un``, ``Uq``, ``Us``, ``Ut``, ``Uv``, ``Uy``: Memory address
3304   operand. Treated the same as operand ``m``, at the moment.
3305
3306 ARM and ARM's Thumb2 mode:
3307
3308 - ``j``: An immediate integer between 0 and 65535 (valid for ``MOVW``)
3309 - ``I``: An immediate integer valid for a data-processing instruction.
3310 - ``J``: An immediate integer between -4095 and 4095.
3311 - ``K``: An immediate integer whose bitwise inverse is valid for a
3312   data-processing instruction. (Can be used with template modifier "``B``" to
3313   print the inverted value).
3314 - ``L``: An immediate integer whose negation is valid for a data-processing
3315   instruction. (Can be used with template modifier "``n``" to print the negated
3316   value).
3317 - ``M``: A power of two or a integer between 0 and 32.
3318 - ``N``: Invalid immediate constraint.
3319 - ``O``: Invalid immediate constraint.
3320 - ``r``: A general-purpose 32-bit integer register (``r0-r15``).
3321 - ``l``: In Thumb2 mode, low 32-bit GPR registers (``r0-r7``). In ARM mode, same
3322   as ``r``.
3323 - ``h``: In Thumb2 mode, a high 32-bit GPR register (``r8-r15``). In ARM mode,
3324   invalid.
3325 - ``w``: A 32, 64, or 128-bit floating-point/SIMD register: ``s0-s31``,
3326   ``d0-d31``, or ``q0-q15``.
3327 - ``x``: A 32, 64, or 128-bit floating-point/SIMD register: ``s0-s15``,
3328   ``d0-d7``, or ``q0-q3``.
3329 - ``t``: A floating-point/SIMD register, only supports 32-bit values:
3330   ``s0-s31``.
3331
3332 ARM's Thumb1 mode:
3333
3334 - ``I``: An immediate integer between 0 and 255.
3335 - ``J``: An immediate integer between -255 and -1.
3336 - ``K``: An immediate integer between 0 and 255, with optional left-shift by
3337   some amount.
3338 - ``L``: An immediate integer between -7 and 7.
3339 - ``M``: An immediate integer which is a multiple of 4 between 0 and 1020.
3340 - ``N``: An immediate integer between 0 and 31.
3341 - ``O``: An immediate integer which is a multiple of 4 between -508 and 508.
3342 - ``r``: A low 32-bit GPR register (``r0-r7``).
3343 - ``l``: A low 32-bit GPR register (``r0-r7``).
3344 - ``h``: A high GPR register (``r0-r7``).
3345 - ``w``: A 32, 64, or 128-bit floating-point/SIMD register: ``s0-s31``,
3346   ``d0-d31``, or ``q0-q15``.
3347 - ``x``: A 32, 64, or 128-bit floating-point/SIMD register: ``s0-s15``,
3348   ``d0-d7``, or ``q0-q3``.
3349 - ``t``: A floating-point/SIMD register, only supports 32-bit values:
3350   ``s0-s31``.
3351
3352
3353 Hexagon:
3354
3355 - ``o``, ``v``: A memory address operand, treated the same as constraint ``m``,
3356   at the moment.
3357 - ``r``: A 32 or 64-bit register.
3358
3359 MSP430:
3360
3361 - ``r``: An 8 or 16-bit register.
3362
3363 MIPS:
3364
3365 - ``I``: An immediate signed 16-bit integer.
3366 - ``J``: An immediate integer zero.
3367 - ``K``: An immediate unsigned 16-bit integer.
3368 - ``L``: An immediate 32-bit integer, where the lower 16 bits are 0.
3369 - ``N``: An immediate integer between -65535 and -1.
3370 - ``O``: An immediate signed 15-bit integer.
3371 - ``P``: An immediate integer between 1 and 65535.
3372 - ``m``: A memory address operand. In MIPS-SE mode, allows a base address
3373   register plus 16-bit immediate offset. In MIPS mode, just a base register.
3374 - ``R``: A memory address operand. In MIPS-SE mode, allows a base address
3375   register plus a 9-bit signed offset. In MIPS mode, the same as constraint
3376   ``m``.
3377 - ``ZC``: A memory address operand, suitable for use in a ``pref``, ``ll``, or
3378   ``sc`` instruction on the given subtarget (details vary).
3379 - ``r``, ``d``,  ``y``: A 32 or 64-bit GPR register.
3380 - ``f``: A 32 or 64-bit FPU register (``F0-F31``), or a 128-bit MSA register
3381   (``W0-W31``). In the case of MSA registers, it is recommended to use the ``w``
3382   argument modifier for compatibility with GCC.
3383 - ``c``: A 32-bit or 64-bit GPR register suitable for indirect jump (always
3384   ``25``).
3385 - ``l``: The ``lo`` register, 32 or 64-bit.
3386 - ``x``: Invalid.
3387
3388 NVPTX:
3389
3390 - ``b``: A 1-bit integer register.
3391 - ``c`` or ``h``: A 16-bit integer register.
3392 - ``r``: A 32-bit integer register.
3393 - ``l`` or ``N``: A 64-bit integer register.
3394 - ``f``: A 32-bit float register.
3395 - ``d``: A 64-bit float register.
3396
3397
3398 PowerPC:
3399
3400 - ``I``: An immediate signed 16-bit integer.
3401 - ``J``: An immediate unsigned 16-bit integer, shifted left 16 bits.
3402 - ``K``: An immediate unsigned 16-bit integer.
3403 - ``L``: An immediate signed 16-bit integer, shifted left 16 bits.
3404 - ``M``: An immediate integer greater than 31.
3405 - ``N``: An immediate integer that is an exact power of 2.
3406 - ``O``: The immediate integer constant 0.
3407 - ``P``: An immediate integer constant whose negation is a signed 16-bit
3408   constant.
3409 - ``es``, ``o``, ``Q``, ``Z``, ``Zy``: A memory address operand, currently
3410   treated the same as ``m``.
3411 - ``r``: A 32 or 64-bit integer register.
3412 - ``b``: A 32 or 64-bit integer register, excluding ``R0`` (that is:
3413   ``R1-R31``).
3414 - ``f``: A 32 or 64-bit float register (``F0-F31``), or when QPX is enabled, a
3415   128 or 256-bit QPX register (``Q0-Q31``; aliases the ``F`` registers).
3416 - ``v``: For ``4 x f32`` or ``4 x f64`` types, when QPX is enabled, a
3417   128 or 256-bit QPX register (``Q0-Q31``), otherwise a 128-bit
3418   altivec vector register (``V0-V31``).
3419
3420   .. FIXME: is this a bug that v accepts QPX registers? I think this
3421      is supposed to only use the altivec vector registers?
3422
3423 - ``y``: Condition register (``CR0-CR7``).
3424 - ``wc``: An individual CR bit in a CR register.
3425 - ``wa``, ``wd``, ``wf``: Any 128-bit VSX vector register, from the full VSX
3426   register set (overlapping both the floating-point and vector register files).
3427 - ``ws``: A 32 or 64-bit floating point register, from the full VSX register
3428   set.
3429
3430 Sparc:
3431
3432 - ``I``: An immediate 13-bit signed integer.
3433 - ``r``: A 32-bit integer register.
3434
3435 SystemZ:
3436
3437 - ``I``: An immediate unsigned 8-bit integer.
3438 - ``J``: An immediate unsigned 12-bit integer.
3439 - ``K``: An immediate signed 16-bit integer.
3440 - ``L``: An immediate signed 20-bit integer.
3441 - ``M``: An immediate integer 0x7fffffff.
3442 - ``Q``, ``R``, ``S``, ``T``: A memory address operand, treated the same as
3443   ``m``, at the moment.
3444 - ``r`` or ``d``: A 32, 64, or 128-bit integer register.
3445 - ``a``: A 32, 64, or 128-bit integer address register (excludes R0, which in an
3446   address context evaluates as zero).
3447 - ``h``: A 32-bit value in the high part of a 64bit data register
3448   (LLVM-specific)
3449 - ``f``: A 32, 64, or 128-bit floating point register.
3450
3451 X86:
3452
3453 - ``I``: An immediate integer between 0 and 31.
3454 - ``J``: An immediate integer between 0 and 64.
3455 - ``K``: An immediate signed 8-bit integer.
3456 - ``L``: An immediate integer, 0xff or 0xffff or (in 64-bit mode only)
3457   0xffffffff.
3458 - ``M``: An immediate integer between 0 and 3.
3459 - ``N``: An immediate unsigned 8-bit integer.
3460 - ``O``: An immediate integer between 0 and 127.
3461 - ``e``: An immediate 32-bit signed integer.
3462 - ``Z``: An immediate 32-bit unsigned integer.
3463 - ``o``, ``v``: Treated the same as ``m``, at the moment.
3464 - ``q``: An 8, 16, 32, or 64-bit register which can be accessed as an 8-bit
3465   ``l`` integer register. On X86-32, this is the ``a``, ``b``, ``c``, and ``d``
3466   registers, and on X86-64, it is all of the integer registers.
3467 - ``Q``: An 8, 16, 32, or 64-bit register which can be accessed as an 8-bit
3468   ``h`` integer register. This is the ``a``, ``b``, ``c``, and ``d`` registers.
3469 - ``r`` or ``l``: An 8, 16, 32, or 64-bit integer register.
3470 - ``R``: An 8, 16, 32, or 64-bit "legacy" integer register -- one which has
3471   existed since i386, and can be accessed without the REX prefix.
3472 - ``f``: A 32, 64, or 80-bit '387 FPU stack pseudo-register.
3473 - ``y``: A 64-bit MMX register, if MMX is enabled.
3474 - ``x``: If SSE is enabled: a 32 or 64-bit scalar operand, or 128-bit vector
3475   operand in a SSE register. If AVX is also enabled, can also be a 256-bit
3476   vector operand in an AVX register. If AVX-512 is also enabled, can also be a
3477   512-bit vector operand in an AVX512 register, Otherwise, an error.
3478 - ``Y``: The same as ``x``, if *SSE2* is enabled, otherwise an error.
3479 - ``A``: Special case: allocates EAX first, then EDX, for a single operand (in
3480   32-bit mode, a 64-bit integer operand will get split into two registers). It
3481   is not recommended to use this constraint, as in 64-bit mode, the 64-bit
3482   operand will get allocated only to RAX -- if two 32-bit operands are needed,
3483   you're better off splitting it yourself, before passing it to the asm
3484   statement.
3485
3486 XCore:
3487
3488 - ``r``: A 32-bit integer register.
3489
3490
3491 .. _inline-asm-modifiers:
3492
3493 Asm template argument modifiers
3494 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
3495
3496 In the asm template string, modifiers can be used on the operand reference, like
3497 "``${0:n}``".
3498
3499 The modifiers are, in general, expected to behave the same way they do in
3500 GCC. LLVM's support is often implemented on an 'as-needed' basis, to support C
3501 inline asm code which was supported by GCC. A mismatch in behavior between LLVM
3502 and GCC likely indicates a bug in LLVM.
3503
3504 Target-independent:
3505
3506 - ``c``: Print an immediate integer constant unadorned, without
3507   the target-specific immediate punctuation (e.g. no ``$`` prefix).
3508 - ``n``: Negate and print immediate integer constant unadorned, without the
3509   target-specific immediate punctuation (e.g. no ``$`` prefix).
3510 - ``l``: Print as an unadorned label, without the target-specific label
3511   punctuation (e.g. no ``$`` prefix).
3512
3513 AArch64:
3514
3515 - ``w``: Print a GPR register with a ``w*`` name instead of ``x*`` name. E.g.,
3516   instead of ``x30``, print ``w30``.
3517 - ``x``: Print a GPR register with a ``x*`` name. (this is the default, anyhow).
3518 - ``b``, ``h``, ``s``, ``d``, ``q``: Print a floating-point/SIMD register with a
3519   ``b*``, ``h*``, ``s*``, ``d*``, or ``q*`` name, rather than the default of
3520   ``v*``.
3521
3522 AMDGPU:
3523
3524 - ``r``: No effect.
3525
3526 ARM:
3527
3528 - ``a``: Print an operand as an address (with ``[`` and ``]`` surrounding a
3529   register).
3530 - ``P``: No effect.
3531 - ``q``: No effect.
3532 - ``y``: Print a VFP single-precision register as an indexed double (e.g. print
3533   as ``d4[1]`` instead of ``s9``)
3534 - ``B``: Bitwise invert and print an immediate integer constant without ``#``
3535   prefix.
3536 - ``L``: Print the low 16-bits of an immediate integer constant.
3537 - ``M``: Print as a register set suitable for ldm/stm. Also prints *all*
3538   register operands subsequent to the specified one (!), so use carefully.
3539 - ``Q``: Print the low-order register of a register-pair, or the low-order
3540   register of a two-register operand.
3541 - ``R``: Print the high-order register of a register-pair, or the high-order
3542   register of a two-register operand.
3543 - ``H``: Print the second register of a register-pair. (On a big-endian system,
3544   ``H`` is equivalent to ``Q``, and on little-endian system, ``H`` is equivalent
3545   to ``R``.)
3546
3547   .. FIXME: H doesn't currently support printing the second register
3548      of a two-register operand.
3549
3550 - ``e``: Print the low doubleword register of a NEON quad register.
3551 - ``f``: Print the high doubleword register of a NEON quad register.
3552 - ``m``: Print the base register of a memory operand without the ``[`` and ``]``
3553   adornment.
3554
3555 Hexagon:
3556
3557 - ``L``: Print the second register of a two-register operand. Requires that it
3558   has been allocated consecutively to the first.
3559
3560   .. FIXME: why is it restricted to consecutive ones? And there's
3561      nothing that ensures that happens, is there?
3562
3563 - ``I``: Print the letter 'i' if the operand is an integer constant, otherwise
3564   nothing. Used to print 'addi' vs 'add' instructions.
3565
3566 MSP430:
3567
3568 No additional modifiers.
3569
3570 MIPS:
3571
3572 - ``X``: Print an immediate integer as hexadecimal
3573 - ``x``: Print the low 16 bits of an immediate integer as hexadecimal.
3574 - ``d``: Print an immediate integer as decimal.
3575 - ``m``: Subtract one and print an immediate integer as decimal.
3576 - ``z``: Print $0 if an immediate zero, otherwise print normally.
3577 - ``L``: Print the low-order register of a two-register operand, or prints the
3578   address of the low-order word of a double-word memory operand.
3579
3580   .. FIXME: L seems to be missing memory operand support.
3581
3582 - ``M``: Print the high-order register of a two-register operand, or prints the
3583   address of the high-order word of a double-word memory operand.
3584
3585   .. FIXME: M seems to be missing memory operand support.
3586
3587 - ``D``: Print the second register of a two-register operand, or prints the
3588   second word of a double-word memory operand. (On a big-endian system, ``D`` is
3589   equivalent to ``L``, and on little-endian system, ``D`` is equivalent to
3590   ``M``.)
3591 - ``w``: No effect. Provided for compatibility with GCC which requires this
3592   modifier in order to print MSA registers (``W0-W31``) with the ``f``
3593   constraint.
3594
3595 NVPTX:
3596
3597 - ``r``: No effect.