cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 if( UNIX AND NOT BEOS )
  15   # Used by check_symbol_exists:
  16   set(CMAKE_REQUIRED_LIBRARIES m)
  17 endif()
  18
  19 # Helper macros and functions
  20 macro(add_cxx_include result files)
  21   set(${result} "")
  22   foreach (file_name ${files})
  23      set(${result} "${${result}}#include<${file_name}>\n")
  24   endforeach()
  25 endmacro(add_cxx_include files result)
  26
  27 function(check_type_exists type files variable)
  28   add_cxx_include(includes "${files}")
  29   CHECK_CXX_SOURCE_COMPILES("
  30     ${includes} ${type} typeVar;
  31     int main() {
  32         return 0;
  33     }
  34     " ${variable})
  35 endfunction()
  36
  37 # include checks
  38 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
  39 check_include_file(dirent.h HAVE_DIRENT_H)
  40 check_include_file(dlfcn.h HAVE_DLFCN_H)
  41 check_include_file(errno.h HAVE_ERRNO_H)
  42 check_include_file(execinfo.h HAVE_EXECINFO_H)
  43 check_include_file(fcntl.h HAVE_FCNTL_H)
  44 check_include_file(inttypes.h HAVE_INTTYPES_H)
  45 check_include_file(limits.h HAVE_LIMITS_H)
  46 check_include_file(malloc.h HAVE_MALLOC_H)
  47 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  48 check_include_file(ndir.h HAVE_NDIR_H)
  49 if( NOT PURE_WINDOWS )
  50   check_include_file(pthread.h HAVE_PTHREAD_H)
  51 endif()
  52 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  53 check_include_file(signal.h HAVE_SIGNAL_H)
  54 check_include_file(stdint.h HAVE_STDINT_H)
  55 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  56 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  57 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  58 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  59 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  60 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  61 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  62 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  63 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  64 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  65 check_include_file(termios.h HAVE_TERMIOS_H)
  66 check_include_file(unistd.h HAVE_UNISTD_H)
  67 check_include_file(utime.h HAVE_UTIME_H)
  68 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  69 check_include_file(zlib.h HAVE_ZLIB_H)
  70 check_include_file(fenv.h HAVE_FENV_H)
  71 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  72 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  73
  74 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  75 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  76
  77 # library checks
  78 if( NOT PURE_WINDOWS )
  79   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  80   if (HAVE_LIBPTHREAD)
  81     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  82     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  83     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  84   else()
  85     # this could be Android
  86     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  87     if (PTHREAD_IN_LIBC)
  88       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  89       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  90       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  91     endif()
  92   endif()
  93   check_library_exists(dl dlopen "" HAVE_LIBDL)
  94   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
  95   if (LLVM_ENABLE_ZLIB)
  96     check_library_exists(z compress2 "" HAVE_LIBZ)
  97   else()
  98     set(HAVE_LIBZ 0)
  99   endif()
 100   check_library_exists(edit el_init "" HAVE_LIBEDIT)
 101   if(LLVM_ENABLE_TERMINFO)
 102     set(HAVE_TERMINFO 0)
 103     foreach(library tinfo terminfo curses ncurses ncursesw)
 104       string(TOUPPER ${library} library_suffix)
 105       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 106       if(HAVE_TERMINFO_${library_suffix})
 107         set(HAVE_TERMINFO 1)
 108         set(TERMINFO_LIBS "${library}")
 109         break()
 110       endif()
 111     endforeach()
 112   else()
 113     set(HAVE_TERMINFO 0)
 114   endif()
 115 endif()
 116
 117 # function checks
 118 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 119 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 120 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 121 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 122 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 123 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 124 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 125 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 126 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 127 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 128 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 129 check_symbol_exists(ceilf math.h HAVE_CEILF)
 130 check_symbol_exists(floorf math.h HAVE_FLOORF)
 131 check_symbol_exists(fmodf math.h HAVE_FMODF)
 132 check_symbol_exists(log math.h HAVE_LOG)
 133 check_symbol_exists(log2 math.h HAVE_LOG2)
 134 check_symbol_exists(log10 math.h HAVE_LOG10)
 135 check_symbol_exists(exp math.h HAVE_EXP)
 136 check_symbol_exists(exp2 math.h HAVE_EXP2)
 137 check_symbol_exists(exp10 math.h HAVE_EXP10)
 138 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 139 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 140 if( HAVE_SETJMP_H )
 141   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 142   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 143   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 144   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 145 endif()
 146 if( HAVE_SYS_UIO_H )
 147   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 148 endif()
 149 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 150 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 151 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 152                     HAVE_MALLOC_ZONE_STATISTICS)
 153 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 154 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 155 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 156 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 157 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 158 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 159 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 160 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 161 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 162 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 163 check_symbol_exists(pread unistd.h HAVE_PREAD)
 164 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 165 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 166 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 167 if( HAVE_RAND48_SRAND48 )
 168   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 169   if( HAVE_RAND48_LRAND48 )
 170     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 171     if( HAVE_RAND48_DRAND48 )
 172       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 173     endif()
 174   endif()
 175 endif()
 176 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 177 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 178 check_symbol_exists(strerror string.h HAVE_STRERROR)
 179 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 180 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 181 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 182 if( PURE_WINDOWS )
 183   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 184
 185   check_function_exists(_alloca HAVE__ALLOCA)
 186   check_function_exists(__alloca HAVE___ALLOCA)
 187   check_function_exists(__chkstk HAVE___CHKSTK)
 188   check_function_exists(___chkstk HAVE____CHKSTK)
 189
 190   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 191   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 192   check_function_exists(__divdi3 HAVE___DIVDI3)
 193   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 194   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 195   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 196   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 197   check_function_exists(__moddi3 HAVE___MODDI3)
 198   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 199   check_function_exists(__umoddi3 HAVE___UMODDI3)
 200
 201   check_function_exists(__main HAVE___MAIN)
 202   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 203 endif()
 204 if( HAVE_DLFCN_H )
 205   if( HAVE_LIBDL )
 206     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 207   endif()
 208   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 209   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 210   if( HAVE_LIBDL )
 211     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 212   endif()
 213 endif()
 214
 215 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 216 if( LLVM_USING_GLIBC )
 217   add_llvm_definitions( -D_GNU_SOURCE )
 218 endif()
 219
 220 set(headers "sys/types.h")
 221
 222 if (HAVE_INTTYPES_H)
 223   set(headers ${headers} "inttypes.h")
 224 endif()
 225
 226 if (HAVE_STDINT_H)
 227   set(headers ${headers} "stdint.h")
 228 endif()
 229
 230 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 231 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 232 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 233
 234 # available programs checks
 235 function(llvm_find_program name)
 236   string(TOUPPER ${name} NAME)
 237   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 238
 239   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 240   mark_as_advanced(LLVM_PATH_${NAME})
 241   if(LLVM_PATH_${NAME})
 242     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 243     mark_as_advanced(HAVE_${NAME})
 244   else(LLVM_PATH_${NAME})
 245     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 246   endif(LLVM_PATH_${NAME})
 247 endfunction()
 248
 249 llvm_find_program(gv)
 250 llvm_find_program(circo)
 251 llvm_find_program(twopi)
 252 llvm_find_program(neato)
 253 llvm_find_program(fdp)
 254 llvm_find_program(dot)
 255 llvm_find_program(dotty)
 256 llvm_find_program(xdot xdot.py)
 257 llvm_find_program(Graphviz)
 258
 259 if( LLVM_ENABLE_FFI )
 260   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 261   if( FFI_INCLUDE_PATH )
 262     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 263     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 264   else()
 265     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 266     if( FFI_INCLUDE_PATH )
 267       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 268       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 269     endif()
 270   endif()
 271
 272   if( NOT FFI_HEADER )
 273     message(FATAL_ERROR "libffi includes are not found.")
 274   endif()
 275
 276   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 277   if( NOT FFI_LIBRARY_PATH )
 278     message(FATAL_ERROR "libffi is not found.")
 279   endif()
 280
 281   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 282   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 283   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 284   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 285   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 286 else()
 287   unset(HAVE_FFI_FFI_H CACHE)
 288   unset(HAVE_FFI_H CACHE)
 289   unset(HAVE_FFI_CALL CACHE)
 290 endif( LLVM_ENABLE_FFI )
 291
 292 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 293 include(CheckAtomic)
 294
 295 if( LLVM_ENABLE_PIC )
 296   set(ENABLE_PIC 1)
 297 else()
 298   set(ENABLE_PIC 0)
 299 endif()
 300
 301 find_package(LibXml2)
 302 if (LIBXML2_FOUND)
 303   set(CLANG_HAVE_LIBXML 1)
 304   # When cross-compiling, liblzma is not detected as a dependency for libxml2,
 305   # which makes linking c-index-test fail. But for native builds, all libraries
 306   # are installed and checked by CMake before Makefiles are generated and everything
 307   # works according to the plan. However, if a -llzma is added to native builds,
 308   # an additional requirement on the static liblzma.a is required, but will not
 309   # be checked by CMake, breaking native compilation.
 310   # Since this is only pertinent to cross-compilations, and there's no way CMake
 311   # can check for every foreign library on every OS, we add the dep and warn the dev.
 312   if ( CMAKE_CROSSCOMPILING )
 313     if (NOT PC_LIBXML_VERSION VERSION_LESS "2.8.0")
 314       message(STATUS "Adding LZMA as a dep to XML2 for cross-compilation, make sure liblzma.a is available.")
 315       set(LIBXML2_LIBRARIES ${LIBXML2_LIBRARIES} "-llzma")
 316     endif ()
 317   endif ()
 318 endif ()
 319
 320 include(CheckCXXCompilerFlag)
 321
 322 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 323
 324 set(USE_NO_MAYBE_UNINITIALIZED 0)
 325 set(USE_NO_UNINITIALIZED 0)
 326
 327 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 328 # false positives.
 329 if (CMAKE_COMPILER_IS_GNUCXX)
 330   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 331   if (HAS_MAYBE_UNINITIALIZED)
 332     set(USE_NO_MAYBE_UNINITIALIZED 1)
 333   else()
 334     # Only recent versions of gcc make the distinction between -Wuninitialized
 335     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 336     # turn off all uninitialized use warnings.
 337     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 338     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 339   endif()
 340 endif()
 341
 342 # By default, we target the host, but this can be overridden at CMake
 343 # invocation time.
 344 include(GetHostTriple)
 345 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 346
 347 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 348     "Host on which LLVM binaries will run")
 349
 350 # Determine the native architecture.
 351 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 352 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 353   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 354 endif ()
 355
 356 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 357   set(LLVM_NATIVE_ARCH X86)
 358 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 359   set(LLVM_NATIVE_ARCH X86)
 360 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 361   set(LLVM_NATIVE_ARCH X86)
 362 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 363   set(LLVM_NATIVE_ARCH X86)
 364 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 365   set(LLVM_NATIVE_ARCH Sparc)
 366 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 367   set(LLVM_NATIVE_ARCH PowerPC)
 368 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 369   set(LLVM_NATIVE_ARCH AArch64)
 370 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 371   set(LLVM_NATIVE_ARCH ARM)
 372 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 373   set(LLVM_NATIVE_ARCH Mips)
 374 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 375   set(LLVM_NATIVE_ARCH XCore)
 376 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 377   set(LLVM_NATIVE_ARCH MSP430)
 378 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 379   set(LLVM_NATIVE_ARCH Hexagon)
 380 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 381   set(LLVM_NATIVE_ARCH SystemZ)
 382 else ()
 383   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 384 endif ()
 385
 386 # If build targets includes "host", then replace with native architecture.
 387 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 388 if( NOT idx LESS 0 )
 389   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 390   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 391   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 392 endif()
 393
 394 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 395 if (NATIVE_ARCH_IDX EQUAL -1)
 396   message(STATUS
 397     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 398 else ()
 399   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 400   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 401   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 402   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 403   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 404
 405   # We don't have an ASM parser for all architectures yet.
 406   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 407     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 408   endif ()
 409
 410   # We don't have an disassembler for all architectures yet.
 411   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 412     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 413   endif ()
 414 endif ()
 415
 416 if( MINGW )
 417   set(HAVE_LIBIMAGEHLP 1)
 418   set(HAVE_LIBPSAPI 1)
 419   set(HAVE_LIBSHELL32 1)
 420   # TODO: Check existence of libraries.
 421   #   include(CheckLibraryExists)
 422   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 423 endif( MINGW )
 424
 425 if (NOT HAVE_STRTOLL)
 426   # Use _strtoi64 if strtoll is not available.
 427   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 428   if (have_strtoi64)
 429     set(HAVE_STRTOLL 1)
 430     set(strtoll "_strtoi64")
 431     set(strtoull "_strtoui64")
 432   endif ()
 433 endif ()
 434
 435 if( MSVC )
 436   set(SHLIBEXT ".lib")
 437   set(stricmp "_stricmp")
 438   set(strdup "_strdup")
 439 endif( MSVC )
 440
 441 if( PURE_WINDOWS )
 442   CHECK_CXX_SOURCE_COMPILES("
 443     #include <windows.h>
 444     #include <imagehlp.h>
 445     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 446     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 447     int main(){return 0;}"
 448     HAVE_ELMCB_PCSTR)
 449   if( HAVE_ELMCB_PCSTR )
 450     set(WIN32_ELMCB_PCSTR "PCSTR")
 451   else()
 452     set(WIN32_ELMCB_PCSTR "PSTR")
 453   endif()
 454 endif( PURE_WINDOWS )
 455
 456 # FIXME: Signal handler return type, currently hardcoded to 'void'
 457 set(RETSIGTYPE void)
 458
 459 if( LLVM_ENABLE_THREADS )
 460   # Check if threading primitives aren't supported on this platform
 461   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 462     set(LLVM_ENABLE_THREADS 0)
 463   endif()
 464 endif()
 465
 466 if( LLVM_ENABLE_THREADS )
 467   message(STATUS "Threads enabled.")
 468 else( LLVM_ENABLE_THREADS )
 469   message(STATUS "Threads disabled.")
 470 endif()
 471
 472 if (LLVM_ENABLE_ZLIB )
 473   # Check if zlib is available in the system.
 474   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 475     set(LLVM_ENABLE_ZLIB 0)
 476   endif()
 477 endif()
 478
 479 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 480
 481 if (LLVM_ENABLE_DOXYGEN)
 482   message(STATUS "Doxygen enabled.")
 483   find_package(Doxygen)
 484
 485   if (DOXYGEN_FOUND)
 486     # If we find doxygen and we want to enable doxygen by default create a
 487     # global aggregate doxygen target for generating llvm and any/all
 488     # subprojects doxygen documentation.
 489     if (LLVM_BUILD_DOCS)
 490       add_custom_target(doxygen ALL)
 491     endif()
 492
 493     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 494     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 495       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external searhc.")
 496       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 497     endif()
 498   endif()
 499 else()
 500   message(STATUS "Doxygen disabled.")
 501 endif()