cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130 endfunction(add_llvm_symbol_exports)
 131
 132 function(add_dead_strip target_name)
 133   if(NOT LLVM_NO_DEAD_STRIP)
 134     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 135       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 136                    LINK_FLAGS " -Wl,-dead_strip")
 137     elseif(NOT WIN32)
 138       # Object files are compiled with -ffunction-data-sections.
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,--gc-sections")
 141     endif()
 142   endif()
 143 endfunction(add_dead_strip)
 144
 145 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 146 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 147 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 148 function(set_output_directory target bindir libdir)
 149   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 150     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 151       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 152       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 153       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 154       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 155       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 156       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 157     endforeach()
 158   else()
 159     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 160     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 161     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${libdir})
 162   endif()
 163 endfunction()
 164
 165 macro(add_llvm_library name)
 166   llvm_process_sources( ALL_FILES ${ARGN} )
 167   add_library( ${name} ${ALL_FILES} )
 168   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 169   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 170   llvm_update_compile_flags(${name})
 171   add_dead_strip( ${name} )
 172   if( LLVM_COMMON_DEPENDS )
 173     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 174   endif( LLVM_COMMON_DEPENDS )
 175
 176   if( BUILD_SHARED_LIBS )
 177     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 178     if (MSVC)
 179       set_target_properties(${name}
 180         PROPERTIES
 181         IMPORT_SUFFIX ".imp")
 182     endif ()
 183
 184     if (LLVM_EXPORTED_SYMBOL_FILE)
 185       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 186     endif()
 187   endif()
 188
 189   # Ensure that the system libraries always comes last on the
 190   # list. Without this, linking the unit tests on MinGW fails.
 191   link_system_libs( ${name} )
 192
 193   if( EXCLUDE_FROM_ALL )
 194     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 195   else()
 196     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 197       install(TARGETS ${name}
 198         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 199         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 200     endif()
 201   endif()
 202   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 203
 204   # Add the explicit dependency information for this library.
 205   #
 206   # It would be nice to verify that we have the dependencies for this library
 207   # name, but using get_property(... SET) doesn't suffice to determine if a
 208   # property has been set to an empty value.
 209   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 210   target_link_libraries(${name} ${lib_deps})
 211 endmacro(add_llvm_library name)
 212
 213 macro(add_llvm_loadable_module name)
 214   if( NOT LLVM_ON_UNIX OR CYGWIN )
 215     message(STATUS "Loadable modules not supported on this platform.
 216 ${name} ignored.")
 217     # Add empty "phony" target
 218     add_custom_target(${name})
 219   else()
 220     llvm_process_sources( ALL_FILES ${ARGN} )
 221     add_library(${name} MODULE ${ALL_FILES})
 222     set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 223     set_target_properties( ${name} PROPERTIES PREFIX "" )
 224     llvm_update_compile_flags(${name})
 225     add_dead_strip( ${name} )
 226
 227     if (LLVM_EXPORTED_SYMBOL_FILE)
 228       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 229     endif(LLVM_EXPORTED_SYMBOL_FILE)
 230
 231     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 232     link_system_libs( ${name} )
 233
 234     if (APPLE)
 235       # Darwin-specific linker flags for loadable modules.
 236       set_property(TARGET ${name} APPEND_STRING PROPERTY
 237         LINK_FLAGS " -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 238     endif()
 239
 240     if (MODULE)
 241       set_property(TARGET ${name} PROPERTY SUFFIX ${LLVM_PLUGIN_EXT})
 242     endif ()
 243
 244     if( EXCLUDE_FROM_ALL )
 245       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 246     else()
 247       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 248         install(TARGETS ${name}
 249           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 250           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 251       endif()
 252     endif()
 253   endif()
 254
 255   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 256 endmacro(add_llvm_loadable_module name)
 257
 258
 259 macro(add_llvm_executable name)
 260   llvm_process_sources( ALL_FILES ${ARGN} )
 261   if( EXCLUDE_FROM_ALL )
 262     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 263   else()
 264     add_executable(${name} ${ALL_FILES})
 265   endif()
 266   llvm_update_compile_flags(${name})
 267   add_dead_strip( ${name} )
 268
 269   if (LLVM_EXPORTED_SYMBOL_FILE)
 270     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 271   endif(LLVM_EXPORTED_SYMBOL_FILE)
 272
 273   set(EXCLUDE_FROM_ALL OFF)
 274   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 275   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 276   if( LLVM_COMMON_DEPENDS )
 277     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 278   endif( LLVM_COMMON_DEPENDS )
 279   link_system_libs( ${name} )
 280 endmacro(add_llvm_executable name)
 281
 282
 283 set (LLVM_TOOLCHAIN_TOOLS
 284   llvm-ar
 285   llvm-objdump
 286   )
 287
 288 macro(add_llvm_tool name)
 289   if( NOT LLVM_BUILD_TOOLS )
 290     set(EXCLUDE_FROM_ALL ON)
 291   endif()
 292   add_llvm_executable(${name} ${ARGN})
 293
 294   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 295   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 296     if( LLVM_BUILD_TOOLS )
 297       install(TARGETS ${name} RUNTIME DESTINATION bin)
 298     endif()
 299   endif()
 300   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 301 endmacro(add_llvm_tool name)
 302
 303
 304 macro(add_llvm_example name)
 305   if( NOT LLVM_BUILD_EXAMPLES )
 306     set(EXCLUDE_FROM_ALL ON)
 307   endif()
 308   add_llvm_executable(${name} ${ARGN})
 309   if( LLVM_BUILD_EXAMPLES )
 310     install(TARGETS ${name} RUNTIME DESTINATION examples)
 311   endif()
 312   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 313 endmacro(add_llvm_example name)
 314
 315
 316 macro(add_llvm_utility name)
 317   add_llvm_executable(${name} ${ARGN})
 318   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 319 endmacro(add_llvm_utility name)
 320
 321
 322 macro(add_llvm_target target_name)
 323   include_directories(BEFORE
 324     ${CMAKE_CURRENT_BINARY_DIR}
 325     ${CMAKE_CURRENT_SOURCE_DIR})
 326   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 327   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 328 endmacro(add_llvm_target)
 329
 330 # Add external project that may want to be built as part of llvm such as Clang,
 331 # lld, and Polly. This adds two options. One for the source directory of the
 332 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 333 # enable or disable building it with everything else.
 334 # Additional parameter can be specified as the name of directory.
 335 macro(add_llvm_external_project name)
 336   set(add_llvm_external_dir "${ARGN}")
 337   if("${add_llvm_external_dir}" STREQUAL "")
 338     set(add_llvm_external_dir ${name})
 339   endif()
 340   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 341   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 342   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 343   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 344       CACHE PATH "Path to ${name} source directory")
 345   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 346       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 347     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 348            "Whether to build ${name} as part of LLVM" ON)
 349     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 350       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 351     endif()
 352   endif()
 353 endmacro(add_llvm_external_project)
 354
 355 macro(add_llvm_tool_subdirectory name)
 356   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 357   add_subdirectory(${name})
 358 endmacro(add_llvm_tool_subdirectory)
 359
 360 macro(ignore_llvm_tool_subdirectory name)
 361   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 362 endmacro(ignore_llvm_tool_subdirectory)
 363
 364 function(add_llvm_implicit_external_projects)
 365   set(list_of_implicit_subdirs "")
 366   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 367   foreach(dir ${sub-dirs})
 368     if(IS_DIRECTORY "${dir}")
 369       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 370       if( tool_subdir_ignore EQUAL -1
 371           AND EXISTS "${dir}/CMakeLists.txt")
 372         get_filename_component(fn "${dir}" NAME)
 373         list(APPEND list_of_implicit_subdirs "${fn}")
 374       endif()
 375     endif()
 376   endforeach()
 377
 378   foreach(external_proj ${list_of_implicit_subdirs})
 379     add_llvm_external_project("${external_proj}")
 380   endforeach()
 381 endfunction(add_llvm_implicit_external_projects)
 382
 383 # Generic support for adding a unittest.
 384 function(add_unittest test_suite test_name)
 385   if( NOT LLVM_BUILD_TESTS )
 386     set(EXCLUDE_FROM_ALL ON)
 387   endif()
 388
 389   # Visual Studio 2012 only supports up to 8 template parameters in
 390   # std::tr1::tuple by default, but gtest requires 10
 391   if (MSVC AND MSVC_VERSION EQUAL 1700)
 392     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 393   endif ()
 394
 395   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 396   if (NOT LLVM_ENABLE_THREADS)
 397     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 398   endif ()
 399
 400   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 401     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 402   endif ()
 403
 404   set(LLVM_REQUIRES_RTTI OFF)
 405
 406   add_llvm_executable(${test_name} ${ARGN})
 407   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 408   set_output_directory(${test_name} ${outdir} ${outdir})
 409   target_link_libraries(${test_name}
 410     gtest
 411     gtest_main
 412     LLVMSupport # gtest needs it for raw_ostream.
 413     )
 414
 415   add_dependencies(${test_suite} ${test_name})
 416   get_target_property(test_suite_folder ${test_suite} FOLDER)
 417   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 418     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 419   endif ()
 420 endfunction()
 421
 422 # This function provides an automatic way to 'configure'-like generate a file
 423 # based on a set of common and custom variables, specifically targeting the
 424 # variables needed for the 'lit.site.cfg' files. This function bundles the
 425 # common variables that any Lit instance is likely to need, and custom
 426 # variables can be passed in.
 427 function(configure_lit_site_cfg input output)
 428   foreach(c ${LLVM_TARGETS_TO_BUILD})
 429     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 430   endforeach(c)
 431   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 432
 433   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 434
 435   if(BUILD_SHARED_LIBS)
 436     set(LLVM_SHARED_LIBS_ENABLED "1")
 437   else()
 438     set(LLVM_SHARED_LIBS_ENABLED "0")
 439   endif(BUILD_SHARED_LIBS)
 440
 441   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 442     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 443   else() # Default for all other unix like systems.
 444     # CMake hardcodes the library locaction using rpath.
 445     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 446     # build dir. We pass it anyways.
 447     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 448   endif()
 449
 450   # Configuration-time: See Unit/lit.site.cfg.in
 451   if (CMAKE_CFG_INTDIR STREQUAL ".")
 452     set(LLVM_BUILD_MODE ".")
 453   else ()
 454     set(LLVM_BUILD_MODE "%(build_mode)s")
 455   endif ()
 456
 457   # They below might not be the build tree but provided binary tree.
 458   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 459   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 460   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 461   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 462
 463   # SHLIBDIR points the build tree.
 464   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 465
 466   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 467   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 468   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 469
 470   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 471     set(ENABLE_ASSERTIONS "1")
 472   else()
 473     set(ENABLE_ASSERTIONS "0")
 474   endif()
 475
 476   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 477   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 478
 479   if (CLANG_ENABLE_ARCMT)
 480     set(ENABLE_CLANG_ARCMT "1")
 481   else()
 482     set(ENABLE_CLANG_ARCMT "0")
 483   endif()
 484   if (CLANG_ENABLE_REWRITER)
 485     set(ENABLE_CLANG_REWRITER "1")
 486   else()
 487     set(ENABLE_CLANG_REWRITER "0")
 488   endif()
 489   if (CLANG_ENABLE_STATIC_ANALYZER)
 490     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 491   else()
 492     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 493   endif()
 494
 495   configure_file(${input} ${output} @ONLY)
 496 endfunction()
 497
 498 # A raw function to create a lit target. This is used to implement the testuite
 499 # management functions.
 500 function(add_lit_target target comment)
 501   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 502   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 503   separate_arguments(LIT_ARGS)
 504   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 505     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 506   endif ()
 507   set(LIT_COMMAND
 508     ${PYTHON_EXECUTABLE}
 509     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 510     ${LIT_ARGS}
 511     )
 512   foreach(param ${ARG_PARAMS})
 513     list(APPEND LIT_COMMAND --param ${param})
 514   endforeach()
 515   if( ARG_DEPENDS )
 516     add_custom_target(${target}
 517       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 518       COMMENT "${comment}"
 519       )
 520     add_dependencies(${target} ${ARG_DEPENDS})
 521   else()
 522     add_custom_target(${target}
 523       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 524     message(STATUS "${target} does nothing.")
 525   endif()
 526
 527   # Tests should be excluded from "Build Solution".
 528   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 529 endfunction()
 530
 531 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 532 function(add_lit_testsuite target comment)
 533   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 534
 535   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 536   if(NOT EXCLUDE_FROM_ALL)
 537     # Register the testsuites, params and depends for the global check rule.
 538     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 539     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 540     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 541     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 542   endif()
 543
 544   # Produce a specific suffixed check rule.
 545   add_lit_target(${target} ${comment}
 546     ${ARG_DEFAULT_ARGS}
 547     PARAMS ${ARG_PARAMS}
 548     DEPENDS ${ARG_DEPENDS}
 549     ARGS ${ARG_ARGS}
 550     )
 551 endfunction()