autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.9cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "privbracket")  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  73       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_link_all_option="-Wl,--whole-archive"
 106     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 107     llvm_cv_os_type="AIX"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-cygwin*)
 110     llvm_cv_link_all_option="-Wl,--whole-archive"
 111     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 112     llvm_cv_os_type="Cygwin"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-darwin*)
 115     llvm_cv_link_all_option="-Wl,-all_load"
 116     llvm_cv_link_all_option="-Wl,-noall_load"
 117     llvm_cv_os_type="Darwin"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-freebsd*)
 120     llvm_cv_link_all_option="-Wl,--whole-archive"
 121     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 122     llvm_cv_os_type="FreeBSD"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-openbsd*)
 125     llvm_cv_link_all_option="-Wl,--whole-archive"
 126     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 127     llvm_cv_os_type="OpenBSD"
 128     llvm_cv_platform_type="Unix" ;;
 129   *-*-hpux*)
 130     llvm_cv_link_all_option="-Wl,--whole-archive"
 131     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 132     llvm_cv_os_type="HP-UX"
 133     llvm_cv_platform_type="Unix" ;;
 134   *-*-interix*)
 135     llvm_cv_link_all_option="-Wl,--whole-archive"
 136     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 137     llvm_cv_os_type="Interix"
 138     llvm_cv_platform_type="Unix" ;;
 139   *-*-linux*)
 140     llvm_cv_link_all_option="-Wl,--whole-archive"
 141     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 142     llvm_cv_os_type="Linux"
 143     llvm_cv_platform_type="Unix" ;;
 144   *-*-solaris*)
 145     llvm_cv_link_all_option="-Wl,-z,allextract"
 146     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 147     llvm_cv_os_type="SunOS"
 148     llvm_cv_platform_type="Unix" ;;
 149   *-*-win32*)
 150     llvm_cv_link_all_option="-Wl,--whole-archive"
 151     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 152     llvm_cv_os_type="Win32"
 153     llvm_cv_platform_type="Win32" ;;
 154   *-*-mingw*)
 155     llvm_cv_link_all_option="-Wl,--whole-archive"
 156     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 157     llvm_cv_os_type="MingW"
 158     llvm_cv_platform_type="Win32" ;;
 159   *)
 160     llvm_cv_link_all_option=""
 161     llvm_cv_no_link_all_option=""
 162     llvm_cv_os_type="Unknown"
 163     llvm_cv_platform_type="Unknown" ;;
 164 esac])
 165
 166 dnl Make sure we aren't attempting to configure for an unknown system
 167 if test "$llvm_cv_os_type" = "Unknown" ; then
 168   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 169 fi
 170
 171 dnl Set the "OS" Makefile variable based on the platform type so the
 172 dnl makefile can configure itself to specific build hosts
 173 AC_SUBST(OS,$llvm_cv_os_type)
 174
 175 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 176 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 177 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 178
 179 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 180 dnl This is used by lib/System to determine the basic kind of implementation
 181 dnl to use.
 182 case $llvm_cv_platform_type in
 183   Unix)
 184     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 185     AC_SUBST(LLVM_ON_UNIX,[1])
 186     AC_SUBST(LLVM_ON_WIN32,[0])
 187     ;;
 188   Win32)
 189     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 190     AC_SUBST(LLVM_ON_UNIX,[0])
 191     AC_SUBST(LLVM_ON_WIN32,[1])
 192     ;;
 193 esac
 194
 195 dnl Determine what our target architecture is and configure accordingly.
 196 dnl This will allow Makefiles to make a distinction between the hardware and
 197 dnl the OS.
 198 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 199 [case $target in
 200   i?86-*)                 llvm_cv_target_arch="x86" ;;
 201   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 202   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 203   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 204   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 205   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 206   *)                      llvm_cv_target_arch="Unknown" ;;
 207 esac])
 208
 209 if test "$llvm_cv_target_arch" = "Unknown" ; then
 210   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 211 fi
 212
 213 dnl Define a substitution, ARCH, for the target architecture
 214 AC_SUBST(ARCH,$llvm_cv_target_arch)
 215
 216 dnl Check for the endianness of the target
 217 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 218
 219 dnl Check for build platform executable suffix if we're crosscompiling
 220 if test "$cross_compiling" = yes; then
 221   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 222   AC_BUILD_EXEEXT
 223 else
 224   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 225 fi
 226
 227 dnl Check to see if there's a "CVS" directory indicating that this build is
 228 dnl being done from a CVS checkout. This sets up several defaults for the
 229 dnl command line switches. When we build with a CVS directory, we get a
 230 dnl debug with assertions turned on. Without, we assume a source release and we
 231 dnl get an optimized build without assertions. See --enable-optimized and
 232 dnl --enable-assertions below
 233 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 234   cvsbuild="yes"
 235   optimize="no"
 236   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 237 else
 238   cvsbuild="no"
 239   optimize="yes"
 240 fi
 241
 242 dnl===-----------------------------------------------------------------------===
 243 dnl===
 244 dnl=== SECTION 3: Command line arguments for the configure script.
 245 dnl===
 246 dnl===-----------------------------------------------------------------------===
 247
 248 dnl --enable-optimized : check whether they want to do an optimized build:
 249 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 250  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 251 if test ${enableval} = "no" ; then
 252   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 253 else
 254   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 255 fi
 256
 257 dnl --enable-assertions : check whether they want to turn on assertions or not:
 258 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 259   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 260 if test ${enableval} = "yes" ; then
 261   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 262 else
 263   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 264 fi
 265
 266 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 267 AC_ARG_ENABLE(debug-runtime,
 268    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 269 if test ${enableval} = "no" ; then
 270   AC_SUBST(DEBUG_RUNTIME,[[]])
 271 else
 272   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 273 fi
 274
 275 dnl --enable-jit: check whether they want to enable the jit
 276 AC_ARG_ENABLE(jit,
 277   AS_HELP_STRING(--enable-jit,
 278                  [Enable Just In Time Compiling (default is YES)]),,
 279   enableval=default)
 280 if test ${enableval} = "no"
 281 then
 282   AC_SUBST(JIT,[[]])
 283 else
 284   case "$llvm_cv_target_arch" in
 285     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 286     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 287     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 288     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 289     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 290     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 291     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 292   esac
 293 fi
 294
 295 dnl Allow enablement of doxygen generated documentation
 296 AC_ARG_ENABLE(doxygen,
 297               AS_HELP_STRING([--enable-doxygen],
 298                              [Build doxygen documentation (default is NO)]),,
 299                              enableval=default)
 300 case "$enableval" in
 301   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 302   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 303   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 304   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 305 esac
 306
 307 dnl Allow disablement of threads
 308 AC_ARG_ENABLE(threads,
 309               AS_HELP_STRING([--enable-threads],
 310                              [Use threads if available (default is YES)]),,
 311                              enableval=yes)
 312 case "$enableval" in
 313   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 314   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 315   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 316 esac
 317 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 318
 319 dnl Allow specific targets to be specified for building (or not)
 320 TARGETS_TO_BUILD=""
 321 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 322     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 323     enableval=all)
 324 case "$enableval" in
 325   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 326   host-only)
 327     case "$llvm_cv_target_arch" in
 328       x86)     TARGETS_TO_BUILD="X86" ;;
 329       x86_64)  TARGETS_TO_BUILD="X86" ;;
 330       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 331       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 332       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 333       IA64)    TARGETS_TO_BUILD="IA64" ;;
 334       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 335     esac
 336     ;;
 337   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 338       case "$a_target" in
 339         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 340         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 341         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 342         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 343         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 344         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 345         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 346       esac
 347   done
 348   ;;
 349 esac
 350 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 351 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 352
 353 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 354 AC_ARG_WITH(llvmgccdir,
 355   AS_HELP_STRING([--with-llvmgccdir],
 356     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 357     withval=default)
 358 case "$withval" in
 359   default) WITH_LLVMGCCDIR=default ;;
 360   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 361   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 362 esac
 363
 364 dnl Specify extra build options
 365 AC_ARG_WITH(extra-options,
 366   AS_HELP_STRING([--with-extra-options],
 367                  [Specify addtional options to compile LLVM with]),,
 368                  withval=default)
 369 case "$withval" in
 370   default) EXTRA_OPTIONS= ;;
 371   *) EXTRA_OPTIONS=$withval ;;
 372 esac
 373 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 374
 375 dnl===-----------------------------------------------------------------------===
 376 dnl===
 377 dnl=== SECTION 4: Check for programs we need and that they are the right version
 378 dnl===
 379 dnl===-----------------------------------------------------------------------===
 380
 381 dnl Check for compilation tools
 382 AC_PROG_CPP
 383 AC_PROG_CC(gcc)
 384 AC_PROG_CXX(g++)
 385 AC_PROG_FLEX
 386 AC_PROG_BISON
 387
 388 AC_PROG_NM
 389 AC_SUBST(NM)
 390
 391 dnl Check for the tools that the makefiles require
 392 AC_CHECK_GNU_MAKE
 393 AC_PROG_LN_S
 394 AC_PATH_PROG(CMP, [cmp], [cmp])
 395 AC_PATH_PROG(CP, [cp], [cp])
 396 AC_PATH_PROG(DATE, [date], [date])
 397 AC_PATH_PROG(FIND, [find], [find])
 398 AC_PATH_PROG(GREP, [grep], [grep])
 399 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 400 AC_PATH_PROG(MV,   [mv],   [mv])
 401 AC_PROG_RANLIB
 402 AC_PATH_PROG(RM,   [rm],   [rm])
 403 AC_PATH_PROG(SED,  [sed],  [sed])
 404 AC_PATH_PROG(TAR,  [tar],  [gtar])
 405 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 406
 407 dnl Looking for misc. graph plotting software
 408 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 409 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 410   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 411   dnl If we're targeting for mingw we should emit windows paths, not msys
 412   if test "$llvm_cv_os_type" == "MingW" ; then
 413     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 414   fi
 415   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 416    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 417 fi
 418 AC_PATH_PROG(DOT, [dot], [echo dot])
 419 if test "$DOT" != "echo dot" ; then
 420   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 421   dnl If we're targeting for mingw we should emit windows paths, not msys
 422   if test "$llvm_cv_os_type" == "MingW" ; then
 423     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 424   fi
 425   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 426    [Define to path to dot program if found or 'echo dot' otherwise])
 427 fi
 428 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 429 if test "$GV" != "echo gv" ; then
 430   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 431   dnl If we're targeting for mingw we should emit windows paths, not msys
 432   if test "$llvm_cv_os_type" == "MingW" ; then
 433     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 434   fi
 435   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 436    [Define to path to gv program if found or 'echo gv' otherwise])
 437 fi
 438 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 439 if test "$DOTTY" != "echo dotty" ; then
 440   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 441   dnl If we're targeting for mingw we should emit windows paths, not msys
 442   if test "$llvm_cv_os_type" == "MingW" ; then
 443     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 444   fi
 445   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 446    [Define to path to dotty program if found or 'echo dotty' otherwise])
 447 fi
 448
 449 dnl Look for a sufficiently recent version of Perl.
 450 LLVM_PROG_PERL([5.006])
 451 AC_SUBST(PERL)
 452 if test x"$PERL" = xnone; then
 453    AC_SUBST(HAVE_PERL,0)
 454 else
 455    AC_SUBST(HAVE_PERL,1)
 456 fi
 457
 458 dnl Find the install program
 459 AC_PROG_INSTALL
 460
 461 dnl Checks for documentation and testing tools that we can do without. If these
 462 dnl are not found then they are set to "true" which always succeeds but does
 463 dnl nothing. This just lets the build output show that we could have done
 464 dnl something if the tool was available.
 465 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 466 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 467 AC_PATH_PROG(ETAGS,[etags],[echo "Skipped: etags not found"])
 468 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 469 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 470 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 471 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 472 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 473 DJ_AC_PATH_TCLSH
 474 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 475
 476 dnl Determine if the linker supports the -R option.
 477 AC_LINK_USE_R
 478
 479 dnl Check for libtool and the library that has dlopen function (which must come
 480 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 481 dnl libtool).
 482 AC_LIBTOOL_DLOPEN
 483 AC_LIB_LTDL
 484 AC_PROG_LIBTOOL
 485
 486 if test "$lt_cv_dlopen_self" = "yes" ; then
 487   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 488               [Define if dlopen(0) will open the symbols of the program])
 489 fi
 490
 491 dnl Check if we know how to tell etags we are using C++:
 492 etags_version=`$ETAGS --version 2>&1`
 493 case "$etags_version" in
 494         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 495         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 496         *) ETAGSFLAGS="" ;;
 497 esac
 498 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 499
 500 if test "$WITH_LLVMGCCDIR" = "default" ; then
 501   LLVMGCC="llvm-gcc${EXEEXT}"
 502   LLVMGXX="llvm-g++${EXEEXT}"
 503   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 504   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 505 else
 506   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 507   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 508   AC_SUBST(LLVMGCC,$LLVMGCC)
 509   AC_SUBST(LLVMGXX,$LLVMGXX)
 510 fi
 511
 512 AC_MSG_CHECKING([tool compatibility])
 513
 514 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 515 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 516 dnl to support those options.
 517 dnl "icc" emits gcc signatures
 518 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 519 ICC=no
 520 IXX=no
 521 case $CC in
 522   icc*|icpc*)
 523     ICC=yes
 524     IXX=yes
 525     ;;
 526    *)
 527     ;;
 528 esac
 529
 530 if test "$GCC" != "yes" && test "$ICC" != "yes"
 531 then
 532   AC_MSG_ERROR([gcc|icc required but not found])
 533 fi
 534
 535 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 536 if test "$GXX" != "yes" && test "$IXX" != "yes"
 537 then
 538   AC_MSG_ERROR([g++|icc required but not found])
 539 fi
 540
 541 dnl Verify that GCC is version 3.0 or higher
 542 if test "$GCC" = "yes"
 543 then
 544   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 545   if test "$gccmajor" -lt "3"
 546   then
 547     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 548   fi
 549 fi
 550
 551 dnl Check for GNU Make.  We use its extensions, so don't build without it
 552 if test -z "$llvm_cv_gnu_make_command"
 553 then
 554   AC_MSG_ERROR([GNU Make required but not found])
 555 fi
 556
 557 dnl Tool compatibility is okay if we make it here.
 558 AC_MSG_RESULT([ok])
 559
 560 dnl===-----------------------------------------------------------------------===
 561 dnl===
 562 dnl=== SECTION 5: Check for libraries
 563 dnl===
 564 dnl===-----------------------------------------------------------------------===
 565
 566 dnl libelf is for sparc only; we can ignore it if we don't have it
 567 AC_CHECK_LIB(elf, elf_begin)
 568 AC_CHECK_LIB(m,sin)
 569 if test "$llvm_cv_os_type" == "MingW" ; then
 570   AC_CHECK_LIB(imagehlp, main)
 571   AC_CHECK_LIB(psapi, main)
 572 fi
 573
 574 dnl lt_dlopen may be required for plugin support.
 575 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 576               [Define if lt_dlopen() is available on this platform]),
 577               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 578                            not be available]))
 579
 580 dnl dlopen() is required for plugin support.
 581 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 582                [Define if dlopen() is available on this platform.]),
 583                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 584
 585 dnl mallinfo is optional; the code can compile (minus features) without it
 586 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 587                [Define if mallinfo() is available on this platform.]))
 588
 589 dnl pthread locking functions are optional - but llvm will not be thread-safe
 590 dnl without locks.
 591 if test "$ENABLE_THREADS" -eq 1 ; then
 592   AC_CHECK_LIB(pthread,pthread_mutex_init)
 593   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 594                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 595                            [Have pthread_mutex_lock]))
 596 fi
 597
 598 dnl===-----------------------------------------------------------------------===
 599 dnl===
 600 dnl=== SECTION 6: Check for header files
 601 dnl===
 602 dnl===-----------------------------------------------------------------------===
 603
 604 dnl First, use autoconf provided macros for specific headers that we need
 605 dnl We don't check for ancient stuff or things that are guaranteed to be there
 606 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 607 dnl Generally we're looking for POSIX headers.
 608 AC_HEADER_DIRENT
 609 AC_HEADER_MMAP_ANONYMOUS
 610 AC_HEADER_STAT
 611 AC_HEADER_STDC
 612 AC_HEADER_SYS_WAIT
 613 AC_HEADER_TIME
 614
 615 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 616 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 617 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 618 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h])
 619 if test "$ENABLE_THREADS" -eq 1 ; then
 620   AC_CHECK_HEADERS(pthread.h)
 621 fi
 622
 623 dnl===-----------------------------------------------------------------------===
 624 dnl===
 625 dnl=== SECTION 7: Check for types and structures
 626 dnl===
 627 dnl===-----------------------------------------------------------------------===
 628
 629 AC_TYPE_PID_T
 630 AC_TYPE_SIZE_T
 631 AC_TYPE_SIGNAL
 632 AC_STRUCT_TM
 633 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 634 AC_CHECK_TYPES([uint64_t],,
 635          AC_CHECK_TYPES([u_int64_t],,
 636          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 637
 638 dnl===-----------------------------------------------------------------------===
 639 dnl===
 640 dnl=== SECTION 8: Check for specific functions needed
 641 dnl===
 642 dnl===-----------------------------------------------------------------------===
 643
 644 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 645 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 646 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 647 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 648 AC_CHECK_FUNCS([_setjmp _longjmp setjmp longjmp sigsetjmp siglongjmp])
 649 AC_C_PRINTF_A
 650 AC_FUNC_ALLOCA
 651 AC_FUNC_RAND48
 652
 653 dnl Check for variations in the Standard C++ library and STL. These macros are
 654 dnl provided by LLVM in the autoconf/m4 directory.
 655 AC_CXX_HAVE_HASH_MAP
 656 AC_CXX_HAVE_HASH_SET
 657 AC_CXX_HAVE_STD_ITERATOR
 658 AC_CXX_HAVE_BI_ITERATOR
 659 AC_CXX_HAVE_FWD_ITERATOR
 660 AC_FUNC_ISNAN
 661 AC_FUNC_ISINF
 662
 663 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 664 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 665 dnl be opened for allocating RWX memory.
 666 AC_FUNC_MMAP
 667 AC_FUNC_MMAP_FILE
 668 AC_NEED_DEV_ZERO_FOR_MMAP
 669 AC_CHECK_FUNC(mprotect,,
 670               AC_MSG_ERROR([Function mprotect() required but not found]))
 671
 672 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 673 then
 674   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 675 fi
 676 if test "$ac_cv_func_mmap_file" = "no"
 677 then
 678   AC_MSG_WARN([mmap() of files required but not found])
 679 fi
 680
 681 dnl===-----------------------------------------------------------------------===
 682 dnl===
 683 dnl=== SECTION 9: Additional checks, variables, etc.
 684 dnl===
 685 dnl===-----------------------------------------------------------------------===
 686
 687 dnl See if the llvm-gcc executable can compile to LLVM assembly
 688 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 689 [llvm_cv_llvmgcc_sanity="no"
 690 if test -x "$LLVMGCC" ; then
 691   cp /dev/null conftest.c
 692   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 693   if test $? -eq 0 ; then
 694     llvm_cv_llvmgcc_sanity="yes"
 695   fi
 696   rm conftest.c
 697 fi])
 698
 699 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 700 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 701   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 702   AC_SUBST(LLVMCC1,$llvmcc1path)
 703   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 704   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 705   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 706   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 707   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 708   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 709   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 710   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 711 fi
 712
 713 dnl Propagate the shared library extension that the libltdl checks did to
 714 dnl the Makefiles so we can use it there too
 715 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 716
 717 # Translate the various configuration directories and other basic
 718 # information into substitutions that will end up in Makefile.config.in
 719 # that these configured values can be used by the makefiles
 720 if test "${prefix}" == "NONE" ; then
 721   prefix="/usr/local"
 722 fi
 723 eval LLVM_PREFIX="${prefix}";
 724 eval LLVM_BINDIR="${prefix}/bin";
 725 eval LLVM_LIBDIR="${prefix}/lib";
 726 eval LLVM_DATADIR="${prefix}/share/llvm";
 727 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 728 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 729 eval LLVM_INCLUDEDIR="${prefix}/include";
 730 eval LLVM_INFODIR="${prefix}/info";
 731 eval LLVM_MANDIR="${prefix}/man";
 732 LLVM_CONFIGTIME=`date`
 733 AC_SUBST(LLVM_PREFIX)
 734 AC_SUBST(LLVM_BINDIR)
 735 AC_SUBST(LLVM_LIBDIR)
 736 AC_SUBST(LLVM_DATADIR)
 737 AC_SUBST(LLVM_DOCSDIR)
 738 AC_SUBST(LLVM_ETCDIR)
 739 AC_SUBST(LLVM_INCLUDEDIR)
 740 AC_SUBST(LLVM_INFODIR)
 741 AC_SUBST(LLVM_MANDIR)
 742 AC_SUBST(LLVM_CONFIGTIME)
 743
 744 # Place the various directores into the config.h file as #defines so that we
 745 # can know about the installation paths within LLVM.
 746 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 747                    [Installation prefix directory])
 748 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 749                    [Installation directory for binary executables])
 750 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 751                    [Installation directory for libraries])
 752 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 753                    [Installation directory for data files])
 754 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 755                    [Installation directory for documentation])
 756 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 757                    [Installation directory for config files])
 758 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 759                    [Installation directory for include files])
 760 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 761                    [Installation directory for .info files])
 762 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 763                    [Installation directory for man pages])
 764 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 765                    [Time at which LLVM was configured])
 766
 767 dnl===-----------------------------------------------------------------------===
 768 dnl===
 769 dnl=== SECTION 10: Specify the output files and generate it
 770 dnl===
 771 dnl===-----------------------------------------------------------------------===
 772
 773 dnl Configure header files
 774 dnl WARNING: dnl If you add or remove any of the following config headers, then
 775 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 776 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 777 dnl files can be updated automatically when their *.in sources change.
 778 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 779 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 780 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 781 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 782 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 783
 784 dnl Configure the makefile's configuration data
 785 AC_CONFIG_FILES([Makefile.config])
 786
 787 dnl Configure doxygen's configuration file
 788 AC_CONFIG_FILES([docs/doxygen.cfg])
 789
 790 dnl Do the first stage of configuration for llvm-config.in.
 791 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 792
 793 dnl Do special configuration of Makefiles
 794 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 795 AC_CONFIG_MAKEFILE(Makefile)
 796 AC_CONFIG_MAKEFILE(Makefile.common)
 797 AC_CONFIG_MAKEFILE(examples/Makefile)
 798 AC_CONFIG_MAKEFILE(lib/Makefile)
 799 AC_CONFIG_MAKEFILE(runtime/Makefile)
 800 AC_CONFIG_MAKEFILE(test/Makefile)
 801 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 802 AC_CONFIG_MAKEFILE(tools/Makefile)
 803 AC_CONFIG_MAKEFILE(utils/Makefile)
 804 AC_CONFIG_MAKEFILE(projects/Makefile)
 805
 806 dnl Finally, crank out the output
 807 AC_OUTPUT
 808
 809 dnl Warn loudly if llvm-gcc was not obviously working
 810 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 811  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 812  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 813  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 814  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 815  AC_MSG_WARN([***** build the llvm tools.])
 816 fi