For llvm-objdump added support for printing Objc1 32-bit runtime meta data
[oota-llvm.git] / cmake / modules / AddLLVM.cmake
1 include(LLVMParseArguments)
2 include(LLVMProcessSources)
3 include(LLVM-Config)
4
5 function(llvm_update_compile_flags name)
6   get_property(sources TARGET ${name} PROPERTY SOURCES)
7   if("${sources}" MATCHES "\\.c(;|$)")
8     set(update_src_props ON)
9   endif()
10
11   # LLVM_REQUIRES_EH is an internal flag that individual
12   # targets can use to force EH
13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
16       set(LLVM_REQUIRES_RTTI ON)
17     endif()
18   else()
19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
21     elseif(MSVC)
22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
24     endif()
25     if (CLANG_CL)
26       # FIXME: Remove this once clang-cl supports SEH
27       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
28     endif()
29   endif()
30
31   # LLVM_REQUIRES_RTTI is an internal flag that individual
32   # targets can use to force RTTI
33   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
34     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
35     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
36       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
37     elseif (MSVC)
38       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
39     endif ()
40   endif()
41
42   # Assume that;
43   #   - LLVM_COMPILE_FLAGS is list.
44   #   - PROPERTY COMPILE_FLAGS is string.
45   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
46
47   if(update_src_props)
48     foreach(fn ${sources})
49       get_filename_component(suf ${fn} EXT)
50       if("${suf}" STREQUAL ".cpp")
51         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
52           COMPILE_FLAGS "${target_compile_flags}")
53       endif()
54     endforeach()
55   else()
56     # Update target props, since all sources are C++.
57     set_property(TARGET ${name} APPEND_STRING PROPERTY
58       COMPILE_FLAGS "${target_compile_flags}")
59   endif()
60
61   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
62 endfunction()
63
64 function(add_llvm_symbol_exports target_name export_file)
65   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
66     set(native_export_file "${target_name}.exports")
67     add_custom_command(OUTPUT ${native_export_file}
68       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
69       DEPENDS ${export_file}
70       VERBATIM
71       COMMENT "Creating export file for ${target_name}")
72     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
73                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
74   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
75     # Gold and BFD ld require a version script rather than a plain list.
76     set(native_export_file "${target_name}.exports")
77     # FIXME: Don't write the "local:" line on OpenBSD.
78     add_custom_command(OUTPUT ${native_export_file}
79       COMMAND echo "{" > ${native_export_file}
80       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
81       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
82       COMMAND echo "  local: *;" >> ${native_export_file}
83       COMMAND echo "};" >> ${native_export_file}
84       DEPENDS ${export_file}
85       VERBATIM
86       COMMENT "Creating export file for ${target_name}")
87     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
88                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
89   else()
90     set(native_export_file "${target_name}.def")
91
92     set(CAT "cat")
93     set(export_file_nativeslashes ${export_file})
94     if(WIN32 AND NOT CYGWIN)
95       set(CAT "type")
96       # Convert ${export_file} to native format (backslashes) for "type"
97       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
98       # path but a build-system specific format (see CMake bug
99       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
100       string(REPLACE / \\ export_file_nativeslashes ${export_file})
101     endif()
102
103     add_custom_command(OUTPUT ${native_export_file}
104       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
105       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
106       DEPENDS ${export_file}
107       VERBATIM
108       COMMENT "Creating export file for ${target_name}")
109     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
110     if(MSVC)
111       set(export_file_linker_flag "/DEF:${export_file_linker_flag}")
112     endif()
113     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
114                  LINK_FLAGS " ${export_file_linker_flag}")
115   endif()
116
117   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
118   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
119
120   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
121   foreach(src ${srcs})
122     get_filename_component(extension ${src} EXT)
123     if(extension STREQUAL ".cpp")
124       set(first_source_file ${src})
125       break()
126     endif()
127   endforeach()
128
129   # Force re-linking when the exports file changes. Actually, it
130   # forces recompilation of the source file. The LINK_DEPENDS target
131   # property only works for makefile-based generators.
132   # FIXME: This is not safe because this will create the same target
133   # ${native_export_file} in several different file:
134   # - One where we emitted ${target_name}_exports
135   # - One where we emitted the build command for the following object.
136   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
137   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
138
139   set_property(DIRECTORY APPEND
140     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
141
142   add_dependencies(${target_name} ${target_name}_exports)
143
144   # Add dependency to *_exports later -- CMake issue 14747
145   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
146   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
147 endfunction(add_llvm_symbol_exports)
148
149 if(NOT WIN32 AND NOT APPLE)
150   execute_process(
151     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
152     OUTPUT_VARIABLE stdout
153     ERROR_QUIET
154     )
155   if("${stdout}" MATCHES "GNU gold")
156     set(LLVM_LINKER_IS_GOLD ON)
157   endif()
158 endif()
159
160 function(add_link_opts target_name)
161   # Don't use linker optimizations in debug builds since it slows down the
162   # linker in a context where the optimizations are not important.
163   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
164
165     # Pass -O3 to the linker. This enabled different optimizations on different
166     # linkers.
167     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32))
168       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
169                    LINK_FLAGS " -Wl,-O3")
170     endif()
171
172     if(LLVM_LINKER_IS_GOLD)
173       # With gold gc-sections is always safe.
174       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
175                    LINK_FLAGS " -Wl,--gc-sections")
176       # Note that there is a bug with -Wl,--icf=safe so it is not safe
177       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
178     endif()
179
180     if(NOT LLVM_NO_DEAD_STRIP)
181       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
182         # ld64's implementation of -dead_strip breaks tools that use plugins.
183         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
184                      LINK_FLAGS " -Wl,-dead_strip")
185       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
186         # Object files are compiled with -ffunction-data-sections.
187         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
188         # tools that use plugins. Always pass --gc-sections once we require
189         # a newer linker.
190         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
191                      LINK_FLAGS " -Wl,--gc-sections")
192       endif()
193     endif()
194   endif()
195 endfunction(add_link_opts)
196
197 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
198 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
199 # or a certain builder, for eaxample, msbuild.exe, would be confused.
200 function(set_output_directory target bindir libdir)
201   # Do nothing if *_OUTPUT_INTDIR is empty.
202   if("${bindir}" STREQUAL "")
203     return()
204   endif()
205
206   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
207   # It affects output of add_library(MODULE).
208   if(WIN32 OR CYGWIN)
209     # DLL platform
210     set(moddir ${bindir})
211   else()
212     set(moddir ${libdir})
213   endif()
214   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
215     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
216       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
217       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
218       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
219       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
220       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
221       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
222       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
223     endforeach()
224   else()
225     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
226     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
227     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
228   endif()
229 endfunction()
230
231 # llvm_add_library(name sources...
232 #   SHARED;STATIC
233 #     STATIC by default w/o BUILD_SHARED_LIBS.
234 #     SHARED by default w/  BUILD_SHARED_LIBS.
235 #   MODULE
236 #     Target ${name} might not be created on unsupported platforms.
237 #     Check with "if(TARGET ${name})".
238 #   OUTPUT_NAME name
239 #     Corresponds to OUTPUT_NAME in target properties.
240 #   DEPENDS targets...
241 #     Same semantics as add_dependencies().
242 #   LINK_COMPONENTS components...
243 #     Same as the variable LLVM_LINK_COMPONENTS.
244 #   LINK_LIBS lib_targets...
245 #     Same semantics as target_link_libraries().
246 #   ADDITIONAL_HEADERS
247 #     May specify header files for IDE generators.
248 #   )
249 function(llvm_add_library name)
250   cmake_parse_arguments(ARG
251     "MODULE;SHARED;STATIC"
252     "OUTPUT_NAME"
253     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
254     ${ARGN})
255   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
256   if(ARG_ADDITIONAL_HEADERS)
257     # Pass through ADDITIONAL_HEADERS.
258     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
259   endif()
260   if(ARG_OBJLIBS)
261     set(ALL_FILES ${ARG_OBJLIBS})
262   else()
263     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
264   endif()
265
266   if(ARG_MODULE)
267     if(ARG_SHARED OR ARG_STATIC)
268       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
269     endif()
270     if(NOT LLVM_ENABLE_PLUGINS)
271       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
272       return()
273     endif()
274   else()
275     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
276       set(ARG_SHARED TRUE)
277     endif()
278     if(NOT ARG_SHARED)
279       set(ARG_STATIC TRUE)
280     endif()
281   endif()
282
283   # Generate objlib
284   if(ARG_SHARED AND ARG_STATIC)
285     # Generate an obj library for both targets.
286     set(obj_name "obj.${name}")
287     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
288       ${ALL_FILES}
289       )
290     llvm_update_compile_flags(${obj_name})
291     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
292
293     # Do add_dependencies(obj) later due to CMake issue 14747.
294     list(APPEND objlibs ${obj_name})
295
296     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
297   endif()
298
299   if(ARG_SHARED AND ARG_STATIC)
300     # static
301     set(name_static "${name}_static")
302     if(ARG_OUTPUT_NAME)
303       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
304     endif()
305     # DEPENDS has been appended to LLVM_COMMON_LIBS.
306     llvm_add_library(${name_static} STATIC
307       ${output_name}
308       OBJLIBS ${ALL_FILES} # objlib
309       LINK_LIBS ${ARG_LINK_LIBS}
310       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
311       )
312     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
313     set(ARG_STATIC)
314   endif()
315
316   if(ARG_MODULE)
317     add_library(${name} MODULE ${ALL_FILES})
318   elseif(ARG_SHARED)
319     add_library(${name} SHARED ${ALL_FILES})
320   else()
321     add_library(${name} STATIC ${ALL_FILES})
322   endif()
323   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
324   llvm_update_compile_flags(${name})
325   add_link_opts( ${name} )
326   if(ARG_OUTPUT_NAME)
327     set_target_properties(${name}
328       PROPERTIES
329       OUTPUT_NAME ${ARG_OUTPUT_NAME}
330       )
331   endif()
332
333   if(ARG_MODULE)
334     set_target_properties(${name} PROPERTIES
335       PREFIX ""
336       SUFFIX ${LLVM_PLUGIN_EXT}
337       )
338   endif()
339
340   if(ARG_SHARED)
341     if(WIN32)
342       set_target_properties(${name} PROPERTIES
343         PREFIX ""
344         )
345     endif()
346
347     set_target_properties(${name}
348       PROPERTIES
349       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
350       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
351   endif()
352
353   if(ARG_MODULE OR ARG_SHARED)
354     # Do not add -Dname_EXPORTS to the command-line when building files in this
355     # target. Doing so is actively harmful for the modules build because it
356     # creates extra module variants, and not useful because we don't use these
357     # macros.
358     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
359
360     if (LLVM_EXPORTED_SYMBOL_FILE)
361       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
362     endif()
363   endif()
364
365   # Add the explicit dependency information for this library.
366   #
367   # It would be nice to verify that we have the dependencies for this library
368   # name, but using get_property(... SET) doesn't suffice to determine if a
369   # property has been set to an empty value.
370   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
371
372   llvm_map_components_to_libnames(llvm_libs
373     ${ARG_LINK_COMPONENTS}
374     ${LLVM_LINK_COMPONENTS}
375     )
376
377   if(CMAKE_VERSION VERSION_LESS 2.8.12)
378     # Link libs w/o keywords, assuming PUBLIC.
379     target_link_libraries(${name}
380       ${ARG_LINK_LIBS}
381       ${lib_deps}
382       ${llvm_libs}
383       )
384   elseif(ARG_STATIC)
385     target_link_libraries(${name} INTERFACE
386       ${ARG_LINK_LIBS}
387       ${lib_deps}
388       ${llvm_libs}
389       )
390   else()
391     # We can use PRIVATE since SO knows its dependent libs.
392     target_link_libraries(${name} PRIVATE
393       ${ARG_LINK_LIBS}
394       ${lib_deps}
395       ${llvm_libs}
396       )
397   endif()
398
399   if(LLVM_COMMON_DEPENDS)
400     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
401     # Add dependencies also to objlibs.
402     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
403     foreach(objlib ${objlibs})
404       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
405     endforeach()
406   endif()
407 endfunction()
408
409 macro(add_llvm_library name)
410   cmake_parse_arguments(ARG
411     "SHARED"
412     ""
413     ""
414     ${ARGN})
415   if( BUILD_SHARED_LIBS )
416     llvm_add_library(${name} SHARED ${ARGN})
417   else()
418     llvm_add_library(${name} ${ARGN})
419   endif()
420   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
421
422   if( EXCLUDE_FROM_ALL )
423     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
424   else()
425     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
426       if(ARG_SHARED OR BUILD_SHARED_LIBS)
427         install(TARGETS ${name}
428           EXPORT LLVMExports
429           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
430           COMPONENT ${name})
431       else()
432         install(TARGETS ${name}
433           EXPORT LLVMExports
434           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX}
435           COMPONENT ${name})
436       endif()
437
438       if (NOT CMAKE_CONFIGURATION_TYPES)
439         add_custom_target(install-${name}
440                           DEPENDS ${name}
441                           COMMAND "${CMAKE_COMMAND}"
442                                   -DCMAKE_INSTALL_COMPONENT=${name}
443                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
444       endif()
445     endif()
446     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
447   endif()
448   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
449 endmacro(add_llvm_library name)
450
451 macro(add_llvm_loadable_module name)
452   llvm_add_library(${name} MODULE ${ARGN})
453   if(NOT TARGET ${name})
454     # Add empty "phony" target
455     add_custom_target(${name})
456   else()
457     if( EXCLUDE_FROM_ALL )
458       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
459     else()
460       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
461         if(WIN32 OR CYGWIN)
462           # DLL platform
463           set(dlldir "bin")
464         else()
465           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
466         endif()
467         install(TARGETS ${name}
468           EXPORT LLVMExports
469           LIBRARY DESTINATION ${dlldir}
470           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
471       endif()
472       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
473     endif()
474   endif()
475
476   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
477 endmacro(add_llvm_loadable_module name)
478
479
480 macro(add_llvm_executable name)
481   llvm_process_sources( ALL_FILES ${ARGN} )
482   if( EXCLUDE_FROM_ALL )
483     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
484   else()
485     add_executable(${name} ${ALL_FILES})
486   endif()
487   llvm_update_compile_flags(${name})
488   add_link_opts( ${name} )
489
490   # Do not add -Dname_EXPORTS to the command-line when building files in this
491   # target. Doing so is actively harmful for the modules build because it
492   # creates extra module variants, and not useful because we don't use these
493   # macros.
494   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
495
496   if (LLVM_EXPORTED_SYMBOL_FILE)
497     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
498   endif(LLVM_EXPORTED_SYMBOL_FILE)
499
500   set(EXCLUDE_FROM_ALL OFF)
501   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
502   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
503   if( LLVM_COMMON_DEPENDS )
504     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
505   endif( LLVM_COMMON_DEPENDS )
506 endmacro(add_llvm_executable name)
507
508 function(export_executable_symbols target)
509   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
510     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
511   endif()
512 endfunction()
513
514
515 set (LLVM_TOOLCHAIN_TOOLS
516   llvm-ar
517   llvm-objdump
518   )
519
520 macro(add_llvm_tool name)
521   if( NOT LLVM_BUILD_TOOLS )
522     set(EXCLUDE_FROM_ALL ON)
523   endif()
524   add_llvm_executable(${name} ${ARGN})
525
526   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
527   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
528     if( LLVM_BUILD_TOOLS )
529       install(TARGETS ${name}
530               EXPORT LLVMExports
531               RUNTIME DESTINATION bin
532               COMPONENT ${name})
533
534       if (NOT CMAKE_CONFIGURATION_TYPES)
535         add_custom_target(install-${name}
536                           DEPENDS ${name}
537                           COMMAND "${CMAKE_COMMAND}"
538                                   -DCMAKE_INSTALL_COMPONENT=${name}
539                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
540       endif()
541     endif()
542   endif()
543   if( LLVM_BUILD_TOOLS )
544     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
545   endif()
546   set_target_properties(${name} PROPERTIES FOLDER "Tools")
547 endmacro(add_llvm_tool name)
548
549
550 macro(add_llvm_example name)
551   if( NOT LLVM_BUILD_EXAMPLES )
552     set(EXCLUDE_FROM_ALL ON)
553   endif()
554   add_llvm_executable(${name} ${ARGN})
555   if( LLVM_BUILD_EXAMPLES )
556     install(TARGETS ${name} RUNTIME DESTINATION examples)
557   endif()
558   set_target_properties(${name} PROPERTIES FOLDER "Examples")
559 endmacro(add_llvm_example name)
560
561
562 macro(add_llvm_utility name)
563   add_llvm_executable(${name} ${ARGN})
564   set_target_properties(${name} PROPERTIES FOLDER "Utils")
565   if( LLVM_INSTALL_UTILS )
566     install (TARGETS ${name}
567       RUNTIME DESTINATION bin
568       COMPONENT ${name})
569     if (NOT CMAKE_CONFIGURATION_TYPES)
570       add_custom_target(install-${name}
571                         DEPENDS ${name}
572                         COMMAND "${CMAKE_COMMAND}"
573                                 -DCMAKE_INSTALL_COMPONENT=${name}
574                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
575     endif()
576   endif()
577 endmacro(add_llvm_utility name)
578
579
580 macro(add_llvm_target target_name)
581   include_directories(BEFORE
582     ${CMAKE_CURRENT_BINARY_DIR}
583     ${CMAKE_CURRENT_SOURCE_DIR})
584   add_llvm_library(LLVM${target_name} ${ARGN})
585   set( CURRENT_LLVM_TARGET LLVM${target_name} )
586 endmacro(add_llvm_target)
587
588 # Add external project that may want to be built as part of llvm such as Clang,
589 # lld, and Polly. This adds two options. One for the source directory of the
590 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
591 # enable or disable building it with everything else.
592 # Additional parameter can be specified as the name of directory.
593 macro(add_llvm_external_project name)
594   set(add_llvm_external_dir "${ARGN}")
595   if("${add_llvm_external_dir}" STREQUAL "")
596     set(add_llvm_external_dir ${name})
597   endif()
598   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
599   string(REPLACE "-" "_" nameUNDERSCORE ${name})
600   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
601   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
602       CACHE PATH "Path to ${name} source directory")
603   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
604       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
605     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
606            "Whether to build ${name} as part of LLVM" ON)
607     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
608       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
609     endif()
610   endif()
611 endmacro(add_llvm_external_project)
612
613 macro(add_llvm_tool_subdirectory name)
614   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
615   add_subdirectory(${name})
616 endmacro(add_llvm_tool_subdirectory)
617
618 macro(ignore_llvm_tool_subdirectory name)
619   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
620 endmacro(ignore_llvm_tool_subdirectory)
621
622 function(add_llvm_implicit_external_projects)
623   set(list_of_implicit_subdirs "")
624   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
625   foreach(dir ${sub-dirs})
626     if(IS_DIRECTORY "${dir}")
627       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
628       if( tool_subdir_ignore EQUAL -1
629           AND EXISTS "${dir}/CMakeLists.txt")
630         get_filename_component(fn "${dir}" NAME)
631         list(APPEND list_of_implicit_subdirs "${fn}")
632       endif()
633     endif()
634   endforeach()
635
636   foreach(external_proj ${list_of_implicit_subdirs})
637     add_llvm_external_project("${external_proj}")
638   endforeach()
639 endfunction(add_llvm_implicit_external_projects)
640
641 # Generic support for adding a unittest.
642 function(add_unittest test_suite test_name)
643   if( NOT LLVM_BUILD_TESTS )
644     set(EXCLUDE_FROM_ALL ON)
645   endif()
646
647   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
648   if (NOT LLVM_ENABLE_THREADS)
649     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
650   endif ()
651
652   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
653     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
654   endif ()
655
656   set(LLVM_REQUIRES_RTTI OFF)
657
658   add_llvm_executable(${test_name} ${ARGN})
659   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
660   set_output_directory(${test_name} ${outdir} ${outdir})
661   target_link_libraries(${test_name}
662     gtest
663     gtest_main
664     LLVMSupport # gtest needs it for raw_ostream.
665     )
666
667   add_dependencies(${test_suite} ${test_name})
668   get_target_property(test_suite_folder ${test_suite} FOLDER)
669   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
670     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
671   endif ()
672 endfunction()
673
674 function(llvm_add_go_executable binary pkgpath)
675   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
676
677   if(LLVM_BINDINGS MATCHES "go")
678     # FIXME: This should depend only on the libraries Go needs.
679     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
680     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
681     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
682     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
683     set(cppflags "")
684     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
685     foreach(d ${include_dirs})
686       set(cppflags "${cppflags} -I${d}")
687     endforeach(d)
688     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
689     add_custom_command(OUTPUT ${binpath}
690       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
691               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
692       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
693               ${llvmlibs} ${ARG_DEPENDS}
694       COMMENT "Building Go executable ${binary}"
695       VERBATIM)
696     if (ARG_ALL)
697       add_custom_target(${binary} ALL DEPENDS ${binpath})
698     else()
699       add_custom_target(${binary} DEPENDS ${binpath})
700     endif()
701   endif()
702 endfunction()
703
704 # This function provides an automatic way to 'configure'-like generate a file
705 # based on a set of common and custom variables, specifically targeting the
706 # variables needed for the 'lit.site.cfg' files. This function bundles the
707 # common variables that any Lit instance is likely to need, and custom
708 # variables can be passed in.
709 function(configure_lit_site_cfg input output)
710   foreach(c ${LLVM_TARGETS_TO_BUILD})
711     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
712   endforeach(c)
713   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
714
715   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
716
717   # Configuration-time: See Unit/lit.site.cfg.in
718   if (CMAKE_CFG_INTDIR STREQUAL ".")
719     set(LLVM_BUILD_MODE ".")
720   else ()
721     set(LLVM_BUILD_MODE "%(build_mode)s")
722   endif ()
723
724   # They below might not be the build tree but provided binary tree.
725   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
726   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
727   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
728   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
729
730   # SHLIBDIR points the build tree.
731   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
732
733   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
734   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
735   # plugins. We may rename it.
736   if(LLVM_ENABLE_PLUGINS)
737     set(ENABLE_SHARED "1")
738   else()
739     set(ENABLE_SHARED "0")
740   endif()
741
742   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
743     set(ENABLE_ASSERTIONS "1")
744   else()
745     set(ENABLE_ASSERTIONS "0")
746   endif()
747
748   set(HOST_OS ${CMAKE_SYSTEM_NAME})
749   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
750
751   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
752   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
753   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
754
755   configure_file(${input} ${output} @ONLY)
756 endfunction()
757
758 # A raw function to create a lit target. This is used to implement the testuite
759 # management functions.
760 function(add_lit_target target comment)
761   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
762   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
763   separate_arguments(LIT_ARGS)
764   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
765     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
766   endif ()
767   if (LLVM_MAIN_SRC_DIR)
768     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
769   else()
770     find_program(LIT_COMMAND llvm-lit)
771   endif ()
772   list(APPEND LIT_COMMAND ${LIT_ARGS})
773   foreach(param ${ARG_PARAMS})
774     list(APPEND LIT_COMMAND --param ${param})
775   endforeach()
776   if (ARG_DEFAULT_ARGS)
777     add_custom_target(${target}
778       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
779       COMMENT "${comment}"
780       ${cmake_3_2_USES_TERMINAL}
781       )
782   else()
783     add_custom_target(${target}
784       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
785     message(STATUS "${target} does nothing.")
786   endif()
787   if (ARG_DEPENDS)
788     add_dependencies(${target} ${ARG_DEPENDS})
789   endif()
790
791   # Tests should be excluded from "Build Solution".
792   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
793 endfunction()
794
795 # A function to add a set of lit test suites to be driven through 'check-*' targets.
796 function(add_lit_testsuite target comment)
797   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
798
799   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
800   if(NOT EXCLUDE_FROM_ALL)
801     # Register the testsuites, params and depends for the global check rule.
802     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
803     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
804     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
805     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
806   endif()
807
808   # Produce a specific suffixed check rule.
809   add_lit_target(${target} ${comment}
810     ${ARG_DEFAULT_ARGS}
811     PARAMS ${ARG_PARAMS}
812     DEPENDS ${ARG_DEPENDS}
813     ARGS ${ARG_ARGS}
814     )
815 endfunction()
816
817 function(add_lit_testsuites project directory)
818   if (NOT CMAKE_CONFIGURATION_TYPES)
819     parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
820     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
821     set(lit_suites)
822     foreach(f ${litCfg})
823       get_filename_component(dir ${f} DIRECTORY)
824       set(lit_suites ${lit_suites} ${dir})
825     endforeach()
826     list(REMOVE_DUPLICATES lit_suites)
827     foreach(dir ${lit_suites})
828       string(REPLACE ${directory} "" name_slash ${dir})
829       if (name_slash)
830         string(REPLACE "/" "-" name_slash ${name_slash})
831         string(REPLACE "\\" "-" name_dashes ${name_slash})
832         string(TOLOWER "${project}${name_dashes}" name_var)
833         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
834           ${dir}
835           PARAMS ${ARG_PARAMS}
836           DEPENDS ${ARG_DEPENDS}
837           ARGS ${ARG_ARGS}
838         )
839       endif()
840     endforeach()
841   endif()
842 endfunction()