cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25     if (CLANG_CL)
  26       # FIXME: Remove this once clang-cl supports SEH
  27       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
  28     endif()
  29   endif()
  30
  31   # LLVM_REQUIRES_RTTI is an internal flag that individual
  32   # targets can use to force RTTI
  33   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  34     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  35     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  36       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  37     elseif (MSVC)
  38       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  39     endif ()
  40   endif()
  41
  42   # Assume that;
  43   #   - LLVM_COMPILE_FLAGS is list.
  44   #   - PROPERTY COMPILE_FLAGS is string.
  45   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  46
  47   if(update_src_props)
  48     foreach(fn ${sources})
  49       get_filename_component(suf ${fn} EXT)
  50       if("${suf}" STREQUAL ".cpp")
  51         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  52           COMPILE_FLAGS "${target_compile_flags}")
  53       endif()
  54     endforeach()
  55   else()
  56     # Update target props, since all sources are C++.
  57     set_property(TARGET ${name} APPEND_STRING PROPERTY
  58       COMPILE_FLAGS "${target_compile_flags}")
  59   endif()
  60
  61   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  62 endfunction()
  63
  64 function(add_llvm_symbol_exports target_name export_file)
  65   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  66     set(native_export_file "${target_name}.exports")
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  69       DEPENDS ${export_file}
  70       VERBATIM
  71       COMMENT "Creating export file for ${target_name}")
  72     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  73                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  74   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  75     # Gold and BFD ld require a version script rather than a plain list.
  76     set(native_export_file "${target_name}.exports")
  77     # FIXME: Don't write the "local:" line on OpenBSD.
  78     add_custom_command(OUTPUT ${native_export_file}
  79       COMMAND echo "{" > ${native_export_file}
  80       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  81       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  82       COMMAND echo "  local: *;" >> ${native_export_file}
  83       COMMAND echo "};" >> ${native_export_file}
  84       DEPENDS ${export_file}
  85       VERBATIM
  86       COMMENT "Creating export file for ${target_name}")
  87     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  88                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  89   else()
  90     set(native_export_file "${target_name}.def")
  91
  92     set(CAT "cat")
  93     set(export_file_nativeslashes ${export_file})
  94     if(WIN32 AND NOT CYGWIN AND NOT MSYS)
  95       set(CAT "type")
  96       # Convert ${export_file} to native format (backslashes) for "type"
  97       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
  98       # path but a build-system specific format (see CMake bug
  99       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
 100       string(REPLACE / \\ export_file_nativeslashes ${export_file})
 101     endif()
 102
 103     add_custom_command(OUTPUT ${native_export_file}
 104       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 105       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 106       DEPENDS ${export_file}
 107       VERBATIM
 108       COMMENT "Creating export file for ${target_name}")
 109     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 110     if(MSVC)
 111       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 112     endif()
 113     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 114                  LINK_FLAGS " ${export_file_linker_flag}")
 115   endif()
 116
 117   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 118   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 119
 120   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 121   foreach(src ${srcs})
 122     get_filename_component(extension ${src} EXT)
 123     if(extension STREQUAL ".cpp")
 124       set(first_source_file ${src})
 125       break()
 126     endif()
 127   endforeach()
 128
 129   # Force re-linking when the exports file changes. Actually, it
 130   # forces recompilation of the source file. The LINK_DEPENDS target
 131   # property only works for makefile-based generators.
 132   # FIXME: This is not safe because this will create the same target
 133   # ${native_export_file} in several different file:
 134   # - One where we emitted ${target_name}_exports
 135   # - One where we emitted the build command for the following object.
 136   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 137   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 138
 139   set_property(DIRECTORY APPEND
 140     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 141
 142   add_dependencies(${target_name} ${target_name}_exports)
 143
 144   # Add dependency to *_exports later -- CMake issue 14747
 145   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 146   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 147 endfunction(add_llvm_symbol_exports)
 148
 149 if(NOT WIN32 AND NOT APPLE)
 150   execute_process(
 151     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 152     OUTPUT_VARIABLE stdout
 153     ERROR_QUIET
 154     )
 155   if("${stdout}" MATCHES "GNU gold")
 156     set(LLVM_LINKER_IS_GOLD ON)
 157   endif()
 158 endif()
 159
 160 function(add_link_opts target_name)
 161   # Don't use linker optimizations in debug builds since it slows down the
 162   # linker in a context where the optimizations are not important.
 163   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 164
 165     # Pass -O3 to the linker. This enabled different optimizations on different
 166     # linkers.
 167     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32))
 168       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 169                    LINK_FLAGS " -Wl,-O3")
 170     endif()
 171
 172     if(LLVM_LINKER_IS_GOLD)
 173       # With gold gc-sections is always safe.
 174       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 175                    LINK_FLAGS " -Wl,--gc-sections")
 176       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 177       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 178     endif()
 179
 180     if(NOT LLVM_NO_DEAD_STRIP)
 181       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 182         # ld64's implementation of -dead_strip breaks tools that use plugins.
 183         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 184                      LINK_FLAGS " -Wl,-dead_strip")
 185       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 186         # Object files are compiled with -ffunction-data-sections.
 187         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 188         # tools that use plugins. Always pass --gc-sections once we require
 189         # a newer linker.
 190         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 191                      LINK_FLAGS " -Wl,--gc-sections")
 192       endif()
 193     endif()
 194   endif()
 195 endfunction(add_link_opts)
 196
 197 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 198 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 199 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 200 function(set_output_directory target bindir libdir)
 201   # Do nothing if *_OUTPUT_INTDIR is empty.
 202   if("${bindir}" STREQUAL "")
 203     return()
 204   endif()
 205
 206   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 207   # It affects output of add_library(MODULE).
 208   if(WIN32 OR CYGWIN)
 209     # DLL platform
 210     set(moddir ${bindir})
 211   else()
 212     set(moddir ${libdir})
 213   endif()
 214   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 215     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 216       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 217       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 218       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 219       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 220       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 221       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 222       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 223     endforeach()
 224   else()
 225     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 226     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 227     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 228   endif()
 229 endfunction()
 230
 231 # If on Windows and building with MSVC, add the resource script containing the
 232 # VERSIONINFO data to the project.  This embeds version resource information
 233 # into the output .exe or .dll.
 234 # TODO: Enable for MinGW Windows builds too.
 235 #
 236 function(add_windows_version_resource_file OUT_VAR)
 237   set(sources ${ARGN})
 238   if (MSVC)
 239     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 240     if(EXISTS ${resource_file})
 241       set(sources ${sources} ${resource_file})
 242       source_group("Resource Files" ${resource_file})
 243       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 244     endif()
 245   endif(MSVC)
 246
 247   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 248 endfunction(add_windows_version_resource_file)
 249
 250 # set_windows_version_resource_properties(name resource_file...
 251 #   VERSION_MAJOR int
 252 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 253 #   VERSION_MINOR int
 254 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 255 #   VERSION_PATCHLEVEL int
 256 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 257 #   VERSION_STRING
 258 #     Optional version string (defaults to PACKAGE_VERSION)
 259 #   PRODUCT_NAME
 260 #     Optional product name string (defaults to "LLVM")
 261 #   )
 262 function(set_windows_version_resource_properties name resource_file)
 263   cmake_parse_arguments(ARG
 264     ""
 265     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 266     ""
 267     ${ARGN})
 268
 269   if (NOT DEFINED ARG_VERSION_MAJOR)
 270     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 271   endif()
 272
 273   if (NOT DEFINED ARG_VERSION_MINOR)
 274     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 278     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 279   endif()
 280
 281   if (NOT DEFINED ARG_VERSION_STRING)
 282     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 283   endif()
 284
 285   if (NOT DEFINED ARG_PRODUCT_NAME)
 286     set(ARG_PRODUCT_NAME "LLVM")
 287   endif()
 288
 289   set_property(SOURCE ${resource_file}
 290                PROPERTY COMPILE_FLAGS /nologo)
 291   set_property(SOURCE ${resource_file}
 292                PROPERTY COMPILE_DEFINITIONS
 293                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 294                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 295                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 296                "RC_VERSION_FIELD_4=0"
 297                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 298                "RC_INTERNAL_NAME=\"${name}\""
 299                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 300                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 301 endfunction(set_windows_version_resource_properties)
 302
 303 # llvm_add_library(name sources...
 304 #   SHARED;STATIC
 305 #     STATIC by default w/o BUILD_SHARED_LIBS.
 306 #     SHARED by default w/  BUILD_SHARED_LIBS.
 307 #   MODULE
 308 #     Target ${name} might not be created on unsupported platforms.
 309 #     Check with "if(TARGET ${name})".
 310 #   OUTPUT_NAME name
 311 #     Corresponds to OUTPUT_NAME in target properties.
 312 #   DEPENDS targets...
 313 #     Same semantics as add_dependencies().
 314 #   LINK_COMPONENTS components...
 315 #     Same as the variable LLVM_LINK_COMPONENTS.
 316 #   LINK_LIBS lib_targets...
 317 #     Same semantics as target_link_libraries().
 318 #   ADDITIONAL_HEADERS
 319 #     May specify header files for IDE generators.
 320 #   )
 321 function(llvm_add_library name)
 322   cmake_parse_arguments(ARG
 323     "MODULE;SHARED;STATIC"
 324     "OUTPUT_NAME"
 325     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 326     ${ARGN})
 327   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 328   if(ARG_ADDITIONAL_HEADERS)
 329     # Pass through ADDITIONAL_HEADERS.
 330     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 331   endif()
 332   if(ARG_OBJLIBS)
 333     set(ALL_FILES ${ARG_OBJLIBS})
 334   else()
 335     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 336   endif()
 337
 338   if(ARG_MODULE)
 339     if(ARG_SHARED OR ARG_STATIC)
 340       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 341     endif()
 342     if(NOT LLVM_ENABLE_PLUGINS)
 343       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 344       return()
 345     endif()
 346   else()
 347     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 348       set(ARG_SHARED TRUE)
 349     endif()
 350     if(NOT ARG_SHARED)
 351       set(ARG_STATIC TRUE)
 352     endif()
 353   endif()
 354
 355   # Generate objlib
 356   if(ARG_SHARED AND ARG_STATIC)
 357     # Generate an obj library for both targets.
 358     set(obj_name "obj.${name}")
 359     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 360       ${ALL_FILES}
 361       )
 362     llvm_update_compile_flags(${obj_name})
 363     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 364
 365     # Do add_dependencies(obj) later due to CMake issue 14747.
 366     list(APPEND objlibs ${obj_name})
 367
 368     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 369   endif()
 370
 371   if(ARG_SHARED AND ARG_STATIC)
 372     # static
 373     set(name_static "${name}_static")
 374     if(ARG_OUTPUT_NAME)
 375       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 376     endif()
 377     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 378     llvm_add_library(${name_static} STATIC
 379       ${output_name}
 380       OBJLIBS ${ALL_FILES} # objlib
 381       LINK_LIBS ${ARG_LINK_LIBS}
 382       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 383       )
 384     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 385     set(ARG_STATIC)
 386   endif()
 387
 388   if(ARG_MODULE)
 389     add_library(${name} MODULE ${ALL_FILES})
 390   elseif(ARG_SHARED)
 391     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 392     add_library(${name} SHARED ${ALL_FILES})
 393   else()
 394     add_library(${name} STATIC ${ALL_FILES})
 395   endif()
 396
 397   if(DEFINED windows_resource_file)
 398     set_windows_version_resource_properties(${name} ${windows_resource_file})
 399     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 400   endif()
 401
 402   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 403   llvm_update_compile_flags(${name})
 404   add_link_opts( ${name} )
 405   if(ARG_OUTPUT_NAME)
 406     set_target_properties(${name}
 407       PROPERTIES
 408       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 409       )
 410   endif()
 411
 412   if(ARG_MODULE)
 413     set_target_properties(${name} PROPERTIES
 414       PREFIX ""
 415       SUFFIX ${LLVM_PLUGIN_EXT}
 416       )
 417   endif()
 418
 419   if(ARG_SHARED)
 420     if(WIN32)
 421       set_target_properties(${name} PROPERTIES
 422         PREFIX ""
 423         )
 424     endif()
 425
 426     set_target_properties(${name}
 427       PROPERTIES
 428       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 429       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 430   endif()
 431
 432   if(ARG_MODULE OR ARG_SHARED)
 433     # Do not add -Dname_EXPORTS to the command-line when building files in this
 434     # target. Doing so is actively harmful for the modules build because it
 435     # creates extra module variants, and not useful because we don't use these
 436     # macros.
 437     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 438
 439     if (LLVM_EXPORTED_SYMBOL_FILE)
 440       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 441     endif()
 442   endif()
 443
 444   # Add the explicit dependency information for this library.
 445   #
 446   # It would be nice to verify that we have the dependencies for this library
 447   # name, but using get_property(... SET) doesn't suffice to determine if a
 448   # property has been set to an empty value.
 449   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 450
 451   llvm_map_components_to_libnames(llvm_libs
 452     ${ARG_LINK_COMPONENTS}
 453     ${LLVM_LINK_COMPONENTS}
 454     )
 455
 456   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 457     # Link libs w/o keywords, assuming PUBLIC.
 458     target_link_libraries(${name}
 459       ${ARG_LINK_LIBS}
 460       ${lib_deps}
 461       ${llvm_libs}
 462       )
 463   elseif(ARG_STATIC)
 464     target_link_libraries(${name} INTERFACE
 465       ${ARG_LINK_LIBS}
 466       ${lib_deps}
 467       ${llvm_libs}
 468       )
 469   else()
 470     # We can use PRIVATE since SO knows its dependent libs.
 471     target_link_libraries(${name} PRIVATE
 472       ${ARG_LINK_LIBS}
 473       ${lib_deps}
 474       ${llvm_libs}
 475       )
 476   endif()
 477
 478   if(LLVM_COMMON_DEPENDS)
 479     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 480     # Add dependencies also to objlibs.
 481     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 482     foreach(objlib ${objlibs})
 483       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 484     endforeach()
 485   endif()
 486 endfunction()
 487
 488 macro(add_llvm_library name)
 489   cmake_parse_arguments(ARG
 490     "SHARED"
 491     ""
 492     ""
 493     ${ARGN})
 494   if( BUILD_SHARED_LIBS )
 495     llvm_add_library(${name} SHARED ${ARGN})
 496   else()
 497     llvm_add_library(${name} ${ARGN})
 498   endif()
 499   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 500
 501   if( EXCLUDE_FROM_ALL )
 502     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 503   else()
 504     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 505       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 506         if(WIN32 OR CYGWIN)
 507           set(install_type RUNTIME)
 508         else()
 509           set(install_type LIBRARY)
 510         endif()
 511       else()
 512         set(install_type ARCHIVE)
 513       endif()
 514
 515       install(TARGETS ${name}
 516             EXPORT LLVMExports
 517             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 518             COMPONENT ${name})
 519
 520       if (NOT CMAKE_CONFIGURATION_TYPES)
 521         add_custom_target(install-${name}
 522                           DEPENDS ${name}
 523                           COMMAND "${CMAKE_COMMAND}"
 524                                   -DCMAKE_INSTALL_COMPONENT=${name}
 525                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 526       endif()
 527     endif()
 528     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 529   endif()
 530   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 531 endmacro(add_llvm_library name)
 532
 533 macro(add_llvm_loadable_module name)
 534   llvm_add_library(${name} MODULE ${ARGN})
 535   if(NOT TARGET ${name})
 536     # Add empty "phony" target
 537     add_custom_target(${name})
 538   else()
 539     if( EXCLUDE_FROM_ALL )
 540       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 541     else()
 542       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 543         if(WIN32 OR CYGWIN)
 544           # DLL platform
 545           set(dlldir "bin")
 546         else()
 547           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 548         endif()
 549         install(TARGETS ${name}
 550           EXPORT LLVMExports
 551           LIBRARY DESTINATION ${dlldir}
 552           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 553       endif()
 554       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 555     endif()
 556   endif()
 557
 558   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 559 endmacro(add_llvm_loadable_module name)
 560
 561
 562 macro(add_llvm_executable name)
 563   llvm_process_sources( ALL_FILES ${ARGN} )
 564   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 565
 566   if( EXCLUDE_FROM_ALL )
 567     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 568   else()
 569     add_executable(${name} ${ALL_FILES})
 570   endif()
 571
 572   if(DEFINED windows_resource_file)
 573     set_windows_version_resource_properties(${name} ${windows_resource_file})
 574   endif()
 575
 576   llvm_update_compile_flags(${name})
 577   add_link_opts( ${name} )
 578
 579   # Do not add -Dname_EXPORTS to the command-line when building files in this
 580   # target. Doing so is actively harmful for the modules build because it
 581   # creates extra module variants, and not useful because we don't use these
 582   # macros.
 583   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 584
 585   if (LLVM_EXPORTED_SYMBOL_FILE)
 586     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 587   endif(LLVM_EXPORTED_SYMBOL_FILE)
 588
 589   set(EXCLUDE_FROM_ALL OFF)
 590   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 591   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 592   if( LLVM_COMMON_DEPENDS )
 593     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 594   endif( LLVM_COMMON_DEPENDS )
 595 endmacro(add_llvm_executable name)
 596
 597 function(export_executable_symbols target)
 598   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 599     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 600   endif()
 601 endfunction()
 602
 603
 604 set (LLVM_TOOLCHAIN_TOOLS
 605   llvm-ar
 606   llvm-objdump
 607   )
 608
 609 macro(add_llvm_tool name)
 610   if( NOT LLVM_BUILD_TOOLS )
 611     set(EXCLUDE_FROM_ALL ON)
 612   endif()
 613   add_llvm_executable(${name} ${ARGN})
 614
 615   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 616   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 617     if( LLVM_BUILD_TOOLS )
 618       install(TARGETS ${name}
 619               EXPORT LLVMExports
 620               RUNTIME DESTINATION bin
 621               COMPONENT ${name})
 622
 623       if (NOT CMAKE_CONFIGURATION_TYPES)
 624         add_custom_target(install-${name}
 625                           DEPENDS ${name}
 626                           COMMAND "${CMAKE_COMMAND}"
 627                                   -DCMAKE_INSTALL_COMPONENT=${name}
 628                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 629       endif()
 630     endif()
 631   endif()
 632   if( LLVM_BUILD_TOOLS )
 633     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 634   endif()
 635   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 636 endmacro(add_llvm_tool name)
 637
 638
 639 macro(add_llvm_example name)
 640   if( NOT LLVM_BUILD_EXAMPLES )
 641     set(EXCLUDE_FROM_ALL ON)
 642   endif()
 643   add_llvm_executable(${name} ${ARGN})
 644   if( LLVM_BUILD_EXAMPLES )
 645     install(TARGETS ${name} RUNTIME DESTINATION examples)
 646   endif()
 647   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 648 endmacro(add_llvm_example name)
 649
 650
 651 macro(add_llvm_utility name)
 652   add_llvm_executable(${name} ${ARGN})
 653   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 654   if( LLVM_INSTALL_UTILS )
 655     install (TARGETS ${name}
 656       RUNTIME DESTINATION bin
 657       COMPONENT ${name})
 658     if (NOT CMAKE_CONFIGURATION_TYPES)
 659       add_custom_target(install-${name}
 660                         DEPENDS ${name}
 661                         COMMAND "${CMAKE_COMMAND}"
 662                                 -DCMAKE_INSTALL_COMPONENT=${name}
 663                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 664     endif()
 665   endif()
 666 endmacro(add_llvm_utility name)
 667
 668
 669 macro(add_llvm_target target_name)
 670   include_directories(BEFORE
 671     ${CMAKE_CURRENT_BINARY_DIR}
 672     ${CMAKE_CURRENT_SOURCE_DIR})
 673   add_llvm_library(LLVM${target_name} ${ARGN})
 674   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 675 endmacro(add_llvm_target)
 676
 677 # Add external project that may want to be built as part of llvm such as Clang,
 678 # lld, and Polly. This adds two options. One for the source directory of the
 679 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 680 # enable or disable building it with everything else.
 681 # Additional parameter can be specified as the name of directory.
 682 macro(add_llvm_external_project name)
 683   set(add_llvm_external_dir "${ARGN}")
 684   if("${add_llvm_external_dir}" STREQUAL "")
 685     set(add_llvm_external_dir ${name})
 686   endif()
 687   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 688   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 689   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 690   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 691       CACHE PATH "Path to ${name} source directory")
 692   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 693       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 694     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 695            "Whether to build ${name} as part of LLVM" ON)
 696     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 697       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 698     endif()
 699   endif()
 700 endmacro(add_llvm_external_project)
 701
 702 macro(add_llvm_tool_subdirectory name)
 703   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 704   add_subdirectory(${name})
 705 endmacro(add_llvm_tool_subdirectory)
 706
 707 macro(ignore_llvm_tool_subdirectory name)
 708   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 709 endmacro(ignore_llvm_tool_subdirectory)
 710
 711 function(add_llvm_implicit_external_projects)
 712   set(list_of_implicit_subdirs "")
 713   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 714   foreach(dir ${sub-dirs})
 715     if(IS_DIRECTORY "${dir}")
 716       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 717       if( tool_subdir_ignore EQUAL -1
 718           AND EXISTS "${dir}/CMakeLists.txt")
 719         get_filename_component(fn "${dir}" NAME)
 720         list(APPEND list_of_implicit_subdirs "${fn}")
 721       endif()
 722     endif()
 723   endforeach()
 724
 725   foreach(external_proj ${list_of_implicit_subdirs})
 726     add_llvm_external_project("${external_proj}")
 727   endforeach()
 728 endfunction(add_llvm_implicit_external_projects)
 729
 730 # Generic support for adding a unittest.
 731 function(add_unittest test_suite test_name)
 732   if( NOT LLVM_BUILD_TESTS )
 733     set(EXCLUDE_FROM_ALL ON)
 734   endif()
 735
 736   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 737   if (NOT LLVM_ENABLE_THREADS)
 738     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 739   endif ()
 740
 741   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 742     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 743   endif ()
 744
 745   set(LLVM_REQUIRES_RTTI OFF)
 746
 747   add_llvm_executable(${test_name} ${ARGN})
 748   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 749   set_output_directory(${test_name} ${outdir} ${outdir})
 750   target_link_libraries(${test_name}
 751     gtest
 752     gtest_main
 753     LLVMSupport # gtest needs it for raw_ostream.
 754     )
 755
 756   add_dependencies(${test_suite} ${test_name})
 757   get_target_property(test_suite_folder ${test_suite} FOLDER)
 758   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 759     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 760   endif ()
 761 endfunction()
 762
 763 function(llvm_add_go_executable binary pkgpath)
 764   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 765
 766   if(LLVM_BINDINGS MATCHES "go")
 767     # FIXME: This should depend only on the libraries Go needs.
 768     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 769     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 770     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 771     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 772     set(cppflags "")
 773     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 774     foreach(d ${include_dirs})
 775       set(cppflags "${cppflags} -I${d}")
 776     endforeach(d)
 777     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 778     add_custom_command(OUTPUT ${binpath}
 779       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
 780               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 781       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 782               ${llvmlibs} ${ARG_DEPENDS}
 783       COMMENT "Building Go executable ${binary}"
 784       VERBATIM)
 785     if (ARG_ALL)
 786       add_custom_target(${binary} ALL DEPENDS ${binpath})
 787     else()
 788       add_custom_target(${binary} DEPENDS ${binpath})
 789     endif()
 790   endif()
 791 endfunction()
 792
 793 # This function provides an automatic way to 'configure'-like generate a file
 794 # based on a set of common and custom variables, specifically targeting the
 795 # variables needed for the 'lit.site.cfg' files. This function bundles the
 796 # common variables that any Lit instance is likely to need, and custom
 797 # variables can be passed in.
 798 function(configure_lit_site_cfg input output)
 799   foreach(c ${LLVM_TARGETS_TO_BUILD})
 800     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 801   endforeach(c)
 802   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 803
 804   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 805
 806   # Configuration-time: See Unit/lit.site.cfg.in
 807   if (CMAKE_CFG_INTDIR STREQUAL ".")
 808     set(LLVM_BUILD_MODE ".")
 809   else ()
 810     set(LLVM_BUILD_MODE "%(build_mode)s")
 811   endif ()
 812
 813   # They below might not be the build tree but provided binary tree.
 814   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 815   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 816   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 817   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 818
 819   # SHLIBDIR points the build tree.
 820   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 821
 822   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 823   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 824   # plugins. We may rename it.
 825   if(LLVM_ENABLE_PLUGINS)
 826     set(ENABLE_SHARED "1")
 827   else()
 828     set(ENABLE_SHARED "0")
 829   endif()
 830
 831   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 832     set(ENABLE_ASSERTIONS "1")
 833   else()
 834     set(ENABLE_ASSERTIONS "0")
 835   endif()
 836
 837   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 838   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 839
 840   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 841   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 842   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 843
 844   configure_file(${input} ${output} @ONLY)
 845 endfunction()
 846
 847 # A raw function to create a lit target. This is used to implement the testuite
 848 # management functions.
 849 function(add_lit_target target comment)
 850   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 851   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 852   separate_arguments(LIT_ARGS)
 853   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 854     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 855   endif ()
 856   if (LLVM_MAIN_SRC_DIR)
 857     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 858   else()
 859     find_program(LIT_COMMAND llvm-lit)
 860   endif ()
 861   list(APPEND LIT_COMMAND ${LIT_ARGS})
 862   foreach(param ${ARG_PARAMS})
 863     list(APPEND LIT_COMMAND --param ${param})
 864   endforeach()
 865   if (ARG_DEFAULT_ARGS)
 866     add_custom_target(${target}
 867       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 868       COMMENT "${comment}"
 869       ${cmake_3_2_USES_TERMINAL}
 870       )
 871   else()
 872     add_custom_target(${target}
 873       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 874     message(STATUS "${target} does nothing.")
 875   endif()
 876   if (ARG_DEPENDS)
 877     add_dependencies(${target} ${ARG_DEPENDS})
 878   endif()
 879
 880   # Tests should be excluded from "Build Solution".
 881   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 882 endfunction()
 883
 884 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 885 function(add_lit_testsuite target comment)
 886   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 887
 888   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 889   if(NOT EXCLUDE_FROM_ALL)
 890     # Register the testsuites, params and depends for the global check rule.
 891     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 892     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 893     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 894     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 895   endif()
 896
 897   # Produce a specific suffixed check rule.
 898   add_lit_target(${target} ${comment}
 899     ${ARG_DEFAULT_ARGS}
 900     PARAMS ${ARG_PARAMS}
 901     DEPENDS ${ARG_DEPENDS}
 902     ARGS ${ARG_ARGS}
 903     )
 904 endfunction()
 905
 906 function(add_lit_testsuites project directory)
 907   if (NOT CMAKE_CONFIGURATION_TYPES)
 908     parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 909     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
 910     set(lit_suites)
 911     foreach(f ${litCfg})
 912       get_filename_component(dir ${f} DIRECTORY)
 913       set(lit_suites ${lit_suites} ${dir})
 914     endforeach()
 915     list(REMOVE_DUPLICATES lit_suites)
 916     foreach(dir ${lit_suites})
 917       string(REPLACE ${directory} "" name_slash ${dir})
 918       if (name_slash)
 919         string(REPLACE "/" "-" name_slash ${name_slash})
 920         string(REPLACE "\\" "-" name_dashes ${name_slash})
 921         string(TOLOWER "${project}${name_dashes}" name_var)
 922         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
 923           ${dir}
 924           PARAMS ${ARG_PARAMS}
 925           DEPENDS ${ARG_DEPENDS}
 926           ARGS ${ARG_ARGS}
 927         )
 928       endif()
 929     endforeach()
 930   endif()
 931 endfunction()