cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3 include(DetermineGCCCompatible)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   set(LLVM_CONFIG_HAS_RTTI YES CACHE INTERNAL "")
  30   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  31     set(LLVM_CONFIG_HAS_RTTI NO CACHE INTERNAL "")
  32     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  33     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  34       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  35     elseif (MSVC)
  36       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  37     endif ()
  38   endif()
  39
  40   # Assume that;
  41   #   - LLVM_COMPILE_FLAGS is list.
  42   #   - PROPERTY COMPILE_FLAGS is string.
  43   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  44
  45   if(update_src_props)
  46     foreach(fn ${sources})
  47       get_filename_component(suf ${fn} EXT)
  48       if("${suf}" STREQUAL ".cpp")
  49         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  50           COMPILE_FLAGS "${target_compile_flags}")
  51       endif()
  52     endforeach()
  53   else()
  54     # Update target props, since all sources are C++.
  55     set_property(TARGET ${name} APPEND_STRING PROPERTY
  56       COMPILE_FLAGS "${target_compile_flags}")
  57   endif()
  58
  59   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  60 endfunction()
  61
  62 function(add_llvm_symbol_exports target_name export_file)
  63   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  64     set(native_export_file "${target_name}.exports")
  65     add_custom_command(OUTPUT ${native_export_file}
  66       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  67       DEPENDS ${export_file}
  68       VERBATIM
  69       COMMENT "Creating export file for ${target_name}")
  70     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  71                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  72   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  73     # Gold and BFD ld require a version script rather than a plain list.
  74     set(native_export_file "${target_name}.exports")
  75     # FIXME: Don't write the "local:" line on OpenBSD.
  76     add_custom_command(OUTPUT ${native_export_file}
  77       COMMAND echo "{" > ${native_export_file}
  78       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  79       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  80       COMMAND echo "  local: *;" >> ${native_export_file}
  81       COMMAND echo "};" >> ${native_export_file}
  82       DEPENDS ${export_file}
  83       VERBATIM
  84       COMMENT "Creating export file for ${target_name}")
  85     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  86       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  87                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  88     else()
  89       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  90                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  91     endif()
  92   else()
  93     set(native_export_file "${target_name}.def")
  94
  95     add_custom_command(OUTPUT ${native_export_file}
  96       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
  97         < ${export_file} > ${native_export_file}
  98       DEPENDS ${export_file}
  99       VERBATIM
 100       COMMENT "Creating export file for ${target_name}")
 101     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 102     if(MSVC)
 103       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 104     endif()
 105     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 106                  LINK_FLAGS " ${export_file_linker_flag}")
 107   endif()
 108
 109   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 110   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 111
 112   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 113   foreach(src ${srcs})
 114     get_filename_component(extension ${src} EXT)
 115     if(extension STREQUAL ".cpp")
 116       set(first_source_file ${src})
 117       break()
 118     endif()
 119   endforeach()
 120
 121   # Force re-linking when the exports file changes. Actually, it
 122   # forces recompilation of the source file. The LINK_DEPENDS target
 123   # property only works for makefile-based generators.
 124   # FIXME: This is not safe because this will create the same target
 125   # ${native_export_file} in several different file:
 126   # - One where we emitted ${target_name}_exports
 127   # - One where we emitted the build command for the following object.
 128   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 129   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 130
 131   set_property(DIRECTORY APPEND
 132     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 133
 134   add_dependencies(${target_name} ${target_name}_exports)
 135
 136   # Add dependency to *_exports later -- CMake issue 14747
 137   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 138   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 139 endfunction(add_llvm_symbol_exports)
 140
 141 if(NOT WIN32 AND NOT APPLE)
 142   execute_process(
 143     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 144     OUTPUT_VARIABLE stdout
 145     ERROR_QUIET
 146     )
 147   if("${stdout}" MATCHES "GNU gold")
 148     set(LLVM_LINKER_IS_GOLD ON)
 149   endif()
 150 endif()
 151
 152 function(add_link_opts target_name)
 153   # Don't use linker optimizations in debug builds since it slows down the
 154   # linker in a context where the optimizations are not important.
 155   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 156
 157     # Pass -O3 to the linker. This enabled different optimizations on different
 158     # linkers.
 159     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 160       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 161                    LINK_FLAGS " -Wl,-O3")
 162     endif()
 163
 164     if(LLVM_LINKER_IS_GOLD)
 165       # With gold gc-sections is always safe.
 166       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 167                    LINK_FLAGS " -Wl,--gc-sections")
 168       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 169       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 170     endif()
 171
 172     if(NOT LLVM_NO_DEAD_STRIP)
 173       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 174         # ld64's implementation of -dead_strip breaks tools that use plugins.
 175         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 176                      LINK_FLAGS " -Wl,-dead_strip")
 177       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 178         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 179                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 180       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 181         # Object files are compiled with -ffunction-data-sections.
 182         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 183         # tools that use plugins. Always pass --gc-sections once we require
 184         # a newer linker.
 185         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 186                      LINK_FLAGS " -Wl,--gc-sections")
 187       endif()
 188     endif()
 189   endif()
 190 endfunction(add_link_opts)
 191
 192 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 193 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 194 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 195 function(set_output_directory target)
 196   cmake_parse_arguments(ARG "" "BINARY_DIR;LIBRARY_DIR" "" ${ARGN})
 197
 198   # module_dir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 199   # It affects output of add_library(MODULE).
 200   if(WIN32 OR CYGWIN)
 201     # DLL platform
 202     set(module_dir ${ARG_BINARY_DIR})
 203   else()
 204     set(module_dir ${ARG_LIBRARY_DIR})
 205   endif()
 206   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 207     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 208       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 209       if(ARG_BINARY_DIR)
 210         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${ARG_BINARY_DIR})
 211         set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 212       endif()
 213       if(ARG_LIBRARY_DIR)
 214         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${ARG_LIBRARY_DIR})
 215         set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 216       endif()
 217       if(module_dir)
 218         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${module_dir})
 219         set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 220       endif()
 221     endforeach()
 222   else()
 223     if(ARG_BINARY_DIR)
 224       set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${ARG_BINARY_DIR})
 225     endif()
 226     if(ARG_LIBRARY_DIR)
 227       set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${ARG_LIBRARY_DIR})
 228     endif()
 229     if(module_dir)
 230       set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${module_dir})
 231     endif()
 232   endif()
 233 endfunction()
 234
 235 # If on Windows and building with MSVC, add the resource script containing the
 236 # VERSIONINFO data to the project.  This embeds version resource information
 237 # into the output .exe or .dll.
 238 # TODO: Enable for MinGW Windows builds too.
 239 #
 240 function(add_windows_version_resource_file OUT_VAR)
 241   set(sources ${ARGN})
 242   if (MSVC)
 243     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 244     if(EXISTS ${resource_file})
 245       set(sources ${sources} ${resource_file})
 246       source_group("Resource Files" ${resource_file})
 247       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 248     endif()
 249   endif(MSVC)
 250
 251   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 252 endfunction(add_windows_version_resource_file)
 253
 254 # set_windows_version_resource_properties(name resource_file...
 255 #   VERSION_MAJOR int
 256 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 257 #   VERSION_MINOR int
 258 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 259 #   VERSION_PATCHLEVEL int
 260 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 261 #   VERSION_STRING
 262 #     Optional version string (defaults to PACKAGE_VERSION)
 263 #   PRODUCT_NAME
 264 #     Optional product name string (defaults to "LLVM")
 265 #   )
 266 function(set_windows_version_resource_properties name resource_file)
 267   cmake_parse_arguments(ARG
 268     ""
 269     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 270     ""
 271     ${ARGN})
 272
 273   if (NOT DEFINED ARG_VERSION_MAJOR)
 274     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_MINOR)
 278     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 279   endif()
 280
 281   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 282     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 283   endif()
 284
 285   if (NOT DEFINED ARG_VERSION_STRING)
 286     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 287   endif()
 288
 289   if (NOT DEFINED ARG_PRODUCT_NAME)
 290     set(ARG_PRODUCT_NAME "LLVM")
 291   endif()
 292
 293   set_property(SOURCE ${resource_file}
 294                PROPERTY COMPILE_FLAGS /nologo)
 295   set_property(SOURCE ${resource_file}
 296                PROPERTY COMPILE_DEFINITIONS
 297                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 298                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 299                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 300                "RC_VERSION_FIELD_4=0"
 301                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 302                "RC_INTERNAL_NAME=\"${name}\""
 303                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 304                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 305 endfunction(set_windows_version_resource_properties)
 306
 307 # llvm_add_library(name sources...
 308 #   SHARED;STATIC
 309 #     STATIC by default w/o BUILD_SHARED_LIBS.
 310 #     SHARED by default w/  BUILD_SHARED_LIBS.
 311 #   MODULE
 312 #     Target ${name} might not be created on unsupported platforms.
 313 #     Check with "if(TARGET ${name})".
 314 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 315 #     Do not link this library to libLLVM, even if
 316 #     LLVM_LINK_LLVM_DYLIB is enabled.
 317 #   OUTPUT_NAME name
 318 #     Corresponds to OUTPUT_NAME in target properties.
 319 #   DEPENDS targets...
 320 #     Same semantics as add_dependencies().
 321 #   LINK_COMPONENTS components...
 322 #     Same as the variable LLVM_LINK_COMPONENTS.
 323 #   LINK_LIBS lib_targets...
 324 #     Same semantics as target_link_libraries().
 325 #   ADDITIONAL_HEADERS
 326 #     May specify header files for IDE generators.
 327 #   SONAME
 328 #     Should set SONAME link flags and create symlinks
 329 #   )
 330 function(llvm_add_library name)
 331   cmake_parse_arguments(ARG
 332     "MODULE;SHARED;STATIC;DISABLE_LLVM_LINK_LLVM_DYLIB;SONAME"
 333     "OUTPUT_NAME"
 334     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 335     ${ARGN})
 336   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 337   if(ARG_ADDITIONAL_HEADERS)
 338     # Pass through ADDITIONAL_HEADERS.
 339     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 340   endif()
 341   if(ARG_OBJLIBS)
 342     set(ALL_FILES ${ARG_OBJLIBS})
 343   else()
 344     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 345   endif()
 346
 347   if(ARG_MODULE)
 348     if(ARG_SHARED OR ARG_STATIC)
 349       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 350     endif()
 351     if(NOT LLVM_ENABLE_PLUGINS)
 352       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 353       return()
 354     endif()
 355   else()
 356     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 357       set(ARG_SHARED TRUE)
 358     endif()
 359     if(NOT ARG_SHARED)
 360       set(ARG_STATIC TRUE)
 361     endif()
 362   endif()
 363
 364   # Generate objlib
 365   if(ARG_SHARED AND ARG_STATIC)
 366     # Generate an obj library for both targets.
 367     set(obj_name "obj.${name}")
 368     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 369       ${ALL_FILES}
 370       )
 371     llvm_update_compile_flags(${obj_name})
 372     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 373
 374     # Do add_dependencies(obj) later due to CMake issue 14747.
 375     list(APPEND objlibs ${obj_name})
 376
 377     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 378   endif()
 379
 380   if(ARG_SHARED AND ARG_STATIC)
 381     # static
 382     set(name_static "${name}_static")
 383     if(ARG_OUTPUT_NAME)
 384       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 385     endif()
 386     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 387     llvm_add_library(${name_static} STATIC
 388       ${output_name}
 389       OBJLIBS ${ALL_FILES} # objlib
 390       LINK_LIBS ${ARG_LINK_LIBS}
 391       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 392       )
 393     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 394     set(ARG_STATIC)
 395   endif()
 396
 397   if(ARG_MODULE)
 398     add_library(${name} MODULE ${ALL_FILES})
 399   elseif(ARG_SHARED)
 400     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 401     add_library(${name} SHARED ${ALL_FILES})
 402   else()
 403     add_library(${name} STATIC ${ALL_FILES})
 404   endif()
 405
 406   if(DEFINED windows_resource_file)
 407     set_windows_version_resource_properties(${name} ${windows_resource_file})
 408     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 409   endif()
 410
 411   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 412   # $<TARGET_OBJECTS> doesn't require compile flags.
 413   if(NOT obj_name)
 414     llvm_update_compile_flags(${name})
 415   endif()
 416   add_link_opts( ${name} )
 417   if(ARG_OUTPUT_NAME)
 418     set_target_properties(${name}
 419       PROPERTIES
 420       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 421       )
 422   endif()
 423
 424   if(ARG_MODULE)
 425     set_target_properties(${name} PROPERTIES
 426       PREFIX ""
 427       SUFFIX ${LLVM_PLUGIN_EXT}
 428       )
 429   endif()
 430
 431   if(ARG_SHARED)
 432     if(WIN32)
 433       set_target_properties(${name} PROPERTIES
 434         PREFIX ""
 435         )
 436     endif()
 437   endif()
 438
 439   if(ARG_MODULE OR ARG_SHARED)
 440     # Do not add -Dname_EXPORTS to the command-line when building files in this
 441     # target. Doing so is actively harmful for the modules build because it
 442     # creates extra module variants, and not useful because we don't use these
 443     # macros.
 444     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 445
 446     if (LLVM_EXPORTED_SYMBOL_FILE)
 447       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 448     endif()
 449   endif()
 450
 451   if(ARG_SHARED AND UNIX)
 452     if(NOT APPLE AND ARG_SONAME)
 453       get_target_property(output_name ${name} OUTPUT_NAME)
 454       if(${output_name} STREQUAL "output_name-NOTFOUND")
 455         set(output_name ${name})
 456       endif()
 457       set(library_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}${LLVM_VERSION_SUFFIX})
 458       set(api_name ${output_name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 459       set_target_properties(${name} PROPERTIES OUTPUT_NAME ${library_name})
 460       llvm_install_library_symlink(${api_name} ${library_name} SHARED
 461         COMPONENT ${name}
 462         ALWAYS_GENERATE)
 463       llvm_install_library_symlink(${output_name} ${library_name} SHARED
 464         COMPONENT ${name}
 465         ALWAYS_GENERATE)
 466     endif()
 467   endif()
 468
 469   # Add the explicit dependency information for this library.
 470   #
 471   # It would be nice to verify that we have the dependencies for this library
 472   # name, but using get_property(... SET) doesn't suffice to determine if a
 473   # property has been set to an empty value.
 474   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 475
 476   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_STATIC AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 477     set(llvm_libs LLVM)
 478   else()
 479     llvm_map_components_to_libnames(llvm_libs
 480       ${ARG_LINK_COMPONENTS}
 481       ${LLVM_LINK_COMPONENTS}
 482       )
 483   endif()
 484
 485   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 486     # Link libs w/o keywords, assuming PUBLIC.
 487     target_link_libraries(${name}
 488       ${ARG_LINK_LIBS}
 489       ${lib_deps}
 490       ${llvm_libs}
 491       )
 492   elseif(ARG_STATIC)
 493     target_link_libraries(${name} INTERFACE
 494       ${ARG_LINK_LIBS}
 495       ${lib_deps}
 496       ${llvm_libs}
 497       )
 498   else()
 499     # We can use PRIVATE since SO knows its dependent libs.
 500     target_link_libraries(${name} PRIVATE
 501       ${ARG_LINK_LIBS}
 502       ${lib_deps}
 503       ${llvm_libs}
 504       )
 505   endif()
 506
 507   if(LLVM_COMMON_DEPENDS)
 508     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 509     # Add dependencies also to objlibs.
 510     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 511     foreach(objlib ${objlibs})
 512       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 513     endforeach()
 514   endif()
 515
 516   if(ARG_SHARED OR ARG_MODULE)
 517     llvm_externalize_debuginfo(${name})
 518   endif()
 519 endfunction()
 520
 521 macro(add_llvm_library name)
 522   cmake_parse_arguments(ARG
 523     "SHARED"
 524     ""
 525     ""
 526     ${ARGN})
 527   if( BUILD_SHARED_LIBS )
 528     llvm_add_library(${name} SHARED ${ARGN})
 529   else()
 530     llvm_add_library(${name} ${ARGN})
 531   endif()
 532   # The gtest libraries should not be installed or exported as a target
 533   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 534     set(_is_gtest TRUE)
 535   else()
 536     set(_is_gtest FALSE)
 537     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 538   endif()
 539
 540   if( EXCLUDE_FROM_ALL )
 541     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 542   elseif(NOT _is_gtest)
 543     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 544       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 545         if(WIN32 OR CYGWIN)
 546           set(install_type RUNTIME)
 547         else()
 548           set(install_type LIBRARY)
 549         endif()
 550       else()
 551         set(install_type ARCHIVE)
 552       endif()
 553
 554       install(TARGETS ${name}
 555             EXPORT LLVMExports
 556             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 557             COMPONENT ${name})
 558
 559       if (NOT CMAKE_CONFIGURATION_TYPES)
 560         add_custom_target(install-${name}
 561                           DEPENDS ${name}
 562                           COMMAND "${CMAKE_COMMAND}"
 563                                   -DCMAKE_INSTALL_COMPONENT=${name}
 564                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 565       endif()
 566     endif()
 567     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 568   endif()
 569   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 570 endmacro(add_llvm_library name)
 571
 572 macro(add_llvm_loadable_module name)
 573   llvm_add_library(${name} MODULE ${ARGN})
 574   if(NOT TARGET ${name})
 575     # Add empty "phony" target
 576     add_custom_target(${name})
 577   else()
 578     if( EXCLUDE_FROM_ALL )
 579       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 580     else()
 581       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 582         if(WIN32 OR CYGWIN)
 583           # DLL platform
 584           set(dlldir "bin")
 585         else()
 586           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 587         endif()
 588         install(TARGETS ${name}
 589           EXPORT LLVMExports
 590           LIBRARY DESTINATION ${dlldir}
 591           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 592       endif()
 593       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 594     endif()
 595   endif()
 596
 597   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 598 endmacro(add_llvm_loadable_module name)
 599
 600
 601 macro(add_llvm_executable name)
 602   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB;IGNORE_EXTERNALIZE_DEBUGINFO" "" "" ${ARGN})
 603   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 604
 605   # Generate objlib
 606   if(LLVM_ENABLE_OBJLIB)
 607     # Generate an obj library for both targets.
 608     set(obj_name "obj.${name}")
 609     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 610       ${ALL_FILES}
 611       )
 612     llvm_update_compile_flags(${obj_name})
 613     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 614
 615     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 616   endif()
 617
 618   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 619
 620   if(XCODE)
 621     # Note: the dummy.cpp source file provides no definitions. However,
 622     # it forces Xcode to properly link the static library.
 623     list(APPEND ALL_FILES "${LLVM_MAIN_SRC_DIR}/cmake/dummy.cpp")
 624   endif()
 625
 626   if( EXCLUDE_FROM_ALL )
 627     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 628   else()
 629     add_executable(${name} ${ALL_FILES})
 630   endif()
 631
 632   if(DEFINED windows_resource_file)
 633     set_windows_version_resource_properties(${name} ${windows_resource_file})
 634   endif()
 635
 636   # $<TARGET_OBJECTS> doesn't require compile flags.
 637   if(NOT LLVM_ENABLE_OBJLIB)
 638     llvm_update_compile_flags(${name})
 639   endif()
 640   add_link_opts( ${name} )
 641
 642   # Do not add -Dname_EXPORTS to the command-line when building files in this
 643   # target. Doing so is actively harmful for the modules build because it
 644   # creates extra module variants, and not useful because we don't use these
 645   # macros.
 646   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 647
 648   if (LLVM_EXPORTED_SYMBOL_FILE)
 649     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 650   endif(LLVM_EXPORTED_SYMBOL_FILE)
 651
 652   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 653     set(USE_SHARED USE_SHARED)
 654   endif()
 655
 656   set(EXCLUDE_FROM_ALL OFF)
 657   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 658   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 659   if( LLVM_COMMON_DEPENDS )
 660     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 661   endif( LLVM_COMMON_DEPENDS )
 662
 663   if(NOT ARG_IGNORE_EXTERNALIZE_DEBUGINFO)
 664     llvm_externalize_debuginfo(${name})
 665   endif()
 666 endmacro(add_llvm_executable name)
 667
 668 function(export_executable_symbols target)
 669   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 670     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 671     if (APPLE)
 672       set_property(TARGET ${target} APPEND_STRING PROPERTY
 673         LINK_FLAGS " -rdynamic")
 674     endif()
 675   endif()
 676 endfunction()
 677
 678 if(NOT LLVM_TOOLCHAIN_TOOLS)
 679   set (LLVM_TOOLCHAIN_TOOLS
 680     llvm-ar
 681     llvm-ranlib
 682     llvm-lib
 683     llvm-objdump
 684     )
 685 endif()
 686
 687 macro(add_llvm_tool name)
 688   if( NOT LLVM_BUILD_TOOLS )
 689     set(EXCLUDE_FROM_ALL ON)
 690   endif()
 691   add_llvm_executable(${name} ${ARGN})
 692
 693   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 694   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 695     if( LLVM_BUILD_TOOLS )
 696       install(TARGETS ${name}
 697               EXPORT LLVMExports
 698               RUNTIME DESTINATION bin
 699               COMPONENT ${name})
 700
 701       if (NOT CMAKE_CONFIGURATION_TYPES)
 702         add_custom_target(install-${name}
 703                           DEPENDS ${name}
 704                           COMMAND "${CMAKE_COMMAND}"
 705                                   -DCMAKE_INSTALL_COMPONENT=${name}
 706                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 707       endif()
 708     endif()
 709   endif()
 710   if( LLVM_BUILD_TOOLS )
 711     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 712   endif()
 713   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 714 endmacro(add_llvm_tool name)
 715
 716
 717 macro(add_llvm_example name)
 718   if( NOT LLVM_BUILD_EXAMPLES )
 719     set(EXCLUDE_FROM_ALL ON)
 720   endif()
 721   add_llvm_executable(${name} ${ARGN})
 722   if( LLVM_BUILD_EXAMPLES )
 723     install(TARGETS ${name} RUNTIME DESTINATION examples)
 724   endif()
 725   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 726 endmacro(add_llvm_example name)
 727
 728
 729 macro(add_llvm_utility name)
 730   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 731   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 732   if( LLVM_INSTALL_UTILS )
 733     install (TARGETS ${name}
 734       RUNTIME DESTINATION bin
 735       COMPONENT ${name})
 736     if (NOT CMAKE_CONFIGURATION_TYPES)
 737       add_custom_target(install-${name}
 738                         DEPENDS ${name}
 739                         COMMAND "${CMAKE_COMMAND}"
 740                                 -DCMAKE_INSTALL_COMPONENT=${name}
 741                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 742     endif()
 743   endif()
 744 endmacro(add_llvm_utility name)
 745
 746
 747 macro(add_llvm_target target_name)
 748   include_directories(BEFORE
 749     ${CMAKE_CURRENT_BINARY_DIR}
 750     ${CMAKE_CURRENT_SOURCE_DIR})
 751   add_llvm_library(LLVM${target_name} ${ARGN})
 752   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 753 endmacro(add_llvm_target)
 754
 755 function(canonicalize_tool_name name output)
 756   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 757   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 758   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 759   set(${output} "${nameUPPER}" PARENT_SCOPE)
 760 endfunction(canonicalize_tool_name)
 761
 762 # Custom add_subdirectory wrapper
 763 # Takes in a project name (i.e. LLVM), the the subdirectory name, and an
 764 # and an optional path if it differs from the name.
 765 macro(add_llvm_subdirectory project type name)
 766   set(add_llvm_external_dir "${ARGN}")
 767   if("${add_llvm_external_dir}" STREQUAL "")
 768     set(add_llvm_external_dir ${name})
 769   endif()
 770   canonicalize_tool_name(${name} nameUPPER)
 771   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 772     # Treat it as in-tree subproject.
 773     option(${project}_${type}_${nameUPPER}_BUILD
 774            "Whether to build ${name} as part of ${project}" On)
 775     mark_as_advanced(${project}_${type}_${name}_BUILD)
 776     if(${project}_${type}_${nameUPPER}_BUILD)
 777       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 778       # Don't process it in add_llvm_implicit_projects().
 779       set(${project}_${type}_${nameUPPER}_BUILD OFF)
 780     endif()
 781   else()
 782     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 783       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 784       CACHE PATH "Path to ${name} source directory")
 785     set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT ON)
 786     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 787       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 788     endif()
 789     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 790       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 791     endif()
 792     option(${project}_${type}_${nameUPPER}_BUILD
 793       "Whether to build ${name} as part of LLVM"
 794       ${${project}_${type}_${nameUPPER}_BUILD_DEFAULT})
 795     if (${project}_${type}_${nameUPPER}_BUILD)
 796       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 797         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 798       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 799         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 800       endif()
 801       # FIXME: It'd be redundant.
 802       set(${project}_${type}_${nameUPPER}_BUILD Off)
 803     endif()
 804   endif()
 805 endmacro()
 806
 807 # Add external project that may want to be built as part of llvm such as Clang,
 808 # lld, and Polly. This adds two options. One for the source directory of the
 809 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 810 # enable or disable building it with everything else.
 811 # Additional parameter can be specified as the name of directory.
 812 macro(add_llvm_external_project name)
 813   add_llvm_subdirectory(LLVM TOOL ${name} ${ARGN})
 814 endmacro()
 815
 816 macro(add_llvm_tool_subdirectory name)
 817   add_llvm_external_project(${name})
 818 endmacro(add_llvm_tool_subdirectory)
 819
 820 function(get_project_name_from_src_var var output)
 821   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 822          MACHED_TOOL "${var}")
 823   if(MACHED_TOOL)
 824     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 825   else()
 826     set(${output} PARENT_SCOPE)
 827   endif()
 828 endfunction()
 829
 830 function(create_subdirectory_options project type)
 831   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 832   foreach(dir ${sub-dirs})
 833     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 834       canonicalize_tool_name(${dir} name)
 835       option(${project}_${type}_${name}_BUILD
 836            "Whether to build ${name} as part of ${project}" On)
 837       mark_as_advanced(${project}_${type}_${name}_BUILD)
 838     endif()
 839   endforeach()
 840 endfunction(create_subdirectory_options)
 841
 842 function(create_llvm_tool_options)
 843   create_subdirectory_options(LLVM TOOL)
 844 endfunction(create_llvm_tool_options)
 845
 846 function(add_llvm_implicit_projects)
 847   set(list_of_implicit_subdirs "")
 848   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 849   foreach(dir ${sub-dirs})
 850     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 851       canonicalize_tool_name(${dir} name)
 852       if (LLVM_TOOL_${name}_BUILD)
 853         get_filename_component(fn "${dir}" NAME)
 854         list(APPEND list_of_implicit_subdirs "${fn}")
 855       endif()
 856     endif()
 857   endforeach()
 858
 859   foreach(external_proj ${list_of_implicit_subdirs})
 860     add_llvm_external_project("${external_proj}")
 861   endforeach()
 862 endfunction(add_llvm_implicit_projects)
 863
 864 # Generic support for adding a unittest.
 865 function(add_unittest test_suite test_name)
 866   if( NOT LLVM_BUILD_TESTS )
 867     set(EXCLUDE_FROM_ALL ON)
 868   endif()
 869
 870   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 871   if (NOT LLVM_ENABLE_THREADS)
 872     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 873   endif ()
 874
 875   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 876     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 877   endif ()
 878
 879   set(LLVM_REQUIRES_RTTI OFF)
 880
 881   add_llvm_executable(${test_name} IGNORE_EXTERNALIZE_DEBUGINFO ${ARGN})
 882   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 883   set_output_directory(${test_name} BINARY_DIR ${outdir} LIBRARY_DIR ${outdir})
 884   target_link_libraries(${test_name}
 885     gtest
 886     gtest_main
 887     LLVMSupport # gtest needs it for raw_ostream.
 888     )
 889
 890   add_dependencies(${test_suite} ${test_name})
 891   get_target_property(test_suite_folder ${test_suite} FOLDER)
 892   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 893     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 894   endif ()
 895 endfunction()
 896
 897 function(llvm_add_go_executable binary pkgpath)
 898   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 899
 900   if(LLVM_BINDINGS MATCHES "go")
 901     # FIXME: This should depend only on the libraries Go needs.
 902     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 903     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 904     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 905     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 906     set(cppflags "")
 907     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 908     foreach(d ${include_dirs})
 909       set(cppflags "${cppflags} -I${d}")
 910     endforeach(d)
 911     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 912     if (LLVM_LINK_LLVM_DYLIB)
 913       set(linkmode "dylib")
 914     else()
 915       set(linkmode "component-libs")
 916     endif()
 917     add_custom_command(OUTPUT ${binpath}
 918       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "linkmode=${linkmode}"
 919               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 920       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 921               ${llvmlibs} ${ARG_DEPENDS}
 922       COMMENT "Building Go executable ${binary}"
 923       VERBATIM)
 924     if (ARG_ALL)
 925       add_custom_target(${binary} ALL DEPENDS ${binpath})
 926     else()
 927       add_custom_target(${binary} DEPENDS ${binpath})
 928     endif()
 929   endif()
 930 endfunction()
 931
 932 # This function provides an automatic way to 'configure'-like generate a file
 933 # based on a set of common and custom variables, specifically targeting the
 934 # variables needed for the 'lit.site.cfg' files. This function bundles the
 935 # common variables that any Lit instance is likely to need, and custom
 936 # variables can be passed in.
 937 function(configure_lit_site_cfg input output)
 938   foreach(c ${LLVM_TARGETS_TO_BUILD})
 939     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 940   endforeach(c)
 941   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 942
 943   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 944
 945   # Configuration-time: See Unit/lit.site.cfg.in
 946   if (CMAKE_CFG_INTDIR STREQUAL ".")
 947     set(LLVM_BUILD_MODE ".")
 948   else ()
 949     set(LLVM_BUILD_MODE "%(build_mode)s")
 950   endif ()
 951
 952   # They below might not be the build tree but provided binary tree.
 953   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 954   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 955   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 956   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 957
 958   # SHLIBDIR points the build tree.
 959   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 960
 961   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 962   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 963   # plugins. We may rename it.
 964   if(LLVM_ENABLE_PLUGINS)
 965     set(ENABLE_SHARED "1")
 966   else()
 967     set(ENABLE_SHARED "0")
 968   endif()
 969
 970   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 971     set(ENABLE_ASSERTIONS "1")
 972   else()
 973     set(ENABLE_ASSERTIONS "0")
 974   endif()
 975
 976   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 977   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 978
 979   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 980   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 981   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 982
 983   configure_file(${input} ${output} @ONLY)
 984 endfunction()
 985
 986 # A raw function to create a lit target. This is used to implement the testuite
 987 # management functions.
 988 function(add_lit_target target comment)
 989   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 990   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 991   separate_arguments(LIT_ARGS)
 992   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 993     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 994   endif ()
 995   if (LLVM_MAIN_SRC_DIR)
 996     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 997   else()
 998     find_program(LIT_COMMAND llvm-lit)
 999   endif ()
1000   list(APPEND LIT_COMMAND ${LIT_ARGS})
1001   foreach(param ${ARG_PARAMS})
1002     list(APPEND LIT_COMMAND --param ${param})
1003   endforeach()
1004   if (ARG_UNPARSED_ARGUMENTS)
1005     add_custom_target(${target}
1006       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
1007       COMMENT "${comment}"
1008       ${cmake_3_2_USES_TERMINAL}
1009       )
1010   else()
1011     add_custom_target(${target}
1012       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
1013     message(STATUS "${target} does nothing.")
1014   endif()
1015   if (ARG_DEPENDS)
1016     add_dependencies(${target} ${ARG_DEPENDS})
1017   endif()
1018
1019   # Tests should be excluded from "Build Solution".
1020   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
1021 endfunction()
1022
1023 # A function to add a set of lit test suites to be driven through 'check-*' targets.
1024 function(add_lit_testsuite target comment)
1025   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1026
1027   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
1028   if(NOT EXCLUDE_FROM_ALL)
1029     # Register the testsuites, params and depends for the global check rule.
1030     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
1031     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
1032     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
1033     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
1034   endif()
1035
1036   # Produce a specific suffixed check rule.
1037   add_lit_target(${target} ${comment}
1038     ${ARG_UNPARSED_ARGUMENTS}
1039     PARAMS ${ARG_PARAMS}
1040     DEPENDS ${ARG_DEPENDS}
1041     ARGS ${ARG_ARGS}
1042     )
1043 endfunction()
1044
1045 function(add_lit_testsuites project directory)
1046   if (NOT CMAKE_CONFIGURATION_TYPES)
1047     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1048     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
1049     set(lit_suites)
1050     foreach(f ${litCfg})
1051       get_filename_component(dir ${f} DIRECTORY)
1052       set(lit_suites ${lit_suites} ${dir})
1053     endforeach()
1054     list(REMOVE_DUPLICATES lit_suites)
1055     foreach(dir ${lit_suites})
1056       string(REPLACE ${directory} "" name_slash ${dir})
1057       if (name_slash)
1058         string(REPLACE "/" "-" name_slash ${name_slash})
1059         string(REPLACE "\\" "-" name_dashes ${name_slash})
1060         string(TOLOWER "${project}${name_dashes}" name_var)
1061         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
1062           ${dir}
1063           PARAMS ${ARG_PARAMS}
1064           DEPENDS ${ARG_DEPENDS}
1065           ARGS ${ARG_ARGS}
1066         )
1067       endif()
1068     endforeach()
1069   endif()
1070 endfunction()
1071
1072 function(llvm_install_library_symlink name dest type)
1073   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "COMPONENT" "" ${ARGN})
1074   foreach(path ${CMAKE_MODULE_PATH})
1075     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1076       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1077       break()
1078     endif()
1079   endforeach()
1080
1081   set(component ${ARG_COMPONENT})
1082   if(NOT component)
1083     set(component ${name})
1084   endif()
1085
1086   set(full_name ${CMAKE_${type}_LIBRARY_PREFIX}${name}${CMAKE_${type}_LIBRARY_SUFFIX})
1087   set(full_dest ${CMAKE_${type}_LIBRARY_PREFIX}${dest}${CMAKE_${type}_LIBRARY_SUFFIX})
1088
1089   set(output_dir lib${LLVM_LIBDIR_SUFFIX})
1090   if(WIN32 AND "${type}" STREQUAL "SHARED")
1091     set(output_dir bin)
1092   endif()
1093
1094   install(SCRIPT ${INSTALL_SYMLINK}
1095           CODE "install_symlink(${full_name} ${full_dest} ${output_dir})"
1096           COMPONENT ${component})
1097
1098   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1099     add_custom_target(install-${name}
1100                       DEPENDS ${name} ${dest} install-${dest}
1101                       COMMAND "${CMAKE_COMMAND}"
1102                               -DCMAKE_INSTALL_COMPONENT=${name}
1103                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1104   endif()
1105 endfunction()
1106
1107 function(llvm_install_symlink name dest)
1108   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1109   foreach(path ${CMAKE_MODULE_PATH})
1110     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1111       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1112       break()
1113     endif()
1114   endforeach()
1115
1116   if(ARG_ALWAYS_GENERATE)
1117     set(component ${dest})
1118   else()
1119     set(component ${name})
1120   endif()
1121
1122   set(full_name ${name}${CMAKE_EXECUTABLE_SUFFIX})
1123   set(full_dest ${dest}${CMAKE_EXECUTABLE_SUFFIX})
1124
1125   install(SCRIPT ${INSTALL_SYMLINK}
1126           CODE "install_symlink(${full_name} ${full_dest} bin)"
1127           COMPONENT ${component})
1128
1129   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1130     add_custom_target(install-${name}
1131                       DEPENDS ${name} ${dest} install-${dest}
1132                       COMMAND "${CMAKE_COMMAND}"
1133                               -DCMAKE_INSTALL_COMPONENT=${name}
1134                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1135   endif()
1136 endfunction()
1137
1138 function(add_llvm_tool_symlink name dest)
1139   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1140   if(UNIX)
1141     set(LLVM_LINK_OR_COPY create_symlink)
1142     set(dest_binary "${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1143   else()
1144     set(LLVM_LINK_OR_COPY copy)
1145     set(dest_binary "${LLVM_RUNTIME_OUTPUT_INTDIR}/${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1146   endif()
1147
1148   set(output_path "${LLVM_RUNTIME_OUTPUT_INTDIR}/${name}${CMAKE_EXECUTABLE_SUFFIX}")
1149
1150   if(ARG_ALWAYS_GENERATE)
1151     set_property(DIRECTORY APPEND PROPERTY
1152       ADDITIONAL_MAKE_CLEAN_FILES ${dest_binary})
1153     add_custom_command(TARGET ${dest} POST_BUILD
1154       COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}")
1155   else()
1156     add_custom_command(OUTPUT ${output_path}
1157                      COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}"
1158                      DEPENDS ${dest})
1159     add_custom_target(${name} ALL DEPENDS ${output_path})
1160     set_target_properties(${name} PROPERTIES FOLDER Tools)
1161
1162     # Make sure the parent tool is a toolchain tool, otherwise exclude this tool
1163     list(FIND LLVM_TOOLCHAIN_TOOLS ${dest} LLVM_IS_${dest}_TOOLCHAIN_TOOL)
1164     if (NOT LLVM_IS_${dest}_TOOLCHAIN_TOOL GREATER -1)
1165       set(LLVM_IS_${name}_TOOLCHAIN_TOOL ${LLVM_IS_${dest}_TOOLCHAIN_TOOL})
1166     else()
1167       list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
1168     endif()
1169
1170     # LLVM_IS_${name}_TOOLCHAIN_TOOL will only be greater than -1 if both this
1171     # tool and its parent tool are in LLVM_TOOLCHAIN_TOOLS
1172     if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1173       if( LLVM_BUILD_TOOLS )
1174         llvm_install_symlink(${name} ${dest})
1175       endif()
1176     endif()
1177   endif()
1178 endfunction()
1179
1180 function(llvm_externalize_debuginfo name)
1181   if(NOT LLVM_EXTERNALIZE_DEBUGINFO)
1182     return()
1183   endif()
1184
1185   if(APPLE)
1186     if(CMAKE_CXX_FLAGS MATCHES "-flto"
1187       OR CMAKE_CXX_FLAGS_${uppercase_CMAKE_BUILD_TYPE} MATCHES "-flto")
1188
1189       set(lto_object ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/${name}-lto.o)
1190       set_property(TARGET ${name} APPEND_STRING PROPERTY
1191         LINK_FLAGS " -Wl,-object_path_lto,${lto_object}")
1192     endif()
1193     add_custom_command(TARGET ${name} POST_BUILD
1194       COMMAND xcrun dsymutil $<TARGET_FILE:${name}>
1195       COMMAND xcrun strip -Sl $<TARGET_FILE:${name}>)
1196   else()
1197     message(FATAL_ERROR "LLVM_EXTERNALIZE_DEBUGINFO isn't implemented for non-darwin platforms!")
1198   endif()
1199 endfunction()