cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3 include(DetermineGCCCompatible)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   set(LLVM_CONFIG_HAS_RTTI YES CACHE INTERNAL "")
  30   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  31     set(LLVM_CONFIG_HAS_RTTI NO CACHE INTERNAL "")
  32     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  33     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  34       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  35     elseif (MSVC)
  36       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  37     endif ()
  38   endif()
  39
  40   # Assume that;
  41   #   - LLVM_COMPILE_FLAGS is list.
  42   #   - PROPERTY COMPILE_FLAGS is string.
  43   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  44
  45   if(update_src_props)
  46     foreach(fn ${sources})
  47       get_filename_component(suf ${fn} EXT)
  48       if("${suf}" STREQUAL ".cpp")
  49         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  50           COMPILE_FLAGS "${target_compile_flags}")
  51       endif()
  52     endforeach()
  53   else()
  54     # Update target props, since all sources are C++.
  55     set_property(TARGET ${name} APPEND_STRING PROPERTY
  56       COMPILE_FLAGS "${target_compile_flags}")
  57   endif()
  58
  59   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  60 endfunction()
  61
  62 function(add_llvm_symbol_exports target_name export_file)
  63   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  64     set(native_export_file "${target_name}.exports")
  65     add_custom_command(OUTPUT ${native_export_file}
  66       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  67       DEPENDS ${export_file}
  68       VERBATIM
  69       COMMENT "Creating export file for ${target_name}")
  70     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  71                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  72   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  73     # Gold and BFD ld require a version script rather than a plain list.
  74     set(native_export_file "${target_name}.exports")
  75     # FIXME: Don't write the "local:" line on OpenBSD.
  76     add_custom_command(OUTPUT ${native_export_file}
  77       COMMAND echo "{" > ${native_export_file}
  78       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  79       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  80       COMMAND echo "  local: *;" >> ${native_export_file}
  81       COMMAND echo "};" >> ${native_export_file}
  82       DEPENDS ${export_file}
  83       VERBATIM
  84       COMMENT "Creating export file for ${target_name}")
  85     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  86       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  87                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  88     else()
  89       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  90                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  91     endif()
  92   else()
  93     set(native_export_file "${target_name}.def")
  94
  95     add_custom_command(OUTPUT ${native_export_file}
  96       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
  97         < ${export_file} > ${native_export_file}
  98       DEPENDS ${export_file}
  99       VERBATIM
 100       COMMENT "Creating export file for ${target_name}")
 101     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 102     if(MSVC)
 103       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 104     endif()
 105     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 106                  LINK_FLAGS " ${export_file_linker_flag}")
 107   endif()
 108
 109   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 110   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 111
 112   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 113   foreach(src ${srcs})
 114     get_filename_component(extension ${src} EXT)
 115     if(extension STREQUAL ".cpp")
 116       set(first_source_file ${src})
 117       break()
 118     endif()
 119   endforeach()
 120
 121   # Force re-linking when the exports file changes. Actually, it
 122   # forces recompilation of the source file. The LINK_DEPENDS target
 123   # property only works for makefile-based generators.
 124   # FIXME: This is not safe because this will create the same target
 125   # ${native_export_file} in several different file:
 126   # - One where we emitted ${target_name}_exports
 127   # - One where we emitted the build command for the following object.
 128   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 129   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 130
 131   set_property(DIRECTORY APPEND
 132     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 133
 134   add_dependencies(${target_name} ${target_name}_exports)
 135
 136   # Add dependency to *_exports later -- CMake issue 14747
 137   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 138   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 139 endfunction(add_llvm_symbol_exports)
 140
 141 if(NOT WIN32 AND NOT APPLE)
 142   execute_process(
 143     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 144     OUTPUT_VARIABLE stdout
 145     ERROR_QUIET
 146     )
 147   if("${stdout}" MATCHES "GNU gold")
 148     set(LLVM_LINKER_IS_GOLD ON)
 149   endif()
 150 endif()
 151
 152 function(add_link_opts target_name)
 153   # Don't use linker optimizations in debug builds since it slows down the
 154   # linker in a context where the optimizations are not important.
 155   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 156
 157     # Pass -O3 to the linker. This enabled different optimizations on different
 158     # linkers.
 159     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 160       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 161                    LINK_FLAGS " -Wl,-O3")
 162     endif()
 163
 164     if(LLVM_LINKER_IS_GOLD)
 165       # With gold gc-sections is always safe.
 166       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 167                    LINK_FLAGS " -Wl,--gc-sections")
 168       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 169       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 170     endif()
 171
 172     if(NOT LLVM_NO_DEAD_STRIP)
 173       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 174         # ld64's implementation of -dead_strip breaks tools that use plugins.
 175         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 176                      LINK_FLAGS " -Wl,-dead_strip")
 177       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 178         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 179                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 180       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 181         # Object files are compiled with -ffunction-data-sections.
 182         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 183         # tools that use plugins. Always pass --gc-sections once we require
 184         # a newer linker.
 185         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 186                      LINK_FLAGS " -Wl,--gc-sections")
 187       endif()
 188     endif()
 189   endif()
 190 endfunction(add_link_opts)
 191
 192 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 193 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 194 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 195 function(set_output_directory target)
 196   cmake_parse_arguments(ARG "" "BINARY_DIR;LIBRARY_DIR;" "" ${ARGN})
 197
 198   # module_dir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 199   # It affects output of add_library(MODULE).
 200   if(WIN32 OR CYGWIN)
 201     # DLL platform
 202     set(module_dir ${ARG_BINARY_DIR})
 203   else()
 204     set(module_dir ${ARG_LIBRARY_DIR})
 205   endif()
 206   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 207     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 208       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 209       if(ARG_BINARY_DIR)
 210         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${ARG_BINARY_DIR})
 211         set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 212       endif()
 213       if(ARG_LIBRARY_DIR)
 214         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${ARG_LIBRARY_DIR})
 215         set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 216       endif()
 217       if(module_dir)
 218         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${module_dir})
 219         set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 220       endif()
 221     endforeach()
 222   else()
 223     if(ARG_BINARY_DIR)
 224       set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${ARG_BINARY_DIR})
 225     endif()
 226     if(ARG_LIBRARY_DIR)
 227       set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${ARG_LIBRARY_DIR})
 228     endif()
 229     if(module_dir)
 230       set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${module_dir})
 231     endif()
 232   endif()
 233 endfunction()
 234
 235 # If on Windows and building with MSVC, add the resource script containing the
 236 # VERSIONINFO data to the project.  This embeds version resource information
 237 # into the output .exe or .dll.
 238 # TODO: Enable for MinGW Windows builds too.
 239 #
 240 function(add_windows_version_resource_file OUT_VAR)
 241   set(sources ${ARGN})
 242   if (MSVC)
 243     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 244     if(EXISTS ${resource_file})
 245       set(sources ${sources} ${resource_file})
 246       source_group("Resource Files" ${resource_file})
 247       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 248     endif()
 249   endif(MSVC)
 250
 251   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 252 endfunction(add_windows_version_resource_file)
 253
 254 # set_windows_version_resource_properties(name resource_file...
 255 #   VERSION_MAJOR int
 256 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 257 #   VERSION_MINOR int
 258 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 259 #   VERSION_PATCHLEVEL int
 260 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 261 #   VERSION_STRING
 262 #     Optional version string (defaults to PACKAGE_VERSION)
 263 #   PRODUCT_NAME
 264 #     Optional product name string (defaults to "LLVM")
 265 #   )
 266 function(set_windows_version_resource_properties name resource_file)
 267   cmake_parse_arguments(ARG
 268     ""
 269     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 270     ""
 271     ${ARGN})
 272
 273   if (NOT DEFINED ARG_VERSION_MAJOR)
 274     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_MINOR)
 278     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 279   endif()
 280
 281   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 282     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 283   endif()
 284
 285   if (NOT DEFINED ARG_VERSION_STRING)
 286     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 287   endif()
 288
 289   if (NOT DEFINED ARG_PRODUCT_NAME)
 290     set(ARG_PRODUCT_NAME "LLVM")
 291   endif()
 292
 293   set_property(SOURCE ${resource_file}
 294                PROPERTY COMPILE_FLAGS /nologo)
 295   set_property(SOURCE ${resource_file}
 296                PROPERTY COMPILE_DEFINITIONS
 297                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 298                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 299                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 300                "RC_VERSION_FIELD_4=0"
 301                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 302                "RC_INTERNAL_NAME=\"${name}\""
 303                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 304                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 305 endfunction(set_windows_version_resource_properties)
 306
 307 # llvm_add_library(name sources...
 308 #   SHARED;STATIC
 309 #     STATIC by default w/o BUILD_SHARED_LIBS.
 310 #     SHARED by default w/  BUILD_SHARED_LIBS.
 311 #   MODULE
 312 #     Target ${name} might not be created on unsupported platforms.
 313 #     Check with "if(TARGET ${name})".
 314 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 315 #     Do not link this library to libLLVM, even if
 316 #     LLVM_LINK_LLVM_DYLIB is enabled.
 317 #   OUTPUT_NAME name
 318 #     Corresponds to OUTPUT_NAME in target properties.
 319 #   DEPENDS targets...
 320 #     Same semantics as add_dependencies().
 321 #   LINK_COMPONENTS components...
 322 #     Same as the variable LLVM_LINK_COMPONENTS.
 323 #   LINK_LIBS lib_targets...
 324 #     Same semantics as target_link_libraries().
 325 #   ADDITIONAL_HEADERS
 326 #     May specify header files for IDE generators.
 327 #   )
 328 function(llvm_add_library name)
 329   cmake_parse_arguments(ARG
 330     "MODULE;SHARED;STATIC;DISABLE_LLVM_LINK_LLVM_DYLIB"
 331     "OUTPUT_NAME"
 332     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 333     ${ARGN})
 334   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 335   if(ARG_ADDITIONAL_HEADERS)
 336     # Pass through ADDITIONAL_HEADERS.
 337     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 338   endif()
 339   if(ARG_OBJLIBS)
 340     set(ALL_FILES ${ARG_OBJLIBS})
 341   else()
 342     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 343   endif()
 344
 345   if(ARG_MODULE)
 346     if(ARG_SHARED OR ARG_STATIC)
 347       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 348     endif()
 349     if(NOT LLVM_ENABLE_PLUGINS)
 350       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 351       return()
 352     endif()
 353   else()
 354     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 355       set(ARG_SHARED TRUE)
 356     endif()
 357     if(NOT ARG_SHARED)
 358       set(ARG_STATIC TRUE)
 359     endif()
 360   endif()
 361
 362   # Generate objlib
 363   if(ARG_SHARED AND ARG_STATIC)
 364     # Generate an obj library for both targets.
 365     set(obj_name "obj.${name}")
 366     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 367       ${ALL_FILES}
 368       )
 369     llvm_update_compile_flags(${obj_name})
 370     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 371
 372     # Do add_dependencies(obj) later due to CMake issue 14747.
 373     list(APPEND objlibs ${obj_name})
 374
 375     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 376   endif()
 377
 378   if(ARG_SHARED AND ARG_STATIC)
 379     # static
 380     set(name_static "${name}_static")
 381     if(ARG_OUTPUT_NAME)
 382       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 383     endif()
 384     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 385     llvm_add_library(${name_static} STATIC
 386       ${output_name}
 387       OBJLIBS ${ALL_FILES} # objlib
 388       LINK_LIBS ${ARG_LINK_LIBS}
 389       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 390       )
 391     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 392     set(ARG_STATIC)
 393   endif()
 394
 395   if(ARG_MODULE)
 396     add_library(${name} MODULE ${ALL_FILES})
 397   elseif(ARG_SHARED)
 398     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 399     add_library(${name} SHARED ${ALL_FILES})
 400   else()
 401     add_library(${name} STATIC ${ALL_FILES})
 402   endif()
 403
 404   if(DEFINED windows_resource_file)
 405     set_windows_version_resource_properties(${name} ${windows_resource_file})
 406     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 407   endif()
 408
 409   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 410   # $<TARGET_OBJECTS> doesn't require compile flags.
 411   if(NOT obj_name)
 412     llvm_update_compile_flags(${name})
 413   endif()
 414   add_link_opts( ${name} )
 415   if(ARG_OUTPUT_NAME)
 416     set_target_properties(${name}
 417       PROPERTIES
 418       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 419       )
 420   endif()
 421
 422   if(ARG_MODULE)
 423     set_target_properties(${name} PROPERTIES
 424       PREFIX ""
 425       SUFFIX ${LLVM_PLUGIN_EXT}
 426       )
 427   endif()
 428
 429   if(ARG_SHARED)
 430     if(WIN32)
 431       set_target_properties(${name} PROPERTIES
 432         PREFIX ""
 433         )
 434     endif()
 435
 436     set_target_properties(${name}
 437       PROPERTIES
 438       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 439       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 440   endif()
 441
 442   if(ARG_MODULE OR ARG_SHARED)
 443     # Do not add -Dname_EXPORTS to the command-line when building files in this
 444     # target. Doing so is actively harmful for the modules build because it
 445     # creates extra module variants, and not useful because we don't use these
 446     # macros.
 447     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 448
 449     if (LLVM_EXPORTED_SYMBOL_FILE)
 450       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 451     endif()
 452   endif()
 453
 454   # Add the explicit dependency information for this library.
 455   #
 456   # It would be nice to verify that we have the dependencies for this library
 457   # name, but using get_property(... SET) doesn't suffice to determine if a
 458   # property has been set to an empty value.
 459   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 460
 461   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_STATIC AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 462     set(llvm_libs LLVM)
 463   else()
 464     llvm_map_components_to_libnames(llvm_libs
 465       ${ARG_LINK_COMPONENTS}
 466       ${LLVM_LINK_COMPONENTS}
 467       )
 468   endif()
 469
 470   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 471     # Link libs w/o keywords, assuming PUBLIC.
 472     target_link_libraries(${name}
 473       ${ARG_LINK_LIBS}
 474       ${lib_deps}
 475       ${llvm_libs}
 476       )
 477   elseif(ARG_STATIC)
 478     target_link_libraries(${name} INTERFACE
 479       ${ARG_LINK_LIBS}
 480       ${lib_deps}
 481       ${llvm_libs}
 482       )
 483   else()
 484     # We can use PRIVATE since SO knows its dependent libs.
 485     target_link_libraries(${name} PRIVATE
 486       ${ARG_LINK_LIBS}
 487       ${lib_deps}
 488       ${llvm_libs}
 489       )
 490   endif()
 491
 492   if(LLVM_COMMON_DEPENDS)
 493     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 494     # Add dependencies also to objlibs.
 495     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 496     foreach(objlib ${objlibs})
 497       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 498     endforeach()
 499   endif()
 500 endfunction()
 501
 502 macro(add_llvm_library name)
 503   cmake_parse_arguments(ARG
 504     "SHARED"
 505     ""
 506     ""
 507     ${ARGN})
 508   if( BUILD_SHARED_LIBS )
 509     llvm_add_library(${name} SHARED ${ARGN})
 510   else()
 511     llvm_add_library(${name} ${ARGN})
 512   endif()
 513   # The gtest libraries should not be installed or exported as a target
 514   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 515     set(_is_gtest TRUE)
 516   else()
 517     set(_is_gtest FALSE)
 518     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 519   endif()
 520
 521   if( EXCLUDE_FROM_ALL )
 522     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 523   elseif(NOT _is_gtest)
 524     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 525       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 526         if(WIN32 OR CYGWIN)
 527           set(install_type RUNTIME)
 528         else()
 529           set(install_type LIBRARY)
 530         endif()
 531       else()
 532         set(install_type ARCHIVE)
 533       endif()
 534
 535       install(TARGETS ${name}
 536             EXPORT LLVMExports
 537             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 538             COMPONENT ${name})
 539
 540       if (NOT CMAKE_CONFIGURATION_TYPES)
 541         add_custom_target(install-${name}
 542                           DEPENDS ${name}
 543                           COMMAND "${CMAKE_COMMAND}"
 544                                   -DCMAKE_INSTALL_COMPONENT=${name}
 545                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 546       endif()
 547     endif()
 548     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 549   endif()
 550   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 551 endmacro(add_llvm_library name)
 552
 553 macro(add_llvm_loadable_module name)
 554   llvm_add_library(${name} MODULE ${ARGN})
 555   if(NOT TARGET ${name})
 556     # Add empty "phony" target
 557     add_custom_target(${name})
 558   else()
 559     if( EXCLUDE_FROM_ALL )
 560       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 561     else()
 562       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 563         if(WIN32 OR CYGWIN)
 564           # DLL platform
 565           set(dlldir "bin")
 566         else()
 567           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 568         endif()
 569         install(TARGETS ${name}
 570           EXPORT LLVMExports
 571           LIBRARY DESTINATION ${dlldir}
 572           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 573       endif()
 574       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 575     endif()
 576   endif()
 577
 578   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 579 endmacro(add_llvm_loadable_module name)
 580
 581
 582 macro(add_llvm_executable name)
 583   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB" "" "" ${ARGN})
 584   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 585
 586   # Generate objlib
 587   if(LLVM_ENABLE_OBJLIB)
 588     # Generate an obj library for both targets.
 589     set(obj_name "obj.${name}")
 590     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 591       ${ALL_FILES}
 592       )
 593     llvm_update_compile_flags(${obj_name})
 594     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 595
 596     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 597   endif()
 598
 599   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 600
 601   if(XCODE)
 602     # Note: the dummy.cpp source file provides no definitions. However,
 603     # it forces Xcode to properly link the static library.
 604     list(APPEND ALL_FILES "${LLVM_MAIN_SRC_DIR}/cmake/dummy.cpp")
 605   endif()
 606
 607   if( EXCLUDE_FROM_ALL )
 608     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 609   else()
 610     add_executable(${name} ${ALL_FILES})
 611   endif()
 612
 613   if(DEFINED windows_resource_file)
 614     set_windows_version_resource_properties(${name} ${windows_resource_file})
 615   endif()
 616
 617   # $<TARGET_OBJECTS> doesn't require compile flags.
 618   if(NOT LLVM_ENABLE_OBJLIB)
 619     llvm_update_compile_flags(${name})
 620   endif()
 621   add_link_opts( ${name} )
 622
 623   # Do not add -Dname_EXPORTS to the command-line when building files in this
 624   # target. Doing so is actively harmful for the modules build because it
 625   # creates extra module variants, and not useful because we don't use these
 626   # macros.
 627   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 628
 629   if (LLVM_EXPORTED_SYMBOL_FILE)
 630     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 631   endif(LLVM_EXPORTED_SYMBOL_FILE)
 632
 633   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 634     set(USE_SHARED USE_SHARED)
 635   endif()
 636
 637   set(EXCLUDE_FROM_ALL OFF)
 638   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 639   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 640   if( LLVM_COMMON_DEPENDS )
 641     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 642   endif( LLVM_COMMON_DEPENDS )
 643 endmacro(add_llvm_executable name)
 644
 645 function(export_executable_symbols target)
 646   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 647     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 648   endif()
 649 endfunction()
 650
 651 if(NOT LLVM_TOOLCHAIN_TOOLS)
 652   set (LLVM_TOOLCHAIN_TOOLS
 653     llvm-ar
 654     llvm-ranlib
 655     llvm-lib
 656     llvm-objdump
 657     )
 658 endif()
 659
 660 macro(add_llvm_tool name)
 661   if( NOT LLVM_BUILD_TOOLS )
 662     set(EXCLUDE_FROM_ALL ON)
 663   endif()
 664   add_llvm_executable(${name} ${ARGN})
 665
 666   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 667   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 668     if( LLVM_BUILD_TOOLS )
 669       install(TARGETS ${name}
 670               EXPORT LLVMExports
 671               RUNTIME DESTINATION bin
 672               COMPONENT ${name})
 673
 674       if (NOT CMAKE_CONFIGURATION_TYPES)
 675         add_custom_target(install-${name}
 676                           DEPENDS ${name}
 677                           COMMAND "${CMAKE_COMMAND}"
 678                                   -DCMAKE_INSTALL_COMPONENT=${name}
 679                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 680       endif()
 681     endif()
 682   endif()
 683   if( LLVM_BUILD_TOOLS )
 684     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 685   endif()
 686   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 687 endmacro(add_llvm_tool name)
 688
 689
 690 macro(add_llvm_example name)
 691   if( NOT LLVM_BUILD_EXAMPLES )
 692     set(EXCLUDE_FROM_ALL ON)
 693   endif()
 694   add_llvm_executable(${name} ${ARGN})
 695   if( LLVM_BUILD_EXAMPLES )
 696     install(TARGETS ${name} RUNTIME DESTINATION examples)
 697   endif()
 698   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 699 endmacro(add_llvm_example name)
 700
 701
 702 macro(add_llvm_utility name)
 703   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 704   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 705   if( LLVM_INSTALL_UTILS )
 706     install (TARGETS ${name}
 707       RUNTIME DESTINATION bin
 708       COMPONENT ${name})
 709     if (NOT CMAKE_CONFIGURATION_TYPES)
 710       add_custom_target(install-${name}
 711                         DEPENDS ${name}
 712                         COMMAND "${CMAKE_COMMAND}"
 713                                 -DCMAKE_INSTALL_COMPONENT=${name}
 714                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 715     endif()
 716   endif()
 717 endmacro(add_llvm_utility name)
 718
 719
 720 macro(add_llvm_target target_name)
 721   include_directories(BEFORE
 722     ${CMAKE_CURRENT_BINARY_DIR}
 723     ${CMAKE_CURRENT_SOURCE_DIR})
 724   add_llvm_library(LLVM${target_name} ${ARGN})
 725   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 726 endmacro(add_llvm_target)
 727
 728 function(canonicalize_tool_name name output)
 729   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 730   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 731   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 732   set(${output} "${nameUPPER}" PARENT_SCOPE)
 733 endfunction(canonicalize_tool_name)
 734
 735 # Custom add_subdirectory wrapper
 736 # Takes in a project name (i.e. LLVM), the the subdirectory name, and an
 737 # and an optional path if it differs from the name.
 738 macro(add_llvm_subdirectory project type name)
 739   set(add_llvm_external_dir "${ARGN}")
 740   if("${add_llvm_external_dir}" STREQUAL "")
 741     set(add_llvm_external_dir ${name})
 742   endif()
 743   canonicalize_tool_name(${name} nameUPPER)
 744   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 745     # Treat it as in-tree subproject.
 746     option(${project}_${type}_${nameUPPER}_BUILD
 747            "Whether to build ${name} as part of ${project}" On)
 748     mark_as_advanced(${project}_${type}_${name}_BUILD)
 749     if(${project}_${type}_${nameUPPER}_BUILD)
 750       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 751       # Don't process it in add_llvm_implicit_projects().
 752       set(${project}_${type}_${nameUPPER}_BUILD OFF)
 753     endif()
 754   else()
 755     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 756       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 757       CACHE PATH "Path to ${name} source directory")
 758     set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT ON)
 759     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 760       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 761     endif()
 762     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 763       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 764     endif()
 765     option(${project}_${type}_${nameUPPER}_BUILD
 766       "Whether to build ${name} as part of LLVM"
 767       ${${project}_${type}_${nameUPPER}_BUILD_DEFAULT})
 768     if (${project}_${type}_${nameUPPER}_BUILD)
 769       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 770         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 771       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 772         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 773       endif()
 774       # FIXME: It'd be redundant.
 775       set(${project}_${type}_${nameUPPER}_BUILD Off)
 776     endif()
 777   endif()
 778 endmacro()
 779
 780 # Add external project that may want to be built as part of llvm such as Clang,
 781 # lld, and Polly. This adds two options. One for the source directory of the
 782 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 783 # enable or disable building it with everything else.
 784 # Additional parameter can be specified as the name of directory.
 785 macro(add_llvm_external_project name)
 786   add_llvm_subdirectory(LLVM TOOL ${name} ${ARGN})
 787 endmacro()
 788
 789 macro(add_llvm_tool_subdirectory name)
 790   add_llvm_external_project(${name})
 791 endmacro(add_llvm_tool_subdirectory)
 792
 793 function(get_project_name_from_src_var var output)
 794   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 795          MACHED_TOOL "${var}")
 796   if(MACHED_TOOL)
 797     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 798   else()
 799     set(${output} PARENT_SCOPE)
 800   endif()
 801 endfunction()
 802
 803 function(create_subdirectory_options project type)
 804   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 805   foreach(dir ${sub-dirs})
 806     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 807       canonicalize_tool_name(${dir} name)
 808       option(${project}_${type}_${name}_BUILD
 809            "Whether to build ${name} as part of ${project}" On)
 810       mark_as_advanced(${project}_${type}_${name}_BUILD)
 811     endif()
 812   endforeach()
 813 endfunction(create_subdirectory_options)
 814
 815 function(create_llvm_tool_options)
 816   create_subdirectory_options(LLVM TOOL)
 817 endfunction(create_llvm_tool_options)
 818
 819 function(add_llvm_implicit_projects)
 820   set(list_of_implicit_subdirs "")
 821   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 822   foreach(dir ${sub-dirs})
 823     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 824       canonicalize_tool_name(${dir} name)
 825       if (LLVM_TOOL_${name}_BUILD)
 826         get_filename_component(fn "${dir}" NAME)
 827         list(APPEND list_of_implicit_subdirs "${fn}")
 828       endif()
 829     endif()
 830   endforeach()
 831
 832   foreach(external_proj ${list_of_implicit_subdirs})
 833     add_llvm_external_project("${external_proj}")
 834   endforeach()
 835 endfunction(add_llvm_implicit_projects)
 836
 837 # Generic support for adding a unittest.
 838 function(add_unittest test_suite test_name)
 839   if( NOT LLVM_BUILD_TESTS )
 840     set(EXCLUDE_FROM_ALL ON)
 841   endif()
 842
 843   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 844   if (NOT LLVM_ENABLE_THREADS)
 845     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 846   endif ()
 847
 848   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 849     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 850   endif ()
 851
 852   set(LLVM_REQUIRES_RTTI OFF)
 853
 854   add_llvm_executable(${test_name} ${ARGN})
 855   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 856   set_output_directory(${test_name} BINARY_DIR ${outdir} LIBRARY_DIR ${outdir})
 857   target_link_libraries(${test_name}
 858     gtest
 859     gtest_main
 860     LLVMSupport # gtest needs it for raw_ostream.
 861     )
 862
 863   add_dependencies(${test_suite} ${test_name})
 864   get_target_property(test_suite_folder ${test_suite} FOLDER)
 865   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 866     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 867   endif ()
 868 endfunction()
 869
 870 function(llvm_add_go_executable binary pkgpath)
 871   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 872
 873   if(LLVM_BINDINGS MATCHES "go")
 874     # FIXME: This should depend only on the libraries Go needs.
 875     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 876     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 877     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 878     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 879     set(cppflags "")
 880     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 881     foreach(d ${include_dirs})
 882       set(cppflags "${cppflags} -I${d}")
 883     endforeach(d)
 884     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 885     if (LLVM_LINK_LLVM_DYLIB)
 886       set(linkmode "dylib")
 887     else()
 888       set(linkmode "component-libs")
 889     endif()
 890     add_custom_command(OUTPUT ${binpath}
 891       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "linkmode=${linkmode}"
 892               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 893       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 894               ${llvmlibs} ${ARG_DEPENDS}
 895       COMMENT "Building Go executable ${binary}"
 896       VERBATIM)
 897     if (ARG_ALL)
 898       add_custom_target(${binary} ALL DEPENDS ${binpath})
 899     else()
 900       add_custom_target(${binary} DEPENDS ${binpath})
 901     endif()
 902   endif()
 903 endfunction()
 904
 905 # This function provides an automatic way to 'configure'-like generate a file
 906 # based on a set of common and custom variables, specifically targeting the
 907 # variables needed for the 'lit.site.cfg' files. This function bundles the
 908 # common variables that any Lit instance is likely to need, and custom
 909 # variables can be passed in.
 910 function(configure_lit_site_cfg input output)
 911   foreach(c ${LLVM_TARGETS_TO_BUILD})
 912     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 913   endforeach(c)
 914   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 915
 916   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 917
 918   # Configuration-time: See Unit/lit.site.cfg.in
 919   if (CMAKE_CFG_INTDIR STREQUAL ".")
 920     set(LLVM_BUILD_MODE ".")
 921   else ()
 922     set(LLVM_BUILD_MODE "%(build_mode)s")
 923   endif ()
 924
 925   # They below might not be the build tree but provided binary tree.
 926   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 927   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 928   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 929   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 930
 931   # SHLIBDIR points the build tree.
 932   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 933
 934   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 935   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 936   # plugins. We may rename it.
 937   if(LLVM_ENABLE_PLUGINS)
 938     set(ENABLE_SHARED "1")
 939   else()
 940     set(ENABLE_SHARED "0")
 941   endif()
 942
 943   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 944     set(ENABLE_ASSERTIONS "1")
 945   else()
 946     set(ENABLE_ASSERTIONS "0")
 947   endif()
 948
 949   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 950   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 951
 952   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 953   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 954   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 955
 956   configure_file(${input} ${output} @ONLY)
 957 endfunction()
 958
 959 # A raw function to create a lit target. This is used to implement the testuite
 960 # management functions.
 961 function(add_lit_target target comment)
 962   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 963   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 964   separate_arguments(LIT_ARGS)
 965   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 966     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 967   endif ()
 968   if (LLVM_MAIN_SRC_DIR)
 969     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 970   else()
 971     find_program(LIT_COMMAND llvm-lit)
 972   endif ()
 973   list(APPEND LIT_COMMAND ${LIT_ARGS})
 974   foreach(param ${ARG_PARAMS})
 975     list(APPEND LIT_COMMAND --param ${param})
 976   endforeach()
 977   if (ARG_UNPARSED_ARGUMENTS)
 978     add_custom_target(${target}
 979       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 980       COMMENT "${comment}"
 981       ${cmake_3_2_USES_TERMINAL}
 982       )
 983   else()
 984     add_custom_target(${target}
 985       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 986     message(STATUS "${target} does nothing.")
 987   endif()
 988   if (ARG_DEPENDS)
 989     add_dependencies(${target} ${ARG_DEPENDS})
 990   endif()
 991
 992   # Tests should be excluded from "Build Solution".
 993   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 994 endfunction()
 995
 996 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 997 function(add_lit_testsuite target comment)
 998   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 999
1000   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
1001   if(NOT EXCLUDE_FROM_ALL)
1002     # Register the testsuites, params and depends for the global check rule.
1003     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
1004     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
1005     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
1006     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
1007   endif()
1008
1009   # Produce a specific suffixed check rule.
1010   add_lit_target(${target} ${comment}
1011     ${ARG_UNPARSED_ARGUMENTS}
1012     PARAMS ${ARG_PARAMS}
1013     DEPENDS ${ARG_DEPENDS}
1014     ARGS ${ARG_ARGS}
1015     )
1016 endfunction()
1017
1018 function(add_lit_testsuites project directory)
1019   if (NOT CMAKE_CONFIGURATION_TYPES)
1020     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1021     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
1022     set(lit_suites)
1023     foreach(f ${litCfg})
1024       get_filename_component(dir ${f} DIRECTORY)
1025       set(lit_suites ${lit_suites} ${dir})
1026     endforeach()
1027     list(REMOVE_DUPLICATES lit_suites)
1028     foreach(dir ${lit_suites})
1029       string(REPLACE ${directory} "" name_slash ${dir})
1030       if (name_slash)
1031         string(REPLACE "/" "-" name_slash ${name_slash})
1032         string(REPLACE "\\" "-" name_dashes ${name_slash})
1033         string(TOLOWER "${project}${name_dashes}" name_var)
1034         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
1035           ${dir}
1036           PARAMS ${ARG_PARAMS}
1037           DEPENDS ${ARG_DEPENDS}
1038           ARGS ${ARG_ARGS}
1039         )
1040       endif()
1041     endforeach()
1042   endif()
1043 endfunction()
1044
1045 function(llvm_install_symlink name dest)
1046   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1047   foreach(path ${CMAKE_MODULE_PATH})
1048     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1049       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1050       break()
1051     endif()
1052   endforeach()
1053
1054   if(ARG_ALWAYS_GENERATE)
1055     set(component ${dest})
1056   else()
1057     set(component ${name})
1058   endif()
1059
1060   set(full_name ${name}${CMAKE_EXECUTABLE_SUFFIX})
1061   set(full_dest ${dest}${CMAKE_EXECUTABLE_SUFFIX})
1062
1063   install(SCRIPT ${INSTALL_SYMLINK}
1064           CODE "install_symlink(${full_name} ${full_dest} bin)"
1065           COMPONENT ${component})
1066
1067   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1068     add_custom_target(install-${name}
1069                       DEPENDS ${name} ${dest} install-${dest}
1070                       COMMAND "${CMAKE_COMMAND}"
1071                               -DCMAKE_INSTALL_COMPONENT=${name}
1072                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1073   endif()
1074 endfunction()
1075
1076 function(add_llvm_tool_symlink name dest)
1077   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1078   if(UNIX)
1079     set(LLVM_LINK_OR_COPY create_symlink)
1080     set(dest_binary "${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1081   else()
1082     set(LLVM_LINK_OR_COPY copy)
1083     set(dest_binary "${LLVM_RUNTIME_OUTPUT_INTDIR}/${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1084   endif()
1085
1086   set(output_path "${LLVM_RUNTIME_OUTPUT_INTDIR}/${name}${CMAKE_EXECUTABLE_SUFFIX}")
1087
1088   if(ARG_ALWAYS_GENERATE)
1089     set_property(DIRECTORY APPEND PROPERTY
1090       ADDITIONAL_MAKE_CLEAN_FILES ${dest_binary})
1091     add_custom_command(TARGET ${dest} POST_BUILD
1092       COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}")
1093   else()
1094     add_custom_command(OUTPUT ${output_path}
1095                      COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}"
1096                      DEPENDS ${dest})
1097     add_custom_target(${name} ALL DEPENDS ${output_path})
1098     set_target_properties(${name} PROPERTIES FOLDER Tools)
1099
1100     # Make sure the parent tool is a toolchain tool, otherwise exclude this tool
1101     list(FIND LLVM_TOOLCHAIN_TOOLS ${dest} LLVM_IS_${dest}_TOOLCHAIN_TOOL)
1102     if (NOT LLVM_IS_${dest}_TOOLCHAIN_TOOL GREATER -1)
1103       set(LLVM_IS_${name}_TOOLCHAIN_TOOL ${LLVM_IS_${dest}_TOOLCHAIN_TOOL})
1104     else()
1105       list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
1106     endif()
1107
1108     # LLVM_IS_${name}_TOOLCHAIN_TOOL will only be greater than -1 if both this
1109     # tool and its parent tool are in LLVM_TOOLCHAIN_TOOLS
1110     if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1111       if( LLVM_BUILD_TOOLS )
1112         llvm_install_symlink(${name} ${dest})
1113       endif()
1114     endif()
1115   endif()
1116 endfunction()
1117