cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3 include(DetermineGCCCompatible)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   set(LLVM_CONFIG_HAS_RTTI YES CACHE INTERNAL "")
  30   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  31     set(LLVM_CONFIG_HAS_RTTI NO CACHE INTERNAL "")
  32     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  33     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  34       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  35     elseif (MSVC)
  36       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  37     endif ()
  38   endif()
  39
  40   # Assume that;
  41   #   - LLVM_COMPILE_FLAGS is list.
  42   #   - PROPERTY COMPILE_FLAGS is string.
  43   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  44
  45   if(update_src_props)
  46     foreach(fn ${sources})
  47       get_filename_component(suf ${fn} EXT)
  48       if("${suf}" STREQUAL ".cpp")
  49         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  50           COMPILE_FLAGS "${target_compile_flags}")
  51       endif()
  52     endforeach()
  53   else()
  54     # Update target props, since all sources are C++.
  55     set_property(TARGET ${name} APPEND_STRING PROPERTY
  56       COMPILE_FLAGS "${target_compile_flags}")
  57   endif()
  58
  59   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  60 endfunction()
  61
  62 function(add_llvm_symbol_exports target_name export_file)
  63   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  64     set(native_export_file "${target_name}.exports")
  65     add_custom_command(OUTPUT ${native_export_file}
  66       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  67       DEPENDS ${export_file}
  68       VERBATIM
  69       COMMENT "Creating export file for ${target_name}")
  70     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  71                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  72   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  73     # Gold and BFD ld require a version script rather than a plain list.
  74     set(native_export_file "${target_name}.exports")
  75     # FIXME: Don't write the "local:" line on OpenBSD.
  76     add_custom_command(OUTPUT ${native_export_file}
  77       COMMAND echo "{" > ${native_export_file}
  78       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  79       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  80       COMMAND echo "  local: *;" >> ${native_export_file}
  81       COMMAND echo "};" >> ${native_export_file}
  82       DEPENDS ${export_file}
  83       VERBATIM
  84       COMMENT "Creating export file for ${target_name}")
  85     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  86       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  87                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  88     else()
  89       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  90                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  91     endif()
  92   else()
  93     set(native_export_file "${target_name}.def")
  94
  95     add_custom_command(OUTPUT ${native_export_file}
  96       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
  97         < ${export_file} > ${native_export_file}
  98       DEPENDS ${export_file}
  99       VERBATIM
 100       COMMENT "Creating export file for ${target_name}")
 101     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 102     if(MSVC)
 103       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 104     endif()
 105     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 106                  LINK_FLAGS " ${export_file_linker_flag}")
 107   endif()
 108
 109   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 110   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 111
 112   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 113   foreach(src ${srcs})
 114     get_filename_component(extension ${src} EXT)
 115     if(extension STREQUAL ".cpp")
 116       set(first_source_file ${src})
 117       break()
 118     endif()
 119   endforeach()
 120
 121   # Force re-linking when the exports file changes. Actually, it
 122   # forces recompilation of the source file. The LINK_DEPENDS target
 123   # property only works for makefile-based generators.
 124   # FIXME: This is not safe because this will create the same target
 125   # ${native_export_file} in several different file:
 126   # - One where we emitted ${target_name}_exports
 127   # - One where we emitted the build command for the following object.
 128   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 129   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 130
 131   set_property(DIRECTORY APPEND
 132     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 133
 134   add_dependencies(${target_name} ${target_name}_exports)
 135
 136   # Add dependency to *_exports later -- CMake issue 14747
 137   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 138   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 139 endfunction(add_llvm_symbol_exports)
 140
 141 if(NOT WIN32 AND NOT APPLE)
 142   execute_process(
 143     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 144     OUTPUT_VARIABLE stdout
 145     ERROR_QUIET
 146     )
 147   if("${stdout}" MATCHES "GNU gold")
 148     set(LLVM_LINKER_IS_GOLD ON)
 149   endif()
 150 endif()
 151
 152 function(add_link_opts target_name)
 153   # Don't use linker optimizations in debug builds since it slows down the
 154   # linker in a context where the optimizations are not important.
 155   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 156
 157     # Pass -O3 to the linker. This enabled different optimizations on different
 158     # linkers.
 159     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 160       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 161                    LINK_FLAGS " -Wl,-O3")
 162     endif()
 163
 164     if(LLVM_LINKER_IS_GOLD)
 165       # With gold gc-sections is always safe.
 166       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 167                    LINK_FLAGS " -Wl,--gc-sections")
 168       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 169       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 170     endif()
 171
 172     if(NOT LLVM_NO_DEAD_STRIP)
 173       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 174         # ld64's implementation of -dead_strip breaks tools that use plugins.
 175         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 176                      LINK_FLAGS " -Wl,-dead_strip")
 177       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 178         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 179                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 180       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 181         # Object files are compiled with -ffunction-data-sections.
 182         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 183         # tools that use plugins. Always pass --gc-sections once we require
 184         # a newer linker.
 185         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 186                      LINK_FLAGS " -Wl,--gc-sections")
 187       endif()
 188     endif()
 189   endif()
 190 endfunction(add_link_opts)
 191
 192 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 193 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 194 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 195 function(set_output_directory target)
 196   cmake_parse_arguments(ARG "" "BINARY_DIR;LIBRARY_DIR" "" ${ARGN})
 197
 198   # module_dir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 199   # It affects output of add_library(MODULE).
 200   if(WIN32 OR CYGWIN)
 201     # DLL platform
 202     set(module_dir ${ARG_BINARY_DIR})
 203   else()
 204     set(module_dir ${ARG_LIBRARY_DIR})
 205   endif()
 206   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 207     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 208       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 209       if(ARG_BINARY_DIR)
 210         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${ARG_BINARY_DIR})
 211         set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 212       endif()
 213       if(ARG_LIBRARY_DIR)
 214         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${ARG_LIBRARY_DIR})
 215         set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 216       endif()
 217       if(module_dir)
 218         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${module_dir})
 219         set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 220       endif()
 221     endforeach()
 222   else()
 223     if(ARG_BINARY_DIR)
 224       set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${ARG_BINARY_DIR})
 225     endif()
 226     if(ARG_LIBRARY_DIR)
 227       set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${ARG_LIBRARY_DIR})
 228     endif()
 229     if(module_dir)
 230       set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${module_dir})
 231     endif()
 232   endif()
 233 endfunction()
 234
 235 # If on Windows and building with MSVC, add the resource script containing the
 236 # VERSIONINFO data to the project.  This embeds version resource information
 237 # into the output .exe or .dll.
 238 # TODO: Enable for MinGW Windows builds too.
 239 #
 240 function(add_windows_version_resource_file OUT_VAR)
 241   set(sources ${ARGN})
 242   if (MSVC)
 243     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 244     if(EXISTS ${resource_file})
 245       set(sources ${sources} ${resource_file})
 246       source_group("Resource Files" ${resource_file})
 247       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 248     endif()
 249   endif(MSVC)
 250
 251   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 252 endfunction(add_windows_version_resource_file)
 253
 254 # set_windows_version_resource_properties(name resource_file...
 255 #   VERSION_MAJOR int
 256 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 257 #   VERSION_MINOR int
 258 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 259 #   VERSION_PATCHLEVEL int
 260 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 261 #   VERSION_STRING
 262 #     Optional version string (defaults to PACKAGE_VERSION)
 263 #   PRODUCT_NAME
 264 #     Optional product name string (defaults to "LLVM")
 265 #   )
 266 function(set_windows_version_resource_properties name resource_file)
 267   cmake_parse_arguments(ARG
 268     ""
 269     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 270     ""
 271     ${ARGN})
 272
 273   if (NOT DEFINED ARG_VERSION_MAJOR)
 274     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_MINOR)
 278     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 279   endif()
 280
 281   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 282     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 283   endif()
 284
 285   if (NOT DEFINED ARG_VERSION_STRING)
 286     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 287   endif()
 288
 289   if (NOT DEFINED ARG_PRODUCT_NAME)
 290     set(ARG_PRODUCT_NAME "LLVM")
 291   endif()
 292
 293   set_property(SOURCE ${resource_file}
 294                PROPERTY COMPILE_FLAGS /nologo)
 295   set_property(SOURCE ${resource_file}
 296                PROPERTY COMPILE_DEFINITIONS
 297                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 298                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 299                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 300                "RC_VERSION_FIELD_4=0"
 301                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 302                "RC_INTERNAL_NAME=\"${name}\""
 303                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 304                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 305 endfunction(set_windows_version_resource_properties)
 306
 307 # llvm_add_library(name sources...
 308 #   SHARED;STATIC
 309 #     STATIC by default w/o BUILD_SHARED_LIBS.
 310 #     SHARED by default w/  BUILD_SHARED_LIBS.
 311 #   MODULE
 312 #     Target ${name} might not be created on unsupported platforms.
 313 #     Check with "if(TARGET ${name})".
 314 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 315 #     Do not link this library to libLLVM, even if
 316 #     LLVM_LINK_LLVM_DYLIB is enabled.
 317 #   OUTPUT_NAME name
 318 #     Corresponds to OUTPUT_NAME in target properties.
 319 #   DEPENDS targets...
 320 #     Same semantics as add_dependencies().
 321 #   LINK_COMPONENTS components...
 322 #     Same as the variable LLVM_LINK_COMPONENTS.
 323 #   LINK_LIBS lib_targets...
 324 #     Same semantics as target_link_libraries().
 325 #   ADDITIONAL_HEADERS
 326 #     May specify header files for IDE generators.
 327 #   SONAME
 328 #     Should set SONAME link flags and create symlinks
 329 #   )
 330 function(llvm_add_library name)
 331   cmake_parse_arguments(ARG
 332     "MODULE;SHARED;STATIC;DISABLE_LLVM_LINK_LLVM_DYLIB;SONAME"
 333     "OUTPUT_NAME"
 334     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 335     ${ARGN})
 336   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 337   if(ARG_ADDITIONAL_HEADERS)
 338     # Pass through ADDITIONAL_HEADERS.
 339     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 340   endif()
 341   if(ARG_OBJLIBS)
 342     set(ALL_FILES ${ARG_OBJLIBS})
 343   else()
 344     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 345   endif()
 346
 347   if(ARG_MODULE)
 348     if(ARG_SHARED OR ARG_STATIC)
 349       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 350     endif()
 351     if(NOT LLVM_ENABLE_PLUGINS)
 352       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 353       return()
 354     endif()
 355   else()
 356     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 357       set(ARG_SHARED TRUE)
 358     endif()
 359     if(NOT ARG_SHARED)
 360       set(ARG_STATIC TRUE)
 361     endif()
 362   endif()
 363
 364   # Generate objlib
 365   if(ARG_SHARED AND ARG_STATIC)
 366     # Generate an obj library for both targets.
 367     set(obj_name "obj.${name}")
 368     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 369       ${ALL_FILES}
 370       )
 371     llvm_update_compile_flags(${obj_name})
 372     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 373
 374     # Do add_dependencies(obj) later due to CMake issue 14747.
 375     list(APPEND objlibs ${obj_name})
 376
 377     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 378   endif()
 379
 380   if(ARG_SHARED AND ARG_STATIC)
 381     # static
 382     set(name_static "${name}_static")
 383     if(ARG_OUTPUT_NAME)
 384       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 385     endif()
 386     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 387     llvm_add_library(${name_static} STATIC
 388       ${output_name}
 389       OBJLIBS ${ALL_FILES} # objlib
 390       LINK_LIBS ${ARG_LINK_LIBS}
 391       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 392       )
 393     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 394     set(ARG_STATIC)
 395   endif()
 396
 397   if(ARG_MODULE)
 398     add_library(${name} MODULE ${ALL_FILES})
 399   elseif(ARG_SHARED)
 400     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 401     add_library(${name} SHARED ${ALL_FILES})
 402   else()
 403     add_library(${name} STATIC ${ALL_FILES})
 404   endif()
 405
 406   if(DEFINED windows_resource_file)
 407     set_windows_version_resource_properties(${name} ${windows_resource_file})
 408     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 409   endif()
 410
 411   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 412   # $<TARGET_OBJECTS> doesn't require compile flags.
 413   if(NOT obj_name)
 414     llvm_update_compile_flags(${name})
 415   endif()
 416   add_link_opts( ${name} )
 417   if(ARG_OUTPUT_NAME)
 418     set_target_properties(${name}
 419       PROPERTIES
 420       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 421       )
 422   endif()
 423
 424   if(ARG_MODULE)
 425     set_target_properties(${name} PROPERTIES
 426       PREFIX ""
 427       SUFFIX ${LLVM_PLUGIN_EXT}
 428       )
 429   endif()
 430
 431   if(ARG_SHARED)
 432     if(WIN32)
 433       set_target_properties(${name} PROPERTIES
 434         PREFIX ""
 435         )
 436     endif()
 437   endif()
 438
 439   if(ARG_MODULE OR ARG_SHARED)
 440     # Do not add -Dname_EXPORTS to the command-line when building files in this
 441     # target. Doing so is actively harmful for the modules build because it
 442     # creates extra module variants, and not useful because we don't use these
 443     # macros.
 444     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 445
 446     if (LLVM_EXPORTED_SYMBOL_FILE)
 447       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 448     endif()
 449   endif()
 450
 451   if(ARG_SHARED AND UNIX)
 452     if(NOT APPLE AND ARG_SONAME)
 453       get_target_property(output_name ${name} OUTPUT_NAME)
 454       if(${output_name} STREQUAL "output_name-NOTFOUND")
 455         set(output_name ${name})
 456       endif()
 457       set(library_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}${LLVM_VERSION_SUFFIX})
 458       set(api_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 459       set_target_properties(${name} PROPERTIES OUTPUT_NAME ${library_name})
 460       llvm_install_library_symlink(${api_name} ${library_name} SHARED
 461         COMPONENT ${name}
 462         ALWAYS_GENERATE)
 463       llvm_install_library_symlink(${output_name} ${library_name} SHARED
 464         COMPONENT ${name}
 465         ALWAYS_GENERATE)
 466     endif()
 467   endif()
 468
 469   # Add the explicit dependency information for this library.
 470   #
 471   # It would be nice to verify that we have the dependencies for this library
 472   # name, but using get_property(... SET) doesn't suffice to determine if a
 473   # property has been set to an empty value.
 474   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 475
 476   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_STATIC AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 477     set(llvm_libs LLVM)
 478   else()
 479     llvm_map_components_to_libnames(llvm_libs
 480       ${ARG_LINK_COMPONENTS}
 481       ${LLVM_LINK_COMPONENTS}
 482       )
 483   endif()
 484
 485   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 486     # Link libs w/o keywords, assuming PUBLIC.
 487     target_link_libraries(${name}
 488       ${ARG_LINK_LIBS}
 489       ${lib_deps}
 490       ${llvm_libs}
 491       )
 492   elseif(ARG_STATIC)
 493     target_link_libraries(${name} INTERFACE
 494       ${ARG_LINK_LIBS}
 495       ${lib_deps}
 496       ${llvm_libs}
 497       )
 498   else()
 499     # We can use PRIVATE since SO knows its dependent libs.
 500     target_link_libraries(${name} PRIVATE
 501       ${ARG_LINK_LIBS}
 502       ${lib_deps}
 503       ${llvm_libs}
 504       )
 505   endif()
 506
 507   if(LLVM_COMMON_DEPENDS)
 508     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 509     # Add dependencies also to objlibs.
 510     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 511     foreach(objlib ${objlibs})
 512       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 513     endforeach()
 514   endif()
 515
 516   if(ARG_SHARED OR ARG_MODULE)
 517     llvm_externalize_debuginfo(${name})
 518   endif()
 519 endfunction()
 520
 521 macro(add_llvm_library name)
 522   cmake_parse_arguments(ARG
 523     "SHARED"
 524     ""
 525     ""
 526     ${ARGN})
 527   if( BUILD_SHARED_LIBS )
 528     llvm_add_library(${name} SHARED ${ARGN})
 529   else()
 530     llvm_add_library(${name} ${ARGN})
 531   endif()
 532   # The gtest libraries should not be installed or exported as a target
 533   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 534     set(_is_gtest TRUE)
 535   else()
 536     set(_is_gtest FALSE)
 537     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 538   endif()
 539
 540   if( EXCLUDE_FROM_ALL )
 541     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 542   elseif(NOT _is_gtest)
 543     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 544       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 545         if(WIN32 OR CYGWIN)
 546           set(install_type RUNTIME)
 547         else()
 548           set(install_type LIBRARY)
 549         endif()
 550       else()
 551         set(install_type ARCHIVE)
 552       endif()
 553
 554       install(TARGETS ${name}
 555             EXPORT LLVMExports
 556             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 557             COMPONENT ${name})
 558
 559       if (NOT CMAKE_CONFIGURATION_TYPES)
 560         add_custom_target(install-${name}
 561                           DEPENDS ${name}
 562                           COMMAND "${CMAKE_COMMAND}"
 563                                   -DCMAKE_INSTALL_COMPONENT=${name}
 564                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 565       endif()
 566     endif()
 567     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 568   endif()
 569   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 570 endmacro(add_llvm_library name)
 571
 572 macro(add_llvm_loadable_module name)
 573   llvm_add_library(${name} MODULE ${ARGN})
 574   if(NOT TARGET ${name})
 575     # Add empty "phony" target
 576     add_custom_target(${name})
 577   else()
 578     if( EXCLUDE_FROM_ALL )
 579       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 580     else()
 581       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 582         if(WIN32 OR CYGWIN)
 583           # DLL platform
 584           set(dlldir "bin")
 585         else()
 586           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 587         endif()
 588         install(TARGETS ${name}
 589           EXPORT LLVMExports
 590           LIBRARY DESTINATION ${dlldir}
 591           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 592       endif()
 593       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 594     endif()
 595   endif()
 596
 597   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 598 endmacro(add_llvm_loadable_module name)
 599
 600
 601 macro(add_llvm_executable name)
 602   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB" "" "" ${ARGN})
 603   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 604
 605   # Generate objlib
 606   if(LLVM_ENABLE_OBJLIB)
 607     # Generate an obj library for both targets.
 608     set(obj_name "obj.${name}")
 609     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 610       ${ALL_FILES}
 611       )
 612     llvm_update_compile_flags(${obj_name})
 613     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 614
 615     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 616   endif()
 617
 618   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 619
 620   if(XCODE)
 621     # Note: the dummy.cpp source file provides no definitions. However,
 622     # it forces Xcode to properly link the static library.
 623     list(APPEND ALL_FILES "${LLVM_MAIN_SRC_DIR}/cmake/dummy.cpp")
 624   endif()
 625
 626   if( EXCLUDE_FROM_ALL )
 627     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 628   else()
 629     add_executable(${name} ${ALL_FILES})
 630   endif()
 631
 632   if(DEFINED windows_resource_file)
 633     set_windows_version_resource_properties(${name} ${windows_resource_file})
 634   endif()
 635
 636   # $<TARGET_OBJECTS> doesn't require compile flags.
 637   if(NOT LLVM_ENABLE_OBJLIB)
 638     llvm_update_compile_flags(${name})
 639   endif()
 640   add_link_opts( ${name} )
 641
 642   # Do not add -Dname_EXPORTS to the command-line when building files in this
 643   # target. Doing so is actively harmful for the modules build because it
 644   # creates extra module variants, and not useful because we don't use these
 645   # macros.
 646   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 647
 648   if (LLVM_EXPORTED_SYMBOL_FILE)
 649     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 650   endif(LLVM_EXPORTED_SYMBOL_FILE)
 651
 652   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 653     set(USE_SHARED USE_SHARED)
 654   endif()
 655
 656   set(EXCLUDE_FROM_ALL OFF)
 657   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 658   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 659   if( LLVM_COMMON_DEPENDS )
 660     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 661   endif( LLVM_COMMON_DEPENDS )
 662
 663   llvm_externalize_debuginfo(${name})
 664 endmacro(add_llvm_executable name)
 665
 666 function(export_executable_symbols target)
 667   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 668     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 669     if (APPLE)
 670       set_property(TARGET ${target} APPEND_STRING PROPERTY
 671         LINK_FLAGS " -rdynamic")
 672     endif()
 673   endif()
 674 endfunction()
 675
 676 if(NOT LLVM_TOOLCHAIN_TOOLS)
 677   set (LLVM_TOOLCHAIN_TOOLS
 678     llvm-ar
 679     llvm-ranlib
 680     llvm-lib
 681     llvm-objdump
 682     )
 683 endif()
 684
 685 macro(add_llvm_tool name)
 686   if( NOT LLVM_BUILD_TOOLS )
 687     set(EXCLUDE_FROM_ALL ON)
 688   endif()
 689   add_llvm_executable(${name} ${ARGN})
 690
 691   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 692   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 693     if( LLVM_BUILD_TOOLS )
 694       install(TARGETS ${name}
 695               EXPORT LLVMExports
 696               RUNTIME DESTINATION bin
 697               COMPONENT ${name})
 698
 699       if (NOT CMAKE_CONFIGURATION_TYPES)
 700         add_custom_target(install-${name}
 701                           DEPENDS ${name}
 702                           COMMAND "${CMAKE_COMMAND}"
 703                                   -DCMAKE_INSTALL_COMPONENT=${name}
 704                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 705       endif()
 706     endif()
 707   endif()
 708   if( LLVM_BUILD_TOOLS )
 709     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 710   endif()
 711   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 712 endmacro(add_llvm_tool name)
 713
 714
 715 macro(add_llvm_example name)
 716   if( NOT LLVM_BUILD_EXAMPLES )
 717     set(EXCLUDE_FROM_ALL ON)
 718   endif()
 719   add_llvm_executable(${name} ${ARGN})
 720   if( LLVM_BUILD_EXAMPLES )
 721     install(TARGETS ${name} RUNTIME DESTINATION examples)
 722   endif()
 723   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 724 endmacro(add_llvm_example name)
 725
 726
 727 macro(add_llvm_utility name)
 728   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 729   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 730   if( LLVM_INSTALL_UTILS )
 731     install (TARGETS ${name}
 732       RUNTIME DESTINATION bin
 733       COMPONENT ${name})
 734     if (NOT CMAKE_CONFIGURATION_TYPES)
 735       add_custom_target(install-${name}
 736                         DEPENDS ${name}
 737                         COMMAND "${CMAKE_COMMAND}"
 738                                 -DCMAKE_INSTALL_COMPONENT=${name}
 739                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 740     endif()
 741   endif()
 742 endmacro(add_llvm_utility name)
 743
 744
 745 macro(add_llvm_target target_name)
 746   include_directories(BEFORE
 747     ${CMAKE_CURRENT_BINARY_DIR}
 748     ${CMAKE_CURRENT_SOURCE_DIR})
 749   add_llvm_library(LLVM${target_name} ${ARGN})
 750   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 751 endmacro(add_llvm_target)
 752
 753 function(canonicalize_tool_name name output)
 754   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 755   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 756   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 757   set(${output} "${nameUPPER}" PARENT_SCOPE)
 758 endfunction(canonicalize_tool_name)
 759
 760 # Custom add_subdirectory wrapper
 761 # Takes in a project name (i.e. LLVM), the the subdirectory name, and an
 762 # and an optional path if it differs from the name.
 763 macro(add_llvm_subdirectory project type name)
 764   set(add_llvm_external_dir "${ARGN}")
 765   if("${add_llvm_external_dir}" STREQUAL "")
 766     set(add_llvm_external_dir ${name})
 767   endif()
 768   canonicalize_tool_name(${name} nameUPPER)
 769   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 770     # Treat it as in-tree subproject.
 771     option(${project}_${type}_${nameUPPER}_BUILD
 772            "Whether to build ${name} as part of ${project}" On)
 773     mark_as_advanced(${project}_${type}_${name}_BUILD)
 774     if(${project}_${type}_${nameUPPER}_BUILD)
 775       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 776       # Don't process it in add_llvm_implicit_projects().
 777       set(${project}_${type}_${nameUPPER}_BUILD OFF)
 778     endif()
 779   else()
 780     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 781       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 782       CACHE PATH "Path to ${name} source directory")
 783     set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT ON)
 784     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 785       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 786     endif()
 787     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 788       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 789     endif()
 790     option(${project}_${type}_${nameUPPER}_BUILD
 791       "Whether to build ${name} as part of LLVM"
 792       ${${project}_${type}_${nameUPPER}_BUILD_DEFAULT})
 793     if (${project}_${type}_${nameUPPER}_BUILD)
 794       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 795         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 796       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 797         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 798       endif()
 799       # FIXME: It'd be redundant.
 800       set(${project}_${type}_${nameUPPER}_BUILD Off)
 801     endif()
 802   endif()
 803 endmacro()
 804
 805 # Add external project that may want to be built as part of llvm such as Clang,
 806 # lld, and Polly. This adds two options. One for the source directory of the
 807 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 808 # enable or disable building it with everything else.
 809 # Additional parameter can be specified as the name of directory.
 810 macro(add_llvm_external_project name)
 811   add_llvm_subdirectory(LLVM TOOL ${name} ${ARGN})
 812 endmacro()
 813
 814 macro(add_llvm_tool_subdirectory name)
 815   add_llvm_external_project(${name})
 816 endmacro(add_llvm_tool_subdirectory)
 817
 818 function(get_project_name_from_src_var var output)
 819   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 820          MACHED_TOOL "${var}")
 821   if(MACHED_TOOL)
 822     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 823   else()
 824     set(${output} PARENT_SCOPE)
 825   endif()
 826 endfunction()
 827
 828 function(create_subdirectory_options project type)
 829   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 830   foreach(dir ${sub-dirs})
 831     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 832       canonicalize_tool_name(${dir} name)
 833       option(${project}_${type}_${name}_BUILD
 834            "Whether to build ${name} as part of ${project}" On)
 835       mark_as_advanced(${project}_${type}_${name}_BUILD)
 836     endif()
 837   endforeach()
 838 endfunction(create_subdirectory_options)
 839
 840 function(create_llvm_tool_options)
 841   create_subdirectory_options(LLVM TOOL)
 842 endfunction(create_llvm_tool_options)
 843
 844 function(add_llvm_implicit_projects)
 845   set(list_of_implicit_subdirs "")
 846   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 847   foreach(dir ${sub-dirs})
 848     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 849       canonicalize_tool_name(${dir} name)
 850       if (LLVM_TOOL_${name}_BUILD)
 851         get_filename_component(fn "${dir}" NAME)
 852         list(APPEND list_of_implicit_subdirs "${fn}")
 853       endif()
 854     endif()
 855   endforeach()
 856
 857   foreach(external_proj ${list_of_implicit_subdirs})
 858     add_llvm_external_project("${external_proj}")
 859   endforeach()
 860 endfunction(add_llvm_implicit_projects)
 861
 862 # Generic support for adding a unittest.
 863 function(add_unittest test_suite test_name)
 864   if( NOT LLVM_BUILD_TESTS )
 865     set(EXCLUDE_FROM_ALL ON)
 866   endif()
 867
 868   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 869   if (NOT LLVM_ENABLE_THREADS)
 870     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 871   endif ()
 872
 873   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 874     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 875   endif ()
 876
 877   set(LLVM_REQUIRES_RTTI OFF)
 878
 879   add_llvm_executable(${test_name} ${ARGN})
 880   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 881   set_output_directory(${test_name} BINARY_DIR ${outdir} LIBRARY_DIR ${outdir})
 882   target_link_libraries(${test_name}
 883     gtest
 884     gtest_main
 885     LLVMSupport # gtest needs it for raw_ostream.
 886     )
 887
 888   add_dependencies(${test_suite} ${test_name})
 889   get_target_property(test_suite_folder ${test_suite} FOLDER)
 890   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 891     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 892   endif ()
 893 endfunction()
 894
 895 function(llvm_add_go_executable binary pkgpath)
 896   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 897
 898   if(LLVM_BINDINGS MATCHES "go")
 899     # FIXME: This should depend only on the libraries Go needs.
 900     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 901     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 902     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 903     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 904     set(cppflags "")
 905     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 906     foreach(d ${include_dirs})
 907       set(cppflags "${cppflags} -I${d}")
 908     endforeach(d)
 909     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 910     if (LLVM_LINK_LLVM_DYLIB)
 911       set(linkmode "dylib")
 912     else()
 913       set(linkmode "component-libs")
 914     endif()
 915     add_custom_command(OUTPUT ${binpath}
 916       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "linkmode=${linkmode}"
 917               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 918       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 919               ${llvmlibs} ${ARG_DEPENDS}
 920       COMMENT "Building Go executable ${binary}"
 921       VERBATIM)
 922     if (ARG_ALL)
 923       add_custom_target(${binary} ALL DEPENDS ${binpath})
 924     else()
 925       add_custom_target(${binary} DEPENDS ${binpath})
 926     endif()
 927   endif()
 928 endfunction()
 929
 930 # This function provides an automatic way to 'configure'-like generate a file
 931 # based on a set of common and custom variables, specifically targeting the
 932 # variables needed for the 'lit.site.cfg' files. This function bundles the
 933 # common variables that any Lit instance is likely to need, and custom
 934 # variables can be passed in.
 935 function(configure_lit_site_cfg input output)
 936   foreach(c ${LLVM_TARGETS_TO_BUILD})
 937     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 938   endforeach(c)
 939   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 940
 941   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 942
 943   # Configuration-time: See Unit/lit.site.cfg.in
 944   if (CMAKE_CFG_INTDIR STREQUAL ".")
 945     set(LLVM_BUILD_MODE ".")
 946   else ()
 947     set(LLVM_BUILD_MODE "%(build_mode)s")
 948   endif ()
 949
 950   # They below might not be the build tree but provided binary tree.
 951   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 952   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 953   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 954   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 955
 956   # SHLIBDIR points the build tree.
 957   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 958
 959   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 960   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 961   # plugins. We may rename it.
 962   if(LLVM_ENABLE_PLUGINS)
 963     set(ENABLE_SHARED "1")
 964   else()
 965     set(ENABLE_SHARED "0")
 966   endif()
 967
 968   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 969     set(ENABLE_ASSERTIONS "1")
 970   else()
 971     set(ENABLE_ASSERTIONS "0")
 972   endif()
 973
 974   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 975   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 976
 977   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 978   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 979   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 980
 981   configure_file(${input} ${output} @ONLY)
 982 endfunction()
 983
 984 # A raw function to create a lit target. This is used to implement the testuite
 985 # management functions.
 986 function(add_lit_target target comment)
 987   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 988   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 989   separate_arguments(LIT_ARGS)
 990   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 991     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 992   endif ()
 993   if (LLVM_MAIN_SRC_DIR)
 994     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 995   else()
 996     find_program(LIT_COMMAND llvm-lit)
 997   endif ()
 998   list(APPEND LIT_COMMAND ${LIT_ARGS})
 999   foreach(param ${ARG_PARAMS})
1000     list(APPEND LIT_COMMAND --param ${param})
1001   endforeach()
1002   if (ARG_UNPARSED_ARGUMENTS)
1003     add_custom_target(${target}
1004       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
1005       COMMENT "${comment}"
1006       ${cmake_3_2_USES_TERMINAL}
1007       )
1008   else()
1009     add_custom_target(${target}
1010       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
1011     message(STATUS "${target} does nothing.")
1012   endif()
1013   if (ARG_DEPENDS)
1014     add_dependencies(${target} ${ARG_DEPENDS})
1015   endif()
1016
1017   # Tests should be excluded from "Build Solution".
1018   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
1019 endfunction()
1020
1021 # A function to add a set of lit test suites to be driven through 'check-*' targets.
1022 function(add_lit_testsuite target comment)
1023   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1024
1025   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
1026   if(NOT EXCLUDE_FROM_ALL)
1027     # Register the testsuites, params and depends for the global check rule.
1028     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
1029     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
1030     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
1031     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
1032   endif()
1033
1034   # Produce a specific suffixed check rule.
1035   add_lit_target(${target} ${comment}
1036     ${ARG_UNPARSED_ARGUMENTS}
1037     PARAMS ${ARG_PARAMS}
1038     DEPENDS ${ARG_DEPENDS}
1039     ARGS ${ARG_ARGS}
1040     )
1041 endfunction()
1042
1043 function(add_lit_testsuites project directory)
1044   if (NOT CMAKE_CONFIGURATION_TYPES)
1045     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1046     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
1047     set(lit_suites)
1048     foreach(f ${litCfg})
1049       get_filename_component(dir ${f} DIRECTORY)
1050       set(lit_suites ${lit_suites} ${dir})
1051     endforeach()
1052     list(REMOVE_DUPLICATES lit_suites)
1053     foreach(dir ${lit_suites})
1054       string(REPLACE ${directory} "" name_slash ${dir})
1055       if (name_slash)
1056         string(REPLACE "/" "-" name_slash ${name_slash})
1057         string(REPLACE "\\" "-" name_dashes ${name_slash})
1058         string(TOLOWER "${project}${name_dashes}" name_var)
1059         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
1060           ${dir}
1061           PARAMS ${ARG_PARAMS}
1062           DEPENDS ${ARG_DEPENDS}
1063           ARGS ${ARG_ARGS}
1064         )
1065       endif()
1066     endforeach()
1067   endif()
1068 endfunction()
1069
1070 function(llvm_install_library_symlink name dest type)
1071   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "COMPONENT" "" ${ARGN})
1072   foreach(path ${CMAKE_MODULE_PATH})
1073     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1074       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1075       break()
1076     endif()
1077   endforeach()
1078
1079   set(component ${ARG_COMPONENT})
1080   if(NOT component)
1081     set(component ${name})
1082   endif()
1083
1084   set(full_name ${CMAKE_${type}_LIBRARY_PREFIX}${name}${CMAKE_${type}_LIBRARY_SUFFIX})
1085   set(full_dest ${CMAKE_${type}_LIBRARY_PREFIX}${dest}${CMAKE_${type}_LIBRARY_SUFFIX})
1086
1087   set(output_dir lib${LLVM_LIBDIR_SUFFIX})
1088   if(WIN32 AND "${type}" STREQUAL "SHARED")
1089     set(output_dir bin)
1090   endif()
1091
1092   install(SCRIPT ${INSTALL_SYMLINK}
1093           CODE "install_symlink(${full_name} ${full_dest} ${output_dir})"
1094           COMPONENT ${component})
1095
1096   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1097     add_custom_target(install-${name}
1098                       DEPENDS ${name} ${dest} install-${dest}
1099                       COMMAND "${CMAKE_COMMAND}"
1100                               -DCMAKE_INSTALL_COMPONENT=${name}
1101                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1102   endif()
1103 endfunction()
1104
1105 function(llvm_install_symlink name dest)
1106   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1107   foreach(path ${CMAKE_MODULE_PATH})
1108     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1109       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1110       break()
1111     endif()
1112   endforeach()
1113
1114   if(ARG_ALWAYS_GENERATE)
1115     set(component ${dest})
1116   else()
1117     set(component ${name})
1118   endif()
1119
1120   set(full_name ${name}${CMAKE_EXECUTABLE_SUFFIX})
1121   set(full_dest ${dest}${CMAKE_EXECUTABLE_SUFFIX})
1122
1123   install(SCRIPT ${INSTALL_SYMLINK}
1124           CODE "install_symlink(${full_name} ${full_dest} bin)"
1125           COMPONENT ${component})
1126
1127   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1128     add_custom_target(install-${name}
1129                       DEPENDS ${name} ${dest} install-${dest}
1130                       COMMAND "${CMAKE_COMMAND}"
1131                               -DCMAKE_INSTALL_COMPONENT=${name}
1132                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1133   endif()
1134 endfunction()
1135
1136 function(add_llvm_tool_symlink name dest)
1137   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1138   if(UNIX)
1139     set(LLVM_LINK_OR_COPY create_symlink)
1140     set(dest_binary "${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1141   else()
1142     set(LLVM_LINK_OR_COPY copy)
1143     set(dest_binary "${LLVM_RUNTIME_OUTPUT_INTDIR}/${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1144   endif()
1145
1146   set(output_path "${LLVM_RUNTIME_OUTPUT_INTDIR}/${name}${CMAKE_EXECUTABLE_SUFFIX}")
1147
1148   if(ARG_ALWAYS_GENERATE)
1149     set_property(DIRECTORY APPEND PROPERTY
1150       ADDITIONAL_MAKE_CLEAN_FILES ${dest_binary})
1151     add_custom_command(TARGET ${dest} POST_BUILD
1152       COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}")
1153   else()
1154     add_custom_command(OUTPUT ${output_path}
1155                      COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}"
1156                      DEPENDS ${dest})
1157     add_custom_target(${name} ALL DEPENDS ${output_path})
1158     set_target_properties(${name} PROPERTIES FOLDER Tools)
1159
1160     # Make sure the parent tool is a toolchain tool, otherwise exclude this tool
1161     list(FIND LLVM_TOOLCHAIN_TOOLS ${dest} LLVM_IS_${dest}_TOOLCHAIN_TOOL)
1162     if (NOT LLVM_IS_${dest}_TOOLCHAIN_TOOL GREATER -1)
1163       set(LLVM_IS_${name}_TOOLCHAIN_TOOL ${LLVM_IS_${dest}_TOOLCHAIN_TOOL})
1164     else()
1165       list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
1166     endif()
1167
1168     # LLVM_IS_${name}_TOOLCHAIN_TOOL will only be greater than -1 if both this
1169     # tool and its parent tool are in LLVM_TOOLCHAIN_TOOLS
1170     if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1171       if( LLVM_BUILD_TOOLS )
1172         llvm_install_symlink(${name} ${dest})
1173       endif()
1174     endif()
1175   endif()
1176 endfunction()
1177
1178 function(llvm_externalize_debuginfo name)
1179   if(NOT LLVM_EXTERNALIZE_DEBUGINFO)
1180     return()
1181   endif()
1182
1183   if(APPLE)
1184     if(CMAKE_CXX_FLAGS MATCHES "-flto"
1185       OR CMAKE_CXX_FLAGS_${uppercase_CMAKE_BUILD_TYPE} MATCHES "-flto")
1186
1187       set(lto_object ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${name}-lto.o)
1188       set_property(TARGET ${name} APPEND_STRING PROPERTY
1189         LINK_FLAGS " -Wl,-object_path_lto,${lto_object}")
1190     endif()
1191     add_custom_command(TARGET ${name} POST_BUILD
1192       COMMAND xcrun dsymutil $<TARGET_FILE:${name}>
1193       COMMAND xcrun strip -Sl $<TARGET_FILE:${name}>)
1194   else()
1195     message(FATAL_ERROR "LLVM_EXTERNALIZE_DEBUGINFO isn't implemented for non-darwin platforms!")
1196   endif()
1197 endfunction()