cmake/modules/HandleLLVMOptions.cmake

   1 include(AddLLVMDefinitions)
   2
   3 # Run-time build mode; It is used for unittests.
   4 if(MSVC_IDE)
   5   # Expect "$(Configuration)", "$(OutDir)", etc.
   6   # It is expanded by msbuild or similar.
   7   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
   8 elseif(NOT CMAKE_BUILD_TYPE STREQUAL "")
   9   # Expect "Release" "Debug", etc.
  10   # Or unittests could not run.
  11   set(RUNTIME_BUILD_MODE ${CMAKE_BUILD_TYPE})
  12 else()
  13   # It might be "."
  14   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
  15 endif()
  16
  17 set(LIT_ARGS_DEFAULT "-sv")
  18 if (MSVC OR XCODE)
  19   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
  20 endif()
  21 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}"
  22     CACHE STRING "Default options for lit")
  23
  24 if( LLVM_ENABLE_ASSERTIONS )
  25   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  26   if( NOT MSVC )
  27     add_definitions( -D_DEBUG )
  28   endif()
  29   # On Release builds cmake automatically defines NDEBUG, so we
  30   # explicitly undefine it:
  31   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  32     add_definitions( -UNDEBUG )
  33   endif()
  34 else()
  35   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  36     if( NOT MSVC_IDE AND NOT XCODE )
  37       add_definitions( -DNDEBUG )
  38     endif()
  39   endif()
  40 endif()
  41
  42 if(WIN32)
  43   if(CYGWIN)
  44     set(LLVM_ON_WIN32 0)
  45     set(LLVM_ON_UNIX 1)
  46   else(CYGWIN)
  47     set(LLVM_ON_WIN32 1)
  48     set(LLVM_ON_UNIX 0)
  49
  50     # This is effective only on Win32 hosts to use gnuwin32 tools.
  51     set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
  52   endif(CYGWIN)
  53   set(LTDL_SHLIB_EXT ".dll")
  54   set(EXEEXT ".exe")
  55   # Maximum path length is 160 for non-unicode paths
  56   set(MAXPATHLEN 160)
  57 else(WIN32)
  58   if(UNIX)
  59     set(LLVM_ON_WIN32 0)
  60     set(LLVM_ON_UNIX 1)
  61     if(APPLE)
  62       set(LTDL_SHLIB_EXT ".dylib")
  63     else(APPLE)
  64       set(LTDL_SHLIB_EXT ".so")
  65     endif(APPLE)
  66     set(EXEEXT "")
  67     # FIXME: Maximum path length is currently set to 'safe' fixed value
  68     set(MAXPATHLEN 2024)
  69   else(UNIX)
  70     MESSAGE(SEND_ERROR "Unable to determine platform")
  71   endif(UNIX)
  72 endif(WIN32)
  73
  74 if( LLVM_ENABLE_PIC )
  75   if( XCODE )
  76     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
  77     # know how to disable this, so just force ENABLE_PIC off for now.
  78     message(WARNING "-fPIC not supported with Xcode.")
  79   elseif( WIN32 )
  80     # On Windows all code is PIC. MinGW warns if -fPIC is used.
  81   else()
  82     include(CheckCXXCompilerFlag)
  83     check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  84     if( SUPPORTS_FPIC_FLAG )
  85       message(STATUS "Building with -fPIC")
  86       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  87       set(CMAKE_C_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  88     else( SUPPORTS_FPIC_FLAG )
  89       message(WARNING "-fPIC not supported.")
  90     endif()
  91   endif()
  92 endif()
  93
  94 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
  95   # TODO: support other platforms and toolchains.
  96   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
  97   if( LLVM_BUILD_32_BITS )
  98     message(STATUS "Building 32 bits executables and libraries.")
  99     add_llvm_definitions( -m32 )
 100     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 101     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 102   endif( LLVM_BUILD_32_BITS )
 103 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 104
 105 if( MSVC )
 106   include(ChooseMSVCCRT)
 107
 108   # Add definitions that make MSVC much less annoying.
 109   add_llvm_definitions(
 110     # For some reason MS wants to deprecate a bunch of standard functions...
 111     -D_CRT_SECURE_NO_DEPRECATE
 112     -D_CRT_SECURE_NO_WARNINGS
 113     -D_CRT_NONSTDC_NO_DEPRECATE
 114     -D_CRT_NONSTDC_NO_WARNINGS
 115     -D_SCL_SECURE_NO_DEPRECATE
 116     -D_SCL_SECURE_NO_WARNINGS
 117
 118     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 119     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 120     -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
 121     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 122     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 123     -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 124     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 125     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 126     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 127     -wd4355 # Suppress ''this' : used in base member initializer list'
 128     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 129     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 130     -wd4715 # Suppress ''function' : not all control paths return a value'
 131     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 132     -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
 133
 134     -w14062 # Promote "enumerator in switch of enum is not handled" to level 1 warning.
 135     )
 136
 137   # Enable warnings
 138   if (LLVM_ENABLE_WARNINGS)
 139     add_llvm_definitions( /W4 /Wall )
 140     if (LLVM_ENABLE_PEDANTIC)
 141       # No MSVC equivalent available
 142     endif (LLVM_ENABLE_PEDANTIC)
 143   endif (LLVM_ENABLE_WARNINGS)
 144   if (LLVM_ENABLE_WERROR)
 145     add_llvm_definitions( /WX )
 146   endif (LLVM_ENABLE_WERROR)
 147 elseif( CMAKE_COMPILER_IS_GNUCXX )
 148   if (LLVM_ENABLE_WARNINGS)
 149     add_llvm_definitions( -Wall -W -Wno-unused-parameter -Wwrite-strings )
 150     if (LLVM_ENABLE_PEDANTIC)
 151       add_llvm_definitions( -pedantic -Wno-long-long )
 152     endif (LLVM_ENABLE_PEDANTIC)
 153   endif (LLVM_ENABLE_WARNINGS)
 154   if (LLVM_ENABLE_WERROR)
 155     add_llvm_definitions( -Werror )
 156   endif (LLVM_ENABLE_WERROR)
 157 endif( MSVC )
 158
 159 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 160 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 161