cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130 endfunction(add_llvm_symbol_exports)
 131
 132 function(add_dead_strip target_name)
 133   if(NOT LLVM_NO_DEAD_STRIP)
 134     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 135       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 136                    LINK_FLAGS " -Wl,-dead_strip")
 137     elseif(NOT WIN32)
 138       # Object files are compiled with -ffunction-data-sections.
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,--gc-sections")
 141     endif()
 142   endif()
 143 endfunction(add_dead_strip)
 144
 145 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 146 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 147 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 148 function(set_output_directory target bindir libdir)
 149   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 150     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 151       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 152       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 153       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 154       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 155       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 156       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 157     endforeach()
 158   else()
 159     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 160     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 161     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${libdir})
 162   endif()
 163 endfunction()
 164
 165 # llvm_add_library(name sources...
 166 #   MODULE;SHARED;STATIC
 167 #     STATIC by default w/o BUILD_SHARED_LIBS.
 168 #     SHARED by default w/  BUILD_SHARED_LIBS.
 169 #   OUTPUT_NAME name
 170 #     Corresponds to OUTPUT_NAME in target properties.
 171 #   DEPENDS targets...
 172 #     Same semantics as add_dependencies().
 173 #   LINK_COMPONENTS components...
 174 #     Same as the variable LLVM_LINK_COMPONENTS.
 175 #   LINK_LIBS lib_targets...
 176 #     Same semantics as target_link_libraries().
 177 #   ADDITIONAL_HEADERS
 178 #     May specify header files for IDE generators.
 179 #   )
 180 function(llvm_add_library name)
 181   cmake_parse_arguments(ARG
 182     "MODULE;SHARED;STATIC"
 183     "OUTPUT_NAME"
 184     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS"
 185     ${ARGN})
 186   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 187   if(ARG_ADDITIONAL_HEADERS)
 188     # Pass through ADDITIONAL_HEADERS.
 189     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 190   endif()
 191   llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 192
 193   if(ARG_MODULE)
 194     if(ARG_SHARED OR ARG_STATIC)
 195       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 196     endif()
 197   else()
 198     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 199       set(ARG_SHARED TRUE)
 200     endif()
 201     if(NOT ARG_SHARED)
 202       set(ARG_STATIC TRUE)
 203     endif()
 204   endif()
 205
 206   if(ARG_MODULE)
 207     add_library(${name} MODULE ${ALL_FILES})
 208   elseif(ARG_SHARED)
 209     add_library(${name} SHARED ${ALL_FILES})
 210   else()
 211     add_library(${name} STATIC ${ALL_FILES})
 212   endif()
 213   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 214   llvm_update_compile_flags(${name})
 215   add_dead_strip( ${name} )
 216   if(ARG_OUTPUT_NAME)
 217     set_target_properties(${name}
 218       PROPERTIES
 219       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 220       )
 221   endif()
 222
 223   if(ARG_MODULE)
 224     set_property(TARGET ${name} PROPERTY SUFFIX ${LLVM_PLUGIN_EXT})
 225   endif()
 226
 227   if(ARG_SHARED)
 228     if (MSVC)
 229       set_target_properties(${name}
 230         PROPERTIES
 231         IMPORT_SUFFIX ".imp")
 232     endif ()
 233   endif()
 234
 235   if(ARG_MODULE OR ARG_SHARED)
 236     if (LLVM_EXPORTED_SYMBOL_FILE)
 237       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 238     endif()
 239   endif()
 240
 241   target_link_libraries(${name} ${ARG_LINK_LIBS})
 242
 243   llvm_config(${name} ${ARG_LINK_COMPONENTS} ${LLVM_LINK_COMPONENTS})
 244
 245   if(LLVM_COMMON_DEPENDS)
 246     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 247   endif()
 248 endfunction()
 249
 250 macro(add_llvm_library name)
 251   if( BUILD_SHARED_LIBS )
 252     llvm_add_library(${name} SHARED ${ARGN})
 253   else()
 254     llvm_add_library(${name} ${ARGN})
 255   endif()
 256   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 257
 258   if( EXCLUDE_FROM_ALL )
 259     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 260   else()
 261     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 262       install(TARGETS ${name}
 263         EXPORT LLVMExports
 264         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 265         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 266     endif()
 267     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 268   endif()
 269   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 270
 271   # Add the explicit dependency information for this library.
 272   #
 273   # It would be nice to verify that we have the dependencies for this library
 274   # name, but using get_property(... SET) doesn't suffice to determine if a
 275   # property has been set to an empty value.
 276   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 277   target_link_libraries(${name} ${lib_deps})
 278 endmacro(add_llvm_library name)
 279
 280 macro(add_llvm_loadable_module name)
 281   if( NOT LLVM_ON_UNIX OR CYGWIN )
 282     message(STATUS "Loadable modules not supported on this platform.
 283 ${name} ignored.")
 284     # Add empty "phony" target
 285     add_custom_target(${name})
 286   else()
 287     llvm_add_library(${name} MODULE ${ARGN})
 288     set_target_properties( ${name} PROPERTIES PREFIX "" )
 289
 290     if( EXCLUDE_FROM_ALL )
 291       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 292     else()
 293       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 294         install(TARGETS ${name}
 295           EXPORT LLVMExports
 296           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 297           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 298       endif()
 299       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 300     endif()
 301   endif()
 302
 303   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 304 endmacro(add_llvm_loadable_module name)
 305
 306
 307 macro(add_llvm_executable name)
 308   llvm_process_sources( ALL_FILES ${ARGN} )
 309   if( EXCLUDE_FROM_ALL )
 310     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 311   else()
 312     add_executable(${name} ${ALL_FILES})
 313   endif()
 314   llvm_update_compile_flags(${name})
 315   add_dead_strip( ${name} )
 316
 317   if (LLVM_EXPORTED_SYMBOL_FILE)
 318     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 319   endif(LLVM_EXPORTED_SYMBOL_FILE)
 320
 321   set(EXCLUDE_FROM_ALL OFF)
 322   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 323   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 324   if( LLVM_COMMON_DEPENDS )
 325     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 326   endif( LLVM_COMMON_DEPENDS )
 327 endmacro(add_llvm_executable name)
 328
 329
 330 set (LLVM_TOOLCHAIN_TOOLS
 331   llvm-ar
 332   llvm-objdump
 333   )
 334
 335 macro(add_llvm_tool name)
 336   if( NOT LLVM_BUILD_TOOLS )
 337     set(EXCLUDE_FROM_ALL ON)
 338   endif()
 339   add_llvm_executable(${name} ${ARGN})
 340
 341   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 342   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 343     if( LLVM_BUILD_TOOLS )
 344       install(TARGETS ${name}
 345               EXPORT LLVMExports
 346               RUNTIME DESTINATION bin)
 347     endif()
 348   endif()
 349   if( LLVM_BUILD_TOOLS )
 350     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 351   endif()
 352   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 353 endmacro(add_llvm_tool name)
 354
 355
 356 macro(add_llvm_example name)
 357   if( NOT LLVM_BUILD_EXAMPLES )
 358     set(EXCLUDE_FROM_ALL ON)
 359   endif()
 360   add_llvm_executable(${name} ${ARGN})
 361   if( LLVM_BUILD_EXAMPLES )
 362     install(TARGETS ${name} RUNTIME DESTINATION examples)
 363   endif()
 364   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 365 endmacro(add_llvm_example name)
 366
 367
 368 macro(add_llvm_utility name)
 369   add_llvm_executable(${name} ${ARGN})
 370   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 371 endmacro(add_llvm_utility name)
 372
 373
 374 macro(add_llvm_target target_name)
 375   include_directories(BEFORE
 376     ${CMAKE_CURRENT_BINARY_DIR}
 377     ${CMAKE_CURRENT_SOURCE_DIR})
 378   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 379   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 380 endmacro(add_llvm_target)
 381
 382 # Add external project that may want to be built as part of llvm such as Clang,
 383 # lld, and Polly. This adds two options. One for the source directory of the
 384 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 385 # enable or disable building it with everything else.
 386 # Additional parameter can be specified as the name of directory.
 387 macro(add_llvm_external_project name)
 388   set(add_llvm_external_dir "${ARGN}")
 389   if("${add_llvm_external_dir}" STREQUAL "")
 390     set(add_llvm_external_dir ${name})
 391   endif()
 392   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 393   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 394   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 395   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 396       CACHE PATH "Path to ${name} source directory")
 397   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 398       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 399     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 400            "Whether to build ${name} as part of LLVM" ON)
 401     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 402       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 403     endif()
 404   endif()
 405 endmacro(add_llvm_external_project)
 406
 407 macro(add_llvm_tool_subdirectory name)
 408   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 409   add_subdirectory(${name})
 410 endmacro(add_llvm_tool_subdirectory)
 411
 412 macro(ignore_llvm_tool_subdirectory name)
 413   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 414 endmacro(ignore_llvm_tool_subdirectory)
 415
 416 function(add_llvm_implicit_external_projects)
 417   set(list_of_implicit_subdirs "")
 418   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 419   foreach(dir ${sub-dirs})
 420     if(IS_DIRECTORY "${dir}")
 421       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 422       if( tool_subdir_ignore EQUAL -1
 423           AND EXISTS "${dir}/CMakeLists.txt")
 424         get_filename_component(fn "${dir}" NAME)
 425         list(APPEND list_of_implicit_subdirs "${fn}")
 426       endif()
 427     endif()
 428   endforeach()
 429
 430   foreach(external_proj ${list_of_implicit_subdirs})
 431     add_llvm_external_project("${external_proj}")
 432   endforeach()
 433 endfunction(add_llvm_implicit_external_projects)
 434
 435 # Generic support for adding a unittest.
 436 function(add_unittest test_suite test_name)
 437   if( NOT LLVM_BUILD_TESTS )
 438     set(EXCLUDE_FROM_ALL ON)
 439   endif()
 440
 441   # Visual Studio 2012 only supports up to 8 template parameters in
 442   # std::tr1::tuple by default, but gtest requires 10
 443   if (MSVC AND MSVC_VERSION EQUAL 1700)
 444     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 445   endif ()
 446
 447   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 448   if (NOT LLVM_ENABLE_THREADS)
 449     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 450   endif ()
 451
 452   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 453     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 454   endif ()
 455
 456   set(LLVM_REQUIRES_RTTI OFF)
 457
 458   add_llvm_executable(${test_name} ${ARGN})
 459   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 460   set_output_directory(${test_name} ${outdir} ${outdir})
 461   target_link_libraries(${test_name}
 462     gtest
 463     gtest_main
 464     LLVMSupport # gtest needs it for raw_ostream.
 465     )
 466
 467   add_dependencies(${test_suite} ${test_name})
 468   get_target_property(test_suite_folder ${test_suite} FOLDER)
 469   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 470     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 471   endif ()
 472 endfunction()
 473
 474 # This function provides an automatic way to 'configure'-like generate a file
 475 # based on a set of common and custom variables, specifically targeting the
 476 # variables needed for the 'lit.site.cfg' files. This function bundles the
 477 # common variables that any Lit instance is likely to need, and custom
 478 # variables can be passed in.
 479 function(configure_lit_site_cfg input output)
 480   foreach(c ${LLVM_TARGETS_TO_BUILD})
 481     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 482   endforeach(c)
 483   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 484
 485   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 486
 487   if(BUILD_SHARED_LIBS)
 488     set(LLVM_SHARED_LIBS_ENABLED "1")
 489   else()
 490     set(LLVM_SHARED_LIBS_ENABLED "0")
 491   endif(BUILD_SHARED_LIBS)
 492
 493   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 494     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 495   else() # Default for all other unix like systems.
 496     # CMake hardcodes the library locaction using rpath.
 497     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 498     # build dir. We pass it anyways.
 499     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 500   endif()
 501
 502   # Configuration-time: See Unit/lit.site.cfg.in
 503   if (CMAKE_CFG_INTDIR STREQUAL ".")
 504     set(LLVM_BUILD_MODE ".")
 505   else ()
 506     set(LLVM_BUILD_MODE "%(build_mode)s")
 507   endif ()
 508
 509   # They below might not be the build tree but provided binary tree.
 510   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 511   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 512   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 513   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 514
 515   # SHLIBDIR points the build tree.
 516   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 517
 518   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 519   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 520   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 521
 522   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 523     set(ENABLE_ASSERTIONS "1")
 524   else()
 525     set(ENABLE_ASSERTIONS "0")
 526   endif()
 527
 528   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 529   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 530
 531   if (CLANG_ENABLE_ARCMT)
 532     set(ENABLE_CLANG_ARCMT "1")
 533   else()
 534     set(ENABLE_CLANG_ARCMT "0")
 535   endif()
 536   if (CLANG_ENABLE_REWRITER)
 537     set(ENABLE_CLANG_REWRITER "1")
 538   else()
 539     set(ENABLE_CLANG_REWRITER "0")
 540   endif()
 541   if (CLANG_ENABLE_STATIC_ANALYZER)
 542     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 543   else()
 544     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 545   endif()
 546
 547   configure_file(${input} ${output} @ONLY)
 548 endfunction()
 549
 550 # A raw function to create a lit target. This is used to implement the testuite
 551 # management functions.
 552 function(add_lit_target target comment)
 553   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 554   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 555   separate_arguments(LIT_ARGS)
 556   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 557     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 558   endif ()
 559   set(LIT_COMMAND
 560     ${PYTHON_EXECUTABLE}
 561     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 562     ${LIT_ARGS}
 563     )
 564   foreach(param ${ARG_PARAMS})
 565     list(APPEND LIT_COMMAND --param ${param})
 566   endforeach()
 567   if( ARG_DEPENDS )
 568     add_custom_target(${target}
 569       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 570       COMMENT "${comment}"
 571       )
 572     add_dependencies(${target} ${ARG_DEPENDS})
 573   else()
 574     add_custom_target(${target}
 575       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 576     message(STATUS "${target} does nothing.")
 577   endif()
 578
 579   # Tests should be excluded from "Build Solution".
 580   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 581 endfunction()
 582
 583 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 584 function(add_lit_testsuite target comment)
 585   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 586
 587   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 588   if(NOT EXCLUDE_FROM_ALL)
 589     # Register the testsuites, params and depends for the global check rule.
 590     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 591     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 592     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 593     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 594   endif()
 595
 596   # Produce a specific suffixed check rule.
 597   add_lit_target(${target} ${comment}
 598     ${ARG_DEFAULT_ARGS}
 599     PARAMS ${ARG_PARAMS}
 600     DEPENDS ${ARG_DEPENDS}
 601     ARGS ${ARG_ARGS}
 602     )
 603 endfunction()