cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 include(HandleLLVMStdlib)
  15
  16 if( UNIX AND NOT BEOS )
  17   # Used by check_symbol_exists:
  18   set(CMAKE_REQUIRED_LIBRARIES m)
  19 endif()
  20 # x86_64 FreeBSD 9.2 requires libcxxrt to be specified explicitly.
  21 if( CMAKE_SYSTEM MATCHES "FreeBSD-9.2-RELEASE" AND
  22     CMAKE_SIZEOF_VOID_P EQUAL 8 )
  23   list(APPEND CMAKE_REQUIRED_LIBRARIES "cxxrt")
  24 endif()
  25
  26 # Helper macros and functions
  27 macro(add_cxx_include result files)
  28   set(${result} "")
  29   foreach (file_name ${files})
  30      set(${result} "${${result}}#include<${file_name}>\n")
  31   endforeach()
  32 endmacro(add_cxx_include files result)
  33
  34 function(check_type_exists type files variable)
  35   add_cxx_include(includes "${files}")
  36   CHECK_CXX_SOURCE_COMPILES("
  37     ${includes} ${type} typeVar;
  38     int main() {
  39         return 0;
  40     }
  41     " ${variable})
  42 endfunction()
  43
  44 # include checks
  45 check_include_file(dirent.h HAVE_DIRENT_H)
  46 check_include_file(dlfcn.h HAVE_DLFCN_H)
  47 check_include_file(errno.h HAVE_ERRNO_H)
  48 check_include_file(execinfo.h HAVE_EXECINFO_H)
  49 check_include_file(fcntl.h HAVE_FCNTL_H)
  50 check_include_file(inttypes.h HAVE_INTTYPES_H)
  51 check_include_file(limits.h HAVE_LIMITS_H)
  52 check_include_file(link.h HAVE_LINK_H)
  53 check_include_file(malloc.h HAVE_MALLOC_H)
  54 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  55 check_include_file(ndir.h HAVE_NDIR_H)
  56 if( NOT PURE_WINDOWS )
  57   check_include_file(pthread.h HAVE_PTHREAD_H)
  58 endif()
  59 check_include_file(signal.h HAVE_SIGNAL_H)
  60 check_include_file(stdint.h HAVE_STDINT_H)
  61 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  62 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  63 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  64 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  65 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  66 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  67 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  68 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  69 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  70 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  71 check_include_file(termios.h HAVE_TERMIOS_H)
  72 check_include_file(unistd.h HAVE_UNISTD_H)
  73 check_include_file(utime.h HAVE_UTIME_H)
  74 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  75 check_include_file(zlib.h HAVE_ZLIB_H)
  76 check_include_file(fenv.h HAVE_FENV_H)
  77 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  78 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  79
  80 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  81 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  82 check_include_file(histedit.h HAVE_HISTEDIT_H)
  83
  84 # size_t must be defined before including cxxabi.h on FreeBSD 10.0.
  85 check_cxx_source_compiles("
  86 #include <stddef.h>
  87 #include <cxxabi.h>
  88 int main() { return 0; }
  89 " HAVE_CXXABI_H)
  90
  91 # library checks
  92 if( NOT PURE_WINDOWS )
  93   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  94   if (HAVE_LIBPTHREAD)
  95     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  96     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  97     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  98   else()
  99     # this could be Android
 100     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
 101     if (PTHREAD_IN_LIBC)
 102       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
 103       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
 104       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
 105     endif()
 106   endif()
 107   check_library_exists(dl dlopen "" HAVE_LIBDL)
 108   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 109   if (LLVM_ENABLE_ZLIB)
 110     check_library_exists(z compress2 "" HAVE_LIBZ)
 111   else()
 112     set(HAVE_LIBZ 0)
 113   endif()
 114   if (HAVE_HISTEDIT_H)
 115     check_library_exists(edit el_init "" HAVE_LIBEDIT)
 116   endif()
 117   if(LLVM_ENABLE_TERMINFO)
 118     set(HAVE_TERMINFO 0)
 119     foreach(library tinfo terminfo curses ncurses ncursesw)
 120       string(TOUPPER ${library} library_suffix)
 121       check_library_exists(${library} setupterm "" HAVE_TERMINFO_${library_suffix})
 122       if(HAVE_TERMINFO_${library_suffix})
 123         set(HAVE_TERMINFO 1)
 124         set(TERMINFO_LIBS "${library}")
 125         break()
 126       endif()
 127     endforeach()
 128   else()
 129     set(HAVE_TERMINFO 0)
 130   endif()
 131 endif()
 132
 133 # function checks
 134 check_symbol_exists(arc4random "stdlib.h" HAVE_DECL_ARC4RANDOM)
 135 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 136 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 137 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 138 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 139 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 140 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 141 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 142 if( HAVE_SETJMP_H )
 143   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 144   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 145   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 146   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 147 endif()
 148 if( HAVE_SYS_UIO_H )
 149   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 150 endif()
 151 check_symbol_exists(mallctl malloc_np.h HAVE_MALLCTL)
 152 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 153 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 154                     HAVE_MALLOC_ZONE_STATISTICS)
 155 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 156 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 157 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 158 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 159 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 160 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 161 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 162 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 163 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 164 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 165 check_symbol_exists(pread unistd.h HAVE_PREAD)
 166 check_symbol_exists(realpath stdlib.h HAVE_REALPATH)
 167 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 168 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 169 if( HAVE_RAND48_SRAND48 )
 170   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 171   if( HAVE_RAND48_LRAND48 )
 172     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 173     if( HAVE_RAND48_DRAND48 )
 174       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 175     endif()
 176   endif()
 177 endif()
 178 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 179 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 180 check_symbol_exists(strerror string.h HAVE_STRERROR)
 181 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 182 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 183 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 184 if( PURE_WINDOWS )
 185   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 186
 187   check_function_exists(_alloca HAVE__ALLOCA)
 188   check_function_exists(__alloca HAVE___ALLOCA)
 189   check_function_exists(__chkstk HAVE___CHKSTK)
 190   check_function_exists(__chkstk_ms HAVE___CHKSTK_MS)
 191   check_function_exists(___chkstk HAVE____CHKSTK)
 192   check_function_exists(___chkstk_ms HAVE____CHKSTK_MS)
 193
 194   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 195   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 196   check_function_exists(__divdi3 HAVE___DIVDI3)
 197   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 198   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 199   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 200   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 201   check_function_exists(__moddi3 HAVE___MODDI3)
 202   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 203   check_function_exists(__umoddi3 HAVE___UMODDI3)
 204
 205   check_function_exists(__main HAVE___MAIN)
 206   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 207 endif()
 208 if( HAVE_DLFCN_H )
 209   if( HAVE_LIBDL )
 210     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 211   endif()
 212   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 213   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 214   if( HAVE_LIBDL )
 215     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 216   endif()
 217 endif()
 218
 219 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 220 if( LLVM_USING_GLIBC )
 221   add_llvm_definitions( -D_GNU_SOURCE )
 222 endif()
 223
 224 set(headers "sys/types.h")
 225
 226 if (HAVE_INTTYPES_H)
 227   set(headers ${headers} "inttypes.h")
 228 endif()
 229
 230 if (HAVE_STDINT_H)
 231   set(headers ${headers} "stdint.h")
 232 endif()
 233
 234 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 235 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 236 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 237
 238 # available programs checks
 239 function(llvm_find_program name)
 240   string(TOUPPER ${name} NAME)
 241   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 242
 243   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 244   mark_as_advanced(LLVM_PATH_${NAME})
 245   if(LLVM_PATH_${NAME})
 246     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 247     mark_as_advanced(HAVE_${NAME})
 248   else(LLVM_PATH_${NAME})
 249     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 250   endif(LLVM_PATH_${NAME})
 251 endfunction()
 252
 253 if (LLVM_ENABLE_DOXYGEN)
 254   llvm_find_program(dot)
 255 endif ()
 256
 257 if( LLVM_ENABLE_FFI )
 258   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 259   if( EXISTS "${FFI_INCLUDE_PATH}/ffi.h" )
 260     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 261     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 262   else()
 263     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 264     if( EXISTS "${FFI_INCLUDE_PATH}/ffi/ffi.h" )
 265       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 266       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 267     endif()
 268   endif()
 269
 270   if( NOT FFI_HEADER )
 271     message(FATAL_ERROR "libffi includes are not found.")
 272   endif()
 273
 274   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 275   if( NOT FFI_LIBRARY_PATH )
 276     message(FATAL_ERROR "libffi is not found.")
 277   endif()
 278
 279   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 280   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 281   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 282   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 283   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 284 else()
 285   unset(HAVE_FFI_FFI_H CACHE)
 286   unset(HAVE_FFI_H CACHE)
 287   unset(HAVE_FFI_CALL CACHE)
 288 endif( LLVM_ENABLE_FFI )
 289
 290 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 291 include(CheckAtomic)
 292
 293 if( LLVM_ENABLE_PIC )
 294   set(ENABLE_PIC 1)
 295 else()
 296   set(ENABLE_PIC 0)
 297 endif()
 298
 299 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 300
 301 set(USE_NO_MAYBE_UNINITIALIZED 0)
 302 set(USE_NO_UNINITIALIZED 0)
 303
 304 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 305 # false positives.
 306 if (CMAKE_COMPILER_IS_GNUCXX)
 307   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 308   if (HAS_MAYBE_UNINITIALIZED)
 309     set(USE_NO_MAYBE_UNINITIALIZED 1)
 310   else()
 311     # Only recent versions of gcc make the distinction between -Wuninitialized
 312     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 313     # turn off all uninitialized use warnings.
 314     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 315     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 316   endif()
 317 endif()
 318
 319 # By default, we target the host, but this can be overridden at CMake
 320 # invocation time.
 321 include(GetHostTriple)
 322 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 323
 324 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 325     "Host on which LLVM binaries will run")
 326
 327 # Determine the native architecture.
 328 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 329 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 330   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 331 endif ()
 332
 333 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 334   set(LLVM_NATIVE_ARCH X86)
 335 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 336   set(LLVM_NATIVE_ARCH X86)
 337 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 338   set(LLVM_NATIVE_ARCH X86)
 339 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 340   set(LLVM_NATIVE_ARCH X86)
 341 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 342   set(LLVM_NATIVE_ARCH Sparc)
 343 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 344   set(LLVM_NATIVE_ARCH PowerPC)
 345 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 346   set(LLVM_NATIVE_ARCH AArch64)
 347 elseif (LLVM_NATIVE_ARCH MATCHES "arm64")
 348   set(LLVM_NATIVE_ARCH AArch64)
 349 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 350   set(LLVM_NATIVE_ARCH ARM)
 351 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 352   set(LLVM_NATIVE_ARCH Mips)
 353 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 354   set(LLVM_NATIVE_ARCH XCore)
 355 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 356   set(LLVM_NATIVE_ARCH MSP430)
 357 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 358   set(LLVM_NATIVE_ARCH Hexagon)
 359 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 360   set(LLVM_NATIVE_ARCH SystemZ)
 361 elseif (LLVM_NATIVE_ARCH MATCHES "wasm32")
 362   set(LLVM_NATIVE_ARCH WebAssembly)
 363 elseif (LLVM_NATIVE_ARCH MATCHES "wasm64")
 364   set(LLVM_NATIVE_ARCH WebAssembly)
 365 else ()
 366   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 367 endif ()
 368
 369 # If build targets includes "host", then replace with native architecture.
 370 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 371 if( NOT idx LESS 0 )
 372   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 373   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 374   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 375 endif()
 376
 377 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 378 if (NATIVE_ARCH_IDX EQUAL -1)
 379   message(STATUS
 380     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 381 else ()
 382   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 383   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 384   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 385   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 386   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 387
 388   # We don't have an ASM parser for all architectures yet.
 389   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 390     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 391   endif ()
 392
 393   # We don't have an disassembler for all architectures yet.
 394   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 395     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 396   endif ()
 397 endif ()
 398
 399 if( MINGW )
 400   set(HAVE_LIBPSAPI 1)
 401   set(HAVE_LIBSHELL32 1)
 402   # TODO: Check existence of libraries.
 403   #   include(CheckLibraryExists)
 404 endif( MINGW )
 405
 406 if (NOT HAVE_STRTOLL)
 407   # Use _strtoi64 if strtoll is not available.
 408   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 409   if (have_strtoi64)
 410     set(HAVE_STRTOLL 1)
 411     set(strtoll "_strtoi64")
 412     set(strtoull "_strtoui64")
 413   endif ()
 414 endif ()
 415
 416 if( MSVC )
 417   set(SHLIBEXT ".lib")
 418   set(stricmp "_stricmp")
 419   set(strdup "_strdup")
 420
 421   # See if the DIA SDK is available and usable.
 422   set(MSVC_DIA_SDK_DIR "$ENV{VSINSTALLDIR}DIA SDK")
 423
 424   # Due to a bug in MSVC 2013's installation software, it is possible
 425   # for MSVC 2013 to write the DIA SDK into the Visual Studio 2012
 426   # install directory.  If this happens, the installation is corrupt
 427   # and there's nothing we can do.  It happens with enough frequency
 428   # though that we should handle it.  We do so by simply checking that
 429   # the DIA SDK folder exists.  Should this happen you will need to
 430   # uninstall VS 2012 and then re-install VS 2013.
 431   if (IS_DIRECTORY ${MSVC_DIA_SDK_DIR})
 432     set(HAVE_DIA_SDK 1)
 433   else()
 434     set(HAVE_DIA_SDK 0)
 435   endif()
 436 else()
 437   set(HAVE_DIA_SDK 0)
 438 endif( MSVC )
 439
 440 if( PURE_WINDOWS )
 441   CHECK_CXX_SOURCE_COMPILES("
 442     #include <windows.h>
 443     #include <imagehlp.h>
 444     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 445     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 446     int main(){return 0;}"
 447     HAVE_ELMCB_PCSTR)
 448   if( HAVE_ELMCB_PCSTR )
 449     set(WIN32_ELMCB_PCSTR "PCSTR")
 450   else()
 451     set(WIN32_ELMCB_PCSTR "PSTR")
 452   endif()
 453 endif( PURE_WINDOWS )
 454
 455 # FIXME: Signal handler return type, currently hardcoded to 'void'
 456 set(RETSIGTYPE void)
 457
 458 if( LLVM_ENABLE_THREADS )
 459   # Check if threading primitives aren't supported on this platform
 460   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 461     set(LLVM_ENABLE_THREADS 0)
 462   endif()
 463 endif()
 464
 465 if( LLVM_ENABLE_THREADS )
 466   message(STATUS "Threads enabled.")
 467 else( LLVM_ENABLE_THREADS )
 468   message(STATUS "Threads disabled.")
 469 endif()
 470
 471 if (LLVM_ENABLE_ZLIB )
 472   # Check if zlib is available in the system.
 473   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 474     set(LLVM_ENABLE_ZLIB 0)
 475   endif()
 476 endif()
 477
 478 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 479
 480 if (LLVM_ENABLE_DOXYGEN)
 481   message(STATUS "Doxygen enabled.")
 482   find_package(Doxygen REQUIRED)
 483
 484   if (DOXYGEN_FOUND)
 485     # If we find doxygen and we want to enable doxygen by default create a
 486     # global aggregate doxygen target for generating llvm and any/all
 487     # subprojects doxygen documentation.
 488     if (LLVM_BUILD_DOCS)
 489       add_custom_target(doxygen ALL)
 490     endif()
 491
 492     option(LLVM_DOXYGEN_EXTERNAL_SEARCH "Enable doxygen external search." OFF)
 493     if (LLVM_DOXYGEN_EXTERNAL_SEARCH)
 494       set(LLVM_DOXYGEN_SEARCHENGINE_URL "" CACHE STRING "URL to use for external search.")
 495       set(LLVM_DOXYGEN_SEARCH_MAPPINGS "" CACHE STRING "Doxygen Search Mappings")
 496     endif()
 497   endif()
 498 else()
 499   message(STATUS "Doxygen disabled.")
 500 endif()
 501
 502 if (LLVM_ENABLE_SPHINX)
 503   message(STATUS "Sphinx enabled.")
 504   find_package(Sphinx REQUIRED)
 505   if (LLVM_BUILD_DOCS)
 506     add_custom_target(sphinx ALL)
 507   endif()
 508 else()
 509   message(STATUS "Sphinx disabled.")
 510 endif()
 511
 512 set(LLVM_BINDINGS "")
 513 if(WIN32)
 514   message(STATUS "Go bindings disabled.")
 515 else()
 516   find_program(GO_EXECUTABLE NAMES go DOC "go executable")
 517   if(GO_EXECUTABLE STREQUAL "GO_EXECUTABLE-NOTFOUND")
 518     message(STATUS "Go bindings disabled.")
 519   else()
 520     execute_process(COMMAND ${GO_EXECUTABLE} run ${CMAKE_SOURCE_DIR}/bindings/go/conftest.go
 521                     RESULT_VARIABLE GO_CONFTEST)
 522     if(GO_CONFTEST STREQUAL "0")
 523       set(LLVM_BINDINGS "${LLVM_BINDINGS} go")
 524       message(STATUS "Go bindings enabled.")
 525     else()
 526       message(STATUS "Go bindings disabled, need at least Go 1.2.")
 527     endif()
 528   endif()
 529 endif()
 530
 531 find_program(GOLD_EXECUTABLE NAMES ${LLVM_DEFAULT_TARGET_TRIPLE}-ld.gold ld.gold ${LLVM_DEFAULT_TARGET_TRIPLE}-ld ld DOC "The gold linker")
 532 set(LLVM_BINUTILS_INCDIR "" CACHE PATH
 533         "PATH to binutils/include containing plugin-api.h for gold plugin.")
 534
 535 if(APPLE)
 536   find_program(LD64_EXECUTABLE NAMES ld DOC "The ld64 linker")
 537 endif()
 538
 539 include(FindOCaml)
 540 include(AddOCaml)
 541 if(WIN32)
 542   message(STATUS "OCaml bindings disabled.")
 543 else()
 544   find_package(OCaml)
 545   if( NOT OCAML_FOUND )
 546     message(STATUS "OCaml bindings disabled.")
 547   else()
 548     if( OCAML_VERSION VERSION_LESS "4.00.0" )
 549       message(STATUS "OCaml bindings disabled, need OCaml >=4.00.0.")
 550     else()
 551       find_ocamlfind_package(ctypes VERSION 0.4 OPTIONAL)
 552       if( HAVE_OCAML_CTYPES )
 553         message(STATUS "OCaml bindings enabled.")
 554         find_ocamlfind_package(oUnit VERSION 2 OPTIONAL)
 555         set(LLVM_BINDINGS "${LLVM_BINDINGS} ocaml")
 556       else()
 557         message(STATUS "OCaml bindings disabled, need ctypes >=0.4.")
 558       endif()
 559     endif()
 560   endif()
 561 endif()
 562
 563 string(REPLACE " " ";" LLVM_BINDINGS_LIST "${LLVM_BINDINGS}")