cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25     if (CLANG_CL)
  26       # FIXME: Remove this once clang-cl supports SEH
  27       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
  28     endif()
  29   endif()
  30
  31   # LLVM_REQUIRES_RTTI is an internal flag that individual
  32   # targets can use to force RTTI
  33   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  34     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  35     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  36       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  37     elseif (MSVC)
  38       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  39     endif ()
  40   endif()
  41
  42   # Assume that;
  43   #   - LLVM_COMPILE_FLAGS is list.
  44   #   - PROPERTY COMPILE_FLAGS is string.
  45   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  46
  47   if(update_src_props)
  48     foreach(fn ${sources})
  49       get_filename_component(suf ${fn} EXT)
  50       if("${suf}" STREQUAL ".cpp")
  51         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  52           COMPILE_FLAGS "${target_compile_flags}")
  53       endif()
  54     endforeach()
  55   else()
  56     # Update target props, since all sources are C++.
  57     set_property(TARGET ${name} APPEND_STRING PROPERTY
  58       COMPILE_FLAGS "${target_compile_flags}")
  59   endif()
  60
  61   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  62 endfunction()
  63
  64 function(add_llvm_symbol_exports target_name export_file)
  65   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  66     set(native_export_file "${target_name}.exports")
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  69       DEPENDS ${export_file}
  70       VERBATIM
  71       COMMENT "Creating export file for ${target_name}")
  72     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  73                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  74   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  75     # Gold and BFD ld require a version script rather than a plain list.
  76     set(native_export_file "${target_name}.exports")
  77     # FIXME: Don't write the "local:" line on OpenBSD.
  78     add_custom_command(OUTPUT ${native_export_file}
  79       COMMAND echo "{" > ${native_export_file}
  80       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  81       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  82       COMMAND echo "  local: *;" >> ${native_export_file}
  83       COMMAND echo "};" >> ${native_export_file}
  84       DEPENDS ${export_file}
  85       VERBATIM
  86       COMMENT "Creating export file for ${target_name}")
  87     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  88                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  89   else()
  90     set(native_export_file "${target_name}.def")
  91
  92     set(CAT "cat")
  93     set(export_file_nativeslashes ${export_file})
  94     if(WIN32 AND NOT CYGWIN AND NOT MSYS)
  95       set(CAT "type")
  96       # Convert ${export_file} to native format (backslashes) for "type"
  97       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
  98       # path but a build-system specific format (see CMake bug
  99       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
 100       string(REPLACE / \\ export_file_nativeslashes ${export_file})
 101     endif()
 102
 103     add_custom_command(OUTPUT ${native_export_file}
 104       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 105       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 106       DEPENDS ${export_file}
 107       VERBATIM
 108       COMMENT "Creating export file for ${target_name}")
 109     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 110     if(MSVC)
 111       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 112     endif()
 113     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 114                  LINK_FLAGS " ${export_file_linker_flag}")
 115   endif()
 116
 117   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 118   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 119
 120   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 121   foreach(src ${srcs})
 122     get_filename_component(extension ${src} EXT)
 123     if(extension STREQUAL ".cpp")
 124       set(first_source_file ${src})
 125       break()
 126     endif()
 127   endforeach()
 128
 129   # Force re-linking when the exports file changes. Actually, it
 130   # forces recompilation of the source file. The LINK_DEPENDS target
 131   # property only works for makefile-based generators.
 132   # FIXME: This is not safe because this will create the same target
 133   # ${native_export_file} in several different file:
 134   # - One where we emitted ${target_name}_exports
 135   # - One where we emitted the build command for the following object.
 136   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 137   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 138
 139   set_property(DIRECTORY APPEND
 140     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 141
 142   add_dependencies(${target_name} ${target_name}_exports)
 143
 144   # Add dependency to *_exports later -- CMake issue 14747
 145   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 146   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 147 endfunction(add_llvm_symbol_exports)
 148
 149 if(NOT WIN32 AND NOT APPLE)
 150   execute_process(
 151     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 152     OUTPUT_VARIABLE stdout
 153     ERROR_QUIET
 154     )
 155   if("${stdout}" MATCHES "GNU gold")
 156     set(LLVM_LINKER_IS_GOLD ON)
 157   endif()
 158 endif()
 159
 160 function(add_link_opts target_name)
 161   # Don't use linker optimizations in debug builds since it slows down the
 162   # linker in a context where the optimizations are not important.
 163   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 164
 165     # Pass -O3 to the linker. This enabled different optimizations on different
 166     # linkers.
 167     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32))
 168       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 169                    LINK_FLAGS " -Wl,-O3")
 170     endif()
 171
 172     if(LLVM_LINKER_IS_GOLD)
 173       # With gold gc-sections is always safe.
 174       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 175                    LINK_FLAGS " -Wl,--gc-sections")
 176       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 177       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 178     endif()
 179
 180     if(NOT LLVM_NO_DEAD_STRIP)
 181       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 182         # ld64's implementation of -dead_strip breaks tools that use plugins.
 183         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 184                      LINK_FLAGS " -Wl,-dead_strip")
 185       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 186         # Object files are compiled with -ffunction-data-sections.
 187         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 188         # tools that use plugins. Always pass --gc-sections once we require
 189         # a newer linker.
 190         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 191                      LINK_FLAGS " -Wl,--gc-sections")
 192       endif()
 193     endif()
 194   endif()
 195 endfunction(add_link_opts)
 196
 197 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 198 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 199 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 200 function(set_output_directory target bindir libdir)
 201   # Do nothing if *_OUTPUT_INTDIR is empty.
 202   if("${bindir}" STREQUAL "")
 203     return()
 204   endif()
 205
 206   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 207   # It affects output of add_library(MODULE).
 208   if(WIN32 OR CYGWIN)
 209     # DLL platform
 210     set(moddir ${bindir})
 211   else()
 212     set(moddir ${libdir})
 213   endif()
 214   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 215     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 216       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 217       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 218       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 219       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 220       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 221       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 222       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 223     endforeach()
 224   else()
 225     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 226     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 227     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 228   endif()
 229 endfunction()
 230
 231 # If on Windows and building with MSVC, add the resource script containing the
 232 # VERSIONINFO data to the project.  This embeds version resource information
 233 # into the output .exe or .dll.
 234 # TODO: Enable for MinGW Windows builds too.
 235 #
 236 function(add_windows_version_resource_file OUT_VAR)
 237   set(sources ${ARGN})
 238   if (MSVC)
 239     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 240     if(EXISTS ${resource_file})
 241       set(sources ${sources} ${resource_file})
 242       source_group("Resource Files" ${resource_file})
 243       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 244     endif()
 245   endif(MSVC)
 246
 247   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 248 endfunction(add_windows_version_resource_file)
 249
 250 # set_windows_version_resource_properties(name resource_file...
 251 #   VERSION_MAJOR int
 252 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 253 #   VERSION_MINOR int
 254 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 255 #   VERSION_PATCHLEVEL int
 256 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 257 #   VERSION_STRING
 258 #     Optional version string (defaults to PACKAGE_VERSION)
 259 #   PRODUCT_NAME
 260 #     Optional product name string (defaults to "LLVM")
 261 #   )
 262 function(set_windows_version_resource_properties name resource_file)
 263   cmake_parse_arguments(ARG
 264     ""
 265     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 266     ""
 267     ${ARGN})
 268
 269   if (NOT DEFINED ARG_VERSION_MAJOR)
 270     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 271   endif()
 272
 273   if (NOT DEFINED ARG_VERSION_MINOR)
 274     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 278     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 279   endif()
 280
 281   if (NOT DEFINED ARG_VERSION_STRING)
 282     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 283   endif()
 284
 285   if (NOT DEFINED ARG_PRODUCT_NAME)
 286     set(ARG_PRODUCT_NAME "LLVM")
 287   endif()
 288
 289   set_property(SOURCE ${resource_file}
 290                PROPERTY COMPILE_DEFINITIONS
 291                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 292                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 293                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 294                "RC_VERSION_FIELD_4=0"
 295                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 296                "RC_INTERNAL_NAME=\"${name}\""
 297                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 298                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 299 endfunction(set_windows_version_resource_properties)
 300
 301 # llvm_add_library(name sources...
 302 #   SHARED;STATIC
 303 #     STATIC by default w/o BUILD_SHARED_LIBS.
 304 #     SHARED by default w/  BUILD_SHARED_LIBS.
 305 #   MODULE
 306 #     Target ${name} might not be created on unsupported platforms.
 307 #     Check with "if(TARGET ${name})".
 308 #   OUTPUT_NAME name
 309 #     Corresponds to OUTPUT_NAME in target properties.
 310 #   DEPENDS targets...
 311 #     Same semantics as add_dependencies().
 312 #   LINK_COMPONENTS components...
 313 #     Same as the variable LLVM_LINK_COMPONENTS.
 314 #   LINK_LIBS lib_targets...
 315 #     Same semantics as target_link_libraries().
 316 #   ADDITIONAL_HEADERS
 317 #     May specify header files for IDE generators.
 318 #   )
 319 function(llvm_add_library name)
 320   cmake_parse_arguments(ARG
 321     "MODULE;SHARED;STATIC"
 322     "OUTPUT_NAME"
 323     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 324     ${ARGN})
 325   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 326   if(ARG_ADDITIONAL_HEADERS)
 327     # Pass through ADDITIONAL_HEADERS.
 328     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 329   endif()
 330   if(ARG_OBJLIBS)
 331     set(ALL_FILES ${ARG_OBJLIBS})
 332   else()
 333     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 334   endif()
 335
 336   if(ARG_MODULE)
 337     if(ARG_SHARED OR ARG_STATIC)
 338       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 339     endif()
 340     if(NOT LLVM_ENABLE_PLUGINS)
 341       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 342       return()
 343     endif()
 344   else()
 345     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 346       set(ARG_SHARED TRUE)
 347     endif()
 348     if(NOT ARG_SHARED)
 349       set(ARG_STATIC TRUE)
 350     endif()
 351   endif()
 352
 353   # Generate objlib
 354   if(ARG_SHARED AND ARG_STATIC)
 355     # Generate an obj library for both targets.
 356     set(obj_name "obj.${name}")
 357     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 358       ${ALL_FILES}
 359       )
 360     llvm_update_compile_flags(${obj_name})
 361     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 362
 363     # Do add_dependencies(obj) later due to CMake issue 14747.
 364     list(APPEND objlibs ${obj_name})
 365
 366     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 367   endif()
 368
 369   if(ARG_SHARED AND ARG_STATIC)
 370     # static
 371     set(name_static "${name}_static")
 372     if(ARG_OUTPUT_NAME)
 373       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 374     endif()
 375     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 376     llvm_add_library(${name_static} STATIC
 377       ${output_name}
 378       OBJLIBS ${ALL_FILES} # objlib
 379       LINK_LIBS ${ARG_LINK_LIBS}
 380       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 381       )
 382     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 383     set(ARG_STATIC)
 384   endif()
 385
 386   if(ARG_MODULE)
 387     add_library(${name} MODULE ${ALL_FILES})
 388   elseif(ARG_SHARED)
 389     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 390     add_library(${name} SHARED ${ALL_FILES})
 391   else()
 392     add_library(${name} STATIC ${ALL_FILES})
 393   endif()
 394
 395   if(DEFINED windows_resource_file)
 396     set_windows_version_resource_properties(${name} ${windows_resource_file})
 397     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 398   endif()
 399
 400   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 401   llvm_update_compile_flags(${name})
 402   add_link_opts( ${name} )
 403   if(ARG_OUTPUT_NAME)
 404     set_target_properties(${name}
 405       PROPERTIES
 406       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 407       )
 408   endif()
 409
 410   if(ARG_MODULE)
 411     set_target_properties(${name} PROPERTIES
 412       PREFIX ""
 413       SUFFIX ${LLVM_PLUGIN_EXT}
 414       )
 415   endif()
 416
 417   if(ARG_SHARED)
 418     if(WIN32)
 419       set_target_properties(${name} PROPERTIES
 420         PREFIX ""
 421         )
 422     endif()
 423
 424     set_target_properties(${name}
 425       PROPERTIES
 426       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 427       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 428   endif()
 429
 430   if(ARG_MODULE OR ARG_SHARED)
 431     # Do not add -Dname_EXPORTS to the command-line when building files in this
 432     # target. Doing so is actively harmful for the modules build because it
 433     # creates extra module variants, and not useful because we don't use these
 434     # macros.
 435     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 436
 437     if (LLVM_EXPORTED_SYMBOL_FILE)
 438       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 439     endif()
 440   endif()
 441
 442   # Add the explicit dependency information for this library.
 443   #
 444   # It would be nice to verify that we have the dependencies for this library
 445   # name, but using get_property(... SET) doesn't suffice to determine if a
 446   # property has been set to an empty value.
 447   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 448
 449   llvm_map_components_to_libnames(llvm_libs
 450     ${ARG_LINK_COMPONENTS}
 451     ${LLVM_LINK_COMPONENTS}
 452     )
 453
 454   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 455     # Link libs w/o keywords, assuming PUBLIC.
 456     target_link_libraries(${name}
 457       ${ARG_LINK_LIBS}
 458       ${lib_deps}
 459       ${llvm_libs}
 460       )
 461   elseif(ARG_STATIC)
 462     target_link_libraries(${name} INTERFACE
 463       ${ARG_LINK_LIBS}
 464       ${lib_deps}
 465       ${llvm_libs}
 466       )
 467   else()
 468     # We can use PRIVATE since SO knows its dependent libs.
 469     target_link_libraries(${name} PRIVATE
 470       ${ARG_LINK_LIBS}
 471       ${lib_deps}
 472       ${llvm_libs}
 473       )
 474   endif()
 475
 476   if(LLVM_COMMON_DEPENDS)
 477     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 478     # Add dependencies also to objlibs.
 479     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 480     foreach(objlib ${objlibs})
 481       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 482     endforeach()
 483   endif()
 484 endfunction()
 485
 486 macro(add_llvm_library name)
 487   cmake_parse_arguments(ARG
 488     "SHARED"
 489     ""
 490     ""
 491     ${ARGN})
 492   if( BUILD_SHARED_LIBS )
 493     llvm_add_library(${name} SHARED ${ARGN})
 494   else()
 495     llvm_add_library(${name} ${ARGN})
 496   endif()
 497   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 498
 499   if( EXCLUDE_FROM_ALL )
 500     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 501   else()
 502     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 503       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 504         if(WIN32 OR CYGWIN)
 505           set(install_type RUNTIME)
 506         else()
 507           set(install_type LIBRARY)
 508         endif()
 509       else()
 510         set(install_type ARCHIVE)
 511       endif()
 512
 513       install(TARGETS ${name}
 514             EXPORT LLVMExports
 515             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 516             COMPONENT ${name})
 517
 518       if (NOT CMAKE_CONFIGURATION_TYPES)
 519         add_custom_target(install-${name}
 520                           DEPENDS ${name}
 521                           COMMAND "${CMAKE_COMMAND}"
 522                                   -DCMAKE_INSTALL_COMPONENT=${name}
 523                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 524       endif()
 525     endif()
 526     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 527   endif()
 528   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 529 endmacro(add_llvm_library name)
 530
 531 macro(add_llvm_loadable_module name)
 532   llvm_add_library(${name} MODULE ${ARGN})
 533   if(NOT TARGET ${name})
 534     # Add empty "phony" target
 535     add_custom_target(${name})
 536   else()
 537     if( EXCLUDE_FROM_ALL )
 538       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 539     else()
 540       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 541         if(WIN32 OR CYGWIN)
 542           # DLL platform
 543           set(dlldir "bin")
 544         else()
 545           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 546         endif()
 547         install(TARGETS ${name}
 548           EXPORT LLVMExports
 549           LIBRARY DESTINATION ${dlldir}
 550           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 551       endif()
 552       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 553     endif()
 554   endif()
 555
 556   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 557 endmacro(add_llvm_loadable_module name)
 558
 559
 560 macro(add_llvm_executable name)
 561   llvm_process_sources( ALL_FILES ${ARGN} )
 562   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 563
 564   if( EXCLUDE_FROM_ALL )
 565     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 566   else()
 567     add_executable(${name} ${ALL_FILES})
 568   endif()
 569
 570   if(DEFINED windows_resource_file)
 571     set_windows_version_resource_properties(${name} ${windows_resource_file})
 572   endif()
 573
 574   llvm_update_compile_flags(${name})
 575   add_link_opts( ${name} )
 576
 577   # Do not add -Dname_EXPORTS to the command-line when building files in this
 578   # target. Doing so is actively harmful for the modules build because it
 579   # creates extra module variants, and not useful because we don't use these
 580   # macros.
 581   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 582
 583   if (LLVM_EXPORTED_SYMBOL_FILE)
 584     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 585   endif(LLVM_EXPORTED_SYMBOL_FILE)
 586
 587   set(EXCLUDE_FROM_ALL OFF)
 588   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 589   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 590   if( LLVM_COMMON_DEPENDS )
 591     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 592   endif( LLVM_COMMON_DEPENDS )
 593 endmacro(add_llvm_executable name)
 594
 595 function(export_executable_symbols target)
 596   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 597     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 598   endif()
 599 endfunction()
 600
 601
 602 set (LLVM_TOOLCHAIN_TOOLS
 603   llvm-ar
 604   llvm-objdump
 605   )
 606
 607 macro(add_llvm_tool name)
 608   if( NOT LLVM_BUILD_TOOLS )
 609     set(EXCLUDE_FROM_ALL ON)
 610   endif()
 611   add_llvm_executable(${name} ${ARGN})
 612
 613   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 614   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 615     if( LLVM_BUILD_TOOLS )
 616       install(TARGETS ${name}
 617               EXPORT LLVMExports
 618               RUNTIME DESTINATION bin
 619               COMPONENT ${name})
 620
 621       if (NOT CMAKE_CONFIGURATION_TYPES)
 622         add_custom_target(install-${name}
 623                           DEPENDS ${name}
 624                           COMMAND "${CMAKE_COMMAND}"
 625                                   -DCMAKE_INSTALL_COMPONENT=${name}
 626                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 627       endif()
 628     endif()
 629   endif()
 630   if( LLVM_BUILD_TOOLS )
 631     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 632   endif()
 633   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 634 endmacro(add_llvm_tool name)
 635
 636
 637 macro(add_llvm_example name)
 638   if( NOT LLVM_BUILD_EXAMPLES )
 639     set(EXCLUDE_FROM_ALL ON)
 640   endif()
 641   add_llvm_executable(${name} ${ARGN})
 642   if( LLVM_BUILD_EXAMPLES )
 643     install(TARGETS ${name} RUNTIME DESTINATION examples)
 644   endif()
 645   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 646 endmacro(add_llvm_example name)
 647
 648
 649 macro(add_llvm_utility name)
 650   add_llvm_executable(${name} ${ARGN})
 651   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 652   if( LLVM_INSTALL_UTILS )
 653     install (TARGETS ${name}
 654       RUNTIME DESTINATION bin
 655       COMPONENT ${name})
 656     if (NOT CMAKE_CONFIGURATION_TYPES)
 657       add_custom_target(install-${name}
 658                         DEPENDS ${name}
 659                         COMMAND "${CMAKE_COMMAND}"
 660                                 -DCMAKE_INSTALL_COMPONENT=${name}
 661                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 662     endif()
 663   endif()
 664 endmacro(add_llvm_utility name)
 665
 666
 667 macro(add_llvm_target target_name)
 668   include_directories(BEFORE
 669     ${CMAKE_CURRENT_BINARY_DIR}
 670     ${CMAKE_CURRENT_SOURCE_DIR})
 671   add_llvm_library(LLVM${target_name} ${ARGN})
 672   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 673 endmacro(add_llvm_target)
 674
 675 # Add external project that may want to be built as part of llvm such as Clang,
 676 # lld, and Polly. This adds two options. One for the source directory of the
 677 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 678 # enable or disable building it with everything else.
 679 # Additional parameter can be specified as the name of directory.
 680 macro(add_llvm_external_project name)
 681   set(add_llvm_external_dir "${ARGN}")
 682   if("${add_llvm_external_dir}" STREQUAL "")
 683     set(add_llvm_external_dir ${name})
 684   endif()
 685   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 686   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 687   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 688   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 689       CACHE PATH "Path to ${name} source directory")
 690   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 691       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 692     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 693            "Whether to build ${name} as part of LLVM" ON)
 694     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 695       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 696     endif()
 697   endif()
 698 endmacro(add_llvm_external_project)
 699
 700 macro(add_llvm_tool_subdirectory name)
 701   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 702   add_subdirectory(${name})
 703 endmacro(add_llvm_tool_subdirectory)
 704
 705 macro(ignore_llvm_tool_subdirectory name)
 706   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 707 endmacro(ignore_llvm_tool_subdirectory)
 708
 709 function(add_llvm_implicit_external_projects)
 710   set(list_of_implicit_subdirs "")
 711   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 712   foreach(dir ${sub-dirs})
 713     if(IS_DIRECTORY "${dir}")
 714       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 715       if( tool_subdir_ignore EQUAL -1
 716           AND EXISTS "${dir}/CMakeLists.txt")
 717         get_filename_component(fn "${dir}" NAME)
 718         list(APPEND list_of_implicit_subdirs "${fn}")
 719       endif()
 720     endif()
 721   endforeach()
 722
 723   foreach(external_proj ${list_of_implicit_subdirs})
 724     add_llvm_external_project("${external_proj}")
 725   endforeach()
 726 endfunction(add_llvm_implicit_external_projects)
 727
 728 # Generic support for adding a unittest.
 729 function(add_unittest test_suite test_name)
 730   if( NOT LLVM_BUILD_TESTS )
 731     set(EXCLUDE_FROM_ALL ON)
 732   endif()
 733
 734   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 735   if (NOT LLVM_ENABLE_THREADS)
 736     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 737   endif ()
 738
 739   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 740     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 741   endif ()
 742
 743   set(LLVM_REQUIRES_RTTI OFF)
 744
 745   add_llvm_executable(${test_name} ${ARGN})
 746   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 747   set_output_directory(${test_name} ${outdir} ${outdir})
 748   target_link_libraries(${test_name}
 749     gtest
 750     gtest_main
 751     LLVMSupport # gtest needs it for raw_ostream.
 752     )
 753
 754   add_dependencies(${test_suite} ${test_name})
 755   get_target_property(test_suite_folder ${test_suite} FOLDER)
 756   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 757     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 758   endif ()
 759 endfunction()
 760
 761 function(llvm_add_go_executable binary pkgpath)
 762   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 763
 764   if(LLVM_BINDINGS MATCHES "go")
 765     # FIXME: This should depend only on the libraries Go needs.
 766     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 767     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 768     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 769     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 770     set(cppflags "")
 771     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 772     foreach(d ${include_dirs})
 773       set(cppflags "${cppflags} -I${d}")
 774     endforeach(d)
 775     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 776     add_custom_command(OUTPUT ${binpath}
 777       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
 778               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 779       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 780               ${llvmlibs} ${ARG_DEPENDS}
 781       COMMENT "Building Go executable ${binary}"
 782       VERBATIM)
 783     if (ARG_ALL)
 784       add_custom_target(${binary} ALL DEPENDS ${binpath})
 785     else()
 786       add_custom_target(${binary} DEPENDS ${binpath})
 787     endif()
 788   endif()
 789 endfunction()
 790
 791 # This function provides an automatic way to 'configure'-like generate a file
 792 # based on a set of common and custom variables, specifically targeting the
 793 # variables needed for the 'lit.site.cfg' files. This function bundles the
 794 # common variables that any Lit instance is likely to need, and custom
 795 # variables can be passed in.
 796 function(configure_lit_site_cfg input output)
 797   foreach(c ${LLVM_TARGETS_TO_BUILD})
 798     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 799   endforeach(c)
 800   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 801
 802   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 803
 804   # Configuration-time: See Unit/lit.site.cfg.in
 805   if (CMAKE_CFG_INTDIR STREQUAL ".")
 806     set(LLVM_BUILD_MODE ".")
 807   else ()
 808     set(LLVM_BUILD_MODE "%(build_mode)s")
 809   endif ()
 810
 811   # They below might not be the build tree but provided binary tree.
 812   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 813   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 814   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 815   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 816
 817   # SHLIBDIR points the build tree.
 818   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 819
 820   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 821   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 822   # plugins. We may rename it.
 823   if(LLVM_ENABLE_PLUGINS)
 824     set(ENABLE_SHARED "1")
 825   else()
 826     set(ENABLE_SHARED "0")
 827   endif()
 828
 829   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 830     set(ENABLE_ASSERTIONS "1")
 831   else()
 832     set(ENABLE_ASSERTIONS "0")
 833   endif()
 834
 835   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 836   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 837
 838   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 839   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 840   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 841
 842   configure_file(${input} ${output} @ONLY)
 843 endfunction()
 844
 845 # A raw function to create a lit target. This is used to implement the testuite
 846 # management functions.
 847 function(add_lit_target target comment)
 848   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 849   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 850   separate_arguments(LIT_ARGS)
 851   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 852     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 853   endif ()
 854   if (LLVM_MAIN_SRC_DIR)
 855     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 856   else()
 857     find_program(LIT_COMMAND llvm-lit)
 858   endif ()
 859   list(APPEND LIT_COMMAND ${LIT_ARGS})
 860   foreach(param ${ARG_PARAMS})
 861     list(APPEND LIT_COMMAND --param ${param})
 862   endforeach()
 863   if (ARG_DEFAULT_ARGS)
 864     add_custom_target(${target}
 865       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 866       COMMENT "${comment}"
 867       ${cmake_3_2_USES_TERMINAL}
 868       )
 869   else()
 870     add_custom_target(${target}
 871       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 872     message(STATUS "${target} does nothing.")
 873   endif()
 874   if (ARG_DEPENDS)
 875     add_dependencies(${target} ${ARG_DEPENDS})
 876   endif()
 877
 878   # Tests should be excluded from "Build Solution".
 879   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 880 endfunction()
 881
 882 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 883 function(add_lit_testsuite target comment)
 884   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 885
 886   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 887   if(NOT EXCLUDE_FROM_ALL)
 888     # Register the testsuites, params and depends for the global check rule.
 889     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 890     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 891     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 892     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 893   endif()
 894
 895   # Produce a specific suffixed check rule.
 896   add_lit_target(${target} ${comment}
 897     ${ARG_DEFAULT_ARGS}
 898     PARAMS ${ARG_PARAMS}
 899     DEPENDS ${ARG_DEPENDS}
 900     ARGS ${ARG_ARGS}
 901     )
 902 endfunction()
 903
 904 function(add_lit_testsuites project directory)
 905   if (NOT CMAKE_CONFIGURATION_TYPES)
 906     parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 907     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
 908     set(lit_suites)
 909     foreach(f ${litCfg})
 910       get_filename_component(dir ${f} DIRECTORY)
 911       set(lit_suites ${lit_suites} ${dir})
 912     endforeach()
 913     list(REMOVE_DUPLICATES lit_suites)
 914     foreach(dir ${lit_suites})
 915       string(REPLACE ${directory} "" name_slash ${dir})
 916       if (name_slash)
 917         string(REPLACE "/" "-" name_slash ${name_slash})
 918         string(REPLACE "\\" "-" name_dashes ${name_slash})
 919         string(TOLOWER "${project}${name_dashes}" name_var)
 920         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
 921           ${dir}
 922           PARAMS ${ARG_PARAMS}
 923           DEPENDS ${ARG_DEPENDS}
 924           ARGS ${ARG_ARGS}
 925         )
 926       endif()
 927     endforeach()
 928   endif()
 929 endfunction()