Raise the minimum CMake version to 2.8.8 -- we have a report that the
[oota-llvm.git] / cmake / modules / HandleLLVMOptions.cmake
1 # This CMake module is responsible for interpreting the user defined LLVM_
2 # options and executing the appropriate CMake commands to realize the users'
3 # selections.
4
5 include(AddLLVMDefinitions)
6 include(CheckCCompilerFlag)
7 include(CheckCXXCompilerFlag)
8
9 if( CMAKE_COMPILER_IS_GNUCXX )
10   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
11 elseif( MSVC )
12   set(LLVM_COMPILER_IS_GCC_COMPATIBLE OFF)
13 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
14   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
15 endif()
16
17 if( LLVM_ENABLE_ASSERTIONS )
18   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
19   if( NOT MSVC )
20     add_definitions( -D_DEBUG )
21   endif()
22   # On non-Debug builds cmake automatically defines NDEBUG, so we
23   # explicitly undefine it:
24   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
25     add_definitions( -UNDEBUG )
26     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
27     set(REGEXP_NDEBUG "(^| )[/-]D *NDEBUG($| )")
28     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
29       CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
30     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
31       CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO}")
32     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
33       CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL}")
34   endif()
35 else()
36   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
37     if( NOT MSVC_IDE AND NOT XCODE )
38       add_definitions( -DNDEBUG )
39     endif()
40   endif()
41 endif()
42
43 if(WIN32)
44   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
45   if(CYGWIN)
46     set(LLVM_ON_WIN32 0)
47     set(LLVM_ON_UNIX 1)
48   else(CYGWIN)
49     set(LLVM_ON_WIN32 1)
50     set(LLVM_ON_UNIX 0)
51   endif(CYGWIN)
52   # Maximum path length is 160 for non-unicode paths
53   set(MAXPATHLEN 160)
54 else(WIN32)
55   if(UNIX)
56     set(LLVM_ON_WIN32 0)
57     set(LLVM_ON_UNIX 1)
58     if(APPLE)
59       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
60     else(APPLE)
61       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
62     endif(APPLE)
63     # FIXME: Maximum path length is currently set to 'safe' fixed value
64     set(MAXPATHLEN 2024)
65   else(UNIX)
66     MESSAGE(SEND_ERROR "Unable to determine platform")
67   endif(UNIX)
68 endif(WIN32)
69
70 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
71 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
72 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_MODULE_SUFFIX})
73
74 function(add_flag_or_print_warning flag)
75   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
76   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
77   if (C_SUPPORTS_FLAG AND CXX_SUPPORTS_FLAG)
78     message(STATUS "Building with ${flag}")
79     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
80     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
81   else()
82     message(WARNING "${flag} is not supported.")
83   endif()
84 endfunction()
85
86 function(append value)
87   foreach(variable ${ARGN})
88     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
89   endforeach(variable)
90 endfunction()
91
92 function(append_if condition value)
93   if (${condition})
94     foreach(variable ${ARGN})
95       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
96     endforeach(variable)
97   endif()
98 endfunction()
99
100 macro(add_flag_if_supported flag)
101   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
102   append_if(C_SUPPORTS_FLAG "${flag}" CMAKE_C_FLAGS)
103   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
104   append_if(CXX_SUPPORTS_FLAG "${flag}" CMAKE_CXX_FLAGS)
105 endmacro()
106
107 if( LLVM_ENABLE_PIC )
108   if( XCODE )
109     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
110     # know how to disable this, so just force ENABLE_PIC off for now.
111     message(WARNING "-fPIC not supported with Xcode.")
112   elseif( WIN32 OR CYGWIN)
113     # On Windows all code is PIC. MinGW warns if -fPIC is used.
114   else()
115     add_flag_or_print_warning("-fPIC")
116
117     if( WIN32 OR CYGWIN)
118       # MinGW warns if -fvisibility-inlines-hidden is used.
119     else()
120       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
121       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
122     endif()
123   endif()
124 endif()
125
126 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
127   # TODO: support other platforms and toolchains.
128   if( LLVM_BUILD_32_BITS )
129     message(STATUS "Building 32 bits executables and libraries.")
130     add_llvm_definitions( -m32 )
131     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
132     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
133     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
134   endif( LLVM_BUILD_32_BITS )
135 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
136
137 # On Win32 using MS tools, provide an option to set the number of parallel jobs
138 # to use.
139 if( MSVC_IDE )
140   set(LLVM_COMPILER_JOBS "0" CACHE STRING
141     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
142   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
143     if( LLVM_COMPILER_JOBS STREQUAL "0" )
144       add_llvm_definitions( /MP )
145     else()
146       if (MSVC10)
147         message(FATAL_ERROR
148           "Due to a bug in CMake only 0 and 1 is supported for "
149           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
150       else()
151         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
152         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
153       endif()
154     endif()
155   else()
156     message(STATUS "Parallel compilation disabled")
157   endif()
158 endif()
159
160 if( MSVC )
161   include(ChooseMSVCCRT)
162
163   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
164     # set stack reserved size to ~10MB
165     # CMake previously automatically set this value for MSVC builds, but the
166     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
167     # value (1 MB) which is not enough for us in tasks such as parsing recursive
168     # C++ templates in Clang.
169     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
170   endif()
171
172   if( MSVC10 )
173     # MSVC 10 will complain about headers in the STL not being exported, but
174     # will not complain in MSVC 11.
175     add_llvm_definitions(
176       -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
177     )
178   elseif( MSVC11 )
179     add_llvm_definitions(-D_VARIADIC_MAX=10)
180   endif()
181   
182   # Add definitions that make MSVC much less annoying.
183   add_llvm_definitions(
184     # For some reason MS wants to deprecate a bunch of standard functions...
185     -D_CRT_SECURE_NO_DEPRECATE
186     -D_CRT_SECURE_NO_WARNINGS
187     -D_CRT_NONSTDC_NO_DEPRECATE
188     -D_CRT_NONSTDC_NO_WARNINGS
189     -D_SCL_SECURE_NO_DEPRECATE
190     -D_SCL_SECURE_NO_WARNINGS
191
192     # Disabled warnings.
193     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
194     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
195     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
196     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
197     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
198     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
199     -wd4355 # Suppress ''this' : used in base member initializer list'
200     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
201     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
202     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
203     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
204     
205     # Promoted warnings.
206     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
207
208     # Promoted warnings to errors.
209     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
210     )
211
212   # Enable warnings
213   if (LLVM_ENABLE_WARNINGS)
214     add_llvm_definitions( /W4 )
215     if (LLVM_ENABLE_PEDANTIC)
216       # No MSVC equivalent available
217     endif (LLVM_ENABLE_PEDANTIC)
218   endif (LLVM_ENABLE_WARNINGS)
219   if (LLVM_ENABLE_WERROR)
220     add_llvm_definitions( /WX )
221   endif (LLVM_ENABLE_WERROR)
222 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
223   if (LLVM_ENABLE_WARNINGS)
224     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
225
226     # Turn off missing field initializer warnings for gcc to avoid noise from
227     # false positives with empty {}. Turn them on otherwise (they're off by
228     # default for clang).
229     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
230     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
231       if (CMAKE_COMPILER_IS_GNUCXX)
232         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
233       else()
234         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
235       endif()
236     endif()
237
238     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
239     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
240     append_if(CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_CXX_FLAGS)
241     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
242     append_if(C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_C_FLAGS)
243     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
244     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
245     check_cxx_compiler_flag("-Werror -Wnon-virtual-dtor" CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG)
246     append_if(CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
247   endif (LLVM_ENABLE_WARNINGS)
248   if (LLVM_ENABLE_WERROR)
249     add_llvm_definitions( -Werror )
250   endif (LLVM_ENABLE_WERROR)
251   if (LLVM_ENABLE_CXX11)
252     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
253     append_if(CXX_SUPPORTS_CXX11 "-std=c++11" CMAKE_CXX_FLAGS)
254   endif (LLVM_ENABLE_CXX11)
255   if(LLVM_ENABLE_LIBCXX)
256     check_cxx_compiler_flag("-stdlib=libc++" CXX_SUPPORTS_STDLIB)
257     append_if(CXX_SUPPORTS_STDLIB "-stdlib=libc++" CMAKE_CXX_FLAGS)
258     append_if(CXX_SUPPORTS_STDLIB "-stdlib=libc++" CMAKE_EXE_LINKER_FLAGS)
259     append_if(CXX_SUPPORTS_STDLIB "-stdlib=libc++" CMAKE_SHARED_LINKER_FLAGS)
260     append_if(CXX_SUPPORTS_STDLIB "-stdlib=libc++" CMAKE_MODULE_LINKER_FLAGS)
261   endif ()
262 endif( MSVC )
263
264 macro(append_common_sanitizer_flags)
265   # Append -fno-omit-frame-pointer and turn on debug info to get better
266   # stack traces.
267   add_flag_if_supported("-fno-omit-frame-pointer")
268   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
269       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
270     add_flag_if_supported("-gline-tables-only")
271   endif()
272   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
273   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
274     add_flag_if_supported("-O1")
275   endif()
276 endmacro()
277
278 # Turn on sanitizers if necessary.
279 if(LLVM_USE_SANITIZER)
280   if (LLVM_ON_UNIX)
281     if (LLVM_USE_SANITIZER STREQUAL "Address")
282       append_common_sanitizer_flags()
283       add_flag_or_print_warning("-fsanitize=address")
284     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
285       append_common_sanitizer_flags()
286       add_flag_or_print_warning("-fsanitize=memory")
287       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
288         add_flag_or_print_warning("-fsanitize-memory-track-origins")
289       endif()
290     else()
291       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
292     endif()
293   else()
294     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
295   endif()
296 endif()
297
298 # Turn on -gsplit-dwarf if requested
299 if(LLVM_USE_SPLIT_DWARF)
300   add_llvm_definitions("-gsplit-dwarf")
301 endif()
302
303 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
304 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
305 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
306
307 # clang doesn't print colored diagnostics when invoked from Ninja
308 if (UNIX AND
309     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
310     CMAKE_GENERATOR STREQUAL "Ninja")
311   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
312 endif()