cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(AddLLVMDefinitions)
   6 include(CheckCCompilerFlag)
   7 include(CheckCXXCompilerFlag)
   8
   9 if( CMAKE_COMPILER_IS_GNUCXX )
  10   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  11 elseif( MSVC )
  12   set(LLVM_COMPILER_IS_GCC_COMPATIBLE OFF)
  13 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
  14   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  15 endif()
  16
  17 if( LLVM_ENABLE_ASSERTIONS )
  18   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  19   if( NOT MSVC )
  20     add_definitions( -D_DEBUG )
  21   endif()
  22   # On non-Debug builds cmake automatically defines NDEBUG, so we
  23   # explicitly undefine it:
  24   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  25     add_definitions( -UNDEBUG )
  26     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  27     set(REGEXP_NDEBUG "(^| )[/-]D *NDEBUG($| )")
  28     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  29       CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
  30     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  31       CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO}")
  32     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  33       CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL}")
  34   endif()
  35 else()
  36   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  37     if( NOT MSVC_IDE AND NOT XCODE )
  38       add_definitions( -DNDEBUG )
  39     endif()
  40   endif()
  41 endif()
  42
  43 if(WIN32)
  44   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  45   if(CYGWIN)
  46     set(LLVM_ON_WIN32 0)
  47     set(LLVM_ON_UNIX 1)
  48   else(CYGWIN)
  49     set(LLVM_ON_WIN32 1)
  50     set(LLVM_ON_UNIX 0)
  51   endif(CYGWIN)
  52   set(LTDL_SHLIB_EXT ".dll")
  53   set(EXEEXT ".exe")
  54   # Maximum path length is 160 for non-unicode paths
  55   set(MAXPATHLEN 160)
  56 else(WIN32)
  57   if(UNIX)
  58     set(LLVM_ON_WIN32 0)
  59     set(LLVM_ON_UNIX 1)
  60     if(APPLE)
  61       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  62       set(LTDL_SHLIB_EXT ".dylib")
  63     else(APPLE)
  64       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
  65       set(LTDL_SHLIB_EXT ".so")
  66     endif(APPLE)
  67     set(EXEEXT "")
  68     # FIXME: Maximum path length is currently set to 'safe' fixed value
  69     set(MAXPATHLEN 2024)
  70   else(UNIX)
  71     MESSAGE(SEND_ERROR "Unable to determine platform")
  72   endif(UNIX)
  73 endif(WIN32)
  74
  75 function(add_flag_or_print_warning flag)
  76   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
  77   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
  78   if (C_SUPPORTS_FLAG AND CXX_SUPPORTS_FLAG)
  79     message(STATUS "Building with ${flag}")
  80     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
  81     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
  82   else()
  83     message(WARNING "${flag} is not supported.")
  84   endif()
  85 endfunction()
  86
  87 function(append value)
  88   foreach(variable ${ARGN})
  89     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
  90   endforeach(variable)
  91 endfunction()
  92
  93 function(append_if condition value)
  94   if (${condition})
  95     foreach(variable ${ARGN})
  96       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
  97     endforeach(variable)
  98   endif()
  99 endfunction()
 100
 101 macro(add_flag_if_supported flag)
 102   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
 103   append_if(C_SUPPORTS_FLAG "${flag}" CMAKE_C_FLAGS)
 104   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
 105   append_if(CXX_SUPPORTS_FLAG "${flag}" CMAKE_CXX_FLAGS)
 106 endmacro()
 107
 108 if( LLVM_ENABLE_PIC )
 109   if( XCODE )
 110     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 111     # know how to disable this, so just force ENABLE_PIC off for now.
 112     message(WARNING "-fPIC not supported with Xcode.")
 113   elseif( WIN32 OR CYGWIN)
 114     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 115   else()
 116     add_flag_or_print_warning("-fPIC")
 117
 118     if( WIN32 OR CYGWIN)
 119       # MinGW warns if -fvisibility-inlines-hidden is used.
 120     else()
 121       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 122       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 123     endif()
 124   endif()
 125 endif()
 126
 127 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 128   # TODO: support other platforms and toolchains.
 129   if( LLVM_BUILD_32_BITS )
 130     message(STATUS "Building 32 bits executables and libraries.")
 131     add_llvm_definitions( -m32 )
 132     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 133     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 134     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 135   endif( LLVM_BUILD_32_BITS )
 136 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 137
 138 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 139 # to use.
 140 if( MSVC_IDE )
 141   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 142     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 143   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 144     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 145       add_llvm_definitions( /MP )
 146     else()
 147       if (MSVC10)
 148         message(FATAL_ERROR
 149           "Due to a bug in CMake only 0 and 1 is supported for "
 150           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 151       else()
 152         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 153         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 154       endif()
 155     endif()
 156   else()
 157     message(STATUS "Parallel compilation disabled")
 158   endif()
 159 endif()
 160
 161 if( MSVC )
 162   include(ChooseMSVCCRT)
 163
 164   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 165     # set stack reserved size to ~10MB
 166     # CMake previously automatically set this value for MSVC builds, but the
 167     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 168     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 169     # C++ templates in Clang.
 170     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 171   endif()
 172
 173   if( MSVC10 )
 174     # MSVC 10 will complain about headers in the STL not being exported, but
 175     # will not complain in MSVC 11.
 176     add_llvm_definitions(
 177       -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 178     )
 179   elseif( MSVC11 )
 180     add_llvm_definitions(-D_VARIADIC_MAX=10)
 181   endif()
 182
 183   # Add definitions that make MSVC much less annoying.
 184   add_llvm_definitions(
 185     # For some reason MS wants to deprecate a bunch of standard functions...
 186     -D_CRT_SECURE_NO_DEPRECATE
 187     -D_CRT_SECURE_NO_WARNINGS
 188     -D_CRT_NONSTDC_NO_DEPRECATE
 189     -D_CRT_NONSTDC_NO_WARNINGS
 190     -D_SCL_SECURE_NO_DEPRECATE
 191     -D_SCL_SECURE_NO_WARNINGS
 192
 193     # Disabled warnings.
 194     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 195     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 196     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 197     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 198     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 199     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 200     -wd4355 # Suppress ''this' : used in base member initializer list'
 201     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 202     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 203     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 204     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 205
 206     # Promoted warnings.
 207     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 208
 209     # Promoted warnings to errors.
 210     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 211     )
 212
 213   # Enable warnings
 214   if (LLVM_ENABLE_WARNINGS)
 215     add_llvm_definitions( /W4 )
 216     if (LLVM_ENABLE_PEDANTIC)
 217       # No MSVC equivalent available
 218     endif (LLVM_ENABLE_PEDANTIC)
 219   endif (LLVM_ENABLE_WARNINGS)
 220   if (LLVM_ENABLE_WERROR)
 221     add_llvm_definitions( /WX )
 222   endif (LLVM_ENABLE_WERROR)
 223 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 224   if (LLVM_ENABLE_WARNINGS)
 225     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 226
 227     # Turn off missing field initializer warnings for gcc to avoid noise from
 228     # false positives with empty {}. Turn them on otherwise (they're off by
 229     # default for clang).
 230     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 231     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 232       if (CMAKE_COMPILER_IS_GNUCXX)
 233         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 234       else()
 235         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 236       endif()
 237     endif()
 238
 239     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 240     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 241     append_if(CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_CXX_FLAGS)
 242     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 243     append_if(C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_C_FLAGS)
 244     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 245     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 246     check_cxx_compiler_flag("-Werror -Wnon-virtual-dtor" CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG)
 247     append_if(CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 248   endif (LLVM_ENABLE_WARNINGS)
 249   if (LLVM_ENABLE_WERROR)
 250     add_llvm_definitions( -Werror )
 251   endif (LLVM_ENABLE_WERROR)
 252   if (LLVM_ENABLE_CXX11)
 253     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 254     append_if(CXX_SUPPORTS_CXX11 "-std=c++11" CMAKE_CXX_FLAGS)
 255   endif (LLVM_ENABLE_CXX11)
 256   if(LLVM_ENABLE_LIBCXX)
 257     check_cxx_compiler_flag("-stdlib=libc++" CXX_SUPPORTS_STDLIB)
 258     append_if(CXX_SUPPORTS_STDLIB "-stdlib=libc++" CMAKE_CXX_FLAGS)
 259     append_if(CXX_SUPPORTS_STDLIB "-stdlib=libc++" CMAKE_EXE_LINKER_FLAGS)
 260     append_if(CXX_SUPPORTS_STDLIB "-stdlib=libc++" CMAKE_SHARED_LINKER_FLAGS)
 261     append_if(CXX_SUPPORTS_STDLIB "-stdlib=libc++" CMAKE_MODULE_LINKER_FLAGS)
 262   endif ()
 263 endif( MSVC )
 264
 265 macro(append_common_sanitizer_flags)
 266   # Append -fno-omit-frame-pointer and turn on debug info to get better
 267   # stack traces.
 268   add_flag_if_supported("-fno-omit-frame-pointer")
 269   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 270       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 271     add_flag_if_supported("-gline-tables-only")
 272   endif()
 273   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 274   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 275     add_flag_if_supported("-O1")
 276   endif()
 277 endmacro()
 278
 279 # Turn on sanitizers if necessary.
 280 if(LLVM_USE_SANITIZER)
 281   if (LLVM_ON_UNIX)
 282     if (LLVM_USE_SANITIZER STREQUAL "Address")
 283       append_common_sanitizer_flags()
 284       add_flag_or_print_warning("-fsanitize=address")
 285     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 286       append_common_sanitizer_flags()
 287       add_flag_or_print_warning("-fsanitize=memory")
 288       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 289         add_flag_or_print_warning("-fsanitize-memory-track-origins")
 290       endif()
 291     else()
 292       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 293     endif()
 294   else()
 295     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 296   endif()
 297 endif()
 298
 299 # Turn on -gsplit-dwarf if requested
 300 if(LLVM_USE_SPLIT_DWARF)
 301   add_llvm_definitions("-gsplit-dwarf")
 302 endif()
 303
 304 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 305 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 306 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 307
 308 # clang doesn't print colored diagnostics when invoked from Ninja
 309 if (UNIX AND
 310     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 311     CMAKE_GENERATOR STREQUAL "Ninja")
 312   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 313 endif()