cmake/config-ix.cmake

   1 include(CheckIncludeFile)
   2 include(CheckLibraryExists)
   3 include(CheckSymbolExists)
   4 include(CheckFunctionExists)
   5 include(CheckCXXSourceCompiles)
   6 include(TestBigEndian)
   7
   8 if( UNIX AND NOT BEOS )
   9   # Used by check_symbol_exists:
  10   set(CMAKE_REQUIRED_LIBRARIES m)
  11 endif()
  12
  13 # Helper macros and functions
  14 macro(add_cxx_include result files)
  15   set(${result} "")
  16   foreach (file_name ${files})
  17      set(${result} "${${result}}#include<${file_name}>\n")
  18   endforeach()
  19 endmacro(add_cxx_include files result)
  20
  21 function(check_type_exists type files variable)
  22   add_cxx_include(includes "${files}")
  23   CHECK_CXX_SOURCE_COMPILES("
  24     ${includes} ${type} typeVar;
  25     int main() {
  26         return 0;
  27     }
  28     " ${variable})
  29 endfunction()
  30
  31 # include checks
  32 check_include_file(argz.h HAVE_ARGZ_H)
  33 check_include_file(assert.h HAVE_ASSERT_H)
  34 check_include_file(ctype.h HAVE_CTYPE_H)
  35 check_include_file(dirent.h HAVE_DIRENT_H)
  36 check_include_file(dl.h HAVE_DL_H)
  37 check_include_file(dld.h HAVE_DLD_H)
  38 check_include_file(dlfcn.h HAVE_DLFCN_H)
  39 check_include_file(errno.h HAVE_ERRNO_H)
  40 check_include_file(execinfo.h HAVE_EXECINFO_H)
  41 check_include_file(fcntl.h HAVE_FCNTL_H)
  42 check_include_file(inttypes.h HAVE_INTTYPES_H)
  43 check_include_file(limits.h HAVE_LIMITS_H)
  44 check_include_file(link.h HAVE_LINK_H)
  45 check_include_file(malloc.h HAVE_MALLOC_H)
  46 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  47 check_include_file(memory.h HAVE_MEMORY_H)
  48 check_include_file(ndir.h HAVE_NDIR_H)
  49 if( NOT LLVM_ON_WIN32 )
  50   check_include_file(pthread.h HAVE_PTHREAD_H)
  51 endif()
  52 check_include_file(setjmp.h HAVE_SETJMP_H)
  53 check_include_file(signal.h HAVE_SIGNAL_H)
  54 check_include_file(stdint.h HAVE_STDINT_H)
  55 check_include_file(stdio.h HAVE_STDIO_H)
  56 check_include_file(stdlib.h HAVE_STDLIB_H)
  57 check_include_file(string.h HAVE_STRING_H)
  58 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  59 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  60 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  61 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  62 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  63 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  64 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  65 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  66 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  67 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  68 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  69 check_include_file(termios.h HAVE_TERMIOS_H)
  70 check_include_file(unistd.h HAVE_UNISTD_H)
  71 check_include_file(utime.h HAVE_UTIME_H)
  72 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  73 check_include_file(windows.h HAVE_WINDOWS_H)
  74 check_include_file(fenv.h HAVE_FENV_H)
  75
  76 # library checks
  77 if( NOT LLVM_ON_WIN32 )
  78   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  79   check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  80   check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  81   check_library_exists(dl dlopen "" HAVE_LIBDL)
  82 endif()
  83
  84 # function checks
  85 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  86 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  87 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  88 check_function_exists(isatty HAVE_ISATTY)
  89 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  90 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  91 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
  92 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  93 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  94 check_symbol_exists(ceilf math.h HAVE_CEILF)
  95 check_symbol_exists(floorf math.h HAVE_FLOORF)
  96 check_symbol_exists(fmodf math.h HAVE_FMODF)
  97 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
  98 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  99 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 100                     HAVE_MALLOC_ZONE_STATISTICS)
 101 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 102 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 103 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 104 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 105 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 106 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 107 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 108 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 109 if( NOT LLVM_ON_WIN32 )
 110   check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
 111 endif()
 112 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 113 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 114 check_symbol_exists(strerror string.h HAVE_STRERROR)
 115 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 116 check_symbol_exists(strerror_s string.h HAVE_STRERROR_S)
 117 check_symbol_exists(memcpy string.h HAVE_MEMCPY)
 118 check_symbol_exists(memmove string.h HAVE_MEMMOVE)
 119 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 120 if ( LLVM_ON_WIN32 )
 121   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 122 endif()
 123 if( HAVE_ARGZ_H )
 124   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 125   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 126   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 127   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 128   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 129 endif()
 130
 131 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 132 if( LLVM_USING_GLIBC )
 133   add_llvm_definitions( -D_GNU_SOURCE )
 134 endif()
 135
 136 # Type checks
 137 check_type_exists(std::bidirectional_iterator<int,int> "iterator;iostream" HAVE_BI_ITERATOR)
 138 check_type_exists(std::iterator<int,int,int> iterator HAVE_STD_ITERATOR)
 139 check_type_exists(std::forward_iterator<int,int> iterator HAVE_FWD_ITERATOR)
 140
 141 set(headers "")
 142 if (HAVE_SYS_TYPES_H)
 143   set(headers ${headers} "sys/types.h")
 144 endif()
 145
 146 if (HAVE_INTTYPES_H)
 147   set(headers ${headers} "inttypes.h")
 148 endif()
 149
 150 if (HAVE_STDINT_H)
 151   set(headers ${headers} "stdint.h")
 152 endif()
 153
 154 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 155 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 156 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 157
 158 # available programs checks
 159 function(llvm_find_program name)
 160   string(TOUPPER ${name} NAME)
 161   find_program(LLVM_PATH_${NAME} ${name})
 162   mark_as_advanced(LLVM_PATH_${NAME})
 163   if(LLVM_PATH_${NAME})
 164     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 165     mark_as_advanced(HAVE_${NAME})
 166   else(LLVM_PATH_${NAME})
 167     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 168   endif(LLVM_PATH_${NAME})
 169 endfunction()
 170
 171 llvm_find_program(gv)
 172 llvm_find_program(circo)
 173 llvm_find_program(twopi)
 174 llvm_find_program(neato)
 175 llvm_find_program(fdp)
 176 llvm_find_program(dot)
 177 llvm_find_program(dotty)
 178
 179 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
 180 include(CheckAtomic)
 181
 182 if( LLVM_ENABLE_PIC )
 183   set(ENABLE_PIC 1)
 184 else()
 185   set(ENABLE_PIC 0)
 186 endif()
 187
 188 include(CheckCXXCompilerFlag)
 189
 190 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 191
 192 include(GetTargetTriple)
 193 get_target_triple(LLVM_HOSTTRIPLE)
 194
 195 # FIXME: We don't distinguish the target and the host. :(
 196 set(TARGET_TRIPLE "${LLVM_HOSTTRIPLE}")
 197
 198 # Determine the native architecture.
 199 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 200 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 201   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
 202 endif ()
 203
 204 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 205   set(LLVM_NATIVE_ARCH X86)
 206 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 207   set(LLVM_NATIVE_ARCH X86)
 208 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 209   set(LLVM_NATIVE_ARCH X86)
 210 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 211   set(LLVM_NATIVE_ARCH X86)
 212 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 213   set(LLVM_NATIVE_ARCH Sparc)
 214 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 215   set(LLVM_NATIVE_ARCH PowerPC)
 216 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 217   set(LLVM_NATIVE_ARCH Alpha)
 218 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 219   set(LLVM_NATIVE_ARCH ARM)
 220 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 221   set(LLVM_NATIVE_ARCH Mips)
 222 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 223   set(LLVM_NATIVE_ARCH XCore)
 224 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 225   set(LLVM_NATIVE_ARCH MSP430)
 226 else ()
 227   message(STATUS
 228     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 229   set(LLVM_NATIVE_ARCH)
 230 endif ()
 231
 232 if (LLVM_NATIVE_ARCH)
 233   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 234   if (NATIVE_ARCH_IDX EQUAL -1)
 235     message(STATUS
 236       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 237     set(LLVM_NATIVE_ARCH)
 238   else ()
 239     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 240     set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 241     set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 242     set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 243   endif ()
 244 endif()
 245
 246 if( MINGW )
 247   set(HAVE_LIBIMAGEHLP 1)
 248   set(HAVE_LIBPSAPI 1)
 249   # TODO: Check existence of libraries.
 250   #   include(CheckLibraryExists)
 251   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 252 endif( MINGW )
 253
 254 if( MSVC )
 255   set(error_t int)
 256   set(mode_t "unsigned short")
 257   set(LTDL_SHLIBPATH_VAR "PATH")
 258   set(LTDL_SYSSEARCHPATH "")
 259   set(LTDL_DLOPEN_DEPLIBS 1)
 260   set(SHLIBEXT ".lib")
 261   set(LTDL_OBJDIR "_libs")
 262   set(HAVE_STRTOLL 1)
 263   set(strtoll "_strtoi64")
 264   set(strtoull "_strtoui64")
 265   set(stricmp "_stricmp")
 266   set(strdup "_strdup")
 267 else( MSVC )
 268   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 269   set(LTDL_SYSSEARCHPATH "") # TODO
 270   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 271 endif( MSVC )
 272
 273 # FIXME: Signal handler return type, currently hardcoded to 'void'
 274 set(RETSIGTYPE void)
 275
 276 if( LLVM_ENABLE_THREADS )
 277   if( HAVE_PTHREAD_H OR WIN32 )
 278     set(ENABLE_THREADS 1)
 279   endif()
 280 endif()
 281
 282 if( ENABLE_THREADS )
 283   message(STATUS "Threads enabled.")
 284 else( ENABLE_THREADS )
 285   message(STATUS "Threads disabled.")
 286 endif()
 287
 288 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 289
 290 configure_file(
 291   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 292   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 293   )
 294
 295 configure_file(
 296   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 297   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h
 298   )
 299
 300 configure_file(
 301   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 302   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 303   )
 304