ReleaseNotes: C API policy; by Eric Christopher
[oota-llvm.git] / cmake / config-ix.cmake
1 if( WIN32 AND NOT CYGWIN )
2   # We consider Cygwin as another Unix
3   set(PURE_WINDOWS 1)
4 endif()
5
6 include(CheckIncludeFile)
7 include(CheckIncludeFileCXX)
8 include(CheckLibraryExists)
9 include(CheckSymbolExists)
10 include(CheckFunctionExists)
11 include(CheckCXXSourceCompiles)
12 include(TestBigEndian)
13
14 include(HandleLLVMStdlib)
15
16 if( UNIX AND NOT BEOS )
17   # Used by check_symbol_exists:
18   set(CMAKE_REQUIRED_LIBRARIES m)
19 endif()
20 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
21 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
22     CMAKE_SIZEOF_VOID_P EQUAL 8 )
23   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
24 endif()
25
26 # Helper macros and functions
27 macro(add_cxx_include result files)
28   set(${result} "")
29   foreach (file_name ${files})
30      set(${result} "${${result}}#include<${file_name}>\n")
31   endforeach()
32 endmacro(add_cxx_include files result)
33
34 function(check_type_exists type files variable)
35   add_cxx_include(includes "${files}")
36   CHECK_CXX_SOURCE_COMPILES("
37     ${includes} ${type} typeVar;
38     int main() {
39         return 0;
40     }
41     " ${variable})
42 endfunction()
43
44 # include checks
45 check_include_file(dirent.h HAVE_DIRENT_H)
46 check_include_file(dlfcn.h HAVE_DLFCN_H)
47 check_include_file(errno.h HAVE_ERRNO_H)
48 check_include_file(execinfo.h HAVE_EXECINFO_H)
49 check_include_file(fcntl.h HAVE_FCNTL_H)
50 check_include_file(inttypes.h HAVE_INTTYPES_H)
51 check_include_file(limits.h HAVE_LIMITS_H)
52 check_include_file(link.h HAVE_LINK_H)
53 check_include_file(malloc.h HAVE_MALLOC_H)
54 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
55 check_include_file(ndir.h HAVE_NDIR_H)
56 if( NOT PURE_WINDOWS )
57   check_include_file(pthread.h HAVE_PTHREAD_H)
58 endif()
59 check_include_file(signal.h HAVE_SIGNAL_H)
60 check_include_file(stdint.h HAVE_STDINT_H)
61 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
62 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
63 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
64 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
65 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
66 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
67 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
68 check_include_file(sys/time.h HAVE_SYS_TIME_H)
69 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
70 check_include_file(termios.h HAVE_TERMIOS_H)
71 check_include_file(unistd.h HAVE_UNISTD_H)
72 check_include_file(utime.h HAVE_UTIME_H)
73 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
74 check_include_file(zlib.h HAVE_ZLIB_H)
75 check_include_file(fenv.h HAVE_FENV_H)
76 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
77 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
78
79 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
80 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
81 check_include_file(histedit.h HAVE_HISTEDIT_H)
82
83 # size_t must be defined before including cxxabi.h on FreeBSD 10.0.
84 check_cxx_source_compiles("
85 #include <stddef.h>
86 #include <cxxabi.h>
87 int main() { return 0; }
88 " HAVE_CXXABI_H)
89
90 # library checks
91 if( NOT PURE_WINDOWS )
92   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
93   if (HAVE_LIBPTHREAD)
94     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
95     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
96     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
97   else()
98     # this could be Android
99     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
100     if (PTHREAD_IN_LIBC)
101       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
102       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
103       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
104     endif()
105   endif()
106   check_library_exists(dl dlopen "" HAVE_LIBDL)
107   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
108 endif()
109
110 # Don't look for these libraries on Windows. Also don't look for them if we're
111 # using MSan, since uninstrmented third party code may call MSan interceptors
112 # like strlen, leading to false positives.
113 if( NOT PURE_WINDOWS AND NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
114   if (LLVM_ENABLE_ZLIB)
115     check_library_exists(z compress2 "" HAVE_LIBZ)
116   else()
117     set(HAVE_LIBZ 0)
118   endif()
119   if (HAVE_HISTEDIT_H)
120     check_library_exists(edit el_init "" HAVE_LIBEDIT)
121   endif()
122   if(LLVM_ENABLE_TERMINFO)
123     set(HAVE_TERMINFO 0)
124     foreach(library tinfo terminfo curses ncurses ncursesw)
125       string(TOUPPER ${library} library_suffix)
126       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
127       if(HAVE_TERMINFO_${library_suffix})
128         set(HAVE_TERMINFO 1)
129         set(TERMINFO_LIBS "${library}")
130         break()
131       endif()
132     endforeach()
133   else()
134     set(HAVE_TERMINFO 0)
135   endif()
136 endif()
137
138 # function checks
139 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
140 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
141 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
142 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
143 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
144 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
145 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
146 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
147 if( HAVE_SETJMP_H )
148   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
149   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
150   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
151   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
152 endif()
153 if( HAVE_SYS_UIO_H )
154   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
155 endif()
156 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
157 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
158 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
159                     HAVE_MALLOC_ZONE_STATISTICS)
160 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
161 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
162 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
163 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
164 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
165 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
166 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
167 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
168 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
169 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
170 check_symbol_exists(pread unistd.h HAVE_PREAD)
171 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
172 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
173 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
174 if( HAVE_RAND48_SRAND48 )
175   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
176   if( HAVE_RAND48_LRAND48 )
177     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
178     if( HAVE_RAND48_DRAND48 )
179       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
180     endif()
181   endif()
182 endif()
183 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
184 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
185 check_symbol_exists(strerror string.h HAVE_STRERROR)
186 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
187 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
188 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
189 if( PURE_WINDOWS )
190   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
191
192   check_function_exists(_alloca HAVE__ALLOCA)
193   check_function_exists(__alloca HAVE___ALLOCA)
194   check_function_exists(__chkstk HAVE___CHKSTK)
195   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
196   check_function_exists(___chkstk HAVE____CHKSTK)
197   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
198
199   check_function_exists(__ashldi3 HAVE___ASHLDI3)
200   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
201   check_function_exists(__divdi3 HAVE___DIVDI3)
202   check_function_exists(__fixdfdi HAVE___FIXDFDI)
203   check_function_exists(__fixsfdi HAVE___FIXSFDI)
204   check_function_exists(__floatdidf HAVE___FLOATDIDF)
205   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
206   check_function_exists(__moddi3 HAVE___MODDI3)
207   check_function_exists(__udivdi3 HAVE___UDIVDI3)
208   check_function_exists(__umoddi3 HAVE___UMODDI3)
209
210   check_function_exists(__main HAVE___MAIN)
211   check_function_exists(__cmpdi2 HAVE___CMPDI2)
212 endif()
213 if( HAVE_DLFCN_H )
214   if( HAVE_LIBDL )
215     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
216   endif()
217   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
218   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
219   if( HAVE_LIBDL )
220     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
221   endif()
222 endif()
223
224 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
225 if( LLVM_USING_GLIBC )
226   add_llvm_definitions( -D_GNU_SOURCE )
227 endif()
228
229 set(headers "sys/types.h")
230
231 if (HAVE_INTTYPES_H)
232   set(headers ${headers} "inttypes.h")
233 endif()
234
235 if (HAVE_STDINT_H)
236   set(headers ${headers} "stdint.h")
237 endif()
238
239 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
240 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
241 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
242
243 # available programs checks
244 function(llvm_find_program name)
245   string(TOUPPER ${name} NAME)
246   string(REGEX REPLACE "\\." "_" NAME ${NAME})
247
248   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
249   mark_as_advanced(LLVM_PATH_${NAME})
250   if(LLVM_PATH_${NAME})
251     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
252     mark_as_advanced(HAVE_${NAME})
253   else(LLVM_PATH_${NAME})
254     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
255   endif(LLVM_PATH_${NAME})
256 endfunction()
257
258 if (LLVM_ENABLE_DOXYGEN)
259   llvm_find_program(dot)
260 endif ()
261
262 if( LLVM_ENABLE_FFI )
263   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
264   if( EXISTS "${FFI_INCLUDE_PATH}/ffi.h" )
265     set(FFI_HEADER ffi.h CACHE INTERNAL "")
266     set(HAVE_FFI_H 1 CACHE INTERNAL "")
267   else()
268     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
269     if( EXISTS "${FFI_INCLUDE_PATH}/ffi/ffi.h" )
270       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
271       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
272     endif()
273   endif()
274
275   if( NOT FFI_HEADER )
276     message(FATAL_ERROR "libffi includes are not found.")
277   endif()
278
279   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
280   if( NOT FFI_LIBRARY_PATH )
281     message(FATAL_ERROR "libffi is not found.")
282   endif()
283
284   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
285   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
286   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
287   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
288   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
289 else()
290   unset(HAVE_FFI_FFI_H CACHE)
291   unset(HAVE_FFI_H CACHE)
292   unset(HAVE_FFI_CALL CACHE)
293 endif( LLVM_ENABLE_FFI )
294
295 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
296 include(CheckAtomic)
297
298 if( LLVM_ENABLE_PIC )
299   set(ENABLE_PIC 1)
300 else()
301   set(ENABLE_PIC 0)
302   check_cxx_compiler_flag("-fno-pie" SUPPORTS_NO_PIE_FLAG)
303   if(SUPPORTS_NO_PIE_FLAG)
304     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fno-pie")
305   endif()
306 endif()
307
308 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
309
310 set(USE_NO_MAYBE_UNINITIALIZED 0)
311 set(USE_NO_UNINITIALIZED 0)
312
313 # Disable gcc's potentially uninitialized use analysis as it presents lots of
314 # false positives.
315 if (CMAKE_COMPILER_IS_GNUCXX)
316   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
317   if (HAS_MAYBE_UNINITIALIZED)
318     set(USE_NO_MAYBE_UNINITIALIZED 1)
319   else()
320     # Only recent versions of gcc make the distinction between -Wuninitialized
321     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
322     # turn off all uninitialized use warnings.
323     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
324     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
325   endif()
326 endif()
327
328 # By default, we target the host, but this can be overridden at CMake
329 # invocation time.
330 include(GetHostTriple)
331 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
332
333 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
334     "Host on which LLVM binaries will run")
335
336 # Determine the native architecture.
337 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
338 if( LLVM_NATIVE_ARCH STREQUAL "host" )
339   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
340 endif ()
341
342 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
343   set(LLVM_NATIVE_ARCH X86)
344 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
345   set(LLVM_NATIVE_ARCH X86)
346 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
347   set(LLVM_NATIVE_ARCH X86)
348 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
349   set(LLVM_NATIVE_ARCH X86)
350 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
351   set(LLVM_NATIVE_ARCH Sparc)
352 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
353   set(LLVM_NATIVE_ARCH PowerPC)
354 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
355   set(LLVM_NATIVE_ARCH AArch64)
356 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
357   set(LLVM_NATIVE_ARCH AArch64)
358 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
359   set(LLVM_NATIVE_ARCH ARM)
360 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
361   set(LLVM_NATIVE_ARCH Mips)
362 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
363   set(LLVM_NATIVE_ARCH XCore)
364 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
365   set(LLVM_NATIVE_ARCH MSP430)
366 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
367   set(LLVM_NATIVE_ARCH Hexagon)
368 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
369   set(LLVM_NATIVE_ARCH SystemZ)
370 elseif (LLVM_NATIVE_ARCH MATCHES "wasm32")
371   set(LLVM_NATIVE_ARCH WebAssembly)
372 elseif (LLVM_NATIVE_ARCH MATCHES "wasm64")
373   set(LLVM_NATIVE_ARCH WebAssembly)
374 else ()
375   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
376 endif ()
377
378 # If build targets includes "host", then replace with native architecture.
379 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
380 if( NOT idx LESS 0 )
381   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
382   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
383   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
384 endif()
385
386 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
387 if (NATIVE_ARCH_IDX EQUAL -1)
388   message(STATUS
389     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
390 else ()
391   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
392   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
393   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
394   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
395   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
396
397   # We don't have an ASM parser for all architectures yet.
398   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
399     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
400   endif ()
401
402   # We don't have an disassembler for all architectures yet.
403   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
404     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
405   endif ()
406 endif ()
407
408 if( MINGW )
409   set(HAVE_LIBPSAPI 1)
410   set(HAVE_LIBSHELL32 1)
411   # TODO: Check existence of libraries.
412   #   include(CheckLibraryExists)
413 endif( MINGW )
414
415 if (NOT HAVE_STRTOLL)
416   # Use _strtoi64 if strtoll is not available.
417   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
418   if (have_strtoi64)
419     set(HAVE_STRTOLL 1)
420     set(strtoll "_strtoi64")
421     set(strtoull "_strtoui64")
422   endif ()
423 endif ()
424
425 if( MSVC )
426   set(SHLIBEXT ".lib")
427   set(stricmp "_stricmp")
428   set(strdup "_strdup")
429
430   # See if the DIA SDK is available and usable.
431   set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK")
432
433   # Due to a bug in MSVC 2013's installation software, it is possible
434   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
435   # install directory.  If this happens, the installation is corrupt
436   # and there's nothing we can do.  It happens with enough frequency
437   # though that we should handle it.  We do so by simply checking that
438   # the DIA SDK folder exists.  Should this happen you will need to
439   # uninstall VS 2012 and then re-install VS 2013.
440   if (IS_DIRECTORY ${MSVC_DIA_SDK_DIR})
441     set(HAVE_DIA_SDK 1)
442   else()
443     set(HAVE_DIA_SDK 0)
444   endif()
445 else()
446   set(HAVE_DIA_SDK 0)
447 endif( MSVC )
448
449 if( PURE_WINDOWS )
450   CHECK_CXX_SOURCE_COMPILES("
451     #include <windows.h>
452     #include <imagehlp.h>
453     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
454     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
455     int main(){return 0;}"
456     HAVE_ELMCB_PCSTR)
457   if( HAVE_ELMCB_PCSTR )
458     set(WIN32_ELMCB_PCSTR "PCSTR")
459   else()
460     set(WIN32_ELMCB_PCSTR "PSTR")
461   endif()
462 endif( PURE_WINDOWS )
463
464 # FIXME: Signal handler return type, currently hardcoded to 'void'
465 set(RETSIGTYPE void)
466
467 if( LLVM_ENABLE_THREADS )
468   # Check if threading primitives aren't supported on this platform
469   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
470     set(LLVM_ENABLE_THREADS 0)
471   endif()
472 endif()
473
474 if( LLVM_ENABLE_THREADS )
475   message(STATUS "Threads enabled.")
476 else( LLVM_ENABLE_THREADS )
477   message(STATUS "Threads disabled.")
478 endif()
479
480 if (LLVM_ENABLE_ZLIB )
481   # Check if zlib is available in the system.
482   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
483     set(LLVM_ENABLE_ZLIB 0)
484   endif()
485 endif()
486
487 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
488
489 if (LLVM_ENABLE_DOXYGEN)
490   message(STATUS "Doxygen enabled.")
491   find_package(Doxygen REQUIRED)
492
493   if (DOXYGEN_FOUND)
494     # If we find doxygen and we want to enable doxygen by default create a
495     # global aggregate doxygen target for generating llvm and any/all
496     # subprojects doxygen documentation.
497     if (LLVM_BUILD_DOCS)
498       add_custom_target(doxygen ALL)
499     endif()
500
501     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
502     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
503       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external search.")
504       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
505     endif()
506   endif()
507 else()
508   message(STATUS "Doxygen disabled.")
509 endif()
510
511 if (LLVM_ENABLE_SPHINX)
512   message(STATUS "Sphinx enabled.")
513   find_package(Sphinx REQUIRED)
514   if (LLVM_BUILD_DOCS)
515     add_custom_target(sphinx ALL)
516   endif()
517 else()
518   message(STATUS "Sphinx disabled.")
519 endif()
520
521 set(LLVM_BINDINGS "")
522 if(WIN32)
523   message(STATUS "Go bindings disabled.")
524 else()
525   find_program(GO_EXECUTABLE NAMES go DOC "go executable")
526   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
527     message(STATUS "Go bindings disabled.")
528   else()
529     execute_process(COMMAND ${GO_EXECUTABLE} run ${CMAKE_SOURCE_DIR}/bindings/go/conftest.go
530                     RESULT_VARIABLE GO_CONFTEST)
531     if(GO_CONFTEST STREQUAL "0")
532       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
533       message(STATUS "Go bindings enabled.")
534     else()
535       message(STATUS "Go bindings disabled, need at least Go 1.2.")
536     endif()
537   endif()
538 endif()
539
540 find_program(GOLD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.gold ld.gold ${LLVM_DEFAULT_TARGET_TRIPLE}-ld ld DOC "The gold linker")
541 set(LLVM_BINUTILS_INCDIR "" CACHE PATH
542         "PATH to binutils/include containing plugin-api.h for gold plugin.")
543
544 if(APPLE)
545   find_program(LD64_EXECUTABLE NAMES ld DOC "The ld64 linker")
546 endif()
547
548 include(FindOCaml)
549 include(AddOCaml)
550 if(WIN32)
551   message(STATUS "OCaml bindings disabled.")
552 else()
553   find_package(OCaml)
554   if( NOT OCAML_FOUND )
555     message(STATUS "OCaml bindings disabled.")
556   else()
557     if( OCAML_VERSION VERSION_LESS "4.00.0" )
558       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
559     else()
560       find_ocamlfind_package(ctypes VERSION 0.4 OPTIONAL)
561       if( HAVE_OCAML_CTYPES )
562         message(STATUS "OCaml bindings enabled.")
563         find_ocamlfind_package(oUnit VERSION 2 OPTIONAL)
564         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
565       else()
566         message(STATUS "OCaml bindings disabled, need ctypes >=0.4.")
567       endif()
568     endif()
569   endif()
570 endif()
571
572 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")