autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.9cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "privbracket")  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  73       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_link_all_option="-Wl,--whole-archive"
 106     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 107     llvm_cv_os_type="AIX"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-irix*)
 110     llvm_cv_link_all_option="-Wl,--whole-archive"
 111     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 112     llvm_cv_os_type="IRIX"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-cygwin*)
 115     llvm_cv_link_all_option="-Wl,--whole-archive"
 116     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 117     llvm_cv_os_type="Cygwin"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-darwin*)
 120     llvm_cv_link_all_option="-Wl,-all_load"
 121     llvm_cv_link_all_option="-Wl,-noall_load"
 122     llvm_cv_os_type="Darwin"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-freebsd*)
 125     llvm_cv_link_all_option="-Wl,--whole-archive"
 126     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 127     llvm_cv_os_type="FreeBSD"
 128     llvm_cv_platform_type="Unix" ;;
 129   *-*-openbsd*)
 130     llvm_cv_link_all_option="-Wl,--whole-archive"
 131     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 132     llvm_cv_os_type="OpenBSD"
 133     llvm_cv_platform_type="Unix" ;;
 134   *-*-hpux*)
 135     llvm_cv_link_all_option="-Wl,--whole-archive"
 136     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 137     llvm_cv_os_type="HP-UX"
 138     llvm_cv_platform_type="Unix" ;;
 139   *-*-interix*)
 140     llvm_cv_link_all_option="-Wl,--whole-archive"
 141     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 142     llvm_cv_os_type="Interix"
 143     llvm_cv_platform_type="Unix" ;;
 144   *-*-linux*)
 145     llvm_cv_link_all_option="-Wl,--whole-archive"
 146     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 147     llvm_cv_os_type="Linux"
 148     llvm_cv_platform_type="Unix" ;;
 149   *-*-solaris*)
 150     llvm_cv_link_all_option="-Wl,-z,allextract"
 151     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 152     llvm_cv_os_type="SunOS"
 153     llvm_cv_platform_type="Unix" ;;
 154   *-*-win32*)
 155     llvm_cv_link_all_option="-Wl,--whole-archive"
 156     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 157     llvm_cv_os_type="Win32"
 158     llvm_cv_platform_type="Win32" ;;
 159   *-*-mingw*)
 160     llvm_cv_link_all_option="-Wl,--whole-archive"
 161     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 162     llvm_cv_os_type="MingW"
 163     llvm_cv_platform_type="Win32" ;;
 164   *)
 165     llvm_cv_link_all_option=""
 166     llvm_cv_no_link_all_option=""
 167     llvm_cv_os_type="Unknown"
 168     llvm_cv_platform_type="Unknown" ;;
 169 esac])
 170
 171 dnl Make sure we aren't attempting to configure for an unknown system
 172 if test "$llvm_cv_os_type" = "Unknown" ; then
 173   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 174 fi
 175
 176 dnl Set the "OS" Makefile variable based on the platform type so the
 177 dnl makefile can configure itself to specific build hosts
 178 AC_SUBST(OS,$llvm_cv_os_type)
 179
 180 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 181 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 182 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 183
 184 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 185 dnl This is used by lib/System to determine the basic kind of implementation
 186 dnl to use.
 187 case $llvm_cv_platform_type in
 188   Unix)
 189     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 190     AC_SUBST(LLVM_ON_UNIX,[1])
 191     AC_SUBST(LLVM_ON_WIN32,[0])
 192     ;;
 193   Win32)
 194     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 195     AC_SUBST(LLVM_ON_UNIX,[0])
 196     AC_SUBST(LLVM_ON_WIN32,[1])
 197     ;;
 198 esac
 199
 200 dnl Determine what our target architecture is and configure accordingly.
 201 dnl This will allow Makefiles to make a distinction between the hardware and
 202 dnl the OS.
 203 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 204 [case $target in
 205   i?86-*)                 llvm_cv_target_arch="x86" ;;
 206   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 207   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 208   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 209   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 210   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 211   *)                      llvm_cv_target_arch="Unknown" ;;
 212 esac])
 213
 214 if test "$llvm_cv_target_arch" = "Unknown" ; then
 215   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 216 fi
 217
 218 dnl Define a substitution, ARCH, for the target architecture
 219 AC_SUBST(ARCH,$llvm_cv_target_arch)
 220
 221 dnl Check for the endianness of the target
 222 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 223
 224 dnl Check for build platform executable suffix if we're crosscompiling
 225 if test "$cross_compiling" = yes; then
 226   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 227   AC_BUILD_EXEEXT
 228 else
 229   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 230 fi
 231
 232 dnl Check to see if there's a "CVS" directory indicating that this build is
 233 dnl being done from a CVS checkout. This sets up several defaults for the
 234 dnl command line switches. When we build with a CVS directory, we get a
 235 dnl debug with assertions turned on. Without, we assume a source release and we
 236 dnl get an optimized build without assertions. See --enable-optimized and
 237 dnl --enable-assertions below
 238 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 239   cvsbuild="yes"
 240   optimize="no"
 241   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 242 else
 243   cvsbuild="no"
 244   optimize="yes"
 245 fi
 246
 247 dnl===-----------------------------------------------------------------------===
 248 dnl===
 249 dnl=== SECTION 3: Command line arguments for the configure script.
 250 dnl===
 251 dnl===-----------------------------------------------------------------------===
 252
 253 dnl --enable-optimized : check whether they want to do an optimized build:
 254 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 255  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 256 if test ${enableval} = "no" ; then
 257   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 258 else
 259   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 260 fi
 261
 262 dnl --enable-assertions : check whether they want to turn on assertions or not:
 263 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 264   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 265 if test ${enableval} = "yes" ; then
 266   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 267 else
 268   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 269 fi
 270
 271 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 272 AC_ARG_ENABLE(debug-runtime,
 273    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 274 if test ${enableval} = "no" ; then
 275   AC_SUBST(DEBUG_RUNTIME,[[]])
 276 else
 277   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 278 fi
 279
 280 dnl --enable-jit: check whether they want to enable the jit
 281 AC_ARG_ENABLE(jit,
 282   AS_HELP_STRING(--enable-jit,
 283                  [Enable Just In Time Compiling (default is YES)]),,
 284   enableval=default)
 285 if test ${enableval} = "no"
 286 then
 287   AC_SUBST(JIT,[[]])
 288 else
 289   case "$llvm_cv_target_arch" in
 290     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 291     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 292     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 293     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 294     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 295     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 296     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 297   esac
 298 fi
 299
 300 dnl Allow enablement of doxygen generated documentation
 301 AC_ARG_ENABLE(doxygen,
 302               AS_HELP_STRING([--enable-doxygen],
 303                              [Build doxygen documentation (default is NO)]),,
 304                              enableval=default)
 305 case "$enableval" in
 306   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 307   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 308   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 309   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 310 esac
 311
 312 dnl Allow disablement of threads
 313 AC_ARG_ENABLE(threads,
 314               AS_HELP_STRING([--enable-threads],
 315                              [Use threads if available (default is YES)]),,
 316                              enableval=default)
 317 case "$enableval" in
 318   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 319   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 320   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 321   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 322 esac
 323 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 324
 325 dnl Allow specific targets to be specified for building (or not)
 326 TARGETS_TO_BUILD=""
 327 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 328     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 329     enableval=all)
 330 case "$enableval" in
 331   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 332   host-only)
 333     case "$llvm_cv_target_arch" in
 334       x86)     TARGETS_TO_BUILD="X86" ;;
 335       x86_64)  TARGETS_TO_BUILD="X86" ;;
 336       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 337       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 338       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 339       IA64)    TARGETS_TO_BUILD="IA64" ;;
 340       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 341     esac
 342     ;;
 343   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 344       case "$a_target" in
 345         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 346         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 347         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 348         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 349         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 350         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 351         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 352       esac
 353   done
 354   ;;
 355 esac
 356 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 357 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 358
 359 dnl Prevent the CBackend from using printf("%a") for floating point so older
 360 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 361 dnl can still compile the CBE's output
 362 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 363   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 364   enableval=default)
 365 case "$enableval" in
 366   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 367   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 368   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 369   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 370 esac
 371 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 372                    [Define if CBE is enabled for printf %a output])
 373
 374 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 375 AC_ARG_WITH(llvmgccdir,
 376   AS_HELP_STRING([--with-llvmgccdir],
 377     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 378     withval=default)
 379 case "$withval" in
 380   default) WITH_LLVMGCCDIR=default ;;
 381   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 382   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 383 esac
 384
 385 dnl Specify extra build options
 386 AC_ARG_WITH(extra-options,
 387   AS_HELP_STRING([--with-extra-options],
 388                  [Specify addtional options to compile LLVM with]),,
 389                  withval=default)
 390 case "$withval" in
 391   default) EXTRA_OPTIONS= ;;
 392   *) EXTRA_OPTIONS=$withval ;;
 393 esac
 394 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 395
 396 dnl===-----------------------------------------------------------------------===
 397 dnl===
 398 dnl=== SECTION 4: Check for programs we need and that they are the right version
 399 dnl===
 400 dnl===-----------------------------------------------------------------------===
 401
 402 dnl Check for compilation tools
 403 AC_PROG_CPP
 404 AC_PROG_CC(gcc)
 405 AC_PROG_CXX(g++)
 406 AC_PROG_FLEX
 407 AC_PROG_BISON
 408
 409 AC_PROG_NM
 410 AC_SUBST(NM)
 411
 412 dnl Check for the tools that the makefiles require
 413 AC_CHECK_GNU_MAKE
 414 AC_PROG_LN_S
 415 AC_PATH_PROG(CMP, [cmp], [cmp])
 416 AC_PATH_PROG(CP, [cp], [cp])
 417 AC_PATH_PROG(DATE, [date], [date])
 418 AC_PATH_PROG(FIND, [find], [find])
 419 AC_PATH_PROG(GREP, [grep], [grep])
 420 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 421 AC_PATH_PROG(MV,   [mv],   [mv])
 422 AC_PROG_RANLIB
 423 AC_PATH_PROG(RM,   [rm],   [rm])
 424 AC_PATH_PROG(SED,  [sed],  [sed])
 425 AC_PATH_PROG(TAR,  [tar],  [gtar])
 426 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 427
 428 dnl Looking for misc. graph plotting software
 429 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 430 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 431   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 432   dnl If we're targeting for mingw we should emit windows paths, not msys
 433   if test "$llvm_cv_os_type" == "MingW" ; then
 434     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 435   fi
 436   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 437    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 438 fi
 439 AC_PATH_PROG(DOT, [dot], [echo dot])
 440 if test "$DOT" != "echo dot" ; then
 441   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 442   dnl If we're targeting for mingw we should emit windows paths, not msys
 443   if test "$llvm_cv_os_type" == "MingW" ; then
 444     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 445   fi
 446   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 447    [Define to path to dot program if found or 'echo dot' otherwise])
 448 fi
 449 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 450 if test "$GV" != "echo gv" ; then
 451   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 452   dnl If we're targeting for mingw we should emit windows paths, not msys
 453   if test "$llvm_cv_os_type" == "MingW" ; then
 454     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 455   fi
 456   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 457    [Define to path to gv program if found or 'echo gv' otherwise])
 458 fi
 459 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 460 if test "$DOTTY" != "echo dotty" ; then
 461   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 462   dnl If we're targeting for mingw we should emit windows paths, not msys
 463   if test "$llvm_cv_os_type" == "MingW" ; then
 464     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 465   fi
 466   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 467    [Define to path to dotty program if found or 'echo dotty' otherwise])
 468 fi
 469
 470 dnl Look for a sufficiently recent version of Perl.
 471 LLVM_PROG_PERL([5.006])
 472 AC_SUBST(PERL)
 473 if test x"$PERL" = xnone; then
 474    AC_SUBST(HAVE_PERL,0)
 475 else
 476    AC_SUBST(HAVE_PERL,1)
 477 fi
 478
 479 dnl Find the install program
 480 AC_PROG_INSTALL
 481
 482 dnl Checks for documentation and testing tools that we can do without. If these
 483 dnl are not found then they are set to "true" which always succeeds but does
 484 dnl nothing. This just lets the build output show that we could have done
 485 dnl something if the tool was available.
 486 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 487 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 488 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 489 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 490 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 491 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 492 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 493 DJ_AC_PATH_TCLSH
 494 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 495
 496 dnl Determine if the linker supports the -R option.
 497 AC_LINK_USE_R
 498
 499 dnl Check for libtool and the library that has dlopen function (which must come
 500 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 501 dnl libtool).
 502 AC_LIBTOOL_DLOPEN
 503 AC_LIB_LTDL
 504 AC_PROG_LIBTOOL
 505
 506 if test "$lt_cv_dlopen_self" = "yes" ; then
 507   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 508               [Define if dlopen(0) will open the symbols of the program])
 509 fi
 510
 511 dnl Check if we know how to tell etags we are using C++:
 512 etags_version=`$ETAGS --version 2>&1`
 513 case "$etags_version" in
 514         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 515         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 516         *) ETAGSFLAGS="" ;;
 517 esac
 518 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 519
 520 if test "$WITH_LLVMGCCDIR" = "default" ; then
 521   LLVMGCC="llvm-gcc${EXEEXT}"
 522   LLVMGXX="llvm-g++${EXEEXT}"
 523   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 524   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 525 else
 526   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 527   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 528   AC_SUBST(LLVMGCC,$LLVMGCC)
 529   AC_SUBST(LLVMGXX,$LLVMGXX)
 530 fi
 531
 532 AC_MSG_CHECKING([tool compatibility])
 533
 534 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 535 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 536 dnl to support those options.
 537 dnl "icc" emits gcc signatures
 538 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 539 ICC=no
 540 IXX=no
 541 case $CC in
 542   icc*|icpc*)
 543     ICC=yes
 544     IXX=yes
 545     ;;
 546    *)
 547     ;;
 548 esac
 549
 550 if test "$GCC" != "yes" && test "$ICC" != "yes"
 551 then
 552   AC_MSG_ERROR([gcc|icc required but not found])
 553 fi
 554
 555 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 556 if test "$GXX" != "yes" && test "$IXX" != "yes"
 557 then
 558   AC_MSG_ERROR([g++|icc required but not found])
 559 fi
 560
 561 dnl Verify that GCC is version 3.0 or higher
 562 if test "$GCC" = "yes"
 563 then
 564   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 565   if test "$gccmajor" -lt "3"
 566   then
 567     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 568   fi
 569 fi
 570
 571 dnl Check for GNU Make.  We use its extensions, so don't build without it
 572 if test -z "$llvm_cv_gnu_make_command"
 573 then
 574   AC_MSG_ERROR([GNU Make required but not found])
 575 fi
 576
 577 dnl Tool compatibility is okay if we make it here.
 578 AC_MSG_RESULT([ok])
 579
 580 dnl===-----------------------------------------------------------------------===
 581 dnl===
 582 dnl=== SECTION 5: Check for libraries
 583 dnl===
 584 dnl===-----------------------------------------------------------------------===
 585
 586 dnl libelf is for sparc only; we can ignore it if we don't have it
 587 AC_CHECK_LIB(elf, elf_begin)
 588 AC_CHECK_LIB(m,sin)
 589 if test "$llvm_cv_os_type" == "MingW" ; then
 590   AC_CHECK_LIB(imagehlp, main)
 591   AC_CHECK_LIB(psapi, main)
 592 fi
 593
 594 dnl lt_dlopen may be required for plugin support.
 595 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 596               [Define if lt_dlopen() is available on this platform]),
 597               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 598                            not be available]))
 599
 600 dnl dlopen() is required for plugin support.
 601 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 602                [Define if dlopen() is available on this platform.]),
 603                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 604
 605 dnl mallinfo is optional; the code can compile (minus features) without it
 606 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 607                [Define if mallinfo() is available on this platform.]))
 608
 609 dnl pthread locking functions are optional - but llvm will not be thread-safe
 610 dnl without locks.
 611 if test "$ENABLE_THREADS" -eq 1 ; then
 612   AC_CHECK_LIB(pthread,pthread_mutex_init)
 613   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 614                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 615                            [Have pthread_mutex_lock]))
 616 fi
 617
 618 dnl===-----------------------------------------------------------------------===
 619 dnl===
 620 dnl=== SECTION 6: Check for header files
 621 dnl===
 622 dnl===-----------------------------------------------------------------------===
 623
 624 dnl First, use autoconf provided macros for specific headers that we need
 625 dnl We don't check for ancient stuff or things that are guaranteed to be there
 626 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 627 dnl Generally we're looking for POSIX headers.
 628 AC_HEADER_DIRENT
 629 AC_HEADER_MMAP_ANONYMOUS
 630 AC_HEADER_STAT
 631 AC_HEADER_STDC
 632 AC_HEADER_SYS_WAIT
 633 AC_HEADER_TIME
 634
 635 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 636 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 637 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 638 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 639 if test "$ENABLE_THREADS" -eq 1 ; then
 640   AC_CHECK_HEADERS(pthread.h)
 641 fi
 642
 643 dnl===-----------------------------------------------------------------------===
 644 dnl===
 645 dnl=== SECTION 7: Check for types and structures
 646 dnl===
 647 dnl===-----------------------------------------------------------------------===
 648
 649 AC_HUGE_VAL_CHECK
 650 AC_TYPE_PID_T
 651 AC_TYPE_SIZE_T
 652 AC_TYPE_SIGNAL
 653 AC_STRUCT_TM
 654 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 655 AC_CHECK_TYPES([uint64_t],,
 656          AC_CHECK_TYPES([u_int64_t],,
 657          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 658
 659 dnl===-----------------------------------------------------------------------===
 660 dnl===
 661 dnl=== SECTION 8: Check for specific functions needed
 662 dnl===
 663 dnl===-----------------------------------------------------------------------===
 664
 665 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 666 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 667 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 668 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 669 AC_CHECK_FUNCS([_setjmp _longjmp setjmp longjmp sigsetjmp siglongjmp])
 670 AC_C_PRINTF_A
 671 AC_FUNC_ALLOCA
 672 AC_FUNC_RAND48
 673
 674 dnl Check for variations in the Standard C++ library and STL. These macros are
 675 dnl provided by LLVM in the autoconf/m4 directory.
 676 AC_CXX_HAVE_HASH_MAP
 677 AC_CXX_HAVE_HASH_SET
 678 AC_CXX_HAVE_STD_ITERATOR
 679 AC_CXX_HAVE_BI_ITERATOR
 680 AC_CXX_HAVE_FWD_ITERATOR
 681 AC_FUNC_ISNAN
 682 AC_FUNC_ISINF
 683
 684 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 685 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 686 dnl be opened for allocating RWX memory.
 687 AC_FUNC_MMAP
 688 AC_FUNC_MMAP_FILE
 689 AC_NEED_DEV_ZERO_FOR_MMAP
 690 AC_CHECK_FUNC(mprotect,,
 691               AC_MSG_ERROR([Function mprotect() required but not found]))
 692
 693 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 694 then
 695   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 696 fi
 697 if test "$ac_cv_func_mmap_file" = "no"
 698 then
 699   AC_MSG_WARN([mmap() of files required but not found])
 700 fi
 701
 702 dnl===-----------------------------------------------------------------------===
 703 dnl===
 704 dnl=== SECTION 9: Additional checks, variables, etc.
 705 dnl===
 706 dnl===-----------------------------------------------------------------------===
 707
 708 dnl See if the llvm-gcc executable can compile to LLVM assembly
 709 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 710 [llvm_cv_llvmgcc_sanity="no"
 711 if test -x "$LLVMGCC" ; then
 712   cp /dev/null conftest.c
 713   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 714   if test $? -eq 0 ; then
 715     llvm_cv_llvmgcc_sanity="yes"
 716   fi
 717   rm conftest.c
 718 fi])
 719
 720 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 721 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 722   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 723   AC_SUBST(LLVMCC1,$llvmcc1path)
 724   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 725   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 726   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 727   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 728   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 729   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 730   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 731   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 732 fi
 733
 734 dnl Propagate the shared library extension that the libltdl checks did to
 735 dnl the Makefiles so we can use it there too
 736 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 737
 738 # Translate the various configuration directories and other basic
 739 # information into substitutions that will end up in Makefile.config.in
 740 # that these configured values can be used by the makefiles
 741 if test "${prefix}" == "NONE" ; then
 742   prefix="/usr/local"
 743 fi
 744 eval LLVM_PREFIX="${prefix}";
 745 eval LLVM_BINDIR="${prefix}/bin";
 746 eval LLVM_LIBDIR="${prefix}/lib";
 747 eval LLVM_DATADIR="${prefix}/share/llvm";
 748 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 749 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 750 eval LLVM_INCLUDEDIR="${prefix}/include";
 751 eval LLVM_INFODIR="${prefix}/info";
 752 eval LLVM_MANDIR="${prefix}/man";
 753 LLVM_CONFIGTIME=`date`
 754 AC_SUBST(LLVM_PREFIX)
 755 AC_SUBST(LLVM_BINDIR)
 756 AC_SUBST(LLVM_LIBDIR)
 757 AC_SUBST(LLVM_DATADIR)
 758 AC_SUBST(LLVM_DOCSDIR)
 759 AC_SUBST(LLVM_ETCDIR)
 760 AC_SUBST(LLVM_INCLUDEDIR)
 761 AC_SUBST(LLVM_INFODIR)
 762 AC_SUBST(LLVM_MANDIR)
 763 AC_SUBST(LLVM_CONFIGTIME)
 764
 765 # Place the various directores into the config.h file as #defines so that we
 766 # can know about the installation paths within LLVM.
 767 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 768                    [Installation prefix directory])
 769 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 770                    [Installation directory for binary executables])
 771 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 772                    [Installation directory for libraries])
 773 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 774                    [Installation directory for data files])
 775 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 776                    [Installation directory for documentation])
 777 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 778                    [Installation directory for config files])
 779 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 780                    [Installation directory for include files])
 781 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 782                    [Installation directory for .info files])
 783 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 784                    [Installation directory for man pages])
 785 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 786                    [Time at which LLVM was configured])
 787
 788 dnl===-----------------------------------------------------------------------===
 789 dnl===
 790 dnl=== SECTION 10: Specify the output files and generate it
 791 dnl===
 792 dnl===-----------------------------------------------------------------------===
 793
 794 dnl Configure header files
 795 dnl WARNING: dnl If you add or remove any of the following config headers, then
 796 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 797 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 798 dnl files can be updated automatically when their *.in sources change.
 799 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 800 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 801 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 802 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 803 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 804
 805 dnl Configure the makefile's configuration data
 806 AC_CONFIG_FILES([Makefile.config])
 807
 808 dnl Configure the RPM spec file for LLVM
 809 AC_CONFIG_FILES([llvm.spec])
 810
 811 dnl Configure doxygen's configuration file
 812 AC_CONFIG_FILES([docs/doxygen.cfg])
 813
 814 dnl Do the first stage of configuration for llvm-config.in.
 815 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 816
 817 dnl Do special configuration of Makefiles
 818 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 819 AC_CONFIG_MAKEFILE(Makefile)
 820 AC_CONFIG_MAKEFILE(Makefile.common)
 821 AC_CONFIG_MAKEFILE(examples/Makefile)
 822 AC_CONFIG_MAKEFILE(lib/Makefile)
 823 AC_CONFIG_MAKEFILE(runtime/Makefile)
 824 AC_CONFIG_MAKEFILE(test/Makefile)
 825 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 826 AC_CONFIG_MAKEFILE(tools/Makefile)
 827 AC_CONFIG_MAKEFILE(utils/Makefile)
 828 AC_CONFIG_MAKEFILE(projects/Makefile)
 829
 830 dnl Finally, crank out the output
 831 AC_OUTPUT
 832
 833 dnl Warn loudly if llvm-gcc was not obviously working
 834 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 835  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 836  AC_MSG_WARN([***** working. Please make sure you have llvm-gcc and llvm-g++ in])
 837  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 838  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 839  AC_MSG_WARN([***** build the llvm tools.])
 840 fi