cmake/modules/TableGen.cmake

   1 # LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
   2 # Extra parameters for `tblgen' may come after `ofn' parameter.
   3 # Adds the name of the generated file to TABLEGEN_OUTPUT.
   4
   5 function(tablegen project ofn)
   6   file(GLOB local_tds "*.td")
   7   file(GLOB_RECURSE global_tds "${LLVM_MAIN_INCLUDE_DIR}/llvm/*.td")
   8
   9   if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  10     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  11   else()
  12     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
  13       ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
  14   endif()
  15   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  16     # Generate tablegen output in a temporary file.
  17     COMMAND ${${project}_TABLEGEN_EXE} ${ARGN} -I ${CMAKE_CURRENT_SOURCE_DIR}
  18     -I ${LLVM_MAIN_SRC_DIR}/lib/Target -I ${LLVM_MAIN_INCLUDE_DIR}
  19     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  20     -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  21     # The file in LLVM_TARGET_DEFINITIONS may be not in the current
  22     # directory and local_tds may not contain it, so we must
  23     # explicitly list it here:
  24     DEPENDS ${${project}_TABLEGEN_EXE} ${local_tds} ${global_tds}
  25     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  26     COMMENT "Building ${ofn}..."
  27     )
  28   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  29     # Only update the real output file if there are any differences.
  30     # This prevents recompilation of all the files depending on it if there
  31     # aren't any.
  32     COMMAND ${CMAKE_COMMAND} -E copy_if_different
  33         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  34         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  35     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  36     COMMENT "Updating ${ofn}..."
  37     )
  38
  39   # `make clean' must remove all those generated files:
  40   set_property(DIRECTORY APPEND
  41     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${ofn}.tmp ${ofn})
  42
  43   set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn} PARENT_SCOPE)
  44   set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  45     PROPERTIES GENERATED 1)
  46 endfunction(tablegen)
  47
  48 macro(add_public_tablegen_target target)
  49   # Creates a target for publicly exporting tablegen dependencies.
  50   if( TABLEGEN_OUTPUT )
  51     add_custom_target(${target}
  52       DEPENDS ${TABLEGEN_OUTPUT})
  53     if (LLVM_COMMON_DEPENDS)
  54       add_dependencies(${target} ${LLVM_COMMON_DEPENDS})
  55     endif ()
  56     set_target_properties(${target} PROPERTIES FOLDER "Tablegenning")
  57     list(APPEND LLVM_COMMON_DEPENDS ${target} intrinsics_gen)
  58   endif( TABLEGEN_OUTPUT )
  59 endmacro()
  60
  61 if(CMAKE_CROSSCOMPILING)
  62   set(CX_NATIVE_TG_DIR "${CMAKE_BINARY_DIR}/native")
  63
  64   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}
  65     COMMAND ${CMAKE_COMMAND} -E make_directory ${CX_NATIVE_TG_DIR}
  66     COMMENT "Creating ${CX_NATIVE_TG_DIR}...")
  67
  68   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}/CMakeCache.txt
  69     COMMAND ${CMAKE_COMMAND} -UMAKE_TOOLCHAIN_FILE -DCMAKE_BUILD_TYPE=Release
  70                              -DLLVM_BUILD_POLLY=OFF
  71                              -G "${CMAKE_GENERATOR}" ${CMAKE_SOURCE_DIR}
  72     WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
  73     DEPENDS ${CX_NATIVE_TG_DIR}
  74     COMMENT "Configuring native TableGen...")
  75
  76   add_custom_target(ConfigureNativeTableGen DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt)
  77
  78   set_directory_properties(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES ${CX_NATIVE_TG_DIR})
  79 endif()
  80
  81 macro(add_tablegen target project)
  82   set(${target}_OLD_LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS})
  83   set(LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS} TableGen)
  84   add_llvm_utility(${target} ${ARGN})
  85   set(LLVM_LINK_COMPONENTS ${${target}_OLD_LLVM_LINK_COMPONENTS})
  86
  87   set(${project}_TABLEGEN "${target}" CACHE
  88       STRING "Native TableGen executable. Saves building one when cross-compiling.")
  89
  90   # Upgrade existing LLVM_TABLEGEN setting.
  91   if(${project} STREQUAL LLVM)
  92     if(${LLVM_TABLEGEN} STREQUAL tblgen)
  93       set(LLVM_TABLEGEN "${target}" CACHE
  94           STRING "Native TableGen executable. Saves building one when cross-compiling."
  95           FORCE)
  96     endif()
  97   endif()
  98
  99   # Effective tblgen executable to be used:
 100   set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN} PARENT_SCOPE)
 101
 102   if(CMAKE_CROSSCOMPILING)
 103     if( ${${project}_TABLEGEN} STREQUAL "${target}" )
 104       set(${project}_TABLEGEN_EXE "${CX_NATIVE_TG_DIR}/bin/${target}")
 105       set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN_EXE} PARENT_SCOPE)
 106
 107       add_custom_command(OUTPUT ${${project}_TABLEGEN_EXE}
 108         COMMAND ${CMAKE_BUILD_TOOL} ${target}
 109         DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt
 110         WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
 111         COMMENT "Building native TableGen...")
 112       add_custom_target(${project}NativeTableGen DEPENDS ${${project}_TABLEGEN_EXE})
 113       add_dependencies(${project}NativeTableGen ConfigureNativeTableGen)
 114
 115       add_dependencies(${target} ${project}NativeTableGen)
 116     endif()
 117   endif()
 118
 119   if( MINGW )
 120     target_link_libraries(${target} imagehlp psapi shell32)
 121     if(CMAKE_SIZEOF_VOID_P MATCHES "8")
 122       set_target_properties(${target} PROPERTIES LINK_FLAGS -Wl,--stack,16777216)
 123     endif(CMAKE_SIZEOF_VOID_P MATCHES "8")
 124   endif( MINGW )
 125   if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD AND NOT BEOS )
 126     target_link_libraries(${target} pthread)
 127   endif()
 128
 129   if (${project} STREQUAL LLVM AND NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 130     install(TARGETS ${target}
 131             EXPORT LLVMExports
 132             RUNTIME DESTINATION bin)
 133   endif()
 134   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${target})
 135 endmacro()