autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.5.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=5
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45
  46 AC_SUBST([LLVM_VERSION_MAJOR])
  47 AC_SUBST([LLVM_VERSION_MINOR])
  48 AC_SUBST([LLVM_VERSION_PATCH])
  49 AC_SUBST([LLVM_VERSION_SUFFIX])
  50
  51 dnl Provide a copyright substitution and ensure the copyright notice is included
  52 dnl in the output of --version option of the generated configure script.
  53 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  54 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  55
  56 dnl Indicate that we require autoconf 2.60 or later.
  57 AC_PREREQ(2.60)
  58
  59 dnl Verify that the source directory is valid. This makes sure that we are
  60 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  61 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  62
  63 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  64 dnl various tools where the m4 autoconf macros are.
  65 AC_CONFIG_AUX_DIR([autoconf])
  66
  67 dnl Quit if the source directory has already been configured.
  68 dnl NOTE: This relies upon undocumented autoconf behavior.
  69 if test ${srcdir} != "." ; then
  70   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  71     AC_MSG_ERROR([Already configured in ${srcdir}])
  72   fi
  73 fi
  74
  75 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  76 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  77 : ${CFLAGS=}
  78 : ${CXXFLAGS=}
  79
  80 dnl We need to check for the compiler up here to avoid anything else
  81 dnl starting with a different one.
  82 AC_PROG_CC(clang gcc)
  83 AC_PROG_CXX(clang++ g++)
  84 AC_PROG_CPP
  85
  86 dnl If CXX is Clang, check that it can find and parse C++ standard library
  87 dnl headers.
  88 if test "$CXX" = "clang++" ; then
  89   AC_MSG_CHECKING([whether clang works])
  90   AC_LANG_PUSH([C++])
  91   dnl Note that space between 'include' and '(' is required.  There's a broken
  92   dnl regex in aclocal that otherwise will think that we call m4's include
  93   dnl builtin.
  94   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  95 #if __has_include (<cxxabi.h>)
  96 #include <cxxabi.h>
  97 #endif
  98 #if __has_include (<unwind.h>)
  99 #include <unwind.h>
 100 #endif
 101 ]])],
 102 [
 103   AC_MSG_RESULT([yes])
 104 ],
 105 [
 106   AC_MSG_RESULT([no])
 107   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
 108 ])
 109   AC_LANG_POP([C++])
 110 fi
 111
 112 dnl Set up variables that track whether the host compiler is GCC or Clang where
 113 dnl we can effectively sanity check them. We don't try to sanity check all the
 114 dnl other possible compilers.
 115 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 116 AC_LANG_PUSH([C++])
 117 llvm_cv_cxx_compiler=unknown
 118 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 119                                     #error
 120                                     #endif
 121                                     ]])],
 122                   llvm_cv_cxx_compiler=clang,
 123                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 124                                                        #error
 125                                                        #endif
 126                                                        ]])],
 127                                      llvm_cv_cxx_compiler=gcc, [])])
 128 AC_LANG_POP([C++])
 129 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 130
 131 dnl Configure all of the projects present in our source tree. While we could
 132 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 133 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 134 dnl Instead we match on the known projects.
 135
 136 dnl
 137 dnl One tricky part of doing this is that some projects depend upon other
 138 dnl projects.  For example, several projects rely upon the LLVM test suite.
 139 dnl We want to configure those projects first so that their object trees are
 140 dnl created before running the configure scripts of projects that depend upon
 141 dnl them.
 142 dnl
 143
 144 dnl Several projects use the LLVM test suite, so configure it next.
 145 if test -d ${srcdir}/projects/test-suite ; then
 146   AC_CONFIG_SUBDIRS([projects/test-suite])
 147 fi
 148
 149 dnl llvm-test is the old name of the test-suite, kept here for backwards
 150 dnl compatibility
 151 if test -d ${srcdir}/projects/llvm-test ; then
 152   AC_CONFIG_SUBDIRS([projects/llvm-test])
 153 fi
 154
 155 dnl Some projects use poolalloc; configure that next
 156 if test -d ${srcdir}/projects/poolalloc ; then
 157   AC_CONFIG_SUBDIRS([projects/poolalloc])
 158 fi
 159
 160 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 161   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 162 fi
 163
 164 dnl Check for all other projects
 165 for i in `ls ${srcdir}/projects`
 166 do
 167   if test -d ${srcdir}/projects/${i} ; then
 168     case ${i} in
 169       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 170       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 171       compiler-rt)       ;;
 172       test-suite)     ;;
 173       llvm-test)      ;;
 174       poolalloc)      ;;
 175       llvm-poolalloc) ;;
 176       *)
 177         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 178         ;;
 179     esac
 180   fi
 181 done
 182
 183 dnl Disable the build of polly, even if it is checked out into tools/polly.
 184 AC_ARG_ENABLE(polly,
 185               AS_HELP_STRING([--enable-polly],
 186                              [Use polly if available (default is YES)]),,
 187                              enableval=default)
 188 case "$enableval" in
 189   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 190   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 191   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 192   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 193 esac
 194
 195
 196 dnl Check if polly is checked out into tools/polly and configure it if
 197 dnl available.
 198 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 199   AC_SUBST(LLVM_HAS_POLLY,1)
 200   AC_CONFIG_SUBDIRS([tools/polly])
 201 fi
 202
 203 dnl===-----------------------------------------------------------------------===
 204 dnl===
 205 dnl=== SECTION 2: Architecture, target, and host checks
 206 dnl===
 207 dnl===-----------------------------------------------------------------------===
 208
 209 dnl Check the target for which we're compiling and the host that will do the
 210 dnl compilations. This will tell us which LLVM compiler will be used for
 211 dnl compiling SSA into object code. This needs to be done early because
 212 dnl following tests depend on it.
 213 AC_CANONICAL_TARGET
 214
 215 dnl Determine the platform type and cache its value. This helps us configure
 216 dnl the System library to the correct build platform.
 217 AC_CACHE_CHECK([type of operating system we're going to host on],
 218                [llvm_cv_os_type],
 219 [case $host in
 220   *-*-aix*)
 221     llvm_cv_link_all_option="-Wl,--whole-archive"
 222     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 223     llvm_cv_os_type="AIX"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-irix*)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="IRIX"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-cygwin*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="Cygwin"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-darwin*)
 236     llvm_cv_link_all_option="-Wl,-all_load"
 237     llvm_cv_no_link_all_option="-Wl,-noall_load"
 238     llvm_cv_os_type="Darwin"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-minix*)
 241     llvm_cv_link_all_option="-Wl,-all_load"
 242     llvm_cv_no_link_all_option="-Wl,-noall_load"
 243     llvm_cv_os_type="Minix"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-freebsd*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="FreeBSD"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-kfreebsd-gnu)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="GNU/kFreeBSD"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-openbsd*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="OpenBSD"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-netbsd*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="NetBSD"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-dragonfly*)
 266     llvm_cv_link_all_option="-Wl,--whole-archive"
 267     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 268     llvm_cv_os_type="DragonFly"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-hpux*)
 271     llvm_cv_link_all_option="-Wl,--whole-archive"
 272     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 273     llvm_cv_os_type="HP-UX"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-interix*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="Interix"
 279     llvm_cv_platform_type="Unix" ;;
 280   *-*-linux*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="Linux"
 284     llvm_cv_platform_type="Unix" ;;
 285   *-*-gnu*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="GNU"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-*-solaris*)
 291     llvm_cv_link_all_option="-Wl,-z,allextract"
 292     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 293     llvm_cv_os_type="SunOS"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-*-auroraux*)
 296     llvm_cv_link_all_option="-Wl,-z,allextract"
 297     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 298     llvm_cv_os_type="AuroraUX"
 299     llvm_cv_platform_type="Unix" ;;
 300   *-*-win32*)
 301     llvm_cv_link_all_option="-Wl,--whole-archive"
 302     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 303     llvm_cv_os_type="Win32"
 304     llvm_cv_platform_type="Win32" ;;
 305   *-*-mingw*)
 306     llvm_cv_link_all_option="-Wl,--whole-archive"
 307     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 308     llvm_cv_os_type="MingW"
 309     llvm_cv_platform_type="Win32" ;;
 310   *-*-haiku*)
 311     llvm_cv_link_all_option="-Wl,--whole-archive"
 312     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 313     llvm_cv_os_type="Haiku"
 314     llvm_cv_platform_type="Unix" ;;
 315   *-unknown-eabi*)
 316     llvm_cv_link_all_option="-Wl,--whole-archive"
 317     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 318     llvm_cv_os_type="Freestanding"
 319     llvm_cv_platform_type="Unix" ;;
 320   *-unknown-elf*)
 321     llvm_cv_link_all_option="-Wl,--whole-archive"
 322     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 323     llvm_cv_os_type="Freestanding"
 324     llvm_cv_platform_type="Unix" ;;
 325   *)
 326     llvm_cv_link_all_option=""
 327     llvm_cv_no_link_all_option=""
 328     llvm_cv_os_type="Unknown"
 329     llvm_cv_platform_type="Unknown" ;;
 330 esac])
 331
 332 AC_CACHE_CHECK([type of operating system we're going to target],
 333                [llvm_cv_target_os_type],
 334 [case $target in
 335   *-*-aix*)
 336     llvm_cv_target_os_type="AIX" ;;
 337   *-*-irix*)
 338     llvm_cv_target_os_type="IRIX" ;;
 339   *-*-cygwin*)
 340     llvm_cv_target_os_type="Cygwin" ;;
 341   *-*-darwin*)
 342     llvm_cv_target_os_type="Darwin" ;;
 343   *-*-minix*)
 344     llvm_cv_target_os_type="Minix" ;;
 345   *-*-freebsd*)
 346     llvm_cv_target_os_type="FreeBSD" ;;
 347   *-*-kfreebsd-gnu)
 348     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 349   *-*-openbsd*)
 350     llvm_cv_target_os_type="OpenBSD" ;;
 351   *-*-netbsd*)
 352     llvm_cv_target_os_type="NetBSD" ;;
 353   *-*-dragonfly*)
 354     llvm_cv_target_os_type="DragonFly" ;;
 355   *-*-hpux*)
 356     llvm_cv_target_os_type="HP-UX" ;;
 357   *-*-interix*)
 358     llvm_cv_target_os_type="Interix" ;;
 359   *-*-linux*)
 360     llvm_cv_target_os_type="Linux" ;;
 361   *-*-gnu*)
 362     llvm_cv_target_os_type="GNU" ;;
 363   *-*-solaris*)
 364     llvm_cv_target_os_type="SunOS" ;;
 365   *-*-auroraux*)
 366     llvm_cv_target_os_type="AuroraUX" ;;
 367   *-*-win32*)
 368     llvm_cv_target_os_type="Win32" ;;
 369   *-*-mingw*)
 370     llvm_cv_target_os_type="MingW" ;;
 371   *-*-haiku*)
 372     llvm_cv_target_os_type="Haiku" ;;
 373   *-*-rtems*)
 374     llvm_cv_target_os_type="RTEMS" ;;
 375   *-*-nacl*)
 376     llvm_cv_target_os_type="NativeClient" ;;
 377   *-unknown-eabi*)
 378     llvm_cv_target_os_type="Freestanding" ;;
 379   *)
 380     llvm_cv_target_os_type="Unknown" ;;
 381 esac])
 382
 383 dnl Make sure we aren't attempting to configure for an unknown system
 384 if test "$llvm_cv_os_type" = "Unknown" ; then
 385   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 386 fi
 387
 388 dnl Set the "OS" Makefile variable based on the platform type so the
 389 dnl makefile can configure itself to specific build hosts
 390 AC_SUBST(OS,$llvm_cv_os_type)
 391 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 392 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 393
 394 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 395 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 396 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 397
 398 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 399 dnl This is used by lib/Support to determine the basic kind of implementation
 400 dnl to use.
 401 case $llvm_cv_platform_type in
 402   Unix)
 403     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 404     AC_SUBST(LLVM_ON_UNIX,[1])
 405     AC_SUBST(LLVM_ON_WIN32,[0])
 406     ;;
 407   Win32)
 408     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 409     AC_SUBST(LLVM_ON_UNIX,[0])
 410     AC_SUBST(LLVM_ON_WIN32,[1])
 411     ;;
 412 esac
 413
 414 dnl Determine what our target architecture is and configure accordingly.
 415 dnl This will allow Makefiles to make a distinction between the hardware and
 416 dnl the OS.
 417 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 418 [case $target in
 419   i?86-*)                 llvm_cv_target_arch="x86" ;;
 420   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 421   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 422   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 423   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 424   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 425   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 426   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 427   xcore-*)                llvm_cv_target_arch="XCore" ;;
 428   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 429   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 430   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 431   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 432   *)                      llvm_cv_target_arch="Unknown" ;;
 433 esac])
 434
 435 if test "$llvm_cv_target_arch" = "Unknown" ; then
 436   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 437 fi
 438
 439 dnl Determine the LLVM native architecture for the target
 440 case "$llvm_cv_target_arch" in
 441     x86)     LLVM_NATIVE_ARCH="X86" ;;
 442     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 443     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 444 esac
 445
 446 dnl Define a substitution, ARCH, for the target architecture
 447 AC_SUBST(ARCH,$llvm_cv_target_arch)
 448 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 449
 450 dnl Determine what our host architecture.
 451 dnl This will allow MCJIT regress tests runs only for supported
 452 dnl platforms.
 453 case $host in
 454   i?86-*)                 host_arch="x86" ;;
 455   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 456   sparc*-*)               host_arch="Sparc" ;;
 457   powerpc*-*)             host_arch="PowerPC" ;;
 458   arm*-*)                 host_arch="ARM" ;;
 459   aarch64*-*)             host_arch="AArch64" ;;
 460   mips-* | mips64-*)      host_arch="Mips" ;;
 461   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 462   xcore-*)                host_arch="XCore" ;;
 463   msp430-*)               host_arch="MSP430" ;;
 464   hexagon-*)              host_arch="Hexagon" ;;
 465   s390x-*)                host_arch="SystemZ" ;;
 466   *)                      host_arch="Unknown" ;;
 467 esac
 468
 469 if test "$host_arch" = "Unknown" ; then
 470   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 471 fi
 472
 473 AC_SUBST(HOST_ARCH,$host_arch)
 474
 475 dnl Check for build platform executable suffix if we're cross-compiling
 476 if test "$cross_compiling" = yes; then
 477   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 478   AC_BUILD_EXEEXT
 479   ac_build_prefix=${build_alias}-
 480   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 481   if test -z "$BUILD_CXX"; then
 482      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 483      if test -z "$BUILD_CXX"; then
 484        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 485      fi
 486   fi
 487 else
 488   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 489 fi
 490
 491 dnl Check to see if there's a .svn or .git directory indicating that this
 492 dnl build is being done from a checkout. This sets up several defaults for
 493 dnl the command line switches. When we build with a checkout directory,
 494 dnl we get a debug with assertions turned on. Without, we assume a source
 495 dnl release and we get an optimized build without assertions.
 496 dnl See --enable-optimized and --enable-assertions below
 497 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 498   cvsbuild="yes"
 499   optimize="no"
 500   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 501 else
 502   cvsbuild="no"
 503   optimize="yes"
 504 fi
 505
 506 dnl===-----------------------------------------------------------------------===
 507 dnl===
 508 dnl=== SECTION 3: Command line arguments for the configure script.
 509 dnl===
 510 dnl===-----------------------------------------------------------------------===
 511
 512 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 513 AC_ARG_ENABLE(libcpp,
 514               AS_HELP_STRING([--enable-libcpp],
 515                              [Use libc++ if available (default is NO)]),,
 516                              enableval=default)
 517 case "$enableval" in
 518   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 519   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 520   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 521   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 522 esac
 523
 524 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 525 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 526 dnl these checks here so that we have the configuration of the standard C++
 527 dnl library finished.
 528 AC_ARG_ENABLE(compiler-version-checks,
 529               AS_HELP_STRING([--enable-compiler-version-checks],
 530                              [Check the version of the host compiler (default is YES)]),,
 531                              enableval=default)
 532 case "$enableval" in
 533   no)
 534     ;;
 535   yes|default)
 536     AC_LANG_PUSH([C++])
 537     case "$llvm_cv_cxx_compiler" in
 538     clang)
 539       AC_MSG_CHECKING([whether Clang is new enough])
 540       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 541 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 542 #error This version of Clang is too old to build LLVM
 543 #endif
 544 ]])],
 545           [AC_MSG_RESULT([yes])],
 546           [AC_MSG_RESULT([no])
 547            AC_MSG_ERROR([
 548 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 549 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 550 bypass these sanity checks.])])
 551
 552       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 553       dnl are sometimes deeply confusing though. Here we test for an obvious
 554       dnl incomplete feature in 4.6's standard library that was completed in
 555       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 556       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 557       dnl that happening in the Makefile.
 558       if test "$ENABLE_LIBCPP" -eq 0 ; then
 559         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 560         llvm_cv_old_cxxflags="$CXXFLAGS"
 561         CXXFLAGS="$CXXFLAGS -std=c++0x"
 562         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 563 #include <atomic>
 564 std::atomic<float> x(0.0f);
 565 int main() { return (float)x; }
 566 ]])],
 567             [AC_MSG_RESULT([yes])],
 568             [AC_MSG_RESULT([no])
 569              AC_MSG_ERROR([
 570 We detected a missing feature in the standard C++ library that was known to be
 571 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 572 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 573 than 4.7. You will need to update your system and ensure Clang uses the newer
 574 standard library.
 575
 576 If this error is incorrect or you need to force things to work, you may pass
 577 '--disable-compiler-version-checks' to configure to bypass this test.])])
 578         CXXFLAGS="$llvm_cv_old_cxxflags"
 579       fi
 580       ;;
 581     gcc)
 582       AC_MSG_CHECKING([whether GCC is new enough])
 583       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 584 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 585 #error This version of GCC is too old to build LLVM
 586 #endif
 587 ]])],
 588           [AC_MSG_RESULT([yes])],
 589           [AC_MSG_RESULT([no])
 590            AC_MSG_ERROR([
 591 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 592 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 593 bypass these sanity checks.])])
 594       ;;
 595     unknown)
 596       ;;
 597     esac
 598     AC_LANG_POP([C++])
 599     ;;
 600   *)
 601     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 602     ;;
 603 esac
 604
 605 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 606 AC_ARG_ENABLE(cxx1y,
 607               AS_HELP_STRING([--enable-cxx1y],
 608                              [Use c++1y if available (default is NO)]),,
 609                              enableval=default)
 610 case "$enableval" in
 611   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 612   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 613   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 614   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 615 esac
 616
 617 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 618 dnl line
 619 AC_ARG_ENABLE(split-dwarf,
 620               AS_HELP_STRING([--enable-split-dwarf],
 621                              [Use split-dwarf if available (default is NO)]),,
 622                              enableval=default)
 623 case "$enableval" in
 624   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 625   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 626   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 627   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 628 esac
 629
 630 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 631 clang_arcmt="yes"
 632 AC_ARG_ENABLE(clang-arcmt,
 633               AS_HELP_STRING([--enable-clang-arcmt],
 634                              [Enable building of clang ARCMT (default is YES)]),
 635                              clang_arcmt="$enableval",
 636                              enableval="yes")
 637 case "$enableval" in
 638   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 639   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 640   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 641   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 642 esac
 643
 644 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 645 clang_plugin_support="yes"
 646 AC_ARG_ENABLE(clang-plugin-support,
 647               AS_HELP_STRING([--enable-clang-plugin-support],
 648                              [Enable plugin support in clang (default is YES)]),
 649                              clang_plugin_support="$enableval",
 650                              enableval="yes")
 651 case "$enableval" in
 652   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 653   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 654   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 655   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 656 esac
 657
 658 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 659 clang_static_analyzer="yes"
 660 AC_ARG_ENABLE(clang-static-analyzer,
 661               AS_HELP_STRING([--enable-clang-static-analyzer],
 662                              [Enable building of clang Static Analyzer (default is YES)]),
 663                              clang_static_analyzer="$enableval",
 664                              enableval="yes")
 665 case "$enableval" in
 666   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 667   no)
 668     if test ${clang_arcmt} != "no" ; then
 669       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 670     fi
 671     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 672     ;;
 673   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 674   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 675 esac
 676
 677 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 678 AC_ARG_ENABLE(clang-rewriter,
 679               AS_HELP_STRING([--enable-clang-rewriter],
 680                              [Enable building of clang rewriter (default is YES)]),,
 681                              enableval="yes")
 682 case "$enableval" in
 683   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 684   no)
 685     if test ${clang_arcmt} != "no" ; then
 686       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 687     fi
 688     if test ${clang_static_analyzer} != "no" ; then
 689       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 690     fi
 691     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 692     ;;
 693   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 694   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 695 esac
 696
 697 dnl --enable-optimized : check whether they want to do an optimized build:
 698 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 699  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 700 if test ${enableval} = "no" ; then
 701   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 702 else
 703   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 704 fi
 705
 706 dnl --enable-profiling : check whether they want to do a profile build:
 707 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 708  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 709 if test ${enableval} = "no" ; then
 710   AC_SUBST(ENABLE_PROFILING,[[]])
 711 else
 712   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 713 fi
 714
 715 dnl --enable-assertions : check whether they want to turn on assertions or not:
 716 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 717   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 718 if test ${enableval} = "yes" ; then
 719   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 720 else
 721   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 722 fi
 723
 724 dnl --enable-werror : check whether we want Werror on by default
 725 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 726   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 727 case "$enableval" in
 728   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 729   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 730   default) AC_SUBST(ENABLE_WERROR,[0]);;
 731   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 732 esac
 733
 734 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 735 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 736   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 737 if test ${enableval} = "yes" ; then
 738   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 739   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 740 else
 741   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 742   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 743 fi
 744
 745 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 746 AC_ARG_ENABLE(debug-runtime,
 747    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 748 if test ${enableval} = "no" ; then
 749   AC_SUBST(DEBUG_RUNTIME,[[]])
 750 else
 751   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 752 fi
 753
 754 dnl --enable-debug-symbols : should even optimized compiler libraries
 755 dnl have debug symbols?
 756 AC_ARG_ENABLE(debug-symbols,
 757    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 758 if test ${enableval} = "no" ; then
 759   AC_SUBST(DEBUG_SYMBOLS,[[]])
 760 else
 761   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 762 fi
 763
 764 dnl --enable-keep-symbols : do not strip installed executables
 765 AC_ARG_ENABLE(keep-symbols,
 766    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 767 if test ${enableval} = "no" ; then
 768   AC_SUBST(KEEP_SYMBOLS,[[]])
 769 else
 770   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 771 fi
 772
 773 dnl --enable-jit: check whether they want to enable the jit
 774 AC_ARG_ENABLE(jit,
 775   AS_HELP_STRING(--enable-jit,
 776                  [Enable Just In Time Compiling (default is YES)]),,
 777   enableval=default)
 778 if test ${enableval} = "no"
 779 then
 780   AC_SUBST(JIT,[[]])
 781 else
 782   case "$llvm_cv_target_arch" in
 783     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 784     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 785     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 786     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 787     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 788     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 789     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 790     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 791     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 792     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 793     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 794     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 795     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 796   esac
 797 fi
 798
 799 TARGETS_WITH_JIT="AArch64 ARM Mips PowerPC SystemZ X86"
 800 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 801
 802 dnl Allow enablement of building and installing docs
 803 AC_ARG_ENABLE(docs,
 804               AS_HELP_STRING([--enable-docs],
 805                              [Build documents (default is YES)]),,
 806                              enableval=default)
 807 case "$enableval" in
 808   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 809   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 810   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 811   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 812 esac
 813
 814 dnl Allow enablement of doxygen generated documentation
 815 AC_ARG_ENABLE(doxygen,
 816               AS_HELP_STRING([--enable-doxygen],
 817                              [Build doxygen documentation (default is NO)]),,
 818                              enableval=default)
 819 case "$enableval" in
 820   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 821   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 822   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 823   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 824 esac
 825
 826 dnl Allow disablement of threads
 827 AC_ARG_ENABLE(threads,
 828               AS_HELP_STRING([--enable-threads],
 829                              [Use threads if available (default is YES)]),,
 830                              enableval=default)
 831 case "$enableval" in
 832   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 833   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 834   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 835   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 836 esac
 837 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 838                    [Define if threads enabled])
 839
 840 dnl Allow disablement of pthread.h
 841 AC_ARG_ENABLE(pthreads,
 842               AS_HELP_STRING([--enable-pthreads],
 843                              [Use pthreads if available (default is YES)]),,
 844                              enableval=default)
 845 case "$enableval" in
 846   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 847   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 848   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 849   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 850 esac
 851
 852 dnl Allow disablement of zlib
 853 AC_ARG_ENABLE(zlib,
 854               AS_HELP_STRING([--enable-zlib],
 855                              [Use zlib for compression/decompression if
 856                               available (default is YES)]),,
 857                               enableval=default)
 858 case "$enableval" in
 859   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 860   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 861   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 862   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 863 esac
 864 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 865                    [Define if zlib is enabled])
 866
 867 dnl Allow building without position independent code
 868 AC_ARG_ENABLE(pic,
 869   AS_HELP_STRING([--enable-pic],
 870                  [Build LLVM with Position Independent Code (default is YES)]),,
 871                  enableval=default)
 872 case "$enableval" in
 873   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 874   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 875   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 876   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 877 esac
 878 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 879                    [Define if position independent code is enabled])
 880
 881 dnl Allow building a shared library and linking tools against it.
 882 AC_ARG_ENABLE(shared,
 883   AS_HELP_STRING([--enable-shared],
 884                  [Build a shared library and link tools against it (default is NO)]),,
 885                  enableval=default)
 886 case "$enableval" in
 887   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 888   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 889   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 890   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 891 esac
 892
 893 dnl Allow libstdc++ is embedded in LLVM.dll.
 894 AC_ARG_ENABLE(embed-stdcxx,
 895   AS_HELP_STRING([--enable-embed-stdcxx],
 896                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 897                  enableval=default)
 898 case "$enableval" in
 899   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 900   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 901   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 902   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 903 esac
 904
 905 dnl Enable embedding timestamp information into build.
 906 AC_ARG_ENABLE(timestamps,
 907   AS_HELP_STRING([--enable-timestamps],
 908                  [Enable embedding timestamp information in build (default is YES)]),,
 909                  enableval=default)
 910 case "$enableval" in
 911   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 912   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 913   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 914   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 915 esac
 916 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 917                    [Define if timestamp information (e.g., __DATE__) is allowed])
 918
 919 dnl Enable support for showing backtraces.
 920 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 921   [--enable-backtraces],
 922   [Enable embedding backtraces on crash (default is YES)]),
 923   [case "$enableval" in
 924     yes) llvm_cv_enable_backtraces="yes" ;;
 925     no)  llvm_cv_enable_backtraces="no"  ;;
 926     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 927   esac],
 928   llvm_cv_enable_backtraces="yes")
 929 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 930   AC_DEFINE([ENABLE_BACKTRACES],[1],
 931             [Define if you want backtraces on crash])
 932 fi
 933
 934 dnl Enable installing platform specific signal handling overrides, for improved
 935 dnl CrashRecovery support or interaction with crash reporting software. This
 936 dnl support may be inappropriate for some clients embedding LLVM as a library.
 937 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 938   [--enable-crash-overrides],
 939   [Enable crash handling overrides (default is YES)]),
 940   [case "$enableval" in
 941     yes) llvm_cv_enable_crash_overrides="yes" ;;
 942     no)  llvm_cv_enable_crash_overrides="no"  ;;
 943     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 944   esac],
 945   llvm_cv_enable_crash_overrides="yes")
 946 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 947   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 948             [Define to enable crash handling overrides])
 949 fi
 950
 951 dnl List all possible targets
 952 ALL_TARGETS="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600"
 953 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
 954
 955 dnl Allow specific targets to be specified for building (or not)
 956 TARGETS_TO_BUILD=""
 957 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 958     [Build specific host targets: all or target1,target2,... Valid targets are:
 959      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 960      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 961     enableval=all)
 962 if test "$enableval" = host-only ; then
 963   enableval=host
 964 fi
 965 case "$enableval" in
 966   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
 967   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 968       case "$a_target" in
 969         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 970         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 971         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 972         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 973         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 974         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 975         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 976         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 977         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 978         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 979         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 980         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 981         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 982         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 983         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 984         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 985         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 986         host) case "$llvm_cv_target_arch" in
 987             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 988             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 989             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 990             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 991             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 992             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 993             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 994             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 995             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 996             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 997             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 998             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 999             *)       AC_MSG_ERROR([Can not set target to build]) ;;
1000           esac ;;
1001         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
1002       esac
1003   done
1004   ;;
1005 esac
1006
1007 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
1008     [Build experimental host targets: disable or target1,target2,...
1009      (default=disable)]),,
1010     enableval=disable)
1011
1012 if test ${enableval} != "disable"
1013 then
1014   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
1015 fi
1016
1017 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
1018
1019 dnl Determine whether we are building LLVM support for the native architecture.
1020 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
1021 for a_target in $TARGETS_TO_BUILD; do
1022   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1023     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1024       [LLVM architecture name for the native architecture, if available])
1025     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1026     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1027     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1028     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1029     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1030       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1031     fi
1032     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1033       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1034     fi
1035     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1036       [LLVM name for the native Target init function, if available])
1037     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1038       [LLVM name for the native TargetInfo init function, if available])
1039     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1040       [LLVM name for the native target MC init function, if available])
1041     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1042       [LLVM name for the native AsmPrinter init function, if available])
1043     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1044       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1045        [LLVM name for the native AsmParser init function, if available])
1046     fi
1047     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1048       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1049        [LLVM name for the native Disassembler init function, if available])
1050     fi
1051   fi
1052 done
1053
1054 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1055 dnl target feature def files.
1056 LLVM_ENUM_TARGETS=""
1057 LLVM_ENUM_ASM_PRINTERS=""
1058 LLVM_ENUM_ASM_PARSERS=""
1059 LLVM_ENUM_DISASSEMBLERS=""
1060 for target_to_build in $TARGETS_TO_BUILD; do
1061   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1062   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1063     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1064   fi
1065   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1066     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1067   fi
1068   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1069     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1070   fi
1071 done
1072 AC_SUBST(LLVM_ENUM_TARGETS)
1073 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1074 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1075 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1076
1077 dnl Override the option to use for optimized builds.
1078 AC_ARG_WITH(optimize-option,
1079   AS_HELP_STRING([--with-optimize-option],
1080                  [Select the compiler options to use for optimized builds]),,
1081                  withval=default)
1082 AC_MSG_CHECKING([optimization flags])
1083 case "$withval" in
1084   default)
1085     case "$llvm_cv_os_type" in
1086     FreeBSD) optimize_option=-O2 ;;
1087     MingW) optimize_option=-O2 ;;
1088     *)     optimize_option=-O3 ;;
1089     esac ;;
1090   *) optimize_option="$withval" ;;
1091 esac
1092 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1093 AC_MSG_RESULT([$optimize_option])
1094
1095 dnl Specify extra build options
1096 AC_ARG_WITH(extra-options,
1097   AS_HELP_STRING([--with-extra-options],
1098                  [Specify additional options to compile LLVM with]),,
1099                  withval=default)
1100 case "$withval" in
1101   default) EXTRA_OPTIONS= ;;
1102   *) EXTRA_OPTIONS=$withval ;;
1103 esac
1104 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1105
1106 dnl Specify extra linker build options
1107 AC_ARG_WITH(extra-ld-options,
1108   AS_HELP_STRING([--with-extra-ld-options],
1109                  [Specify additional options to link LLVM with]),,
1110                  withval=default)
1111 case "$withval" in
1112   default) EXTRA_LD_OPTIONS= ;;
1113   *) EXTRA_LD_OPTIONS=$withval ;;
1114 esac
1115 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1116
1117 dnl Allow specific bindings to be specified for building (or not)
1118 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1119     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1120     enableval=default)
1121 BINDINGS_TO_BUILD=""
1122 case "$enableval" in
1123   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1124   all ) BINDINGS_TO_BUILD="ocaml" ;;
1125   none | no) BINDINGS_TO_BUILD="" ;;
1126   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1127       case "$a_binding" in
1128         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1129         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1130       esac
1131   done
1132   ;;
1133 esac
1134
1135 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1136 dnl script for bindings/ocaml/configure, except that its auto value depends on
1137 dnl OCAMLC, which is found here to support tests.
1138 AC_ARG_WITH([ocaml-libdir],
1139   [AS_HELP_STRING([--with-ocaml-libdir],
1140     [Specify install location for ocaml bindings (default is stdlib)])],
1141   [],
1142   [withval=auto])
1143 case "$withval" in
1144   auto) with_ocaml_libdir="$withval" ;;
1145   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1146   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1147 esac
1148
1149 AC_ARG_WITH(clang-srcdir,
1150   AS_HELP_STRING([--with-clang-srcdir],
1151     [Directory to the out-of-tree Clang source]),,
1152     withval="-")
1153 case "$withval" in
1154   -) clang_src_root="" ;;
1155   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1156   *) clang_src_root="$ac_pwd/$withval" ;;
1157 esac
1158 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1159
1160 AC_ARG_WITH(clang-resource-dir,
1161   AS_HELP_STRING([--with-clang-resource-dir],
1162     [Relative directory from the Clang binary for resource files]),,
1163     withval="")
1164 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1165                    [Relative directory for resource files])
1166
1167 AC_ARG_WITH(c-include-dirs,
1168   AS_HELP_STRING([--with-c-include-dirs],
1169     [Colon separated list of directories clang will search for headers]),,
1170     withval="")
1171 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1172                    [Directories clang will search for headers])
1173
1174 # Clang normally uses the system c++ headers and libraries. With this option,
1175 # clang will use the ones provided by a gcc installation instead. This option should
1176 # be passed the same value that was used with --prefix when configuring gcc.
1177 AC_ARG_WITH(gcc-toolchain,
1178   AS_HELP_STRING([--with-gcc-toolchain],
1179     [Directory where gcc is installed.]),,
1180     withval="")
1181 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1182                    [Directory where gcc is installed.])
1183
1184 AC_ARG_WITH(default-sysroot,
1185   AS_HELP_STRING([--with-default-sysroot],
1186     [Add --sysroot=<path> to all compiler invocations.]),,
1187     withval="")
1188 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1189                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1190
1191 dnl Allow linking of LLVM with GPLv3 binutils code.
1192 AC_ARG_WITH(binutils-include,
1193   AS_HELP_STRING([--with-binutils-include],
1194     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1195   withval=default)
1196 case "$withval" in
1197   default) WITH_BINUTILS_INCDIR=default ;;
1198   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1199   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1200 esac
1201 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1202   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1203   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1204      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1205      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1206   fi
1207 fi
1208
1209 dnl Specify the URL where bug reports should be submitted.
1210 AC_ARG_WITH(bug-report-url,
1211   AS_HELP_STRING([--with-bug-report-url],
1212     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1213     withval="http://llvm.org/bugs/")
1214 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1215                    [Bug report URL.])
1216
1217 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1218 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1219   [--enable-terminfo],
1220   [Query the terminfo database if available (default is YES)]),
1221   [case "$enableval" in
1222     yes) llvm_cv_enable_terminfo="yes" ;;
1223     no)  llvm_cv_enable_terminfo="no"  ;;
1224     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1225   esac],
1226   llvm_cv_enable_terminfo="yes")
1227 case "$llvm_cv_enable_terminfo" in
1228   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1229   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1230 esac
1231
1232 dnl --enable-libedit: check whether the user wants to turn off libedit.
1233 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1234   [--enable-libedit],
1235   [Use libedit if available (default is YES)]),
1236   [case "$enableval" in
1237     yes) llvm_cv_enable_libedit="yes" ;;
1238     no)  llvm_cv_enable_libedit="no"  ;;
1239     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1240   esac],
1241   llvm_cv_enable_libedit="yes")
1242
1243 dnl --enable-libffi : check whether the user wants to turn off libffi:
1244 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1245   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1246   [case "$enableval" in
1247     yes) llvm_cv_enable_libffi="yes" ;;
1248     no)  llvm_cv_enable_libffi="no"  ;;
1249     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1250   esac],
1251   llvm_cv_enable_libffi=no)
1252
1253 AC_ARG_WITH(internal-prefix,
1254   AS_HELP_STRING([--with-internal-prefix],
1255     [Installation directory for internal files]),,
1256     withval="")
1257 AC_SUBST(INTERNAL_PREFIX,[$withval])
1258
1259 dnl===-----------------------------------------------------------------------===
1260 dnl===
1261 dnl=== SECTION 4: Check for programs we need and that they are the right version
1262 dnl===
1263 dnl===-----------------------------------------------------------------------===
1264
1265 dnl Check for the tools that the makefiles require
1266 AC_CHECK_GNU_MAKE
1267 AC_PROG_LN_S
1268 AC_PATH_PROG(NM, [nm], [nm])
1269 AC_PATH_PROG(CMP, [cmp], [cmp])
1270 AC_PATH_PROG(CP, [cp], [cp])
1271 AC_PATH_PROG(DATE, [date], [date])
1272 AC_PATH_PROG(FIND, [find], [find])
1273 AC_PATH_PROG(GREP, [grep], [grep])
1274 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1275 AC_PATH_PROG(MV,   [mv],   [mv])
1276 AC_PROG_RANLIB
1277 AC_CHECK_TOOL(AR, ar, false)
1278 AC_PATH_PROG(RM,   [rm],   [rm])
1279 AC_PATH_PROG(SED,  [sed],  [sed])
1280 AC_PATH_PROG(TAR,  [tar],  [gtar])
1281 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1282
1283 dnl Looking for misc. graph plotting software
1284 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1285 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1286   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1287   dnl If we're targeting for mingw we should emit windows paths, not msys
1288   if test "$llvm_cv_os_type" = "MingW" ; then
1289     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1290   fi
1291   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1292    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1293 fi
1294 AC_PATH_PROG(DOT, [dot], [echo dot])
1295 if test "$DOT" != "echo dot" ; then
1296   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1297   dnl If we're targeting for mingw we should emit windows paths, not msys
1298   if test "$llvm_cv_os_type" = "MingW" ; then
1299     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1300   fi
1301   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1302    [Define to path to dot program if found or 'echo dot' otherwise])
1303 fi
1304 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1305 if test "$FDP" != "echo fdp" ; then
1306   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1307   dnl If we're targeting for mingw we should emit windows paths, not msys
1308   if test "$llvm_cv_os_type" = "MingW" ; then
1309     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1310   fi
1311   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1312    [Define to path to fdp program if found or 'echo fdp' otherwise])
1313 fi
1314 AC_PATH_PROG(NEATO, [neato], [echo neato])
1315 if test "$NEATO" != "echo neato" ; then
1316   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1317   dnl If we're targeting for mingw we should emit windows paths, not msys
1318   if test "$llvm_cv_os_type" = "MingW" ; then
1319     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1320   fi
1321   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1322    [Define to path to neato program if found or 'echo neato' otherwise])
1323 fi
1324 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1325 if test "$TWOPI" != "echo twopi" ; then
1326   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1327   dnl If we're targeting for mingw we should emit windows paths, not msys
1328   if test "$llvm_cv_os_type" = "MingW" ; then
1329     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1330   fi
1331   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1332    [Define to path to twopi program if found or 'echo twopi' otherwise])
1333 fi
1334 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1335 if test "$CIRCO" != "echo circo" ; then
1336   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1337   dnl If we're targeting for mingw we should emit windows paths, not msys
1338   if test "$llvm_cv_os_type" = "MingW" ; then
1339     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1340   fi
1341   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1342    [Define to path to circo program if found or 'echo circo' otherwise])
1343 fi
1344 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1345 if test "$GV" != "echo gv" ; then
1346   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1347   dnl If we're targeting for mingw we should emit windows paths, not msys
1348   if test "$llvm_cv_os_type" = "MingW" ; then
1349     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1350   fi
1351   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1352    [Define to path to gv program if found or 'echo gv' otherwise])
1353 fi
1354 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1355 if test "$DOTTY" != "echo dotty" ; then
1356   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1357   dnl If we're targeting for mingw we should emit windows paths, not msys
1358   if test "$llvm_cv_os_type" = "MingW" ; then
1359     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1360   fi
1361   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1362    [Define to path to dotty program if found or 'echo dotty' otherwise])
1363 fi
1364 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1365 if test "$XDOT" != "echo xdot" ; then
1366   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1367   dnl If we're targeting for mingw we should emit windows paths, not msys
1368   if test "$llvm_cv_os_type" = "MingW" ; then
1369     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1370   fi
1371   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1372    [Define to path to xdot program if found or 'echo xdot' otherwise])
1373 fi
1374
1375 dnl Find the install program
1376 AC_PROG_INSTALL
1377 dnl Prepend src dir to install path dir if it's a relative path
1378 dnl This is a hack for installs that take place in something other
1379 dnl than the top level.
1380 case "$INSTALL" in
1381  [[\\/$]]* | ?:[[\\/]]* ) ;;
1382  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1383 esac
1384
1385 dnl Checks for documentation and testing tools that we can do without. If these
1386 dnl are not found then they are set to "true" which always succeeds but does
1387 dnl nothing. This just lets the build output show that we could have done
1388 dnl something if the tool was available.
1389 AC_PATH_PROG(BZIP2, [bzip2])
1390 AC_PATH_PROG(CAT, [cat])
1391 AC_PATH_PROG(DOXYGEN, [doxygen])
1392 AC_PATH_PROG(GROFF, [groff])
1393 AC_PATH_PROG(GZIPBIN, [gzip])
1394 AC_PATH_PROG(PDFROFF, [pdfroff])
1395 AC_PATH_PROG(ZIP, [zip])
1396 AC_PATH_PROGS(OCAMLC, [ocamlc])
1397 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1398 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1399 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1400 AC_PATH_PROGS(GAS, [gas as])
1401
1402 dnl Get the version of the linker in use.
1403 AC_LINK_GET_VERSION
1404
1405 dnl Determine whether the linker supports the -R option.
1406 AC_LINK_USE_R
1407
1408 dnl Determine whether the compiler supports the -rdynamic option.
1409 AC_LINK_EXPORT_DYNAMIC
1410
1411 dnl Determine whether the linker supports the --version-script option.
1412 AC_LINK_VERSION_SCRIPT
1413
1414 AC_CHECK_HEADERS([errno.h])
1415
1416 case "$llvm_cv_os_type" in
1417   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1418   Darwin) llvm_shlib_ext=.dylib ;;
1419   *) llvm_shlib_ext=.so ;;
1420 esac
1421
1422 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1423
1424 AC_MSG_CHECKING([tool compatibility])
1425
1426 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1427 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1428 dnl to support those options.
1429 dnl "icc" emits gcc signatures
1430 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1431 ICC=no
1432 IXX=no
1433 case $CC in
1434   icc*|icpc*)
1435     ICC=yes
1436     IXX=yes
1437     ;;
1438    *)
1439     ;;
1440 esac
1441
1442 if test "$GCC" != "yes" && test "$ICC" != "yes"
1443 then
1444   AC_MSG_ERROR([gcc|icc required but not found])
1445 fi
1446
1447 dnl Ensure that compilation tools are compatible with GCC extensions
1448 if test "$GXX" != "yes" && test "$IXX" != "yes"
1449 then
1450   AC_MSG_ERROR([g++|clang++|icc required but not found])
1451 fi
1452
1453 dnl Verify that GCC is version 3.0 or higher
1454 if test "$GCC" = "yes"
1455 then
1456   AC_COMPILE_IFELSE(
1457 [
1458   AC_LANG_SOURCE([[
1459     #if !defined(__GNUC__) || __GNUC__ < 3
1460     #error Unsupported GCC version
1461     #endif
1462   ]])
1463 ],
1464 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1465 fi
1466
1467 dnl Check for GNU Make.  We use its extensions, so don't build without it
1468 if test -z "$llvm_cv_gnu_make_command"
1469 then
1470   AC_MSG_ERROR([GNU Make required but not found])
1471 fi
1472
1473 dnl Tool compatibility is okay if we make it here.
1474 AC_MSG_RESULT([ok])
1475
1476 dnl Check optional compiler flags.
1477 AC_MSG_CHECKING([optional compiler flags])
1478 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1479 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1480 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1481
1482 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1483 dnl false positives, so disable it.
1484 NO_UNINITIALIZED=
1485 NO_MAYBE_UNINITIALIZED=
1486 if test "$GXX" = "yes"
1487 then
1488   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1489   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1490   dnl known to be uninitialized from cases which might be uninitialized.  We
1491   dnl still want to catch the first kind of errors.
1492   if test -z "$NO_MAYBE_UNINITIALIZED"
1493   then
1494     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1495   fi
1496 fi
1497 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1498
1499 AC_ARG_WITH([python],
1500             [AS_HELP_STRING([--with-python], [path to python])],
1501             [PYTHON="$withval"])
1502
1503 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1504   AC_MSG_CHECKING([for python])
1505   AC_MSG_RESULT([user defined: $with_python])
1506 else
1507   if test -n "$PYTHON" ; then
1508     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1509   fi
1510
1511   AC_PATH_PROG([PYTHON], [python python2 python26],
1512                [AC_MSG_RESULT([not found])
1513                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1514 fi
1515
1516 AC_MSG_CHECKING([for python >= 2.5])
1517 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1518 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1519 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1520 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1521 if test "$ac_python_version_major" -gt "2" || \
1522    (test "$ac_python_version_major" -eq "2" && \
1523     test "$ac_python_version_minor" -ge "5") ; then
1524   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1525 else
1526   AC_MSG_RESULT([not found])
1527   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1528 fi
1529
1530 dnl===-----------------------------------------------------------------------===
1531 dnl===
1532 dnl=== SECTION 5: Check for libraries
1533 dnl===
1534 dnl===-----------------------------------------------------------------------===
1535
1536 AC_CHECK_LIB(m,sin)
1537 if test "$llvm_cv_os_type" = "MingW" ; then
1538   AC_CHECK_LIB(imagehlp, main)
1539   AC_CHECK_LIB(psapi, main)
1540   AC_CHECK_LIB(shell32, main)
1541 fi
1542
1543 dnl dlopen() is required for plugin support.
1544 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1545                [Define if dlopen() is available on this platform.]),
1546                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1547
1548 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1549 dnl macros to detect whether clock_gettime is available, this just finds the
1550 dnl right libraries to link with.
1551 AC_SEARCH_LIBS(clock_gettime,rt)
1552
1553 dnl The curses library is optional; used for querying terminal info
1554 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1555   dnl We need the has_color functionality in curses for it to be useful.
1556   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1557                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1558                                    [Define if the setupterm() function is supported this platform.]))
1559 fi
1560
1561 dnl The libedit library is optional; used by lib/LineEditor
1562 if test "$llvm_cv_enable_libedit" = "yes" ; then
1563   AC_SEARCH_LIBS(el_init,edit,
1564                  AC_DEFINE([HAVE_LIBEDIT],[1],
1565                            [Define if libedit is available on this platform.]))
1566 fi
1567
1568 dnl libffi is optional; used to call external functions from the interpreter
1569 if test "$llvm_cv_enable_libffi" = "yes" ; then
1570   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1571                  [Define if libffi is available on this platform.]),
1572                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1573 fi
1574
1575 dnl mallinfo is optional; the code can compile (minus features) without it
1576 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1577                [Define if mallinfo() is available on this platform.]))
1578
1579 dnl pthread locking functions are optional - but llvm will not be thread-safe
1580 dnl without locks.
1581 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1582   AC_CHECK_LIB(pthread, pthread_mutex_init)
1583   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1584                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1585                            [Have pthread_mutex_lock]))
1586   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1587                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1588                  [Have pthread_rwlock_init]))
1589   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1590                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1591                  [Have pthread_getspecific]))
1592 fi
1593
1594 dnl zlib is optional; used for compression/uncompression
1595 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1596   AC_CHECK_LIB(z, compress2)
1597 fi
1598
1599 dnl Allow extra x86-disassembler library
1600 AC_ARG_WITH(udis86,
1601   AS_HELP_STRING([--with-udis86=<path>],
1602     [Use udis86 external x86 disassembler library]),
1603     [
1604       AC_SUBST(USE_UDIS86, [1])
1605       case "$withval" in
1606         /usr/lib|yes) ;;
1607         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1608       esac
1609       AC_CHECK_LIB(udis86, ud_init, [], [
1610         echo "Error! You need to have libudis86 around."
1611         exit -1
1612       ])
1613     ],
1614     AC_SUBST(USE_UDIS86, [0]))
1615 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1616                    [Define if use udis86 library])
1617
1618 dnl Allow OProfile support for JIT output.
1619 AC_ARG_WITH(oprofile,
1620   AS_HELP_STRING([--with-oprofile=<prefix>],
1621     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1622     [
1623       AC_SUBST(USE_OPROFILE, [1])
1624       case "$withval" in
1625         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1626         no) llvm_cv_oppath=
1627             AC_SUBST(USE_OPROFILE, [0]) ;;
1628         *) llvm_cv_oppath="${withval}/lib/oprofile"
1629            CPPFLAGS="-I${withval}/include";;
1630       esac
1631       case $llvm_cv_os_type in
1632         Linux)
1633           if test -n "$llvm_cv_oppath" ; then
1634             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1635             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1636             dnl libbfd is not included properly in libopagent in some Debian
1637             dnl versions.  If libbfd isn't found at all, we assume opagent works
1638             dnl anyway.
1639             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1640             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1641               echo "Error! You need to have libopagent around."
1642               exit -1
1643             ])
1644             AC_CHECK_HEADER([opagent.h], [], [
1645               echo "Error! You need to have opagent.h around."
1646               exit -1
1647               ])
1648           fi ;;
1649         *)
1650           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1651       esac
1652     ],
1653     [
1654       AC_SUBST(USE_OPROFILE, [0])
1655     ])
1656 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1657                    [Define if we have the oprofile JIT-support library])
1658
1659 dnl Enable support for Intel JIT Events API.
1660 AC_ARG_WITH(intel-jitevents,
1661   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1662     [
1663        case "$withval" in
1664           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1665           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1666           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1667        esac
1668
1669       case $llvm_cv_os_type in
1670         Linux|Win32|Cygwin|MingW) ;;
1671         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1672       esac
1673
1674       case "$llvm_cv_target_arch" in
1675         x86|x86_64) ;;
1676         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1677       esac
1678     ],
1679     [
1680       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1681     ])
1682 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1683                    [Define if we have the Intel JIT API runtime support library])
1684
1685 dnl Check for libxml2
1686 dnl Right now we're just checking for the existence, we could also check for a
1687 dnl particular version via --version on xml2-config
1688 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1689
1690 AC_MSG_CHECKING(for libxml2 includes)
1691 if test "x$XML2CONFIG" = "x"; then
1692  AC_MSG_RESULT(xml2-config not found)
1693 else
1694  LIBXML2_INC=`$XML2CONFIG --cflags`
1695  AC_MSG_RESULT($LIBXML2_INC)
1696  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1697                                 LIBXML2_LIBS="-lxml2"])
1698 fi
1699 AC_SUBST(LIBXML2_LIBS)
1700 AC_SUBST(LIBXML2_INC)
1701
1702 dnl===-----------------------------------------------------------------------===
1703 dnl===
1704 dnl=== SECTION 6: Check for header files
1705 dnl===
1706 dnl===-----------------------------------------------------------------------===
1707
1708 dnl First, use autoconf provided macros for specific headers that we need
1709 dnl We don't check for ancient stuff or things that are guaranteed to be there
1710 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1711 dnl Generally we're looking for POSIX headers.
1712 AC_HEADER_DIRENT
1713 AC_HEADER_MMAP_ANONYMOUS
1714 AC_HEADER_STAT
1715 AC_HEADER_SYS_WAIT
1716 AC_HEADER_TIME
1717
1718 AC_LANG_PUSH([C++])
1719 AC_CHECK_HEADERS([cxxabi.h])
1720 AC_LANG_POP([C++])
1721 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1722 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1723 AC_CHECK_HEADERS([utime.h])
1724 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1725 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1726 AC_CHECK_HEADERS([valgrind/valgrind.h])
1727 AC_CHECK_HEADERS([fenv.h])
1728 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1729 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1730   AC_CHECK_HEADERS(pthread.h,
1731                    AC_SUBST(HAVE_PTHREAD, 1),
1732                    AC_SUBST(HAVE_PTHREAD, 0))
1733 else
1734   AC_SUBST(HAVE_PTHREAD, 0)
1735 fi
1736 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1737   AC_CHECK_HEADERS(zlib.h,
1738                    AC_SUBST(HAVE_LIBZ, 1),
1739                    AC_SUBST(HAVE_LIBZ, 0))
1740 else
1741   AC_SUBST(HAVE_LIBZ, 0)
1742 fi
1743
1744 dnl Try to find ffi.h.
1745 if test "$llvm_cv_enable_libffi" = "yes" ; then
1746   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1747 fi
1748
1749 dnl Try to find Darwin specific crash reporting libraries.
1750 AC_CHECK_HEADERS([CrashReporterClient.h])
1751
1752 dnl Try to find Darwin specific crash reporting global.
1753 AC_MSG_CHECKING([__crashreporter_info__])
1754 AC_LINK_IFELSE(
1755 [
1756   AC_LANG_SOURCE([[
1757     extern const char *__crashreporter_info__;
1758     int main() {
1759       __crashreporter_info__ = "test";
1760       return 0;
1761     }
1762   ]])
1763 ],
1764 [
1765   AC_MSG_RESULT([yes])
1766   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1767 ],
1768 [
1769   AC_MSG_RESULT([no])
1770   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1771 ])
1772
1773 dnl===-----------------------------------------------------------------------===
1774 dnl===
1775 dnl=== SECTION 7: Check for types and structures
1776 dnl===
1777 dnl===-----------------------------------------------------------------------===
1778
1779 AC_HUGE_VAL_CHECK
1780 AC_TYPE_PID_T
1781 AC_TYPE_SIZE_T
1782 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1783 AC_STRUCT_TM
1784 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1785 AC_CHECK_TYPES([uint64_t],,
1786          AC_CHECK_TYPES([u_int64_t],,
1787          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1788
1789 dnl===-----------------------------------------------------------------------===
1790 dnl===
1791 dnl=== SECTION 8: Check for specific functions needed
1792 dnl===
1793 dnl===-----------------------------------------------------------------------===
1794
1795 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1796 AC_CHECK_FUNCS([powf fmodf strtof round ])
1797 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1798 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1799 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1800 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1801 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1802 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1803 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1804 AC_CHECK_FUNCS([futimes futimens])
1805 AC_C_PRINTF_A
1806 AC_FUNC_RAND48
1807
1808 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1809 AC_CHECK_DECLS([arc4random])
1810
1811 dnl Check the declaration "Secure API" on Windows environments.
1812 AC_CHECK_DECLS([strerror_s])
1813
1814 dnl Check symbols in libgcc.a for JIT on Mingw.
1815 if test "$llvm_cv_os_type" = "MingW" ; then
1816   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1817   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1818   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1819   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1820
1821   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1822   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1823   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1824   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1825   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1826   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1827   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1828   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1829   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1830   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1831
1832   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1833   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1834 fi
1835
1836 dnl Check Win32 API EnumerateLoadedModules.
1837 if test "$llvm_cv_os_type" = "MingW" ; then
1838   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1839   AC_COMPILE_IFELSE(
1840 [
1841   AC_LANG_SOURCE([[
1842     #include <windows.h>
1843     #include <imagehlp.h>
1844     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1845     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1846   ]])
1847 ],
1848 [
1849   AC_MSG_RESULT([yes])
1850   llvm_cv_win32_elmcb_pcstr="PCSTR"
1851 ],
1852 [
1853   AC_MSG_RESULT([no])
1854   llvm_cv_win32_elmcb_pcstr="PSTR"
1855 ])
1856   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1857 fi
1858
1859 dnl Check for variations in the Standard C++ library and STL. These macros are
1860 dnl provided by LLVM in the autoconf/m4 directory.
1861 AC_FUNC_ISNAN
1862 AC_FUNC_ISINF
1863
1864 dnl Check for mmap support.We also need to know if /dev/zero is required to
1865 dnl be opened for allocating RWX memory.
1866 dnl Make sure we aren't attempting to configure for an unknown system
1867 if test "$llvm_cv_platform_type" = "Unix" ; then
1868   AC_FUNC_MMAP
1869   AC_FUNC_MMAP_FILE
1870   AC_NEED_DEV_ZERO_FOR_MMAP
1871
1872   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1873   then
1874     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1875   fi
1876   if test "$ac_cv_func_mmap_file" = "no"
1877   then
1878     AC_MSG_WARN([mmap() of files required but not found])
1879   fi
1880 fi
1881
1882 dnl atomic builtins are required for threading support.
1883 AC_MSG_CHECKING(for GCC atomic builtins)
1884 dnl Since we'll be using these atomic builtins in C++ files we should test
1885 dnl the C++ compiler.
1886 AC_LANG_PUSH([C++])
1887 AC_LINK_IFELSE(
1888 [
1889   AC_LANG_SOURCE([[
1890     int main() {
1891       volatile unsigned long val = 1;
1892       __sync_synchronize();
1893       __sync_val_compare_and_swap(&val, 1, 0);
1894       __sync_add_and_fetch(&val, 1);
1895       __sync_sub_and_fetch(&val, 1);
1896       return 0;
1897     }
1898   ]])
1899 ],
1900 [
1901   AC_MSG_RESULT([yes])
1902   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1903 ],
1904 [
1905   AC_MSG_RESULT([no])
1906   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1907   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1908 ])
1909 AC_LANG_POP([C++])
1910
1911 dnl===-----------------------------------------------------------------------===
1912 dnl===
1913 dnl=== SECTION 9: Additional checks, variables, etc.
1914 dnl===
1915 dnl===-----------------------------------------------------------------------===
1916
1917 dnl Handle 32-bit linux systems running a 64-bit kernel.
1918 dnl This has to come after section 4 because it invokes the compiler.
1919 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1920   AC_IS_LINUX_MIXED
1921   if test "$llvm_cv_linux_mixed" = "yes"; then
1922     llvm_cv_target_arch="x86"
1923     ARCH="x86"
1924   fi
1925 fi
1926
1927 dnl Check whether __dso_handle is present
1928 AC_CHECK_FUNCS([__dso_handle])
1929
1930 dnl Propagate the shared library extension that the libltdl checks did to
1931 dnl the Makefiles so we can use it there too
1932 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
1933
1934 dnl Translate the various configuration directories and other basic
1935 dnl information into substitutions that will end up in Makefile.config.in
1936 dnl that these configured values can be used by the makefiles
1937 if test "${prefix}" = "NONE" ; then
1938   prefix="/usr/local"
1939 fi
1940 eval LLVM_PREFIX="${prefix}";
1941 eval LLVM_BINDIR="${prefix}/bin";
1942 eval LLVM_DATADIR="${prefix}/share/llvm";
1943 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1944 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1945 eval LLVM_INCLUDEDIR="${prefix}/include";
1946 eval LLVM_INFODIR="${prefix}/info";
1947 eval LLVM_MANDIR="${prefix}/man";
1948 LLVM_CONFIGTIME=`date`
1949 AC_SUBST(LLVM_PREFIX)
1950 AC_SUBST(LLVM_BINDIR)
1951 AC_SUBST(LLVM_DATADIR)
1952 AC_SUBST(LLVM_DOCSDIR)
1953 AC_SUBST(LLVM_ETCDIR)
1954 AC_SUBST(LLVM_INCLUDEDIR)
1955 AC_SUBST(LLVM_INFODIR)
1956 AC_SUBST(LLVM_MANDIR)
1957 AC_SUBST(LLVM_CONFIGTIME)
1958
1959 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1960 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1961   LLVM_CONFIGTIME="(timestamp not enabled)"
1962 fi
1963
1964 dnl Place the various directories into the config.h file as #defines so that we
1965 dnl can know about the installation paths within LLVM.
1966 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1967                    [Installation prefix directory])
1968 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1969                    [Installation directory for binary executables])
1970 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1971                    [Installation directory for data files])
1972 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1973                    [Installation directory for documentation])
1974 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1975                    [Installation directory for config files])
1976 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1977                    [Installation directory for include files])
1978 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1979                    [Installation directory for .info files])
1980 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1981                    [Installation directory for man pages])
1982 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1983                    [Time at which LLVM was configured])
1984 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1985                    [Host triple LLVM will be executed on])
1986 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1987                    [Target triple LLVM will generate code for by default])
1988
1989 dnl Determine which bindings to build.
1990 if test "$BINDINGS_TO_BUILD" = auto ; then
1991   BINDINGS_TO_BUILD=""
1992   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1993     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1994   fi
1995 fi
1996 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1997
1998 dnl This isn't really configurey, but it avoids having to repeat the list in
1999 dnl other files.
2000 AC_SUBST(ALL_BINDINGS,ocaml)
2001
2002 dnl Do any work necessary to ensure that bindings have what they need.
2003 binding_prereqs_failed=0
2004 for a_binding in $BINDINGS_TO_BUILD ; do
2005   case "$a_binding" in
2006   ocaml)
2007     if test "x$OCAMLC" = x ; then
2008       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
2009       binding_prereqs_failed=1
2010     fi
2011     if test "x$OCAMLDEP" = x ; then
2012       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
2013       binding_prereqs_failed=1
2014     fi
2015     if test "x$OCAMLOPT" = x ; then
2016       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
2017       dnl ocamlopt is optional!
2018     fi
2019     if test "x$with_ocaml_libdir" != xauto ; then
2020       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
2021     else
2022       ocaml_stdlib="`"$OCAMLC" -where`"
2023       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
2024       then
2025         # ocaml stdlib is beneath our prefix; use stdlib
2026         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
2027       else
2028         # ocaml stdlib is outside our prefix; use libdir/ocaml
2029         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
2030       fi
2031     fi
2032     ;;
2033   esac
2034 done
2035 if test "$binding_prereqs_failed" = 1 ; then
2036   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2037 fi
2038
2039 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2040 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2041
2042 dnl Determine linker rpath flag
2043 if test "$llvm_cv_link_use_r" = "yes" ; then
2044   RPATH="-Wl,-R"
2045 else
2046   RPATH="-Wl,-rpath"
2047 fi
2048 AC_SUBST(RPATH)
2049
2050 dnl Determine linker rdynamic flag
2051 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2052   RDYNAMIC="-rdynamic"
2053 else
2054   RDYNAMIC=""
2055 fi
2056 AC_SUBST(RDYNAMIC)
2057
2058 dnl===-----------------------------------------------------------------------===
2059 dnl===
2060 dnl=== SECTION 10: Specify the output files and generate it
2061 dnl===
2062 dnl===-----------------------------------------------------------------------===
2063
2064 dnl Configure header files
2065 dnl WARNING: dnl If you add or remove any of the following config headers, then
2066 dnl you MUST also update Makefile so that the variable FilesToConfig
2067 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2068 dnl files can be updated automatically when their *.in sources change.
2069 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2070 AH_TOP([#ifndef CONFIG_H
2071 #define CONFIG_H])
2072 AH_BOTTOM([#endif])
2073
2074 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2075 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2076 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2077 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2078 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2079
2080 dnl Configure the makefile's configuration data
2081 AC_CONFIG_FILES([Makefile.config])
2082
2083 dnl Configure the RPM spec file for LLVM
2084 AC_CONFIG_FILES([llvm.spec])
2085
2086 dnl Configure doxygen's configuration file
2087 AC_CONFIG_FILES([docs/doxygen.cfg])
2088
2089 dnl Configure clang, if present
2090 if test "${clang_src_root}" = ""; then
2091   clang_src_root="$srcdir/tools/clang"
2092 fi
2093 if test -f ${clang_src_root}/README.txt; then
2094   dnl Use variables to stay under 80 columns.
2095   configh="include/clang/Config/config.h"
2096   doxy="docs/doxygen.cfg"
2097   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2098   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2099 fi
2100
2101 dnl OCaml findlib META file
2102 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2103
2104 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2105 test "x$program_prefix" = "xNONE" && program_prefix=""
2106 AC_SUBST([program_prefix])
2107
2108
2109 dnl Do special configuration of Makefiles
2110 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2111 AC_CONFIG_MAKEFILE(Makefile)
2112 AC_CONFIG_MAKEFILE(Makefile.common)
2113 AC_CONFIG_MAKEFILE(examples/Makefile)
2114 AC_CONFIG_MAKEFILE(lib/Makefile)
2115 AC_CONFIG_MAKEFILE(test/Makefile)
2116 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2117 AC_CONFIG_MAKEFILE(unittests/Makefile)
2118 AC_CONFIG_MAKEFILE(tools/Makefile)
2119 AC_CONFIG_MAKEFILE(utils/Makefile)
2120 AC_CONFIG_MAKEFILE(projects/Makefile)
2121 AC_CONFIG_MAKEFILE(bindings/Makefile)
2122 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2123
2124 dnl Finally, crank out the output
2125 AC_OUTPUT