6c3109c4de76ff48fe8dbb823645402a78c2b324
[oota-llvm.git] / cmake / modules / HandleLLVMOptions.cmake
1 # This CMake module is responsible for interpreting the user defined LLVM_
2 # options and executing the appropriate CMake commands to realize the users'
3 # selections.
4
5 # This is commonly needed so make sure it's defined before we include anything
6 # else.
7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
8
9 include(HandleLLVMStdlib)
10 include(AddLLVMDefinitions)
11 include(CheckCCompilerFlag)
12 include(CheckCXXCompilerFlag)
13
14 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
15   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
16     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
17       message(FATAL_ERROR "Host GCC version must be at least 4.7!")
18     endif()
19   elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
20     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
21       message(FATAL_ERROR "Host Clang version must be at least 3.1!")
22     endif()
23
24     if (CMAKE_CXX_SIMULATE_ID MATCHES "MSVC")
25       if (CMAKE_CXX_SIMULATE_VERSION VERSION_LESS 18.0)
26         message(FATAL_ERROR "Host Clang must have at least -fms-compatibility-version=18.0")
27       endif()
28       set(CLANG_CL 1)
29     elseif(NOT LLVM_ENABLE_LIBCXX)
30       # Otherwise, test that we aren't using too old of a version of libstdc++
31       # with the Clang compiler. This is tricky as there is no real way to
32       # check the version of libstdc++ directly. Instead we test for a known
33       # bug in libstdc++4.6 that is fixed in libstdc++4.7.
34       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
35       set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
36       set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
37       check_cxx_source_compiles("
38 #include <atomic>
39 std::atomic<float> x(0.0f);
40 int main() { return (float)x; }"
41         LLVM_NO_OLD_LIBSTDCXX)
42       if(NOT LLVM_NO_OLD_LIBSTDCXX)
43         message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
44       endif()
45       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
46       set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
47     endif()
48   elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
49     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 18.0)
50       message(FATAL_ERROR "Host Visual Studio must be at least 2013")
51     elseif(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 18.0.31101)
52       message(WARNING "Host Visual Studio should at least be 2013 Update 4 (MSVC 18.0.31101)"
53         "  due to miscompiles from earlier versions")
54     endif()
55   endif()
56 endif()
57
58 if( LLVM_ENABLE_ASSERTIONS )
59   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
60   if( NOT MSVC )
61     add_definitions( -D_DEBUG )
62   endif()
63   # On non-Debug builds cmake automatically defines NDEBUG, so we
64   # explicitly undefine it:
65   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
66     add_definitions( -UNDEBUG )
67     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
68     foreach (flags_var_to_scrub
69         CMAKE_CXX_FLAGS_RELEASE
70         CMAKE_CXX_FLAGS_RELWITHDEBINFO
71         CMAKE_CXX_FLAGS_MINSIZEREL
72         CMAKE_C_FLAGS_RELEASE
73         CMAKE_C_FLAGS_RELWITHDEBINFO
74         CMAKE_C_FLAGS_MINSIZEREL)
75       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
76         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
77     endforeach()
78   endif()
79 endif()
80
81 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
82
83 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
84   if( LLVM_ENABLE_ASSERTIONS )
85     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
86   endif()
87 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
88   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
89 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
90   # We don't need to do anything special to turn off ABI breaking checks.
91 elseif( NOT DEFINED LLVM_ABI_BREAKING_CHECKS )
92   # Treat LLVM_ABI_BREAKING_CHECKS like "FORCE_OFF" when it has not been
93   # defined.
94 else()
95   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
96 endif()
97
98 if(WIN32)
99   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
100   if(CYGWIN)
101     set(LLVM_ON_WIN32 0)
102     set(LLVM_ON_UNIX 1)
103   else(CYGWIN)
104     set(LLVM_ON_WIN32 1)
105     set(LLVM_ON_UNIX 0)
106   endif(CYGWIN)
107 else(WIN32)
108   if(UNIX)
109     set(LLVM_ON_WIN32 0)
110     set(LLVM_ON_UNIX 1)
111     if(APPLE)
112       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
113     else(APPLE)
114       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
115     endif(APPLE)
116   else(UNIX)
117     MESSAGE(SEND_ERROR "Unable to determine platform")
118   endif(UNIX)
119 endif(WIN32)
120
121 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
122 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
123
124 # We use *.dylib rather than *.so on darwin.
125 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
126
127 if(APPLE)
128   # Darwin-specific linker flags for loadable modules.
129   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
130 endif()
131
132 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
133 # build might work on ELF but fail on MachO/COFF.
134 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32 OR CYGWIN OR
135         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD" OR
136         ${CMAKE_SYSTEM_NAME} MATCHES "OpenBSD") AND
137    NOT LLVM_USE_SANITIZER)
138   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
139 endif()
140
141
142 function(append value)
143   foreach(variable ${ARGN})
144     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
145   endforeach(variable)
146 endfunction()
147
148 function(append_if condition value)
149   if (${condition})
150     foreach(variable ${ARGN})
151       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
152     endforeach(variable)
153   endif()
154 endfunction()
155
156 macro(add_flag_if_supported flag name)
157   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
158   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
159   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
160   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
161 endmacro()
162
163 function(add_flag_or_print_warning flag name)
164   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
165   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
166   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
167     message(STATUS "Building with ${flag}")
168     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
169     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
170     set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} ${flag}" PARENT_SCOPE)
171   else()
172     message(WARNING "${flag} is not supported.")
173   endif()
174 endfunction()
175
176 if( LLVM_ENABLE_PIC )
177   if( XCODE )
178     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
179     # know how to disable this, so just force ENABLE_PIC off for now.
180     message(WARNING "-fPIC not supported with Xcode.")
181   elseif( WIN32 OR CYGWIN)
182     # On Windows all code is PIC. MinGW warns if -fPIC is used.
183   else()
184     add_flag_or_print_warning("-fPIC" FPIC)
185   endif()
186 endif()
187
188 if(NOT WIN32 AND NOT CYGWIN)
189   # MinGW warns if -fvisibility-inlines-hidden is used.
190   check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
191   append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
192 endif()
193
194 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
195   # TODO: support other platforms and toolchains.
196   if( LLVM_BUILD_32_BITS )
197     message(STATUS "Building 32 bits executables and libraries.")
198     add_llvm_definitions( -m32 )
199     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
200     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
201     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
202   endif( LLVM_BUILD_32_BITS )
203 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
204
205 if (LLVM_BUILD_STATIC)
206   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
207 endif()
208
209 if( XCODE )
210   # For Xcode enable several build settings that correspond to
211   # many warnings that are on by default in Clang but are
212   # not enabled for historical reasons.  For versions of Xcode
213   # that do not support these options they will simply
214   # be ignored.
215   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
216   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
217   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
218   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
219   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
220   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
221   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
222   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
223   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
224   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
225   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
226   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
227   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
228   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
229   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
230 endif()
231
232 # On Win32 using MS tools, provide an option to set the number of parallel jobs
233 # to use.
234 if( MSVC_IDE )
235   set(LLVM_COMPILER_JOBS "0" CACHE STRING
236     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
237   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
238     if( LLVM_COMPILER_JOBS STREQUAL "0" )
239       add_llvm_definitions( /MP )
240     else()
241       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
242       add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
243     endif()
244   else()
245     message(STATUS "Parallel compilation disabled")
246   endif()
247 endif()
248
249 if( MSVC )
250   if( CMAKE_CXX_COMPILER_VERSION VERSION_LESS 19.0 )
251     # For MSVC 2013, disable iterator null pointer checking in debug mode,
252     # especially so std::equal(nullptr, nullptr, nullptr) will not assert.
253     add_llvm_definitions("-D_DEBUG_POINTER_IMPL=")
254   endif()
255   
256   include(ChooseMSVCCRT)
257
258   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
259     # set stack reserved size to ~10MB
260     # CMake previously automatically set this value for MSVC builds, but the
261     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
262     # value (1 MB) which is not enough for us in tasks such as parsing recursive
263     # C++ templates in Clang.
264     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
265   endif()
266
267   if( MSVC11 )
268     add_llvm_definitions(-D_VARIADIC_MAX=10)
269   endif()
270   
271   # Add definitions that make MSVC much less annoying.
272   add_llvm_definitions(
273     # For some reason MS wants to deprecate a bunch of standard functions...
274     -D_CRT_SECURE_NO_DEPRECATE
275     -D_CRT_SECURE_NO_WARNINGS
276     -D_CRT_NONSTDC_NO_DEPRECATE
277     -D_CRT_NONSTDC_NO_WARNINGS
278     -D_SCL_SECURE_NO_DEPRECATE
279     -D_SCL_SECURE_NO_WARNINGS
280     )
281
282   set(msvc_warning_flags
283     # Disabled warnings.
284     -wd4141 # Suppress ''modifier' : used more than once' (because of __forceinline combined with inline)
285     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
286     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
287     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
288     -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
289     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
290     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
291     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
292     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
293     -wd4355 # Suppress ''this' : used in base member initializer list'
294     -wd4456 # Suppress 'declaration of 'var' hides local variable'
295     -wd4457 # Suppress 'declaration of 'var' hides function parameter'
296     -wd4458 # Suppress 'declaration of 'var' hides class member'
297     -wd4459 # Suppress 'declaration of 'var' hides global declaration'
298     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
299     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
300     -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
301     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
302     -wd4100 # Suppress 'unreferenced formal parameter'
303     -wd4127 # Suppress 'conditional expression is constant'
304     -wd4512 # Suppress 'assignment operator could not be generated'
305     -wd4505 # Suppress 'unreferenced local function has been removed'
306     -wd4610 # Suppress '<class> can never be instantiated'
307     -wd4510 # Suppress 'default constructor could not be generated'
308     -wd4702 # Suppress 'unreachable code'
309     -wd4245 # Suppress 'signed/unsigned mismatch'
310     -wd4706 # Suppress 'assignment within conditional expression'
311     -wd4310 # Suppress 'cast truncates constant value'
312     -wd4701 # Suppress 'potentially uninitialized local variable'
313     -wd4703 # Suppress 'potentially uninitialized local pointer variable'
314     -wd4389 # Suppress 'signed/unsigned mismatch'
315     -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
316     -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
317     -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
318     -wd4577 # Suppress 'noexcept used with no exception handling mode specified; termination on exception is not guaranteed'
319     -wd4091 # Suppress 'typedef: ignored on left of '' when no variable is declared'
320         # C4592 is disabled because of false positives in Visual Studio 2015
321         # Update 1. Re-evaluate the usefulness of this diagnostic with Update 2.
322     -wd4592 # Suppress ''var': symbol will be dynamically initialized (implementation limitation)
323
324         # Ideally, we'd like this warning to be enabled, but MSVC 2013 doesn't
325         # support the 'aligned' attribute in the way that clang sources requires (for
326         # any code that uses the LLVM_ALIGNAS macro), so this is must be disabled to
327         # avoid unwanted alignment warnings.
328         # When we switch to requiring a version of MSVC that supports the 'alignas'
329         # specifier (MSVC 2015?) this warning can be re-enabled.
330     -wd4324 # Suppress 'structure was padded due to __declspec(align())'
331             
332     # Promoted warnings.
333     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
334
335     # Promoted warnings to errors.
336     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
337     )
338
339   # Enable warnings
340   if (LLVM_ENABLE_WARNINGS)
341     append("/W4" msvc_warning_flags)
342     # CMake appends /W3 by default, and having /W3 followed by /W4 will result in 
343     # cl : Command line warning D9025 : overriding '/W3' with '/W4'.  Since this is
344     # a command line warning and not a compiler warning, it cannot be suppressed except
345     # by fixing the command line.
346     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
347     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
348
349     if (LLVM_ENABLE_PEDANTIC)
350       # No MSVC equivalent available
351     endif (LLVM_ENABLE_PEDANTIC)
352   endif (LLVM_ENABLE_WARNINGS)
353   if (LLVM_ENABLE_WERROR)
354     append("/WX" msvc_warning_flags)
355   endif (LLVM_ENABLE_WERROR)
356
357   foreach(flag ${msvc_warning_flags})
358     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
359   endforeach(flag)
360
361   append("/Zc:inline" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
362
363   # Disable sized deallocation if the flag is supported. MSVC fails to compile
364   # the operator new overload in User otherwise.
365   check_c_compiler_flag("/WX /Zc:sizedDealloc-" SUPPORTS_SIZED_DEALLOC)
366   append_if(SUPPORTS_SIZED_DEALLOC "/Zc:sizedDealloc-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
367
368 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
369   if (LLVM_ENABLE_WARNINGS)
370     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
371     append("-Wcast-qual" CMAKE_CXX_FLAGS)
372
373     # Turn off missing field initializer warnings for gcc to avoid noise from
374     # false positives with empty {}. Turn them on otherwise (they're off by
375     # default for clang).
376     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
377     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
378       if (CMAKE_COMPILER_IS_GNUCXX)
379         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
380       else()
381         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
382       endif()
383     endif()
384
385     append_if(LLVM_ENABLE_PEDANTIC "-pedantic" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
386     append_if(LLVM_ENABLE_PEDANTIC "-Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
387     add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
388     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
389     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
390
391     # Check if -Wnon-virtual-dtor warns even though the class is marked final.
392     # If it does, don't add it. So it won't be added on clang 3.4 and older.
393     # This also catches cases when -Wnon-virtual-dtor isn't supported by
394     # the compiler at all.
395     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
396     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
397     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
398                                class derived final : public base { public: ~derived();};
399                                int main() { return 0; }"
400                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
401     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
402     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
403               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
404
405     # Check if -Wcomment is OK with an // comment ending with '\' if the next
406     # line is also a // comment.
407     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
408     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
409     CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
410                             C_WCOMMENT_ALLOWS_LINE_WRAP)
411     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
412     if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
413       append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
414     endif()
415   endif (LLVM_ENABLE_WARNINGS)
416   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
417   if (NOT LLVM_ENABLE_TIMESTAMPS)
418     add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
419   endif ()
420   if (LLVM_ENABLE_CXX1Y)
421     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
422     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
423   else()
424     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
425     if (CXX_SUPPORTS_CXX11)
426       if (CYGWIN OR MINGW)
427         # MinGW and Cygwin are a bit stricter and lack things like
428         # 'strdup', 'stricmp', etc in c++11 mode.
429         append("-std=gnu++11" CMAKE_CXX_FLAGS)
430       else()
431         append("-std=c++11" CMAKE_CXX_FLAGS)
432       endif()
433     else()
434       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
435     endif()
436   endif()
437   if (LLVM_ENABLE_MODULES)
438     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
439     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fmodules")
440     # Check that we can build code with modules enabled, and that repeatedly
441     # including <cassert> still manages to respect NDEBUG properly.
442     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
443                                #include <cassert>
444                                #define NDEBUG
445                                #include <cassert>
446                                int main() { assert(this code is not compiled); }"
447                                CXX_SUPPORTS_MODULES)
448     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
449     if (CXX_SUPPORTS_MODULES)
450       append_if(CXX_SUPPORTS_MODULES "-fmodules" CMAKE_C_FLAGS)
451       append_if(CXX_SUPPORTS_MODULES "-fmodules -fcxx-modules" CMAKE_CXX_FLAGS)
452     else()
453       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
454     endif()
455   endif(LLVM_ENABLE_MODULES)
456 endif( MSVC )
457
458 macro(append_common_sanitizer_flags)
459   if (NOT MSVC)
460     # Append -fno-omit-frame-pointer and turn on debug info to get better
461     # stack traces.
462     add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
463     if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
464         NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
465       add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
466     endif()
467     # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
468     if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
469       add_flag_if_supported("-O1" O1)
470     endif()
471   elseif (CLANG_CL)
472     # Keep frame pointers around.
473     append("/Oy-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
474     if (CMAKE_LINKER MATCHES "lld-link.exe")
475       # Use DWARF debug info with LLD.
476       append("-gdwarf" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
477       # Pass /MANIFEST:NO so that CMake doesn't run mt.exe on our binaries.
478       # Adding manifests with mt.exe breaks LLD's symbol tables. See PR24476.
479       append("/MANIFEST:NO"
480         CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
481     else()
482       # Enable codeview otherwise.
483       append("/Z7" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
484     endif()
485     # Always ask the linker to produce symbols with asan.
486     append("-debug" CMAKE_EXE_LINKER_FLAGS CMAKE_MODULE_LINKER_FLAGS CMAKE_SHARED_LINKER_FLAGS)
487   endif()
488 endmacro()
489
490 # Turn on sanitizers if necessary.
491 if(LLVM_USE_SANITIZER)
492   if (LLVM_ON_UNIX)
493     if (LLVM_USE_SANITIZER STREQUAL "Address")
494       append_common_sanitizer_flags()
495       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
496     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
497       append_common_sanitizer_flags()
498       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
499       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
500         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
501       endif()
502     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
503       append_common_sanitizer_flags()
504       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
505               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
506     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
507       append_common_sanitizer_flags()
508       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
509     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
510             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
511       append_common_sanitizer_flags()
512       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
513               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
514     else()
515       message(FATAL_ERROR "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
516     endif()
517   elseif(MSVC)
518     if (LLVM_USE_SANITIZER STREQUAL "Address")
519       append_common_sanitizer_flags()
520       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
521     else()
522       message(FATAL_ERROR "This sanitizer not yet supported in the MSVC environment: ${LLVM_USE_SANITIZER}")
523     endif()
524   else()
525     message(FATAL_ERROR "LLVM_USE_SANITIZER is not supported on this platform.")
526   endif()
527   if (LLVM_USE_SANITIZE_COVERAGE)
528     append("-fsanitize-coverage=edge,indirect-calls,8bit-counters,trace-cmp" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
529   endif()
530 endif()
531
532 # Turn on -gsplit-dwarf if requested
533 if(LLVM_USE_SPLIT_DWARF)
534   add_definitions("-gsplit-dwarf")
535 endif()
536
537 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
538 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
539 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
540
541 # clang doesn't print colored diagnostics when invoked from Ninja
542 if (UNIX AND
543     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
544     CMAKE_GENERATOR STREQUAL "Ninja")
545   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
546 endif()
547
548 # Add flags for add_dead_strip().
549 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
550 # But MinSizeRel seems to add that automatically, so maybe disable these
551 # flags instead if LLVM_NO_DEAD_STRIP is set.
552 if(NOT CYGWIN AND NOT WIN32)
553   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND
554      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
555     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
556     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
557       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
558       # Doing so will break sanitizers.
559       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
560     endif()
561     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
562   endif()
563 endif()
564
565 if(CYGWIN OR MINGW)
566   # Prune --out-implib from executables. It doesn't make sense even
567   # with --export-all-symbols.
568   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
569     CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
570   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
571     CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
572 endif()
573
574 if(MSVC)
575   # Remove flags here, for exceptions and RTTI.
576   # Each target property or source property should be responsible to control
577   # them.
578   # CL.EXE complains to override flags like "/GR /GR-".
579   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
580   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
581 endif()
582
583 # Provide public options to globally control RTTI and EH
584 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
585 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
586 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
587   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
588 endif()
589
590 # Plugin support
591 # FIXME: Make this configurable.
592 if(WIN32 OR CYGWIN)
593   if(BUILD_SHARED_LIBS)
594     set(LLVM_ENABLE_PLUGINS ON)
595   else()
596     set(LLVM_ENABLE_PLUGINS OFF)
597   endif()
598 else()
599   set(LLVM_ENABLE_PLUGINS ON)
600 endif()