autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.6.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=6
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45
  46 AC_SUBST([LLVM_VERSION_MAJOR])
  47 AC_SUBST([LLVM_VERSION_MINOR])
  48 AC_SUBST([LLVM_VERSION_PATCH])
  49 AC_SUBST([LLVM_VERSION_SUFFIX])
  50
  51 dnl Provide a copyright substitution and ensure the copyright notice is included
  52 dnl in the output of --version option of the generated configure script.
  53 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  54 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  55
  56 dnl Indicate that we require autoconf 2.60 or later.
  57 AC_PREREQ(2.60)
  58
  59 dnl Verify that the source directory is valid. This makes sure that we are
  60 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  61 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  62
  63 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  64 dnl various tools where the m4 autoconf macros are.
  65 AC_CONFIG_AUX_DIR([autoconf])
  66
  67 dnl Quit if the source directory has already been configured.
  68 dnl NOTE: This relies upon undocumented autoconf behavior.
  69 if test ${srcdir} != "." ; then
  70   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  71     AC_MSG_ERROR([Already configured in ${srcdir}])
  72   fi
  73 fi
  74
  75 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  76 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  77 : ${CFLAGS=}
  78 : ${CXXFLAGS=}
  79
  80 dnl We need to check for the compiler up here to avoid anything else
  81 dnl starting with a different one.
  82 AC_PROG_CC(clang gcc)
  83 AC_PROG_CXX(clang++ g++)
  84 AC_PROG_CPP
  85
  86 dnl If CXX is Clang, check that it can find and parse C++ standard library
  87 dnl headers.
  88 if test "$CXX" = "clang++" ; then
  89   AC_MSG_CHECKING([whether clang works])
  90   AC_LANG_PUSH([C++])
  91   dnl Note that space between 'include' and '(' is required.  There's a broken
  92   dnl regex in aclocal that otherwise will think that we call m4's include
  93   dnl builtin.
  94   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  95 #if __has_include (<cxxabi.h>)
  96 #include <cxxabi.h>
  97 #endif
  98 #if __has_include (<unwind.h>)
  99 #include <unwind.h>
 100 #endif
 101 ]])],
 102 [
 103   AC_MSG_RESULT([yes])
 104 ],
 105 [
 106   AC_MSG_RESULT([no])
 107   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
 108 ])
 109   AC_LANG_POP([C++])
 110 fi
 111
 112 dnl Set up variables that track whether the host compiler is GCC or Clang where
 113 dnl we can effectively sanity check them. We don't try to sanity check all the
 114 dnl other possible compilers.
 115 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 116 AC_LANG_PUSH([C++])
 117 llvm_cv_cxx_compiler=unknown
 118 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 119                                     #error
 120                                     #endif
 121                                     ]])],
 122                   llvm_cv_cxx_compiler=clang,
 123                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 124                                                        #error
 125                                                        #endif
 126                                                        ]])],
 127                                      llvm_cv_cxx_compiler=gcc, [])])
 128 AC_LANG_POP([C++])
 129 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 130
 131 dnl Configure all of the projects present in our source tree. While we could
 132 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 133 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 134 dnl Instead we match on the known projects.
 135
 136 dnl
 137 dnl One tricky part of doing this is that some projects depend upon other
 138 dnl projects.  For example, several projects rely upon the LLVM test suite.
 139 dnl We want to configure those projects first so that their object trees are
 140 dnl created before running the configure scripts of projects that depend upon
 141 dnl them.
 142 dnl
 143
 144 dnl Several projects use the LLVM test suite, so configure it next.
 145 if test -d ${srcdir}/projects/test-suite ; then
 146   AC_CONFIG_SUBDIRS([projects/test-suite])
 147 fi
 148
 149 dnl llvm-test is the old name of the test-suite, kept here for backwards
 150 dnl compatibility
 151 if test -d ${srcdir}/projects/llvm-test ; then
 152   AC_CONFIG_SUBDIRS([projects/llvm-test])
 153 fi
 154
 155 dnl Some projects use poolalloc; configure that next
 156 if test -d ${srcdir}/projects/poolalloc ; then
 157   AC_CONFIG_SUBDIRS([projects/poolalloc])
 158 fi
 159
 160 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 161   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 162 fi
 163
 164 dnl Check for all other projects
 165 for i in `ls ${srcdir}/projects`
 166 do
 167   if test -d ${srcdir}/projects/${i} ; then
 168     case ${i} in
 169       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 170       compiler-rt)       ;;
 171       test-suite)     ;;
 172       llvm-test)      ;;
 173       poolalloc)      ;;
 174       llvm-poolalloc) ;;
 175       *)
 176         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 177         ;;
 178     esac
 179   fi
 180 done
 181
 182 dnl Disable the build of polly, even if it is checked out into tools/polly.
 183 AC_ARG_ENABLE(polly,
 184               AS_HELP_STRING([--enable-polly],
 185                              [Use polly if available (default is YES)]),,
 186                              enableval=default)
 187 case "$enableval" in
 188   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 189   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 190   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 191   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 192 esac
 193
 194
 195 dnl Check if polly is checked out into tools/polly and configure it if
 196 dnl available.
 197 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 198   AC_SUBST(LLVM_HAS_POLLY,1)
 199   AC_CONFIG_SUBDIRS([tools/polly])
 200 fi
 201
 202 dnl===-----------------------------------------------------------------------===
 203 dnl===
 204 dnl=== SECTION 2: Architecture, target, and host checks
 205 dnl===
 206 dnl===-----------------------------------------------------------------------===
 207
 208 dnl Check the target for which we're compiling and the host that will do the
 209 dnl compilations. This will tell us which LLVM compiler will be used for
 210 dnl compiling SSA into object code. This needs to be done early because
 211 dnl following tests depend on it.
 212 AC_CANONICAL_TARGET
 213
 214 dnl Determine the platform type and cache its value. This helps us configure
 215 dnl the System library to the correct build platform.
 216 AC_CACHE_CHECK([type of operating system we're going to host on],
 217                [llvm_cv_os_type],
 218 [case $host in
 219   *-*-aix*)
 220     llvm_cv_link_all_option="-Wl,--whole-archive"
 221     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 222     llvm_cv_os_type="AIX"
 223     llvm_cv_platform_type="Unix" ;;
 224   *-*-irix*)
 225     llvm_cv_link_all_option="-Wl,--whole-archive"
 226     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 227     llvm_cv_os_type="IRIX"
 228     llvm_cv_platform_type="Unix" ;;
 229   *-*-cygwin*)
 230     llvm_cv_link_all_option="-Wl,--whole-archive"
 231     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 232     llvm_cv_os_type="Cygwin"
 233     llvm_cv_platform_type="Unix" ;;
 234   *-*-darwin*)
 235     llvm_cv_link_all_option="-Wl,-all_load"
 236     llvm_cv_no_link_all_option="-Wl,-noall_load"
 237     llvm_cv_os_type="Darwin"
 238     llvm_cv_platform_type="Unix" ;;
 239   *-*-minix*)
 240     llvm_cv_link_all_option="-Wl,-all_load"
 241     llvm_cv_no_link_all_option="-Wl,-noall_load"
 242     llvm_cv_os_type="Minix"
 243     llvm_cv_platform_type="Unix" ;;
 244   *-*-freebsd*)
 245     llvm_cv_link_all_option="-Wl,--whole-archive"
 246     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 247     llvm_cv_os_type="FreeBSD"
 248     llvm_cv_platform_type="Unix" ;;
 249   *-*-kfreebsd-gnu)
 250     llvm_cv_link_all_option="-Wl,--whole-archive"
 251     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 252     llvm_cv_os_type="GNU/kFreeBSD"
 253     llvm_cv_platform_type="Unix" ;;
 254   *-*-openbsd*)
 255     llvm_cv_link_all_option="-Wl,--whole-archive"
 256     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 257     llvm_cv_os_type="OpenBSD"
 258     llvm_cv_platform_type="Unix" ;;
 259   *-*-netbsd*)
 260     llvm_cv_link_all_option="-Wl,--whole-archive"
 261     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 262     llvm_cv_os_type="NetBSD"
 263     llvm_cv_platform_type="Unix" ;;
 264   *-*-dragonfly*)
 265     llvm_cv_link_all_option="-Wl,--whole-archive"
 266     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 267     llvm_cv_os_type="DragonFly"
 268     llvm_cv_platform_type="Unix" ;;
 269   *-*-hpux*)
 270     llvm_cv_link_all_option="-Wl,--whole-archive"
 271     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 272     llvm_cv_os_type="HP-UX"
 273     llvm_cv_platform_type="Unix" ;;
 274   *-*-interix*)
 275     llvm_cv_link_all_option="-Wl,--whole-archive"
 276     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 277     llvm_cv_os_type="Interix"
 278     llvm_cv_platform_type="Unix" ;;
 279   *-*-linux*)
 280     llvm_cv_link_all_option="-Wl,--whole-archive"
 281     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 282     llvm_cv_os_type="Linux"
 283     llvm_cv_platform_type="Unix" ;;
 284   *-*-gnu*)
 285     llvm_cv_link_all_option="-Wl,--whole-archive"
 286     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 287     llvm_cv_os_type="GNU"
 288     llvm_cv_platform_type="Unix" ;;
 289   *-*-solaris*)
 290     llvm_cv_link_all_option="-Wl,-z,allextract"
 291     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 292     llvm_cv_os_type="SunOS"
 293     llvm_cv_platform_type="Unix" ;;
 294   *-*-win32*)
 295     llvm_cv_link_all_option="-Wl,--whole-archive"
 296     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 297     llvm_cv_os_type="Win32"
 298     llvm_cv_platform_type="Win32" ;;
 299   *-*-mingw*)
 300     llvm_cv_link_all_option="-Wl,--whole-archive"
 301     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 302     llvm_cv_os_type="MingW"
 303     llvm_cv_platform_type="Win32" ;;
 304   *-*-haiku*)
 305     llvm_cv_link_all_option="-Wl,--whole-archive"
 306     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 307     llvm_cv_os_type="Haiku"
 308     llvm_cv_platform_type="Unix" ;;
 309   *-unknown-eabi*)
 310     llvm_cv_link_all_option="-Wl,--whole-archive"
 311     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 312     llvm_cv_os_type="Freestanding"
 313     llvm_cv_platform_type="Unix" ;;
 314   *-unknown-elf*)
 315     llvm_cv_link_all_option="-Wl,--whole-archive"
 316     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 317     llvm_cv_os_type="Freestanding"
 318     llvm_cv_platform_type="Unix" ;;
 319   *)
 320     llvm_cv_link_all_option=""
 321     llvm_cv_no_link_all_option=""
 322     llvm_cv_os_type="Unknown"
 323     llvm_cv_platform_type="Unknown" ;;
 324 esac])
 325
 326 AC_CACHE_CHECK([type of operating system we're going to target],
 327                [llvm_cv_target_os_type],
 328 [case $target in
 329   *-*-aix*)
 330     llvm_cv_target_os_type="AIX" ;;
 331   *-*-irix*)
 332     llvm_cv_target_os_type="IRIX" ;;
 333   *-*-cygwin*)
 334     llvm_cv_target_os_type="Cygwin" ;;
 335   *-*-darwin*)
 336     llvm_cv_target_os_type="Darwin" ;;
 337   *-*-minix*)
 338     llvm_cv_target_os_type="Minix" ;;
 339   *-*-freebsd*)
 340     llvm_cv_target_os_type="FreeBSD" ;;
 341   *-*-kfreebsd-gnu)
 342     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 343   *-*-openbsd*)
 344     llvm_cv_target_os_type="OpenBSD" ;;
 345   *-*-netbsd*)
 346     llvm_cv_target_os_type="NetBSD" ;;
 347   *-*-dragonfly*)
 348     llvm_cv_target_os_type="DragonFly" ;;
 349   *-*-hpux*)
 350     llvm_cv_target_os_type="HP-UX" ;;
 351   *-*-interix*)
 352     llvm_cv_target_os_type="Interix" ;;
 353   *-*-linux*)
 354     llvm_cv_target_os_type="Linux" ;;
 355   *-*-gnu*)
 356     llvm_cv_target_os_type="GNU" ;;
 357   *-*-solaris*)
 358     llvm_cv_target_os_type="SunOS" ;;
 359   *-*-win32*)
 360     llvm_cv_target_os_type="Win32" ;;
 361   *-*-mingw*)
 362     llvm_cv_target_os_type="MingW" ;;
 363   *-*-haiku*)
 364     llvm_cv_target_os_type="Haiku" ;;
 365   *-*-rtems*)
 366     llvm_cv_target_os_type="RTEMS" ;;
 367   *-*-nacl*)
 368     llvm_cv_target_os_type="NativeClient" ;;
 369   *-unknown-eabi*)
 370     llvm_cv_target_os_type="Freestanding" ;;
 371   *)
 372     llvm_cv_target_os_type="Unknown" ;;
 373 esac])
 374
 375 dnl Make sure we aren't attempting to configure for an unknown system
 376 if test "$llvm_cv_os_type" = "Unknown" ; then
 377   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 378 fi
 379
 380 dnl Set the "OS" Makefile variable based on the platform type so the
 381 dnl makefile can configure itself to specific build hosts
 382 AC_SUBST(OS,$llvm_cv_os_type)
 383 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 384 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 385
 386 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 387 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 388 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 389
 390 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 391 dnl This is used by lib/Support to determine the basic kind of implementation
 392 dnl to use.
 393 case $llvm_cv_platform_type in
 394   Unix)
 395     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 396     AC_SUBST(LLVM_ON_UNIX,[1])
 397     AC_SUBST(LLVM_ON_WIN32,[0])
 398     ;;
 399   Win32)
 400     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 401     AC_SUBST(LLVM_ON_UNIX,[0])
 402     AC_SUBST(LLVM_ON_WIN32,[1])
 403     ;;
 404 esac
 405
 406 dnl Determine what our target architecture is and configure accordingly.
 407 dnl This will allow Makefiles to make a distinction between the hardware and
 408 dnl the OS.
 409 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 410 [case $target in
 411   i?86-*)                 llvm_cv_target_arch="x86" ;;
 412   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 413   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 414   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 415   arm64*-*)               llvm_cv_target_arch="AArch64" ;;
 416   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 417   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 418   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 419   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 420   xcore-*)                llvm_cv_target_arch="XCore" ;;
 421   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 422   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 423   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 424   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 425   *)                      llvm_cv_target_arch="Unknown" ;;
 426 esac])
 427
 428 if test "$llvm_cv_target_arch" = "Unknown" ; then
 429   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 430 fi
 431
 432 dnl Determine the LLVM native architecture for the target
 433 case "$llvm_cv_target_arch" in
 434     x86)     LLVM_NATIVE_ARCH="X86" ;;
 435     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 436     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 437 esac
 438
 439 dnl Define a substitution, ARCH, for the target architecture
 440 AC_SUBST(ARCH,$llvm_cv_target_arch)
 441 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 442
 443 dnl Determine what our host architecture.
 444 dnl This will allow MCJIT regress tests runs only for supported
 445 dnl platforms.
 446 case $host in
 447   i?86-*)                 host_arch="x86" ;;
 448   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 449   sparc*-*)               host_arch="Sparc" ;;
 450   powerpc*-*)             host_arch="PowerPC" ;;
 451   arm64*-*)               host_arch="AArch64" ;;
 452   arm*-*)                 host_arch="ARM" ;;
 453   aarch64*-*)             host_arch="AArch64" ;;
 454   mips-* | mips64-*)      host_arch="Mips" ;;
 455   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 456   xcore-*)                host_arch="XCore" ;;
 457   msp430-*)               host_arch="MSP430" ;;
 458   hexagon-*)              host_arch="Hexagon" ;;
 459   s390x-*)                host_arch="SystemZ" ;;
 460   *)                      host_arch="Unknown" ;;
 461 esac
 462
 463 if test "$host_arch" = "Unknown" ; then
 464   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 465 fi
 466
 467 AC_SUBST(HOST_ARCH,$host_arch)
 468
 469 dnl Check for build platform executable suffix if we're cross-compiling
 470 if test "$cross_compiling" = yes; then
 471   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 472   AC_BUILD_EXEEXT
 473   ac_build_prefix=${build_alias}-
 474   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 475   if test -z "$BUILD_CXX"; then
 476      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 477      if test -z "$BUILD_CXX"; then
 478        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 479      fi
 480   fi
 481 else
 482   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 483 fi
 484
 485 dnl Check to see if there's a .svn or .git directory indicating that this
 486 dnl build is being done from a checkout. This sets up several defaults for
 487 dnl the command line switches. When we build with a checkout directory,
 488 dnl we get a debug with assertions turned on. Without, we assume a source
 489 dnl release and we get an optimized build without assertions.
 490 dnl See --enable-optimized and --enable-assertions below
 491 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 492   cvsbuild="yes"
 493   optimize="no"
 494   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 495 else
 496   cvsbuild="no"
 497   optimize="yes"
 498 fi
 499
 500 dnl===-----------------------------------------------------------------------===
 501 dnl===
 502 dnl=== SECTION 3: Command line arguments for the configure script.
 503 dnl===
 504 dnl===-----------------------------------------------------------------------===
 505
 506 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 507 AC_ARG_ENABLE(libcpp,
 508               AS_HELP_STRING([--enable-libcpp],
 509                              [Use libc++ if available (default is NO)]),,
 510                              enableval=default)
 511 case "$enableval" in
 512   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 513   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 514   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 515   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 516 esac
 517
 518 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 519 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 520 dnl these checks here so that we have the configuration of the standard C++
 521 dnl library finished.
 522 AC_ARG_ENABLE(compiler-version-checks,
 523               AS_HELP_STRING([--enable-compiler-version-checks],
 524                              [Check the version of the host compiler (default is YES)]),,
 525                              enableval=default)
 526 case "$enableval" in
 527   no)
 528     ;;
 529   yes|default)
 530     AC_LANG_PUSH([C++])
 531     case "$llvm_cv_cxx_compiler" in
 532     clang)
 533       AC_MSG_CHECKING([whether Clang is new enough])
 534       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 535 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 536 #error This version of Clang is too old to build LLVM
 537 #endif
 538 ]])],
 539           [AC_MSG_RESULT([yes])],
 540           [AC_MSG_RESULT([no])
 541            AC_MSG_ERROR([
 542 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 543 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 544 bypass these sanity checks.])])
 545
 546       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 547       dnl are sometimes deeply confusing though. Here we test for an obvious
 548       dnl incomplete feature in 4.6's standard library that was completed in
 549       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 550       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 551       dnl that happening in the Makefile.
 552       if test "$ENABLE_LIBCPP" -eq 0 ; then
 553         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 554         llvm_cv_old_cxxflags="$CXXFLAGS"
 555         CXXFLAGS="$CXXFLAGS -std=c++0x"
 556         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 557 #include <atomic>
 558 std::atomic<float> x(0.0f);
 559 int main() { return (float)x; }
 560 ]])],
 561             [AC_MSG_RESULT([yes])],
 562             [AC_MSG_RESULT([no])
 563              AC_MSG_ERROR([
 564 We detected a missing feature in the standard C++ library that was known to be
 565 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 566 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 567 than 4.7. You will need to update your system and ensure Clang uses the newer
 568 standard library.
 569
 570 If this error is incorrect or you need to force things to work, you may pass
 571 '--disable-compiler-version-checks' to configure to bypass this test.])])
 572         CXXFLAGS="$llvm_cv_old_cxxflags"
 573       fi
 574       ;;
 575     gcc)
 576       AC_MSG_CHECKING([whether GCC is new enough])
 577       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 578 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 579 #error This version of GCC is too old to build LLVM
 580 #endif
 581 ]])],
 582           [AC_MSG_RESULT([yes])],
 583           [AC_MSG_RESULT([no])
 584            AC_MSG_ERROR([
 585 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 586 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 587 bypass these sanity checks.])])
 588       ;;
 589     unknown)
 590       ;;
 591     esac
 592     AC_LANG_POP([C++])
 593     ;;
 594   *)
 595     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 596     ;;
 597 esac
 598
 599 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 600 AC_ARG_ENABLE(cxx1y,
 601               AS_HELP_STRING([--enable-cxx1y],
 602                              [Use c++1y if available (default is NO)]),,
 603                              enableval=default)
 604 case "$enableval" in
 605   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 606   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 607   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 608   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 609 esac
 610
 611 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 612 dnl line
 613 AC_ARG_ENABLE(split-dwarf,
 614               AS_HELP_STRING([--enable-split-dwarf],
 615                              [Use split-dwarf if available (default is NO)]),,
 616                              enableval=default)
 617 case "$enableval" in
 618   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 619   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 620   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 621   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 622 esac
 623
 624 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 625 clang_arcmt="yes"
 626 AC_ARG_ENABLE(clang-arcmt,
 627               AS_HELP_STRING([--enable-clang-arcmt],
 628                              [Enable building of clang ARCMT (default is YES)]),
 629                              clang_arcmt="$enableval",
 630                              enableval="yes")
 631 case "$enableval" in
 632   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 633   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 634   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 635   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 636 esac
 637
 638 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 639 clang_plugin_support="yes"
 640 AC_ARG_ENABLE(clang-plugin-support,
 641               AS_HELP_STRING([--enable-clang-plugin-support],
 642                              [Enable plugin support in clang (default is YES)]),
 643                              clang_plugin_support="$enableval",
 644                              enableval="yes")
 645 case "$enableval" in
 646   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 647   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 648   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 649   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 650 esac
 651
 652 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 653 clang_static_analyzer="yes"
 654 AC_ARG_ENABLE(clang-static-analyzer,
 655               AS_HELP_STRING([--enable-clang-static-analyzer],
 656                              [Enable building of clang Static Analyzer (default is YES)]),
 657                              clang_static_analyzer="$enableval",
 658                              enableval="yes")
 659 case "$enableval" in
 660   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 661   no)
 662     if test ${clang_arcmt} != "no" ; then
 663       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 664     fi
 665     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 666     ;;
 667   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 668   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 669 esac
 670
 671 dnl --enable-optimized : check whether they want to do an optimized build:
 672 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 673  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 674 if test ${enableval} = "no" ; then
 675   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 676 else
 677   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 678 fi
 679
 680 dnl --enable-profiling : check whether they want to do a profile build:
 681 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 682  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 683 if test ${enableval} = "no" ; then
 684   AC_SUBST(ENABLE_PROFILING,[[]])
 685 else
 686   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 687 fi
 688
 689 dnl --enable-assertions : check whether they want to turn on assertions or not:
 690 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 691   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 692 if test ${enableval} = "yes" ; then
 693   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 694 else
 695   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 696 fi
 697
 698 dnl --enable-werror : check whether we want Werror on by default
 699 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 700   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 701 case "$enableval" in
 702   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 703   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 704   default) AC_SUBST(ENABLE_WERROR,[0]);;
 705   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 706 esac
 707
 708 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 709 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 710   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 711 if test ${enableval} = "yes" ; then
 712   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 713   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 714 else
 715   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 716   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 717 fi
 718
 719 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 720 AC_ARG_ENABLE(debug-runtime,
 721    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 722 if test ${enableval} = "no" ; then
 723   AC_SUBST(DEBUG_RUNTIME,[[]])
 724 else
 725   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 726 fi
 727
 728 dnl --enable-debug-symbols : should even optimized compiler libraries
 729 dnl have debug symbols?
 730 AC_ARG_ENABLE(debug-symbols,
 731    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 732 if test ${enableval} = "no" ; then
 733   AC_SUBST(DEBUG_SYMBOLS,[[]])
 734 else
 735   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 736 fi
 737
 738 dnl --enable-keep-symbols : do not strip installed executables
 739 AC_ARG_ENABLE(keep-symbols,
 740    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 741 if test ${enableval} = "no" ; then
 742   AC_SUBST(KEEP_SYMBOLS,[[]])
 743 else
 744   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 745 fi
 746
 747 dnl --enable-jit: check whether they want to enable the jit
 748 AC_ARG_ENABLE(jit,
 749   AS_HELP_STRING(--enable-jit,
 750                  [Enable Just In Time Compiling (default is YES)]),,
 751   enableval=default)
 752 if test ${enableval} = "no"
 753 then
 754   AC_SUBST(JIT,[[]])
 755 else
 756   case "$llvm_cv_target_arch" in
 757     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 758     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 759     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 760     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 761     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 762     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 763     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 764     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 765     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 766     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 767     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 768     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 769   esac
 770 fi
 771
 772 TARGETS_WITH_JIT="ARM AArch64 Mips PowerPC SystemZ X86"
 773 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 774
 775 dnl Allow enablement of building and installing docs
 776 AC_ARG_ENABLE(docs,
 777               AS_HELP_STRING([--enable-docs],
 778                              [Build documents (default is YES)]),,
 779                              enableval=default)
 780 case "$enableval" in
 781   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 782   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 783   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 784   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 785 esac
 786
 787 dnl Allow enablement of doxygen generated documentation
 788 AC_ARG_ENABLE(doxygen,
 789               AS_HELP_STRING([--enable-doxygen],
 790                              [Build doxygen documentation (default is NO)]),,
 791                              enableval=default)
 792 case "$enableval" in
 793   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 794   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 795   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 796   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 797 esac
 798
 799 dnl Allow disablement of threads
 800 AC_ARG_ENABLE(threads,
 801               AS_HELP_STRING([--enable-threads],
 802                              [Use threads if available (default is YES)]),,
 803                              enableval=default)
 804 case "$enableval" in
 805   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 806   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 807   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 808   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 809 esac
 810 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 811                    [Define if threads enabled])
 812
 813 dnl Allow disablement of pthread.h
 814 AC_ARG_ENABLE(pthreads,
 815               AS_HELP_STRING([--enable-pthreads],
 816                              [Use pthreads if available (default is YES)]),,
 817                              enableval=default)
 818 case "$enableval" in
 819   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 820   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 821   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 822   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 823 esac
 824
 825 dnl Allow disablement of zlib
 826 AC_ARG_ENABLE(zlib,
 827               AS_HELP_STRING([--enable-zlib],
 828                              [Use zlib for compression/decompression if
 829                               available (default is YES)]),,
 830                               enableval=default)
 831 case "$enableval" in
 832   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 833   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 834   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 835   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 836 esac
 837 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 838                    [Define if zlib is enabled])
 839
 840 dnl Allow building without position independent code
 841 AC_ARG_ENABLE(pic,
 842   AS_HELP_STRING([--enable-pic],
 843                  [Build LLVM with Position Independent Code (default is YES)]),,
 844                  enableval=default)
 845 case "$enableval" in
 846   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 847   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 848   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 849   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 850 esac
 851 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 852                    [Define if position independent code is enabled])
 853
 854 dnl Allow building a shared library and linking tools against it.
 855 AC_ARG_ENABLE(shared,
 856   AS_HELP_STRING([--enable-shared],
 857                  [Build a shared library and link tools against it (default is NO)]),,
 858                  enableval=default)
 859 case "$enableval" in
 860   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 861   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 862   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 863   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 864 esac
 865
 866 dnl Allow libstdc++ is embedded in LLVM.dll.
 867 AC_ARG_ENABLE(embed-stdcxx,
 868   AS_HELP_STRING([--enable-embed-stdcxx],
 869                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 870                  enableval=default)
 871 case "$enableval" in
 872   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 873   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 874   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 875   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 876 esac
 877
 878 dnl Enable embedding timestamp information into build.
 879 AC_ARG_ENABLE(timestamps,
 880   AS_HELP_STRING([--enable-timestamps],
 881                  [Enable embedding timestamp information in build (default is YES)]),,
 882                  enableval=default)
 883 case "$enableval" in
 884   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 885   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 886   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 887   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 888 esac
 889 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 890                    [Define if timestamp information (e.g., __DATE__) is allowed])
 891
 892 dnl Enable support for showing backtraces.
 893 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 894   [--enable-backtraces],
 895   [Enable embedding backtraces on crash (default is YES)]),
 896   [case "$enableval" in
 897     yes) llvm_cv_enable_backtraces="yes" ;;
 898     no)  llvm_cv_enable_backtraces="no"  ;;
 899     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 900   esac],
 901   llvm_cv_enable_backtraces="yes")
 902 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 903   AC_DEFINE([ENABLE_BACKTRACES],[1],
 904             [Define if you want backtraces on crash])
 905 fi
 906
 907 dnl Enable installing platform specific signal handling overrides, for improved
 908 dnl CrashRecovery support or interaction with crash reporting software. This
 909 dnl support may be inappropriate for some clients embedding LLVM as a library.
 910 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 911   [--enable-crash-overrides],
 912   [Enable crash handling overrides (default is YES)]),
 913   [case "$enableval" in
 914     yes) llvm_cv_enable_crash_overrides="yes" ;;
 915     no)  llvm_cv_enable_crash_overrides="no"  ;;
 916     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 917   esac],
 918   llvm_cv_enable_crash_overrides="yes")
 919 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 920   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 921             [Define to enable crash handling overrides])
 922 fi
 923
 924 dnl List all possible targets
 925 ALL_TARGETS="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600"
 926 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
 927
 928 dnl Allow specific targets to be specified for building (or not)
 929 TARGETS_TO_BUILD=""
 930 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 931     [Build specific host targets: all or target1,target2,... Valid targets are:
 932      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
 933      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 934     enableval=all)
 935 if test "$enableval" = host-only ; then
 936   enableval=host
 937 fi
 938 case "$enableval" in
 939   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
 940   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 941       case "$a_target" in
 942         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 943         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 944         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 945         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 946         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 947         arm64)    TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 948         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 949         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 950         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 951         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 952         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 953         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 954         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 955         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 956         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 957         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 958         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 959         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 960         host) case "$llvm_cv_target_arch" in
 961             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 962             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 963             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 964             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 965             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 966             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 967             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 968             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 969             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 970             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 971             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 972             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 973             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 974           esac ;;
 975         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 976       esac
 977   done
 978   ;;
 979 esac
 980
 981 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 982     [Build experimental host targets: disable or target1,target2,...
 983      (default=disable)]),,
 984     enableval=disable)
 985
 986 if test ${enableval} != "disable"
 987 then
 988   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 989 fi
 990
 991 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 992
 993 dnl Determine whether we are building LLVM support for the native architecture.
 994 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 995 for a_target in $TARGETS_TO_BUILD; do
 996   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 997     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 998       [LLVM architecture name for the native architecture, if available])
 999     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1000     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1001     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1002     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1003     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1004       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1005     fi
1006     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1007       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1008     fi
1009     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1010       [LLVM name for the native Target init function, if available])
1011     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1012       [LLVM name for the native TargetInfo init function, if available])
1013     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1014       [LLVM name for the native target MC init function, if available])
1015     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1016       [LLVM name for the native AsmPrinter init function, if available])
1017     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1018       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1019        [LLVM name for the native AsmParser init function, if available])
1020     fi
1021     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1022       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1023        [LLVM name for the native Disassembler init function, if available])
1024     fi
1025   fi
1026 done
1027
1028 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1029 dnl target feature def files.
1030 LLVM_ENUM_TARGETS=""
1031 LLVM_ENUM_ASM_PRINTERS=""
1032 LLVM_ENUM_ASM_PARSERS=""
1033 LLVM_ENUM_DISASSEMBLERS=""
1034 for target_to_build in $TARGETS_TO_BUILD; do
1035   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1036   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1037     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1038   fi
1039   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1040     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1041   fi
1042   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1043     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1044   fi
1045 done
1046 AC_SUBST(LLVM_ENUM_TARGETS)
1047 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1048 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1049 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1050
1051 dnl Override the option to use for optimized builds.
1052 AC_ARG_WITH(optimize-option,
1053   AS_HELP_STRING([--with-optimize-option],
1054                  [Select the compiler options to use for optimized builds]),,
1055                  withval=default)
1056 AC_MSG_CHECKING([optimization flags])
1057 case "$withval" in
1058   default)
1059     case "$llvm_cv_os_type" in
1060     FreeBSD) optimize_option=-O2 ;;
1061     MingW) optimize_option=-O2 ;;
1062     *)     optimize_option=-O3 ;;
1063     esac ;;
1064   *) optimize_option="$withval" ;;
1065 esac
1066 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1067 AC_MSG_RESULT([$optimize_option])
1068
1069 dnl Specify extra build options
1070 AC_ARG_WITH(extra-options,
1071   AS_HELP_STRING([--with-extra-options],
1072                  [Specify additional options to compile LLVM with]),,
1073                  withval=default)
1074 case "$withval" in
1075   default) EXTRA_OPTIONS= ;;
1076   *) EXTRA_OPTIONS=$withval ;;
1077 esac
1078 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1079
1080 dnl Specify extra linker build options
1081 AC_ARG_WITH(extra-ld-options,
1082   AS_HELP_STRING([--with-extra-ld-options],
1083                  [Specify additional options to link LLVM with]),,
1084                  withval=default)
1085 case "$withval" in
1086   default) EXTRA_LD_OPTIONS= ;;
1087   *) EXTRA_LD_OPTIONS=$withval ;;
1088 esac
1089 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1090
1091 dnl Allow specific bindings to be specified for building (or not)
1092 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1093     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1094     enableval=default)
1095 BINDINGS_TO_BUILD=""
1096 case "$enableval" in
1097   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1098   all ) BINDINGS_TO_BUILD="ocaml" ;;
1099   none | no) BINDINGS_TO_BUILD="" ;;
1100   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1101       case "$a_binding" in
1102         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1103         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1104       esac
1105   done
1106   ;;
1107 esac
1108
1109 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1110 dnl script for bindings/ocaml/configure, except that its auto value depends on
1111 dnl OCAMLC, which is found here to support tests.
1112 AC_ARG_WITH([ocaml-libdir],
1113   [AS_HELP_STRING([--with-ocaml-libdir],
1114     [Specify install location for ocaml bindings (default is stdlib)])],
1115   [],
1116   [withval=auto])
1117 case "$withval" in
1118   auto) with_ocaml_libdir="$withval" ;;
1119   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1120   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1121 esac
1122
1123 AC_ARG_WITH(clang-srcdir,
1124   AS_HELP_STRING([--with-clang-srcdir],
1125     [Directory to the out-of-tree Clang source]),,
1126     withval="-")
1127 case "$withval" in
1128   -) clang_src_root="" ;;
1129   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1130   *) clang_src_root="$ac_pwd/$withval" ;;
1131 esac
1132 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1133
1134 AC_ARG_WITH(clang-resource-dir,
1135   AS_HELP_STRING([--with-clang-resource-dir],
1136     [Relative directory from the Clang binary for resource files]),,
1137     withval="")
1138 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1139                    [Relative directory for resource files])
1140
1141 AC_ARG_WITH(c-include-dirs,
1142   AS_HELP_STRING([--with-c-include-dirs],
1143     [Colon separated list of directories clang will search for headers]),,
1144     withval="")
1145 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1146                    [Directories clang will search for headers])
1147
1148 # Clang normally uses the system c++ headers and libraries. With this option,
1149 # clang will use the ones provided by a gcc installation instead. This option should
1150 # be passed the same value that was used with --prefix when configuring gcc.
1151 AC_ARG_WITH(gcc-toolchain,
1152   AS_HELP_STRING([--with-gcc-toolchain],
1153     [Directory where gcc is installed.]),,
1154     withval="")
1155 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1156                    [Directory where gcc is installed.])
1157
1158 AC_ARG_WITH(default-sysroot,
1159   AS_HELP_STRING([--with-default-sysroot],
1160     [Add --sysroot=<path> to all compiler invocations.]),,
1161     withval="")
1162 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1163                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1164
1165 dnl Allow linking of LLVM with GPLv3 binutils code.
1166 AC_ARG_WITH(binutils-include,
1167   AS_HELP_STRING([--with-binutils-include],
1168     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1169   withval=default)
1170 case "$withval" in
1171   default) WITH_BINUTILS_INCDIR=default ;;
1172   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1173   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1174 esac
1175 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1176   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1177   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1178      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1179      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1180   fi
1181 fi
1182
1183 dnl Specify the URL where bug reports should be submitted.
1184 AC_ARG_WITH(bug-report-url,
1185   AS_HELP_STRING([--with-bug-report-url],
1186     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1187     withval="http://llvm.org/bugs/")
1188 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1189                    [Bug report URL.])
1190
1191 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1192 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1193   [--enable-terminfo],
1194   [Query the terminfo database if available (default is YES)]),
1195   [case "$enableval" in
1196     yes) llvm_cv_enable_terminfo="yes" ;;
1197     no)  llvm_cv_enable_terminfo="no"  ;;
1198     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1199   esac],
1200   llvm_cv_enable_terminfo="yes")
1201 case "$llvm_cv_enable_terminfo" in
1202   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1203   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1204 esac
1205
1206 dnl --enable-libedit: check whether the user wants to turn off libedit.
1207 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1208   [--enable-libedit],
1209   [Use libedit if available (default is YES)]),
1210   [case "$enableval" in
1211     yes) llvm_cv_enable_libedit="yes" ;;
1212     no)  llvm_cv_enable_libedit="no"  ;;
1213     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1214   esac],
1215   llvm_cv_enable_libedit="yes")
1216
1217 dnl --enable-libffi : check whether the user wants to turn off libffi:
1218 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1219   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1220   [case "$enableval" in
1221     yes) llvm_cv_enable_libffi="yes" ;;
1222     no)  llvm_cv_enable_libffi="no"  ;;
1223     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1224   esac],
1225   llvm_cv_enable_libffi=no)
1226
1227 AC_ARG_WITH(internal-prefix,
1228   AS_HELP_STRING([--with-internal-prefix],
1229     [Installation directory for internal files]),,
1230     withval="")
1231 AC_SUBST(INTERNAL_PREFIX,[$withval])
1232
1233 dnl===-----------------------------------------------------------------------===
1234 dnl===
1235 dnl=== SECTION 4: Check for programs we need and that they are the right version
1236 dnl===
1237 dnl===-----------------------------------------------------------------------===
1238
1239 dnl Check for the tools that the makefiles require
1240 AC_CHECK_GNU_MAKE
1241 AC_PROG_LN_S
1242 AC_PATH_PROG(NM, [nm], [nm])
1243 AC_PATH_PROG(CMP, [cmp], [cmp])
1244 AC_PATH_PROG(CP, [cp], [cp])
1245 AC_PATH_PROG(DATE, [date], [date])
1246 AC_PATH_PROG(FIND, [find], [find])
1247 AC_PATH_PROG(GREP, [grep], [grep])
1248 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1249 AC_PATH_PROG(MV,   [mv],   [mv])
1250 AC_PROG_RANLIB
1251 AC_CHECK_TOOL(AR, ar, false)
1252 AC_PATH_PROG(RM,   [rm],   [rm])
1253 AC_PATH_PROG(SED,  [sed],  [sed])
1254 AC_PATH_PROG(TAR,  [tar],  [gtar])
1255 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1256
1257 dnl Looking for misc. graph plotting software
1258 AC_PATH_PROG(DOT, [dot], [echo dot])
1259 if test "$DOT" != "echo dot" ; then
1260   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1261   dnl If we're targeting for mingw we should emit windows paths, not msys
1262   if test "$llvm_cv_os_type" = "MingW" ; then
1263     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1264   fi
1265   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1266    [Define to path to dot program if found or 'echo dot' otherwise])
1267 fi
1268
1269 dnl Find the install program
1270 AC_PROG_INSTALL
1271 dnl Prepend src dir to install path dir if it's a relative path
1272 dnl This is a hack for installs that take place in something other
1273 dnl than the top level.
1274 case "$INSTALL" in
1275  [[\\/$]]* | ?:[[\\/]]* ) ;;
1276  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1277 esac
1278
1279 dnl Checks for documentation and testing tools that we can do without. If these
1280 dnl are not found then they are set to "true" which always succeeds but does
1281 dnl nothing. This just lets the build output show that we could have done
1282 dnl something if the tool was available.
1283 AC_PATH_PROG(BZIP2, [bzip2])
1284 AC_PATH_PROG(CAT, [cat])
1285 AC_PATH_PROG(DOXYGEN, [doxygen])
1286 AC_PATH_PROG(GROFF, [groff])
1287 AC_PATH_PROG(GZIPBIN, [gzip])
1288 AC_PATH_PROG(PDFROFF, [pdfroff])
1289 AC_PATH_PROG(ZIP, [zip])
1290 AC_PATH_PROG(GO, [go])
1291 AC_PATH_PROGS(OCAMLC, [ocamlc])
1292 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1293 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1294 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1295 AC_PATH_PROGS(GAS, [gas as])
1296
1297 dnl Get the version of the linker in use.
1298 AC_LINK_GET_VERSION
1299
1300 dnl Determine whether the linker supports the -R option.
1301 AC_LINK_USE_R
1302
1303 dnl Determine whether the compiler supports the -rdynamic option.
1304 AC_LINK_EXPORT_DYNAMIC
1305
1306 dnl Determine whether the linker supports the --version-script option.
1307 AC_LINK_VERSION_SCRIPT
1308
1309 AC_CHECK_HEADERS([errno.h])
1310
1311 case "$llvm_cv_os_type" in
1312   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1313   Darwin) llvm_shlib_ext=.dylib ;;
1314   *) llvm_shlib_ext=.so ;;
1315 esac
1316
1317 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1318
1319 AC_MSG_CHECKING([tool compatibility])
1320
1321 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1322 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1323 dnl to support those options.
1324 dnl "icc" emits gcc signatures
1325 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1326 ICC=no
1327 IXX=no
1328 case $CC in
1329   icc*|icpc*)
1330     ICC=yes
1331     IXX=yes
1332     ;;
1333    *)
1334     ;;
1335 esac
1336
1337 if test "$GCC" != "yes" && test "$ICC" != "yes"
1338 then
1339   AC_MSG_ERROR([gcc|icc required but not found])
1340 fi
1341
1342 dnl Ensure that compilation tools are compatible with GCC extensions
1343 if test "$GXX" != "yes" && test "$IXX" != "yes"
1344 then
1345   AC_MSG_ERROR([g++|clang++|icc required but not found])
1346 fi
1347
1348 dnl Verify that GCC is version 3.0 or higher
1349 if test "$GCC" = "yes"
1350 then
1351   AC_COMPILE_IFELSE(
1352 [
1353   AC_LANG_SOURCE([[
1354     #if !defined(__GNUC__) || __GNUC__ < 3
1355     #error Unsupported GCC version
1356     #endif
1357   ]])
1358 ],
1359 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1360 fi
1361
1362 dnl Check for GNU Make.  We use its extensions, so don't build without it
1363 if test -z "$llvm_cv_gnu_make_command"
1364 then
1365   AC_MSG_ERROR([GNU Make required but not found])
1366 fi
1367
1368 dnl Tool compatibility is okay if we make it here.
1369 AC_MSG_RESULT([ok])
1370
1371 dnl Check optional compiler flags.
1372 AC_MSG_CHECKING([optional compiler flags])
1373 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1374 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1375 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1376
1377 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1378 dnl false positives, so disable it.
1379 NO_UNINITIALIZED=
1380 NO_MAYBE_UNINITIALIZED=
1381 if test "$GXX" = "yes"
1382 then
1383   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1384   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1385   dnl known to be uninitialized from cases which might be uninitialized.  We
1386   dnl still want to catch the first kind of errors.
1387   if test -z "$NO_MAYBE_UNINITIALIZED"
1388   then
1389     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1390   fi
1391 fi
1392 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1393
1394 AC_ARG_WITH([python],
1395             [AS_HELP_STRING([--with-python], [path to python])],
1396             [PYTHON="$withval"])
1397
1398 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1399   AC_MSG_CHECKING([for python])
1400   AC_MSG_RESULT([user defined: $with_python])
1401 else
1402   if test -n "$PYTHON" ; then
1403     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1404   fi
1405
1406   AC_PATH_PROG([PYTHON], [python python2 python26],
1407                [AC_MSG_RESULT([not found])
1408                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1409 fi
1410
1411 AC_MSG_CHECKING([for python >= 2.5])
1412 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1413 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1414 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1415 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1416 if test "$ac_python_version_major" -gt "2" || \
1417    (test "$ac_python_version_major" -eq "2" && \
1418     test "$ac_python_version_minor" -ge "5") ; then
1419   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1420 else
1421   AC_MSG_RESULT([not found])
1422   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1423 fi
1424
1425 dnl===-----------------------------------------------------------------------===
1426 dnl===
1427 dnl=== SECTION 5: Check for libraries
1428 dnl===
1429 dnl===-----------------------------------------------------------------------===
1430
1431 AC_CHECK_LIB(m,sin)
1432 if test "$llvm_cv_os_type" = "MingW" ; then
1433   AC_CHECK_LIB(imagehlp, main)
1434   AC_CHECK_LIB(psapi, main)
1435   AC_CHECK_LIB(shell32, main)
1436 fi
1437
1438 dnl dlopen() is required for plugin support.
1439 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1440                [Define if dlopen() is available on this platform.]),
1441                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1442
1443 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1444 dnl macros to detect whether clock_gettime is available, this just finds the
1445 dnl right libraries to link with.
1446 AC_SEARCH_LIBS(clock_gettime,rt)
1447
1448 dnl The curses library is optional; used for querying terminal info
1449 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1450   dnl We need the has_color functionality in curses for it to be useful.
1451   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1452                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1453                                    [Define if the setupterm() function is supported this platform.]))
1454 fi
1455
1456 dnl The libedit library is optional; used by lib/LineEditor
1457 if test "$llvm_cv_enable_libedit" = "yes" ; then
1458   AC_SEARCH_LIBS(el_init,edit,
1459                  AC_DEFINE([HAVE_LIBEDIT],[1],
1460                            [Define if libedit is available on this platform.]))
1461 fi
1462
1463 dnl libffi is optional; used to call external functions from the interpreter
1464 if test "$llvm_cv_enable_libffi" = "yes" ; then
1465   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1466                  [Define if libffi is available on this platform.]),
1467                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1468 fi
1469
1470 dnl mallinfo is optional; the code can compile (minus features) without it
1471 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1472                [Define if mallinfo() is available on this platform.]))
1473
1474 dnl pthread locking functions are optional - but llvm will not be thread-safe
1475 dnl without locks.
1476 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1477   AC_CHECK_LIB(pthread, pthread_mutex_init)
1478   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1479                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1480                            [Have pthread_mutex_lock]))
1481   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1482                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1483                  [Have pthread_rwlock_init]))
1484   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1485                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1486                  [Have pthread_getspecific]))
1487 fi
1488
1489 dnl zlib is optional; used for compression/uncompression
1490 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1491   AC_CHECK_LIB(z, compress2)
1492 fi
1493
1494 dnl Allow OProfile support for JIT output.
1495 AC_ARG_WITH(oprofile,
1496   AS_HELP_STRING([--with-oprofile=<prefix>],
1497     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1498     [
1499       AC_SUBST(USE_OPROFILE, [1])
1500       case "$withval" in
1501         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1502         no) llvm_cv_oppath=
1503             AC_SUBST(USE_OPROFILE, [0]) ;;
1504         *) llvm_cv_oppath="${withval}/lib/oprofile"
1505            CPPFLAGS="-I${withval}/include";;
1506       esac
1507       case $llvm_cv_os_type in
1508         Linux)
1509           if test -n "$llvm_cv_oppath" ; then
1510             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1511             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1512             dnl libbfd is not included properly in libopagent in some Debian
1513             dnl versions.  If libbfd isn't found at all, we assume opagent works
1514             dnl anyway.
1515             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1516             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1517               echo "Error! You need to have libopagent around."
1518               exit -1
1519             ])
1520             AC_CHECK_HEADER([opagent.h], [], [
1521               echo "Error! You need to have opagent.h around."
1522               exit -1
1523               ])
1524           fi ;;
1525         *)
1526           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1527       esac
1528     ],
1529     [
1530       AC_SUBST(USE_OPROFILE, [0])
1531     ])
1532 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1533                    [Define if we have the oprofile JIT-support library])
1534
1535 dnl Enable support for Intel JIT Events API.
1536 AC_ARG_WITH(intel-jitevents,
1537   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1538     [
1539        case "$withval" in
1540           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1541           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1542           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1543        esac
1544
1545       case $llvm_cv_os_type in
1546         Linux|Win32|Cygwin|MingW) ;;
1547         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1548       esac
1549
1550       case "$llvm_cv_target_arch" in
1551         x86|x86_64) ;;
1552         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1553       esac
1554     ],
1555     [
1556       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1557     ])
1558 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1559                    [Define if we have the Intel JIT API runtime support library])
1560
1561 dnl Check for libxml2
1562 dnl Right now we're just checking for the existence, we could also check for a
1563 dnl particular version via --version on xml2-config
1564 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1565
1566 AC_MSG_CHECKING(for libxml2 includes)
1567 if test "x$XML2CONFIG" = "x"; then
1568  AC_MSG_RESULT(xml2-config not found)
1569 else
1570  LIBXML2_INC=`$XML2CONFIG --cflags`
1571  AC_MSG_RESULT($LIBXML2_INC)
1572  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1573                                 LIBXML2_LIBS="-lxml2"])
1574 fi
1575 AC_SUBST(LIBXML2_LIBS)
1576 AC_SUBST(LIBXML2_INC)
1577
1578 dnl===-----------------------------------------------------------------------===
1579 dnl===
1580 dnl=== SECTION 6: Check for header files
1581 dnl===
1582 dnl===-----------------------------------------------------------------------===
1583
1584 dnl First, use autoconf provided macros for specific headers that we need
1585 dnl We don't check for ancient stuff or things that are guaranteed to be there
1586 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1587 dnl Generally we're looking for POSIX headers.
1588 AC_HEADER_DIRENT
1589 AC_HEADER_MMAP_ANONYMOUS
1590 AC_HEADER_STAT
1591 AC_HEADER_SYS_WAIT
1592 AC_HEADER_TIME
1593
1594 AC_LANG_PUSH([C++])
1595 AC_CHECK_HEADERS([cxxabi.h])
1596 AC_LANG_POP([C++])
1597 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1598 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1599 AC_CHECK_HEADERS([utime.h])
1600 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1601 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1602 AC_CHECK_HEADERS([valgrind/valgrind.h])
1603 AC_CHECK_HEADERS([fenv.h])
1604 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1605 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1606   AC_CHECK_HEADERS(pthread.h,
1607                    AC_SUBST(HAVE_PTHREAD, 1),
1608                    AC_SUBST(HAVE_PTHREAD, 0))
1609 else
1610   AC_SUBST(HAVE_PTHREAD, 0)
1611 fi
1612 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1613   AC_CHECK_HEADERS(zlib.h,
1614                    AC_SUBST(HAVE_LIBZ, 1),
1615                    AC_SUBST(HAVE_LIBZ, 0))
1616 else
1617   AC_SUBST(HAVE_LIBZ, 0)
1618 fi
1619
1620 dnl Try to find ffi.h.
1621 if test "$llvm_cv_enable_libffi" = "yes" ; then
1622   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1623 fi
1624
1625 dnl Try to find Darwin specific crash reporting libraries.
1626 AC_CHECK_HEADERS([CrashReporterClient.h])
1627
1628 dnl Try to find Darwin specific crash reporting global.
1629 AC_MSG_CHECKING([__crashreporter_info__])
1630 AC_LINK_IFELSE(
1631 [
1632   AC_LANG_SOURCE([[
1633     extern const char *__crashreporter_info__;
1634     int main() {
1635       __crashreporter_info__ = "test";
1636       return 0;
1637     }
1638   ]])
1639 ],
1640 [
1641   AC_MSG_RESULT([yes])
1642   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1643 ],
1644 [
1645   AC_MSG_RESULT([no])
1646   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1647 ])
1648
1649 dnl===-----------------------------------------------------------------------===
1650 dnl===
1651 dnl=== SECTION 7: Check for types and structures
1652 dnl===
1653 dnl===-----------------------------------------------------------------------===
1654
1655 AC_HUGE_VAL_CHECK
1656 AC_TYPE_PID_T
1657 AC_TYPE_SIZE_T
1658 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1659 AC_STRUCT_TM
1660 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1661 AC_CHECK_TYPES([uint64_t],,
1662          AC_CHECK_TYPES([u_int64_t],,
1663          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1664
1665 dnl===-----------------------------------------------------------------------===
1666 dnl===
1667 dnl=== SECTION 8: Check for specific functions needed
1668 dnl===
1669 dnl===-----------------------------------------------------------------------===
1670
1671 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1672 AC_CHECK_FUNCS([powf fmodf strtof round ])
1673 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1674 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1675 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1676 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1677 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1678 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1679 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1680 AC_CHECK_FUNCS([futimes futimens])
1681 AC_C_PRINTF_A
1682 AC_FUNC_RAND48
1683
1684 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1685 AC_CHECK_DECLS([arc4random])
1686
1687 dnl Check the declaration "Secure API" on Windows environments.
1688 AC_CHECK_DECLS([strerror_s])
1689
1690 dnl Check symbols in libgcc.a for JIT on Mingw.
1691 if test "$llvm_cv_os_type" = "MingW" ; then
1692   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1693   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1694   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1695   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1696
1697   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1698   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1699   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1700   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1701   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1702   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1703   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1704   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1705   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1706   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1707
1708   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1709   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1710 fi
1711
1712 dnl Check Win32 API EnumerateLoadedModules.
1713 if test "$llvm_cv_os_type" = "MingW" ; then
1714   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1715   AC_COMPILE_IFELSE(
1716 [
1717   AC_LANG_SOURCE([[
1718     #include <windows.h>
1719     #include <imagehlp.h>
1720     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1721     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1722   ]])
1723 ],
1724 [
1725   AC_MSG_RESULT([yes])
1726   llvm_cv_win32_elmcb_pcstr="PCSTR"
1727 ],
1728 [
1729   AC_MSG_RESULT([no])
1730   llvm_cv_win32_elmcb_pcstr="PSTR"
1731 ])
1732   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1733 fi
1734
1735 dnl Check for variations in the Standard C++ library and STL. These macros are
1736 dnl provided by LLVM in the autoconf/m4 directory.
1737 AC_FUNC_ISNAN
1738 AC_FUNC_ISINF
1739
1740 dnl Check for mmap support.We also need to know if /dev/zero is required to
1741 dnl be opened for allocating RWX memory.
1742 dnl Make sure we aren't attempting to configure for an unknown system
1743 if test "$llvm_cv_platform_type" = "Unix" ; then
1744   AC_FUNC_MMAP
1745   AC_FUNC_MMAP_FILE
1746   AC_NEED_DEV_ZERO_FOR_MMAP
1747
1748   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1749   then
1750     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1751   fi
1752   if test "$ac_cv_func_mmap_file" = "no"
1753   then
1754     AC_MSG_WARN([mmap() of files required but not found])
1755   fi
1756 fi
1757
1758 dnl atomic builtins are required for threading support.
1759 AC_MSG_CHECKING(for GCC atomic builtins)
1760 dnl Since we'll be using these atomic builtins in C++ files we should test
1761 dnl the C++ compiler.
1762 AC_LANG_PUSH([C++])
1763 AC_LINK_IFELSE(
1764 [
1765   AC_LANG_SOURCE([[
1766     int main() {
1767       volatile unsigned long val = 1;
1768       __sync_synchronize();
1769       __sync_val_compare_and_swap(&val, 1, 0);
1770       __sync_add_and_fetch(&val, 1);
1771       __sync_sub_and_fetch(&val, 1);
1772       return 0;
1773     }
1774   ]])
1775 ],
1776 [
1777   AC_MSG_RESULT([yes])
1778   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1779 ],
1780 [
1781   AC_MSG_RESULT([no])
1782   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1783   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1784 ])
1785 AC_LANG_POP([C++])
1786
1787 dnl===-----------------------------------------------------------------------===
1788 dnl===
1789 dnl=== SECTION 9: Additional checks, variables, etc.
1790 dnl===
1791 dnl===-----------------------------------------------------------------------===
1792
1793 dnl Handle 32-bit linux systems running a 64-bit kernel.
1794 dnl This has to come after section 4 because it invokes the compiler.
1795 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1796   AC_IS_LINUX_MIXED
1797   if test "$llvm_cv_linux_mixed" = "yes"; then
1798     llvm_cv_target_arch="x86"
1799     ARCH="x86"
1800   fi
1801 fi
1802
1803 dnl Check whether __dso_handle is present
1804 AC_CHECK_FUNCS([__dso_handle])
1805
1806 dnl Propagate the shared library extension that the libltdl checks did to
1807 dnl the Makefiles so we can use it there too
1808 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
1809
1810 dnl Translate the various configuration directories and other basic
1811 dnl information into substitutions that will end up in Makefile.config.in
1812 dnl that these configured values can be used by the makefiles
1813 if test "${prefix}" = "NONE" ; then
1814   prefix="/usr/local"
1815 fi
1816 eval LLVM_PREFIX="${prefix}";
1817 eval LLVM_BINDIR="${prefix}/bin";
1818 eval LLVM_DATADIR="${prefix}/share/llvm";
1819 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1820 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1821 eval LLVM_INCLUDEDIR="${prefix}/include";
1822 eval LLVM_INFODIR="${prefix}/info";
1823 eval LLVM_MANDIR="${prefix}/man";
1824 LLVM_CONFIGTIME=`date`
1825 AC_SUBST(LLVM_PREFIX)
1826 AC_SUBST(LLVM_BINDIR)
1827 AC_SUBST(LLVM_DATADIR)
1828 AC_SUBST(LLVM_DOCSDIR)
1829 AC_SUBST(LLVM_ETCDIR)
1830 AC_SUBST(LLVM_INCLUDEDIR)
1831 AC_SUBST(LLVM_INFODIR)
1832 AC_SUBST(LLVM_MANDIR)
1833 AC_SUBST(LLVM_CONFIGTIME)
1834
1835 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1836 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1837   LLVM_CONFIGTIME="(timestamp not enabled)"
1838 fi
1839
1840 dnl Place the various directories into the config.h file as #defines so that we
1841 dnl can know about the installation paths within LLVM.
1842 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1843                    [Installation prefix directory])
1844 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1845                    [Installation directory for binary executables])
1846 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1847                    [Installation directory for data files])
1848 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1849                    [Installation directory for documentation])
1850 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1851                    [Installation directory for config files])
1852 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1853                    [Installation directory for include files])
1854 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1855                    [Installation directory for .info files])
1856 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1857                    [Installation directory for man pages])
1858 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1859                    [Time at which LLVM was configured])
1860 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1861                    [Host triple LLVM will be executed on])
1862 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1863                    [Target triple LLVM will generate code for by default])
1864
1865 dnl Determine which bindings to build.
1866 if test "$BINDINGS_TO_BUILD" = auto ; then
1867   BINDINGS_TO_BUILD=""
1868   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1869     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1870   fi
1871   if test "x$GO" != x ; then
1872     if $GO run ${srcdir}/bindings/go/conftest.go ; then
1873       BINDINGS_TO_BUILD="go $BINDINGS_TO_BUILD"
1874     fi
1875   fi
1876 fi
1877 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1878
1879 dnl Do any work necessary to ensure that bindings have what they need.
1880 binding_prereqs_failed=0
1881 for a_binding in $BINDINGS_TO_BUILD ; do
1882   case "$a_binding" in
1883   ocaml)
1884     if test "x$OCAMLC" = x ; then
1885       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1886       binding_prereqs_failed=1
1887     fi
1888     if test "x$OCAMLDEP" = x ; then
1889       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1890       binding_prereqs_failed=1
1891     fi
1892     if test "x$OCAMLOPT" = x ; then
1893       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1894       dnl ocamlopt is optional!
1895     fi
1896     if test "x$with_ocaml_libdir" != xauto ; then
1897       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1898     else
1899       ocaml_stdlib="`"$OCAMLC" -where`"
1900       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1901       then
1902         # ocaml stdlib is beneath our prefix; use stdlib
1903         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1904       else
1905         # ocaml stdlib is outside our prefix; use libdir/ocaml
1906         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1907       fi
1908     fi
1909     ;;
1910   go)
1911     if test "x$GO" = x ; then
1912       AC_MSG_WARN([--enable-bindings=go specified, but go not found. Try configure GO=/path/to/go])
1913       binding_prereqs_failed=1
1914     else
1915       if $GO run ${srcdir}/bindings/go/conftest.go ; then
1916         :
1917       else
1918         AC_MSG_WARN([--enable-bindings=go specified, but need at least Go 1.2. Try configure GO=/path/to/go])
1919         binding_prereqs_failed=1
1920       fi
1921     fi
1922     ;;
1923   esac
1924 done
1925 if test "$binding_prereqs_failed" = 1 ; then
1926   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1927 fi
1928
1929 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1930 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1931
1932 dnl Determine linker rpath flag
1933 if test "$llvm_cv_link_use_r" = "yes" ; then
1934   RPATH="-Wl,-R"
1935 else
1936   RPATH="-Wl,-rpath"
1937 fi
1938 AC_SUBST(RPATH)
1939
1940 dnl Determine linker rdynamic flag
1941 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1942   RDYNAMIC="-rdynamic"
1943 else
1944   RDYNAMIC=""
1945 fi
1946 AC_SUBST(RDYNAMIC)
1947
1948 dnl===-----------------------------------------------------------------------===
1949 dnl===
1950 dnl=== SECTION 10: Specify the output files and generate it
1951 dnl===
1952 dnl===-----------------------------------------------------------------------===
1953
1954 dnl Configure header files
1955 dnl WARNING: dnl If you add or remove any of the following config headers, then
1956 dnl you MUST also update Makefile so that the variable FilesToConfig
1957 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1958 dnl files can be updated automatically when their *.in sources change.
1959 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1960 AH_TOP([#ifndef CONFIG_H
1961 #define CONFIG_H])
1962 AH_BOTTOM([#endif])
1963
1964 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1965 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1966 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1967 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1968 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1969
1970 dnl Configure the makefile's configuration data
1971 AC_CONFIG_FILES([Makefile.config])
1972
1973 dnl Configure the RPM spec file for LLVM
1974 AC_CONFIG_FILES([llvm.spec])
1975
1976 dnl Configure doxygen's configuration file
1977 AC_CONFIG_FILES([docs/doxygen.cfg])
1978
1979 dnl Configure clang, if present
1980 if test "${clang_src_root}" = ""; then
1981   clang_src_root="$srcdir/tools/clang"
1982 fi
1983 if test -f ${clang_src_root}/README.txt; then
1984   dnl Use variables to stay under 80 columns.
1985   configh="include/clang/Config/config.h"
1986   doxy="docs/doxygen.cfg"
1987   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1988   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1989 fi
1990
1991 dnl OCaml findlib META file
1992 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1993
1994 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
1995 test "x$program_prefix" = "xNONE" && program_prefix=""
1996 AC_SUBST([program_prefix])
1997
1998
1999 dnl Do special configuration of Makefiles
2000 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2001 AC_CONFIG_MAKEFILE(Makefile)
2002 AC_CONFIG_MAKEFILE(Makefile.common)
2003 AC_CONFIG_MAKEFILE(examples/Makefile)
2004 AC_CONFIG_MAKEFILE(lib/Makefile)
2005 AC_CONFIG_MAKEFILE(test/Makefile)
2006 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2007 AC_CONFIG_MAKEFILE(unittests/Makefile)
2008 AC_CONFIG_MAKEFILE(tools/Makefile)
2009 AC_CONFIG_MAKEFILE(utils/Makefile)
2010 AC_CONFIG_MAKEFILE(projects/Makefile)
2011 AC_CONFIG_MAKEFILE(bindings/Makefile)
2012 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2013
2014 dnl Finally, crank out the output
2015 AC_OUTPUT