cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(HandleLLVMStdlib)
   6 include(AddLLVMDefinitions)
   7 include(CheckCCompilerFlag)
   8 include(CheckCXXCompilerFlag)
   9
  10 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
  11   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  12     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
  13       message(FATAL_ERROR "Host GCC version must be at least 4.7!")
  14     endif()
  15   elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  16     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
  17       message(FATAL_ERROR "Host Clang version must be at least 3.1!")
  18     endif()
  19
  20     # Also test that we aren't using too old of a version of libstdc++ with the
  21     # Clang compiler. This is tricky as there is no real way to check the
  22     # version of libstdc++ directly. Instead we test for a known bug in
  23     # libstdc++4.6 that is fixed in libstdc++4.7.
  24     if(NOT LLVM_ENABLE_LIBCXX)
  25       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  26       set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  27       set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
  28       if (ANDROID)
  29         set(CMAKE_REQUIRED_LIBRARIES "atomic")
  30       endif()
  31       check_cxx_source_compiles("
  32 #include <atomic>
  33 std::atomic<float> x(0.0f);
  34 int main() { return (float)x; }"
  35         LLVM_NO_OLD_LIBSTDCXX)
  36       if(NOT LLVM_NO_OLD_LIBSTDCXX)
  37         message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
  38       endif()
  39       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
  40       set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
  41     endif()
  42   elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  43     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 17.0)
  44       message(FATAL_ERROR "Host Visual Studio must be at least 2012 (MSVC 17.0)")
  45     endif()
  46   endif()
  47 endif()
  48
  49 if( LLVM_ENABLE_ASSERTIONS )
  50   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  51   if( NOT MSVC )
  52     add_definitions( -D_DEBUG )
  53   endif()
  54   # On non-Debug builds cmake automatically defines NDEBUG, so we
  55   # explicitly undefine it:
  56   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  57     add_definitions( -UNDEBUG )
  58     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  59     set(REGEXP_NDEBUG "(^| )[/-]D *NDEBUG($| )")
  60     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  61       CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
  62     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  63       CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO}")
  64     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  65       CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL}")
  66   endif()
  67 else()
  68   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  69     if( NOT MSVC_IDE AND NOT XCODE )
  70       add_definitions( -DNDEBUG )
  71     endif()
  72   endif()
  73 endif()
  74
  75 if(WIN32)
  76   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  77   if(CYGWIN)
  78     set(LLVM_ON_WIN32 0)
  79     set(LLVM_ON_UNIX 1)
  80   else(CYGWIN)
  81     set(LLVM_ON_WIN32 1)
  82     set(LLVM_ON_UNIX 0)
  83   endif(CYGWIN)
  84   # Maximum path length is 160 for non-unicode paths
  85   set(MAXPATHLEN 160)
  86 else(WIN32)
  87   if(UNIX)
  88     set(LLVM_ON_WIN32 0)
  89     set(LLVM_ON_UNIX 1)
  90     if(APPLE)
  91       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  92     else(APPLE)
  93       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
  94     endif(APPLE)
  95     # FIXME: Maximum path length is currently set to 'safe' fixed value
  96     set(MAXPATHLEN 2024)
  97   else(UNIX)
  98     MESSAGE(SEND_ERROR "Unable to determine platform")
  99   endif(UNIX)
 100 endif(WIN32)
 101
 102 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 103 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 104
 105 # We use *.dylib rather than *.so on darwin.
 106 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 107
 108 if(APPLE)
 109   # Darwin-specific linker flags for loadable modules.
 110   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 111 endif()
 112
 113 function(add_flag_or_print_warning flag)
 114   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
 115   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
 116   if (C_SUPPORTS_FLAG AND CXX_SUPPORTS_FLAG)
 117     message(STATUS "Building with ${flag}")
 118     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 119     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 120   else()
 121     message(WARNING "${flag} is not supported.")
 122   endif()
 123 endfunction()
 124
 125 function(append value)
 126   foreach(variable ${ARGN})
 127     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 128   endforeach(variable)
 129 endfunction()
 130
 131 function(append_if condition value)
 132   if (${condition})
 133     foreach(variable ${ARGN})
 134       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 135     endforeach(variable)
 136   endif()
 137 endfunction()
 138
 139 macro(add_flag_if_supported flag)
 140   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
 141   append_if(C_SUPPORTS_FLAG "${flag}" CMAKE_C_FLAGS)
 142   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
 143   append_if(CXX_SUPPORTS_FLAG "${flag}" CMAKE_CXX_FLAGS)
 144 endmacro()
 145
 146 if( LLVM_ENABLE_PIC )
 147   if( XCODE )
 148     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 149     # know how to disable this, so just force ENABLE_PIC off for now.
 150     message(WARNING "-fPIC not supported with Xcode.")
 151   elseif( WIN32 OR CYGWIN)
 152     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 153   else()
 154     add_flag_or_print_warning("-fPIC")
 155
 156     if( WIN32 OR CYGWIN)
 157       # MinGW warns if -fvisibility-inlines-hidden is used.
 158     else()
 159       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 160       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 161     endif()
 162   endif()
 163 endif()
 164
 165 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 166   # TODO: support other platforms and toolchains.
 167   if( LLVM_BUILD_32_BITS )
 168     message(STATUS "Building 32 bits executables and libraries.")
 169     add_llvm_definitions( -m32 )
 170     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 171     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 172     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 173   endif( LLVM_BUILD_32_BITS )
 174 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 175
 176 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 177 # to use.
 178 if( MSVC_IDE )
 179   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 180     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 181   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 182     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 183       add_llvm_definitions( /MP )
 184     else()
 185       if (MSVC10)
 186         message(FATAL_ERROR
 187           "Due to a bug in CMake only 0 and 1 is supported for "
 188           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 189       else()
 190         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 191         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 192       endif()
 193     endif()
 194   else()
 195     message(STATUS "Parallel compilation disabled")
 196   endif()
 197 endif()
 198
 199 if( MSVC )
 200   include(ChooseMSVCCRT)
 201
 202   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 203     # set stack reserved size to ~10MB
 204     # CMake previously automatically set this value for MSVC builds, but the
 205     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 206     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 207     # C++ templates in Clang.
 208     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 209   endif()
 210
 211   if( MSVC10 )
 212     # MSVC 10 will complain about headers in the STL not being exported, but
 213     # will not complain in MSVC 11.
 214     add_llvm_definitions(
 215       -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 216     )
 217   elseif( MSVC11 )
 218     add_llvm_definitions(-D_VARIADIC_MAX=10)
 219   endif()
 220
 221   # Add definitions that make MSVC much less annoying.
 222   add_llvm_definitions(
 223     # For some reason MS wants to deprecate a bunch of standard functions...
 224     -D_CRT_SECURE_NO_DEPRECATE
 225     -D_CRT_SECURE_NO_WARNINGS
 226     -D_CRT_NONSTDC_NO_DEPRECATE
 227     -D_CRT_NONSTDC_NO_WARNINGS
 228     -D_SCL_SECURE_NO_DEPRECATE
 229     -D_SCL_SECURE_NO_WARNINGS
 230
 231     # Disabled warnings.
 232     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 233     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 234     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 235     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 236     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 237     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 238     -wd4355 # Suppress ''this' : used in base member initializer list'
 239     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 240     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 241     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 242     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 243
 244     # Promoted warnings.
 245     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 246
 247     # Promoted warnings to errors.
 248     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 249     )
 250
 251   # Enable warnings
 252   if (LLVM_ENABLE_WARNINGS)
 253     add_llvm_definitions( /W4 )
 254     if (LLVM_ENABLE_PEDANTIC)
 255       # No MSVC equivalent available
 256     endif (LLVM_ENABLE_PEDANTIC)
 257   endif (LLVM_ENABLE_WARNINGS)
 258   if (LLVM_ENABLE_WERROR)
 259     add_llvm_definitions( /WX )
 260   endif (LLVM_ENABLE_WERROR)
 261 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 262   if (LLVM_ENABLE_WARNINGS)
 263     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 264
 265     # Turn off missing field initializer warnings for gcc to avoid noise from
 266     # false positives with empty {}. Turn them on otherwise (they're off by
 267     # default for clang).
 268     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 269     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 270       if (CMAKE_COMPILER_IS_GNUCXX)
 271         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 272       else()
 273         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 274       endif()
 275     endif()
 276
 277     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 278     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 279     append_if(CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_CXX_FLAGS)
 280     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 281     append_if(C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_C_FLAGS)
 282     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 283     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 284     check_cxx_compiler_flag("-Werror -Wnon-virtual-dtor" CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG)
 285     append_if(CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 286   endif (LLVM_ENABLE_WARNINGS)
 287   if (LLVM_ENABLE_WERROR)
 288     add_llvm_definitions( -Werror )
 289   endif (LLVM_ENABLE_WERROR)
 290   if (LLVM_ENABLE_CXX11)
 291     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 292     append_if(CXX_SUPPORTS_CXX11 "-std=c++11" CMAKE_CXX_FLAGS)
 293   endif (LLVM_ENABLE_CXX11)
 294 endif( MSVC )
 295
 296 macro(append_common_sanitizer_flags)
 297   # Append -fno-omit-frame-pointer and turn on debug info to get better
 298   # stack traces.
 299   add_flag_if_supported("-fno-omit-frame-pointer")
 300   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 301       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 302     add_flag_if_supported("-gline-tables-only")
 303   endif()
 304   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 305   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 306     add_flag_if_supported("-O1")
 307   endif()
 308 endmacro()
 309
 310 # Turn on sanitizers if necessary.
 311 if(LLVM_USE_SANITIZER)
 312   if (LLVM_ON_UNIX)
 313     if (LLVM_USE_SANITIZER STREQUAL "Address")
 314       append_common_sanitizer_flags()
 315       add_flag_or_print_warning("-fsanitize=address")
 316     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 317       append_common_sanitizer_flags()
 318       add_flag_or_print_warning("-fsanitize=memory")
 319       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 320         add_flag_or_print_warning("-fsanitize-memory-track-origins")
 321       endif()
 322     else()
 323       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 324     endif()
 325   else()
 326     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 327   endif()
 328 endif()
 329
 330 # Turn on -gsplit-dwarf if requested
 331 if(LLVM_USE_SPLIT_DWARF)
 332   add_llvm_definitions("-gsplit-dwarf")
 333 endif()
 334
 335 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 336 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 337 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 338
 339 # clang doesn't print colored diagnostics when invoked from Ninja
 340 if (UNIX AND
 341     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 342     CMAKE_GENERATOR STREQUAL "Ninja")
 343   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 344 endif()
 345
 346 # Add flags for add_dead_strip().
 347 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 348 # But MinSizeRel seems to add that automatically, so maybe disable these
 349 # flags instead if LLVM_NO_DEAD_STRIP is set.
 350 if(NOT CYGWIN AND NOT WIN32)
 351   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 352     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 353     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 354       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 355       # Doing so will break sanitizers.
 356       check_c_compiler_flag("-Werror -ffunction-sections" C_SUPPORTS_FFUNCTION_SECTIONS)
 357       check_cxx_compiler_flag("-Werror -ffunction-sections" CXX_SUPPORTS_FFUNCTION_SECTIONS)
 358       append_if(C_SUPPORTS_FFUNCTION_SECTIONS "-ffunction-sections" CMAKE_C_FLAGS)
 359       append_if(CXX_SUPPORTS_FFUNCTION_SECTIONS "-ffunction-sections" CMAKE_CXX_FLAGS)
 360     endif()
 361     check_c_compiler_flag("-Werror -fdata-sections" C_SUPPORTS_FDATA_SECTIONS)
 362     check_cxx_compiler_flag("-Werror -fdata-sections" CXX_SUPPORTS_FDATA_SECTIONS)
 363     append_if(C_SUPPORTS_FDATA_SECTIONS "-fdata-sections" CMAKE_C_FLAGS)
 364     append_if(CXX_SUPPORTS_FDATA_SECTIONS "-fdata-sections" CMAKE_CXX_FLAGS)
 365   endif()
 366 endif()
 367
 368 if(MSVC)
 369   # Remove flags here, for exceptions and RTTI.
 370   # Each target property or source property should be responsible to control
 371   # them.
 372   # CL.EXE complains to override flags like "/GR /GR-".
 373   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 374   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 375 endif()