cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3
   4 function(llvm_update_compile_flags name)
   5   get_property(sources TARGET ${name} PROPERTY SOURCES)
   6   if("${sources}" MATCHES "\\.c(;|$)")
   7     set(update_src_props ON)
   8   endif()
   9
  10   # LLVM_REQUIRES_EH is an internal flag that individual
  11   # targets can use to force EH
  12   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  13     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  14       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  15       set(LLVM_REQUIRES_RTTI ON)
  16     endif()
  17   else()
  18     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  19       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  20     elseif(MSVC)
  21       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  22       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  23     endif()
  24     if (CLANG_CL)
  25       # FIXME: Remove this once clang-cl supports SEH
  26       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
  27     endif()
  28   endif()
  29
  30   # LLVM_REQUIRES_RTTI is an internal flag that individual
  31   # targets can use to force RTTI
  32   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  33     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  34     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  35       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  36     elseif (MSVC)
  37       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  38     endif ()
  39   endif()
  40
  41   # Assume that;
  42   #   - LLVM_COMPILE_FLAGS is list.
  43   #   - PROPERTY COMPILE_FLAGS is string.
  44   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  45
  46   if(update_src_props)
  47     foreach(fn ${sources})
  48       get_filename_component(suf ${fn} EXT)
  49       if("${suf}" STREQUAL ".cpp")
  50         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  51           COMPILE_FLAGS "${target_compile_flags}")
  52       endif()
  53     endforeach()
  54   else()
  55     # Update target props, since all sources are C++.
  56     set_property(TARGET ${name} APPEND_STRING PROPERTY
  57       COMPILE_FLAGS "${target_compile_flags}")
  58   endif()
  59
  60   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  61 endfunction()
  62
  63 function(add_llvm_symbol_exports target_name export_file)
  64   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  65     set(native_export_file "${target_name}.exports")
  66     add_custom_command(OUTPUT ${native_export_file}
  67       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  68       DEPENDS ${export_file}
  69       VERBATIM
  70       COMMENT "Creating export file for ${target_name}")
  71     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  72                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  73   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  74     # Gold and BFD ld require a version script rather than a plain list.
  75     set(native_export_file "${target_name}.exports")
  76     # FIXME: Don't write the "local:" line on OpenBSD.
  77     add_custom_command(OUTPUT ${native_export_file}
  78       COMMAND echo "{" > ${native_export_file}
  79       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  80       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  81       COMMAND echo "  local: *;" >> ${native_export_file}
  82       COMMAND echo "};" >> ${native_export_file}
  83       DEPENDS ${export_file}
  84       VERBATIM
  85       COMMENT "Creating export file for ${target_name}")
  86     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  87       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  88                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  89     else()
  90       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  91                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  92     endif()
  93   else()
  94     set(native_export_file "${target_name}.def")
  95
  96     add_custom_command(OUTPUT ${native_export_file}
  97       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
  98         < ${export_file} > ${native_export_file}
  99       DEPENDS ${export_file}
 100       VERBATIM
 101       COMMENT "Creating export file for ${target_name}")
 102     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 103     if(MSVC)
 104       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 105     endif()
 106     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 107                  LINK_FLAGS " ${export_file_linker_flag}")
 108   endif()
 109
 110   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 111   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 112
 113   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 114   foreach(src ${srcs})
 115     get_filename_component(extension ${src} EXT)
 116     if(extension STREQUAL ".cpp")
 117       set(first_source_file ${src})
 118       break()
 119     endif()
 120   endforeach()
 121
 122   # Force re-linking when the exports file changes. Actually, it
 123   # forces recompilation of the source file. The LINK_DEPENDS target
 124   # property only works for makefile-based generators.
 125   # FIXME: This is not safe because this will create the same target
 126   # ${native_export_file} in several different file:
 127   # - One where we emitted ${target_name}_exports
 128   # - One where we emitted the build command for the following object.
 129   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 130   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 131
 132   set_property(DIRECTORY APPEND
 133     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 134
 135   add_dependencies(${target_name} ${target_name}_exports)
 136
 137   # Add dependency to *_exports later -- CMake issue 14747
 138   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 139   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 140 endfunction(add_llvm_symbol_exports)
 141
 142 if(NOT WIN32 AND NOT APPLE)
 143   execute_process(
 144     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 145     OUTPUT_VARIABLE stdout
 146     ERROR_QUIET
 147     )
 148   if("${stdout}" MATCHES "GNU gold")
 149     set(LLVM_LINKER_IS_GOLD ON)
 150   endif()
 151 endif()
 152
 153 function(add_link_opts target_name)
 154   # Don't use linker optimizations in debug builds since it slows down the
 155   # linker in a context where the optimizations are not important.
 156   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 157
 158     # Pass -O3 to the linker. This enabled different optimizations on different
 159     # linkers.
 160     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 161       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 162                    LINK_FLAGS " -Wl,-O3")
 163     endif()
 164
 165     if(LLVM_LINKER_IS_GOLD)
 166       # With gold gc-sections is always safe.
 167       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 168                    LINK_FLAGS " -Wl,--gc-sections")
 169       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 170       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 171     endif()
 172
 173     if(NOT LLVM_NO_DEAD_STRIP)
 174       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 175         # ld64's implementation of -dead_strip breaks tools that use plugins.
 176         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 177                      LINK_FLAGS " -Wl,-dead_strip")
 178       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 179         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 180                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 181       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 182         # Object files are compiled with -ffunction-data-sections.
 183         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 184         # tools that use plugins. Always pass --gc-sections once we require
 185         # a newer linker.
 186         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 187                      LINK_FLAGS " -Wl,--gc-sections")
 188       endif()
 189     endif()
 190   endif()
 191 endfunction(add_link_opts)
 192
 193 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 194 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 195 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 196 function(set_output_directory target bindir libdir)
 197   # Do nothing if *_OUTPUT_INTDIR is empty.
 198   if("${bindir}" STREQUAL "")
 199     return()
 200   endif()
 201
 202   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 203   # It affects output of add_library(MODULE).
 204   if(WIN32 OR CYGWIN)
 205     # DLL platform
 206     set(moddir ${bindir})
 207   else()
 208     set(moddir ${libdir})
 209   endif()
 210   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 211     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 212       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 213       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 214       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 215       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 216       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 217       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 218       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 219     endforeach()
 220   else()
 221     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 222     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 223     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 224   endif()
 225 endfunction()
 226
 227 # If on Windows and building with MSVC, add the resource script containing the
 228 # VERSIONINFO data to the project.  This embeds version resource information
 229 # into the output .exe or .dll.
 230 # TODO: Enable for MinGW Windows builds too.
 231 #
 232 function(add_windows_version_resource_file OUT_VAR)
 233   set(sources ${ARGN})
 234   if (MSVC)
 235     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 236     if(EXISTS ${resource_file})
 237       set(sources ${sources} ${resource_file})
 238       source_group("Resource Files" ${resource_file})
 239       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 240     endif()
 241   endif(MSVC)
 242
 243   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 244 endfunction(add_windows_version_resource_file)
 245
 246 # set_windows_version_resource_properties(name resource_file...
 247 #   VERSION_MAJOR int
 248 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 249 #   VERSION_MINOR int
 250 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 251 #   VERSION_PATCHLEVEL int
 252 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 253 #   VERSION_STRING
 254 #     Optional version string (defaults to PACKAGE_VERSION)
 255 #   PRODUCT_NAME
 256 #     Optional product name string (defaults to "LLVM")
 257 #   )
 258 function(set_windows_version_resource_properties name resource_file)
 259   cmake_parse_arguments(ARG
 260     ""
 261     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 262     ""
 263     ${ARGN})
 264
 265   if (NOT DEFINED ARG_VERSION_MAJOR)
 266     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 267   endif()
 268
 269   if (NOT DEFINED ARG_VERSION_MINOR)
 270     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 271   endif()
 272
 273   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 274     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_STRING)
 278     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 279   endif()
 280
 281   if (NOT DEFINED ARG_PRODUCT_NAME)
 282     set(ARG_PRODUCT_NAME "LLVM")
 283   endif()
 284
 285   set_property(SOURCE ${resource_file}
 286                PROPERTY COMPILE_FLAGS /nologo)
 287   set_property(SOURCE ${resource_file}
 288                PROPERTY COMPILE_DEFINITIONS
 289                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 290                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 291                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 292                "RC_VERSION_FIELD_4=0"
 293                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 294                "RC_INTERNAL_NAME=\"${name}\""
 295                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 296                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 297 endfunction(set_windows_version_resource_properties)
 298
 299 # llvm_add_library(name sources...
 300 #   SHARED;STATIC
 301 #     STATIC by default w/o BUILD_SHARED_LIBS.
 302 #     SHARED by default w/  BUILD_SHARED_LIBS.
 303 #   MODULE
 304 #     Target ${name} might not be created on unsupported platforms.
 305 #     Check with "if(TARGET ${name})".
 306 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 307 #     Do not link this library to libLLVM, even if
 308 #     LLVM_LINK_LLVM_DYLIB is enabled.
 309 #   OUTPUT_NAME name
 310 #     Corresponds to OUTPUT_NAME in target properties.
 311 #   DEPENDS targets...
 312 #     Same semantics as add_dependencies().
 313 #   LINK_COMPONENTS components...
 314 #     Same as the variable LLVM_LINK_COMPONENTS.
 315 #   LINK_LIBS lib_targets...
 316 #     Same semantics as target_link_libraries().
 317 #   ADDITIONAL_HEADERS
 318 #     May specify header files for IDE generators.
 319 #   )
 320 function(llvm_add_library name)
 321   cmake_parse_arguments(ARG
 322     "MODULE;SHARED;STATIC;DISABLE_LLVM_LINK_LLVM_DYLIB"
 323     "OUTPUT_NAME"
 324     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 325     ${ARGN})
 326   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 327   if(ARG_ADDITIONAL_HEADERS)
 328     # Pass through ADDITIONAL_HEADERS.
 329     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 330   endif()
 331   if(ARG_OBJLIBS)
 332     set(ALL_FILES ${ARG_OBJLIBS})
 333   else()
 334     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 335   endif()
 336
 337   if(ARG_MODULE)
 338     if(ARG_SHARED OR ARG_STATIC)
 339       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 340     endif()
 341     if(NOT LLVM_ENABLE_PLUGINS)
 342       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 343       return()
 344     endif()
 345   else()
 346     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 347       set(ARG_SHARED TRUE)
 348     endif()
 349     if(NOT ARG_SHARED)
 350       set(ARG_STATIC TRUE)
 351     endif()
 352   endif()
 353
 354   # Generate objlib
 355   if(ARG_SHARED AND ARG_STATIC)
 356     # Generate an obj library for both targets.
 357     set(obj_name "obj.${name}")
 358     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 359       ${ALL_FILES}
 360       )
 361     llvm_update_compile_flags(${obj_name})
 362     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 363
 364     # Do add_dependencies(obj) later due to CMake issue 14747.
 365     list(APPEND objlibs ${obj_name})
 366
 367     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 368   endif()
 369
 370   if(ARG_SHARED AND ARG_STATIC)
 371     # static
 372     set(name_static "${name}_static")
 373     if(ARG_OUTPUT_NAME)
 374       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 375     endif()
 376     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 377     llvm_add_library(${name_static} STATIC
 378       ${output_name}
 379       OBJLIBS ${ALL_FILES} # objlib
 380       LINK_LIBS ${ARG_LINK_LIBS}
 381       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 382       )
 383     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 384     set(ARG_STATIC)
 385   endif()
 386
 387   if(ARG_MODULE)
 388     add_library(${name} MODULE ${ALL_FILES})
 389   elseif(ARG_SHARED)
 390     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 391     add_library(${name} SHARED ${ALL_FILES})
 392   else()
 393     add_library(${name} STATIC ${ALL_FILES})
 394   endif()
 395
 396   if(DEFINED windows_resource_file)
 397     set_windows_version_resource_properties(${name} ${windows_resource_file})
 398     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 399   endif()
 400
 401   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 402   # $<TARGET_OBJECTS> doesn't require compile flags.
 403   if(NOT obj_name)
 404     llvm_update_compile_flags(${name})
 405   endif()
 406   add_link_opts( ${name} )
 407   if(ARG_OUTPUT_NAME)
 408     set_target_properties(${name}
 409       PROPERTIES
 410       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 411       )
 412   endif()
 413
 414   if(ARG_MODULE)
 415     set_target_properties(${name} PROPERTIES
 416       PREFIX ""
 417       SUFFIX ${LLVM_PLUGIN_EXT}
 418       )
 419   endif()
 420
 421   if(ARG_SHARED)
 422     if(WIN32)
 423       set_target_properties(${name} PROPERTIES
 424         PREFIX ""
 425         )
 426     endif()
 427
 428     set_target_properties(${name}
 429       PROPERTIES
 430       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 431       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 432   endif()
 433
 434   if(ARG_MODULE OR ARG_SHARED)
 435     # Do not add -Dname_EXPORTS to the command-line when building files in this
 436     # target. Doing so is actively harmful for the modules build because it
 437     # creates extra module variants, and not useful because we don't use these
 438     # macros.
 439     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 440
 441     if (LLVM_EXPORTED_SYMBOL_FILE)
 442       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 443     endif()
 444   endif()
 445
 446   # Add the explicit dependency information for this library.
 447   #
 448   # It would be nice to verify that we have the dependencies for this library
 449   # name, but using get_property(... SET) doesn't suffice to determine if a
 450   # property has been set to an empty value.
 451   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 452
 453   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_STATIC AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 454     set(llvm_libs LLVM)
 455   else()
 456     llvm_map_components_to_libnames(llvm_libs
 457       ${ARG_LINK_COMPONENTS}
 458       ${LLVM_LINK_COMPONENTS}
 459       )
 460   endif()
 461
 462   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 463     # Link libs w/o keywords, assuming PUBLIC.
 464     target_link_libraries(${name}
 465       ${ARG_LINK_LIBS}
 466       ${lib_deps}
 467       ${llvm_libs}
 468       )
 469   elseif(ARG_STATIC)
 470     target_link_libraries(${name} INTERFACE
 471       ${ARG_LINK_LIBS}
 472       ${lib_deps}
 473       ${llvm_libs}
 474       )
 475   else()
 476     # We can use PRIVATE since SO knows its dependent libs.
 477     target_link_libraries(${name} PRIVATE
 478       ${ARG_LINK_LIBS}
 479       ${lib_deps}
 480       ${llvm_libs}
 481       )
 482   endif()
 483
 484   if(LLVM_COMMON_DEPENDS)
 485     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 486     # Add dependencies also to objlibs.
 487     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 488     foreach(objlib ${objlibs})
 489       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 490     endforeach()
 491   endif()
 492 endfunction()
 493
 494 macro(add_llvm_library name)
 495   cmake_parse_arguments(ARG
 496     "SHARED"
 497     ""
 498     ""
 499     ${ARGN})
 500   if( BUILD_SHARED_LIBS )
 501     llvm_add_library(${name} SHARED ${ARGN})
 502   else()
 503     llvm_add_library(${name} ${ARGN})
 504   endif()
 505   # The gtest libraries should not be installed or exported as a target
 506   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 507     set(_is_gtest TRUE)
 508   else()
 509     set(_is_gtest FALSE)
 510     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 511   endif()
 512
 513   if( EXCLUDE_FROM_ALL )
 514     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 515   elseif(NOT _is_gtest)
 516     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 517       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 518         if(WIN32 OR CYGWIN)
 519           set(install_type RUNTIME)
 520         else()
 521           set(install_type LIBRARY)
 522         endif()
 523       else()
 524         set(install_type ARCHIVE)
 525       endif()
 526
 527       install(TARGETS ${name}
 528             EXPORT LLVMExports
 529             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 530             COMPONENT ${name})
 531
 532       if (NOT CMAKE_CONFIGURATION_TYPES)
 533         add_custom_target(install-${name}
 534                           DEPENDS ${name}
 535                           COMMAND "${CMAKE_COMMAND}"
 536                                   -DCMAKE_INSTALL_COMPONENT=${name}
 537                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 538       endif()
 539     endif()
 540     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 541   endif()
 542   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 543 endmacro(add_llvm_library name)
 544
 545 macro(add_llvm_loadable_module name)
 546   llvm_add_library(${name} MODULE ${ARGN})
 547   if(NOT TARGET ${name})
 548     # Add empty "phony" target
 549     add_custom_target(${name})
 550   else()
 551     if( EXCLUDE_FROM_ALL )
 552       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 553     else()
 554       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 555         if(WIN32 OR CYGWIN)
 556           # DLL platform
 557           set(dlldir "bin")
 558         else()
 559           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 560         endif()
 561         install(TARGETS ${name}
 562           EXPORT LLVMExports
 563           LIBRARY DESTINATION ${dlldir}
 564           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 565       endif()
 566       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 567     endif()
 568   endif()
 569
 570   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 571 endmacro(add_llvm_loadable_module name)
 572
 573
 574 macro(add_llvm_executable name)
 575   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB" "" "" ${ARGN})
 576   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 577
 578   # Generate objlib
 579   if(LLVM_ENABLE_OBJLIB)
 580     # Generate an obj library for both targets.
 581     set(obj_name "obj.${name}")
 582     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 583       ${ALL_FILES}
 584       )
 585     llvm_update_compile_flags(${obj_name})
 586     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 587
 588     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 589   endif()
 590
 591   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 592
 593   if( EXCLUDE_FROM_ALL )
 594     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 595   else()
 596     add_executable(${name} ${ALL_FILES})
 597   endif()
 598
 599   if(DEFINED windows_resource_file)
 600     set_windows_version_resource_properties(${name} ${windows_resource_file})
 601   endif()
 602
 603   # $<TARGET_OBJECTS> doesn't require compile flags.
 604   if(NOT LLVM_ENABLE_OBJLIB)
 605     llvm_update_compile_flags(${name})
 606   endif()
 607   add_link_opts( ${name} )
 608
 609   # Do not add -Dname_EXPORTS to the command-line when building files in this
 610   # target. Doing so is actively harmful for the modules build because it
 611   # creates extra module variants, and not useful because we don't use these
 612   # macros.
 613   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 614
 615   if (LLVM_EXPORTED_SYMBOL_FILE)
 616     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 617   endif(LLVM_EXPORTED_SYMBOL_FILE)
 618
 619   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 620     set(USE_SHARED USE_SHARED)
 621   endif()
 622
 623   set(EXCLUDE_FROM_ALL OFF)
 624   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 625   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 626   if( LLVM_COMMON_DEPENDS )
 627     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 628   endif( LLVM_COMMON_DEPENDS )
 629 endmacro(add_llvm_executable name)
 630
 631 function(export_executable_symbols target)
 632   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 633     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 634   endif()
 635 endfunction()
 636
 637
 638 set (LLVM_TOOLCHAIN_TOOLS
 639   llvm-ar
 640   llvm-objdump
 641   )
 642
 643 macro(add_llvm_tool name)
 644   if( NOT LLVM_BUILD_TOOLS )
 645     set(EXCLUDE_FROM_ALL ON)
 646   endif()
 647   add_llvm_executable(${name} ${ARGN})
 648
 649   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 650   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 651     if( LLVM_BUILD_TOOLS )
 652       install(TARGETS ${name}
 653               EXPORT LLVMExports
 654               RUNTIME DESTINATION bin
 655               COMPONENT ${name})
 656
 657       if (NOT CMAKE_CONFIGURATION_TYPES)
 658         add_custom_target(install-${name}
 659                           DEPENDS ${name}
 660                           COMMAND "${CMAKE_COMMAND}"
 661                                   -DCMAKE_INSTALL_COMPONENT=${name}
 662                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 663       endif()
 664     endif()
 665   endif()
 666   if( LLVM_BUILD_TOOLS )
 667     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 668   endif()
 669   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 670 endmacro(add_llvm_tool name)
 671
 672
 673 macro(add_llvm_example name)
 674   if( NOT LLVM_BUILD_EXAMPLES )
 675     set(EXCLUDE_FROM_ALL ON)
 676   endif()
 677   add_llvm_executable(${name} ${ARGN})
 678   if( LLVM_BUILD_EXAMPLES )
 679     install(TARGETS ${name} RUNTIME DESTINATION examples)
 680   endif()
 681   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 682 endmacro(add_llvm_example name)
 683
 684
 685 macro(add_llvm_utility name)
 686   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 687   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 688   if( LLVM_INSTALL_UTILS )
 689     install (TARGETS ${name}
 690       RUNTIME DESTINATION bin
 691       COMPONENT ${name})
 692     if (NOT CMAKE_CONFIGURATION_TYPES)
 693       add_custom_target(install-${name}
 694                         DEPENDS ${name}
 695                         COMMAND "${CMAKE_COMMAND}"
 696                                 -DCMAKE_INSTALL_COMPONENT=${name}
 697                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 698     endif()
 699   endif()
 700 endmacro(add_llvm_utility name)
 701
 702
 703 macro(add_llvm_target target_name)
 704   include_directories(BEFORE
 705     ${CMAKE_CURRENT_BINARY_DIR}
 706     ${CMAKE_CURRENT_SOURCE_DIR})
 707   add_llvm_library(LLVM${target_name} ${ARGN})
 708   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 709 endmacro(add_llvm_target)
 710
 711 function(canonicalize_tool_name name output)
 712   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 713   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 714   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 715   set(${output} "${nameUPPER}" PARENT_SCOPE)
 716 endfunction(canonicalize_tool_name)
 717
 718 # Add external project that may want to be built as part of llvm such as Clang,
 719 # lld, and Polly. This adds two options. One for the source directory of the
 720 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 721 # enable or disable building it with everything else.
 722 # Additional parameter can be specified as the name of directory.
 723 macro(add_llvm_external_project name)
 724   set(add_llvm_external_dir "${ARGN}")
 725   if("${add_llvm_external_dir}" STREQUAL "")
 726     set(add_llvm_external_dir ${name})
 727   endif()
 728   canonicalize_tool_name(${name} nameUPPER)
 729   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 730     # Treat it as in-tree subproject.
 731     option(LLVM_TOOL_${nameUPPER}_BUILD
 732            "Whether to build ${name} as part of LLVM" On)
 733     mark_as_advanced(LLVM_TOOL_${name}_BUILD)
 734     if(LLVM_TOOL_${nameUPPER}_BUILD)
 735       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 736       # Don't process it in add_llvm_implicit_projects().
 737       set(LLVM_TOOL_${nameUPPER}_BUILD OFF)
 738     endif()
 739   else()
 740     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 741       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 742       CACHE PATH "Path to ${name} source directory")
 743     set(LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT ON)
 744     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 745       set(LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT OFF)
 746     endif()
 747     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 748       set(LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT OFF)
 749     endif()
 750     option(LLVM_TOOL_${nameUPPER}_BUILD
 751       "Whether to build ${name} as part of LLVM"
 752       ${LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT})
 753     if (LLVM_TOOL_${nameUPPER}_BUILD)
 754       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 755         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 756       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 757         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 758       endif()
 759       # FIXME: It'd be redundant.
 760       set(LLVM_TOOL_${nameUPPER}_BUILD Off)
 761     endif()
 762   endif()
 763 endmacro(add_llvm_external_project)
 764
 765 macro(add_llvm_tool_subdirectory name)
 766   add_llvm_external_project(${name})
 767 endmacro(add_llvm_tool_subdirectory)
 768
 769 function(get_project_name_from_src_var var output)
 770   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 771          MACHED_TOOL "${var}")
 772   if(MACHED_TOOL)
 773     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 774   else()
 775     set(${output} PARENT_SCOPE)
 776   endif()
 777 endfunction()
 778
 779 function(create_llvm_tool_options)
 780   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 781   foreach(dir ${sub-dirs})
 782     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 783       canonicalize_tool_name(${dir} name)
 784       option(LLVM_TOOL_${name}_BUILD
 785            "Whether to build ${name} as part of LLVM" On)
 786       mark_as_advanced(LLVM_TOOL_${name}_BUILD)
 787     endif()
 788   endforeach()
 789 endfunction(create_llvm_tool_options)
 790
 791 function(add_llvm_implicit_projects)
 792   set(list_of_implicit_subdirs "")
 793   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 794   foreach(dir ${sub-dirs})
 795     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 796       canonicalize_tool_name(${dir} name)
 797       if (LLVM_TOOL_${name}_BUILD)
 798         get_filename_component(fn "${dir}" NAME)
 799         list(APPEND list_of_implicit_subdirs "${fn}")
 800       endif()
 801     endif()
 802   endforeach()
 803
 804   foreach(external_proj ${list_of_implicit_subdirs})
 805     add_llvm_external_project("${external_proj}")
 806   endforeach()
 807 endfunction(add_llvm_implicit_projects)
 808
 809 # Generic support for adding a unittest.
 810 function(add_unittest test_suite test_name)
 811   if( NOT LLVM_BUILD_TESTS )
 812     set(EXCLUDE_FROM_ALL ON)
 813   endif()
 814
 815   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 816   if (NOT LLVM_ENABLE_THREADS)
 817     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 818   endif ()
 819
 820   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 821     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 822   endif ()
 823
 824   set(LLVM_REQUIRES_RTTI OFF)
 825
 826   add_llvm_executable(${test_name} ${ARGN})
 827   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 828   set_output_directory(${test_name} ${outdir} ${outdir})
 829   target_link_libraries(${test_name}
 830     gtest
 831     gtest_main
 832     LLVMSupport # gtest needs it for raw_ostream.
 833     )
 834
 835   add_dependencies(${test_suite} ${test_name})
 836   get_target_property(test_suite_folder ${test_suite} FOLDER)
 837   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 838     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 839   endif ()
 840 endfunction()
 841
 842 function(llvm_add_go_executable binary pkgpath)
 843   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 844
 845   if(LLVM_BINDINGS MATCHES "go")
 846     # FIXME: This should depend only on the libraries Go needs.
 847     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 848     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 849     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 850     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 851     set(cppflags "")
 852     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 853     foreach(d ${include_dirs})
 854       set(cppflags "${cppflags} -I${d}")
 855     endforeach(d)
 856     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 857     if (LLVM_LINK_LLVM_DYLIB)
 858       set(linkmode "dylib")
 859     else()
 860       set(linkmode "component-libs")
 861     endif()
 862     add_custom_command(OUTPUT ${binpath}
 863       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "linkmode=${linkmode}"
 864               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 865       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 866               ${llvmlibs} ${ARG_DEPENDS}
 867       COMMENT "Building Go executable ${binary}"
 868       VERBATIM)
 869     if (ARG_ALL)
 870       add_custom_target(${binary} ALL DEPENDS ${binpath})
 871     else()
 872       add_custom_target(${binary} DEPENDS ${binpath})
 873     endif()
 874   endif()
 875 endfunction()
 876
 877 # This function provides an automatic way to 'configure'-like generate a file
 878 # based on a set of common and custom variables, specifically targeting the
 879 # variables needed for the 'lit.site.cfg' files. This function bundles the
 880 # common variables that any Lit instance is likely to need, and custom
 881 # variables can be passed in.
 882 function(configure_lit_site_cfg input output)
 883   foreach(c ${LLVM_TARGETS_TO_BUILD})
 884     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 885   endforeach(c)
 886   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 887
 888   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 889
 890   # Configuration-time: See Unit/lit.site.cfg.in
 891   if (CMAKE_CFG_INTDIR STREQUAL ".")
 892     set(LLVM_BUILD_MODE ".")
 893   else ()
 894     set(LLVM_BUILD_MODE "%(build_mode)s")
 895   endif ()
 896
 897   # They below might not be the build tree but provided binary tree.
 898   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 899   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 900   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 901   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 902
 903   # SHLIBDIR points the build tree.
 904   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 905
 906   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 907   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 908   # plugins. We may rename it.
 909   if(LLVM_ENABLE_PLUGINS)
 910     set(ENABLE_SHARED "1")
 911   else()
 912     set(ENABLE_SHARED "0")
 913   endif()
 914
 915   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 916     set(ENABLE_ASSERTIONS "1")
 917   else()
 918     set(ENABLE_ASSERTIONS "0")
 919   endif()
 920
 921   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 922   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 923
 924   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 925   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 926   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 927
 928   configure_file(${input} ${output} @ONLY)
 929 endfunction()
 930
 931 # A raw function to create a lit target. This is used to implement the testuite
 932 # management functions.
 933 function(add_lit_target target comment)
 934   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 935   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 936   separate_arguments(LIT_ARGS)
 937   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 938     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 939   endif ()
 940   if (LLVM_MAIN_SRC_DIR)
 941     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 942   else()
 943     find_program(LIT_COMMAND llvm-lit)
 944   endif ()
 945   list(APPEND LIT_COMMAND ${LIT_ARGS})
 946   foreach(param ${ARG_PARAMS})
 947     list(APPEND LIT_COMMAND --param ${param})
 948   endforeach()
 949   if (ARG_UNPARSED_ARGUMENTS)
 950     add_custom_target(${target}
 951       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 952       COMMENT "${comment}"
 953       ${cmake_3_2_USES_TERMINAL}
 954       )
 955   else()
 956     add_custom_target(${target}
 957       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 958     message(STATUS "${target} does nothing.")
 959   endif()
 960   if (ARG_DEPENDS)
 961     add_dependencies(${target} ${ARG_DEPENDS})
 962   endif()
 963
 964   # Tests should be excluded from "Build Solution".
 965   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 966 endfunction()
 967
 968 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 969 function(add_lit_testsuite target comment)
 970   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 971
 972   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 973   if(NOT EXCLUDE_FROM_ALL)
 974     # Register the testsuites, params and depends for the global check rule.
 975     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
 976     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 977     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 978     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 979   endif()
 980
 981   # Produce a specific suffixed check rule.
 982   add_lit_target(${target} ${comment}
 983     ${ARG_UNPARSED_ARGUMENTS}
 984     PARAMS ${ARG_PARAMS}
 985     DEPENDS ${ARG_DEPENDS}
 986     ARGS ${ARG_ARGS}
 987     )
 988 endfunction()
 989
 990 function(add_lit_testsuites project directory)
 991   if (NOT CMAKE_CONFIGURATION_TYPES)
 992     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 993     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
 994     set(lit_suites)
 995     foreach(f ${litCfg})
 996       get_filename_component(dir ${f} DIRECTORY)
 997       set(lit_suites ${lit_suites} ${dir})
 998     endforeach()
 999     list(REMOVE_DUPLICATES lit_suites)
1000     foreach(dir ${lit_suites})
1001       string(REPLACE ${directory} "" name_slash ${dir})
1002       if (name_slash)
1003         string(REPLACE "/" "-" name_slash ${name_slash})
1004         string(REPLACE "\\" "-" name_dashes ${name_slash})
1005         string(TOLOWER "${project}${name_dashes}" name_var)
1006         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
1007           ${dir}
1008           PARAMS ${ARG_PARAMS}
1009           DEPENDS ${ARG_DEPENDS}
1010           ARGS ${ARG_ARGS}
1011         )
1012       endif()
1013     endforeach()
1014   endif()
1015 endfunction()