cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3
   4 function(llvm_update_compile_flags name)
   5   get_property(sources TARGET ${name} PROPERTY SOURCES)
   6   if("${sources}" MATCHES "\\.c(;|$)")
   7     set(update_src_props ON)
   8   endif()
   9
  10   # LLVM_REQUIRES_EH is an internal flag that individual
  11   # targets can use to force EH
  12   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  13     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  14       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  15       set(LLVM_REQUIRES_RTTI ON)
  16     endif()
  17   else()
  18     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  19       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  20     elseif(MSVC)
  21       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  22       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  23     endif()
  24     if (CLANG_CL)
  25       # FIXME: Remove this once clang-cl supports SEH
  26       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
  27     endif()
  28   endif()
  29
  30   # LLVM_REQUIRES_RTTI is an internal flag that individual
  31   # targets can use to force RTTI
  32   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  33     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  34     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  35       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  36     elseif (MSVC)
  37       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  38     endif ()
  39   endif()
  40
  41   # Assume that;
  42   #   - LLVM_COMPILE_FLAGS is list.
  43   #   - PROPERTY COMPILE_FLAGS is string.
  44   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  45
  46   if(update_src_props)
  47     foreach(fn ${sources})
  48       get_filename_component(suf ${fn} EXT)
  49       if("${suf}" STREQUAL ".cpp")
  50         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  51           COMPILE_FLAGS "${target_compile_flags}")
  52       endif()
  53     endforeach()
  54   else()
  55     # Update target props, since all sources are C++.
  56     set_property(TARGET ${name} APPEND_STRING PROPERTY
  57       COMPILE_FLAGS "${target_compile_flags}")
  58   endif()
  59
  60   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  61 endfunction()
  62
  63 function(add_llvm_symbol_exports target_name export_file)
  64   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  65     set(native_export_file "${target_name}.exports")
  66     add_custom_command(OUTPUT ${native_export_file}
  67       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  68       DEPENDS ${export_file}
  69       VERBATIM
  70       COMMENT "Creating export file for ${target_name}")
  71     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  72                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  73   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  74     # Gold and BFD ld require a version script rather than a plain list.
  75     set(native_export_file "${target_name}.exports")
  76     # FIXME: Don't write the "local:" line on OpenBSD.
  77     add_custom_command(OUTPUT ${native_export_file}
  78       COMMAND echo "{" > ${native_export_file}
  79       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  80       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  81       COMMAND echo "  local: *;" >> ${native_export_file}
  82       COMMAND echo "};" >> ${native_export_file}
  83       DEPENDS ${export_file}
  84       VERBATIM
  85       COMMENT "Creating export file for ${target_name}")
  86     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  87       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  88                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  89     else()
  90       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  91                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  92     endif()
  93   else()
  94     set(native_export_file "${target_name}.def")
  95
  96     add_custom_command(OUTPUT ${native_export_file}
  97       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
  98         < ${export_file} > ${native_export_file}
  99       DEPENDS ${export_file}
 100       VERBATIM
 101       COMMENT "Creating export file for ${target_name}")
 102     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 103     if(MSVC)
 104       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 105     endif()
 106     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 107                  LINK_FLAGS " ${export_file_linker_flag}")
 108   endif()
 109
 110   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 111   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 112
 113   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 114   foreach(src ${srcs})
 115     get_filename_component(extension ${src} EXT)
 116     if(extension STREQUAL ".cpp")
 117       set(first_source_file ${src})
 118       break()
 119     endif()
 120   endforeach()
 121
 122   # Force re-linking when the exports file changes. Actually, it
 123   # forces recompilation of the source file. The LINK_DEPENDS target
 124   # property only works for makefile-based generators.
 125   # FIXME: This is not safe because this will create the same target
 126   # ${native_export_file} in several different file:
 127   # - One where we emitted ${target_name}_exports
 128   # - One where we emitted the build command for the following object.
 129   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 130   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 131
 132   set_property(DIRECTORY APPEND
 133     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 134
 135   add_dependencies(${target_name} ${target_name}_exports)
 136
 137   # Add dependency to *_exports later -- CMake issue 14747
 138   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 139   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 140 endfunction(add_llvm_symbol_exports)
 141
 142 if(NOT WIN32 AND NOT APPLE)
 143   execute_process(
 144     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 145     OUTPUT_VARIABLE stdout
 146     ERROR_QUIET
 147     )
 148   if("${stdout}" MATCHES "GNU gold")
 149     set(LLVM_LINKER_IS_GOLD ON)
 150   endif()
 151 endif()
 152
 153 function(add_link_opts target_name)
 154   # Don't use linker optimizations in debug builds since it slows down the
 155   # linker in a context where the optimizations are not important.
 156   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 157
 158     # Pass -O3 to the linker. This enabled different optimizations on different
 159     # linkers.
 160     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 161       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 162                    LINK_FLAGS " -Wl,-O3")
 163     endif()
 164
 165     if(LLVM_LINKER_IS_GOLD)
 166       # With gold gc-sections is always safe.
 167       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 168                    LINK_FLAGS " -Wl,--gc-sections")
 169       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 170       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 171     endif()
 172
 173     if(NOT LLVM_NO_DEAD_STRIP)
 174       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 175         # ld64's implementation of -dead_strip breaks tools that use plugins.
 176         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 177                      LINK_FLAGS " -Wl,-dead_strip")
 178       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 179         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 180                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 181       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 182         # Object files are compiled with -ffunction-data-sections.
 183         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 184         # tools that use plugins. Always pass --gc-sections once we require
 185         # a newer linker.
 186         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 187                      LINK_FLAGS " -Wl,--gc-sections")
 188       endif()
 189     endif()
 190   endif()
 191 endfunction(add_link_opts)
 192
 193 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 194 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 195 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 196 function(set_output_directory target bindir libdir)
 197   # Do nothing if *_OUTPUT_INTDIR is empty.
 198   if("${bindir}" STREQUAL "")
 199     return()
 200   endif()
 201
 202   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 203   # It affects output of add_library(MODULE).
 204   if(WIN32 OR CYGWIN)
 205     # DLL platform
 206     set(moddir ${bindir})
 207   else()
 208     set(moddir ${libdir})
 209   endif()
 210   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 211     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 212       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 213       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 214       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 215       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 216       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 217       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 218       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 219     endforeach()
 220   else()
 221     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 222     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 223     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 224   endif()
 225 endfunction()
 226
 227 # If on Windows and building with MSVC, add the resource script containing the
 228 # VERSIONINFO data to the project.  This embeds version resource information
 229 # into the output .exe or .dll.
 230 # TODO: Enable for MinGW Windows builds too.
 231 #
 232 function(add_windows_version_resource_file OUT_VAR)
 233   set(sources ${ARGN})
 234   if (MSVC)
 235     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 236     if(EXISTS ${resource_file})
 237       set(sources ${sources} ${resource_file})
 238       source_group("Resource Files" ${resource_file})
 239       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 240     endif()
 241   endif(MSVC)
 242
 243   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 244 endfunction(add_windows_version_resource_file)
 245
 246 # set_windows_version_resource_properties(name resource_file...
 247 #   VERSION_MAJOR int
 248 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 249 #   VERSION_MINOR int
 250 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 251 #   VERSION_PATCHLEVEL int
 252 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 253 #   VERSION_STRING
 254 #     Optional version string (defaults to PACKAGE_VERSION)
 255 #   PRODUCT_NAME
 256 #     Optional product name string (defaults to "LLVM")
 257 #   )
 258 function(set_windows_version_resource_properties name resource_file)
 259   cmake_parse_arguments(ARG
 260     ""
 261     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 262     ""
 263     ${ARGN})
 264
 265   if (NOT DEFINED ARG_VERSION_MAJOR)
 266     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 267   endif()
 268
 269   if (NOT DEFINED ARG_VERSION_MINOR)
 270     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 271   endif()
 272
 273   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 274     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_STRING)
 278     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 279   endif()
 280
 281   if (NOT DEFINED ARG_PRODUCT_NAME)
 282     set(ARG_PRODUCT_NAME "LLVM")
 283   endif()
 284
 285   set_property(SOURCE ${resource_file}
 286                PROPERTY COMPILE_FLAGS /nologo)
 287   set_property(SOURCE ${resource_file}
 288                PROPERTY COMPILE_DEFINITIONS
 289                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 290                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 291                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 292                "RC_VERSION_FIELD_4=0"
 293                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 294                "RC_INTERNAL_NAME=\"${name}\""
 295                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 296                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 297 endfunction(set_windows_version_resource_properties)
 298
 299 # llvm_add_library(name sources...
 300 #   SHARED;STATIC
 301 #     STATIC by default w/o BUILD_SHARED_LIBS.
 302 #     SHARED by default w/  BUILD_SHARED_LIBS.
 303 #   MODULE
 304 #     Target ${name} might not be created on unsupported platforms.
 305 #     Check with "if(TARGET ${name})".
 306 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 307 #     Do not link this library to libLLVM, even if
 308 #     LLVM_LINK_LLVM_DYLIB is enabled.
 309 #   OUTPUT_NAME name
 310 #     Corresponds to OUTPUT_NAME in target properties.
 311 #   DEPENDS targets...
 312 #     Same semantics as add_dependencies().
 313 #   LINK_COMPONENTS components...
 314 #     Same as the variable LLVM_LINK_COMPONENTS.
 315 #   LINK_LIBS lib_targets...
 316 #     Same semantics as target_link_libraries().
 317 #   ADDITIONAL_HEADERS
 318 #     May specify header files for IDE generators.
 319 #   )
 320 function(llvm_add_library name)
 321   cmake_parse_arguments(ARG
 322     "MODULE;SHARED;STATIC;DISABLE_LLVM_LINK_LLVM_DYLIB"
 323     "OUTPUT_NAME"
 324     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 325     ${ARGN})
 326   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 327   if(ARG_ADDITIONAL_HEADERS)
 328     # Pass through ADDITIONAL_HEADERS.
 329     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 330   endif()
 331   if(ARG_OBJLIBS)
 332     set(ALL_FILES ${ARG_OBJLIBS})
 333   else()
 334     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 335   endif()
 336
 337   if(ARG_MODULE)
 338     if(ARG_SHARED OR ARG_STATIC)
 339       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 340     endif()
 341     if(NOT LLVM_ENABLE_PLUGINS)
 342       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 343       return()
 344     endif()
 345   else()
 346     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 347       set(ARG_SHARED TRUE)
 348     endif()
 349     if(NOT ARG_SHARED)
 350       set(ARG_STATIC TRUE)
 351     endif()
 352   endif()
 353
 354   # Generate objlib
 355   if(ARG_SHARED AND ARG_STATIC)
 356     # Generate an obj library for both targets.
 357     set(obj_name "obj.${name}")
 358     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 359       ${ALL_FILES}
 360       )
 361     llvm_update_compile_flags(${obj_name})
 362     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 363
 364     # Do add_dependencies(obj) later due to CMake issue 14747.
 365     list(APPEND objlibs ${obj_name})
 366
 367     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 368   endif()
 369
 370   if(ARG_SHARED AND ARG_STATIC)
 371     # static
 372     set(name_static "${name}_static")
 373     if(ARG_OUTPUT_NAME)
 374       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 375     endif()
 376     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 377     llvm_add_library(${name_static} STATIC
 378       ${output_name}
 379       OBJLIBS ${ALL_FILES} # objlib
 380       LINK_LIBS ${ARG_LINK_LIBS}
 381       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 382       )
 383     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 384     set(ARG_STATIC)
 385   endif()
 386
 387   if(ARG_MODULE)
 388     add_library(${name} MODULE ${ALL_FILES})
 389   elseif(ARG_SHARED)
 390     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 391     add_library(${name} SHARED ${ALL_FILES})
 392   else()
 393     add_library(${name} STATIC ${ALL_FILES})
 394   endif()
 395
 396   if(DEFINED windows_resource_file)
 397     set_windows_version_resource_properties(${name} ${windows_resource_file})
 398     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 399   endif()
 400
 401   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 402   llvm_update_compile_flags(${name})
 403   add_link_opts( ${name} )
 404   if(ARG_OUTPUT_NAME)
 405     set_target_properties(${name}
 406       PROPERTIES
 407       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 408       )
 409   endif()
 410
 411   if(ARG_MODULE)
 412     set_target_properties(${name} PROPERTIES
 413       PREFIX ""
 414       SUFFIX ${LLVM_PLUGIN_EXT}
 415       )
 416   endif()
 417
 418   if(ARG_SHARED)
 419     if(WIN32)
 420       set_target_properties(${name} PROPERTIES
 421         PREFIX ""
 422         )
 423     endif()
 424
 425     set_target_properties(${name}
 426       PROPERTIES
 427       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 428       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 429   endif()
 430
 431   if(ARG_MODULE OR ARG_SHARED)
 432     # Do not add -Dname_EXPORTS to the command-line when building files in this
 433     # target. Doing so is actively harmful for the modules build because it
 434     # creates extra module variants, and not useful because we don't use these
 435     # macros.
 436     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 437
 438     if (LLVM_EXPORTED_SYMBOL_FILE)
 439       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 440     endif()
 441   endif()
 442
 443   # Add the explicit dependency information for this library.
 444   #
 445   # It would be nice to verify that we have the dependencies for this library
 446   # name, but using get_property(... SET) doesn't suffice to determine if a
 447   # property has been set to an empty value.
 448   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 449
 450   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_STATIC AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 451     set(llvm_libs LLVM)
 452   else()
 453     llvm_map_components_to_libnames(llvm_libs
 454       ${ARG_LINK_COMPONENTS}
 455       ${LLVM_LINK_COMPONENTS}
 456       )
 457   endif()
 458
 459   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 460     # Link libs w/o keywords, assuming PUBLIC.
 461     target_link_libraries(${name}
 462       ${ARG_LINK_LIBS}
 463       ${lib_deps}
 464       ${llvm_libs}
 465       )
 466   elseif(ARG_STATIC)
 467     target_link_libraries(${name} INTERFACE
 468       ${ARG_LINK_LIBS}
 469       ${lib_deps}
 470       ${llvm_libs}
 471       )
 472   else()
 473     # We can use PRIVATE since SO knows its dependent libs.
 474     target_link_libraries(${name} PRIVATE
 475       ${ARG_LINK_LIBS}
 476       ${lib_deps}
 477       ${llvm_libs}
 478       )
 479   endif()
 480
 481   if(LLVM_COMMON_DEPENDS)
 482     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 483     # Add dependencies also to objlibs.
 484     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 485     foreach(objlib ${objlibs})
 486       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 487     endforeach()
 488   endif()
 489 endfunction()
 490
 491 macro(add_llvm_library name)
 492   cmake_parse_arguments(ARG
 493     "SHARED"
 494     ""
 495     ""
 496     ${ARGN})
 497   if( BUILD_SHARED_LIBS )
 498     llvm_add_library(${name} SHARED ${ARGN})
 499   else()
 500     llvm_add_library(${name} ${ARGN})
 501   endif()
 502   # The gtest libraries should not be installed or exported as a target
 503   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 504     set(_is_gtest TRUE)
 505   else()
 506     set(_is_gtest FALSE)
 507     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 508   endif()
 509
 510   if( EXCLUDE_FROM_ALL )
 511     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 512   elseif(NOT _is_gtest)
 513     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 514       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 515         if(WIN32 OR CYGWIN)
 516           set(install_type RUNTIME)
 517         else()
 518           set(install_type LIBRARY)
 519         endif()
 520       else()
 521         set(install_type ARCHIVE)
 522       endif()
 523
 524       install(TARGETS ${name}
 525             EXPORT LLVMExports
 526             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 527             COMPONENT ${name})
 528
 529       if (NOT CMAKE_CONFIGURATION_TYPES)
 530         add_custom_target(install-${name}
 531                           DEPENDS ${name}
 532                           COMMAND "${CMAKE_COMMAND}"
 533                                   -DCMAKE_INSTALL_COMPONENT=${name}
 534                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 535       endif()
 536     endif()
 537     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 538   endif()
 539   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 540 endmacro(add_llvm_library name)
 541
 542 macro(add_llvm_loadable_module name)
 543   llvm_add_library(${name} MODULE ${ARGN})
 544   if(NOT TARGET ${name})
 545     # Add empty "phony" target
 546     add_custom_target(${name})
 547   else()
 548     if( EXCLUDE_FROM_ALL )
 549       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 550     else()
 551       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 552         if(WIN32 OR CYGWIN)
 553           # DLL platform
 554           set(dlldir "bin")
 555         else()
 556           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 557         endif()
 558         install(TARGETS ${name}
 559           EXPORT LLVMExports
 560           LIBRARY DESTINATION ${dlldir}
 561           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 562       endif()
 563       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 564     endif()
 565   endif()
 566
 567   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 568 endmacro(add_llvm_loadable_module name)
 569
 570
 571 macro(add_llvm_executable name)
 572   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB" "" "" ${ARGN})
 573   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 574
 575   # Generate objlib
 576   if(LLVM_ENABLE_OBJLIB)
 577     # Generate an obj library for both targets.
 578     set(obj_name "obj.${name}")
 579     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 580       ${ALL_FILES}
 581       )
 582     llvm_update_compile_flags(${obj_name})
 583     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 584
 585     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 586   endif()
 587
 588   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 589
 590   if( EXCLUDE_FROM_ALL )
 591     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 592   else()
 593     add_executable(${name} ${ALL_FILES})
 594   endif()
 595
 596   if(DEFINED windows_resource_file)
 597     set_windows_version_resource_properties(${name} ${windows_resource_file})
 598   endif()
 599
 600   llvm_update_compile_flags(${name})
 601   add_link_opts( ${name} )
 602
 603   # Do not add -Dname_EXPORTS to the command-line when building files in this
 604   # target. Doing so is actively harmful for the modules build because it
 605   # creates extra module variants, and not useful because we don't use these
 606   # macros.
 607   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 608
 609   if (LLVM_EXPORTED_SYMBOL_FILE)
 610     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 611   endif(LLVM_EXPORTED_SYMBOL_FILE)
 612
 613   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 614     set(USE_SHARED USE_SHARED)
 615   endif()
 616
 617   set(EXCLUDE_FROM_ALL OFF)
 618   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 619   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 620   if( LLVM_COMMON_DEPENDS )
 621     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 622   endif( LLVM_COMMON_DEPENDS )
 623 endmacro(add_llvm_executable name)
 624
 625 function(export_executable_symbols target)
 626   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 627     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 628   endif()
 629 endfunction()
 630
 631
 632 set (LLVM_TOOLCHAIN_TOOLS
 633   llvm-ar
 634   llvm-objdump
 635   )
 636
 637 macro(add_llvm_tool name)
 638   if( NOT LLVM_BUILD_TOOLS )
 639     set(EXCLUDE_FROM_ALL ON)
 640   endif()
 641   add_llvm_executable(${name} ${ARGN})
 642
 643   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 644   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 645     if( LLVM_BUILD_TOOLS )
 646       install(TARGETS ${name}
 647               EXPORT LLVMExports
 648               RUNTIME DESTINATION bin
 649               COMPONENT ${name})
 650
 651       if (NOT CMAKE_CONFIGURATION_TYPES)
 652         add_custom_target(install-${name}
 653                           DEPENDS ${name}
 654                           COMMAND "${CMAKE_COMMAND}"
 655                                   -DCMAKE_INSTALL_COMPONENT=${name}
 656                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 657       endif()
 658     endif()
 659   endif()
 660   if( LLVM_BUILD_TOOLS )
 661     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 662   endif()
 663   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 664 endmacro(add_llvm_tool name)
 665
 666
 667 macro(add_llvm_example name)
 668   if( NOT LLVM_BUILD_EXAMPLES )
 669     set(EXCLUDE_FROM_ALL ON)
 670   endif()
 671   add_llvm_executable(${name} ${ARGN})
 672   if( LLVM_BUILD_EXAMPLES )
 673     install(TARGETS ${name} RUNTIME DESTINATION examples)
 674   endif()
 675   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 676 endmacro(add_llvm_example name)
 677
 678
 679 macro(add_llvm_utility name)
 680   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 681   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 682   if( LLVM_INSTALL_UTILS )
 683     install (TARGETS ${name}
 684       RUNTIME DESTINATION bin
 685       COMPONENT ${name})
 686     if (NOT CMAKE_CONFIGURATION_TYPES)
 687       add_custom_target(install-${name}
 688                         DEPENDS ${name}
 689                         COMMAND "${CMAKE_COMMAND}"
 690                                 -DCMAKE_INSTALL_COMPONENT=${name}
 691                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 692     endif()
 693   endif()
 694 endmacro(add_llvm_utility name)
 695
 696
 697 macro(add_llvm_target target_name)
 698   include_directories(BEFORE
 699     ${CMAKE_CURRENT_BINARY_DIR}
 700     ${CMAKE_CURRENT_SOURCE_DIR})
 701   add_llvm_library(LLVM${target_name} ${ARGN})
 702   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 703 endmacro(add_llvm_target)
 704
 705 function(canonicalize_tool_name name output)
 706   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 707   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 708   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 709   set(${output} "${nameUPPER}" PARENT_SCOPE)
 710 endfunction(canonicalize_tool_name)
 711
 712 # Add external project that may want to be built as part of llvm such as Clang,
 713 # lld, and Polly. This adds two options. One for the source directory of the
 714 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 715 # enable or disable building it with everything else.
 716 # Additional parameter can be specified as the name of directory.
 717 macro(add_llvm_external_project name)
 718   set(add_llvm_external_dir "${ARGN}")
 719   if("${add_llvm_external_dir}" STREQUAL "")
 720     set(add_llvm_external_dir ${name})
 721   endif()
 722   canonicalize_tool_name(${name} nameUPPER)
 723   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 724     # Treat it as in-tree subproject.
 725     option(LLVM_TOOL_${nameUPPER}_BUILD
 726            "Whether to build ${name} as part of LLVM" On)
 727     mark_as_advanced(LLVM_TOOL_${name}_BUILD)
 728     if(LLVM_TOOL_${nameUPPER}_BUILD)
 729       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 730       # Don't process it in add_llvm_implicit_projects().
 731       set(LLVM_TOOL_${nameUPPER}_BUILD OFF)
 732     endif()
 733   else()
 734     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 735       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 736       CACHE PATH "Path to ${name} source directory")
 737     set(LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT ON)
 738     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 739       set(LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT OFF)
 740     endif()
 741     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 742       set(LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT OFF)
 743     endif()
 744     option(LLVM_TOOL_${nameUPPER}_BUILD
 745       "Whether to build ${name} as part of LLVM"
 746       ${LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT})
 747     if (LLVM_TOOL_${nameUPPER}_BUILD)
 748       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 749         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 750       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 751         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 752       endif()
 753       # FIXME: It'd be redundant.
 754       set(LLVM_TOOL_${nameUPPER}_BUILD Off)
 755     endif()
 756   endif()
 757 endmacro(add_llvm_external_project)
 758
 759 macro(add_llvm_tool_subdirectory name)
 760   add_llvm_external_project(${name})
 761 endmacro(add_llvm_tool_subdirectory)
 762
 763 function(get_project_name_from_src_var var output)
 764   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 765          MACHED_TOOL "${var}")
 766   if(MACHED_TOOL)
 767     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 768   else()
 769     set(${output} PARENT_SCOPE)
 770   endif()
 771 endfunction()
 772
 773 function(create_llvm_tool_options)
 774   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 775   foreach(dir ${sub-dirs})
 776     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 777       canonicalize_tool_name(${dir} name)
 778       option(LLVM_TOOL_${name}_BUILD
 779            "Whether to build ${name} as part of LLVM" On)
 780       mark_as_advanced(LLVM_TOOL_${name}_BUILD)
 781     endif()
 782   endforeach()
 783 endfunction(create_llvm_tool_options)
 784
 785 function(add_llvm_implicit_projects)
 786   set(list_of_implicit_subdirs "")
 787   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 788   foreach(dir ${sub-dirs})
 789     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 790       canonicalize_tool_name(${dir} name)
 791       if (LLVM_TOOL_${name}_BUILD)
 792         get_filename_component(fn "${dir}" NAME)
 793         list(APPEND list_of_implicit_subdirs "${fn}")
 794       endif()
 795     endif()
 796   endforeach()
 797
 798   foreach(external_proj ${list_of_implicit_subdirs})
 799     add_llvm_external_project("${external_proj}")
 800   endforeach()
 801 endfunction(add_llvm_implicit_projects)
 802
 803 # Generic support for adding a unittest.
 804 function(add_unittest test_suite test_name)
 805   if( NOT LLVM_BUILD_TESTS )
 806     set(EXCLUDE_FROM_ALL ON)
 807   endif()
 808
 809   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 810   if (NOT LLVM_ENABLE_THREADS)
 811     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 812   endif ()
 813
 814   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 815     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 816   endif ()
 817
 818   set(LLVM_REQUIRES_RTTI OFF)
 819
 820   add_llvm_executable(${test_name} ${ARGN})
 821   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 822   set_output_directory(${test_name} ${outdir} ${outdir})
 823   target_link_libraries(${test_name}
 824     gtest
 825     gtest_main
 826     LLVMSupport # gtest needs it for raw_ostream.
 827     )
 828
 829   add_dependencies(${test_suite} ${test_name})
 830   get_target_property(test_suite_folder ${test_suite} FOLDER)
 831   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 832     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 833   endif ()
 834 endfunction()
 835
 836 function(llvm_add_go_executable binary pkgpath)
 837   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 838
 839   if(LLVM_BINDINGS MATCHES "go")
 840     # FIXME: This should depend only on the libraries Go needs.
 841     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 842     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 843     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 844     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 845     set(cppflags "")
 846     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 847     foreach(d ${include_dirs})
 848       set(cppflags "${cppflags} -I${d}")
 849     endforeach(d)
 850     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 851     if (LLVM_LINK_LLVM_DYLIB)
 852       set(linkmode "dylib")
 853     else()
 854       set(linkmode "component-libs")
 855     endif()
 856     add_custom_command(OUTPUT ${binpath}
 857       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "linkmode=${linkmode}"
 858               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 859       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 860               ${llvmlibs} ${ARG_DEPENDS}
 861       COMMENT "Building Go executable ${binary}"
 862       VERBATIM)
 863     if (ARG_ALL)
 864       add_custom_target(${binary} ALL DEPENDS ${binpath})
 865     else()
 866       add_custom_target(${binary} DEPENDS ${binpath})
 867     endif()
 868   endif()
 869 endfunction()
 870
 871 # This function provides an automatic way to 'configure'-like generate a file
 872 # based on a set of common and custom variables, specifically targeting the
 873 # variables needed for the 'lit.site.cfg' files. This function bundles the
 874 # common variables that any Lit instance is likely to need, and custom
 875 # variables can be passed in.
 876 function(configure_lit_site_cfg input output)
 877   foreach(c ${LLVM_TARGETS_TO_BUILD})
 878     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 879   endforeach(c)
 880   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 881
 882   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 883
 884   # Configuration-time: See Unit/lit.site.cfg.in
 885   if (CMAKE_CFG_INTDIR STREQUAL ".")
 886     set(LLVM_BUILD_MODE ".")
 887   else ()
 888     set(LLVM_BUILD_MODE "%(build_mode)s")
 889   endif ()
 890
 891   # They below might not be the build tree but provided binary tree.
 892   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 893   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 894   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 895   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 896
 897   # SHLIBDIR points the build tree.
 898   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 899
 900   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 901   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 902   # plugins. We may rename it.
 903   if(LLVM_ENABLE_PLUGINS)
 904     set(ENABLE_SHARED "1")
 905   else()
 906     set(ENABLE_SHARED "0")
 907   endif()
 908
 909   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 910     set(ENABLE_ASSERTIONS "1")
 911   else()
 912     set(ENABLE_ASSERTIONS "0")
 913   endif()
 914
 915   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 916   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 917
 918   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 919   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 920   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 921
 922   configure_file(${input} ${output} @ONLY)
 923 endfunction()
 924
 925 # A raw function to create a lit target. This is used to implement the testuite
 926 # management functions.
 927 function(add_lit_target target comment)
 928   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 929   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 930   separate_arguments(LIT_ARGS)
 931   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 932     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 933   endif ()
 934   if (LLVM_MAIN_SRC_DIR)
 935     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 936   else()
 937     find_program(LIT_COMMAND llvm-lit)
 938   endif ()
 939   list(APPEND LIT_COMMAND ${LIT_ARGS})
 940   foreach(param ${ARG_PARAMS})
 941     list(APPEND LIT_COMMAND --param ${param})
 942   endforeach()
 943   if (ARG_UNPARSED_ARGUMENTS)
 944     add_custom_target(${target}
 945       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 946       COMMENT "${comment}"
 947       ${cmake_3_2_USES_TERMINAL}
 948       )
 949   else()
 950     add_custom_target(${target}
 951       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 952     message(STATUS "${target} does nothing.")
 953   endif()
 954   if (ARG_DEPENDS)
 955     add_dependencies(${target} ${ARG_DEPENDS})
 956   endif()
 957
 958   # Tests should be excluded from "Build Solution".
 959   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 960 endfunction()
 961
 962 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 963 function(add_lit_testsuite target comment)
 964   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 965
 966   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 967   if(NOT EXCLUDE_FROM_ALL)
 968     # Register the testsuites, params and depends for the global check rule.
 969     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
 970     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 971     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 972     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 973   endif()
 974
 975   # Produce a specific suffixed check rule.
 976   add_lit_target(${target} ${comment}
 977     ${ARG_UNPARSED_ARGUMENTS}
 978     PARAMS ${ARG_PARAMS}
 979     DEPENDS ${ARG_DEPENDS}
 980     ARGS ${ARG_ARGS}
 981     )
 982 endfunction()
 983
 984 function(add_lit_testsuites project directory)
 985   if (NOT CMAKE_CONFIGURATION_TYPES)
 986     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 987     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
 988     set(lit_suites)
 989     foreach(f ${litCfg})
 990       get_filename_component(dir ${f} DIRECTORY)
 991       set(lit_suites ${lit_suites} ${dir})
 992     endforeach()
 993     list(REMOVE_DUPLICATES lit_suites)
 994     foreach(dir ${lit_suites})
 995       string(REPLACE ${directory} "" name_slash ${dir})
 996       if (name_slash)
 997         string(REPLACE "/" "-" name_slash ${name_slash})
 998         string(REPLACE "\\" "-" name_dashes ${name_slash})
 999         string(TOLOWER "${project}${name_dashes}" name_var)
1000         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
1001           ${dir}
1002           PARAMS ${ARG_PARAMS}
1003           DEPENDS ${ARG_DEPENDS}
1004           ARGS ${ARG_ARGS}
1005         )
1006       endif()
1007     endforeach()
1008   endif()
1009 endfunction()