cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckLibraryExists)
   8 include(CheckSymbolExists)
   9 include(CheckFunctionExists)
  10 include(CheckCXXSourceCompiles)
  11 include(TestBigEndian)
  12
  13 if( UNIX AND NOT BEOS )
  14   # Used by check_symbol_exists:
  15   set(CMAKE_REQUIRED_LIBRARIES m)
  16 endif()
  17
  18 # Helper macros and functions
  19 macro(add_cxx_include result files)
  20   set(${result} "")
  21   foreach (file_name ${files})
  22      set(${result} "${${result}}#include<${file_name}>\n")
  23   endforeach()
  24 endmacro(add_cxx_include files result)
  25
  26 function(check_type_exists type files variable)
  27   add_cxx_include(includes "${files}")
  28   CHECK_CXX_SOURCE_COMPILES("
  29     ${includes} ${type} typeVar;
  30     int main() {
  31         return 0;
  32     }
  33     " ${variable})
  34 endfunction()
  35
  36 # include checks
  37 check_include_file(argz.h HAVE_ARGZ_H)
  38 check_include_file(assert.h HAVE_ASSERT_H)
  39 check_include_file(ctype.h HAVE_CTYPE_H)
  40 check_include_file(dirent.h HAVE_DIRENT_H)
  41 check_include_file(dl.h HAVE_DL_H)
  42 check_include_file(dld.h HAVE_DLD_H)
  43 check_include_file(dlfcn.h HAVE_DLFCN_H)
  44 check_include_file(errno.h HAVE_ERRNO_H)
  45 check_include_file(execinfo.h HAVE_EXECINFO_H)
  46 check_include_file(fcntl.h HAVE_FCNTL_H)
  47 check_include_file(inttypes.h HAVE_INTTYPES_H)
  48 check_include_file(limits.h HAVE_LIMITS_H)
  49 check_include_file(link.h HAVE_LINK_H)
  50 check_include_file(malloc.h HAVE_MALLOC_H)
  51 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  52 check_include_file(memory.h HAVE_MEMORY_H)
  53 check_include_file(ndir.h HAVE_NDIR_H)
  54 if( NOT PURE_WINDOWS )
  55   check_include_file(pthread.h HAVE_PTHREAD_H)
  56 endif()
  57 check_include_file(setjmp.h HAVE_SETJMP_H)
  58 check_include_file(signal.h HAVE_SIGNAL_H)
  59 check_include_file(stdint.h HAVE_STDINT_H)
  60 check_include_file(stdio.h HAVE_STDIO_H)
  61 check_include_file(stdlib.h HAVE_STDLIB_H)
  62 check_include_file(string.h HAVE_STRING_H)
  63 check_include_file(strings.h HAVE_STRINGS_H)
  64 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  65 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  66 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  67 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  68 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  69 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  70 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  71 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  72 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  73 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  74 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  75 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  76 check_include_file(termios.h HAVE_TERMIOS_H)
  77 check_include_file(unistd.h HAVE_UNISTD_H)
  78 check_include_file(utime.h HAVE_UTIME_H)
  79 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  80 check_include_file(windows.h HAVE_WINDOWS_H)
  81 check_include_file(fenv.h HAVE_FENV_H)
  82 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  83 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  84
  85 # library checks
  86 if( NOT PURE_WINDOWS )
  87   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  88   check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  89   check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  90   check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  91   check_library_exists(dl dlopen "" HAVE_LIBDL)
  92 endif()
  93
  94 # function checks
  95 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
  96 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  97 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  98 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  99 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 100 check_symbol_exists(index strings.h HAVE_INDEX)
 101 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 102 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 103 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 104 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 105 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 106 check_symbol_exists(ceilf math.h HAVE_CEILF)
 107 check_symbol_exists(floorf math.h HAVE_FLOORF)
 108 check_symbol_exists(fmodf math.h HAVE_FMODF)
 109 if( HAVE_SETJMP_H )
 110   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 111   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 112   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 113   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 114 endif()
 115 if( HAVE_SYS_UIO_H )
 116   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 117 endif()
 118 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 119 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 120 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 121                     HAVE_MALLOC_ZONE_STATISTICS)
 122 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 123 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 124 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 125 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 126 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 127 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 128 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 129 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 130 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 131 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 132 check_symbol_exists(pread unistd.h HAVE_PREAD)
 133 check_symbol_exists(rindex strings.h HAVE_RINDEX)
 134 check_symbol_exists(strchr string.h HAVE_STRCHR)
 135 check_symbol_exists(strcmp string.h HAVE_STRCMP)
 136 check_symbol_exists(strdup string.h HAVE_STRDUP)
 137 check_symbol_exists(strrchr string.h HAVE_STRRCHR)
 138 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 139 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 140 if( HAVE_RAND48_SRAND48 )
 141   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 142   if( HAVE_RAND48_LRAND48 )
 143     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 144     if( HAVE_RAND48_DRAND48 )
 145       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 146     endif()
 147   endif()
 148 endif()
 149 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 150 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 151 check_symbol_exists(strerror string.h HAVE_STRERROR)
 152 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 153 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 154 check_symbol_exists(memcpy string.h HAVE_MEMCPY)
 155 check_symbol_exists(memmove string.h HAVE_MEMMOVE)
 156 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 157 if( PURE_WINDOWS )
 158   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 159
 160   check_function_exists(_alloca HAVE__ALLOCA)
 161   check_function_exists(__alloca HAVE___ALLOCA)
 162   check_function_exists(__chkstk HAVE___CHKSTK)
 163   check_function_exists(___chkstk HAVE____CHKSTK)
 164
 165   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 166   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 167   check_function_exists(__divdi3 HAVE___DIVDI3)
 168   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 169   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 170   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 171   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 172   check_function_exists(__moddi3 HAVE___MODDI3)
 173   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 174   check_function_exists(__umoddi3 HAVE___UMODDI3)
 175
 176   check_function_exists(__main HAVE___MAIN)
 177   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 178 endif()
 179 if( HAVE_ARGZ_H )
 180   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 181   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 182   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 183   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 184   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 185 endif()
 186 if( HAVE_DLFCN_H )
 187   if( HAVE_LIBDL )
 188     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 189   endif()
 190   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 191   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 192   if( HAVE_LIBDL )
 193     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 194   endif()
 195 endif()
 196
 197 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 198 if( LLVM_USING_GLIBC )
 199   add_llvm_definitions( -D_GNU_SOURCE )
 200 endif()
 201
 202 set(headers "")
 203 if (HAVE_SYS_TYPES_H)
 204   set(headers ${headers} "sys/types.h")
 205 endif()
 206
 207 if (HAVE_INTTYPES_H)
 208   set(headers ${headers} "inttypes.h")
 209 endif()
 210
 211 if (HAVE_STDINT_H)
 212   set(headers ${headers} "stdint.h")
 213 endif()
 214
 215 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 216 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 217 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 218 check_type_exists(error_t errno.h HAVE_ERROR_T)
 219
 220 # available programs checks
 221 function(llvm_find_program name)
 222   string(TOUPPER ${name} NAME)
 223   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 224   find_program(LLVM_PATH_${NAME} ${name})
 225   mark_as_advanced(LLVM_PATH_${NAME})
 226   if(LLVM_PATH_${NAME})
 227     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 228     mark_as_advanced(HAVE_${NAME})
 229   else(LLVM_PATH_${NAME})
 230     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 231   endif(LLVM_PATH_${NAME})
 232 endfunction()
 233
 234 llvm_find_program(gv)
 235 llvm_find_program(circo)
 236 llvm_find_program(twopi)
 237 llvm_find_program(neato)
 238 llvm_find_program(fdp)
 239 llvm_find_program(dot)
 240 llvm_find_program(dotty)
 241 llvm_find_program(xdot.py)
 242 llvm_find_program(Graphviz)
 243
 244 if( LLVM_ENABLE_FFI )
 245   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 246   if( FFI_INCLUDE_PATH )
 247     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 248     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 249   else()
 250     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 251     if( FFI_INCLUDE_PATH )
 252       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 253       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 254     endif()
 255   endif()
 256
 257   if( NOT FFI_HEADER )
 258     message(FATAL_ERROR "libffi includes are not found.")
 259   endif()
 260
 261   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 262   if( NOT FFI_LIBRARY_PATH )
 263     message(FATAL_ERROR "libffi is not found.")
 264   endif()
 265
 266   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 267   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 268   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 269   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 270   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 271 else()
 272   unset(HAVE_FFI_FFI_H CACHE)
 273   unset(HAVE_FFI_H CACHE)
 274   unset(HAVE_FFI_CALL CACHE)
 275 endif( LLVM_ENABLE_FFI )
 276
 277 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 278 include(CheckAtomic)
 279
 280 if( LLVM_ENABLE_PIC )
 281   set(ENABLE_PIC 1)
 282 else()
 283   set(ENABLE_PIC 0)
 284 endif()
 285
 286 include(CheckCXXCompilerFlag)
 287
 288 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 289
 290 include(GetHostTriple)
 291 get_host_triple(LLVM_HOST_TRIPLE)
 292
 293 # By default, we target the host, but this can be overridden at CMake
 294 # invocation time.
 295 set(LLVM_HOSTTRIPLE "${LLVM_HOST_TRIPLE}")
 296
 297 # Determine the native architecture.
 298 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 299 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 300   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 301 endif ()
 302
 303 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 304   set(LLVM_NATIVE_ARCH X86)
 305 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 306   set(LLVM_NATIVE_ARCH X86)
 307 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 308   set(LLVM_NATIVE_ARCH X86)
 309 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 310   set(LLVM_NATIVE_ARCH X86)
 311 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 312   set(LLVM_NATIVE_ARCH Sparc)
 313 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 314   set(LLVM_NATIVE_ARCH PowerPC)
 315 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 316   set(LLVM_NATIVE_ARCH ARM)
 317 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 318   set(LLVM_NATIVE_ARCH Mips)
 319 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 320   set(LLVM_NATIVE_ARCH XCore)
 321 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 322   set(LLVM_NATIVE_ARCH MSP430)
 323 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 324   set(LLVM_NATIVE_ARCH Hexagon)
 325 else ()
 326   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 327 endif ()
 328
 329 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 330 if (NATIVE_ARCH_IDX EQUAL -1)
 331   message(STATUS
 332     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 333 else ()
 334   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 335   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 336   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 337   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 338   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 339
 340   # We don't have an ASM parser for all architectures yet.
 341   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 342     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 343   endif ()
 344
 345   # We don't have an disassembler for all architectures yet.
 346   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 347     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 348   endif ()
 349 endif ()
 350
 351 if( MINGW )
 352   set(HAVE_LIBIMAGEHLP 1)
 353   set(HAVE_LIBPSAPI 1)
 354   # TODO: Check existence of libraries.
 355   #   include(CheckLibraryExists)
 356   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 357 endif( MINGW )
 358
 359 if( MSVC )
 360   set(error_t int)
 361   set(LTDL_SHLIBPATH_VAR "PATH")
 362   set(LTDL_SYSSEARCHPATH "")
 363   set(LTDL_DLOPEN_DEPLIBS 1)
 364   set(SHLIBEXT ".lib")
 365   set(LTDL_OBJDIR "_libs")
 366   set(HAVE_STRTOLL 1)
 367   set(strtoll "_strtoi64")
 368   set(strtoull "_strtoui64")
 369   set(stricmp "_stricmp")
 370   set(strdup "_strdup")
 371 else( MSVC )
 372   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 373   set(LTDL_SYSSEARCHPATH "") # TODO
 374   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 375 endif( MSVC )
 376
 377 if( PURE_WINDOWS )
 378   CHECK_CXX_SOURCE_COMPILES("
 379     #include <windows.h>
 380     #include <imagehlp.h>
 381     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 382     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 383     int main(){return 0;}"
 384     HAVE_ELMCB_PCSTR)
 385   if( HAVE_ELMCB_PCSTR )
 386     set(WIN32_ELMCB_PCSTR "PCSTR")
 387   else()
 388     set(WIN32_ELMCB_PCSTR "PSTR")
 389   endif()
 390 endif( PURE_WINDOWS )
 391
 392 # FIXME: Signal handler return type, currently hardcoded to 'void'
 393 set(RETSIGTYPE void)
 394
 395 if( LLVM_ENABLE_THREADS )
 396   # Check if threading primitives aren't supported on this platform
 397   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 398     set(LLVM_ENABLE_THREADS 0)
 399   endif()
 400 endif()
 401
 402 if( LLVM_ENABLE_THREADS )
 403   message(STATUS "Threads enabled.")
 404 else( LLVM_ENABLE_THREADS )
 405   message(STATUS "Threads disabled.")
 406 endif()
 407
 408 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})