cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 if( UNIX AND NOT BEOS )
  15   # Used by check_symbol_exists:
  16   set(CMAKE_REQUIRED_LIBRARIES m)
  17 endif()
  18
  19 # Helper macros and functions
  20 macro(add_cxx_include result files)
  21   set(${result} "")
  22   foreach (file_name ${files})
  23      set(${result} "${${result}}#include<${file_name}>\n")
  24   endforeach()
  25 endmacro(add_cxx_include files result)
  26
  27 function(check_type_exists type files variable)
  28   add_cxx_include(includes "${files}")
  29   CHECK_CXX_SOURCE_COMPILES("
  30     ${includes} ${type} typeVar;
  31     int main() {
  32         return 0;
  33     }
  34     " ${variable})
  35 endfunction()
  36
  37 # include checks
  38 check_include_file(argz.h HAVE_ARGZ_H)
  39 check_include_file(assert.h HAVE_ASSERT_H)
  40 check_include_file(ctype.h HAVE_CTYPE_H)
  41 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
  42 check_include_file(dirent.h HAVE_DIRENT_H)
  43 check_include_file(dl.h HAVE_DL_H)
  44 check_include_file(dld.h HAVE_DLD_H)
  45 check_include_file(dlfcn.h HAVE_DLFCN_H)
  46 check_include_file(errno.h HAVE_ERRNO_H)
  47 check_include_file(execinfo.h HAVE_EXECINFO_H)
  48 check_include_file(fcntl.h HAVE_FCNTL_H)
  49 check_include_file(inttypes.h HAVE_INTTYPES_H)
  50 check_include_file(limits.h HAVE_LIMITS_H)
  51 check_include_file(link.h HAVE_LINK_H)
  52 check_include_file(malloc.h HAVE_MALLOC_H)
  53 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  54 check_include_file(memory.h HAVE_MEMORY_H)
  55 check_include_file(ndir.h HAVE_NDIR_H)
  56 if( NOT PURE_WINDOWS )
  57   check_include_file(pthread.h HAVE_PTHREAD_H)
  58 endif()
  59 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  60 check_include_file(setjmp.h HAVE_SETJMP_H)
  61 check_include_file(signal.h HAVE_SIGNAL_H)
  62 check_include_file(stdint.h HAVE_STDINT_H)
  63 check_include_file(stdio.h HAVE_STDIO_H)
  64 check_include_file(stdlib.h HAVE_STDLIB_H)
  65 check_include_file(string.h HAVE_STRING_H)
  66 check_include_file(strings.h HAVE_STRINGS_H)
  67 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  68 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  69 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  70 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  71 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  72 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  73 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  74 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  75 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  76 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  77 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  78 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  79 check_include_file(termios.h HAVE_TERMIOS_H)
  80 check_include_file(unistd.h HAVE_UNISTD_H)
  81 check_include_file(utime.h HAVE_UTIME_H)
  82 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  83 check_include_file(windows.h HAVE_WINDOWS_H)
  84 check_include_file(zlib.h HAVE_ZLIB_H)
  85 check_include_file(fenv.h HAVE_FENV_H)
  86 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  87 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  88
  89 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  90 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  91
  92 # library checks
  93 if( NOT PURE_WINDOWS )
  94   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  95   if (HAVE_LIBPTHREAD)
  96     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  97     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  98     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  99   else()
 100     # this could be Android
 101     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
 102     if (PTHREAD_IN_LIBC)
 103       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
 104       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
 105       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
 106     endif()
 107   endif()
 108   check_library_exists(dl dlopen "" HAVE_LIBDL)
 109   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 110   if (LLVM_ENABLE_ZLIB)
 111     check_library_exists(z compress2 "" HAVE_LIBZ)
 112   else()
 113     set(HAVE_LIBZ 0)
 114   endif()
 115 endif()
 116
 117 # function checks
 118 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 119 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 120 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 121 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 122 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 123 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 124 check_symbol_exists(index strings.h HAVE_INDEX)
 125 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 126 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 127 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 128 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 129 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 130 check_symbol_exists(ceilf math.h HAVE_CEILF)
 131 check_symbol_exists(floorf math.h HAVE_FLOORF)
 132 check_symbol_exists(fmodf math.h HAVE_FMODF)
 133 check_symbol_exists(log math.h HAVE_LOG)
 134 check_symbol_exists(log2 math.h HAVE_LOG2)
 135 check_symbol_exists(log10 math.h HAVE_LOG10)
 136 check_symbol_exists(exp math.h HAVE_EXP)
 137 check_symbol_exists(exp2 math.h HAVE_EXP2)
 138 check_symbol_exists(exp10 math.h HAVE_EXP10)
 139 if( HAVE_SETJMP_H )
 140   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 141   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 142   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 143   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 144 endif()
 145 if( HAVE_SYS_UIO_H )
 146   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 147 endif()
 148 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 149 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 150 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 151                     HAVE_MALLOC_ZONE_STATISTICS)
 152 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 153 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 154 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 155 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 156 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 157 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 158 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 159 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 160 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 161 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 162 check_symbol_exists(pread unistd.h HAVE_PREAD)
 163 check_symbol_exists(rindex strings.h HAVE_RINDEX)
 164 check_symbol_exists(strchr string.h HAVE_STRCHR)
 165 check_symbol_exists(strcmp string.h HAVE_STRCMP)
 166 check_symbol_exists(strdup string.h HAVE_STRDUP)
 167 check_symbol_exists(strrchr string.h HAVE_STRRCHR)
 168 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 169 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 170 if( HAVE_RAND48_SRAND48 )
 171   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 172   if( HAVE_RAND48_LRAND48 )
 173     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 174     if( HAVE_RAND48_DRAND48 )
 175       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 176     endif()
 177   endif()
 178 endif()
 179 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 180 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 181 check_symbol_exists(strerror string.h HAVE_STRERROR)
 182 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 183 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 184 check_symbol_exists(memcpy string.h HAVE_MEMCPY)
 185 check_symbol_exists(memmove string.h HAVE_MEMMOVE)
 186 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 187 if( PURE_WINDOWS )
 188   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 189
 190   check_function_exists(_alloca HAVE__ALLOCA)
 191   check_function_exists(__alloca HAVE___ALLOCA)
 192   check_function_exists(__chkstk HAVE___CHKSTK)
 193   check_function_exists(___chkstk HAVE____CHKSTK)
 194
 195   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 196   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 197   check_function_exists(__divdi3 HAVE___DIVDI3)
 198   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 199   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 200   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 201   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 202   check_function_exists(__moddi3 HAVE___MODDI3)
 203   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 204   check_function_exists(__umoddi3 HAVE___UMODDI3)
 205
 206   check_function_exists(__main HAVE___MAIN)
 207   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 208 endif()
 209 if( HAVE_ARGZ_H )
 210   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 211   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 212   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 213   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 214   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 215 endif()
 216 if( HAVE_DLFCN_H )
 217   if( HAVE_LIBDL )
 218     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 219   endif()
 220   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 221   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 222   if( HAVE_LIBDL )
 223     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 224   endif()
 225 endif()
 226
 227 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 228 if( LLVM_USING_GLIBC )
 229   add_llvm_definitions( -D_GNU_SOURCE )
 230 endif()
 231
 232 set(headers "")
 233 if (HAVE_SYS_TYPES_H)
 234   set(headers ${headers} "sys/types.h")
 235 endif()
 236
 237 if (HAVE_INTTYPES_H)
 238   set(headers ${headers} "inttypes.h")
 239 endif()
 240
 241 if (HAVE_STDINT_H)
 242   set(headers ${headers} "stdint.h")
 243 endif()
 244
 245 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 246 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 247 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 248 check_type_exists(error_t errno.h HAVE_ERROR_T)
 249
 250 # available programs checks
 251 function(llvm_find_program name)
 252   string(TOUPPER ${name} NAME)
 253   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 254   find_program(LLVM_PATH_${NAME} ${name})
 255   mark_as_advanced(LLVM_PATH_${NAME})
 256   if(LLVM_PATH_${NAME})
 257     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 258     mark_as_advanced(HAVE_${NAME})
 259   else(LLVM_PATH_${NAME})
 260     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 261   endif(LLVM_PATH_${NAME})
 262 endfunction()
 263
 264 llvm_find_program(gv)
 265 llvm_find_program(circo)
 266 llvm_find_program(twopi)
 267 llvm_find_program(neato)
 268 llvm_find_program(fdp)
 269 llvm_find_program(dot)
 270 llvm_find_program(dotty)
 271 llvm_find_program(xdot.py)
 272 llvm_find_program(Graphviz)
 273
 274 if( LLVM_ENABLE_FFI )
 275   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 276   if( FFI_INCLUDE_PATH )
 277     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 278     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 279   else()
 280     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 281     if( FFI_INCLUDE_PATH )
 282       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 283       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 284     endif()
 285   endif()
 286
 287   if( NOT FFI_HEADER )
 288     message(FATAL_ERROR "libffi includes are not found.")
 289   endif()
 290
 291   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 292   if( NOT FFI_LIBRARY_PATH )
 293     message(FATAL_ERROR "libffi is not found.")
 294   endif()
 295
 296   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 297   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 298   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 299   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 300   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 301 else()
 302   unset(HAVE_FFI_FFI_H CACHE)
 303   unset(HAVE_FFI_H CACHE)
 304   unset(HAVE_FFI_CALL CACHE)
 305 endif( LLVM_ENABLE_FFI )
 306
 307 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 308 include(CheckAtomic)
 309
 310 if( LLVM_ENABLE_PIC )
 311   set(ENABLE_PIC 1)
 312 else()
 313   set(ENABLE_PIC 0)
 314 endif()
 315
 316 find_package(LibXml2)
 317 if (LIBXML2_FOUND)
 318   set(CLANG_HAVE_LIBXML 1)
 319 endif ()
 320
 321 include(CheckCXXCompilerFlag)
 322
 323 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 324
 325 set(USE_NO_MAYBE_UNINITIALIZED 0)
 326 set(USE_NO_UNINITIALIZED 0)
 327
 328 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 329 # false positives.
 330 if (CMAKE_COMPILER_IS_GNUCXX)
 331   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 332   if (HAS_MAYBE_UNINITIALIZED)
 333     set(USE_NO_MAYBE_UNINITIALIZED 1)
 334   else()
 335     # Only recent versions of gcc make the distinction between -Wuninitialized
 336     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 337     # turn off all uninitialized use warnings.
 338     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 339     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 340   endif()
 341 endif()
 342
 343 # By default, we target the host, but this can be overridden at CMake
 344 # invocation time.
 345 include(GetHostTriple)
 346 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 347
 348 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 349     "Host on which LLVM binaries will run")
 350
 351 # Determine the native architecture.
 352 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 353 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 354   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 355 endif ()
 356
 357 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 358   set(LLVM_NATIVE_ARCH X86)
 359 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 360   set(LLVM_NATIVE_ARCH X86)
 361 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 362   set(LLVM_NATIVE_ARCH X86)
 363 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 364   set(LLVM_NATIVE_ARCH X86)
 365 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 366   set(LLVM_NATIVE_ARCH Sparc)
 367 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 368   set(LLVM_NATIVE_ARCH PowerPC)
 369 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 370   set(LLVM_NATIVE_ARCH AArch64)
 371 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 372   set(LLVM_NATIVE_ARCH ARM)
 373 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 374   set(LLVM_NATIVE_ARCH Mips)
 375 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 376   set(LLVM_NATIVE_ARCH XCore)
 377 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 378   set(LLVM_NATIVE_ARCH MSP430)
 379 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 380   set(LLVM_NATIVE_ARCH Hexagon)
 381 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 382   set(LLVM_NATIVE_ARCH SystemZ)
 383 else ()
 384   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 385 endif ()
 386
 387 # If build targets includes "host", then replace with native architecture.
 388 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 389 if( NOT idx LESS 0 )
 390   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 391   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 392   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 393 endif()
 394
 395 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 396 if (NATIVE_ARCH_IDX EQUAL -1)
 397   message(STATUS
 398     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 399 else ()
 400   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 401   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 402   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 403   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 404   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 405
 406   # We don't have an ASM parser for all architectures yet.
 407   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 408     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 409   endif ()
 410
 411   # We don't have an disassembler for all architectures yet.
 412   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 413     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 414   endif ()
 415 endif ()
 416
 417 if( MINGW )
 418   set(HAVE_LIBIMAGEHLP 1)
 419   set(HAVE_LIBPSAPI 1)
 420   # TODO: Check existence of libraries.
 421   #   include(CheckLibraryExists)
 422   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 423 endif( MINGW )
 424
 425 if( MSVC )
 426   set(error_t int)
 427   set(LTDL_SYSSEARCHPATH "")
 428   set(LTDL_DLOPEN_DEPLIBS 1)
 429   set(SHLIBEXT ".lib")
 430   set(LTDL_OBJDIR "_libs")
 431   set(HAVE_STRTOLL 1)
 432   set(strtoll "_strtoi64")
 433   set(strtoull "_strtoui64")
 434   set(stricmp "_stricmp")
 435   set(strdup "_strdup")
 436 else( MSVC )
 437   set(LTDL_SYSSEARCHPATH "") # TODO
 438   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 439 endif( MSVC )
 440
 441 if( PURE_WINDOWS )
 442   CHECK_CXX_SOURCE_COMPILES("
 443     #include <windows.h>
 444     #include <imagehlp.h>
 445     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 446     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 447     int main(){return 0;}"
 448     HAVE_ELMCB_PCSTR)
 449   if( HAVE_ELMCB_PCSTR )
 450     set(WIN32_ELMCB_PCSTR "PCSTR")
 451   else()
 452     set(WIN32_ELMCB_PCSTR "PSTR")
 453   endif()
 454 endif( PURE_WINDOWS )
 455
 456 # FIXME: Signal handler return type, currently hardcoded to 'void'
 457 set(RETSIGTYPE void)
 458
 459 if( LLVM_ENABLE_THREADS )
 460   # Check if threading primitives aren't supported on this platform
 461   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 462     set(LLVM_ENABLE_THREADS 0)
 463   endif()
 464 endif()
 465
 466 if( LLVM_ENABLE_THREADS )
 467   message(STATUS "Threads enabled.")
 468 else( LLVM_ENABLE_THREADS )
 469   message(STATUS "Threads disabled.")
 470 endif()
 471
 472 if (LLVM_ENABLE_ZLIB )
 473   # Check if zlib is available in the system.
 474   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 475     set(LLVM_ENABLE_ZLIB 0)
 476   endif()
 477 endif()
 478
 479 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})