cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if(LLVM_REQUIRES_EH OR LLVM_ENABLE_EH)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  30     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  31     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  32       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  33     elseif (MSVC)
  34       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  35     endif ()
  36   endif()
  37
  38   # Assume that;
  39   #   - LLVM_COMPILE_FLAGS is list.
  40   #   - PROPERTY COMPILE_FLAGS is string.
  41   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  42
  43   if(update_src_props)
  44     foreach(fn ${sources})
  45       get_filename_component(suf ${fn} EXT)
  46       if("${suf}" STREQUAL ".cpp")
  47         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  48           COMPILE_FLAGS "${target_compile_flags}")
  49       endif()
  50     endforeach()
  51   else()
  52     # Update target props, since all sources are C++.
  53     set_property(TARGET ${name} APPEND_STRING PROPERTY
  54       COMPILE_FLAGS "${target_compile_flags}")
  55   endif()
  56
  57   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  58 endfunction()
  59
  60 function(add_llvm_symbol_exports target_name export_file)
  61   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  62     set(native_export_file "${target_name}.exports")
  63     add_custom_command(OUTPUT ${native_export_file}
  64       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  65       DEPENDS ${export_file}
  66       VERBATIM
  67       COMMENT "Creating export file for ${target_name}")
  68     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  69                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  70   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  71     # Gold and BFD ld require a version script rather than a plain list.
  72     set(native_export_file "${target_name}.exports")
  73     # FIXME: Don't write the "local:" line on OpenBSD.
  74     add_custom_command(OUTPUT ${native_export_file}
  75       COMMAND echo "{" > ${native_export_file}
  76       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  77       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  78       COMMAND echo "  local: *;" >> ${native_export_file}
  79       COMMAND echo "};" >> ${native_export_file}
  80       DEPENDS ${export_file}
  81       VERBATIM
  82       COMMENT "Creating export file for ${target_name}")
  83     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  84                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  85   else()
  86     set(native_export_file "${target_name}.def")
  87
  88     set(CAT "type")
  89     if(CYGWIN)
  90       set(CAT "cat")
  91     endif()
  92
  93     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  94     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  95
  96     add_custom_command(OUTPUT ${native_export_file}
  97       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  98       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  99       DEPENDS ${export_file}
 100       VERBATIM
 101       COMMENT "Creating export file for ${target_name}")
 102     if(CYGWIN OR MINGW)
 103       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 104                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 105     else()
 106       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 107                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 108     endif()
 109   endif()
 110
 111   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 112   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 113
 114   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 115   foreach(src ${srcs})
 116     get_filename_component(extension ${src} EXT)
 117     if(extension STREQUAL ".cpp")
 118       set(first_source_file ${src})
 119       break()
 120     endif()
 121   endforeach()
 122
 123   # Force re-linking when the exports file changes. Actually, it
 124   # forces recompilation of the source file. The LINK_DEPENDS target
 125   # property only works for makefile-based generators.
 126   # FIXME: This is not safe because this will create the same target
 127   # ${native_export_file} in several different file:
 128   # - One where we emitted ${target_name}_exports
 129   # - One where we emitted the build command for the following object.
 130   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 131   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 132
 133   set_property(DIRECTORY APPEND
 134     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 135
 136   add_dependencies(${target_name} ${target_name}_exports)
 137
 138   # Add dependency to *_exports later -- CMake issue 14747
 139   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 140   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 141 endfunction(add_llvm_symbol_exports)
 142
 143 function(add_dead_strip target_name)
 144   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 145     # ld64's implementation of -dead_strip breaks tools that use plugins.
 146     if(NOT LLVM_NO_DEAD_STRIP)
 147       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 148                    LINK_FLAGS " -Wl,-dead_strip")
 149     endif()
 150   elseif(NOT WIN32)
 151     # Object files are compiled with -ffunction-data-sections.
 152     # On ELF --gc-sections handles --export-dynamic correctly, so we can always
 153     # use it.
 154     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 155                  LINK_FLAGS " -Wl,--gc-sections")
 156   endif()
 157 endfunction(add_dead_strip)
 158
 159 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 160 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 161 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 162 function(set_output_directory target bindir libdir)
 163   # Do nothing if *_OUTPUT_INTDIR is empty.
 164   if("${bindir}" STREQUAL "")
 165     return()
 166   endif()
 167
 168   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 169   # It affects output of add_library(MODULE).
 170   if(WIN32 OR CYGWIN)
 171     # DLL platform
 172     set(moddir ${bindir})
 173   else()
 174     set(moddir ${libdir})
 175   endif()
 176   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 177     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 178       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 179       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 180       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 181       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 182       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 183       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 184       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 185     endforeach()
 186   else()
 187     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 188     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 189     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 190   endif()
 191 endfunction()
 192
 193 # llvm_add_library(name sources...
 194 #   SHARED;STATIC
 195 #     STATIC by default w/o BUILD_SHARED_LIBS.
 196 #     SHARED by default w/  BUILD_SHARED_LIBS.
 197 #   MODULE
 198 #     Target ${name} might not be created on unsupported platforms.
 199 #     Check with "if(TARGET ${name})".
 200 #   OUTPUT_NAME name
 201 #     Corresponds to OUTPUT_NAME in target properties.
 202 #   DEPENDS targets...
 203 #     Same semantics as add_dependencies().
 204 #   LINK_COMPONENTS components...
 205 #     Same as the variable LLVM_LINK_COMPONENTS.
 206 #   LINK_LIBS lib_targets...
 207 #     Same semantics as target_link_libraries().
 208 #   ADDITIONAL_HEADERS
 209 #     May specify header files for IDE generators.
 210 #   )
 211 function(llvm_add_library name)
 212   cmake_parse_arguments(ARG
 213     "MODULE;SHARED;STATIC"
 214     "OUTPUT_NAME"
 215     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 216     ${ARGN})
 217   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 218   if(ARG_ADDITIONAL_HEADERS)
 219     # Pass through ADDITIONAL_HEADERS.
 220     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 221   endif()
 222   if(ARG_OBJLIBS)
 223     set(ALL_FILES ${ARG_OBJLIBS})
 224   else()
 225     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 226   endif()
 227
 228   if(ARG_MODULE)
 229     if(ARG_SHARED OR ARG_STATIC)
 230       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 231     endif()
 232     if(NOT LLVM_ENABLE_PLUGINS)
 233       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 234       return()
 235     endif()
 236   else()
 237     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 238       set(ARG_SHARED TRUE)
 239     endif()
 240     if(NOT ARG_SHARED)
 241       set(ARG_STATIC TRUE)
 242     endif()
 243   endif()
 244
 245   # Generate objlib
 246   if(ARG_SHARED AND ARG_STATIC)
 247     # Generate an obj library for both targets.
 248     set(obj_name "obj.${name}")
 249     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 250       ${ALL_FILES}
 251       )
 252     llvm_update_compile_flags(${obj_name})
 253     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 254
 255     # Do add_dependencies(obj) later due to CMake issue 14747.
 256     list(APPEND objlibs ${obj_name})
 257
 258     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 259   endif()
 260
 261   if(ARG_SHARED AND ARG_STATIC)
 262     # static
 263     set(name_static "${name}_static")
 264     if(ARG_OUTPUT_NAME)
 265       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 266     endif()
 267     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 268     llvm_add_library(${name_static} STATIC
 269       ${output_name}
 270       OBJLIBS ${ALL_FILES} # objlib
 271       LINK_LIBS ${ARG_LINK_LIBS}
 272       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 273       )
 274     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 275     set(ARG_STATIC)
 276   endif()
 277
 278   if(ARG_MODULE)
 279     add_library(${name} MODULE ${ALL_FILES})
 280   elseif(ARG_SHARED)
 281     add_library(${name} SHARED ${ALL_FILES})
 282   else()
 283     add_library(${name} STATIC ${ALL_FILES})
 284   endif()
 285   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 286   llvm_update_compile_flags(${name})
 287   add_dead_strip( ${name} )
 288   if(ARG_OUTPUT_NAME)
 289     set_target_properties(${name}
 290       PROPERTIES
 291       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 292       )
 293   endif()
 294
 295   if(ARG_MODULE)
 296     set_target_properties(${name} PROPERTIES
 297       PREFIX ""
 298       SUFFIX ${LLVM_PLUGIN_EXT}
 299       )
 300   endif()
 301
 302   if(ARG_SHARED)
 303     if(WIN32)
 304       set_target_properties(${name} PROPERTIES
 305         PREFIX ""
 306         )
 307     endif()
 308     if (MSVC)
 309       set_target_properties(${name}
 310         PROPERTIES
 311         IMPORT_SUFFIX ".imp")
 312     endif ()
 313   endif()
 314
 315   if(ARG_MODULE OR ARG_SHARED)
 316     # Do not add -Dname_EXPORTS to the command-line when building files in this
 317     # target. Doing so is actively harmful for the modules build because it
 318     # creates extra module variants, and not useful because we don't use these
 319     # macros.
 320     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 321
 322     if (LLVM_EXPORTED_SYMBOL_FILE)
 323       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 324     endif()
 325   endif()
 326
 327   # Add the explicit dependency information for this library.
 328   #
 329   # It would be nice to verify that we have the dependencies for this library
 330   # name, but using get_property(... SET) doesn't suffice to determine if a
 331   # property has been set to an empty value.
 332   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 333
 334   llvm_map_components_to_libnames(llvm_libs
 335     ${ARG_LINK_COMPONENTS}
 336     ${LLVM_LINK_COMPONENTS}
 337     )
 338
 339   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 340     # Link libs w/o keywords, assuming PUBLIC.
 341     target_link_libraries(${name}
 342       ${ARG_LINK_LIBS}
 343       ${lib_deps}
 344       ${llvm_libs}
 345       )
 346   elseif(ARG_STATIC)
 347     target_link_libraries(${name} INTERFACE
 348       ${ARG_LINK_LIBS}
 349       ${lib_deps}
 350       ${llvm_libs}
 351       )
 352   elseif((CYGWIN OR WIN32) AND ARG_SHARED)
 353     # Win32's import library may be unaware of its dependent libs.
 354     target_link_libraries(${name} PRIVATE
 355       ${ARG_LINK_LIBS}
 356       ${lib_deps}
 357       ${llvm_libs}
 358       )
 359   elseif(ARG_SHARED AND BUILD_SHARED_LIBS)
 360     # FIXME: It may be PRIVATE since SO knows its dependent libs.
 361     target_link_libraries(${name} PUBLIC
 362       ${ARG_LINK_LIBS}
 363       ${lib_deps}
 364       ${llvm_libs}
 365       )
 366   else()
 367     # MODULE|SHARED
 368     target_link_libraries(${name} PRIVATE
 369       ${ARG_LINK_LIBS}
 370       ${lib_deps}
 371       ${llvm_libs}
 372       )
 373   endif()
 374
 375   if(LLVM_COMMON_DEPENDS)
 376     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 377     # Add dependencies also to objlibs.
 378     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 379     foreach(objlib ${objlibs})
 380       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 381     endforeach()
 382   endif()
 383 endfunction()
 384
 385 macro(add_llvm_library name)
 386   if( BUILD_SHARED_LIBS )
 387     llvm_add_library(${name} SHARED ${ARGN})
 388   else()
 389     llvm_add_library(${name} ${ARGN})
 390   endif()
 391   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 392
 393   if( EXCLUDE_FROM_ALL )
 394     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 395   else()
 396     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 397       install(TARGETS ${name}
 398         EXPORT LLVMExports
 399         RUNTIME DESTINATION bin
 400         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 401         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 402     endif()
 403     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 404   endif()
 405   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 406 endmacro(add_llvm_library name)
 407
 408 macro(add_llvm_loadable_module name)
 409   llvm_add_library(${name} MODULE ${ARGN})
 410   if(NOT TARGET ${name})
 411     # Add empty "phony" target
 412     add_custom_target(${name})
 413   else()
 414     if( EXCLUDE_FROM_ALL )
 415       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 416     else()
 417       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 418         if(WIN32 OR CYGWIN)
 419           # DLL platform
 420           set(dlldir "bin")
 421         else()
 422           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 423         endif()
 424         install(TARGETS ${name}
 425           EXPORT LLVMExports
 426           LIBRARY DESTINATION ${dlldir}
 427           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 428       endif()
 429       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 430     endif()
 431   endif()
 432
 433   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 434 endmacro(add_llvm_loadable_module name)
 435
 436
 437 macro(add_llvm_executable name)
 438   llvm_process_sources( ALL_FILES ${ARGN} )
 439   if( EXCLUDE_FROM_ALL )
 440     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 441   else()
 442     add_executable(${name} ${ALL_FILES})
 443   endif()
 444   llvm_update_compile_flags(${name})
 445   add_dead_strip( ${name} )
 446
 447   # Do not add -Dname_EXPORTS to the command-line when building files in this
 448   # target. Doing so is actively harmful for the modules build because it
 449   # creates extra module variants, and not useful because we don't use these
 450   # macros.
 451   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 452
 453   if (LLVM_EXPORTED_SYMBOL_FILE)
 454     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 455   endif(LLVM_EXPORTED_SYMBOL_FILE)
 456
 457   set(EXCLUDE_FROM_ALL OFF)
 458   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 459   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 460   if( LLVM_COMMON_DEPENDS )
 461     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 462   endif( LLVM_COMMON_DEPENDS )
 463 endmacro(add_llvm_executable name)
 464
 465
 466 set (LLVM_TOOLCHAIN_TOOLS
 467   llvm-ar
 468   llvm-objdump
 469   )
 470
 471 macro(add_llvm_tool name)
 472   if( NOT LLVM_BUILD_TOOLS )
 473     set(EXCLUDE_FROM_ALL ON)
 474   endif()
 475   add_llvm_executable(${name} ${ARGN})
 476
 477   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 478   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 479     if( LLVM_BUILD_TOOLS )
 480       install(TARGETS ${name}
 481               EXPORT LLVMExports
 482               RUNTIME DESTINATION bin)
 483     endif()
 484   endif()
 485   if( LLVM_BUILD_TOOLS )
 486     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 487   endif()
 488   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 489 endmacro(add_llvm_tool name)
 490
 491
 492 macro(add_llvm_example name)
 493   if( NOT LLVM_BUILD_EXAMPLES )
 494     set(EXCLUDE_FROM_ALL ON)
 495   endif()
 496   add_llvm_executable(${name} ${ARGN})
 497   if( LLVM_BUILD_EXAMPLES )
 498     install(TARGETS ${name} RUNTIME DESTINATION examples)
 499   endif()
 500   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 501 endmacro(add_llvm_example name)
 502
 503
 504 macro(add_llvm_utility name)
 505   add_llvm_executable(${name} ${ARGN})
 506   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 507 endmacro(add_llvm_utility name)
 508
 509
 510 macro(add_llvm_target target_name)
 511   include_directories(BEFORE
 512     ${CMAKE_CURRENT_BINARY_DIR}
 513     ${CMAKE_CURRENT_SOURCE_DIR})
 514   add_llvm_library(LLVM${target_name} ${ARGN})
 515   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 516 endmacro(add_llvm_target)
 517
 518 # Add external project that may want to be built as part of llvm such as Clang,
 519 # lld, and Polly. This adds two options. One for the source directory of the
 520 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 521 # enable or disable building it with everything else.
 522 # Additional parameter can be specified as the name of directory.
 523 macro(add_llvm_external_project name)
 524   set(add_llvm_external_dir "${ARGN}")
 525   if("${add_llvm_external_dir}" STREQUAL "")
 526     set(add_llvm_external_dir ${name})
 527   endif()
 528   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 529   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 530   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 531   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 532       CACHE PATH "Path to ${name} source directory")
 533   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 534       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 535     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 536            "Whether to build ${name} as part of LLVM" ON)
 537     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 538       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 539     endif()
 540   endif()
 541 endmacro(add_llvm_external_project)
 542
 543 macro(add_llvm_tool_subdirectory name)
 544   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 545   add_subdirectory(${name})
 546 endmacro(add_llvm_tool_subdirectory)
 547
 548 macro(ignore_llvm_tool_subdirectory name)
 549   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 550 endmacro(ignore_llvm_tool_subdirectory)
 551
 552 function(add_llvm_implicit_external_projects)
 553   set(list_of_implicit_subdirs "")
 554   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 555   foreach(dir ${sub-dirs})
 556     if(IS_DIRECTORY "${dir}")
 557       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 558       if( tool_subdir_ignore EQUAL -1
 559           AND EXISTS "${dir}/CMakeLists.txt")
 560         get_filename_component(fn "${dir}" NAME)
 561         list(APPEND list_of_implicit_subdirs "${fn}")
 562       endif()
 563     endif()
 564   endforeach()
 565
 566   foreach(external_proj ${list_of_implicit_subdirs})
 567     add_llvm_external_project("${external_proj}")
 568   endforeach()
 569 endfunction(add_llvm_implicit_external_projects)
 570
 571 # Generic support for adding a unittest.
 572 function(add_unittest test_suite test_name)
 573   if( NOT LLVM_BUILD_TESTS )
 574     set(EXCLUDE_FROM_ALL ON)
 575   endif()
 576
 577   # Visual Studio 2012 only supports up to 8 template parameters in
 578   # std::tr1::tuple by default, but gtest requires 10
 579   if (MSVC AND MSVC_VERSION EQUAL 1700)
 580     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 581   endif ()
 582
 583   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 584   if (NOT LLVM_ENABLE_THREADS)
 585     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 586   endif ()
 587
 588   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 589     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 590   endif ()
 591
 592   set(LLVM_REQUIRES_RTTI OFF)
 593
 594   add_llvm_executable(${test_name} ${ARGN})
 595   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 596   set_output_directory(${test_name} ${outdir} ${outdir})
 597   target_link_libraries(${test_name}
 598     gtest
 599     gtest_main
 600     LLVMSupport # gtest needs it for raw_ostream.
 601     )
 602
 603   add_dependencies(${test_suite} ${test_name})
 604   get_target_property(test_suite_folder ${test_suite} FOLDER)
 605   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 606     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 607   endif ()
 608 endfunction()
 609
 610 # This function provides an automatic way to 'configure'-like generate a file
 611 # based on a set of common and custom variables, specifically targeting the
 612 # variables needed for the 'lit.site.cfg' files. This function bundles the
 613 # common variables that any Lit instance is likely to need, and custom
 614 # variables can be passed in.
 615 function(configure_lit_site_cfg input output)
 616   foreach(c ${LLVM_TARGETS_TO_BUILD})
 617     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 618   endforeach(c)
 619   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 620
 621   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 622
 623   # Configuration-time: See Unit/lit.site.cfg.in
 624   if (CMAKE_CFG_INTDIR STREQUAL ".")
 625     set(LLVM_BUILD_MODE ".")
 626   else ()
 627     set(LLVM_BUILD_MODE "%(build_mode)s")
 628   endif ()
 629
 630   # They below might not be the build tree but provided binary tree.
 631   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 632   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 633   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 634   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 635
 636   # SHLIBDIR points the build tree.
 637   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 638
 639   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 640   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 641   # plugins. We may rename it.
 642   if(LLVM_ENABLE_PLUGINS)
 643     set(ENABLE_SHARED "1")
 644   else()
 645     set(ENABLE_SHARED "0")
 646   endif()
 647
 648   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 649     set(ENABLE_ASSERTIONS "1")
 650   else()
 651     set(ENABLE_ASSERTIONS "0")
 652   endif()
 653
 654   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 655   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 656
 657   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 658   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 659
 660   configure_file(${input} ${output} @ONLY)
 661 endfunction()
 662
 663 # A raw function to create a lit target. This is used to implement the testuite
 664 # management functions.
 665 function(add_lit_target target comment)
 666   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 667   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 668   separate_arguments(LIT_ARGS)
 669   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 670     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 671   endif ()
 672   if (LLVM_MAIN_SRC_DIR)
 673     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 674   else()
 675     find_program(LIT_COMMAND llvm-lit)
 676   endif ()
 677   list(APPEND LIT_COMMAND ${LIT_ARGS})
 678   foreach(param ${ARG_PARAMS})
 679     list(APPEND LIT_COMMAND --param ${param})
 680   endforeach()
 681   if( ARG_DEPENDS )
 682     add_custom_target(${target}
 683       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 684       COMMENT "${comment}"
 685       )
 686     add_dependencies(${target} ${ARG_DEPENDS})
 687   else()
 688     add_custom_target(${target}
 689       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 690     message(STATUS "${target} does nothing.")
 691   endif()
 692
 693   # Tests should be excluded from "Build Solution".
 694   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 695 endfunction()
 696
 697 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 698 function(add_lit_testsuite target comment)
 699   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 700
 701   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 702   if(NOT EXCLUDE_FROM_ALL)
 703     # Register the testsuites, params and depends for the global check rule.
 704     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 705     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 706     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 707     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 708   endif()
 709
 710   # Produce a specific suffixed check rule.
 711   add_lit_target(${target} ${comment}
 712     ${ARG_DEFAULT_ARGS}
 713     PARAMS ${ARG_PARAMS}
 714     DEPENDS ${ARG_DEPENDS}
 715     ARGS ${ARG_ARGS}
 716     )
 717 endfunction()