cmake/modules/CrossCompile.cmake

   1 function(llvm_create_cross_target_internal target_name toochain buildtype)
   2
   3   if(NOT DEFINED LLVM_${target_name}_BUILD)
   4     set(LLVM_${target_name}_BUILD "${CMAKE_BINARY_DIR}/${target_name}")
   5     set(LLVM_${target_name}_BUILD ${LLVM_${target_name}_BUILD} PARENT_SCOPE)
   6     message(STATUS "Setting native build dir to " ${LLVM_${target_name}_BUILD})
   7   endif(NOT DEFINED LLVM_${target_name}_BUILD)
   8
   9   if (EXISTS ${LLVM_MAIN_SRC_DIR}/cmake/platforms/${toolchain}.cmake)
  10     set(CROSS_TOOLCHAIN_FLAGS_${target_name}
  11         -DCMAKE_TOOLCHAIN_FILE=\"${LLVM_MAIN_SRC_DIR}/cmake/platforms/${toolchain}.cmake\"
  12         CACHE STRING "Toolchain file for ${target_name}")
  13   endif()
  14
  15   add_custom_command(OUTPUT ${LLVM_${target_name}_BUILD}
  16     COMMAND ${CMAKE_COMMAND} -E make_directory ${LLVM_${target_name}_BUILD}
  17     COMMENT "Creating ${LLVM_${target_name}_BUILD}...")
  18
  19   add_custom_command(OUTPUT ${LLVM_${target_name}_BUILD}/CMakeCache.txt
  20     COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}"
  21         ${CROSS_TOOLCHAIN_FLAGS_${target_name}} ${CMAKE_SOURCE_DIR}
  22     WORKING_DIRECTORY ${LLVM_${target_name}_BUILD}
  23     DEPENDS ${LLVM_${target_name}_BUILD}
  24     COMMENT "Configuring ${target_name} LLVM...")
  25
  26   add_custom_target(CONFIGURE_LLVM_${target_name}
  27                     DEPENDS ${LLVM_${target_name}_BUILD}/CMakeCache.txt)
  28
  29   set_directory_properties(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES
  30                                       ${LLVM_${target_name}_BUILD})
  31
  32   if(NOT IS_DIRECTORY ${LLVM_${target_name}_BUILD})
  33
  34
  35     message(STATUS "Configuring ${target_name} build...")
  36     execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory
  37       ${LLVM_${target_name}_BUILD} )
  38
  39     message(STATUS "Configuring ${target_name} targets...")
  40     if (buildtype)
  41       set(build_type_flags "-DCMAKE_BUILD_TYPE=${buildtype}")
  42     endif()
  43     execute_process(COMMAND ${CMAKE_COMMAND} ${build_type_flags}
  44         -G "${CMAKE_GENERATOR}" -DLLVM_TARGETS_TO_BUILD=${LLVM_TARGETS_TO_BUILD}
  45         ${CROSS_TOOLCHAIN_FLAGS_${target_name}} ${CMAKE_SOURCE_DIR}
  46       WORKING_DIRECTORY ${LLVM_${target_name}_BUILD} )
  47   endif(NOT IS_DIRECTORY ${LLVM_${target_name}_BUILD})
  48
  49 endfunction()
  50
  51 function(llvm_create_cross_target target_name sysroot)
  52   llvm_create_cross_target_internal(${target_name} ${sysroot} ${CMAKE_BUILD_TYPE})
  53 endfunction()
  54
  55 llvm_create_cross_target_internal(NATIVE "" Release)