cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3 include(DetermineGCCCompatible)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   set(LLVM_CONFIG_HAS_RTTI YES CACHE INTERNAL "")
  30   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  31     set(LLVM_CONFIG_HAS_RTTI NO CACHE INTERNAL "")
  32     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  33     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  34       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  35     elseif (MSVC)
  36       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  37     endif ()
  38   endif()
  39
  40   # Assume that;
  41   #   - LLVM_COMPILE_FLAGS is list.
  42   #   - PROPERTY COMPILE_FLAGS is string.
  43   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  44
  45   if(update_src_props)
  46     foreach(fn ${sources})
  47       get_filename_component(suf ${fn} EXT)
  48       if("${suf}" STREQUAL ".cpp")
  49         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  50           COMPILE_FLAGS "${target_compile_flags}")
  51       endif()
  52     endforeach()
  53   else()
  54     # Update target props, since all sources are C++.
  55     set_property(TARGET ${name} APPEND_STRING PROPERTY
  56       COMPILE_FLAGS "${target_compile_flags}")
  57   endif()
  58
  59   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  60 endfunction()
  61
  62 function(add_llvm_symbol_exports target_name export_file)
  63   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  64     set(native_export_file "${target_name}.exports")
  65     add_custom_command(OUTPUT ${native_export_file}
  66       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  67       DEPENDS ${export_file}
  68       VERBATIM
  69       COMMENT "Creating export file for ${target_name}")
  70     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  71                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  72   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  73     # Gold and BFD ld require a version script rather than a plain list.
  74     set(native_export_file "${target_name}.exports")
  75     # FIXME: Don't write the "local:" line on OpenBSD.
  76     add_custom_command(OUTPUT ${native_export_file}
  77       COMMAND echo "{" > ${native_export_file}
  78       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  79       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  80       COMMAND echo "  local: *;" >> ${native_export_file}
  81       COMMAND echo "};" >> ${native_export_file}
  82       DEPENDS ${export_file}
  83       VERBATIM
  84       COMMENT "Creating export file for ${target_name}")
  85     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  86       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  87                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  88     else()
  89       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  90                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  91     endif()
  92   else()
  93     set(native_export_file "${target_name}.def")
  94
  95     add_custom_command(OUTPUT ${native_export_file}
  96       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
  97         < ${export_file} > ${native_export_file}
  98       DEPENDS ${export_file}
  99       VERBATIM
 100       COMMENT "Creating export file for ${target_name}")
 101     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 102     if(MSVC)
 103       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 104     endif()
 105     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 106                  LINK_FLAGS " ${export_file_linker_flag}")
 107   endif()
 108
 109   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 110   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 111
 112   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 113   foreach(src ${srcs})
 114     get_filename_component(extension ${src} EXT)
 115     if(extension STREQUAL ".cpp")
 116       set(first_source_file ${src})
 117       break()
 118     endif()
 119   endforeach()
 120
 121   # Force re-linking when the exports file changes. Actually, it
 122   # forces recompilation of the source file. The LINK_DEPENDS target
 123   # property only works for makefile-based generators.
 124   # FIXME: This is not safe because this will create the same target
 125   # ${native_export_file} in several different file:
 126   # - One where we emitted ${target_name}_exports
 127   # - One where we emitted the build command for the following object.
 128   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 129   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 130
 131   set_property(DIRECTORY APPEND
 132     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 133
 134   add_dependencies(${target_name} ${target_name}_exports)
 135
 136   # Add dependency to *_exports later -- CMake issue 14747
 137   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 138   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 139 endfunction(add_llvm_symbol_exports)
 140
 141 if(NOT WIN32 AND NOT APPLE)
 142   execute_process(
 143     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 144     OUTPUT_VARIABLE stdout
 145     ERROR_QUIET
 146     )
 147   if("${stdout}" MATCHES "GNU gold")
 148     set(LLVM_LINKER_IS_GOLD ON)
 149   endif()
 150 endif()
 151
 152 function(add_link_opts target_name)
 153   # Don't use linker optimizations in debug builds since it slows down the
 154   # linker in a context where the optimizations are not important.
 155   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 156
 157     # Pass -O3 to the linker. This enabled different optimizations on different
 158     # linkers.
 159     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 160       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 161                    LINK_FLAGS " -Wl,-O3")
 162     endif()
 163
 164     if(LLVM_LINKER_IS_GOLD)
 165       # With gold gc-sections is always safe.
 166       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 167                    LINK_FLAGS " -Wl,--gc-sections")
 168       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 169       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 170     endif()
 171
 172     if(NOT LLVM_NO_DEAD_STRIP)
 173       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 174         # ld64's implementation of -dead_strip breaks tools that use plugins.
 175         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 176                      LINK_FLAGS " -Wl,-dead_strip")
 177       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 178         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 179                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 180       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 181         # Object files are compiled with -ffunction-data-sections.
 182         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 183         # tools that use plugins. Always pass --gc-sections once we require
 184         # a newer linker.
 185         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 186                      LINK_FLAGS " -Wl,--gc-sections")
 187       endif()
 188     endif()
 189   endif()
 190 endfunction(add_link_opts)
 191
 192 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 193 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 194 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 195 function(set_output_directory target)
 196   cmake_parse_arguments(ARG "" "BINARY_DIR;LIBRARY_DIR" "" ${ARGN})
 197
 198   # module_dir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 199   # It affects output of add_library(MODULE).
 200   if(WIN32 OR CYGWIN)
 201     # DLL platform
 202     set(module_dir ${ARG_BINARY_DIR})
 203   else()
 204     set(module_dir ${ARG_LIBRARY_DIR})
 205   endif()
 206   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 207     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 208       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 209       if(ARG_BINARY_DIR)
 210         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${ARG_BINARY_DIR})
 211         set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 212       endif()
 213       if(ARG_LIBRARY_DIR)
 214         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${ARG_LIBRARY_DIR})
 215         set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 216       endif()
 217       if(module_dir)
 218         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${module_dir})
 219         set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 220       endif()
 221     endforeach()
 222   else()
 223     if(ARG_BINARY_DIR)
 224       set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${ARG_BINARY_DIR})
 225     endif()
 226     if(ARG_LIBRARY_DIR)
 227       set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${ARG_LIBRARY_DIR})
 228     endif()
 229     if(module_dir)
 230       set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${module_dir})
 231     endif()
 232   endif()
 233 endfunction()
 234
 235 # If on Windows and building with MSVC, add the resource script containing the
 236 # VERSIONINFO data to the project.  This embeds version resource information
 237 # into the output .exe or .dll.
 238 # TODO: Enable for MinGW Windows builds too.
 239 #
 240 function(add_windows_version_resource_file OUT_VAR)
 241   set(sources ${ARGN})
 242   if (MSVC)
 243     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 244     if(EXISTS ${resource_file})
 245       set(sources ${sources} ${resource_file})
 246       source_group("Resource Files" ${resource_file})
 247       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 248     endif()
 249   endif(MSVC)
 250
 251   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 252 endfunction(add_windows_version_resource_file)
 253
 254 # set_windows_version_resource_properties(name resource_file...
 255 #   VERSION_MAJOR int
 256 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 257 #   VERSION_MINOR int
 258 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 259 #   VERSION_PATCHLEVEL int
 260 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 261 #   VERSION_STRING
 262 #     Optional version string (defaults to PACKAGE_VERSION)
 263 #   PRODUCT_NAME
 264 #     Optional product name string (defaults to "LLVM")
 265 #   )
 266 function(set_windows_version_resource_properties name resource_file)
 267   cmake_parse_arguments(ARG
 268     ""
 269     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 270     ""
 271     ${ARGN})
 272
 273   if (NOT DEFINED ARG_VERSION_MAJOR)
 274     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_MINOR)
 278     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 279   endif()
 280
 281   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 282     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 283   endif()
 284
 285   if (NOT DEFINED ARG_VERSION_STRING)
 286     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 287   endif()
 288
 289   if (NOT DEFINED ARG_PRODUCT_NAME)
 290     set(ARG_PRODUCT_NAME "LLVM")
 291   endif()
 292
 293   set_property(SOURCE ${resource_file}
 294                PROPERTY COMPILE_FLAGS /nologo)
 295   set_property(SOURCE ${resource_file}
 296                PROPERTY COMPILE_DEFINITIONS
 297                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 298                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 299                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 300                "RC_VERSION_FIELD_4=0"
 301                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 302                "RC_INTERNAL_NAME=\"${name}\""
 303                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 304                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 305 endfunction(set_windows_version_resource_properties)
 306
 307 # llvm_add_library(name sources...
 308 #   SHARED;STATIC
 309 #     STATIC by default w/o BUILD_SHARED_LIBS.
 310 #     SHARED by default w/  BUILD_SHARED_LIBS.
 311 #   MODULE
 312 #     Target ${name} might not be created on unsupported platforms.
 313 #     Check with "if(TARGET ${name})".
 314 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 315 #     Do not link this library to libLLVM, even if
 316 #     LLVM_LINK_LLVM_DYLIB is enabled.
 317 #   OUTPUT_NAME name
 318 #     Corresponds to OUTPUT_NAME in target properties.
 319 #   DEPENDS targets...
 320 #     Same semantics as add_dependencies().
 321 #   LINK_COMPONENTS components...
 322 #     Same as the variable LLVM_LINK_COMPONENTS.
 323 #   LINK_LIBS lib_targets...
 324 #     Same semantics as target_link_libraries().
 325 #   ADDITIONAL_HEADERS
 326 #     May specify header files for IDE generators.
 327 #   SONAME
 328 #     Should set SONAME link flags and create symlinks
 329 #   )
 330 function(llvm_add_library name)
 331   cmake_parse_arguments(ARG
 332     "MODULE;SHARED;STATIC;DISABLE_LLVM_LINK_LLVM_DYLIB;SONAME"
 333     "OUTPUT_NAME"
 334     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 335     ${ARGN})
 336   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 337   if(ARG_ADDITIONAL_HEADERS)
 338     # Pass through ADDITIONAL_HEADERS.
 339     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 340   endif()
 341   if(ARG_OBJLIBS)
 342     set(ALL_FILES ${ARG_OBJLIBS})
 343   else()
 344     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 345   endif()
 346
 347   if(ARG_MODULE)
 348     if(ARG_SHARED OR ARG_STATIC)
 349       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 350     endif()
 351     if(NOT LLVM_ENABLE_PLUGINS)
 352       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 353       return()
 354     endif()
 355   else()
 356     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 357       set(ARG_SHARED TRUE)
 358     endif()
 359     if(NOT ARG_SHARED)
 360       set(ARG_STATIC TRUE)
 361     endif()
 362   endif()
 363
 364   # Generate objlib
 365   if(ARG_SHARED AND ARG_STATIC)
 366     # Generate an obj library for both targets.
 367     set(obj_name "obj.${name}")
 368     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 369       ${ALL_FILES}
 370       )
 371     llvm_update_compile_flags(${obj_name})
 372     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 373
 374     # Do add_dependencies(obj) later due to CMake issue 14747.
 375     list(APPEND objlibs ${obj_name})
 376
 377     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 378   endif()
 379
 380   if(ARG_SHARED AND ARG_STATIC)
 381     # static
 382     set(name_static "${name}_static")
 383     if(ARG_OUTPUT_NAME)
 384       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 385     endif()
 386     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 387     llvm_add_library(${name_static} STATIC
 388       ${output_name}
 389       OBJLIBS ${ALL_FILES} # objlib
 390       LINK_LIBS ${ARG_LINK_LIBS}
 391       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 392       )
 393     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 394     set(ARG_STATIC)
 395   endif()
 396
 397   if(ARG_MODULE)
 398     add_library(${name} MODULE ${ALL_FILES})
 399   elseif(ARG_SHARED)
 400     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 401     add_library(${name} SHARED ${ALL_FILES})
 402   else()
 403     add_library(${name} STATIC ${ALL_FILES})
 404   endif()
 405
 406   if(DEFINED windows_resource_file)
 407     set_windows_version_resource_properties(${name} ${windows_resource_file})
 408     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 409   endif()
 410
 411   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 412   # $<TARGET_OBJECTS> doesn't require compile flags.
 413   if(NOT obj_name)
 414     llvm_update_compile_flags(${name})
 415   endif()
 416   add_link_opts( ${name} )
 417   if(ARG_OUTPUT_NAME)
 418     set_target_properties(${name}
 419       PROPERTIES
 420       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 421       )
 422   endif()
 423
 424   if(ARG_MODULE)
 425     set_target_properties(${name} PROPERTIES
 426       PREFIX ""
 427       SUFFIX ${LLVM_PLUGIN_EXT}
 428       )
 429   endif()
 430
 431   if(ARG_SHARED)
 432     if(WIN32)
 433       set_target_properties(${name} PROPERTIES
 434         PREFIX ""
 435         )
 436     endif()
 437   endif()
 438
 439   if(ARG_MODULE OR ARG_SHARED)
 440     # Do not add -Dname_EXPORTS to the command-line when building files in this
 441     # target. Doing so is actively harmful for the modules build because it
 442     # creates extra module variants, and not useful because we don't use these
 443     # macros.
 444     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 445
 446     if (LLVM_EXPORTED_SYMBOL_FILE)
 447       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 448     endif()
 449   endif()
 450
 451   if(ARG_SHARED AND UNIX)
 452     if(NOT APPLE AND ARG_SONAME)
 453       get_target_property(output_name ${name} OUTPUT_NAME)
 454       if(${output_name} STREQUAL "output_name-NOTFOUND")
 455         set(output_name ${name})
 456       endif()
 457       set(library_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}${LLVM_VERSION_SUFFIX})
 458       set(api_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 459       set_target_properties(${name} PROPERTIES OUTPUT_NAME ${library_name})
 460       llvm_install_library_symlink(${api_name} ${library_name} SHARED
 461         COMPONENT ${name}
 462         ALWAYS_GENERATE)
 463       llvm_install_library_symlink(${output_name} ${library_name} SHARED
 464         COMPONENT ${name}
 465         ALWAYS_GENERATE)
 466     endif()
 467   endif()
 468
 469   # Add the explicit dependency information for this library.
 470   #
 471   # It would be nice to verify that we have the dependencies for this library
 472   # name, but using get_property(... SET) doesn't suffice to determine if a
 473   # property has been set to an empty value.
 474   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 475
 476   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_STATIC AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 477     set(llvm_libs LLVM)
 478   else()
 479     llvm_map_components_to_libnames(llvm_libs
 480       ${ARG_LINK_COMPONENTS}
 481       ${LLVM_LINK_COMPONENTS}
 482       )
 483   endif()
 484
 485   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 486     # Link libs w/o keywords, assuming PUBLIC.
 487     target_link_libraries(${name}
 488       ${ARG_LINK_LIBS}
 489       ${lib_deps}
 490       ${llvm_libs}
 491       )
 492   elseif(ARG_STATIC)
 493     target_link_libraries(${name} INTERFACE
 494       ${ARG_LINK_LIBS}
 495       ${lib_deps}
 496       ${llvm_libs}
 497       )
 498   else()
 499     # We can use PRIVATE since SO knows its dependent libs.
 500     target_link_libraries(${name} PRIVATE
 501       ${ARG_LINK_LIBS}
 502       ${lib_deps}
 503       ${llvm_libs}
 504       )
 505   endif()
 506
 507   if(LLVM_COMMON_DEPENDS)
 508     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 509     # Add dependencies also to objlibs.
 510     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 511     foreach(objlib ${objlibs})
 512       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 513     endforeach()
 514   endif()
 515 endfunction()
 516
 517 macro(add_llvm_library name)
 518   cmake_parse_arguments(ARG
 519     "SHARED"
 520     ""
 521     ""
 522     ${ARGN})
 523   if( BUILD_SHARED_LIBS )
 524     llvm_add_library(${name} SHARED ${ARGN})
 525   else()
 526     llvm_add_library(${name} ${ARGN})
 527   endif()
 528   # The gtest libraries should not be installed or exported as a target
 529   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 530     set(_is_gtest TRUE)
 531   else()
 532     set(_is_gtest FALSE)
 533     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 534   endif()
 535
 536   if( EXCLUDE_FROM_ALL )
 537     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 538   elseif(NOT _is_gtest)
 539     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 540       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 541         if(WIN32 OR CYGWIN)
 542           set(install_type RUNTIME)
 543         else()
 544           set(install_type LIBRARY)
 545         endif()
 546       else()
 547         set(install_type ARCHIVE)
 548       endif()
 549
 550       install(TARGETS ${name}
 551             EXPORT LLVMExports
 552             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 553             COMPONENT ${name})
 554
 555       if (NOT CMAKE_CONFIGURATION_TYPES)
 556         add_custom_target(install-${name}
 557                           DEPENDS ${name}
 558                           COMMAND "${CMAKE_COMMAND}"
 559                                   -DCMAKE_INSTALL_COMPONENT=${name}
 560                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 561       endif()
 562     endif()
 563     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 564   endif()
 565   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 566 endmacro(add_llvm_library name)
 567
 568 macro(add_llvm_loadable_module name)
 569   llvm_add_library(${name} MODULE ${ARGN})
 570   if(NOT TARGET ${name})
 571     # Add empty "phony" target
 572     add_custom_target(${name})
 573   else()
 574     if( EXCLUDE_FROM_ALL )
 575       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 576     else()
 577       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 578         if(WIN32 OR CYGWIN)
 579           # DLL platform
 580           set(dlldir "bin")
 581         else()
 582           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 583         endif()
 584         install(TARGETS ${name}
 585           EXPORT LLVMExports
 586           LIBRARY DESTINATION ${dlldir}
 587           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 588       endif()
 589       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 590     endif()
 591   endif()
 592
 593   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 594 endmacro(add_llvm_loadable_module name)
 595
 596
 597 macro(add_llvm_executable name)
 598   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB" "" "" ${ARGN})
 599   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 600
 601   # Generate objlib
 602   if(LLVM_ENABLE_OBJLIB)
 603     # Generate an obj library for both targets.
 604     set(obj_name "obj.${name}")
 605     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 606       ${ALL_FILES}
 607       )
 608     llvm_update_compile_flags(${obj_name})
 609     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 610
 611     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 612   endif()
 613
 614   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 615
 616   if(XCODE)
 617     # Note: the dummy.cpp source file provides no definitions. However,
 618     # it forces Xcode to properly link the static library.
 619     list(APPEND ALL_FILES "${LLVM_MAIN_SRC_DIR}/cmake/dummy.cpp")
 620   endif()
 621
 622   if( EXCLUDE_FROM_ALL )
 623     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 624   else()
 625     add_executable(${name} ${ALL_FILES})
 626   endif()
 627
 628   if(DEFINED windows_resource_file)
 629     set_windows_version_resource_properties(${name} ${windows_resource_file})
 630   endif()
 631
 632   # $<TARGET_OBJECTS> doesn't require compile flags.
 633   if(NOT LLVM_ENABLE_OBJLIB)
 634     llvm_update_compile_flags(${name})
 635   endif()
 636   add_link_opts( ${name} )
 637
 638   # Do not add -Dname_EXPORTS to the command-line when building files in this
 639   # target. Doing so is actively harmful for the modules build because it
 640   # creates extra module variants, and not useful because we don't use these
 641   # macros.
 642   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 643
 644   if (LLVM_EXPORTED_SYMBOL_FILE)
 645     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 646   endif(LLVM_EXPORTED_SYMBOL_FILE)
 647
 648   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 649     set(USE_SHARED USE_SHARED)
 650   endif()
 651
 652   set(EXCLUDE_FROM_ALL OFF)
 653   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 654   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 655   if( LLVM_COMMON_DEPENDS )
 656     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 657   endif( LLVM_COMMON_DEPENDS )
 658 endmacro(add_llvm_executable name)
 659
 660 function(export_executable_symbols target)
 661   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 662     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 663   endif()
 664 endfunction()
 665
 666 if(NOT LLVM_TOOLCHAIN_TOOLS)
 667   set (LLVM_TOOLCHAIN_TOOLS
 668     llvm-ar
 669     llvm-ranlib
 670     llvm-lib
 671     llvm-objdump
 672     )
 673 endif()
 674
 675 macro(add_llvm_tool name)
 676   if( NOT LLVM_BUILD_TOOLS )
 677     set(EXCLUDE_FROM_ALL ON)
 678   endif()
 679   add_llvm_executable(${name} ${ARGN})
 680
 681   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 682   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 683     if( LLVM_BUILD_TOOLS )
 684       install(TARGETS ${name}
 685               EXPORT LLVMExports
 686               RUNTIME DESTINATION bin
 687               COMPONENT ${name})
 688
 689       if (NOT CMAKE_CONFIGURATION_TYPES)
 690         add_custom_target(install-${name}
 691                           DEPENDS ${name}
 692                           COMMAND "${CMAKE_COMMAND}"
 693                                   -DCMAKE_INSTALL_COMPONENT=${name}
 694                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 695       endif()
 696     endif()
 697   endif()
 698   if( LLVM_BUILD_TOOLS )
 699     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 700   endif()
 701   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 702 endmacro(add_llvm_tool name)
 703
 704
 705 macro(add_llvm_example name)
 706   if( NOT LLVM_BUILD_EXAMPLES )
 707     set(EXCLUDE_FROM_ALL ON)
 708   endif()
 709   add_llvm_executable(${name} ${ARGN})
 710   if( LLVM_BUILD_EXAMPLES )
 711     install(TARGETS ${name} RUNTIME DESTINATION examples)
 712   endif()
 713   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 714 endmacro(add_llvm_example name)
 715
 716
 717 macro(add_llvm_utility name)
 718   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 719   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 720   if( LLVM_INSTALL_UTILS )
 721     install (TARGETS ${name}
 722       RUNTIME DESTINATION bin
 723       COMPONENT ${name})
 724     if (NOT CMAKE_CONFIGURATION_TYPES)
 725       add_custom_target(install-${name}
 726                         DEPENDS ${name}
 727                         COMMAND "${CMAKE_COMMAND}"
 728                                 -DCMAKE_INSTALL_COMPONENT=${name}
 729                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 730     endif()
 731   endif()
 732 endmacro(add_llvm_utility name)
 733
 734
 735 macro(add_llvm_target target_name)
 736   include_directories(BEFORE
 737     ${CMAKE_CURRENT_BINARY_DIR}
 738     ${CMAKE_CURRENT_SOURCE_DIR})
 739   add_llvm_library(LLVM${target_name} ${ARGN})
 740   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 741 endmacro(add_llvm_target)
 742
 743 function(canonicalize_tool_name name output)
 744   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 745   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 746   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 747   set(${output} "${nameUPPER}" PARENT_SCOPE)
 748 endfunction(canonicalize_tool_name)
 749
 750 # Custom add_subdirectory wrapper
 751 # Takes in a project name (i.e. LLVM), the the subdirectory name, and an
 752 # and an optional path if it differs from the name.
 753 macro(add_llvm_subdirectory project type name)
 754   set(add_llvm_external_dir "${ARGN}")
 755   if("${add_llvm_external_dir}" STREQUAL "")
 756     set(add_llvm_external_dir ${name})
 757   endif()
 758   canonicalize_tool_name(${name} nameUPPER)
 759   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 760     # Treat it as in-tree subproject.
 761     option(${project}_${type}_${nameUPPER}_BUILD
 762            "Whether to build ${name} as part of ${project}" On)
 763     mark_as_advanced(${project}_${type}_${name}_BUILD)
 764     if(${project}_${type}_${nameUPPER}_BUILD)
 765       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 766       # Don't process it in add_llvm_implicit_projects().
 767       set(${project}_${type}_${nameUPPER}_BUILD OFF)
 768     endif()
 769   else()
 770     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 771       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 772       CACHE PATH "Path to ${name} source directory")
 773     set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT ON)
 774     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 775       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 776     endif()
 777     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 778       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 779     endif()
 780     option(${project}_${type}_${nameUPPER}_BUILD
 781       "Whether to build ${name} as part of LLVM"
 782       ${${project}_${type}_${nameUPPER}_BUILD_DEFAULT})
 783     if (${project}_${type}_${nameUPPER}_BUILD)
 784       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 785         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 786       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 787         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 788       endif()
 789       # FIXME: It'd be redundant.
 790       set(${project}_${type}_${nameUPPER}_BUILD Off)
 791     endif()
 792   endif()
 793 endmacro()
 794
 795 # Add external project that may want to be built as part of llvm such as Clang,
 796 # lld, and Polly. This adds two options. One for the source directory of the
 797 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 798 # enable or disable building it with everything else.
 799 # Additional parameter can be specified as the name of directory.
 800 macro(add_llvm_external_project name)
 801   add_llvm_subdirectory(LLVM TOOL ${name} ${ARGN})
 802 endmacro()
 803
 804 macro(add_llvm_tool_subdirectory name)
 805   add_llvm_external_project(${name})
 806 endmacro(add_llvm_tool_subdirectory)
 807
 808 function(get_project_name_from_src_var var output)
 809   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 810          MACHED_TOOL "${var}")
 811   if(MACHED_TOOL)
 812     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 813   else()
 814     set(${output} PARENT_SCOPE)
 815   endif()
 816 endfunction()
 817
 818 function(create_subdirectory_options project type)
 819   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 820   foreach(dir ${sub-dirs})
 821     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 822       canonicalize_tool_name(${dir} name)
 823       option(${project}_${type}_${name}_BUILD
 824            "Whether to build ${name} as part of ${project}" On)
 825       mark_as_advanced(${project}_${type}_${name}_BUILD)
 826     endif()
 827   endforeach()
 828 endfunction(create_subdirectory_options)
 829
 830 function(create_llvm_tool_options)
 831   create_subdirectory_options(LLVM TOOL)
 832 endfunction(create_llvm_tool_options)
 833
 834 function(add_llvm_implicit_projects)
 835   set(list_of_implicit_subdirs "")
 836   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 837   foreach(dir ${sub-dirs})
 838     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 839       canonicalize_tool_name(${dir} name)
 840       if (LLVM_TOOL_${name}_BUILD)
 841         get_filename_component(fn "${dir}" NAME)
 842         list(APPEND list_of_implicit_subdirs "${fn}")
 843       endif()
 844     endif()
 845   endforeach()
 846
 847   foreach(external_proj ${list_of_implicit_subdirs})
 848     add_llvm_external_project("${external_proj}")
 849   endforeach()
 850 endfunction(add_llvm_implicit_projects)
 851
 852 # Generic support for adding a unittest.
 853 function(add_unittest test_suite test_name)
 854   if( NOT LLVM_BUILD_TESTS )
 855     set(EXCLUDE_FROM_ALL ON)
 856   endif()
 857
 858   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 859   if (NOT LLVM_ENABLE_THREADS)
 860     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 861   endif ()
 862
 863   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 864     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 865   endif ()
 866
 867   set(LLVM_REQUIRES_RTTI OFF)
 868
 869   add_llvm_executable(${test_name} ${ARGN})
 870   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 871   set_output_directory(${test_name} BINARY_DIR ${outdir} LIBRARY_DIR ${outdir})
 872   target_link_libraries(${test_name}
 873     gtest
 874     gtest_main
 875     LLVMSupport # gtest needs it for raw_ostream.
 876     )
 877
 878   add_dependencies(${test_suite} ${test_name})
 879   get_target_property(test_suite_folder ${test_suite} FOLDER)
 880   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 881     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 882   endif ()
 883 endfunction()
 884
 885 function(llvm_add_go_executable binary pkgpath)
 886   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 887
 888   if(LLVM_BINDINGS MATCHES "go")
 889     # FIXME: This should depend only on the libraries Go needs.
 890     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 891     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 892     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 893     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 894     set(cppflags "")
 895     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 896     foreach(d ${include_dirs})
 897       set(cppflags "${cppflags} -I${d}")
 898     endforeach(d)
 899     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 900     if (LLVM_LINK_LLVM_DYLIB)
 901       set(linkmode "dylib")
 902     else()
 903       set(linkmode "component-libs")
 904     endif()
 905     add_custom_command(OUTPUT ${binpath}
 906       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "linkmode=${linkmode}"
 907               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 908       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 909               ${llvmlibs} ${ARG_DEPENDS}
 910       COMMENT "Building Go executable ${binary}"
 911       VERBATIM)
 912     if (ARG_ALL)
 913       add_custom_target(${binary} ALL DEPENDS ${binpath})
 914     else()
 915       add_custom_target(${binary} DEPENDS ${binpath})
 916     endif()
 917   endif()
 918 endfunction()
 919
 920 # This function provides an automatic way to 'configure'-like generate a file
 921 # based on a set of common and custom variables, specifically targeting the
 922 # variables needed for the 'lit.site.cfg' files. This function bundles the
 923 # common variables that any Lit instance is likely to need, and custom
 924 # variables can be passed in.
 925 function(configure_lit_site_cfg input output)
 926   foreach(c ${LLVM_TARGETS_TO_BUILD})
 927     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 928   endforeach(c)
 929   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 930
 931   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 932
 933   # Configuration-time: See Unit/lit.site.cfg.in
 934   if (CMAKE_CFG_INTDIR STREQUAL ".")
 935     set(LLVM_BUILD_MODE ".")
 936   else ()
 937     set(LLVM_BUILD_MODE "%(build_mode)s")
 938   endif ()
 939
 940   # They below might not be the build tree but provided binary tree.
 941   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 942   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 943   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 944   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 945
 946   # SHLIBDIR points the build tree.
 947   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 948
 949   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 950   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 951   # plugins. We may rename it.
 952   if(LLVM_ENABLE_PLUGINS)
 953     set(ENABLE_SHARED "1")
 954   else()
 955     set(ENABLE_SHARED "0")
 956   endif()
 957
 958   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 959     set(ENABLE_ASSERTIONS "1")
 960   else()
 961     set(ENABLE_ASSERTIONS "0")
 962   endif()
 963
 964   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 965   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 966
 967   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 968   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 969   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 970
 971   configure_file(${input} ${output} @ONLY)
 972 endfunction()
 973
 974 # A raw function to create a lit target. This is used to implement the testuite
 975 # management functions.
 976 function(add_lit_target target comment)
 977   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 978   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 979   separate_arguments(LIT_ARGS)
 980   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 981     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 982   endif ()
 983   if (LLVM_MAIN_SRC_DIR)
 984     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 985   else()
 986     find_program(LIT_COMMAND llvm-lit)
 987   endif ()
 988   list(APPEND LIT_COMMAND ${LIT_ARGS})
 989   foreach(param ${ARG_PARAMS})
 990     list(APPEND LIT_COMMAND --param ${param})
 991   endforeach()
 992   if (ARG_UNPARSED_ARGUMENTS)
 993     add_custom_target(${target}
 994       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 995       COMMENT "${comment}"
 996       ${cmake_3_2_USES_TERMINAL}
 997       )
 998   else()
 999     add_custom_target(${target}
1000       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
1001     message(STATUS "${target} does nothing.")
1002   endif()
1003   if (ARG_DEPENDS)
1004     add_dependencies(${target} ${ARG_DEPENDS})
1005   endif()
1006
1007   # Tests should be excluded from "Build Solution".
1008   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
1009 endfunction()
1010
1011 # A function to add a set of lit test suites to be driven through 'check-*' targets.
1012 function(add_lit_testsuite target comment)
1013   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1014
1015   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
1016   if(NOT EXCLUDE_FROM_ALL)
1017     # Register the testsuites, params and depends for the global check rule.
1018     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
1019     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
1020     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
1021     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
1022   endif()
1023
1024   # Produce a specific suffixed check rule.
1025   add_lit_target(${target} ${comment}
1026     ${ARG_UNPARSED_ARGUMENTS}
1027     PARAMS ${ARG_PARAMS}
1028     DEPENDS ${ARG_DEPENDS}
1029     ARGS ${ARG_ARGS}
1030     )
1031 endfunction()
1032
1033 function(add_lit_testsuites project directory)
1034   if (NOT CMAKE_CONFIGURATION_TYPES)
1035     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1036     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
1037     set(lit_suites)
1038     foreach(f ${litCfg})
1039       get_filename_component(dir ${f} DIRECTORY)
1040       set(lit_suites ${lit_suites} ${dir})
1041     endforeach()
1042     list(REMOVE_DUPLICATES lit_suites)
1043     foreach(dir ${lit_suites})
1044       string(REPLACE ${directory} "" name_slash ${dir})
1045       if (name_slash)
1046         string(REPLACE "/" "-" name_slash ${name_slash})
1047         string(REPLACE "\\" "-" name_dashes ${name_slash})
1048         string(TOLOWER "${project}${name_dashes}" name_var)
1049         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
1050           ${dir}
1051           PARAMS ${ARG_PARAMS}
1052           DEPENDS ${ARG_DEPENDS}
1053           ARGS ${ARG_ARGS}
1054         )
1055       endif()
1056     endforeach()
1057   endif()
1058 endfunction()
1059
1060 function(llvm_install_library_symlink name dest type)
1061   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "COMPONENT" "" ${ARGN})
1062   foreach(path ${CMAKE_MODULE_PATH})
1063     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1064       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1065       break()
1066     endif()
1067   endforeach()
1068
1069   set(component ${ARG_COMPONENT})
1070   if(NOT component)
1071     set(component ${name})
1072   endif()
1073
1074   set(full_name ${CMAKE_${type}_LIBRARY_PREFIX}${name}${CMAKE_${type}_LIBRARY_SUFFIX})
1075   set(full_dest ${CMAKE_${type}_LIBRARY_PREFIX}${dest}${CMAKE_${type}_LIBRARY_SUFFIX})
1076
1077   set(output_dir lib${LLVM_LIBDIR_SUFFIX})
1078   if(WIN32 AND "${type}" STREQUAL "SHARED")
1079     set(output_dir bin)
1080   endif()
1081
1082   install(SCRIPT ${INSTALL_SYMLINK}
1083           CODE "install_symlink(${full_name} ${full_dest} ${output_dir})"
1084           COMPONENT ${component})
1085
1086   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1087     add_custom_target(install-${name}
1088                       DEPENDS ${name} ${dest} install-${dest}
1089                       COMMAND "${CMAKE_COMMAND}"
1090                               -DCMAKE_INSTALL_COMPONENT=${name}
1091                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1092   endif()
1093 endfunction()
1094
1095 function(llvm_install_symlink name dest)
1096   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1097   foreach(path ${CMAKE_MODULE_PATH})
1098     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1099       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1100       break()
1101     endif()
1102   endforeach()
1103
1104   if(ARG_ALWAYS_GENERATE)
1105     set(component ${dest})
1106   else()
1107     set(component ${name})
1108   endif()
1109
1110   set(full_name ${name}${CMAKE_EXECUTABLE_SUFFIX})
1111   set(full_dest ${dest}${CMAKE_EXECUTABLE_SUFFIX})
1112
1113   install(SCRIPT ${INSTALL_SYMLINK}
1114           CODE "install_symlink(${full_name} ${full_dest} bin)"
1115           COMPONENT ${component})
1116
1117   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1118     add_custom_target(install-${name}
1119                       DEPENDS ${name} ${dest} install-${dest}
1120                       COMMAND "${CMAKE_COMMAND}"
1121                               -DCMAKE_INSTALL_COMPONENT=${name}
1122                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1123   endif()
1124 endfunction()
1125
1126 function(add_llvm_tool_symlink name dest)
1127   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1128   if(UNIX)
1129     set(LLVM_LINK_OR_COPY create_symlink)
1130     set(dest_binary "${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1131   else()
1132     set(LLVM_LINK_OR_COPY copy)
1133     set(dest_binary "${LLVM_RUNTIME_OUTPUT_INTDIR}/${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1134   endif()
1135
1136   set(output_path "${LLVM_RUNTIME_OUTPUT_INTDIR}/${name}${CMAKE_EXECUTABLE_SUFFIX}")
1137
1138   if(ARG_ALWAYS_GENERATE)
1139     set_property(DIRECTORY APPEND PROPERTY
1140       ADDITIONAL_MAKE_CLEAN_FILES ${dest_binary})
1141     add_custom_command(TARGET ${dest} POST_BUILD
1142       COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}")
1143   else()
1144     add_custom_command(OUTPUT ${output_path}
1145                      COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}"
1146                      DEPENDS ${dest})
1147     add_custom_target(${name} ALL DEPENDS ${output_path})
1148     set_target_properties(${name} PROPERTIES FOLDER Tools)
1149
1150     # Make sure the parent tool is a toolchain tool, otherwise exclude this tool
1151     list(FIND LLVM_TOOLCHAIN_TOOLS ${dest} LLVM_IS_${dest}_TOOLCHAIN_TOOL)
1152     if (NOT LLVM_IS_${dest}_TOOLCHAIN_TOOL GREATER -1)
1153       set(LLVM_IS_${name}_TOOLCHAIN_TOOL ${LLVM_IS_${dest}_TOOLCHAIN_TOOL})
1154     else()
1155       list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
1156     endif()
1157
1158     # LLVM_IS_${name}_TOOLCHAIN_TOOL will only be greater than -1 if both this
1159     # tool and its parent tool are in LLVM_TOOLCHAIN_TOOLS
1160     if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1161       if( LLVM_BUILD_TOOLS )
1162         llvm_install_symlink(${name} ${dest})
1163       endif()
1164     endif()
1165   endif()
1166 endfunction()