cmake/modules/TableGen.cmake

   1 # LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
   2 # Extra parameters for `tblgen' may come after `ofn' parameter.
   3 # Adds the name of the generated file to TABLEGEN_OUTPUT.
   4
   5 function(tablegen project ofn)
   6   # Validate calling context.
   7   foreach(v
   8       ${project}_TABLEGEN_EXE
   9       LLVM_MAIN_SRC_DIR
  10       LLVM_MAIN_INCLUDE_DIR
  11       )
  12     if(NOT ${v})
  13       message(FATAL_ERROR "${v} not set")
  14     endif()
  15   endforeach()
  16
  17   file(GLOB local_tds "*.td")
  18   file(GLOB_RECURSE global_tds "${LLVM_MAIN_INCLUDE_DIR}/llvm/*.td")
  19
  20   if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  21     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  22   else()
  23     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
  24       ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
  25   endif()
  26   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  27     # Generate tablegen output in a temporary file.
  28     COMMAND ${${project}_TABLEGEN_EXE} ${ARGN} -I ${CMAKE_CURRENT_SOURCE_DIR}
  29     -I ${LLVM_MAIN_SRC_DIR}/lib/Target -I ${LLVM_MAIN_INCLUDE_DIR}
  30     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  31     -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  32     # The file in LLVM_TARGET_DEFINITIONS may be not in the current
  33     # directory and local_tds may not contain it, so we must
  34     # explicitly list it here:
  35     DEPENDS ${${project}_TABLEGEN_TARGET} ${local_tds} ${global_tds}
  36     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  37     COMMENT "Building ${ofn}..."
  38     )
  39   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  40     # Only update the real output file if there are any differences.
  41     # This prevents recompilation of all the files depending on it if there
  42     # aren't any.
  43     COMMAND ${CMAKE_COMMAND} -E copy_if_different
  44         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  45         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  46     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  47     COMMENT "Updating ${ofn}..."
  48     )
  49
  50   # `make clean' must remove all those generated files:
  51   set_property(DIRECTORY APPEND
  52     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${ofn}.tmp ${ofn})
  53
  54   set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn} PARENT_SCOPE)
  55   set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn} PROPERTIES
  56     GENERATED 1)
  57 endfunction()
  58
  59 # Creates a target for publicly exporting tablegen dependencies.
  60 function(add_public_tablegen_target target)
  61   if(NOT TABLEGEN_OUTPUT)
  62     message(FATAL_ERROR "Requires tablegen() definitions as TABLEGEN_OUTPUT.")
  63   endif()
  64   add_custom_target(${target}
  65     DEPENDS ${TABLEGEN_OUTPUT})
  66   if(LLVM_COMMON_DEPENDS)
  67     add_dependencies(${target} ${LLVM_COMMON_DEPENDS})
  68   endif()
  69   set_target_properties(${target} PROPERTIES FOLDER "Tablegenning")
  70   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${target} PARENT_SCOPE)
  71 endfunction()
  72
  73 if(LLVM_USE_HOST_TOOLS)
  74   add_custom_command(OUTPUT LIB_LLVMSUPPORT
  75       COMMAND ${CMAKE_COMMAND} --build . --target LLVMSupport --config Release
  76       DEPENDS CONFIGURE_LLVM_NATIVE
  77       WORKING_DIRECTORY ${LLVM_NATIVE_BUILD}
  78       COMMENT "Building libLLVMSupport for native TableGen...")
  79   add_custom_target(NATIVE_LIB_LLVMSUPPORT DEPENDS LIB_LLVMSUPPORT)
  80
  81   add_custom_command(OUTPUT LIB_LLVMTABLEGEN
  82       COMMAND ${CMAKE_COMMAND} --build . --target LLVMTableGen --config Release
  83       DEPENDS CONFIGURE_LLVM_NATIVE
  84       WORKING_DIRECTORY ${LLVM_NATIVE_BUILD}
  85       COMMENT "Building libLLVMTableGen for native TableGen...")
  86   add_custom_target(NATIVE_LIB_LLVMTABLEGEN DEPENDS LIB_LLVMTABLEGEN)
  87 endif(LLVM_USE_HOST_TOOLS)
  88
  89 macro(add_tablegen target project)
  90   set(${target}_OLD_LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS})
  91   set(LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS} TableGen)
  92
  93   if(NOT XCODE)
  94     # FIXME: It leaks to user, callee of add_tablegen.
  95     set(LLVM_ENABLE_OBJLIB ON)
  96   endif()
  97
  98   add_llvm_utility(${target} ${ARGN})
  99   set(LLVM_LINK_COMPONENTS ${${target}_OLD_LLVM_LINK_COMPONENTS})
 100
 101   set(${project}_TABLEGEN "${target}" CACHE
 102       STRING "Native TableGen executable. Saves building one when cross-compiling.")
 103
 104   # Upgrade existing LLVM_TABLEGEN setting.
 105   if(${project} STREQUAL LLVM)
 106     if(${LLVM_TABLEGEN} STREQUAL tblgen)
 107       set(LLVM_TABLEGEN "${target}" CACHE
 108           STRING "Native TableGen executable. Saves building one when cross-compiling."
 109           FORCE)
 110     endif()
 111   endif()
 112
 113   # Effective tblgen executable to be used:
 114   set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN} PARENT_SCOPE)
 115   set(${project}_TABLEGEN_TARGET ${${project}_TABLEGEN} PARENT_SCOPE)
 116
 117   if(LLVM_USE_HOST_TOOLS)
 118     if( ${${project}_TABLEGEN} STREQUAL "${target}" )
 119       if (NOT CMAKE_CONFIGURATION_TYPES)
 120         set(${project}_TABLEGEN_EXE "${LLVM_NATIVE_BUILD}/bin/${target}")
 121       else()
 122         set(${project}_TABLEGEN_EXE "${LLVM_NATIVE_BUILD}/Release/bin/${target}")
 123       endif()
 124       set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN_EXE} PARENT_SCOPE)
 125
 126       add_custom_command(OUTPUT ${${project}_TABLEGEN_EXE}
 127         COMMAND ${CMAKE_COMMAND} --build . --target ${target} --config Release
 128         DEPENDS ${target} NATIVE_LIB_LLVMSUPPORT NATIVE_LIB_LLVMTABLEGEN
 129         WORKING_DIRECTORY ${LLVM_NATIVE_BUILD}
 130         COMMENT "Building native TableGen...")
 131       add_custom_target(${project}-tablegen-host DEPENDS ${${project}_TABLEGEN_EXE})
 132       set(${project}_TABLEGEN_TARGET ${project}-tablegen-host PARENT_SCOPE)
 133     endif()
 134   endif()
 135
 136   if( MINGW )
 137     if(CMAKE_SIZEOF_VOID_P MATCHES "8")
 138       set_target_properties(${target} PROPERTIES LINK_FLAGS -Wl,--stack,16777216)
 139     endif(CMAKE_SIZEOF_VOID_P MATCHES "8")
 140   endif( MINGW )
 141   if (${project} STREQUAL LLVM AND NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 142     install(TARGETS ${target}
 143             EXPORT LLVMExports
 144             RUNTIME DESTINATION bin)
 145   endif()
 146   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${target})
 147 endmacro()