cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130 endfunction(add_llvm_symbol_exports)
 131
 132 function(add_dead_strip target_name)
 133   if(NOT LLVM_NO_DEAD_STRIP)
 134     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 135       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 136                    LINK_FLAGS " -Wl,-dead_strip")
 137     elseif(NOT WIN32)
 138       # Object files are compiled with -ffunction-data-sections.
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,--gc-sections")
 141     endif()
 142   endif()
 143 endfunction(add_dead_strip)
 144
 145 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 146 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 147 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 148 function(set_output_directory target bindir libdir)
 149   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 150     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 151       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 152       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 153       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 154       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 155       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 156       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 157     endforeach()
 158   else()
 159     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 160     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 161     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${libdir})
 162   endif()
 163 endfunction()
 164
 165 # llvm_add_library(name sources...
 166 #   MODULE;SHARED;STATIC
 167 #     STATIC by default w/o BUILD_SHARED_LIBS.
 168 #     SHARED by default w/  BUILD_SHARED_LIBS.
 169 #   OUTPUT_NAME name
 170 #     Corresponds to OUTPUT_NAME in target properties.
 171 #   DEPENDS targets...
 172 #     Same semantics as add_dependencies().
 173 #   LINK_COMPONENTS components...
 174 #     Same as the variable LLVM_LINK_COMPONENTS.
 175 #   LINK_LIBS lib_targets...
 176 #     Same semantics as target_link_libraries().
 177 #   ADDITIONAL_HEADERS (implemented in LLVMProcessSources)
 178 #     May specify header files for IDE generators.
 179 #   )
 180 function(llvm_add_library name)
 181   cmake_parse_arguments(ARG
 182     "MODULE;SHARED;STATIC"
 183     "OUTPUT_NAME"
 184     "DEPENDS;LINK_COMPONENTS;LINK_LIBS"
 185     ${ARGN})
 186   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 187   llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS})
 188
 189   if(ARG_MODULE)
 190     if(ARG_SHARED OR ARG_STATIC)
 191       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 192     endif()
 193   else()
 194     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 195       set(ARG_SHARED TRUE)
 196     endif()
 197     if(NOT ARG_SHARED)
 198       set(ARG_STATIC TRUE)
 199     endif()
 200   endif()
 201
 202   if(ARG_MODULE)
 203     add_library(${name} MODULE ${ALL_FILES})
 204   elseif(ARG_SHARED)
 205     add_library(${name} SHARED ${ALL_FILES})
 206   else()
 207     add_library(${name} STATIC ${ALL_FILES})
 208   endif()
 209   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 210   llvm_update_compile_flags(${name})
 211   add_dead_strip( ${name} )
 212   if(ARG_OUTPUT_NAME)
 213     set_target_properties(${name}
 214       PROPERTIES
 215       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 216       )
 217   endif()
 218
 219   if(ARG_MODULE)
 220     set_property(TARGET ${name} PROPERTY SUFFIX ${LLVM_PLUGIN_EXT})
 221   endif()
 222
 223   if(ARG_SHARED)
 224     if (MSVC)
 225       set_target_properties(${name}
 226         PROPERTIES
 227         IMPORT_SUFFIX ".imp")
 228     endif ()
 229   endif()
 230
 231   if(ARG_MODULE OR ARG_SHARED)
 232     if (LLVM_EXPORTED_SYMBOL_FILE)
 233       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 234     endif()
 235   endif()
 236
 237   target_link_libraries(${name} ${ARG_LINK_LIBS})
 238
 239   llvm_config(${name} ${ARG_LINK_COMPONENTS} ${LLVM_LINK_COMPONENTS})
 240
 241   if(LLVM_COMMON_DEPENDS)
 242     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 243   endif()
 244 endfunction()
 245
 246 macro(add_llvm_library name)
 247   if( BUILD_SHARED_LIBS )
 248     llvm_add_library(${name} SHARED ${ARGN})
 249   else()
 250     llvm_add_library(${name} ${ARGN})
 251   endif()
 252   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 253
 254   if( EXCLUDE_FROM_ALL )
 255     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 256   else()
 257     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 258       install(TARGETS ${name}
 259         EXPORT LLVMExports
 260         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 261         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 262     endif()
 263     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 264   endif()
 265   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 266
 267   # Add the explicit dependency information for this library.
 268   #
 269   # It would be nice to verify that we have the dependencies for this library
 270   # name, but using get_property(... SET) doesn't suffice to determine if a
 271   # property has been set to an empty value.
 272   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 273   target_link_libraries(${name} ${lib_deps})
 274 endmacro(add_llvm_library name)
 275
 276 macro(add_llvm_loadable_module name)
 277   if( NOT LLVM_ON_UNIX OR CYGWIN )
 278     message(STATUS "Loadable modules not supported on this platform.
 279 ${name} ignored.")
 280     # Add empty "phony" target
 281     add_custom_target(${name})
 282   else()
 283     llvm_add_library(${name} MODULE ${ARGN})
 284     set_target_properties( ${name} PROPERTIES PREFIX "" )
 285
 286     if (APPLE)
 287       # Darwin-specific linker flags for loadable modules.
 288       set_property(TARGET ${name} APPEND_STRING PROPERTY
 289         LINK_FLAGS " -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 290     endif()
 291
 292     if( EXCLUDE_FROM_ALL )
 293       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 294     else()
 295       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 296         install(TARGETS ${name}
 297           EXPORT LLVMExports
 298           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 299           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 300       endif()
 301       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 302     endif()
 303   endif()
 304
 305   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 306 endmacro(add_llvm_loadable_module name)
 307
 308
 309 macro(add_llvm_executable name)
 310   llvm_process_sources( ALL_FILES ${ARGN} )
 311   if( EXCLUDE_FROM_ALL )
 312     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 313   else()
 314     add_executable(${name} ${ALL_FILES})
 315   endif()
 316   llvm_update_compile_flags(${name})
 317   add_dead_strip( ${name} )
 318
 319   if (LLVM_EXPORTED_SYMBOL_FILE)
 320     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 321   endif(LLVM_EXPORTED_SYMBOL_FILE)
 322
 323   set(EXCLUDE_FROM_ALL OFF)
 324   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 325   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 326   if( LLVM_COMMON_DEPENDS )
 327     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 328   endif( LLVM_COMMON_DEPENDS )
 329 endmacro(add_llvm_executable name)
 330
 331
 332 set (LLVM_TOOLCHAIN_TOOLS
 333   llvm-ar
 334   llvm-objdump
 335   )
 336
 337 macro(add_llvm_tool name)
 338   if( NOT LLVM_BUILD_TOOLS )
 339     set(EXCLUDE_FROM_ALL ON)
 340   endif()
 341   add_llvm_executable(${name} ${ARGN})
 342
 343   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 344   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 345     if( LLVM_BUILD_TOOLS )
 346       install(TARGETS ${name}
 347               EXPORT LLVMExports
 348               RUNTIME DESTINATION bin)
 349     endif()
 350   endif()
 351   if( LLVM_BUILD_TOOLS )
 352     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 353   endif()
 354   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 355 endmacro(add_llvm_tool name)
 356
 357
 358 macro(add_llvm_example name)
 359   if( NOT LLVM_BUILD_EXAMPLES )
 360     set(EXCLUDE_FROM_ALL ON)
 361   endif()
 362   add_llvm_executable(${name} ${ARGN})
 363   if( LLVM_BUILD_EXAMPLES )
 364     install(TARGETS ${name} RUNTIME DESTINATION examples)
 365   endif()
 366   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 367 endmacro(add_llvm_example name)
 368
 369
 370 macro(add_llvm_utility name)
 371   add_llvm_executable(${name} ${ARGN})
 372   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 373 endmacro(add_llvm_utility name)
 374
 375
 376 macro(add_llvm_target target_name)
 377   include_directories(BEFORE
 378     ${CMAKE_CURRENT_BINARY_DIR}
 379     ${CMAKE_CURRENT_SOURCE_DIR})
 380   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 381   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 382 endmacro(add_llvm_target)
 383
 384 # Add external project that may want to be built as part of llvm such as Clang,
 385 # lld, and Polly. This adds two options. One for the source directory of the
 386 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 387 # enable or disable building it with everything else.
 388 # Additional parameter can be specified as the name of directory.
 389 macro(add_llvm_external_project name)
 390   set(add_llvm_external_dir "${ARGN}")
 391   if("${add_llvm_external_dir}" STREQUAL "")
 392     set(add_llvm_external_dir ${name})
 393   endif()
 394   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 395   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 396   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 397   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 398       CACHE PATH "Path to ${name} source directory")
 399   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 400       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 401     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 402            "Whether to build ${name} as part of LLVM" ON)
 403     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 404       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 405     endif()
 406   endif()
 407 endmacro(add_llvm_external_project)
 408
 409 macro(add_llvm_tool_subdirectory name)
 410   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 411   add_subdirectory(${name})
 412 endmacro(add_llvm_tool_subdirectory)
 413
 414 macro(ignore_llvm_tool_subdirectory name)
 415   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 416 endmacro(ignore_llvm_tool_subdirectory)
 417
 418 function(add_llvm_implicit_external_projects)
 419   set(list_of_implicit_subdirs "")
 420   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 421   foreach(dir ${sub-dirs})
 422     if(IS_DIRECTORY "${dir}")
 423       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 424       if( tool_subdir_ignore EQUAL -1
 425           AND EXISTS "${dir}/CMakeLists.txt")
 426         get_filename_component(fn "${dir}" NAME)
 427         list(APPEND list_of_implicit_subdirs "${fn}")
 428       endif()
 429     endif()
 430   endforeach()
 431
 432   foreach(external_proj ${list_of_implicit_subdirs})
 433     add_llvm_external_project("${external_proj}")
 434   endforeach()
 435 endfunction(add_llvm_implicit_external_projects)
 436
 437 # Generic support for adding a unittest.
 438 function(add_unittest test_suite test_name)
 439   if( NOT LLVM_BUILD_TESTS )
 440     set(EXCLUDE_FROM_ALL ON)
 441   endif()
 442
 443   # Visual Studio 2012 only supports up to 8 template parameters in
 444   # std::tr1::tuple by default, but gtest requires 10
 445   if (MSVC AND MSVC_VERSION EQUAL 1700)
 446     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 447   endif ()
 448
 449   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 450   if (NOT LLVM_ENABLE_THREADS)
 451     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 452   endif ()
 453
 454   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 455     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 456   endif ()
 457
 458   set(LLVM_REQUIRES_RTTI OFF)
 459
 460   add_llvm_executable(${test_name} ${ARGN})
 461   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 462   set_output_directory(${test_name} ${outdir} ${outdir})
 463   target_link_libraries(${test_name}
 464     gtest
 465     gtest_main
 466     LLVMSupport # gtest needs it for raw_ostream.
 467     )
 468
 469   add_dependencies(${test_suite} ${test_name})
 470   get_target_property(test_suite_folder ${test_suite} FOLDER)
 471   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 472     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 473   endif ()
 474 endfunction()
 475
 476 # This function provides an automatic way to 'configure'-like generate a file
 477 # based on a set of common and custom variables, specifically targeting the
 478 # variables needed for the 'lit.site.cfg' files. This function bundles the
 479 # common variables that any Lit instance is likely to need, and custom
 480 # variables can be passed in.
 481 function(configure_lit_site_cfg input output)
 482   foreach(c ${LLVM_TARGETS_TO_BUILD})
 483     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 484   endforeach(c)
 485   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 486
 487   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 488
 489   if(BUILD_SHARED_LIBS)
 490     set(LLVM_SHARED_LIBS_ENABLED "1")
 491   else()
 492     set(LLVM_SHARED_LIBS_ENABLED "0")
 493   endif(BUILD_SHARED_LIBS)
 494
 495   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 496     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 497   else() # Default for all other unix like systems.
 498     # CMake hardcodes the library locaction using rpath.
 499     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 500     # build dir. We pass it anyways.
 501     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 502   endif()
 503
 504   # Configuration-time: See Unit/lit.site.cfg.in
 505   if (CMAKE_CFG_INTDIR STREQUAL ".")
 506     set(LLVM_BUILD_MODE ".")
 507   else ()
 508     set(LLVM_BUILD_MODE "%(build_mode)s")
 509   endif ()
 510
 511   # They below might not be the build tree but provided binary tree.
 512   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 513   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 514   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 515   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 516
 517   # SHLIBDIR points the build tree.
 518   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 519
 520   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 521   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 522   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 523
 524   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 525     set(ENABLE_ASSERTIONS "1")
 526   else()
 527     set(ENABLE_ASSERTIONS "0")
 528   endif()
 529
 530   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 531   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 532
 533   if (CLANG_ENABLE_ARCMT)
 534     set(ENABLE_CLANG_ARCMT "1")
 535   else()
 536     set(ENABLE_CLANG_ARCMT "0")
 537   endif()
 538   if (CLANG_ENABLE_REWRITER)
 539     set(ENABLE_CLANG_REWRITER "1")
 540   else()
 541     set(ENABLE_CLANG_REWRITER "0")
 542   endif()
 543   if (CLANG_ENABLE_STATIC_ANALYZER)
 544     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 545   else()
 546     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 547   endif()
 548
 549   configure_file(${input} ${output} @ONLY)
 550 endfunction()
 551
 552 # A raw function to create a lit target. This is used to implement the testuite
 553 # management functions.
 554 function(add_lit_target target comment)
 555   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 556   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 557   separate_arguments(LIT_ARGS)
 558   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 559     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 560   endif ()
 561   set(LIT_COMMAND
 562     ${PYTHON_EXECUTABLE}
 563     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 564     ${LIT_ARGS}
 565     )
 566   foreach(param ${ARG_PARAMS})
 567     list(APPEND LIT_COMMAND --param ${param})
 568   endforeach()
 569   if( ARG_DEPENDS )
 570     add_custom_target(${target}
 571       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 572       COMMENT "${comment}"
 573       )
 574     add_dependencies(${target} ${ARG_DEPENDS})
 575   else()
 576     add_custom_target(${target}
 577       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 578     message(STATUS "${target} does nothing.")
 579   endif()
 580
 581   # Tests should be excluded from "Build Solution".
 582   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 583 endfunction()
 584
 585 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 586 function(add_lit_testsuite target comment)
 587   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 588
 589   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 590   if(NOT EXCLUDE_FROM_ALL)
 591     # Register the testsuites, params and depends for the global check rule.
 592     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 593     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 594     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 595     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 596   endif()
 597
 598   # Produce a specific suffixed check rule.
 599   add_lit_target(${target} ${comment}
 600     ${ARG_DEFAULT_ARGS}
 601     PARAMS ${ARG_PARAMS}
 602     DEPENDS ${ARG_DEPENDS}
 603     ARGS ${ARG_ARGS}
 604     )
 605 endfunction()