cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(target_compile_flags TARGET ${name} PROPERTY COMPILE_FLAGS)
   7   if(NOT "${LLVM_COMPILE_FLAGS}" STREQUAL "")
   8     set(target_compile_flags "${target_compile_flags} ${LLVM_COMPILE_FLAGS}")
   9   endif()
  10   if(LLVM_NO_RTTI)
  11     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  12     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  13       set(target_compile_flags "${target_compile_flags} -fno-rtti")
  14     elseif (MSVC)
  15       llvm_replace_compiler_option(target_compile_flags "/GR" "/GR-")
  16     endif ()
  17   endif()
  18
  19   set_property(TARGET ${name} PROPERTY COMPILE_FLAGS "${target_compile_flags}")
  20   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  21 endfunction()
  22
  23 function(add_llvm_symbol_exports target_name export_file)
  24   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  25     set(native_export_file "${target_name}.exports")
  26     add_custom_command(OUTPUT ${native_export_file}
  27       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  28       DEPENDS ${export_file}
  29       VERBATIM
  30       COMMENT "Creating export file for ${target_name}")
  31     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  32                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  33   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  34     # Gold and BFD ld require a version script rather than a plain list.
  35     set(native_export_file "${target_name}.exports")
  36     # FIXME: Don't write the "local:" line on OpenBSD.
  37     add_custom_command(OUTPUT ${native_export_file}
  38       COMMAND echo "{" > ${native_export_file}
  39       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  40       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  41       COMMAND echo "  local: *;" >> ${native_export_file}
  42       COMMAND echo "};" >> ${native_export_file}
  43       DEPENDS ${export_file}
  44       VERBATIM
  45       COMMENT "Creating export file for ${target_name}")
  46     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  47                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  48   else()
  49     set(native_export_file "${target_name}.def")
  50
  51     set(CAT "type")
  52     if(CYGWIN)
  53       set(CAT "cat")
  54     endif()
  55
  56     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  57     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  58
  59     add_custom_command(OUTPUT ${native_export_file}
  60       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  61       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  62       DEPENDS ${export_file}
  63       VERBATIM
  64       COMMENT "Creating export file for ${target_name}")
  65     if(CYGWIN OR MINGW)
  66       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  67                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  68     else()
  69       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  70                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  71     endif()
  72   endif()
  73
  74   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
  75
  76   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
  77   foreach(src ${srcs})
  78     get_filename_component(extension ${src} EXT)
  79     if(extension STREQUAL ".cpp")
  80       set(first_source_file ${src})
  81       break()
  82     endif()
  83   endforeach()
  84
  85   # Force re-linking when the exports file changes. Actually, it
  86   # forces recompilation of the source file. The LINK_DEPENDS target
  87   # property only works for makefile-based generators.
  88   # FIXME: This is not safe because this will create the same target
  89   # ${native_export_file} in several different file:
  90   # - One where we emitted ${target_name}_exports
  91   # - One where we emitted the build command for the following object.
  92   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
  93   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
  94
  95   set_property(DIRECTORY APPEND
  96     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
  97
  98   add_dependencies(${target_name} ${target_name}_exports)
  99 endfunction(add_llvm_symbol_exports)
 100
 101 function(add_dead_strip target_name)
 102   # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 103   # But MinSizeRel seems to add that automatically, so maybe disable these
 104   # flags instead if LLVM_NO_DEAD_STRIP is set.
 105   if(NOT CYGWIN AND NOT MINGW AND NOT MSVC)
 106     if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 107        SET(CMAKE_CXX_FLAGS
 108            "${CMAKE_CXX_FLAGS}  -ffunction-sections -fdata-sections"
 109            PARENT_SCOPE)
 110     endif()
 111   endif()
 112   if(NOT LLVM_NO_DEAD_STRIP)
 113     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 114       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 115                    LINK_FLAGS " -Wl,-dead_strip")
 116     elseif(NOT WIN32)
 117       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 118                    LINK_FLAGS " -Wl,--gc-sections")
 119     endif()
 120   endif()
 121 endfunction(add_dead_strip)
 122
 123 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 124 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 125 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 126 function(set_output_directory target bindir libdir)
 127   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 128     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 129       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 130       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 131       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 132       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 133       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 134       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 135     endforeach()
 136   else()
 137     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 138     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 139     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${libdir})
 140   endif()
 141 endfunction()
 142
 143 macro(add_llvm_library name)
 144   llvm_process_sources( ALL_FILES ${ARGN} )
 145   add_library( ${name} ${ALL_FILES} )
 146   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 147   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 148   add_dead_strip( ${name} )
 149   if( LLVM_COMMON_DEPENDS )
 150     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 151   endif( LLVM_COMMON_DEPENDS )
 152
 153   if( BUILD_SHARED_LIBS )
 154     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 155     if (MSVC)
 156       set_target_properties(${name}
 157         PROPERTIES
 158         IMPORT_SUFFIX ".imp")
 159     endif ()
 160
 161     if (LLVM_EXPORTED_SYMBOL_FILE)
 162       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 163     endif()
 164   endif()
 165
 166   # Ensure that the system libraries always comes last on the
 167   # list. Without this, linking the unit tests on MinGW fails.
 168   link_system_libs( ${name} )
 169
 170   if( EXCLUDE_FROM_ALL )
 171     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 172   else()
 173     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 174       install(TARGETS ${name}
 175         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 176         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 177     endif()
 178   endif()
 179   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 180
 181   # Add the explicit dependency information for this library.
 182   #
 183   # It would be nice to verify that we have the dependencies for this library
 184   # name, but using get_property(... SET) doesn't suffice to determine if a
 185   # property has been set to an empty value.
 186   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 187   target_link_libraries(${name} ${lib_deps})
 188 endmacro(add_llvm_library name)
 189
 190 macro(add_llvm_loadable_module name)
 191   if( NOT LLVM_ON_UNIX OR CYGWIN )
 192     message(STATUS "Loadable modules not supported on this platform.
 193 ${name} ignored.")
 194     # Add empty "phony" target
 195     add_custom_target(${name})
 196   else()
 197     llvm_process_sources( ALL_FILES ${ARGN} )
 198     if (MODULE)
 199       set(libkind MODULE)
 200     else()
 201       set(libkind SHARED)
 202     endif()
 203
 204     add_library( ${name} ${libkind} ${ALL_FILES} )
 205     set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 206     set_target_properties( ${name} PROPERTIES PREFIX "" )
 207     add_dead_strip( ${name} )
 208
 209     if (LLVM_EXPORTED_SYMBOL_FILE)
 210       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 211     endif(LLVM_EXPORTED_SYMBOL_FILE)
 212
 213     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 214     link_system_libs( ${name} )
 215
 216     if (APPLE)
 217       # Darwin-specific linker flags for loadable modules.
 218       set_property(TARGET ${name} APPEND_STRING PROPERTY
 219         LINK_FLAGS " -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 220     endif()
 221
 222     if (MODULE)
 223       set_property(TARGET ${name} PROPERTY SUFFIX ${LLVM_PLUGIN_EXT})
 224     endif ()
 225
 226     if( EXCLUDE_FROM_ALL )
 227       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 228     else()
 229       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 230         install(TARGETS ${name}
 231           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 232           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 233       endif()
 234     endif()
 235   endif()
 236
 237   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 238 endmacro(add_llvm_loadable_module name)
 239
 240
 241 macro(add_llvm_executable name)
 242   llvm_process_sources( ALL_FILES ${ARGN} )
 243   if( EXCLUDE_FROM_ALL )
 244     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 245   else()
 246     add_executable(${name} ${ALL_FILES})
 247   endif()
 248   add_dead_strip( ${name} )
 249
 250   if (LLVM_EXPORTED_SYMBOL_FILE)
 251     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 252   endif(LLVM_EXPORTED_SYMBOL_FILE)
 253
 254   set(EXCLUDE_FROM_ALL OFF)
 255   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 256   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 257   if( LLVM_COMMON_DEPENDS )
 258     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 259   endif( LLVM_COMMON_DEPENDS )
 260   link_system_libs( ${name} )
 261 endmacro(add_llvm_executable name)
 262
 263
 264 set (LLVM_TOOLCHAIN_TOOLS
 265   llvm-ar
 266   llvm-objdump
 267   )
 268
 269 macro(add_llvm_tool name)
 270   if( NOT LLVM_BUILD_TOOLS )
 271     set(EXCLUDE_FROM_ALL ON)
 272   endif()
 273   add_llvm_executable(${name} ${ARGN})
 274
 275   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 276   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 277     if( LLVM_BUILD_TOOLS )
 278       install(TARGETS ${name} RUNTIME DESTINATION bin)
 279     endif()
 280   endif()
 281   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 282 endmacro(add_llvm_tool name)
 283
 284
 285 macro(add_llvm_example name)
 286   if( NOT LLVM_BUILD_EXAMPLES )
 287     set(EXCLUDE_FROM_ALL ON)
 288   endif()
 289   add_llvm_executable(${name} ${ARGN})
 290   if( LLVM_BUILD_EXAMPLES )
 291     install(TARGETS ${name} RUNTIME DESTINATION examples)
 292   endif()
 293   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 294 endmacro(add_llvm_example name)
 295
 296
 297 macro(add_llvm_utility name)
 298   add_llvm_executable(${name} ${ARGN})
 299   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 300 endmacro(add_llvm_utility name)
 301
 302
 303 macro(add_llvm_target target_name)
 304   include_directories(BEFORE
 305     ${CMAKE_CURRENT_BINARY_DIR}
 306     ${CMAKE_CURRENT_SOURCE_DIR})
 307   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 308   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 309 endmacro(add_llvm_target)
 310
 311 # Add external project that may want to be built as part of llvm such as Clang,
 312 # lld, and Polly. This adds two options. One for the source directory of the
 313 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 314 # enable or disable building it with everything else.
 315 # Additional parameter can be specified as the name of directory.
 316 macro(add_llvm_external_project name)
 317   set(add_llvm_external_dir "${ARGN}")
 318   if("${add_llvm_external_dir}" STREQUAL "")
 319     set(add_llvm_external_dir ${name})
 320   endif()
 321   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 322   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 323   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 324   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 325       CACHE PATH "Path to ${name} source directory")
 326   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 327       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 328     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 329            "Whether to build ${name} as part of LLVM" ON)
 330     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 331       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 332     endif()
 333   endif()
 334 endmacro(add_llvm_external_project)
 335
 336 macro(add_llvm_tool_subdirectory name)
 337   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 338   add_subdirectory(${name})
 339 endmacro(add_llvm_tool_subdirectory)
 340
 341 macro(ignore_llvm_tool_subdirectory name)
 342   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 343 endmacro(ignore_llvm_tool_subdirectory)
 344
 345 function(add_llvm_implicit_external_projects)
 346   set(list_of_implicit_subdirs "")
 347   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 348   foreach(dir ${sub-dirs})
 349     if(IS_DIRECTORY "${dir}")
 350       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 351       if( tool_subdir_ignore EQUAL -1
 352           AND EXISTS "${dir}/CMakeLists.txt")
 353         get_filename_component(fn "${dir}" NAME)
 354         list(APPEND list_of_implicit_subdirs "${fn}")
 355       endif()
 356     endif()
 357   endforeach()
 358
 359   foreach(external_proj ${list_of_implicit_subdirs})
 360     add_llvm_external_project("${external_proj}")
 361   endforeach()
 362 endfunction(add_llvm_implicit_external_projects)
 363
 364 # Generic support for adding a unittest.
 365 function(add_unittest test_suite test_name)
 366   if( NOT LLVM_BUILD_TESTS )
 367     set(EXCLUDE_FROM_ALL ON)
 368   endif()
 369
 370   # Visual Studio 2012 only supports up to 8 template parameters in
 371   # std::tr1::tuple by default, but gtest requires 10
 372   if (MSVC AND MSVC_VERSION EQUAL 1700)
 373     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 374   endif ()
 375
 376   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 377   if (NOT LLVM_ENABLE_THREADS)
 378     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 379   endif ()
 380
 381   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 382     set(LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 383   endif ()
 384
 385   set(LLVM_NO_RTTI ON)
 386
 387   add_llvm_executable(${test_name} ${ARGN})
 388   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 389   set_output_directory(${test_name} ${outdir} ${outdir})
 390   target_link_libraries(${test_name}
 391     gtest
 392     gtest_main
 393     LLVMSupport # gtest needs it for raw_ostream.
 394     )
 395
 396   add_dependencies(${test_suite} ${test_name})
 397   get_target_property(test_suite_folder ${test_suite} FOLDER)
 398   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 399     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 400   endif ()
 401   llvm_update_compile_flags(${test_name})
 402 endfunction()
 403
 404 # This function provides an automatic way to 'configure'-like generate a file
 405 # based on a set of common and custom variables, specifically targeting the
 406 # variables needed for the 'lit.site.cfg' files. This function bundles the
 407 # common variables that any Lit instance is likely to need, and custom
 408 # variables can be passed in.
 409 function(configure_lit_site_cfg input output)
 410   foreach(c ${LLVM_TARGETS_TO_BUILD})
 411     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 412   endforeach(c)
 413   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 414
 415   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 416
 417   if(BUILD_SHARED_LIBS)
 418     set(LLVM_SHARED_LIBS_ENABLED "1")
 419   else()
 420     set(LLVM_SHARED_LIBS_ENABLED "0")
 421   endif(BUILD_SHARED_LIBS)
 422
 423   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 424     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 425   else() # Default for all other unix like systems.
 426     # CMake hardcodes the library locaction using rpath.
 427     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 428     # build dir. We pass it anyways.
 429     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 430   endif()
 431
 432   # Configuration-time: See Unit/lit.site.cfg.in
 433   if (CMAKE_CFG_INTDIR STREQUAL ".")
 434     set(LLVM_BUILD_MODE ".")
 435   else ()
 436     set(LLVM_BUILD_MODE "%(build_mode)s")
 437   endif ()
 438
 439   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 440   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 441   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 442   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_OUTPUT_INTDIR})
 443   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR  ${LLVM_LIBRARY_OUTPUT_INTDIR})
 444   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 445   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 446   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 447
 448   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 449     set(ENABLE_ASSERTIONS "1")
 450   else()
 451     set(ENABLE_ASSERTIONS "0")
 452   endif()
 453
 454   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 455   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 456
 457   if (CLANG_ENABLE_ARCMT)
 458     set(ENABLE_CLANG_ARCMT "1")
 459   else()
 460     set(ENABLE_CLANG_ARCMT "0")
 461   endif()
 462   if (CLANG_ENABLE_REWRITER)
 463     set(ENABLE_CLANG_REWRITER "1")
 464   else()
 465     set(ENABLE_CLANG_REWRITER "0")
 466   endif()
 467   if (CLANG_ENABLE_STATIC_ANALYZER)
 468     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 469   else()
 470     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 471   endif()
 472
 473   configure_file(${input} ${output} @ONLY)
 474 endfunction()
 475
 476 # A raw function to create a lit target. This is used to implement the testuite
 477 # management functions.
 478 function(add_lit_target target comment)
 479   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 480   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 481   separate_arguments(LIT_ARGS)
 482   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 483     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 484   endif ()
 485   set(LIT_COMMAND
 486     ${PYTHON_EXECUTABLE}
 487     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 488     ${LIT_ARGS}
 489     )
 490   foreach(param ${ARG_PARAMS})
 491     list(APPEND LIT_COMMAND --param ${param})
 492   endforeach()
 493   if( ARG_DEPENDS )
 494     add_custom_target(${target}
 495       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 496       COMMENT "${comment}"
 497       )
 498     add_dependencies(${target} ${ARG_DEPENDS})
 499   else()
 500     add_custom_target(${target}
 501       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 502     message(STATUS "${target} does nothing.")
 503   endif()
 504
 505   # Tests should be excluded from "Build Solution".
 506   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 507 endfunction()
 508
 509 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 510 function(add_lit_testsuite target comment)
 511   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 512
 513   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 514   if(NOT EXCLUDE_FROM_ALL)
 515     # Register the testsuites, params and depends for the global check rule.
 516     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 517     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 518     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 519     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 520   endif()
 521
 522   # Produce a specific suffixed check rule.
 523   add_lit_target(${target} ${comment}
 524     ${ARG_DEFAULT_ARGS}
 525     PARAMS ${ARG_PARAMS}
 526     DEPENDS ${ARG_DEPENDS}
 527     ARGS ${ARG_ARGS}
 528     )
 529 endfunction()