cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(HandleLLVMStdlib)
  10 include(AddLLVMDefinitions)
  11 include(CheckCCompilerFlag)
  12 include(CheckCXXCompilerFlag)
  13
  14 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
  15   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  16     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
  17       message(FATAL_ERROR "Host GCC version must be at least 4.7!")
  18     endif()
  19   elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  20     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
  21       message(FATAL_ERROR "Host Clang version must be at least 3.1!")
  22     endif()
  23
  24     if (CMAKE_CXX_SIMULATE_ID MATCHES "MSVC")
  25       if (CMAKE_CXX_SIMULATE_VERSION VERSION_LESS 18.0)
  26         message(FATAL_ERROR "Host Clang must have at least -fms-compatibility-version=18.0")
  27       endif()
  28       set(CLANG_CL 1)
  29     elseif(NOT LLVM_ENABLE_LIBCXX)
  30       # Otherwise, test that we aren't using too old of a version of libstdc++
  31       # with the Clang compiler. This is tricky as there is no real way to
  32       # check the version of libstdc++ directly. Instead we test for a known
  33       # bug in libstdc++4.6 that is fixed in libstdc++4.7.
  34       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  35       set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  36       set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
  37       check_cxx_source_compiles("
  38 #include <atomic>
  39 std::atomic<float> x(0.0f);
  40 int main() { return (float)x; }"
  41         LLVM_NO_OLD_LIBSTDCXX)
  42       if(NOT LLVM_NO_OLD_LIBSTDCXX)
  43         message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
  44       endif()
  45       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
  46       set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
  47     endif()
  48   elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  49     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 18.0)
  50       message(FATAL_ERROR "Host Visual Studio must be at least 2013")
  51     elseif(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 18.0.31101)
  52       message(WARNING "Host Visual Studio should at least be 2013 Update 4 (MSVC 18.0.31101)"
  53         "  due to miscompiles from earlier versions")
  54     endif()
  55   endif()
  56 endif()
  57
  58 if( LLVM_ENABLE_ASSERTIONS )
  59   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  60   if( NOT MSVC )
  61     add_definitions( -D_DEBUG )
  62   endif()
  63   # On non-Debug builds cmake automatically defines NDEBUG, so we
  64   # explicitly undefine it:
  65   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  66     add_definitions( -UNDEBUG )
  67     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  68     foreach (flags_var_to_scrub
  69         CMAKE_CXX_FLAGS_RELEASE
  70         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  71         CMAKE_CXX_FLAGS_MINSIZEREL
  72         CMAKE_C_FLAGS_RELEASE
  73         CMAKE_C_FLAGS_RELWITHDEBINFO
  74         CMAKE_C_FLAGS_MINSIZEREL)
  75       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  76         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  77     endforeach()
  78   endif()
  79 endif()
  80
  81 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
  82
  83 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
  84   if( LLVM_ENABLE_ASSERTIONS )
  85     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  86   endif()
  87 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
  88   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  89 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
  90   # We don't need to do anything special to turn off ABI breaking checks.
  91 else()
  92   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
  93 endif()
  94
  95 if(WIN32)
  96   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  97   if(CYGWIN)
  98     set(LLVM_ON_WIN32 0)
  99     set(LLVM_ON_UNIX 1)
 100   else(CYGWIN)
 101     set(LLVM_ON_WIN32 1)
 102     set(LLVM_ON_UNIX 0)
 103   endif(CYGWIN)
 104 else(WIN32)
 105   if(UNIX)
 106     set(LLVM_ON_WIN32 0)
 107     set(LLVM_ON_UNIX 1)
 108     if(APPLE)
 109       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 110     else(APPLE)
 111       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
 112     endif(APPLE)
 113   else(UNIX)
 114     MESSAGE(SEND_ERROR "Unable to determine platform")
 115   endif(UNIX)
 116 endif(WIN32)
 117
 118 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 119 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 120
 121 # We use *.dylib rather than *.so on darwin.
 122 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 123
 124 if(APPLE)
 125   # Darwin-specific linker flags for loadable modules.
 126   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 127 endif()
 128
 129 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 130 # build might work on ELF but fail on MachO/COFF.
 131 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32 OR
 132         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD") AND
 133    NOT LLVM_USE_SANITIZER)
 134   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 135 endif()
 136
 137
 138 function(append value)
 139   foreach(variable ${ARGN})
 140     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 141   endforeach(variable)
 142 endfunction()
 143
 144 function(append_if condition value)
 145   if (${condition})
 146     foreach(variable ${ARGN})
 147       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 148     endforeach(variable)
 149   endif()
 150 endfunction()
 151
 152 macro(add_flag_if_supported flag name)
 153   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 154   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 155   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 156   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 157 endmacro()
 158
 159 function(add_flag_or_print_warning flag name)
 160   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 161   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 162   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 163     message(STATUS "Building with ${flag}")
 164     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 165     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 166   else()
 167     message(WARNING "${flag} is not supported.")
 168   endif()
 169 endfunction()
 170
 171 if( LLVM_ENABLE_PIC )
 172   if( XCODE )
 173     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 174     # know how to disable this, so just force ENABLE_PIC off for now.
 175     message(WARNING "-fPIC not supported with Xcode.")
 176   elseif( WIN32 OR CYGWIN)
 177     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 178   else()
 179     add_flag_or_print_warning("-fPIC" FPIC)
 180
 181     if( WIN32 OR CYGWIN)
 182       # MinGW warns if -fvisibility-inlines-hidden is used.
 183     else()
 184       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 185       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 186     endif()
 187   endif()
 188 endif()
 189
 190 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 191   # TODO: support other platforms and toolchains.
 192   if( LLVM_BUILD_32_BITS )
 193     message(STATUS "Building 32 bits executables and libraries.")
 194     add_llvm_definitions( -m32 )
 195     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 196     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 197     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 198   endif( LLVM_BUILD_32_BITS )
 199 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 200
 201 if (LLVM_BUILD_STATIC)
 202   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 203 endif()
 204
 205 if( XCODE )
 206   # For Xcode enable several build settings that correspond to
 207   # many warnings that are on by default in Clang but are
 208   # not enabled for historical reasons.  For versions of Xcode
 209   # that do not support these options they will simply
 210   # be ignored.
 211   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 212   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 213   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 214   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 215   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 216   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 217   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 218   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 219   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 220   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 221   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 222   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 223   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 224   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 225   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 226 endif()
 227
 228 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 229 # to use.
 230 if( MSVC_IDE )
 231   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 232     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 233   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 234     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 235       add_llvm_definitions( /MP )
 236     else()
 237       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 238       add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 239     endif()
 240   else()
 241     message(STATUS "Parallel compilation disabled")
 242   endif()
 243 endif()
 244
 245 if( MSVC )
 246   include(ChooseMSVCCRT)
 247
 248   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 249     # set stack reserved size to ~10MB
 250     # CMake previously automatically set this value for MSVC builds, but the
 251     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 252     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 253     # C++ templates in Clang.
 254     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 255   endif()
 256
 257   if( MSVC11 )
 258     add_llvm_definitions(-D_VARIADIC_MAX=10)
 259   endif()
 260
 261   # Add definitions that make MSVC much less annoying.
 262   add_llvm_definitions(
 263     # For some reason MS wants to deprecate a bunch of standard functions...
 264     -D_CRT_SECURE_NO_DEPRECATE
 265     -D_CRT_SECURE_NO_WARNINGS
 266     -D_CRT_NONSTDC_NO_DEPRECATE
 267     -D_CRT_NONSTDC_NO_WARNINGS
 268     -D_SCL_SECURE_NO_DEPRECATE
 269     -D_SCL_SECURE_NO_WARNINGS
 270     )
 271
 272   set(msvc_warning_flags
 273     # Disabled warnings.
 274     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 275     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 276     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 277     -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 278     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 279     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 280     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 281     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 282     -wd4355 # Suppress ''this' : used in base member initializer list'
 283     -wd4456 # Suppress 'declaration of 'var' hides local variable'
 284     -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 285     -wd4458 # Suppress 'declaration of 'var' hides class member'
 286     -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 287     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 288     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 289     -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 290     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 291     -wd4100 # Suppress 'unreferenced formal parameter'
 292     -wd4127 # Suppress 'conditional expression is constant'
 293     -wd4512 # Suppress 'assignment operator could not be generated'
 294     -wd4505 # Suppress 'unreferenced local function has been removed'
 295     -wd4610 # Suppress '<class> can never be instantiated'
 296     -wd4510 # Suppress 'default constructor could not be generated'
 297     -wd4702 # Suppress 'unreachable code'
 298     -wd4245 # Suppress 'signed/unsigned mismatch'
 299     -wd4706 # Suppress 'assignment within conditional expression'
 300     -wd4310 # Suppress 'cast truncates constant value'
 301     -wd4701 # Suppress 'potentially uninitialized local variable'
 302     -wd4703 # Suppress 'potentially uninitialized local pointer variable'
 303     -wd4389 # Suppress 'signed/unsigned mismatch'
 304     -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
 305     -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
 306     -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
 307
 308     # Promoted warnings.
 309     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 310
 311     # Promoted warnings to errors.
 312     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 313     )
 314
 315   # Enable warnings
 316   if (LLVM_ENABLE_WARNINGS)
 317     append("/W4" msvc_warning_flags)
 318     if (LLVM_ENABLE_PEDANTIC)
 319       # No MSVC equivalent available
 320     endif (LLVM_ENABLE_PEDANTIC)
 321   endif (LLVM_ENABLE_WARNINGS)
 322   if (LLVM_ENABLE_WERROR)
 323     append("/WX" msvc_warning_flags)
 324   endif (LLVM_ENABLE_WERROR)
 325
 326   foreach(flag ${msvc_warning_flags})
 327     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 328   endforeach(flag)
 329
 330 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 331   if (LLVM_ENABLE_WARNINGS)
 332     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 333     append("-Wcast-qual" CMAKE_CXX_FLAGS)
 334
 335     # Turn off missing field initializer warnings for gcc to avoid noise from
 336     # false positives with empty {}. Turn them on otherwise (they're off by
 337     # default for clang).
 338     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 339     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 340       if (CMAKE_COMPILER_IS_GNUCXX)
 341         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 342       else()
 343         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 344       endif()
 345     endif()
 346
 347     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 348     add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 349     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 350     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 351
 352     # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 353     # If it does, don't add it. So it won't be added on clang 3.4 and older.
 354     # This also catches cases when -Wnon-virtual-dtor isn't supported by
 355     # the compiler at all.
 356     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 357     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 358     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 359                                class derived final : public base { public: ~derived();};
 360                                int main() { return 0; }"
 361                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 362     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 363     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 364               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 365
 366     # Check if -Wcomment is OK with an // comment ending with '\' if the next
 367     # line is also a // comment.
 368     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 369     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 370     CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 371                             C_WCOMMENT_ALLOWS_LINE_WRAP)
 372     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 373     if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 374       append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 375     endif()
 376   endif (LLVM_ENABLE_WARNINGS)
 377   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 378   if (NOT LLVM_ENABLE_TIMESTAMPS)
 379     add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 380   endif ()
 381   if (LLVM_ENABLE_CXX1Y)
 382     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 383     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 384   else()
 385     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 386     if (CXX_SUPPORTS_CXX11)
 387       if (CYGWIN OR MINGW)
 388         # MinGW and Cygwin are a bit stricter and lack things like
 389         # 'strdup', 'stricmp', etc in c++11 mode.
 390         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 391       else()
 392         append("-std=c++11" CMAKE_CXX_FLAGS)
 393       endif()
 394     else()
 395       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 396     endif()
 397   endif()
 398   if (LLVM_ENABLE_MODULES)
 399     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 400     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fmodules -fcxx-modules")
 401     # Check that we can build code with modules enabled, and that repeatedly
 402     # including <cassert> still manages to respect NDEBUG properly.
 403     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 404                                #include <cassert>
 405                                #define NDEBUG
 406                                #include <cassert>
 407                                int main() { assert(this code is not compiled); }"
 408                                CXX_SUPPORTS_MODULES)
 409     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 410     if (CXX_SUPPORTS_MODULES)
 411       append_if(CXX_SUPPORTS_MODULES "-fmodules" CMAKE_C_FLAGS)
 412       append_if(CXX_SUPPORTS_MODULES "-fmodules -fcxx-modules" CMAKE_CXX_FLAGS)
 413     else()
 414       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 415     endif()
 416   endif(LLVM_ENABLE_MODULES)
 417 endif( MSVC )
 418
 419 macro(append_common_sanitizer_flags)
 420   # Append -fno-omit-frame-pointer and turn on debug info to get better
 421   # stack traces.
 422   add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 423   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 424       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 425     add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 426   endif()
 427   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 428   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 429     add_flag_if_supported("-O1" O1)
 430   endif()
 431 endmacro()
 432
 433 # Turn on sanitizers if necessary.
 434 if(LLVM_USE_SANITIZER)
 435   if (LLVM_ON_UNIX)
 436     if (LLVM_USE_SANITIZER STREQUAL "Address")
 437       append_common_sanitizer_flags()
 438       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 439     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 440       append_common_sanitizer_flags()
 441       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 442       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 443         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 444       endif()
 445     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 446       append_common_sanitizer_flags()
 447       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover"
 448               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 449     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 450       append_common_sanitizer_flags()
 451       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 452     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
 453             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
 454       append_common_sanitizer_flags()
 455       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover"
 456               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 457     else()
 458       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 459     endif()
 460   else()
 461     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 462   endif()
 463   if (LLVM_USE_SANITIZE_COVERAGE)
 464     append("-fsanitize-coverage=4 -mllvm -sanitizer-coverage-8bit-counters=1" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 465   endif()
 466 endif()
 467
 468 # Turn on -gsplit-dwarf if requested
 469 if(LLVM_USE_SPLIT_DWARF)
 470   add_definitions("-gsplit-dwarf")
 471 endif()
 472
 473 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 474 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 475 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 476
 477 # clang doesn't print colored diagnostics when invoked from Ninja
 478 if (UNIX AND
 479     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 480     CMAKE_GENERATOR STREQUAL "Ninja")
 481   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 482 endif()
 483
 484 # Add flags for add_dead_strip().
 485 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 486 # But MinSizeRel seems to add that automatically, so maybe disable these
 487 # flags instead if LLVM_NO_DEAD_STRIP is set.
 488 if(NOT CYGWIN AND NOT WIN32)
 489   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 490     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 491     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 492       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 493       # Doing so will break sanitizers.
 494       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 495     endif()
 496     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 497   endif()
 498 endif()
 499
 500 if(CYGWIN OR MINGW)
 501   # Prune --out-implib from executables. It doesn't make sense even
 502   # with --export-all-symbols.
 503   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 504     CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
 505   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 506     CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
 507 endif()
 508
 509 if(MSVC)
 510   # Remove flags here, for exceptions and RTTI.
 511   # Each target property or source property should be responsible to control
 512   # them.
 513   # CL.EXE complains to override flags like "/GR /GR-".
 514   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 515   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 516 endif()
 517
 518 # Provide public options to globally control RTTI and EH
 519 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 520 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 521 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 522   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 523 endif()
 524
 525 # Plugin support
 526 # FIXME: Make this configurable.
 527 if(WIN32 OR CYGWIN)
 528   if(BUILD_SHARED_LIBS)
 529     set(LLVM_ENABLE_PLUGINS ON)
 530   else()
 531     set(LLVM_ENABLE_PLUGINS OFF)
 532   endif()
 533 else()
 534   set(LLVM_ENABLE_PLUGINS ON)
 535 endif()