cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25     if (CLANG_CL)
  26       # FIXME: Remove this once clang-cl supports SEH
  27       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
  28     endif()
  29   endif()
  30
  31   # LLVM_REQUIRES_RTTI is an internal flag that individual
  32   # targets can use to force RTTI
  33   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  34     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  35     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  36       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  37     elseif (MSVC)
  38       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  39     endif ()
  40   endif()
  41
  42   # Assume that;
  43   #   - LLVM_COMPILE_FLAGS is list.
  44   #   - PROPERTY COMPILE_FLAGS is string.
  45   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  46
  47   if(update_src_props)
  48     foreach(fn ${sources})
  49       get_filename_component(suf ${fn} EXT)
  50       if("${suf}" STREQUAL ".cpp")
  51         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  52           COMPILE_FLAGS "${target_compile_flags}")
  53       endif()
  54     endforeach()
  55   else()
  56     # Update target props, since all sources are C++.
  57     set_property(TARGET ${name} APPEND_STRING PROPERTY
  58       COMPILE_FLAGS "${target_compile_flags}")
  59   endif()
  60
  61   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  62 endfunction()
  63
  64 function(add_llvm_symbol_exports target_name export_file)
  65   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  66     set(native_export_file "${target_name}.exports")
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  69       DEPENDS ${export_file}
  70       VERBATIM
  71       COMMENT "Creating export file for ${target_name}")
  72     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  73                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  74   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  75     # Gold and BFD ld require a version script rather than a plain list.
  76     set(native_export_file "${target_name}.exports")
  77     # FIXME: Don't write the "local:" line on OpenBSD.
  78     add_custom_command(OUTPUT ${native_export_file}
  79       COMMAND echo "{" > ${native_export_file}
  80       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  81       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  82       COMMAND echo "  local: *;" >> ${native_export_file}
  83       COMMAND echo "};" >> ${native_export_file}
  84       DEPENDS ${export_file}
  85       VERBATIM
  86       COMMENT "Creating export file for ${target_name}")
  87     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  88                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  89   else()
  90     set(native_export_file "${target_name}.def")
  91
  92     set(CAT "cat")
  93     set(export_file_nativeslashes ${export_file})
  94     if(WIN32 AND NOT CYGWIN AND NOT MSYS)
  95       set(CAT "type")
  96       # Convert ${export_file} to native format (backslashes) for "type"
  97       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
  98       # path but a build-system specific format (see CMake bug
  99       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
 100       string(REPLACE / \\ export_file_nativeslashes ${export_file})
 101     endif()
 102
 103     add_custom_command(OUTPUT ${native_export_file}
 104       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 105       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 106       DEPENDS ${export_file}
 107       VERBATIM
 108       COMMENT "Creating export file for ${target_name}")
 109     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 110     if(MSVC)
 111       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 112     endif()
 113     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 114                  LINK_FLAGS " ${export_file_linker_flag}")
 115   endif()
 116
 117   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 118   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 119
 120   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 121   foreach(src ${srcs})
 122     get_filename_component(extension ${src} EXT)
 123     if(extension STREQUAL ".cpp")
 124       set(first_source_file ${src})
 125       break()
 126     endif()
 127   endforeach()
 128
 129   # Force re-linking when the exports file changes. Actually, it
 130   # forces recompilation of the source file. The LINK_DEPENDS target
 131   # property only works for makefile-based generators.
 132   # FIXME: This is not safe because this will create the same target
 133   # ${native_export_file} in several different file:
 134   # - One where we emitted ${target_name}_exports
 135   # - One where we emitted the build command for the following object.
 136   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 137   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 138
 139   set_property(DIRECTORY APPEND
 140     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 141
 142   add_dependencies(${target_name} ${target_name}_exports)
 143
 144   # Add dependency to *_exports later -- CMake issue 14747
 145   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 146   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 147 endfunction(add_llvm_symbol_exports)
 148
 149 if(NOT WIN32 AND NOT APPLE)
 150   execute_process(
 151     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 152     OUTPUT_VARIABLE stdout
 153     ERROR_QUIET
 154     )
 155   if("${stdout}" MATCHES "GNU gold")
 156     set(LLVM_LINKER_IS_GOLD ON)
 157   endif()
 158 endif()
 159
 160 function(add_link_opts target_name)
 161   # Don't use linker optimizations in debug builds since it slows down the
 162   # linker in a context where the optimizations are not important.
 163   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 164
 165     # Pass -O3 to the linker. This enabled different optimizations on different
 166     # linkers.
 167     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32))
 168       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 169                    LINK_FLAGS " -Wl,-O3")
 170     endif()
 171
 172     if(LLVM_LINKER_IS_GOLD)
 173       # With gold gc-sections is always safe.
 174       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 175                    LINK_FLAGS " -Wl,--gc-sections")
 176       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 177       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 178     endif()
 179
 180     if(NOT LLVM_NO_DEAD_STRIP)
 181       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 182         # ld64's implementation of -dead_strip breaks tools that use plugins.
 183         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 184                      LINK_FLAGS " -Wl,-dead_strip")
 185       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 186         # Object files are compiled with -ffunction-data-sections.
 187         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 188         # tools that use plugins. Always pass --gc-sections once we require
 189         # a newer linker.
 190         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 191                      LINK_FLAGS " -Wl,--gc-sections")
 192       endif()
 193     endif()
 194   endif()
 195 endfunction(add_link_opts)
 196
 197 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 198 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 199 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 200 function(set_output_directory target bindir libdir)
 201   # Do nothing if *_OUTPUT_INTDIR is empty.
 202   if("${bindir}" STREQUAL "")
 203     return()
 204   endif()
 205
 206   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 207   # It affects output of add_library(MODULE).
 208   if(WIN32 OR CYGWIN)
 209     # DLL platform
 210     set(moddir ${bindir})
 211   else()
 212     set(moddir ${libdir})
 213   endif()
 214   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 215     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 216       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 217       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 218       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 219       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 220       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 221       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 222       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 223     endforeach()
 224   else()
 225     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 226     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 227     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 228   endif()
 229 endfunction()
 230
 231 # If on Windows and building with MSVC, add the resource script containing the
 232 # VERSIONINFO data to the project.  This embeds version resource information
 233 # into the output .exe or .dll.
 234 # TODO: Enable for MinGW Windows builds too.
 235 #
 236 function(add_windows_version_resource_file OUT_VAR)
 237   set(sources ${ARGN})
 238   if (MSVC)
 239     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 240     set(sources ${sources} ${resource_file})
 241     source_group("Resource Files" ${resource_file})
 242     set(windows_resource_file ${resource_file} PARENT_SCOPE)
 243   endif(MSVC)
 244
 245   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 246 endfunction(add_windows_version_resource_file)
 247
 248 # set_windows_version_resource_properties(name resource_file...
 249 #   VERSION_MAJOR int
 250 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 251 #   VERSION_MINOR int
 252 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 253 #   VERSION_PATCHLEVEL int
 254 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 255 #   VERSION_STRING
 256 #     Optional version string (defaults to PACKAGE_VERSION)
 257 #   PRODUCT_NAME
 258 #     Optional product name string (defaults to "LLVM")
 259 #   )
 260 function(set_windows_version_resource_properties name resource_file)
 261   cmake_parse_arguments(ARG
 262     ""
 263     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 264     ""
 265     ${ARGN})
 266
 267   if (NOT DEFINED ARG_VERSION_MAJOR)
 268     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 269   endif()
 270
 271   if (NOT DEFINED ARG_VERSION_MINOR)
 272     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 273   endif()
 274
 275   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 276     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 277   endif()
 278
 279   if (NOT DEFINED ARG_VERSION_STRING)
 280     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 281   endif()
 282
 283   if (NOT DEFINED ARG_PRODUCT_NAME)
 284     set(ARG_PRODUCT_NAME "LLVM")
 285   endif()
 286
 287   set_property(SOURCE ${resource_file}
 288                PROPERTY COMPILE_DEFINITIONS
 289                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 290                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 291                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 292                "RC_VERSION_FIELD_4=0"
 293                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 294                "RC_INTERNAL_NAME=\"${name}\""
 295                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 296                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 297 endfunction(set_windows_version_resource_properties)
 298
 299 # llvm_add_library(name sources...
 300 #   SHARED;STATIC
 301 #     STATIC by default w/o BUILD_SHARED_LIBS.
 302 #     SHARED by default w/  BUILD_SHARED_LIBS.
 303 #   MODULE
 304 #     Target ${name} might not be created on unsupported platforms.
 305 #     Check with "if(TARGET ${name})".
 306 #   OUTPUT_NAME name
 307 #     Corresponds to OUTPUT_NAME in target properties.
 308 #   DEPENDS targets...
 309 #     Same semantics as add_dependencies().
 310 #   LINK_COMPONENTS components...
 311 #     Same as the variable LLVM_LINK_COMPONENTS.
 312 #   LINK_LIBS lib_targets...
 313 #     Same semantics as target_link_libraries().
 314 #   ADDITIONAL_HEADERS
 315 #     May specify header files for IDE generators.
 316 #   )
 317 function(llvm_add_library name)
 318   cmake_parse_arguments(ARG
 319     "MODULE;SHARED;STATIC"
 320     "OUTPUT_NAME"
 321     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 322     ${ARGN})
 323   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 324   if(ARG_ADDITIONAL_HEADERS)
 325     # Pass through ADDITIONAL_HEADERS.
 326     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 327   endif()
 328   if(ARG_OBJLIBS)
 329     set(ALL_FILES ${ARG_OBJLIBS})
 330   else()
 331     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 332   endif()
 333
 334   if(ARG_MODULE)
 335     if(ARG_SHARED OR ARG_STATIC)
 336       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 337     endif()
 338     if(NOT LLVM_ENABLE_PLUGINS)
 339       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 340       return()
 341     endif()
 342   else()
 343     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 344       set(ARG_SHARED TRUE)
 345     endif()
 346     if(NOT ARG_SHARED)
 347       set(ARG_STATIC TRUE)
 348     endif()
 349   endif()
 350
 351   # Generate objlib
 352   if(ARG_SHARED AND ARG_STATIC)
 353     # Generate an obj library for both targets.
 354     set(obj_name "obj.${name}")
 355     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 356       ${ALL_FILES}
 357       )
 358     llvm_update_compile_flags(${obj_name})
 359     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 360
 361     # Do add_dependencies(obj) later due to CMake issue 14747.
 362     list(APPEND objlibs ${obj_name})
 363
 364     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 365   endif()
 366
 367   if(ARG_SHARED AND ARG_STATIC)
 368     # static
 369     set(name_static "${name}_static")
 370     if(ARG_OUTPUT_NAME)
 371       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 372     endif()
 373     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 374     llvm_add_library(${name_static} STATIC
 375       ${output_name}
 376       OBJLIBS ${ALL_FILES} # objlib
 377       LINK_LIBS ${ARG_LINK_LIBS}
 378       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 379       )
 380     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 381     set(ARG_STATIC)
 382   endif()
 383
 384   if(ARG_MODULE)
 385     add_library(${name} MODULE ${ALL_FILES})
 386   elseif(ARG_SHARED)
 387     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 388     add_library(${name} SHARED ${ALL_FILES})
 389   else()
 390     add_library(${name} STATIC ${ALL_FILES})
 391   endif()
 392
 393   if(DEFINED windows_resource_file)
 394     set_windows_version_resource_properties(${name} ${windows_resource_file})
 395     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 396   endif()
 397
 398   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 399   llvm_update_compile_flags(${name})
 400   add_link_opts( ${name} )
 401   if(ARG_OUTPUT_NAME)
 402     set_target_properties(${name}
 403       PROPERTIES
 404       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 405       )
 406   endif()
 407
 408   if(ARG_MODULE)
 409     set_target_properties(${name} PROPERTIES
 410       PREFIX ""
 411       SUFFIX ${LLVM_PLUGIN_EXT}
 412       )
 413   endif()
 414
 415   if(ARG_SHARED)
 416     if(WIN32)
 417       set_target_properties(${name} PROPERTIES
 418         PREFIX ""
 419         )
 420     endif()
 421
 422     set_target_properties(${name}
 423       PROPERTIES
 424       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 425       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 426   endif()
 427
 428   if(ARG_MODULE OR ARG_SHARED)
 429     # Do not add -Dname_EXPORTS to the command-line when building files in this
 430     # target. Doing so is actively harmful for the modules build because it
 431     # creates extra module variants, and not useful because we don't use these
 432     # macros.
 433     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 434
 435     if (LLVM_EXPORTED_SYMBOL_FILE)
 436       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 437     endif()
 438   endif()
 439
 440   # Add the explicit dependency information for this library.
 441   #
 442   # It would be nice to verify that we have the dependencies for this library
 443   # name, but using get_property(... SET) doesn't suffice to determine if a
 444   # property has been set to an empty value.
 445   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 446
 447   llvm_map_components_to_libnames(llvm_libs
 448     ${ARG_LINK_COMPONENTS}
 449     ${LLVM_LINK_COMPONENTS}
 450     )
 451
 452   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 453     # Link libs w/o keywords, assuming PUBLIC.
 454     target_link_libraries(${name}
 455       ${ARG_LINK_LIBS}
 456       ${lib_deps}
 457       ${llvm_libs}
 458       )
 459   elseif(ARG_STATIC)
 460     target_link_libraries(${name} INTERFACE
 461       ${ARG_LINK_LIBS}
 462       ${lib_deps}
 463       ${llvm_libs}
 464       )
 465   else()
 466     # We can use PRIVATE since SO knows its dependent libs.
 467     target_link_libraries(${name} PRIVATE
 468       ${ARG_LINK_LIBS}
 469       ${lib_deps}
 470       ${llvm_libs}
 471       )
 472   endif()
 473
 474   if(LLVM_COMMON_DEPENDS)
 475     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 476     # Add dependencies also to objlibs.
 477     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 478     foreach(objlib ${objlibs})
 479       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 480     endforeach()
 481   endif()
 482 endfunction()
 483
 484 macro(add_llvm_library name)
 485   cmake_parse_arguments(ARG
 486     "SHARED"
 487     ""
 488     ""
 489     ${ARGN})
 490   if( BUILD_SHARED_LIBS )
 491     llvm_add_library(${name} SHARED ${ARGN})
 492   else()
 493     llvm_add_library(${name} ${ARGN})
 494   endif()
 495   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 496
 497   if( EXCLUDE_FROM_ALL )
 498     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 499   else()
 500     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 501       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 502         if(WIN32 OR CYGWIN)
 503           set(install_type RUNTIME)
 504         else()
 505           set(install_type LIBRARY)
 506         endif()
 507       else()
 508         set(install_type ARCHIVE)
 509       endif()
 510
 511       install(TARGETS ${name}
 512             EXPORT LLVMExports
 513             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 514             COMPONENT ${name})
 515
 516       if (NOT CMAKE_CONFIGURATION_TYPES)
 517         add_custom_target(install-${name}
 518                           DEPENDS ${name}
 519                           COMMAND "${CMAKE_COMMAND}"
 520                                   -DCMAKE_INSTALL_COMPONENT=${name}
 521                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 522       endif()
 523     endif()
 524     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 525   endif()
 526   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 527 endmacro(add_llvm_library name)
 528
 529 macro(add_llvm_loadable_module name)
 530   llvm_add_library(${name} MODULE ${ARGN})
 531   if(NOT TARGET ${name})
 532     # Add empty "phony" target
 533     add_custom_target(${name})
 534   else()
 535     if( EXCLUDE_FROM_ALL )
 536       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 537     else()
 538       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 539         if(WIN32 OR CYGWIN)
 540           # DLL platform
 541           set(dlldir "bin")
 542         else()
 543           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 544         endif()
 545         install(TARGETS ${name}
 546           EXPORT LLVMExports
 547           LIBRARY DESTINATION ${dlldir}
 548           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 549       endif()
 550       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 551     endif()
 552   endif()
 553
 554   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 555 endmacro(add_llvm_loadable_module name)
 556
 557
 558 macro(add_llvm_executable name)
 559   llvm_process_sources( ALL_FILES ${ARGN} )
 560   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 561
 562   if( EXCLUDE_FROM_ALL )
 563     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 564   else()
 565     add_executable(${name} ${ALL_FILES})
 566   endif()
 567
 568   if(DEFINED windows_resource_file)
 569     set_windows_version_resource_properties(${name} ${windows_resource_file})
 570   endif()
 571
 572   llvm_update_compile_flags(${name})
 573   add_link_opts( ${name} )
 574
 575   # Do not add -Dname_EXPORTS to the command-line when building files in this
 576   # target. Doing so is actively harmful for the modules build because it
 577   # creates extra module variants, and not useful because we don't use these
 578   # macros.
 579   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 580
 581   if (LLVM_EXPORTED_SYMBOL_FILE)
 582     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 583   endif(LLVM_EXPORTED_SYMBOL_FILE)
 584
 585   set(EXCLUDE_FROM_ALL OFF)
 586   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 587   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 588   if( LLVM_COMMON_DEPENDS )
 589     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 590   endif( LLVM_COMMON_DEPENDS )
 591 endmacro(add_llvm_executable name)
 592
 593 function(export_executable_symbols target)
 594   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 595     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 596   endif()
 597 endfunction()
 598
 599
 600 set (LLVM_TOOLCHAIN_TOOLS
 601   llvm-ar
 602   llvm-objdump
 603   )
 604
 605 macro(add_llvm_tool name)
 606   if( NOT LLVM_BUILD_TOOLS )
 607     set(EXCLUDE_FROM_ALL ON)
 608   endif()
 609   add_llvm_executable(${name} ${ARGN})
 610
 611   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 612   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 613     if( LLVM_BUILD_TOOLS )
 614       install(TARGETS ${name}
 615               EXPORT LLVMExports
 616               RUNTIME DESTINATION bin
 617               COMPONENT ${name})
 618
 619       if (NOT CMAKE_CONFIGURATION_TYPES)
 620         add_custom_target(install-${name}
 621                           DEPENDS ${name}
 622                           COMMAND "${CMAKE_COMMAND}"
 623                                   -DCMAKE_INSTALL_COMPONENT=${name}
 624                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 625       endif()
 626     endif()
 627   endif()
 628   if( LLVM_BUILD_TOOLS )
 629     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 630   endif()
 631   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 632 endmacro(add_llvm_tool name)
 633
 634
 635 macro(add_llvm_example name)
 636   if( NOT LLVM_BUILD_EXAMPLES )
 637     set(EXCLUDE_FROM_ALL ON)
 638   endif()
 639   add_llvm_executable(${name} ${ARGN})
 640   if( LLVM_BUILD_EXAMPLES )
 641     install(TARGETS ${name} RUNTIME DESTINATION examples)
 642   endif()
 643   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 644 endmacro(add_llvm_example name)
 645
 646
 647 macro(add_llvm_utility name)
 648   add_llvm_executable(${name} ${ARGN})
 649   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 650   if( LLVM_INSTALL_UTILS )
 651     install (TARGETS ${name}
 652       RUNTIME DESTINATION bin
 653       COMPONENT ${name})
 654     if (NOT CMAKE_CONFIGURATION_TYPES)
 655       add_custom_target(install-${name}
 656                         DEPENDS ${name}
 657                         COMMAND "${CMAKE_COMMAND}"
 658                                 -DCMAKE_INSTALL_COMPONENT=${name}
 659                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 660     endif()
 661   endif()
 662 endmacro(add_llvm_utility name)
 663
 664
 665 macro(add_llvm_target target_name)
 666   include_directories(BEFORE
 667     ${CMAKE_CURRENT_BINARY_DIR}
 668     ${CMAKE_CURRENT_SOURCE_DIR})
 669   add_llvm_library(LLVM${target_name} ${ARGN})
 670   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 671 endmacro(add_llvm_target)
 672
 673 # Add external project that may want to be built as part of llvm such as Clang,
 674 # lld, and Polly. This adds two options. One for the source directory of the
 675 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 676 # enable or disable building it with everything else.
 677 # Additional parameter can be specified as the name of directory.
 678 macro(add_llvm_external_project name)
 679   set(add_llvm_external_dir "${ARGN}")
 680   if("${add_llvm_external_dir}" STREQUAL "")
 681     set(add_llvm_external_dir ${name})
 682   endif()
 683   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 684   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 685   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 686   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 687       CACHE PATH "Path to ${name} source directory")
 688   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 689       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 690     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 691            "Whether to build ${name} as part of LLVM" ON)
 692     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 693       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 694     endif()
 695   endif()
 696 endmacro(add_llvm_external_project)
 697
 698 macro(add_llvm_tool_subdirectory name)
 699   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 700   add_subdirectory(${name})
 701 endmacro(add_llvm_tool_subdirectory)
 702
 703 macro(ignore_llvm_tool_subdirectory name)
 704   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 705 endmacro(ignore_llvm_tool_subdirectory)
 706
 707 function(add_llvm_implicit_external_projects)
 708   set(list_of_implicit_subdirs "")
 709   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 710   foreach(dir ${sub-dirs})
 711     if(IS_DIRECTORY "${dir}")
 712       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 713       if( tool_subdir_ignore EQUAL -1
 714           AND EXISTS "${dir}/CMakeLists.txt")
 715         get_filename_component(fn "${dir}" NAME)
 716         list(APPEND list_of_implicit_subdirs "${fn}")
 717       endif()
 718     endif()
 719   endforeach()
 720
 721   foreach(external_proj ${list_of_implicit_subdirs})
 722     add_llvm_external_project("${external_proj}")
 723   endforeach()
 724 endfunction(add_llvm_implicit_external_projects)
 725
 726 # Generic support for adding a unittest.
 727 function(add_unittest test_suite test_name)
 728   if( NOT LLVM_BUILD_TESTS )
 729     set(EXCLUDE_FROM_ALL ON)
 730   endif()
 731
 732   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 733   if (NOT LLVM_ENABLE_THREADS)
 734     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 735   endif ()
 736
 737   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 738     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 739   endif ()
 740
 741   set(LLVM_REQUIRES_RTTI OFF)
 742
 743   add_llvm_executable(${test_name} ${ARGN})
 744   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 745   set_output_directory(${test_name} ${outdir} ${outdir})
 746   target_link_libraries(${test_name}
 747     gtest
 748     gtest_main
 749     LLVMSupport # gtest needs it for raw_ostream.
 750     )
 751
 752   add_dependencies(${test_suite} ${test_name})
 753   get_target_property(test_suite_folder ${test_suite} FOLDER)
 754   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 755     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 756   endif ()
 757 endfunction()
 758
 759 function(llvm_add_go_executable binary pkgpath)
 760   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 761
 762   if(LLVM_BINDINGS MATCHES "go")
 763     # FIXME: This should depend only on the libraries Go needs.
 764     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 765     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 766     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 767     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 768     set(cppflags "")
 769     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 770     foreach(d ${include_dirs})
 771       set(cppflags "${cppflags} -I${d}")
 772     endforeach(d)
 773     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 774     add_custom_command(OUTPUT ${binpath}
 775       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
 776               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 777       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 778               ${llvmlibs} ${ARG_DEPENDS}
 779       COMMENT "Building Go executable ${binary}"
 780       VERBATIM)
 781     if (ARG_ALL)
 782       add_custom_target(${binary} ALL DEPENDS ${binpath})
 783     else()
 784       add_custom_target(${binary} DEPENDS ${binpath})
 785     endif()
 786   endif()
 787 endfunction()
 788
 789 # This function provides an automatic way to 'configure'-like generate a file
 790 # based on a set of common and custom variables, specifically targeting the
 791 # variables needed for the 'lit.site.cfg' files. This function bundles the
 792 # common variables that any Lit instance is likely to need, and custom
 793 # variables can be passed in.
 794 function(configure_lit_site_cfg input output)
 795   foreach(c ${LLVM_TARGETS_TO_BUILD})
 796     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 797   endforeach(c)
 798   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 799
 800   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 801
 802   # Configuration-time: See Unit/lit.site.cfg.in
 803   if (CMAKE_CFG_INTDIR STREQUAL ".")
 804     set(LLVM_BUILD_MODE ".")
 805   else ()
 806     set(LLVM_BUILD_MODE "%(build_mode)s")
 807   endif ()
 808
 809   # They below might not be the build tree but provided binary tree.
 810   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 811   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 812   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 813   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 814
 815   # SHLIBDIR points the build tree.
 816   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 817
 818   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 819   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 820   # plugins. We may rename it.
 821   if(LLVM_ENABLE_PLUGINS)
 822     set(ENABLE_SHARED "1")
 823   else()
 824     set(ENABLE_SHARED "0")
 825   endif()
 826
 827   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 828     set(ENABLE_ASSERTIONS "1")
 829   else()
 830     set(ENABLE_ASSERTIONS "0")
 831   endif()
 832
 833   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 834   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 835
 836   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 837   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 838   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 839
 840   configure_file(${input} ${output} @ONLY)
 841 endfunction()
 842
 843 # A raw function to create a lit target. This is used to implement the testuite
 844 # management functions.
 845 function(add_lit_target target comment)
 846   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 847   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 848   separate_arguments(LIT_ARGS)
 849   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 850     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 851   endif ()
 852   if (LLVM_MAIN_SRC_DIR)
 853     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 854   else()
 855     find_program(LIT_COMMAND llvm-lit)
 856   endif ()
 857   list(APPEND LIT_COMMAND ${LIT_ARGS})
 858   foreach(param ${ARG_PARAMS})
 859     list(APPEND LIT_COMMAND --param ${param})
 860   endforeach()
 861   if (ARG_DEFAULT_ARGS)
 862     add_custom_target(${target}
 863       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 864       COMMENT "${comment}"
 865       ${cmake_3_2_USES_TERMINAL}
 866       )
 867   else()
 868     add_custom_target(${target}
 869       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 870     message(STATUS "${target} does nothing.")
 871   endif()
 872   if (ARG_DEPENDS)
 873     add_dependencies(${target} ${ARG_DEPENDS})
 874   endif()
 875
 876   # Tests should be excluded from "Build Solution".
 877   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 878 endfunction()
 879
 880 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 881 function(add_lit_testsuite target comment)
 882   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 883
 884   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 885   if(NOT EXCLUDE_FROM_ALL)
 886     # Register the testsuites, params and depends for the global check rule.
 887     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 888     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 889     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 890     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 891   endif()
 892
 893   # Produce a specific suffixed check rule.
 894   add_lit_target(${target} ${comment}
 895     ${ARG_DEFAULT_ARGS}
 896     PARAMS ${ARG_PARAMS}
 897     DEPENDS ${ARG_DEPENDS}
 898     ARGS ${ARG_ARGS}
 899     )
 900 endfunction()
 901
 902 function(add_lit_testsuites project directory)
 903   if (NOT CMAKE_CONFIGURATION_TYPES)
 904     parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 905     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
 906     set(lit_suites)
 907     foreach(f ${litCfg})
 908       get_filename_component(dir ${f} DIRECTORY)
 909       set(lit_suites ${lit_suites} ${dir})
 910     endforeach()
 911     list(REMOVE_DUPLICATES lit_suites)
 912     foreach(dir ${lit_suites})
 913       string(REPLACE ${directory} "" name_slash ${dir})
 914       if (name_slash)
 915         string(REPLACE "/" "-" name_slash ${name_slash})
 916         string(REPLACE "\\" "-" name_dashes ${name_slash})
 917         string(TOLOWER "${project}${name_dashes}" name_var)
 918         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
 919           ${dir}
 920           PARAMS ${ARG_PARAMS}
 921           DEPENDS ${ARG_DEPENDS}
 922           ARGS ${ARG_ARGS}
 923         )
 924       endif()
 925     endforeach()
 926   endif()
 927 endfunction()