cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if(LLVM_REQUIRES_EH OR LLVM_ENABLE_EH)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  30     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  31     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  32       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  33     elseif (MSVC)
  34       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  35     endif ()
  36   endif()
  37
  38   # Assume that;
  39   #   - LLVM_COMPILE_FLAGS is list.
  40   #   - PROPERTY COMPILE_FLAGS is string.
  41   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  42
  43   if(update_src_props)
  44     foreach(fn ${sources})
  45       get_filename_component(suf ${fn} EXT)
  46       if("${suf}" STREQUAL ".cpp")
  47         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  48           COMPILE_FLAGS "${target_compile_flags}")
  49       endif()
  50     endforeach()
  51   else()
  52     # Update target props, since all sources are C++.
  53     set_property(TARGET ${name} APPEND_STRING PROPERTY
  54       COMPILE_FLAGS "${target_compile_flags}")
  55   endif()
  56
  57   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  58 endfunction()
  59
  60 function(add_llvm_symbol_exports target_name export_file)
  61   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  62     set(native_export_file "${target_name}.exports")
  63     add_custom_command(OUTPUT ${native_export_file}
  64       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  65       DEPENDS ${export_file}
  66       VERBATIM
  67       COMMENT "Creating export file for ${target_name}")
  68     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  69                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  70   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  71     # Gold and BFD ld require a version script rather than a plain list.
  72     set(native_export_file "${target_name}.exports")
  73     # FIXME: Don't write the "local:" line on OpenBSD.
  74     add_custom_command(OUTPUT ${native_export_file}
  75       COMMAND echo "{" > ${native_export_file}
  76       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  77       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  78       COMMAND echo "  local: *;" >> ${native_export_file}
  79       COMMAND echo "};" >> ${native_export_file}
  80       DEPENDS ${export_file}
  81       VERBATIM
  82       COMMENT "Creating export file for ${target_name}")
  83     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  84                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  85   else()
  86     set(native_export_file "${target_name}.def")
  87
  88     set(CAT "cat")
  89     set(export_file_nativeslashes ${export_file})
  90     if(WIN32 AND NOT CYGWIN)
  91       set(CAT "type")
  92       # Convert ${export_file} to native format (backslashes) for "type"
  93       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
  94       # path but a build-system specific format (see CMake bug
  95       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
  96       string(REPLACE / \\ export_file_nativeslashes ${export_file})
  97     endif()
  98
  99     add_custom_command(OUTPUT ${native_export_file}
 100       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 101       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 102       DEPENDS ${export_file}
 103       VERBATIM
 104       COMMENT "Creating export file for ${target_name}")
 105     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 106     if(MSVC)
 107       set(export_file_linker_flag "/DEF:${export_file_linker_flag}")
 108     endif()
 109     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 110                  LINK_FLAGS " ${export_file_linker_flag}")
 111   endif()
 112
 113   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 114   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 115
 116   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 117   foreach(src ${srcs})
 118     get_filename_component(extension ${src} EXT)
 119     if(extension STREQUAL ".cpp")
 120       set(first_source_file ${src})
 121       break()
 122     endif()
 123   endforeach()
 124
 125   # Force re-linking when the exports file changes. Actually, it
 126   # forces recompilation of the source file. The LINK_DEPENDS target
 127   # property only works for makefile-based generators.
 128   # FIXME: This is not safe because this will create the same target
 129   # ${native_export_file} in several different file:
 130   # - One where we emitted ${target_name}_exports
 131   # - One where we emitted the build command for the following object.
 132   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 133   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 134
 135   set_property(DIRECTORY APPEND
 136     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 137
 138   add_dependencies(${target_name} ${target_name}_exports)
 139
 140   # Add dependency to *_exports later -- CMake issue 14747
 141   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 142   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 143 endfunction(add_llvm_symbol_exports)
 144
 145 if(NOT WIN32 AND NOT APPLE)
 146   execute_process(COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 147                   OUTPUT_VARIABLE stdout)
 148   if("${stdout}" MATCHES "GNU gold")
 149     set(LLVM_LINKER_IS_GOLD ON)
 150   endif()
 151 endif()
 152
 153 function(add_link_opts target_name)
 154   # Pass -O3 to the linker. This enabled different optimizations on different
 155   # linkers.
 156   if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32))
 157     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 158                  LINK_FLAGS " -Wl,-O3")
 159   endif()
 160
 161   if(LLVM_LINKER_IS_GOLD)
 162     # With gold gc-sections is always safe.
 163     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 164                  LINK_FLAGS " -Wl,--gc-sections")
 165     # Note that there is a bug with -Wl,--icf=safe so it is not safe
 166     # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 167   endif()
 168
 169   if(NOT LLVM_NO_DEAD_STRIP)
 170     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 171       # ld64's implementation of -dead_strip breaks tools that use plugins.
 172       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 173                    LINK_FLAGS " -Wl,-dead_strip")
 174     elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 175       # Object files are compiled with -ffunction-data-sections.
 176       # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 177       # tools that use plugins. Always pass --gc-sections once we require
 178       # a newer linker.
 179       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 180                    LINK_FLAGS " -Wl,--gc-sections")
 181     endif()
 182   endif()
 183 endfunction(add_link_opts)
 184
 185 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 186 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 187 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 188 function(set_output_directory target bindir libdir)
 189   # Do nothing if *_OUTPUT_INTDIR is empty.
 190   if("${bindir}" STREQUAL "")
 191     return()
 192   endif()
 193
 194   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 195   # It affects output of add_library(MODULE).
 196   if(WIN32 OR CYGWIN)
 197     # DLL platform
 198     set(moddir ${bindir})
 199   else()
 200     set(moddir ${libdir})
 201   endif()
 202   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 203     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 204       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 205       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 206       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 207       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 208       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 209       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 210       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 211     endforeach()
 212   else()
 213     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 214     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 215     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 216   endif()
 217 endfunction()
 218
 219 # llvm_add_library(name sources...
 220 #   SHARED;STATIC
 221 #     STATIC by default w/o BUILD_SHARED_LIBS.
 222 #     SHARED by default w/  BUILD_SHARED_LIBS.
 223 #   MODULE
 224 #     Target ${name} might not be created on unsupported platforms.
 225 #     Check with "if(TARGET ${name})".
 226 #   OUTPUT_NAME name
 227 #     Corresponds to OUTPUT_NAME in target properties.
 228 #   DEPENDS targets...
 229 #     Same semantics as add_dependencies().
 230 #   LINK_COMPONENTS components...
 231 #     Same as the variable LLVM_LINK_COMPONENTS.
 232 #   LINK_LIBS lib_targets...
 233 #     Same semantics as target_link_libraries().
 234 #   ADDITIONAL_HEADERS
 235 #     May specify header files for IDE generators.
 236 #   )
 237 function(llvm_add_library name)
 238   cmake_parse_arguments(ARG
 239     "MODULE;SHARED;STATIC"
 240     "OUTPUT_NAME"
 241     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 242     ${ARGN})
 243   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 244   if(ARG_ADDITIONAL_HEADERS)
 245     # Pass through ADDITIONAL_HEADERS.
 246     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 247   endif()
 248   if(ARG_OBJLIBS)
 249     set(ALL_FILES ${ARG_OBJLIBS})
 250   else()
 251     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 252   endif()
 253
 254   if(ARG_MODULE)
 255     if(ARG_SHARED OR ARG_STATIC)
 256       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 257     endif()
 258     if(NOT LLVM_ENABLE_PLUGINS)
 259       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 260       return()
 261     endif()
 262   else()
 263     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 264       set(ARG_SHARED TRUE)
 265     endif()
 266     if(NOT ARG_SHARED)
 267       set(ARG_STATIC TRUE)
 268     endif()
 269   endif()
 270
 271   # Generate objlib
 272   if(ARG_SHARED AND ARG_STATIC)
 273     # Generate an obj library for both targets.
 274     set(obj_name "obj.${name}")
 275     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 276       ${ALL_FILES}
 277       )
 278     llvm_update_compile_flags(${obj_name})
 279     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 280
 281     # Do add_dependencies(obj) later due to CMake issue 14747.
 282     list(APPEND objlibs ${obj_name})
 283
 284     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 285   endif()
 286
 287   if(ARG_SHARED AND ARG_STATIC)
 288     # static
 289     set(name_static "${name}_static")
 290     if(ARG_OUTPUT_NAME)
 291       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 292     endif()
 293     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 294     llvm_add_library(${name_static} STATIC
 295       ${output_name}
 296       OBJLIBS ${ALL_FILES} # objlib
 297       LINK_LIBS ${ARG_LINK_LIBS}
 298       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 299       )
 300     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 301     set(ARG_STATIC)
 302   endif()
 303
 304   if(ARG_MODULE)
 305     add_library(${name} MODULE ${ALL_FILES})
 306   elseif(ARG_SHARED)
 307     add_library(${name} SHARED ${ALL_FILES})
 308   else()
 309     add_library(${name} STATIC ${ALL_FILES})
 310   endif()
 311   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 312   llvm_update_compile_flags(${name})
 313   add_link_opts( ${name} )
 314   if(ARG_OUTPUT_NAME)
 315     set_target_properties(${name}
 316       PROPERTIES
 317       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 318       )
 319   endif()
 320
 321   if(ARG_MODULE)
 322     set_target_properties(${name} PROPERTIES
 323       PREFIX ""
 324       SUFFIX ${LLVM_PLUGIN_EXT}
 325       )
 326   endif()
 327
 328   if(ARG_SHARED)
 329     if(WIN32)
 330       set_target_properties(${name} PROPERTIES
 331         PREFIX ""
 332         )
 333     endif()
 334     if (MSVC)
 335       set_target_properties(${name}
 336         PROPERTIES
 337         IMPORT_SUFFIX ".imp")
 338     endif ()
 339   endif()
 340
 341   if(ARG_MODULE OR ARG_SHARED)
 342     # Do not add -Dname_EXPORTS to the command-line when building files in this
 343     # target. Doing so is actively harmful for the modules build because it
 344     # creates extra module variants, and not useful because we don't use these
 345     # macros.
 346     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 347
 348     if (LLVM_EXPORTED_SYMBOL_FILE)
 349       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 350     endif()
 351   endif()
 352
 353   # Add the explicit dependency information for this library.
 354   #
 355   # It would be nice to verify that we have the dependencies for this library
 356   # name, but using get_property(... SET) doesn't suffice to determine if a
 357   # property has been set to an empty value.
 358   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 359
 360   llvm_map_components_to_libnames(llvm_libs
 361     ${ARG_LINK_COMPONENTS}
 362     ${LLVM_LINK_COMPONENTS}
 363     )
 364
 365   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 366     # Link libs w/o keywords, assuming PUBLIC.
 367     target_link_libraries(${name}
 368       ${ARG_LINK_LIBS}
 369       ${lib_deps}
 370       ${llvm_libs}
 371       )
 372   elseif(ARG_STATIC)
 373     target_link_libraries(${name} INTERFACE
 374       ${ARG_LINK_LIBS}
 375       ${lib_deps}
 376       ${llvm_libs}
 377       )
 378   else()
 379     # We can use PRIVATE since SO knows its dependent libs.
 380     target_link_libraries(${name} PRIVATE
 381       ${ARG_LINK_LIBS}
 382       ${lib_deps}
 383       ${llvm_libs}
 384       )
 385   endif()
 386
 387   if(LLVM_COMMON_DEPENDS)
 388     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 389     # Add dependencies also to objlibs.
 390     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 391     foreach(objlib ${objlibs})
 392       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 393     endforeach()
 394   endif()
 395 endfunction()
 396
 397 macro(add_llvm_library name)
 398   if( BUILD_SHARED_LIBS )
 399     llvm_add_library(${name} SHARED ${ARGN})
 400   else()
 401     llvm_add_library(${name} ${ARGN})
 402   endif()
 403   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 404
 405   if( EXCLUDE_FROM_ALL )
 406     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 407   else()
 408     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 409       install(TARGETS ${name}
 410         EXPORT LLVMExports
 411         RUNTIME DESTINATION bin
 412         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 413         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 414     endif()
 415     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 416   endif()
 417   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 418 endmacro(add_llvm_library name)
 419
 420 macro(add_llvm_loadable_module name)
 421   llvm_add_library(${name} MODULE ${ARGN})
 422   if(NOT TARGET ${name})
 423     # Add empty "phony" target
 424     add_custom_target(${name})
 425   else()
 426     if( EXCLUDE_FROM_ALL )
 427       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 428     else()
 429       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 430         if(WIN32 OR CYGWIN)
 431           # DLL platform
 432           set(dlldir "bin")
 433         else()
 434           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 435         endif()
 436         install(TARGETS ${name}
 437           EXPORT LLVMExports
 438           LIBRARY DESTINATION ${dlldir}
 439           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 440       endif()
 441       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 442     endif()
 443   endif()
 444
 445   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 446 endmacro(add_llvm_loadable_module name)
 447
 448
 449 macro(add_llvm_executable name)
 450   llvm_process_sources( ALL_FILES ${ARGN} )
 451   if( EXCLUDE_FROM_ALL )
 452     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 453   else()
 454     add_executable(${name} ${ALL_FILES})
 455   endif()
 456   llvm_update_compile_flags(${name})
 457   add_link_opts( ${name} )
 458
 459   # Do not add -Dname_EXPORTS to the command-line when building files in this
 460   # target. Doing so is actively harmful for the modules build because it
 461   # creates extra module variants, and not useful because we don't use these
 462   # macros.
 463   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 464
 465   if (LLVM_EXPORTED_SYMBOL_FILE)
 466     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 467   endif(LLVM_EXPORTED_SYMBOL_FILE)
 468
 469   set(EXCLUDE_FROM_ALL OFF)
 470   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 471   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 472   if( LLVM_COMMON_DEPENDS )
 473     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 474   endif( LLVM_COMMON_DEPENDS )
 475 endmacro(add_llvm_executable name)
 476
 477
 478 set (LLVM_TOOLCHAIN_TOOLS
 479   llvm-ar
 480   llvm-objdump
 481   )
 482
 483 macro(add_llvm_tool name)
 484   if( NOT LLVM_BUILD_TOOLS )
 485     set(EXCLUDE_FROM_ALL ON)
 486   endif()
 487   add_llvm_executable(${name} ${ARGN})
 488
 489   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 490   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 491     if( LLVM_BUILD_TOOLS )
 492       install(TARGETS ${name}
 493               EXPORT LLVMExports
 494               RUNTIME DESTINATION bin)
 495     endif()
 496   endif()
 497   if( LLVM_BUILD_TOOLS )
 498     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 499   endif()
 500   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 501 endmacro(add_llvm_tool name)
 502
 503
 504 macro(add_llvm_example name)
 505   if( NOT LLVM_BUILD_EXAMPLES )
 506     set(EXCLUDE_FROM_ALL ON)
 507   endif()
 508   add_llvm_executable(${name} ${ARGN})
 509   if( LLVM_BUILD_EXAMPLES )
 510     install(TARGETS ${name} RUNTIME DESTINATION examples)
 511   endif()
 512   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 513 endmacro(add_llvm_example name)
 514
 515
 516 macro(add_llvm_utility name)
 517   add_llvm_executable(${name} ${ARGN})
 518   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 519 endmacro(add_llvm_utility name)
 520
 521
 522 macro(add_llvm_target target_name)
 523   include_directories(BEFORE
 524     ${CMAKE_CURRENT_BINARY_DIR}
 525     ${CMAKE_CURRENT_SOURCE_DIR})
 526   add_llvm_library(LLVM${target_name} ${ARGN})
 527   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 528 endmacro(add_llvm_target)
 529
 530 # Add external project that may want to be built as part of llvm such as Clang,
 531 # lld, and Polly. This adds two options. One for the source directory of the
 532 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 533 # enable or disable building it with everything else.
 534 # Additional parameter can be specified as the name of directory.
 535 macro(add_llvm_external_project name)
 536   set(add_llvm_external_dir "${ARGN}")
 537   if("${add_llvm_external_dir}" STREQUAL "")
 538     set(add_llvm_external_dir ${name})
 539   endif()
 540   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 541   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 542   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 543   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 544       CACHE PATH "Path to ${name} source directory")
 545   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 546       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 547     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 548            "Whether to build ${name} as part of LLVM" ON)
 549     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 550       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 551     endif()
 552   endif()
 553 endmacro(add_llvm_external_project)
 554
 555 macro(add_llvm_tool_subdirectory name)
 556   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 557   add_subdirectory(${name})
 558 endmacro(add_llvm_tool_subdirectory)
 559
 560 macro(ignore_llvm_tool_subdirectory name)
 561   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 562 endmacro(ignore_llvm_tool_subdirectory)
 563
 564 function(add_llvm_implicit_external_projects)
 565   set(list_of_implicit_subdirs "")
 566   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 567   foreach(dir ${sub-dirs})
 568     if(IS_DIRECTORY "${dir}")
 569       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 570       if( tool_subdir_ignore EQUAL -1
 571           AND EXISTS "${dir}/CMakeLists.txt")
 572         get_filename_component(fn "${dir}" NAME)
 573         list(APPEND list_of_implicit_subdirs "${fn}")
 574       endif()
 575     endif()
 576   endforeach()
 577
 578   foreach(external_proj ${list_of_implicit_subdirs})
 579     add_llvm_external_project("${external_proj}")
 580   endforeach()
 581 endfunction(add_llvm_implicit_external_projects)
 582
 583 # Generic support for adding a unittest.
 584 function(add_unittest test_suite test_name)
 585   if( NOT LLVM_BUILD_TESTS )
 586     set(EXCLUDE_FROM_ALL ON)
 587   endif()
 588
 589   # Visual Studio 2012 only supports up to 8 template parameters in
 590   # std::tr1::tuple by default, but gtest requires 10
 591   if (MSVC AND MSVC_VERSION EQUAL 1700)
 592     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 593   endif ()
 594
 595   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 596   if (NOT LLVM_ENABLE_THREADS)
 597     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 598   endif ()
 599
 600   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 601     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 602   endif ()
 603
 604   set(LLVM_REQUIRES_RTTI OFF)
 605
 606   add_llvm_executable(${test_name} ${ARGN})
 607   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 608   set_output_directory(${test_name} ${outdir} ${outdir})
 609   target_link_libraries(${test_name}
 610     gtest
 611     gtest_main
 612     LLVMSupport # gtest needs it for raw_ostream.
 613     )
 614
 615   add_dependencies(${test_suite} ${test_name})
 616   get_target_property(test_suite_folder ${test_suite} FOLDER)
 617   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 618     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 619   endif ()
 620 endfunction()
 621
 622 function(llvm_add_go_executable binary pkgpath)
 623   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 624
 625   if(LLVM_BINDINGS MATCHES "go")
 626     # FIXME: This should depend only on the libraries Go needs.
 627     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 628     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 629     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 630     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 631     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 632     add_custom_command(OUTPUT ${binpath}
 633       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "ldflags=${ldflags}"
 634               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 635       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 636               ${llvmlibs} ${ARG_DEPENDS}
 637       COMMENT "Building Go executable ${binary}"
 638       VERBATIM)
 639     if (ARG_ALL)
 640       add_custom_target(${binary} ALL DEPENDS ${binpath})
 641     else()
 642       add_custom_target(${binary} DEPENDS ${binpath})
 643     endif()
 644   endif()
 645 endfunction()
 646
 647 # This function provides an automatic way to 'configure'-like generate a file
 648 # based on a set of common and custom variables, specifically targeting the
 649 # variables needed for the 'lit.site.cfg' files. This function bundles the
 650 # common variables that any Lit instance is likely to need, and custom
 651 # variables can be passed in.
 652 function(configure_lit_site_cfg input output)
 653   foreach(c ${LLVM_TARGETS_TO_BUILD})
 654     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 655   endforeach(c)
 656   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 657
 658   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 659
 660   # Configuration-time: See Unit/lit.site.cfg.in
 661   if (CMAKE_CFG_INTDIR STREQUAL ".")
 662     set(LLVM_BUILD_MODE ".")
 663   else ()
 664     set(LLVM_BUILD_MODE "%(build_mode)s")
 665   endif ()
 666
 667   # They below might not be the build tree but provided binary tree.
 668   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 669   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 670   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 671   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 672
 673   # SHLIBDIR points the build tree.
 674   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 675
 676   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 677   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 678   # plugins. We may rename it.
 679   if(LLVM_ENABLE_PLUGINS)
 680     set(ENABLE_SHARED "1")
 681   else()
 682     set(ENABLE_SHARED "0")
 683   endif()
 684
 685   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 686     set(ENABLE_ASSERTIONS "1")
 687   else()
 688     set(ENABLE_ASSERTIONS "0")
 689   endif()
 690
 691   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 692   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 693
 694   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 695   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 696   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 697
 698   configure_file(${input} ${output} @ONLY)
 699 endfunction()
 700
 701 # A raw function to create a lit target. This is used to implement the testuite
 702 # management functions.
 703 function(add_lit_target target comment)
 704   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 705   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 706   separate_arguments(LIT_ARGS)
 707   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 708     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 709   endif ()
 710   if (LLVM_MAIN_SRC_DIR)
 711     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 712   else()
 713     find_program(LIT_COMMAND llvm-lit)
 714   endif ()
 715   list(APPEND LIT_COMMAND ${LIT_ARGS})
 716   foreach(param ${ARG_PARAMS})
 717     list(APPEND LIT_COMMAND --param ${param})
 718   endforeach()
 719   if( ARG_DEPENDS )
 720     add_custom_target(${target}
 721       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 722       COMMENT "${comment}"
 723       ${cmake_3_2_USES_TERMINAL}
 724       )
 725     add_dependencies(${target} ${ARG_DEPENDS})
 726   else()
 727     add_custom_target(${target}
 728       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 729     message(STATUS "${target} does nothing.")
 730   endif()
 731
 732   # Tests should be excluded from "Build Solution".
 733   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 734 endfunction()
 735
 736 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 737 function(add_lit_testsuite target comment)
 738   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 739
 740   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 741   if(NOT EXCLUDE_FROM_ALL)
 742     # Register the testsuites, params and depends for the global check rule.
 743     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 744     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 745     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 746     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 747   endif()
 748
 749   # Produce a specific suffixed check rule.
 750   add_lit_target(${target} ${comment}
 751     ${ARG_DEFAULT_ARGS}
 752     PARAMS ${ARG_PARAMS}
 753     DEPENDS ${ARG_DEPENDS}
 754     ARGS ${ARG_ARGS}
 755     )
 756 endfunction()