cmake/modules/CMakeLists.txt

   1 set(LLVM_INSTALL_PACKAGE_DIR share/llvm/cmake)
   2 set(llvm_cmake_builddir "${LLVM_BINARY_DIR}/${LLVM_INSTALL_PACKAGE_DIR}")
   3
   4 get_property(LLVM_EXPORTS GLOBAL PROPERTY LLVM_EXPORTS)
   5 export(TARGETS ${LLVM_EXPORTS}
   6   FILE ${llvm_cmake_builddir}/LLVMExports.cmake)
   7
   8 get_property(llvm_libs GLOBAL PROPERTY LLVM_LIBS)
   9
  10 foreach(lib ${llvm_libs})
  11   get_property(llvm_lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${lib})
  12   set(all_llvm_lib_deps
  13     "${all_llvm_lib_deps}\nset_property(GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${lib} ${llvm_lib_deps})")
  14 endforeach(lib)
  15
  16 # Generate LLVMConfig.cmake for the build tree.
  17 set(LLVM_CONFIG_CODE "
  18 # LLVM_BUILD_* values available only from LLVM build tree.
  19 set(LLVM_BUILD_BINARY_DIR \"${LLVM_BINARY_DIR}\")
  20 set(LLVM_BUILD_ENABLE_ASSERTIONS \"${LLVM_ENABLE_ASSERTIONS}\")
  21 set(LLVM_BUILD_LIBRARY_DIR \"${LLVM_LIBRARY_DIR}\")
  22 set(LLVM_BUILD_MAIN_INCLUDE_DIR \"${LLVM_MAIN_INCLUDE_DIR}\")
  23 set(LLVM_BUILD_MAIN_SRC_DIR \"${LLVM_MAIN_SRC_DIR}\")
  24 set(LLVM_BUILD_TOOLS_BINARY_DIR \"${LLVM_TOOLS_BINARY_DIR}\")
  25 ")
  26 set(LLVM_CONFIG_INCLUDE_DIRS
  27   "${LLVM_MAIN_INCLUDE_DIR}"
  28   "${LLVM_INCLUDE_DIR}"
  29   )
  30 set(LLVM_CONFIG_LIBRARY_DIRS
  31   "${LLVM_LIBRARY_DIR}"
  32   )
  33 set(LLVM_CONFIG_CMAKE_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
  34 configure_file(
  35   LLVMConfig.cmake.in
  36   ${llvm_cmake_builddir}/LLVMConfig.cmake
  37   @ONLY)
  38
  39 # For compatibility with projects that include(LLVMConfig)
  40 # via CMAKE_MODULE_PATH, place API modules next to it.
  41 # This should be removed in the future.
  42 file(COPY .
  43   DESTINATION ${llvm_cmake_builddir}
  44   FILES_MATCHING PATTERN *.cmake
  45   PATTERN .svn EXCLUDE
  46   PATTERN CMakeFiles EXCLUDE
  47   )
  48
  49 # Generate LLVMConfig.cmake for the install tree.
  50 set(LLVM_CONFIG_CODE "
  51 # Compute the installation prefix from this LLVMConfig.cmake file location.
  52 get_filename_component(LLVM_INSTALL_PREFIX \"\${CMAKE_CURRENT_LIST_FILE}\" PATH)")
  53 # Construct the proper number of get_filename_component(... PATH)
  54 # calls to compute the installation prefix.
  55 string(REGEX REPLACE "/" ";" _count "${LLVM_INSTALL_PACKAGE_DIR}")
  56 foreach(p ${_count})
  57   set(LLVM_CONFIG_CODE "${LLVM_CONFIG_CODE}
  58 get_filename_component(LLVM_INSTALL_PREFIX \"\${LLVM_INSTALL_PREFIX}\" PATH)")
  59 endforeach(p)
  60 set(LLVM_CONFIG_INCLUDE_DIRS "\${LLVM_INSTALL_PREFIX}/include")
  61 set(LLVM_CONFIG_LIBRARY_DIRS "\${LLVM_INSTALL_PREFIX}/lib")
  62 set(LLVM_CONFIG_CMAKE_DIR "\${LLVM_INSTALL_PREFIX}/${LLVM_INSTALL_PACKAGE_DIR}")
  63 configure_file(
  64   LLVMConfig.cmake.in
  65   ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/LLVMConfig.cmake
  66   @ONLY)
  67
  68 # Generate LLVMConfigVersion.cmake for build and install tree.
  69 configure_file(
  70   LLVMConfigVersion.cmake.in
  71   ${llvm_cmake_builddir}/LLVMConfigVersion.cmake
  72   @ONLY)
  73
  74 install(EXPORT LLVMExports DESTINATION ${LLVM_INSTALL_PACKAGE_DIR})
  75
  76 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
  77   install(FILES
  78     ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/LLVMConfig.cmake
  79     ${llvm_cmake_builddir}/LLVMConfigVersion.cmake
  80     LLVM-Config.cmake
  81     DESTINATION ${LLVM_INSTALL_PACKAGE_DIR})
  82
  83   install(DIRECTORY .
  84     DESTINATION ${LLVM_INSTALL_PACKAGE_DIR}
  85     FILES_MATCHING PATTERN *.cmake
  86     PATTERN .svn EXCLUDE
  87     PATTERN LLVMConfig.cmake EXCLUDE
  88     PATTERN LLVMConfigVersion.cmake EXCLUDE
  89     PATTERN LLVM-Config.cmake EXCLUDE
  90     PATTERN GetHostTriple.cmake EXCLUDE
  91     PATTERN VersionFromVCS.cmake EXCLUDE
  92     PATTERN CheckAtomic.cmake EXCLUDE)
  93 endif()