cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130 endfunction(add_llvm_symbol_exports)
 131
 132 function(add_dead_strip target_name)
 133   if(NOT LLVM_NO_DEAD_STRIP)
 134     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 135       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 136                    LINK_FLAGS " -Wl,-dead_strip")
 137     elseif(NOT WIN32)
 138       # Object files are compiled with -ffunction-data-sections.
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,--gc-sections")
 141     endif()
 142   endif()
 143 endfunction(add_dead_strip)
 144
 145 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 146 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 147 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 148 function(set_output_directory target bindir libdir)
 149   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 150     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 151       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 152       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 153       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 154       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 155       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 156       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 157     endforeach()
 158   else()
 159     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 160     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 161     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${libdir})
 162   endif()
 163 endfunction()
 164
 165 macro(add_llvm_library name)
 166   llvm_process_sources( ALL_FILES ${ARGN} )
 167   add_library( ${name} ${ALL_FILES} )
 168   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 169   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 170   llvm_update_compile_flags(${name})
 171   add_dead_strip( ${name} )
 172   if( LLVM_COMMON_DEPENDS )
 173     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 174   endif( LLVM_COMMON_DEPENDS )
 175
 176   if( BUILD_SHARED_LIBS )
 177     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 178     if (MSVC)
 179       set_target_properties(${name}
 180         PROPERTIES
 181         IMPORT_SUFFIX ".imp")
 182     endif ()
 183
 184     if (LLVM_EXPORTED_SYMBOL_FILE)
 185       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 186     endif()
 187   endif()
 188
 189   # Ensure that the system libraries always comes last on the
 190   # list. Without this, linking the unit tests on MinGW fails.
 191   link_system_libs( ${name} )
 192
 193   if( EXCLUDE_FROM_ALL )
 194     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 195   else()
 196     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 197       install(TARGETS ${name}
 198         EXPORT LLVMExports
 199         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 200         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 201     endif()
 202   endif()
 203   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 204
 205   # Add the explicit dependency information for this library.
 206   #
 207   # It would be nice to verify that we have the dependencies for this library
 208   # name, but using get_property(... SET) doesn't suffice to determine if a
 209   # property has been set to an empty value.
 210   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 211   target_link_libraries(${name} ${lib_deps})
 212 endmacro(add_llvm_library name)
 213
 214 macro(add_llvm_loadable_module name)
 215   if( NOT LLVM_ON_UNIX OR CYGWIN )
 216     message(STATUS "Loadable modules not supported on this platform.
 217 ${name} ignored.")
 218     # Add empty "phony" target
 219     add_custom_target(${name})
 220   else()
 221     llvm_process_sources( ALL_FILES ${ARGN} )
 222     add_library(${name} MODULE ${ALL_FILES})
 223     set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 224     set_target_properties( ${name} PROPERTIES PREFIX "" )
 225     llvm_update_compile_flags(${name})
 226     add_dead_strip( ${name} )
 227
 228     if (LLVM_EXPORTED_SYMBOL_FILE)
 229       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 230     endif(LLVM_EXPORTED_SYMBOL_FILE)
 231
 232     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 233     link_system_libs( ${name} )
 234
 235     if (APPLE)
 236       # Darwin-specific linker flags for loadable modules.
 237       set_property(TARGET ${name} APPEND_STRING PROPERTY
 238         LINK_FLAGS " -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 239     endif()
 240
 241     if (MODULE)
 242       set_property(TARGET ${name} PROPERTY SUFFIX ${LLVM_PLUGIN_EXT})
 243     endif ()
 244
 245     if( EXCLUDE_FROM_ALL )
 246       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 247     else()
 248       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 249         install(TARGETS ${name}
 250           EXPORT LLVMExports
 251           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 252           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 253       endif()
 254     endif()
 255   endif()
 256
 257   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 258 endmacro(add_llvm_loadable_module name)
 259
 260
 261 macro(add_llvm_executable name)
 262   llvm_process_sources( ALL_FILES ${ARGN} )
 263   if( EXCLUDE_FROM_ALL )
 264     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 265   else()
 266     add_executable(${name} ${ALL_FILES})
 267   endif()
 268   llvm_update_compile_flags(${name})
 269   add_dead_strip( ${name} )
 270
 271   if (LLVM_EXPORTED_SYMBOL_FILE)
 272     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 273   endif(LLVM_EXPORTED_SYMBOL_FILE)
 274
 275   set(EXCLUDE_FROM_ALL OFF)
 276   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 277   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 278   if( LLVM_COMMON_DEPENDS )
 279     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 280   endif( LLVM_COMMON_DEPENDS )
 281   link_system_libs( ${name} )
 282 endmacro(add_llvm_executable name)
 283
 284
 285 set (LLVM_TOOLCHAIN_TOOLS
 286   llvm-ar
 287   llvm-objdump
 288   )
 289
 290 macro(add_llvm_tool name)
 291   if( NOT LLVM_BUILD_TOOLS )
 292     set(EXCLUDE_FROM_ALL ON)
 293   endif()
 294   add_llvm_executable(${name} ${ARGN})
 295
 296   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 297   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 298     if( LLVM_BUILD_TOOLS )
 299       install(TARGETS ${name}
 300               EXPORT LLVMExports
 301               RUNTIME DESTINATION bin)
 302     endif()
 303   endif()
 304   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 305 endmacro(add_llvm_tool name)
 306
 307
 308 macro(add_llvm_example name)
 309   if( NOT LLVM_BUILD_EXAMPLES )
 310     set(EXCLUDE_FROM_ALL ON)
 311   endif()
 312   add_llvm_executable(${name} ${ARGN})
 313   if( LLVM_BUILD_EXAMPLES )
 314     install(TARGETS ${name} RUNTIME DESTINATION examples)
 315   endif()
 316   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 317 endmacro(add_llvm_example name)
 318
 319
 320 macro(add_llvm_utility name)
 321   add_llvm_executable(${name} ${ARGN})
 322   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 323 endmacro(add_llvm_utility name)
 324
 325
 326 macro(add_llvm_target target_name)
 327   include_directories(BEFORE
 328     ${CMAKE_CURRENT_BINARY_DIR}
 329     ${CMAKE_CURRENT_SOURCE_DIR})
 330   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 331   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 332 endmacro(add_llvm_target)
 333
 334 # Add external project that may want to be built as part of llvm such as Clang,
 335 # lld, and Polly. This adds two options. One for the source directory of the
 336 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 337 # enable or disable building it with everything else.
 338 # Additional parameter can be specified as the name of directory.
 339 macro(add_llvm_external_project name)
 340   set(add_llvm_external_dir "${ARGN}")
 341   if("${add_llvm_external_dir}" STREQUAL "")
 342     set(add_llvm_external_dir ${name})
 343   endif()
 344   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 345   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 346   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 347   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 348       CACHE PATH "Path to ${name} source directory")
 349   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 350       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 351     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 352            "Whether to build ${name} as part of LLVM" ON)
 353     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 354       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 355     endif()
 356   endif()
 357 endmacro(add_llvm_external_project)
 358
 359 macro(add_llvm_tool_subdirectory name)
 360   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 361   add_subdirectory(${name})
 362 endmacro(add_llvm_tool_subdirectory)
 363
 364 macro(ignore_llvm_tool_subdirectory name)
 365   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 366 endmacro(ignore_llvm_tool_subdirectory)
 367
 368 function(add_llvm_implicit_external_projects)
 369   set(list_of_implicit_subdirs "")
 370   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 371   foreach(dir ${sub-dirs})
 372     if(IS_DIRECTORY "${dir}")
 373       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 374       if( tool_subdir_ignore EQUAL -1
 375           AND EXISTS "${dir}/CMakeLists.txt")
 376         get_filename_component(fn "${dir}" NAME)
 377         list(APPEND list_of_implicit_subdirs "${fn}")
 378       endif()
 379     endif()
 380   endforeach()
 381
 382   foreach(external_proj ${list_of_implicit_subdirs})
 383     add_llvm_external_project("${external_proj}")
 384   endforeach()
 385 endfunction(add_llvm_implicit_external_projects)
 386
 387 # Generic support for adding a unittest.
 388 function(add_unittest test_suite test_name)
 389   if( NOT LLVM_BUILD_TESTS )
 390     set(EXCLUDE_FROM_ALL ON)
 391   endif()
 392
 393   # Visual Studio 2012 only supports up to 8 template parameters in
 394   # std::tr1::tuple by default, but gtest requires 10
 395   if (MSVC AND MSVC_VERSION EQUAL 1700)
 396     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 397   endif ()
 398
 399   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 400   if (NOT LLVM_ENABLE_THREADS)
 401     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 402   endif ()
 403
 404   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 405     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 406   endif ()
 407
 408   set(LLVM_REQUIRES_RTTI OFF)
 409
 410   add_llvm_executable(${test_name} ${ARGN})
 411   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 412   set_output_directory(${test_name} ${outdir} ${outdir})
 413   target_link_libraries(${test_name}
 414     gtest
 415     gtest_main
 416     LLVMSupport # gtest needs it for raw_ostream.
 417     )
 418
 419   add_dependencies(${test_suite} ${test_name})
 420   get_target_property(test_suite_folder ${test_suite} FOLDER)
 421   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 422     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 423   endif ()
 424 endfunction()
 425
 426 # This function provides an automatic way to 'configure'-like generate a file
 427 # based on a set of common and custom variables, specifically targeting the
 428 # variables needed for the 'lit.site.cfg' files. This function bundles the
 429 # common variables that any Lit instance is likely to need, and custom
 430 # variables can be passed in.
 431 function(configure_lit_site_cfg input output)
 432   foreach(c ${LLVM_TARGETS_TO_BUILD})
 433     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 434   endforeach(c)
 435   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 436
 437   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 438
 439   if(BUILD_SHARED_LIBS)
 440     set(LLVM_SHARED_LIBS_ENABLED "1")
 441   else()
 442     set(LLVM_SHARED_LIBS_ENABLED "0")
 443   endif(BUILD_SHARED_LIBS)
 444
 445   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 446     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 447   else() # Default for all other unix like systems.
 448     # CMake hardcodes the library locaction using rpath.
 449     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 450     # build dir. We pass it anyways.
 451     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 452   endif()
 453
 454   # Configuration-time: See Unit/lit.site.cfg.in
 455   if (CMAKE_CFG_INTDIR STREQUAL ".")
 456     set(LLVM_BUILD_MODE ".")
 457   else ()
 458     set(LLVM_BUILD_MODE "%(build_mode)s")
 459   endif ()
 460
 461   # They below might not be the build tree but provided binary tree.
 462   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 463   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 464   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 465   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 466
 467   # SHLIBDIR points the build tree.
 468   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 469
 470   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 471   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 472   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 473
 474   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 475     set(ENABLE_ASSERTIONS "1")
 476   else()
 477     set(ENABLE_ASSERTIONS "0")
 478   endif()
 479
 480   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 481   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 482
 483   if (CLANG_ENABLE_ARCMT)
 484     set(ENABLE_CLANG_ARCMT "1")
 485   else()
 486     set(ENABLE_CLANG_ARCMT "0")
 487   endif()
 488   if (CLANG_ENABLE_REWRITER)
 489     set(ENABLE_CLANG_REWRITER "1")
 490   else()
 491     set(ENABLE_CLANG_REWRITER "0")
 492   endif()
 493   if (CLANG_ENABLE_STATIC_ANALYZER)
 494     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 495   else()
 496     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 497   endif()
 498
 499   configure_file(${input} ${output} @ONLY)
 500 endfunction()
 501
 502 # A raw function to create a lit target. This is used to implement the testuite
 503 # management functions.
 504 function(add_lit_target target comment)
 505   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 506   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 507   separate_arguments(LIT_ARGS)
 508   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 509     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 510   endif ()
 511   set(LIT_COMMAND
 512     ${PYTHON_EXECUTABLE}
 513     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 514     ${LIT_ARGS}
 515     )
 516   foreach(param ${ARG_PARAMS})
 517     list(APPEND LIT_COMMAND --param ${param})
 518   endforeach()
 519   if( ARG_DEPENDS )
 520     add_custom_target(${target}
 521       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 522       COMMENT "${comment}"
 523       )
 524     add_dependencies(${target} ${ARG_DEPENDS})
 525   else()
 526     add_custom_target(${target}
 527       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 528     message(STATUS "${target} does nothing.")
 529   endif()
 530
 531   # Tests should be excluded from "Build Solution".
 532   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 533 endfunction()
 534
 535 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 536 function(add_lit_testsuite target comment)
 537   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 538
 539   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 540   if(NOT EXCLUDE_FROM_ALL)
 541     # Register the testsuites, params and depends for the global check rule.
 542     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 543     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 544     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 545     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 546   endif()
 547
 548   # Produce a specific suffixed check rule.
 549   add_lit_target(${target} ${comment}
 550     ${ARG_DEFAULT_ARGS}
 551     PARAMS ${ARG_PARAMS}
 552     DEPENDS ${ARG_DEPENDS}
 553     ARGS ${ARG_ARGS}
 554     )
 555 endfunction()