autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.9cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "privbracket")  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  73       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_link_all_option="-Wl,--whole-archive"
 106     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 107     llvm_cv_os_type="AIX"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-irix*)
 110     llvm_cv_link_all_option="-Wl,--whole-archive"
 111     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 112     llvm_cv_os_type="IRIX"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-cygwin*)
 115     llvm_cv_link_all_option="-Wl,--whole-archive"
 116     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 117     llvm_cv_os_type="Cygwin"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-darwin*)
 120     llvm_cv_link_all_option="-Wl,-all_load"
 121     llvm_cv_link_all_option="-Wl,-noall_load"
 122     llvm_cv_os_type="Darwin"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-freebsd*)
 125     llvm_cv_link_all_option="-Wl,--whole-archive"
 126     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 127     llvm_cv_os_type="FreeBSD"
 128     llvm_cv_platform_type="Unix" ;;
 129   *-*-openbsd*)
 130     llvm_cv_link_all_option="-Wl,--whole-archive"
 131     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 132     llvm_cv_os_type="OpenBSD"
 133     llvm_cv_platform_type="Unix" ;;
 134   *-*-hpux*)
 135     llvm_cv_link_all_option="-Wl,--whole-archive"
 136     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 137     llvm_cv_os_type="HP-UX"
 138     llvm_cv_platform_type="Unix" ;;
 139   *-*-interix*)
 140     llvm_cv_link_all_option="-Wl,--whole-archive"
 141     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 142     llvm_cv_os_type="Interix"
 143     llvm_cv_platform_type="Unix" ;;
 144   *-*-linux*)
 145     llvm_cv_link_all_option="-Wl,--whole-archive"
 146     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 147     llvm_cv_os_type="Linux"
 148     llvm_cv_platform_type="Unix" ;;
 149   *-*-solaris*)
 150     llvm_cv_link_all_option="-Wl,-z,allextract"
 151     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 152     llvm_cv_os_type="SunOS"
 153     llvm_cv_platform_type="Unix" ;;
 154   *-*-win32*)
 155     llvm_cv_link_all_option="-Wl,--whole-archive"
 156     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 157     llvm_cv_os_type="Win32"
 158     llvm_cv_platform_type="Win32" ;;
 159   *-*-mingw*)
 160     llvm_cv_link_all_option="-Wl,--whole-archive"
 161     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 162     llvm_cv_os_type="MingW"
 163     llvm_cv_platform_type="Win32" ;;
 164   *)
 165     llvm_cv_link_all_option=""
 166     llvm_cv_no_link_all_option=""
 167     llvm_cv_os_type="Unknown"
 168     llvm_cv_platform_type="Unknown" ;;
 169 esac])
 170
 171 dnl Make sure we aren't attempting to configure for an unknown system
 172 if test "$llvm_cv_os_type" = "Unknown" ; then
 173   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 174 fi
 175
 176 dnl Set the "OS" Makefile variable based on the platform type so the
 177 dnl makefile can configure itself to specific build hosts
 178 AC_SUBST(OS,$llvm_cv_os_type)
 179
 180 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 181 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 182 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 183
 184 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 185 dnl This is used by lib/System to determine the basic kind of implementation
 186 dnl to use.
 187 case $llvm_cv_platform_type in
 188   Unix)
 189     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 190     AC_SUBST(LLVM_ON_UNIX,[1])
 191     AC_SUBST(LLVM_ON_WIN32,[0])
 192     ;;
 193   Win32)
 194     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 195     AC_SUBST(LLVM_ON_UNIX,[0])
 196     AC_SUBST(LLVM_ON_WIN32,[1])
 197     ;;
 198 esac
 199
 200 dnl Determine what our target architecture is and configure accordingly.
 201 dnl This will allow Makefiles to make a distinction between the hardware and
 202 dnl the OS.
 203 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 204 [case $target in
 205   i?86-*)                 llvm_cv_target_arch="x86" ;;
 206   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 207   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 208   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 209   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 210   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 211   *)                      llvm_cv_target_arch="Unknown" ;;
 212 esac])
 213
 214 if test "$llvm_cv_target_arch" = "Unknown" ; then
 215   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 216 fi
 217
 218 dnl Define a substitution, ARCH, for the target architecture
 219 AC_SUBST(ARCH,$llvm_cv_target_arch)
 220
 221 dnl Check for the endianness of the target
 222 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 223
 224 dnl Check for build platform executable suffix if we're crosscompiling
 225 if test "$cross_compiling" = yes; then
 226   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 227   AC_BUILD_EXEEXT
 228 else
 229   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 230 fi
 231
 232 dnl Check to see if there's a "CVS" directory indicating that this build is
 233 dnl being done from a CVS checkout. This sets up several defaults for the
 234 dnl command line switches. When we build with a CVS directory, we get a
 235 dnl debug with assertions turned on. Without, we assume a source release and we
 236 dnl get an optimized build without assertions. See --enable-optimized and
 237 dnl --enable-assertions below
 238 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 239   cvsbuild="yes"
 240   optimize="no"
 241   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 242 else
 243   cvsbuild="no"
 244   optimize="yes"
 245 fi
 246
 247 dnl===-----------------------------------------------------------------------===
 248 dnl===
 249 dnl=== SECTION 3: Command line arguments for the configure script.
 250 dnl===
 251 dnl===-----------------------------------------------------------------------===
 252
 253 dnl --enable-optimized : check whether they want to do an optimized build:
 254 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 255  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 256 if test ${enableval} = "no" ; then
 257   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 258 else
 259   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 260 fi
 261
 262 dnl --enable-assertions : check whether they want to turn on assertions or not:
 263 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 264   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 265 if test ${enableval} = "yes" ; then
 266   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 267 else
 268   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 269 fi
 270
 271 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 272 AC_ARG_ENABLE(debug-runtime,
 273    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 274 if test ${enableval} = "no" ; then
 275   AC_SUBST(DEBUG_RUNTIME,[[]])
 276 else
 277   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 278 fi
 279
 280 dnl --enable-jit: check whether they want to enable the jit
 281 AC_ARG_ENABLE(jit,
 282   AS_HELP_STRING(--enable-jit,
 283                  [Enable Just In Time Compiling (default is YES)]),,
 284   enableval=default)
 285 if test ${enableval} = "no"
 286 then
 287   AC_SUBST(JIT,[[]])
 288 else
 289   case "$llvm_cv_target_arch" in
 290     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 291     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 292     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 293     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 294     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 295     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 296     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 297   esac
 298 fi
 299
 300 dnl Allow enablement of doxygen generated documentation
 301 AC_ARG_ENABLE(doxygen,
 302               AS_HELP_STRING([--enable-doxygen],
 303                              [Build doxygen documentation (default is NO)]),,
 304                              enableval=default)
 305 case "$enableval" in
 306   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 307   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 308   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 309   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 310 esac
 311
 312 dnl Allow disablement of threads
 313 AC_ARG_ENABLE(threads,
 314               AS_HELP_STRING([--enable-threads],
 315                              [Use threads if available (default is YES)]),,
 316                              enableval=yes)
 317 case "$enableval" in
 318   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 319   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 320   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 321 esac
 322 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 323
 324 dnl Allow specific targets to be specified for building (or not)
 325 TARGETS_TO_BUILD=""
 326 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 327     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 328     enableval=all)
 329 case "$enableval" in
 330   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 331   host-only)
 332     case "$llvm_cv_target_arch" in
 333       x86)     TARGETS_TO_BUILD="X86" ;;
 334       x86_64)  TARGETS_TO_BUILD="X86" ;;
 335       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 336       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 337       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 338       IA64)    TARGETS_TO_BUILD="IA64" ;;
 339       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 340     esac
 341     ;;
 342   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 343       case "$a_target" in
 344         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 345         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 346         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 347         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 348         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 349         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 350         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 351       esac
 352   done
 353   ;;
 354 esac
 355 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 356 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 357
 358 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 359 AC_ARG_WITH(llvmgccdir,
 360   AS_HELP_STRING([--with-llvmgccdir],
 361     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 362     withval=default)
 363 case "$withval" in
 364   default) WITH_LLVMGCCDIR=default ;;
 365   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 366   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 367 esac
 368
 369 dnl Specify extra build options
 370 AC_ARG_WITH(extra-options,
 371   AS_HELP_STRING([--with-extra-options],
 372                  [Specify addtional options to compile LLVM with]),,
 373                  withval=default)
 374 case "$withval" in
 375   default) EXTRA_OPTIONS= ;;
 376   *) EXTRA_OPTIONS=$withval ;;
 377 esac
 378 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 379
 380 dnl===-----------------------------------------------------------------------===
 381 dnl===
 382 dnl=== SECTION 4: Check for programs we need and that they are the right version
 383 dnl===
 384 dnl===-----------------------------------------------------------------------===
 385
 386 dnl Check for compilation tools
 387 AC_PROG_CPP
 388 AC_PROG_CC(gcc)
 389 AC_PROG_CXX(g++)
 390 AC_PROG_FLEX
 391 AC_PROG_BISON
 392
 393 AC_PROG_NM
 394 AC_SUBST(NM)
 395
 396 dnl Check for the tools that the makefiles require
 397 AC_CHECK_GNU_MAKE
 398 AC_PROG_LN_S
 399 AC_PATH_PROG(CMP, [cmp], [cmp])
 400 AC_PATH_PROG(CP, [cp], [cp])
 401 AC_PATH_PROG(DATE, [date], [date])
 402 AC_PATH_PROG(FIND, [find], [find])
 403 AC_PATH_PROG(GREP, [grep], [grep])
 404 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 405 AC_PATH_PROG(MV,   [mv],   [mv])
 406 AC_PROG_RANLIB
 407 AC_PATH_PROG(RM,   [rm],   [rm])
 408 AC_PATH_PROG(SED,  [sed],  [sed])
 409 AC_PATH_PROG(TAR,  [tar],  [gtar])
 410 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 411
 412 dnl Looking for misc. graph plotting software
 413 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 414 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 415   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 416   dnl If we're targeting for mingw we should emit windows paths, not msys
 417   if test "$llvm_cv_os_type" == "MingW" ; then
 418     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 419   fi
 420   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 421    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 422 fi
 423 AC_PATH_PROG(DOT, [dot], [echo dot])
 424 if test "$DOT" != "echo dot" ; then
 425   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 426   dnl If we're targeting for mingw we should emit windows paths, not msys
 427   if test "$llvm_cv_os_type" == "MingW" ; then
 428     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 429   fi
 430   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 431    [Define to path to dot program if found or 'echo dot' otherwise])
 432 fi
 433 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 434 if test "$GV" != "echo gv" ; then
 435   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 436   dnl If we're targeting for mingw we should emit windows paths, not msys
 437   if test "$llvm_cv_os_type" == "MingW" ; then
 438     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 439   fi
 440   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 441    [Define to path to gv program if found or 'echo gv' otherwise])
 442 fi
 443 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 444 if test "$DOTTY" != "echo dotty" ; then
 445   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 446   dnl If we're targeting for mingw we should emit windows paths, not msys
 447   if test "$llvm_cv_os_type" == "MingW" ; then
 448     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 449   fi
 450   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 451    [Define to path to dotty program if found or 'echo dotty' otherwise])
 452 fi
 453
 454 dnl Look for a sufficiently recent version of Perl.
 455 LLVM_PROG_PERL([5.006])
 456 AC_SUBST(PERL)
 457 if test x"$PERL" = xnone; then
 458    AC_SUBST(HAVE_PERL,0)
 459 else
 460    AC_SUBST(HAVE_PERL,1)
 461 fi
 462
 463 dnl Find the install program
 464 AC_PROG_INSTALL
 465
 466 dnl Checks for documentation and testing tools that we can do without. If these
 467 dnl are not found then they are set to "true" which always succeeds but does
 468 dnl nothing. This just lets the build output show that we could have done
 469 dnl something if the tool was available.
 470 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 471 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 472 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 473 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 474 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 475 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 476 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 477 DJ_AC_PATH_TCLSH
 478 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 479
 480 dnl Determine if the linker supports the -R option.
 481 AC_LINK_USE_R
 482
 483 dnl Check for libtool and the library that has dlopen function (which must come
 484 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 485 dnl libtool).
 486 AC_LIBTOOL_DLOPEN
 487 AC_LIB_LTDL
 488 AC_PROG_LIBTOOL
 489
 490 if test "$lt_cv_dlopen_self" = "yes" ; then
 491   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 492               [Define if dlopen(0) will open the symbols of the program])
 493 fi
 494
 495 dnl Check if we know how to tell etags we are using C++:
 496 etags_version=`$ETAGS --version 2>&1`
 497 case "$etags_version" in
 498         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 499         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 500         *) ETAGSFLAGS="" ;;
 501 esac
 502 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 503
 504 if test "$WITH_LLVMGCCDIR" = "default" ; then
 505   LLVMGCC="llvm-gcc${EXEEXT}"
 506   LLVMGXX="llvm-g++${EXEEXT}"
 507   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 508   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 509 else
 510   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 511   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 512   AC_SUBST(LLVMGCC,$LLVMGCC)
 513   AC_SUBST(LLVMGXX,$LLVMGXX)
 514 fi
 515
 516 AC_MSG_CHECKING([tool compatibility])
 517
 518 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 519 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 520 dnl to support those options.
 521 dnl "icc" emits gcc signatures
 522 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 523 ICC=no
 524 IXX=no
 525 case $CC in
 526   icc*|icpc*)
 527     ICC=yes
 528     IXX=yes
 529     ;;
 530    *)
 531     ;;
 532 esac
 533
 534 if test "$GCC" != "yes" && test "$ICC" != "yes"
 535 then
 536   AC_MSG_ERROR([gcc|icc required but not found])
 537 fi
 538
 539 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 540 if test "$GXX" != "yes" && test "$IXX" != "yes"
 541 then
 542   AC_MSG_ERROR([g++|icc required but not found])
 543 fi
 544
 545 dnl Verify that GCC is version 3.0 or higher
 546 if test "$GCC" = "yes"
 547 then
 548   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 549   if test "$gccmajor" -lt "3"
 550   then
 551     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 552   fi
 553 fi
 554
 555 dnl Check for GNU Make.  We use its extensions, so don't build without it
 556 if test -z "$llvm_cv_gnu_make_command"
 557 then
 558   AC_MSG_ERROR([GNU Make required but not found])
 559 fi
 560
 561 dnl Tool compatibility is okay if we make it here.
 562 AC_MSG_RESULT([ok])
 563
 564 dnl===-----------------------------------------------------------------------===
 565 dnl===
 566 dnl=== SECTION 5: Check for libraries
 567 dnl===
 568 dnl===-----------------------------------------------------------------------===
 569
 570 dnl libelf is for sparc only; we can ignore it if we don't have it
 571 AC_CHECK_LIB(elf, elf_begin)
 572 AC_CHECK_LIB(m,sin)
 573 if test "$llvm_cv_os_type" == "MingW" ; then
 574   AC_CHECK_LIB(imagehlp, main)
 575   AC_CHECK_LIB(psapi, main)
 576 fi
 577
 578 dnl lt_dlopen may be required for plugin support.
 579 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 580               [Define if lt_dlopen() is available on this platform]),
 581               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 582                            not be available]))
 583
 584 dnl dlopen() is required for plugin support.
 585 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 586                [Define if dlopen() is available on this platform.]),
 587                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 588
 589 dnl mallinfo is optional; the code can compile (minus features) without it
 590 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 591                [Define if mallinfo() is available on this platform.]))
 592
 593 dnl pthread locking functions are optional - but llvm will not be thread-safe
 594 dnl without locks.
 595 if test "$ENABLE_THREADS" -eq 1 ; then
 596   AC_CHECK_LIB(pthread,pthread_mutex_init)
 597   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 598                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 599                            [Have pthread_mutex_lock]))
 600 fi
 601
 602 dnl===-----------------------------------------------------------------------===
 603 dnl===
 604 dnl=== SECTION 6: Check for header files
 605 dnl===
 606 dnl===-----------------------------------------------------------------------===
 607
 608 dnl First, use autoconf provided macros for specific headers that we need
 609 dnl We don't check for ancient stuff or things that are guaranteed to be there
 610 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 611 dnl Generally we're looking for POSIX headers.
 612 AC_HEADER_DIRENT
 613 AC_HEADER_MMAP_ANONYMOUS
 614 AC_HEADER_STAT
 615 AC_HEADER_STDC
 616 AC_HEADER_SYS_WAIT
 617 AC_HEADER_TIME
 618
 619 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 620 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 621 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 622 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 623 if test "$ENABLE_THREADS" -eq 1 ; then
 624   AC_CHECK_HEADERS(pthread.h)
 625 fi
 626
 627 dnl===-----------------------------------------------------------------------===
 628 dnl===
 629 dnl=== SECTION 7: Check for types and structures
 630 dnl===
 631 dnl===-----------------------------------------------------------------------===
 632
 633 AC_TYPE_PID_T
 634 AC_TYPE_SIZE_T
 635 AC_TYPE_SIGNAL
 636 AC_STRUCT_TM
 637 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 638 AC_CHECK_TYPES([uint64_t],,
 639          AC_CHECK_TYPES([u_int64_t],,
 640          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 641
 642 dnl===-----------------------------------------------------------------------===
 643 dnl===
 644 dnl=== SECTION 8: Check for specific functions needed
 645 dnl===
 646 dnl===-----------------------------------------------------------------------===
 647
 648 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 649 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 650 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 651 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 652 AC_CHECK_FUNCS([_setjmp _longjmp setjmp longjmp sigsetjmp siglongjmp])
 653 AC_C_PRINTF_A
 654 AC_FUNC_ALLOCA
 655 AC_FUNC_RAND48
 656
 657 dnl Check for variations in the Standard C++ library and STL. These macros are
 658 dnl provided by LLVM in the autoconf/m4 directory.
 659 AC_CXX_HAVE_HASH_MAP
 660 AC_CXX_HAVE_HASH_SET
 661 AC_CXX_HAVE_STD_ITERATOR
 662 AC_CXX_HAVE_BI_ITERATOR
 663 AC_CXX_HAVE_FWD_ITERATOR
 664 AC_FUNC_ISNAN
 665 AC_FUNC_ISINF
 666
 667 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 668 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 669 dnl be opened for allocating RWX memory.
 670 AC_FUNC_MMAP
 671 AC_FUNC_MMAP_FILE
 672 AC_NEED_DEV_ZERO_FOR_MMAP
 673 AC_CHECK_FUNC(mprotect,,
 674               AC_MSG_ERROR([Function mprotect() required but not found]))
 675
 676 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 677 then
 678   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 679 fi
 680 if test "$ac_cv_func_mmap_file" = "no"
 681 then
 682   AC_MSG_WARN([mmap() of files required but not found])
 683 fi
 684
 685 dnl===-----------------------------------------------------------------------===
 686 dnl===
 687 dnl=== SECTION 9: Additional checks, variables, etc.
 688 dnl===
 689 dnl===-----------------------------------------------------------------------===
 690
 691 dnl See if the llvm-gcc executable can compile to LLVM assembly
 692 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 693 [llvm_cv_llvmgcc_sanity="no"
 694 if test -x "$LLVMGCC" ; then
 695   cp /dev/null conftest.c
 696   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 697   if test $? -eq 0 ; then
 698     llvm_cv_llvmgcc_sanity="yes"
 699   fi
 700   rm conftest.c
 701 fi])
 702
 703 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 704 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 705   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 706   AC_SUBST(LLVMCC1,$llvmcc1path)
 707   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 708   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 709   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 710   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 711   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 712   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 713   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 714   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 715 fi
 716
 717 dnl Propagate the shared library extension that the libltdl checks did to
 718 dnl the Makefiles so we can use it there too
 719 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 720
 721 # Translate the various configuration directories and other basic
 722 # information into substitutions that will end up in Makefile.config.in
 723 # that these configured values can be used by the makefiles
 724 if test "${prefix}" == "NONE" ; then
 725   prefix="/usr/local"
 726 fi
 727 eval LLVM_PREFIX="${prefix}";
 728 eval LLVM_BINDIR="${prefix}/bin";
 729 eval LLVM_LIBDIR="${prefix}/lib";
 730 eval LLVM_DATADIR="${prefix}/share/llvm";
 731 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 732 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 733 eval LLVM_INCLUDEDIR="${prefix}/include";
 734 eval LLVM_INFODIR="${prefix}/info";
 735 eval LLVM_MANDIR="${prefix}/man";
 736 LLVM_CONFIGTIME=`date`
 737 AC_SUBST(LLVM_PREFIX)
 738 AC_SUBST(LLVM_BINDIR)
 739 AC_SUBST(LLVM_LIBDIR)
 740 AC_SUBST(LLVM_DATADIR)
 741 AC_SUBST(LLVM_DOCSDIR)
 742 AC_SUBST(LLVM_ETCDIR)
 743 AC_SUBST(LLVM_INCLUDEDIR)
 744 AC_SUBST(LLVM_INFODIR)
 745 AC_SUBST(LLVM_MANDIR)
 746 AC_SUBST(LLVM_CONFIGTIME)
 747
 748 # Place the various directores into the config.h file as #defines so that we
 749 # can know about the installation paths within LLVM.
 750 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 751                    [Installation prefix directory])
 752 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 753                    [Installation directory for binary executables])
 754 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 755                    [Installation directory for libraries])
 756 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 757                    [Installation directory for data files])
 758 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 759                    [Installation directory for documentation])
 760 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 761                    [Installation directory for config files])
 762 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 763                    [Installation directory for include files])
 764 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 765                    [Installation directory for .info files])
 766 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 767                    [Installation directory for man pages])
 768 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 769                    [Time at which LLVM was configured])
 770
 771 dnl===-----------------------------------------------------------------------===
 772 dnl===
 773 dnl=== SECTION 10: Specify the output files and generate it
 774 dnl===
 775 dnl===-----------------------------------------------------------------------===
 776
 777 dnl Configure header files
 778 dnl WARNING: dnl If you add or remove any of the following config headers, then
 779 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 780 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 781 dnl files can be updated automatically when their *.in sources change.
 782 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 783 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 784 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 785 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 786 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 787
 788 dnl Configure the makefile's configuration data
 789 AC_CONFIG_FILES([Makefile.config])
 790
 791 dnl Configure the RPM spec file for LLVM
 792 AC_CONFIG_FILES([llvm.spec])
 793
 794 dnl Configure doxygen's configuration file
 795 AC_CONFIG_FILES([docs/doxygen.cfg])
 796
 797 dnl Do the first stage of configuration for llvm-config.in.
 798 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 799
 800 dnl Do special configuration of Makefiles
 801 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 802 AC_CONFIG_MAKEFILE(Makefile)
 803 AC_CONFIG_MAKEFILE(Makefile.common)
 804 AC_CONFIG_MAKEFILE(examples/Makefile)
 805 AC_CONFIG_MAKEFILE(lib/Makefile)
 806 AC_CONFIG_MAKEFILE(runtime/Makefile)
 807 AC_CONFIG_MAKEFILE(test/Makefile)
 808 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 809 AC_CONFIG_MAKEFILE(tools/Makefile)
 810 AC_CONFIG_MAKEFILE(utils/Makefile)
 811 AC_CONFIG_MAKEFILE(projects/Makefile)
 812
 813 dnl Finally, crank out the output
 814 AC_OUTPUT
 815
 816 dnl Warn loudly if llvm-gcc was not obviously working
 817 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 818  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 819  AC_MSG_WARN([***** working. Please make sure you have llvm-gcc and llvm-g++ in])
 820  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 821  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 822  AC_MSG_WARN([***** build the llvm tools.])
 823 fi