autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.2svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [2], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2012 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl We need to check for the compiler up here to avoid anything else
  63 dnl starting with a different one.
  64 AC_PROG_CC(clang llvm-gcc gcc)
  65 AC_PROG_CXX(clang++ llvm-g++ g++)
  66 AC_PROG_CPP
  67
  68 dnl Configure all of the projects present in our source tree. While we could
  69 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  70 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  71 dnl Instead we match on the known projects.
  72
  73 dnl
  74 dnl One tricky part of doing this is that some projects depend upon other
  75 dnl projects.  For example, several projects rely upon the LLVM test suite.
  76 dnl We want to configure those projects first so that their object trees are
  77 dnl created before running the configure scripts of projects that depend upon
  78 dnl them.
  79 dnl
  80
  81 dnl Several projects use llvm-gcc, so configure that first
  82 if test -d ${srcdir}/projects/llvm-gcc ; then
  83   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  84 fi
  85
  86 dnl Several projects use the LLVM test suite, so configure it next.
  87 if test -d ${srcdir}/projects/test-suite ; then
  88   AC_CONFIG_SUBDIRS([projects/test-suite])
  89 fi
  90
  91 dnl llvm-test is the old name of the test-suite, kept here for backwards
  92 dnl compatibility
  93 if test -d ${srcdir}/projects/llvm-test ; then
  94   AC_CONFIG_SUBDIRS([projects/llvm-test])
  95 fi
  96
  97 dnl Some projects use poolalloc; configure that next
  98 if test -d ${srcdir}/projects/poolalloc ; then
  99   AC_CONFIG_SUBDIRS([projects/poolalloc])
 100 fi
 101
 102 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 103   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 104 fi
 105
 106 dnl Check for all other projects
 107 for i in `ls ${srcdir}/projects`
 108 do
 109   if test -d ${srcdir}/projects/${i} ; then
 110     case ${i} in
 111       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 112       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 113       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 114       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 115       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 116       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 117       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 118       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 119       compiler-rt)       ;;
 120       llvm-gcc)       ;;
 121       test-suite)     ;;
 122       llvm-test)      ;;
 123       poolalloc)      ;;
 124       llvm-poolalloc) ;;
 125       *)
 126         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 127         ;;
 128     esac
 129   fi
 130 done
 131
 132 dnl Disable the build of polly, even if it is checked out into tools/polly.
 133 AC_ARG_ENABLE(polly,
 134               AS_HELP_STRING([--enable-polly],
 135                              [Use polly if available (default is YES)]),,
 136                              enableval=default)
 137 case "$enableval" in
 138   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 139   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 140   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 141   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 142 esac
 143
 144
 145 dnl Check if polly is checked out into tools/polly and configure it if
 146 dnl available.
 147 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 148   AC_SUBST(LLVM_HAS_POLLY,1)
 149   AC_CONFIG_SUBDIRS([tools/polly])
 150 fi
 151
 152 dnl===-----------------------------------------------------------------------===
 153 dnl===
 154 dnl=== SECTION 2: Architecture, target, and host checks
 155 dnl===
 156 dnl===-----------------------------------------------------------------------===
 157
 158 dnl Check the target for which we're compiling and the host that will do the
 159 dnl compilations. This will tell us which LLVM compiler will be used for
 160 dnl compiling SSA into object code. This needs to be done early because
 161 dnl following tests depend on it.
 162 AC_CANONICAL_TARGET
 163
 164 dnl Determine the platform type and cache its value. This helps us configure
 165 dnl the System library to the correct build platform.
 166 AC_CACHE_CHECK([type of operating system we're going to host on],
 167                [llvm_cv_os_type],
 168 [case $host in
 169   *-*-aix*)
 170     llvm_cv_link_all_option="-Wl,--whole-archive"
 171     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 172     llvm_cv_os_type="AIX"
 173     llvm_cv_platform_type="Unix" ;;
 174   *-*-irix*)
 175     llvm_cv_link_all_option="-Wl,--whole-archive"
 176     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 177     llvm_cv_os_type="IRIX"
 178     llvm_cv_platform_type="Unix" ;;
 179   *-*-cygwin*)
 180     llvm_cv_link_all_option="-Wl,--whole-archive"
 181     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 182     llvm_cv_os_type="Cygwin"
 183     llvm_cv_platform_type="Unix" ;;
 184   *-*-darwin*)
 185     llvm_cv_link_all_option="-Wl,-all_load"
 186     llvm_cv_no_link_all_option="-Wl,-noall_load"
 187     llvm_cv_os_type="Darwin"
 188     llvm_cv_platform_type="Unix" ;;
 189   *-*-minix*)
 190     llvm_cv_link_all_option="-Wl,-all_load"
 191     llvm_cv_no_link_all_option="-Wl,-noall_load"
 192     llvm_cv_os_type="Minix"
 193     llvm_cv_platform_type="Unix" ;;
 194   *-*-freebsd* | *-*-kfreebsd-gnu)
 195     llvm_cv_link_all_option="-Wl,--whole-archive"
 196     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 197     llvm_cv_os_type="FreeBSD"
 198     llvm_cv_platform_type="Unix" ;;
 199   *-*-openbsd*)
 200     llvm_cv_link_all_option="-Wl,--whole-archive"
 201     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 202     llvm_cv_os_type="OpenBSD"
 203     llvm_cv_platform_type="Unix" ;;
 204   *-*-netbsd*)
 205     llvm_cv_link_all_option="-Wl,--whole-archive"
 206     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 207     llvm_cv_os_type="NetBSD"
 208     llvm_cv_platform_type="Unix" ;;
 209   *-*-dragonfly*)
 210     llvm_cv_link_all_option="-Wl,--whole-archive"
 211     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 212     llvm_cv_os_type="DragonFly"
 213     llvm_cv_platform_type="Unix" ;;
 214   *-*-hpux*)
 215     llvm_cv_link_all_option="-Wl,--whole-archive"
 216     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 217     llvm_cv_os_type="HP-UX"
 218     llvm_cv_platform_type="Unix" ;;
 219   *-*-interix*)
 220     llvm_cv_link_all_option="-Wl,--whole-archive"
 221     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 222     llvm_cv_os_type="Interix"
 223     llvm_cv_platform_type="Unix" ;;
 224   *-*-linux*)
 225     llvm_cv_link_all_option="-Wl,--whole-archive"
 226     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 227     llvm_cv_os_type="Linux"
 228     llvm_cv_platform_type="Unix" ;;
 229   *-*-gnu*)
 230     llvm_cv_link_all_option="-Wl,--whole-archive"
 231     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 232     llvm_cv_os_type="GNU"
 233     llvm_cv_platform_type="Unix" ;;
 234   *-*-solaris*)
 235     llvm_cv_link_all_option="-Wl,-z,allextract"
 236     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 237     llvm_cv_os_type="SunOS"
 238     llvm_cv_platform_type="Unix" ;;
 239   *-*-auroraux*)
 240     llvm_cv_link_all_option="-Wl,-z,allextract"
 241     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 242     llvm_cv_os_type="AuroraUX"
 243     llvm_cv_platform_type="Unix" ;;
 244   *-*-win32*)
 245     llvm_cv_link_all_option="-Wl,--whole-archive"
 246     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 247     llvm_cv_os_type="Win32"
 248     llvm_cv_platform_type="Win32" ;;
 249   *-*-mingw*)
 250     llvm_cv_link_all_option="-Wl,--whole-archive"
 251     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 252     llvm_cv_os_type="MingW"
 253     llvm_cv_platform_type="Win32" ;;
 254   *-*-haiku*)
 255     llvm_cv_link_all_option="-Wl,--whole-archive"
 256     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 257     llvm_cv_os_type="Haiku"
 258     llvm_cv_platform_type="Unix" ;;
 259   *-unknown-eabi*)
 260     llvm_cv_link_all_option="-Wl,--whole-archive"
 261     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 262     llvm_cv_os_type="Freestanding"
 263     llvm_cv_platform_type="Unix" ;;
 264   *-unknown-elf*)
 265     llvm_cv_link_all_option="-Wl,--whole-archive"
 266     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 267     llvm_cv_os_type="Freestanding"
 268     llvm_cv_platform_type="Unix" ;;
 269   *)
 270     llvm_cv_link_all_option=""
 271     llvm_cv_no_link_all_option=""
 272     llvm_cv_os_type="Unknown"
 273     llvm_cv_platform_type="Unknown" ;;
 274 esac])
 275
 276 AC_CACHE_CHECK([type of operating system we're going to target],
 277                [llvm_cv_target_os_type],
 278 [case $target in
 279   *-*-aix*)
 280     llvm_cv_target_os_type="AIX" ;;
 281   *-*-irix*)
 282     llvm_cv_target_os_type="IRIX" ;;
 283   *-*-cygwin*)
 284     llvm_cv_target_os_type="Cygwin" ;;
 285   *-*-darwin*)
 286     llvm_cv_target_os_type="Darwin" ;;
 287   *-*-minix*)
 288     llvm_cv_target_os_type="Minix" ;;
 289   *-*-freebsd* | *-*-kfreebsd-gnu)
 290     llvm_cv_target_os_type="FreeBSD" ;;
 291   *-*-openbsd*)
 292     llvm_cv_target_os_type="OpenBSD" ;;
 293   *-*-netbsd*)
 294     llvm_cv_target_os_type="NetBSD" ;;
 295   *-*-dragonfly*)
 296     llvm_cv_target_os_type="DragonFly" ;;
 297   *-*-hpux*)
 298     llvm_cv_target_os_type="HP-UX" ;;
 299   *-*-interix*)
 300     llvm_cv_target_os_type="Interix" ;;
 301   *-*-linux*)
 302     llvm_cv_target_os_type="Linux" ;;
 303   *-*-gnu*)
 304     llvm_cv_target_os_type="GNU" ;;
 305   *-*-solaris*)
 306     llvm_cv_target_os_type="SunOS" ;;
 307   *-*-auroraux*)
 308     llvm_cv_target_os_type="AuroraUX" ;;
 309   *-*-win32*)
 310     llvm_cv_target_os_type="Win32" ;;
 311   *-*-mingw*)
 312     llvm_cv_target_os_type="MingW" ;;
 313   *-*-haiku*)
 314     llvm_cv_target_os_type="Haiku" ;;
 315   *-*-rtems*)
 316     llvm_cv_target_os_type="RTEMS" ;;
 317   *-*-nacl*)
 318     llvm_cv_target_os_type="NativeClient" ;;
 319   *-unknown-eabi*)
 320     llvm_cv_target_os_type="Freestanding" ;;
 321   *)
 322     llvm_cv_target_os_type="Unknown" ;;
 323 esac])
 324
 325 dnl Make sure we aren't attempting to configure for an unknown system
 326 if test "$llvm_cv_os_type" = "Unknown" ; then
 327   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 328 fi
 329
 330 dnl Set the "OS" Makefile variable based on the platform type so the
 331 dnl makefile can configure itself to specific build hosts
 332 AC_SUBST(OS,$llvm_cv_os_type)
 333 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 334 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 335
 336 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 337 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 338 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 339
 340 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 341 dnl This is used by lib/Support to determine the basic kind of implementation
 342 dnl to use.
 343 case $llvm_cv_platform_type in
 344   Unix)
 345     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 346     AC_SUBST(LLVM_ON_UNIX,[1])
 347     AC_SUBST(LLVM_ON_WIN32,[0])
 348     ;;
 349   Win32)
 350     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 351     AC_SUBST(LLVM_ON_UNIX,[0])
 352     AC_SUBST(LLVM_ON_WIN32,[1])
 353     ;;
 354 esac
 355
 356 dnl Determine what our target architecture is and configure accordingly.
 357 dnl This will allow Makefiles to make a distinction between the hardware and
 358 dnl the OS.
 359 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 360 [case $target in
 361   i?86-*)                 llvm_cv_target_arch="x86" ;;
 362   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 363   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 364   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 365   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 366   mips-*)                 llvm_cv_target_arch="Mips" ;;
 367   mipsel-*)               llvm_cv_target_arch="Mips" ;;
 368   xcore-*)                llvm_cv_target_arch="XCore" ;;
 369   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 370   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 371   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 372   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 373   *)                      llvm_cv_target_arch="Unknown" ;;
 374 esac])
 375
 376 if test "$llvm_cv_target_arch" = "Unknown" ; then
 377   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 378 fi
 379
 380 dnl Determine the LLVM native architecture for the target
 381 case "$llvm_cv_target_arch" in
 382     x86)     LLVM_NATIVE_ARCH="X86" ;;
 383     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 384     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 385 esac
 386
 387 dnl Define a substitution, ARCH, for the target architecture
 388 AC_SUBST(ARCH,$llvm_cv_target_arch)
 389
 390 dnl Determine what our host architecture.
 391 dnl This will allow MCJIT regress tests runs only for supported
 392 dnl platforms.
 393 case $host in
 394   i?86-*)                 host_arch="x86" ;;
 395   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 396   sparc*-*)               host_arch="Sparc" ;;
 397   powerpc*-*)             host_arch="PowerPC" ;;
 398   arm*-*)                 host_arch="ARM" ;;
 399   mips-*)                 host_arch="Mips" ;;
 400   mipsel-*)               host_arch="Mips" ;;
 401   xcore-*)                host_arch="XCore" ;;
 402   msp430-*)               host_arch="MSP430" ;;
 403   hexagon-*)              host_arch="Hexagon" ;;
 404   mblaze-*)               host_arch="MBlaze" ;;
 405   *)                      host_arch="Unknown" ;;
 406 esac
 407
 408 if test "$host_arch" = "Unknown" ; then
 409   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 410 fi
 411
 412 AC_SUBST(HOST_ARCH,$host_arch)
 413
 414 dnl Check for the endianness of the target
 415 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 416
 417 dnl Check for build platform executable suffix if we're cross-compiling
 418 if test "$cross_compiling" = yes; then
 419   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 420   AC_BUILD_EXEEXT
 421   ac_build_prefix=${build_alias}-
 422   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 423   if test -z "$BUILD_CXX"; then
 424      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 425      if test -z "$BUILD_CXX"; then
 426        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 427      fi
 428   fi
 429 else
 430   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 431 fi
 432
 433 dnl Check to see if there's a .svn or .git directory indicating that this
 434 dnl build is being done from a checkout. This sets up several defaults for
 435 dnl the command line switches. When we build with a checkout directory,
 436 dnl we get a debug with assertions turned on. Without, we assume a source
 437 dnl release and we get an optimized build without assertions.
 438 dnl See --enable-optimized and --enable-assertions below
 439 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 440   cvsbuild="yes"
 441   optimize="no"
 442   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 443 else
 444   cvsbuild="no"
 445   optimize="yes"
 446 fi
 447
 448 dnl===-----------------------------------------------------------------------===
 449 dnl===
 450 dnl=== SECTION 3: Command line arguments for the configure script.
 451 dnl===
 452 dnl===-----------------------------------------------------------------------===
 453
 454 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 455 AC_ARG_ENABLE(libcpp,
 456               AS_HELP_STRING([--enable-libcpp],
 457                              [Use libc++ if available (default is NO)]),,
 458                              enableval=default)
 459 case "$enableval" in
 460   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 461   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 462   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 463   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 464 esac
 465
 466 dnl --enable-optimized : check whether they want to do an optimized build:
 467 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 468  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 469 if test ${enableval} = "no" ; then
 470   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 471 else
 472   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 473 fi
 474
 475 dnl --enable-profiling : check whether they want to do a profile build:
 476 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 477  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 478 if test ${enableval} = "no" ; then
 479   AC_SUBST(ENABLE_PROFILING,[[]])
 480 else
 481   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 482 fi
 483
 484 dnl --enable-assertions : check whether they want to turn on assertions or not:
 485 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 486   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 487 if test ${enableval} = "yes" ; then
 488   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 489 else
 490   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 491 fi
 492
 493 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 494 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 495   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 496 if test ${enableval} = "yes" ; then
 497   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 498   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 499 else
 500   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 501   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 502 fi
 503
 504 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 505 AC_ARG_ENABLE(debug-runtime,
 506    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 507 if test ${enableval} = "no" ; then
 508   AC_SUBST(DEBUG_RUNTIME,[[]])
 509 else
 510   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 511 fi
 512
 513 dnl --enable-debug-symbols : should even optimized compiler libraries
 514 dnl have debug symbols?
 515 AC_ARG_ENABLE(debug-symbols,
 516    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 517 if test ${enableval} = "no" ; then
 518   AC_SUBST(DEBUG_SYMBOLS,[[]])
 519 else
 520   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 521 fi
 522
 523 dnl --enable-jit: check whether they want to enable the jit
 524 AC_ARG_ENABLE(jit,
 525   AS_HELP_STRING(--enable-jit,
 526                  [Enable Just In Time Compiling (default is YES)]),,
 527   enableval=default)
 528 if test ${enableval} = "no"
 529 then
 530   AC_SUBST(JIT,[[]])
 531 else
 532   case "$llvm_cv_target_arch" in
 533     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 534     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 535     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 536     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 537     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 538     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 539     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 540     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 541     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 542     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 543     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 544     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 545   esac
 546 fi
 547
 548 dnl Allow enablement of building and installing docs
 549 AC_ARG_ENABLE(docs,
 550               AS_HELP_STRING([--enable-docs],
 551                              [Build documents (default is YES)]),,
 552                              enableval=default)
 553 case "$enableval" in
 554   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 555   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 556   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 557   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 558 esac
 559
 560 dnl Allow enablement of doxygen generated documentation
 561 AC_ARG_ENABLE(doxygen,
 562               AS_HELP_STRING([--enable-doxygen],
 563                              [Build doxygen documentation (default is NO)]),,
 564                              enableval=default)
 565 case "$enableval" in
 566   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 567   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 568   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 569   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 570 esac
 571
 572 dnl Allow disablement of threads
 573 AC_ARG_ENABLE(threads,
 574               AS_HELP_STRING([--enable-threads],
 575                              [Use threads if available (default is YES)]),,
 576                              enableval=default)
 577 case "$enableval" in
 578   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 579   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 580   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 581   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 582 esac
 583 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 584                    [Define if threads enabled])
 585
 586 dnl Allow disablement of pthread.h
 587 AC_ARG_ENABLE(pthreads,
 588               AS_HELP_STRING([--enable-pthreads],
 589                              [Use pthreads if available (default is YES)]),,
 590                              enableval=default)
 591 case "$enableval" in
 592   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 593   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 594   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 595   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 596 esac
 597
 598 dnl Allow building without position independent code
 599 AC_ARG_ENABLE(pic,
 600   AS_HELP_STRING([--enable-pic],
 601                  [Build LLVM with Position Independent Code (default is YES)]),,
 602                  enableval=default)
 603 case "$enableval" in
 604   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 605   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 606   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 607   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 608 esac
 609 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 610                    [Define if position independent code is enabled])
 611
 612 dnl Allow building a shared library and linking tools against it.
 613 AC_ARG_ENABLE(shared,
 614   AS_HELP_STRING([--enable-shared],
 615                  [Build a shared library and link tools against it (default is NO)]),,
 616                  enableval=default)
 617 case "$enableval" in
 618   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 619   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 620   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 621   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 622 esac
 623
 624 dnl Allow libstdc++ is embedded in LLVM.dll.
 625 AC_ARG_ENABLE(embed-stdcxx,
 626   AS_HELP_STRING([--enable-embed-stdcxx],
 627                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 628                  enableval=default)
 629 case "$enableval" in
 630   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 631   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 632   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 633   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 634 esac
 635
 636 dnl Enable embedding timestamp information into build.
 637 AC_ARG_ENABLE(timestamps,
 638   AS_HELP_STRING([--enable-timestamps],
 639                  [Enable embedding timestamp information in build (default is YES)]),,
 640                  enableval=default)
 641 case "$enableval" in
 642   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 643   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 644   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 645   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 646 esac
 647 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 648                    [Define if timestamp information (e.g., __DATE__) is allowed])
 649
 650 dnl Allow specific targets to be specified for building (or not)
 651 TARGETS_TO_BUILD=""
 652 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 653     [Build specific host targets: all or target1,target2,... Valid targets are:
 654      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 655      xcore, msp430, nvptx, r600, and cpp (default=all)]),,
 656     enableval=all)
 657 if test "$enableval" = host-only ; then
 658   enableval=host
 659 fi
 660 case "$enableval" in
 661   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 CppBackend MBlaze NVPTX Hexagon AMDGPU" ;;
 662   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 663       case "$a_target" in
 664         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 665         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 666         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 667         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 668         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 669         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 670         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 671         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 672         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 673         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 674         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 675         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 676         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 677         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 678         r600)     TARGETS_TO_BUILD="AMDGPU $TARGETS_TO_BUILD" ;;
 679         host) case "$llvm_cv_target_arch" in
 680             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 681             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 682             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 683             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 684             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 685             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 686             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 687             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 688             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 689             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 690             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 691             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 692             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 693           esac ;;
 694         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 695       esac
 696   done
 697   ;;
 698 esac
 699 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 700
 701 dnl Determine whether we are building LLVM support for the native architecture.
 702 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 703 for a_target in $TARGETS_TO_BUILD; do
 704   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 705     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 706       [LLVM architecture name for the native architecture, if available])
 707     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 708     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 709     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 710     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 711     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 712       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 713     fi
 714     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 715       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 716     fi
 717     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 718       [LLVM name for the native Target init function, if available])
 719     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 720       [LLVM name for the native TargetInfo init function, if available])
 721     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 722       [LLVM name for the native target MC init function, if available])
 723     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 724       [LLVM name for the native AsmPrinter init function, if available])
 725     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 726       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 727        [LLVM name for the native AsmParser init function, if available])
 728     fi
 729     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 730       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 731        [LLVM name for the native Disassembler init function, if available])
 732     fi
 733   fi
 734 done
 735
 736 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 737 dnl target feature def files.
 738 LLVM_ENUM_TARGETS=""
 739 LLVM_ENUM_ASM_PRINTERS=""
 740 LLVM_ENUM_ASM_PARSERS=""
 741 LLVM_ENUM_DISASSEMBLERS=""
 742 for target_to_build in $TARGETS_TO_BUILD; do
 743   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 744   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 745     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 746   fi
 747   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 748     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 749   fi
 750   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 751     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 752   fi
 753 done
 754 AC_SUBST(LLVM_ENUM_TARGETS)
 755 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 756 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 757 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 758
 759 dnl Override the option to use for optimized builds.
 760 AC_ARG_WITH(optimize-option,
 761   AS_HELP_STRING([--with-optimize-option],
 762                  [Select the compiler options to use for optimized builds]),,
 763                  withval=default)
 764 AC_MSG_CHECKING([optimization flags])
 765 case "$withval" in
 766   default)
 767     case "$llvm_cv_os_type" in
 768     FreeBSD) optimize_option=-O2 ;;
 769     MingW) optimize_option=-O2 ;;
 770     *)     optimize_option=-O3 ;;
 771     esac ;;
 772   *) optimize_option="$withval" ;;
 773 esac
 774 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 775 AC_MSG_RESULT([$optimize_option])
 776
 777 dnl Specify extra build options
 778 AC_ARG_WITH(extra-options,
 779   AS_HELP_STRING([--with-extra-options],
 780                  [Specify additional options to compile LLVM with]),,
 781                  withval=default)
 782 case "$withval" in
 783   default) EXTRA_OPTIONS= ;;
 784   *) EXTRA_OPTIONS=$withval ;;
 785 esac
 786 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 787
 788 dnl Specify extra linker build options
 789 AC_ARG_WITH(extra-ld-options,
 790   AS_HELP_STRING([--with-extra-ld-options],
 791                  [Specify additional options to link LLVM with]),,
 792                  withval=default)
 793 case "$withval" in
 794   default) EXTRA_LD_OPTIONS= ;;
 795   *) EXTRA_LD_OPTIONS=$withval ;;
 796 esac
 797 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 798
 799 dnl Allow specific bindings to be specified for building (or not)
 800 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 801     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 802     enableval=default)
 803 BINDINGS_TO_BUILD=""
 804 case "$enableval" in
 805   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 806   all ) BINDINGS_TO_BUILD="ocaml" ;;
 807   none | no) BINDINGS_TO_BUILD="" ;;
 808   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 809       case "$a_binding" in
 810         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 811         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 812       esac
 813   done
 814   ;;
 815 esac
 816
 817 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 818 dnl script for bindings/ocaml/configure, except that its auto value depends on
 819 dnl OCAMLC, which is found here to support tests.
 820 AC_ARG_WITH([ocaml-libdir],
 821   [AS_HELP_STRING([--with-ocaml-libdir],
 822     [Specify install location for ocaml bindings (default is stdlib)])],
 823   [],
 824   [withval=auto])
 825 case "$withval" in
 826   auto) with_ocaml_libdir="$withval" ;;
 827   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 828   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 829 esac
 830
 831 AC_ARG_WITH(clang-srcdir,
 832   AS_HELP_STRING([--with-clang-srcdir],
 833     [Directory to the out-of-tree Clang source]),,
 834     withval="-")
 835 case "$withval" in
 836   -) clang_src_root="" ;;
 837   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 838   *) clang_src_root="$ac_pwd/$withval" ;;
 839 esac
 840 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 841
 842 AC_ARG_WITH(clang-resource-dir,
 843   AS_HELP_STRING([--with-clang-resource-dir],
 844     [Relative directory from the Clang binary for resource files]),,
 845     withval="")
 846 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 847                    [Relative directory for resource files])
 848
 849 AC_ARG_WITH(c-include-dirs,
 850   AS_HELP_STRING([--with-c-include-dirs],
 851     [Colon separated list of directories clang will search for headers]),,
 852     withval="")
 853 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 854                    [Directories clang will search for headers])
 855
 856 # Clang normally uses the system c++ headers and libraries. With this option,
 857 # clang will use the ones provided by a gcc installation instead. This option should
 858 # be passed the same value that was used with --prefix when configuring gcc.
 859 AC_ARG_WITH(gcc-toolchain,
 860   AS_HELP_STRING([--with-gcc-toolchain],
 861     [Directory where gcc is installed.]),,
 862     withval="")
 863 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 864                    [Directory where gcc is installed.])
 865
 866 AC_ARG_WITH(default-sysroot,
 867   AS_HELP_STRING([--with-default-sysroot],
 868     [Add --sysroot=<path> to all compiler invocations.]),,
 869     withval="")
 870 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
 871                    [Default <path> to all compiler invocations for --sysroot=<path>.])
 872
 873 dnl Allow linking of LLVM with GPLv3 binutils code.
 874 AC_ARG_WITH(binutils-include,
 875   AS_HELP_STRING([--with-binutils-include],
 876     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 877   withval=default)
 878 case "$withval" in
 879   default) WITH_BINUTILS_INCDIR=default ;;
 880   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 881   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 882 esac
 883 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 884   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 885   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 886      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 887      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 888   fi
 889 fi
 890
 891 dnl Specify the URL where bug reports should be submitted.
 892 AC_ARG_WITH(bug-report-url,
 893   AS_HELP_STRING([--with-bug-report-url],
 894     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 895     withval="http://llvm.org/bugs/")
 896 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 897                    [Bug report URL.])
 898
 899 dnl --enable-libffi : check whether the user wants to turn off libffi:
 900 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 901   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 902   [case "$enableval" in
 903     yes) llvm_cv_enable_libffi="yes" ;;
 904     no)  llvm_cv_enable_libffi="no"  ;;
 905     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 906   esac],
 907   llvm_cv_enable_libffi=no)
 908
 909 AC_ARG_WITH(internal-prefix,
 910   AS_HELP_STRING([--with-internal-prefix],
 911     [Installation directory for internal files]),,
 912     withval="")
 913 AC_SUBST(INTERNAL_PREFIX,[$withval])
 914
 915 dnl===-----------------------------------------------------------------------===
 916 dnl===
 917 dnl=== SECTION 4: Check for programs we need and that they are the right version
 918 dnl===
 919 dnl===-----------------------------------------------------------------------===
 920
 921 AC_PROG_NM
 922 AC_SUBST(NM)
 923
 924 dnl Check for the tools that the makefiles require
 925 AC_CHECK_GNU_MAKE
 926 AC_PROG_LN_S
 927 AC_PATH_PROG(CMP, [cmp], [cmp])
 928 AC_PATH_PROG(CP, [cp], [cp])
 929 AC_PATH_PROG(DATE, [date], [date])
 930 AC_PATH_PROG(FIND, [find], [find])
 931 AC_PATH_PROG(GREP, [grep], [grep])
 932 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 933 AC_PATH_PROG(MV,   [mv],   [mv])
 934 AC_PROG_RANLIB
 935 AC_CHECK_TOOL(AR, ar, false)
 936 AC_PATH_PROG(RM,   [rm],   [rm])
 937 AC_PATH_PROG(SED,  [sed],  [sed])
 938 AC_PATH_PROG(TAR,  [tar],  [gtar])
 939 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 940
 941 dnl Looking for misc. graph plotting software
 942 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 943 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 944   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 945   dnl If we're targeting for mingw we should emit windows paths, not msys
 946   if test "$llvm_cv_os_type" = "MingW" ; then
 947     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 948   fi
 949   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 950    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 951 fi
 952 AC_PATH_PROG(DOT, [dot], [echo dot])
 953 if test "$DOT" != "echo dot" ; then
 954   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 955   dnl If we're targeting for mingw we should emit windows paths, not msys
 956   if test "$llvm_cv_os_type" = "MingW" ; then
 957     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 958   fi
 959   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 960    [Define to path to dot program if found or 'echo dot' otherwise])
 961 fi
 962 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 963 if test "$FDP" != "echo fdp" ; then
 964   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 965   dnl If we're targeting for mingw we should emit windows paths, not msys
 966   if test "$llvm_cv_os_type" = "MingW" ; then
 967     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 968   fi
 969   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 970    [Define to path to fdp program if found or 'echo fdp' otherwise])
 971 fi
 972 AC_PATH_PROG(NEATO, [neato], [echo neato])
 973 if test "$NEATO" != "echo neato" ; then
 974   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 975   dnl If we're targeting for mingw we should emit windows paths, not msys
 976   if test "$llvm_cv_os_type" = "MingW" ; then
 977     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 978   fi
 979   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 980    [Define to path to neato program if found or 'echo neato' otherwise])
 981 fi
 982 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 983 if test "$TWOPI" != "echo twopi" ; then
 984   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 985   dnl If we're targeting for mingw we should emit windows paths, not msys
 986   if test "$llvm_cv_os_type" = "MingW" ; then
 987     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 988   fi
 989   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 990    [Define to path to twopi program if found or 'echo twopi' otherwise])
 991 fi
 992 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 993 if test "$CIRCO" != "echo circo" ; then
 994   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 995   dnl If we're targeting for mingw we should emit windows paths, not msys
 996   if test "$llvm_cv_os_type" = "MingW" ; then
 997     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 998   fi
 999   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1000    [Define to path to circo program if found or 'echo circo' otherwise])
1001 fi
1002 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1003 if test "$GV" != "echo gv" ; then
1004   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1005   dnl If we're targeting for mingw we should emit windows paths, not msys
1006   if test "$llvm_cv_os_type" = "MingW" ; then
1007     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1008   fi
1009   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1010    [Define to path to gv program if found or 'echo gv' otherwise])
1011 fi
1012 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1013 if test "$DOTTY" != "echo dotty" ; then
1014   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1015   dnl If we're targeting for mingw we should emit windows paths, not msys
1016   if test "$llvm_cv_os_type" = "MingW" ; then
1017     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1018   fi
1019   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1020    [Define to path to dotty program if found or 'echo dotty' otherwise])
1021 fi
1022 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1023 if test "$XDOT_PY" != "echo xdot.py" ; then
1024   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1025   dnl If we're targeting for mingw we should emit windows paths, not msys
1026   if test "$llvm_cv_os_type" = "MingW" ; then
1027     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1028   fi
1029   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1030    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1031 fi
1032
1033 dnl Find the install program
1034 AC_PROG_INSTALL
1035 dnl Prepend src dir to install path dir if it's a relative path
1036 dnl This is a hack for installs that take place in something other
1037 dnl than the top level.
1038 case "$INSTALL" in
1039  [[\\/$]]* | ?:[[\\/]]* ) ;;
1040  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1041 esac
1042
1043 dnl Checks for documentation and testing tools that we can do without. If these
1044 dnl are not found then they are set to "true" which always succeeds but does
1045 dnl nothing. This just lets the build output show that we could have done
1046 dnl something if the tool was available.
1047 AC_PATH_PROG(BZIP2, [bzip2])
1048 AC_PATH_PROG(CAT, [cat])
1049 AC_PATH_PROG(DOXYGEN, [doxygen])
1050 AC_PATH_PROG(GROFF, [groff])
1051 AC_PATH_PROG(GZIPBIN, [gzip])
1052 AC_PATH_PROG(PDFROFF, [pdfroff])
1053 AC_PATH_PROG(ZIP, [zip])
1054 AC_PATH_PROGS(OCAMLC, [ocamlc])
1055 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1056 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1057 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1058 AC_PATH_PROGS(GAS, [gas as])
1059
1060 dnl Get the version of the linker in use.
1061 AC_LINK_GET_VERSION
1062
1063 dnl Determine whether the linker supports the -R option.
1064 AC_LINK_USE_R
1065
1066 dnl Determine whether the linker supports the -export-dynamic option.
1067 AC_LINK_EXPORT_DYNAMIC
1068
1069 dnl Determine whether the linker supports the --version-script option.
1070 AC_LINK_VERSION_SCRIPT
1071
1072 dnl Check for libtool and the library that has dlopen function (which must come
1073 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1074 dnl libtool).
1075 AC_LIBTOOL_DLOPEN
1076 AC_LIB_LTDL
1077
1078 AC_MSG_CHECKING([tool compatibility])
1079
1080 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1081 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1082 dnl to support those options.
1083 dnl "icc" emits gcc signatures
1084 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1085 ICC=no
1086 IXX=no
1087 case $CC in
1088   icc*|icpc*)
1089     ICC=yes
1090     IXX=yes
1091     ;;
1092    *)
1093     ;;
1094 esac
1095
1096 if test "$GCC" != "yes" && test "$ICC" != "yes"
1097 then
1098   AC_MSG_ERROR([gcc|icc required but not found])
1099 fi
1100
1101 dnl Ensure that compilation tools are compatible with GCC extensions
1102 if test "$GXX" != "yes" && test "$IXX" != "yes"
1103 then
1104   AC_MSG_ERROR([g++|clang++|icc required but not found])
1105 fi
1106
1107 dnl Verify that GCC is version 3.0 or higher
1108 if test "$GCC" = "yes"
1109 then
1110   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1111 #error Unsupported GCC version
1112 #endif
1113 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1114 fi
1115
1116 dnl Check for GNU Make.  We use its extensions, so don't build without it
1117 if test -z "$llvm_cv_gnu_make_command"
1118 then
1119   AC_MSG_ERROR([GNU Make required but not found])
1120 fi
1121
1122 dnl Tool compatibility is okay if we make it here.
1123 AC_MSG_RESULT([ok])
1124
1125 dnl Check optional compiler flags.
1126 AC_MSG_CHECKING([optional compiler flags])
1127 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1128 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1129 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1130 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1131
1132 dnl===-----------------------------------------------------------------------===
1133 dnl===
1134 dnl=== SECTION 5: Check for libraries
1135 dnl===
1136 dnl===-----------------------------------------------------------------------===
1137
1138 AC_CHECK_LIB(m,sin)
1139 if test "$llvm_cv_os_type" = "MingW" ; then
1140   AC_CHECK_LIB(imagehlp, main)
1141   AC_CHECK_LIB(psapi, main)
1142 fi
1143
1144 dnl dlopen() is required for plugin support.
1145 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1146                [Define if dlopen() is available on this platform.]),
1147                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1148
1149 dnl libffi is optional; used to call external functions from the interpreter
1150 if test "$llvm_cv_enable_libffi" = "yes" ; then
1151   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1152                  [Define if libffi is available on this platform.]),
1153                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1154 fi
1155
1156 dnl mallinfo is optional; the code can compile (minus features) without it
1157 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1158                [Define if mallinfo() is available on this platform.]))
1159
1160 dnl pthread locking functions are optional - but llvm will not be thread-safe
1161 dnl without locks.
1162 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1163   AC_CHECK_LIB(pthread, pthread_mutex_init)
1164   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1165                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1166                            [Have pthread_mutex_lock]))
1167   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1168                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1169                  [Have pthread_rwlock_init]))
1170   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1171                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1172                  [Have pthread_getspecific]))
1173 fi
1174
1175 dnl Allow extra x86-disassembler library
1176 AC_ARG_WITH(udis86,
1177   AS_HELP_STRING([--with-udis86=<path>],
1178     [Use udis86 external x86 disassembler library]),
1179     [
1180       AC_SUBST(USE_UDIS86, [1])
1181       case "$withval" in
1182         /usr/lib|yes) ;;
1183         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1184       esac
1185       AC_CHECK_LIB(udis86, ud_init, [], [
1186         echo "Error! You need to have libudis86 around."
1187         exit -1
1188       ])
1189     ],
1190     AC_SUBST(USE_UDIS86, [0]))
1191 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1192                    [Define if use udis86 library])
1193
1194 dnl Allow OProfile support for JIT output.
1195 AC_ARG_WITH(oprofile,
1196   AS_HELP_STRING([--with-oprofile=<prefix>],
1197     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1198     [
1199       AC_SUBST(USE_OPROFILE, [1])
1200       case "$withval" in
1201         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1202         no) llvm_cv_oppath=
1203             AC_SUBST(USE_OPROFILE, [0]) ;;
1204         *) llvm_cv_oppath="${withval}/lib/oprofile"
1205            CPPFLAGS="-I${withval}/include";;
1206       esac
1207       case $llvm_cv_os_type in
1208         Linux)
1209           if test -n "$llvm_cv_oppath" ; then
1210             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1211             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1212             dnl libbfd is not included properly in libopagent in some Debian
1213             dnl versions.  If libbfd isn't found at all, we assume opagent works
1214             dnl anyway.
1215             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1216             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1217               echo "Error! You need to have libopagent around."
1218               exit -1
1219             ])
1220             AC_CHECK_HEADER([opagent.h], [], [
1221               echo "Error! You need to have opagent.h around."
1222               exit -1
1223               ])
1224           fi ;;
1225         *)
1226           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1227       esac
1228     ],
1229     [
1230       AC_SUBST(USE_OPROFILE, [0])
1231     ])
1232 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1233                    [Define if we have the oprofile JIT-support library])
1234
1235 dnl Enable support for Intel JIT Events API.
1236 AC_ARG_WITH(intel-jitevents,
1237   AS_HELP_STRING([--with-intel-jitevents=<vtune-amplifier-dir>],
1238     [Specify location of run-time support library for Intel JIT API (default=/opt/intel/vtune_amplifier_xe_2011)]),
1239     [
1240       case $llvm_cv_os_type in
1241         Linux|Win32|Cygwin|MingW) ;;
1242         *)
1243           AC_MSG_ERROR([
1244             Intel JIT API support is available on Linux and Windows only."]) ;;
1245       esac
1246
1247       AC_SUBST(USE_INTEL_JITEVENTS, [1])
1248       case "$llvm_cv_target_arch" in
1249         x86)    llvm_intel_jitevents_archdir="lib32";;
1250         x86_64) llvm_intel_jitevents_archdir="lib64";;
1251         *)      echo "Target architecture $llvm_cv_target_arch does not support Intel JIT Events API"
1252                 exit -1;;
1253       esac
1254       INTEL_JITEVENTS_INCDIR="/opt/intel/vtune_amplifier_xe_2011/include"
1255       INTEL_JITEVENTS_LIBDIR="/opt/intel/vtune_amplifier_xe_2011/$llvm_intel_jitevents_archdir"
1256       case "$withval" in
1257         /* | [[A-Za-z]]:[[\\/]]*) INTEL_JITEVENTS_INCDIR=$withval/include
1258                                   INTEL_JITEVENTS_LIBDIR=$withval/$llvm_intel_jitevents_archdir ;;
1259         *) ;;
1260       esac
1261
1262       AC_SUBST(INTEL_JITEVENTS_INCDIR)
1263       AC_SUBST(INTEL_JITEVENTS_LIBDIR)
1264
1265       LIBS="$LIBS -L${INTEL_JITEVENTS_LIBDIR}"
1266       CPPFLAGS="$CPPFLAGS -I$INTEL_JITEVENTS_INCDIR"
1267
1268       AC_SEARCH_LIBS(iJIT_IsProfilingActive, jitprofiling, [], [
1269         echo "Error! Cannot find libjitprofiling.a. Please check path specified in flag --with-intel-jitevents"
1270         exit -1
1271       ])
1272       AC_CHECK_HEADER([jitprofiling.h], [], [
1273         echo "Error! Cannot find jitprofiling.h. Please check path specified in flag --with-intel-jitevents"
1274         exit -1
1275       ])
1276
1277     ],
1278     [
1279       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1280     ])
1281 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1282                    [Define if we have the Intel JIT API runtime support library])
1283
1284 dnl===-----------------------------------------------------------------------===
1285 dnl===
1286 dnl=== SECTION 6: Check for header files
1287 dnl===
1288 dnl===-----------------------------------------------------------------------===
1289
1290 dnl First, use autoconf provided macros for specific headers that we need
1291 dnl We don't check for ancient stuff or things that are guaranteed to be there
1292 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1293 dnl Generally we're looking for POSIX headers.
1294 AC_HEADER_DIRENT
1295 AC_HEADER_MMAP_ANONYMOUS
1296 AC_HEADER_STAT
1297 AC_HEADER_SYS_WAIT
1298 AC_HEADER_TIME
1299
1300 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1301 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1302 AC_CHECK_HEADERS([utime.h windows.h])
1303 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1304 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1305 AC_CHECK_HEADERS([valgrind/valgrind.h])
1306 AC_CHECK_HEADERS([fenv.h])
1307 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1308   AC_CHECK_HEADERS(pthread.h,
1309                    AC_SUBST(HAVE_PTHREAD, 1),
1310                    AC_SUBST(HAVE_PTHREAD, 0))
1311 else
1312   AC_SUBST(HAVE_PTHREAD, 0)
1313 fi
1314
1315 dnl Try to find ffi.h.
1316 if test "$llvm_cv_enable_libffi" = "yes" ; then
1317   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1318 fi
1319
1320 dnl Try to find Darwin specific crash reporting libraries.
1321 AC_CHECK_HEADERS([CrashReporterClient.h])
1322
1323 dnl Try to find Darwin specific crash reporting global.
1324 AC_MSG_CHECKING([__crashreporter_info__])
1325 AC_LINK_IFELSE(
1326   AC_LANG_SOURCE(
1327     [[extern const char *__crashreporter_info__;
1328       int main() {
1329         __crashreporter_info__ = "test";
1330         return 0;
1331       }
1332     ]]),
1333   AC_MSG_RESULT(yes)
1334   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1335   AC_MSG_RESULT(no)
1336   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1337             Define if __crashreporter_info__ exists.))
1338
1339 dnl===-----------------------------------------------------------------------===
1340 dnl===
1341 dnl=== SECTION 7: Check for types and structures
1342 dnl===
1343 dnl===-----------------------------------------------------------------------===
1344
1345 AC_HUGE_VAL_CHECK
1346 AC_TYPE_PID_T
1347 AC_TYPE_SIZE_T
1348 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1349 AC_STRUCT_TM
1350 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1351 AC_CHECK_TYPES([uint64_t],,
1352          AC_CHECK_TYPES([u_int64_t],,
1353          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1354
1355 dnl===-----------------------------------------------------------------------===
1356 dnl===
1357 dnl=== SECTION 8: Check for specific functions needed
1358 dnl===
1359 dnl===-----------------------------------------------------------------------===
1360
1361 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1362 AC_CHECK_FUNCS([powf fmodf strtof round ])
1363 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1364 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1365 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1366 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1367 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1368 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1369 AC_C_PRINTF_A
1370 AC_FUNC_RAND48
1371
1372 dnl Check the declaration "Secure API" on Windows environments.
1373 AC_CHECK_DECLS([strerror_s])
1374
1375 dnl Check symbols in libgcc.a for JIT on Mingw.
1376 if test "$llvm_cv_os_type" = "MingW" ; then
1377   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1378   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1379   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1380   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1381
1382   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1383   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1384   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1385   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1386   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1387   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1388   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1389   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1390   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1391   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1392
1393   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1394   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1395 fi
1396
1397 dnl Check Win32 API EnumerateLoadedModules.
1398 if test "$llvm_cv_os_type" = "MingW" ; then
1399   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1400   AC_COMPILE_IFELSE([[#include <windows.h>
1401 #include <imagehlp.h>
1402 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1403 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1404 [
1405   AC_MSG_RESULT([yes])
1406   llvm_cv_win32_elmcb_pcstr="PCSTR"
1407 ],
1408 [
1409   AC_MSG_RESULT([no])
1410   llvm_cv_win32_elmcb_pcstr="PSTR"
1411 ])
1412   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1413 fi
1414
1415 dnl Check for variations in the Standard C++ library and STL. These macros are
1416 dnl provided by LLVM in the autoconf/m4 directory.
1417 AC_FUNC_ISNAN
1418 AC_FUNC_ISINF
1419
1420 dnl Check for mmap support.We also need to know if /dev/zero is required to
1421 dnl be opened for allocating RWX memory.
1422 dnl Make sure we aren't attempting to configure for an unknown system
1423 if test "$llvm_cv_platform_type" = "Unix" ; then
1424   AC_FUNC_MMAP
1425   AC_FUNC_MMAP_FILE
1426   AC_NEED_DEV_ZERO_FOR_MMAP
1427
1428   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1429   then
1430     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1431   fi
1432   if test "$ac_cv_func_mmap_file" = "no"
1433   then
1434     AC_MSG_WARN([mmap() of files required but not found])
1435   fi
1436 fi
1437
1438 dnl atomic builtins are required for threading support.
1439 AC_MSG_CHECKING(for GCC atomic builtins)
1440 dnl Since we'll be using these atomic builtins in C++ files we should test
1441 dnl the C++ compiler.
1442 AC_LANG_PUSH([C++])
1443 AC_LINK_IFELSE(
1444   AC_LANG_SOURCE(
1445     [[int main() {
1446         volatile unsigned long val = 1;
1447         __sync_synchronize();
1448         __sync_val_compare_and_swap(&val, 1, 0);
1449         __sync_add_and_fetch(&val, 1);
1450         __sync_sub_and_fetch(&val, 1);
1451         return 0;
1452       }
1453     ]]),
1454   AC_LANG_POP([C++])
1455   AC_MSG_RESULT(yes)
1456   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1457   AC_MSG_RESULT(no)
1458   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1459   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1460
1461 dnl===-----------------------------------------------------------------------===
1462 dnl===
1463 dnl=== SECTION 9: Additional checks, variables, etc.
1464 dnl===
1465 dnl===-----------------------------------------------------------------------===
1466
1467 dnl Handle 32-bit linux systems running a 64-bit kernel.
1468 dnl This has to come after section 4 because it invokes the compiler.
1469 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1470   AC_IS_LINUX_MIXED
1471   if test "$llvm_cv_linux_mixed" = "yes"; then
1472     llvm_cv_target_arch="x86"
1473     ARCH="x86"
1474   fi
1475 fi
1476
1477 dnl Check whether __dso_handle is present
1478 AC_CHECK_FUNCS([__dso_handle])
1479
1480 dnl Propagate the shared library extension that the libltdl checks did to
1481 dnl the Makefiles so we can use it there too
1482 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1483
1484 dnl Propagate the run-time library path variable that the libltdl
1485 dnl checks found to the Makefiles so we can use it there too
1486 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1487
1488 dnl Translate the various configuration directories and other basic
1489 dnl information into substitutions that will end up in Makefile.config.in
1490 dnl that these configured values can be used by the makefiles
1491 if test "${prefix}" = "NONE" ; then
1492   prefix="/usr/local"
1493 fi
1494 eval LLVM_PREFIX="${prefix}";
1495 eval LLVM_BINDIR="${prefix}/bin";
1496 eval LLVM_LIBDIR="${prefix}/lib";
1497 eval LLVM_DATADIR="${prefix}/share/llvm";
1498 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1499 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1500 eval LLVM_INCLUDEDIR="${prefix}/include";
1501 eval LLVM_INFODIR="${prefix}/info";
1502 eval LLVM_MANDIR="${prefix}/man";
1503 LLVM_CONFIGTIME=`date`
1504 AC_SUBST(LLVM_PREFIX)
1505 AC_SUBST(LLVM_BINDIR)
1506 AC_SUBST(LLVM_LIBDIR)
1507 AC_SUBST(LLVM_DATADIR)
1508 AC_SUBST(LLVM_DOCSDIR)
1509 AC_SUBST(LLVM_ETCDIR)
1510 AC_SUBST(LLVM_INCLUDEDIR)
1511 AC_SUBST(LLVM_INFODIR)
1512 AC_SUBST(LLVM_MANDIR)
1513 AC_SUBST(LLVM_CONFIGTIME)
1514
1515 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1516 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1517   LLVM_CONFIGTIME="(timestamp not enabled)"
1518 fi
1519
1520 dnl Place the various directories into the config.h file as #defines so that we
1521 dnl can know about the installation paths within LLVM.
1522 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1523                    [Installation prefix directory])
1524 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1525                    [Installation directory for binary executables])
1526 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1527                    [Installation directory for libraries])
1528 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1529                    [Installation directory for data files])
1530 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1531                    [Installation directory for documentation])
1532 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1533                    [Installation directory for config files])
1534 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1535                    [Installation directory for include files])
1536 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1537                    [Installation directory for .info files])
1538 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1539                    [Installation directory for man pages])
1540 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1541                    [Time at which LLVM was configured])
1542 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1543                    [Target triple LLVM will generate code for by default])
1544
1545 dnl Determine which bindings to build.
1546 if test "$BINDINGS_TO_BUILD" = auto ; then
1547   BINDINGS_TO_BUILD=""
1548   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1549     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1550   fi
1551 fi
1552 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1553
1554 dnl This isn't really configurey, but it avoids having to repeat the list in
1555 dnl other files.
1556 AC_SUBST(ALL_BINDINGS,ocaml)
1557
1558 dnl Do any work necessary to ensure that bindings have what they need.
1559 binding_prereqs_failed=0
1560 for a_binding in $BINDINGS_TO_BUILD ; do
1561   case "$a_binding" in
1562   ocaml)
1563     if test "x$OCAMLC" = x ; then
1564       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1565       binding_prereqs_failed=1
1566     fi
1567     if test "x$OCAMLDEP" = x ; then
1568       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1569       binding_prereqs_failed=1
1570     fi
1571     if test "x$OCAMLOPT" = x ; then
1572       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1573       dnl ocamlopt is optional!
1574     fi
1575     if test "x$with_ocaml_libdir" != xauto ; then
1576       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1577     else
1578       ocaml_stdlib="`"$OCAMLC" -where`"
1579       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1580       then
1581         # ocaml stdlib is beneath our prefix; use stdlib
1582         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1583       else
1584         # ocaml stdlib is outside our prefix; use libdir/ocaml
1585         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1586       fi
1587     fi
1588     ;;
1589   esac
1590 done
1591 if test "$binding_prereqs_failed" = 1 ; then
1592   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1593 fi
1594
1595 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1596 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1597
1598 dnl Determine linker rpath flag
1599 if test "$llvm_cv_link_use_r" = "yes" ; then
1600   RPATH="-Wl,-R"
1601 else
1602   RPATH="-Wl,-rpath"
1603 fi
1604 AC_SUBST(RPATH)
1605
1606 dnl Determine linker rdynamic flag
1607 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1608   RDYNAMIC="-Wl,-export-dynamic"
1609 else
1610   RDYNAMIC=""
1611 fi
1612 AC_SUBST(RDYNAMIC)
1613
1614 dnl===-----------------------------------------------------------------------===
1615 dnl===
1616 dnl=== SECTION 10: Specify the output files and generate it
1617 dnl===
1618 dnl===-----------------------------------------------------------------------===
1619
1620 dnl Configure header files
1621 dnl WARNING: dnl If you add or remove any of the following config headers, then
1622 dnl you MUST also update Makefile so that the variable FilesToConfig
1623 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1624 dnl files can be updated automatically when their *.in sources change.
1625 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1626 AH_TOP([#ifndef CONFIG_H
1627 #define CONFIG_H])
1628 AH_BOTTOM([#endif])
1629
1630 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1631 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1632 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1633 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1634 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1635
1636 dnl Configure the makefile's configuration data
1637 AC_CONFIG_FILES([Makefile.config])
1638
1639 dnl Configure the RPM spec file for LLVM
1640 AC_CONFIG_FILES([llvm.spec])
1641
1642 dnl Configure doxygen's configuration file
1643 AC_CONFIG_FILES([docs/doxygen.cfg])
1644
1645 dnl Configure clang, if present
1646 if test "${clang_src_root}" = ""; then
1647   clang_src_root="$srcdir/tools/clang"
1648 fi
1649 if test -f ${clang_src_root}/README.txt; then
1650   dnl Use variables to stay under 80 columns.
1651   configh="include/clang/Config/config.h"
1652   doxy="docs/doxygen.cfg"
1653   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1654   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1655 fi
1656
1657 dnl OCaml findlib META file
1658 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1659
1660 dnl Do special configuration of Makefiles
1661 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1662 AC_CONFIG_MAKEFILE(Makefile)
1663 AC_CONFIG_MAKEFILE(Makefile.common)
1664 AC_CONFIG_MAKEFILE(examples/Makefile)
1665 AC_CONFIG_MAKEFILE(lib/Makefile)
1666 AC_CONFIG_MAKEFILE(runtime/Makefile)
1667 AC_CONFIG_MAKEFILE(test/Makefile)
1668 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1669 AC_CONFIG_MAKEFILE(unittests/Makefile)
1670 AC_CONFIG_MAKEFILE(tools/Makefile)
1671 AC_CONFIG_MAKEFILE(utils/Makefile)
1672 AC_CONFIG_MAKEFILE(projects/Makefile)
1673 AC_CONFIG_MAKEFILE(bindings/Makefile)
1674 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1675
1676 dnl Finally, crank out the output
1677 AC_OUTPUT