autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.7.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=7
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45 AC_DEFINE_UNQUOTED([LLVM_VERSION_STRING], "$PACKAGE_VERSION", [LLVM version string])
  46
  47 AC_SUBST([LLVM_VERSION_MAJOR])
  48 AC_SUBST([LLVM_VERSION_MINOR])
  49 AC_SUBST([LLVM_VERSION_PATCH])
  50 AC_SUBST([LLVM_VERSION_SUFFIX])
  51
  52 dnl Provide a copyright substitution and ensure the copyright notice is included
  53 dnl in the output of --version option of the generated configure script.
  54 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign."])
  55 AC_COPYRIGHT([Copyright (c) 2003-2015 University of Illinois at Urbana-Champaign.])
  56
  57 dnl Indicate that we require autoconf 2.60 or later.
  58 AC_PREREQ(2.60)
  59
  60 dnl Verify that the source directory is valid. This makes sure that we are
  61 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  62 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  63
  64 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  65 dnl various tools where the m4 autoconf macros are.
  66 AC_CONFIG_AUX_DIR([autoconf])
  67
  68 dnl Quit if the source directory has already been configured.
  69 dnl NOTE: This relies upon undocumented autoconf behavior.
  70 if test ${srcdir} != "." ; then
  71   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  72     AC_MSG_ERROR([Already configured in ${srcdir}])
  73   fi
  74 fi
  75
  76 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  77 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  78 : ${CFLAGS=}
  79 : ${CXXFLAGS=}
  80
  81 dnl We need to check for the compiler up here to avoid anything else
  82 dnl starting with a different one.
  83 AC_PROG_CC(clang gcc)
  84 AC_PROG_CXX(clang++ g++)
  85 AC_PROG_CPP
  86
  87 dnl If CXX is Clang, check that it can find and parse C++ standard library
  88 dnl headers.
  89 if test "$CXX" = "clang++" ; then
  90   AC_MSG_CHECKING([whether clang works])
  91   AC_LANG_PUSH([C++])
  92   dnl Note that space between 'include' and '(' is required.  There's a broken
  93   dnl regex in aclocal that otherwise will think that we call m4's include
  94   dnl builtin.
  95   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  96 #if __has_include (<cxxabi.h>)
  97 #include <cxxabi.h>
  98 #endif
  99 #if __has_include (<unwind.h>)
 100 #include <unwind.h>
 101 #endif
 102 ]])],
 103 [
 104   AC_MSG_RESULT([yes])
 105 ],
 106 [
 107   AC_MSG_RESULT([no])
 108   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
 109 ])
 110   AC_LANG_POP([C++])
 111 fi
 112
 113 dnl Set up variables that track whether the host compiler is GCC or Clang where
 114 dnl we can effectively sanity check them. We don't try to sanity check all the
 115 dnl other possible compilers.
 116 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 117 AC_LANG_PUSH([C++])
 118 llvm_cv_cxx_compiler=unknown
 119 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 120                                     #error
 121                                     #endif
 122                                     ]])],
 123                   llvm_cv_cxx_compiler=clang,
 124                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 125                                                        #error
 126                                                        #endif
 127                                                        ]])],
 128                                      llvm_cv_cxx_compiler=gcc, [])])
 129 AC_LANG_POP([C++])
 130 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 131
 132 dnl Configure all of the projects present in our source tree. While we could
 133 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 134 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 135 dnl Instead we match on the known projects.
 136
 137 dnl
 138 dnl One tricky part of doing this is that some projects depend upon other
 139 dnl projects.  For example, several projects rely upon the LLVM test suite.
 140 dnl We want to configure those projects first so that their object trees are
 141 dnl created before running the configure scripts of projects that depend upon
 142 dnl them.
 143 dnl
 144
 145 dnl Several projects use the LLVM test suite, so configure it next.
 146 if test -d ${srcdir}/projects/test-suite ; then
 147   AC_CONFIG_SUBDIRS([projects/test-suite])
 148 fi
 149
 150 dnl llvm-test is the old name of the test-suite, kept here for backwards
 151 dnl compatibility
 152 if test -d ${srcdir}/projects/llvm-test ; then
 153   AC_CONFIG_SUBDIRS([projects/llvm-test])
 154 fi
 155
 156 dnl Some projects use poolalloc; configure that next
 157 if test -d ${srcdir}/projects/poolalloc ; then
 158   AC_CONFIG_SUBDIRS([projects/poolalloc])
 159 fi
 160
 161 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 162   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 163 fi
 164
 165 dnl Check for all other projects
 166 for i in `ls ${srcdir}/projects`
 167 do
 168   if test -d ${srcdir}/projects/${i} ; then
 169     case ${i} in
 170       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 171       compiler-rt)       ;;
 172       test-suite)     ;;
 173       llvm-test)      ;;
 174       poolalloc)      ;;
 175       llvm-poolalloc) ;;
 176       *)
 177         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 178         ;;
 179     esac
 180   fi
 181 done
 182
 183 dnl Disable the build of polly, even if it is checked out into tools/polly.
 184 AC_ARG_ENABLE(polly,
 185               AS_HELP_STRING([--enable-polly],
 186                              [Use polly if available (default is YES)]),,
 187                              enableval=default)
 188 case "$enableval" in
 189   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 190   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 191   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 192   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 193 esac
 194
 195
 196 dnl Check if polly is checked out into tools/polly and configure it if
 197 dnl available.
 198 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 199   AC_SUBST(LLVM_HAS_POLLY,1)
 200   AC_CONFIG_SUBDIRS([tools/polly])
 201 fi
 202
 203 dnl===-----------------------------------------------------------------------===
 204 dnl===
 205 dnl=== SECTION 2: Architecture, target, and host checks
 206 dnl===
 207 dnl===-----------------------------------------------------------------------===
 208
 209 dnl Check the target for which we're compiling and the host that will do the
 210 dnl compilations. This will tell us which LLVM compiler will be used for
 211 dnl compiling SSA into object code. This needs to be done early because
 212 dnl following tests depend on it.
 213 AC_CANONICAL_TARGET
 214
 215 dnl Determine the platform type and cache its value. This helps us configure
 216 dnl the System library to the correct build platform.
 217 AC_CACHE_CHECK([type of operating system we're going to host on],
 218                [llvm_cv_os_type],
 219 [case $host in
 220   *-*-aix*)
 221     llvm_cv_link_all_option="-Wl,--whole-archive"
 222     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 223     llvm_cv_os_type="AIX"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-irix*)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="IRIX"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-cygwin*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="Cygwin"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-darwin*)
 236     llvm_cv_link_all_option="-Wl,-all_load"
 237     llvm_cv_no_link_all_option="-Wl,-noall_load"
 238     llvm_cv_os_type="Darwin"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-minix*)
 241     llvm_cv_link_all_option="-Wl,-all_load"
 242     llvm_cv_no_link_all_option="-Wl,-noall_load"
 243     llvm_cv_os_type="Minix"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-freebsd*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="FreeBSD"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-kfreebsd-gnu)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="GNU/kFreeBSD"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-openbsd*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="OpenBSD"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-netbsd*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="NetBSD"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-dragonfly*)
 266     llvm_cv_link_all_option="-Wl,--whole-archive"
 267     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 268     llvm_cv_os_type="DragonFly"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-bitrig*)
 271     llvm_cv_link_all_option="-Wl,--whole-archive"
 272     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 273     llvm_cv_os_type="Bitrig"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-hpux*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="HP-UX"
 279     llvm_cv_platform_type="Unix" ;;
 280   *-*-interix*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="Interix"
 284     llvm_cv_platform_type="Unix" ;;
 285   *-*-linux*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="Linux"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-*-gnu*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="GNU"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-*-solaris*)
 296     llvm_cv_link_all_option="-Wl,-z,allextract"
 297     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 298     llvm_cv_os_type="SunOS"
 299     llvm_cv_platform_type="Unix" ;;
 300   *-*-win32*)
 301     llvm_cv_link_all_option="-Wl,--whole-archive"
 302     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 303     llvm_cv_os_type="Win32"
 304     llvm_cv_platform_type="Win32" ;;
 305   *-*-mingw*)
 306     llvm_cv_link_all_option="-Wl,--whole-archive"
 307     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 308     llvm_cv_os_type="MingW"
 309     llvm_cv_platform_type="Win32" ;;
 310   *-*-haiku*)
 311     llvm_cv_link_all_option="-Wl,--whole-archive"
 312     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 313     llvm_cv_os_type="Haiku"
 314     llvm_cv_platform_type="Unix" ;;
 315   *-unknown-eabi*)
 316     llvm_cv_link_all_option="-Wl,--whole-archive"
 317     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 318     llvm_cv_os_type="Freestanding"
 319     llvm_cv_platform_type="Unix" ;;
 320   *-unknown-elf*)
 321     llvm_cv_link_all_option="-Wl,--whole-archive"
 322     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 323     llvm_cv_os_type="Freestanding"
 324     llvm_cv_platform_type="Unix" ;;
 325   *)
 326     llvm_cv_link_all_option=""
 327     llvm_cv_no_link_all_option=""
 328     llvm_cv_os_type="Unknown"
 329     llvm_cv_platform_type="Unknown" ;;
 330 esac])
 331
 332 AC_CACHE_CHECK([type of operating system we're going to target],
 333                [llvm_cv_target_os_type],
 334 [case $target in
 335   *-*-aix*)
 336     llvm_cv_target_os_type="AIX" ;;
 337   *-*-irix*)
 338     llvm_cv_target_os_type="IRIX" ;;
 339   *-*-cygwin*)
 340     llvm_cv_target_os_type="Cygwin" ;;
 341   *-*-darwin*)
 342     llvm_cv_target_os_type="Darwin" ;;
 343   *-*-minix*)
 344     llvm_cv_target_os_type="Minix" ;;
 345   *-*-freebsd*)
 346     llvm_cv_target_os_type="FreeBSD" ;;
 347   *-*-kfreebsd-gnu)
 348     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 349   *-*-openbsd*)
 350     llvm_cv_target_os_type="OpenBSD" ;;
 351   *-*-netbsd*)
 352     llvm_cv_target_os_type="NetBSD" ;;
 353   *-*-dragonfly*)
 354     llvm_cv_target_os_type="DragonFly" ;;
 355   *-*-bitrig*)
 356     llvm_cv_target_os_type="Bitrig" ;;
 357   *-*-hpux*)
 358     llvm_cv_target_os_type="HP-UX" ;;
 359   *-*-interix*)
 360     llvm_cv_target_os_type="Interix" ;;
 361   *-*-linux*)
 362     llvm_cv_target_os_type="Linux" ;;
 363   *-*-gnu*)
 364     llvm_cv_target_os_type="GNU" ;;
 365   *-*-solaris*)
 366     llvm_cv_target_os_type="SunOS" ;;
 367   *-*-win32*)
 368     llvm_cv_target_os_type="Win32" ;;
 369   *-*-mingw*)
 370     llvm_cv_target_os_type="MingW" ;;
 371   *-*-haiku*)
 372     llvm_cv_target_os_type="Haiku" ;;
 373   *-*-rtems*)
 374     llvm_cv_target_os_type="RTEMS" ;;
 375   *-*-nacl*)
 376     llvm_cv_target_os_type="NativeClient" ;;
 377   *-unknown-eabi*)
 378     llvm_cv_target_os_type="Freestanding" ;;
 379   *-*-ps4)
 380     llvm_cv_target_os_type="PS4" ;;
 381   *)
 382     llvm_cv_target_os_type="Unknown" ;;
 383 esac])
 384
 385 dnl Make sure we aren't attempting to configure for an unknown system
 386 if test "$llvm_cv_os_type" = "Unknown" ; then
 387   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 388 fi
 389
 390 dnl Set the "OS" Makefile variable based on the platform type so the
 391 dnl makefile can configure itself to specific build hosts
 392 AC_SUBST(OS,$llvm_cv_os_type)
 393 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 394 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 395
 396 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 397 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 398 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 399
 400 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 401 dnl This is used by lib/Support to determine the basic kind of implementation
 402 dnl to use.
 403 case $llvm_cv_platform_type in
 404   Unix)
 405     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 406     AC_SUBST(LLVM_ON_UNIX,[1])
 407     AC_SUBST(LLVM_ON_WIN32,[0])
 408     ;;
 409   Win32)
 410     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 411     AC_SUBST(LLVM_ON_UNIX,[0])
 412     AC_SUBST(LLVM_ON_WIN32,[1])
 413     ;;
 414 esac
 415
 416 dnl Determine what our target architecture is and configure accordingly.
 417 dnl This will allow Makefiles to make a distinction between the hardware and
 418 dnl the OS.
 419 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 420 [case $target in
 421   i?86-*)                 llvm_cv_target_arch="x86" ;;
 422   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 423   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 424   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 425   arm64*-*)               llvm_cv_target_arch="AArch64" ;;
 426   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 427   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 428   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 429   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 430   xcore-*)                llvm_cv_target_arch="XCore" ;;
 431   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 432   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 433   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 434   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 435   *)                      llvm_cv_target_arch="Unknown" ;;
 436 esac])
 437
 438 if test "$llvm_cv_target_arch" = "Unknown" ; then
 439   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 440 fi
 441
 442 dnl Determine the LLVM native architecture for the target
 443 case "$llvm_cv_target_arch" in
 444     x86)     LLVM_NATIVE_ARCH="X86" ;;
 445     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 446     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 447 esac
 448
 449 dnl Define a substitution, ARCH, for the target architecture
 450 AC_SUBST(ARCH,$llvm_cv_target_arch)
 451 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 452
 453 dnl Determine what our host architecture.
 454 dnl This will allow MCJIT regress tests runs only for supported
 455 dnl platforms.
 456 case $host in
 457   i?86-*)                 host_arch="x86" ;;
 458   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 459   sparc*-*)               host_arch="Sparc" ;;
 460   powerpc*-*)             host_arch="PowerPC" ;;
 461   arm64*-*)               host_arch="AArch64" ;;
 462   arm*-*)                 host_arch="ARM" ;;
 463   aarch64*-*)             host_arch="AArch64" ;;
 464   mips-* | mips64-*)      host_arch="Mips" ;;
 465   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 466   xcore-*)                host_arch="XCore" ;;
 467   msp430-*)               host_arch="MSP430" ;;
 468   hexagon-*)              host_arch="Hexagon" ;;
 469   s390x-*)                host_arch="SystemZ" ;;
 470   *)                      host_arch="Unknown" ;;
 471 esac
 472
 473 if test "$host_arch" = "Unknown" ; then
 474   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 475 fi
 476
 477 AC_SUBST(HOST_ARCH,$host_arch)
 478
 479 dnl Check for build platform executable suffix if we're cross-compiling
 480 if test "$cross_compiling" = yes; then
 481   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 482   AC_BUILD_EXEEXT
 483   ac_build_prefix=${build_alias}-
 484   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 485   if test -z "$BUILD_CXX"; then
 486      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 487      if test -z "$BUILD_CXX"; then
 488        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 489      fi
 490   fi
 491 else
 492   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 493 fi
 494
 495 dnl Check to see if there's a .svn or .git directory indicating that this
 496 dnl build is being done from a checkout. This sets up several defaults for
 497 dnl the command line switches. When we build with a checkout directory,
 498 dnl we get a debug with assertions turned on. Without, we assume a source
 499 dnl release and we get an optimized build without assertions.
 500 dnl See --enable-optimized and --enable-assertions below
 501 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 502   cvsbuild="yes"
 503   optimize="no"
 504   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 505 else
 506   cvsbuild="no"
 507   optimize="yes"
 508 fi
 509
 510 dnl===-----------------------------------------------------------------------===
 511 dnl===
 512 dnl=== SECTION 3: Command line arguments for the configure script.
 513 dnl===
 514 dnl===-----------------------------------------------------------------------===
 515
 516 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 517 AC_ARG_ENABLE(libcpp,
 518               AS_HELP_STRING([--enable-libcpp],
 519                              [Use libc++ if available (default is NO)]),,
 520                              enableval=default)
 521 case "$enableval" in
 522   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 523   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 524   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 525   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 526 esac
 527
 528 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 529 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 530 dnl these checks here so that we have the configuration of the standard C++
 531 dnl library finished.
 532 AC_ARG_ENABLE(compiler-version-checks,
 533               AS_HELP_STRING([--enable-compiler-version-checks],
 534                              [Check the version of the host compiler (default is YES)]),,
 535                              enableval=default)
 536 case "$enableval" in
 537   no)
 538     ;;
 539   yes|default)
 540     AC_LANG_PUSH([C++])
 541     case "$llvm_cv_cxx_compiler" in
 542     clang)
 543       AC_MSG_CHECKING([whether Clang is new enough])
 544       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 545 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 546 #error This version of Clang is too old to build LLVM
 547 #endif
 548 ]])],
 549           [AC_MSG_RESULT([yes])],
 550           [AC_MSG_RESULT([no])
 551            AC_MSG_ERROR([
 552 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 553 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 554 bypass these sanity checks.])])
 555
 556       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 557       dnl are sometimes deeply confusing though. Here we test for an obvious
 558       dnl incomplete feature in 4.6's standard library that was completed in
 559       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 560       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 561       dnl that happening in the Makefile.
 562       if test "$ENABLE_LIBCPP" -eq 0 ; then
 563         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 564         llvm_cv_old_cxxflags="$CXXFLAGS"
 565         CXXFLAGS="$CXXFLAGS -std=c++0x"
 566         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 567 #include <atomic>
 568 std::atomic<float> x(0.0f);
 569 int main() { return (float)x; }
 570 ]])],
 571             [AC_MSG_RESULT([yes])],
 572             [AC_MSG_RESULT([no])
 573              AC_MSG_ERROR([
 574 We detected a missing feature in the standard C++ library that was known to be
 575 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 576 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 577 than 4.7. You will need to update your system and ensure Clang uses the newer
 578 standard library.
 579
 580 If this error is incorrect or you need to force things to work, you may pass
 581 '--disable-compiler-version-checks' to configure to bypass this test.])])
 582         CXXFLAGS="$llvm_cv_old_cxxflags"
 583       fi
 584       ;;
 585     gcc)
 586       AC_MSG_CHECKING([whether GCC is new enough])
 587       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 588 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 589 #error This version of GCC is too old to build LLVM
 590 #endif
 591 ]])],
 592           [AC_MSG_RESULT([yes])],
 593           [AC_MSG_RESULT([no])
 594            AC_MSG_ERROR([
 595 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 596 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 597 bypass these sanity checks.])])
 598       ;;
 599     unknown)
 600       ;;
 601     esac
 602     AC_LANG_POP([C++])
 603     ;;
 604   *)
 605     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 606     ;;
 607 esac
 608
 609 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 610 AC_ARG_ENABLE(cxx1y,
 611               AS_HELP_STRING([--enable-cxx1y],
 612                              [Use c++1y if available (default is NO)]),,
 613                              enableval=default)
 614 case "$enableval" in
 615   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 616   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 617   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 618   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 619 esac
 620
 621 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 622 dnl line
 623 AC_ARG_ENABLE(split-dwarf,
 624               AS_HELP_STRING([--enable-split-dwarf],
 625                              [Use split-dwarf if available (default is NO)]),,
 626                              enableval=default)
 627 case "$enableval" in
 628   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 629   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 630   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 631   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 632 esac
 633
 634 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 635 clang_arcmt="yes"
 636 AC_ARG_ENABLE(clang-arcmt,
 637               AS_HELP_STRING([--enable-clang-arcmt],
 638                              [Enable building of clang ARCMT (default is YES)]),
 639                              clang_arcmt="$enableval",
 640                              enableval="yes")
 641 case "$enableval" in
 642   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 643   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 644   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 645   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 646 esac
 647
 648 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 649 clang_plugin_support="yes"
 650 AC_ARG_ENABLE(clang-plugin-support,
 651               AS_HELP_STRING([--enable-clang-plugin-support],
 652                              [Enable plugin support in clang (default is YES)]),
 653                              clang_plugin_support="$enableval",
 654                              enableval="yes")
 655 case "$enableval" in
 656   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 657   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 658   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 659   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 660 esac
 661
 662 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 663 clang_static_analyzer="yes"
 664 AC_ARG_ENABLE(clang-static-analyzer,
 665               AS_HELP_STRING([--enable-clang-static-analyzer],
 666                              [Enable building of clang Static Analyzer (default is YES)]),
 667                              clang_static_analyzer="$enableval",
 668                              enableval="yes")
 669 case "$enableval" in
 670   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 671   no)
 672     if test ${clang_arcmt} != "no" ; then
 673       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 674     fi
 675     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 676     ;;
 677   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 678   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 679 esac
 680
 681 dnl --enable-optimized : check whether they want to do an optimized build:
 682 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 683  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 684 if test ${enableval} = "no" ; then
 685   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 686 else
 687   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 688 fi
 689
 690 dnl --enable-profiling : check whether they want to do a profile build:
 691 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 692  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 693 if test ${enableval} = "no" ; then
 694   AC_SUBST(ENABLE_PROFILING,[[]])
 695 else
 696   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 697 fi
 698
 699 dnl --enable-assertions : check whether they want to turn on assertions or not:
 700 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 701   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 702 if test ${enableval} = "yes" ; then
 703   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 704 else
 705   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 706 fi
 707
 708 dnl --enable-werror : check whether we want Werror on by default
 709 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 710   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 711 case "$enableval" in
 712   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 713   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 714   default) AC_SUBST(ENABLE_WERROR,[0]);;
 715   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 716 esac
 717
 718 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 719 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 720   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 721 if test ${enableval} = "yes" ; then
 722   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 723   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 724 else
 725   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 726   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 727 fi
 728
 729 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 730 AC_ARG_ENABLE(debug-runtime,
 731    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 732 if test ${enableval} = "no" ; then
 733   AC_SUBST(DEBUG_RUNTIME,[[]])
 734 else
 735   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 736 fi
 737
 738 dnl --enable-debug-symbols : should even optimized compiler libraries
 739 dnl have debug symbols?
 740 AC_ARG_ENABLE(debug-symbols,
 741    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 742 if test ${enableval} = "no" ; then
 743   AC_SUBST(DEBUG_SYMBOLS,[[]])
 744 else
 745   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 746 fi
 747
 748 dnl --enable-keep-symbols : do not strip installed executables
 749 AC_ARG_ENABLE(keep-symbols,
 750    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 751 if test ${enableval} = "no" ; then
 752   AC_SUBST(KEEP_SYMBOLS,[[]])
 753 else
 754   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 755 fi
 756
 757 dnl --enable-jit: check whether they want to enable the jit
 758 AC_ARG_ENABLE(jit,
 759   AS_HELP_STRING(--enable-jit,
 760                  [Enable Just In Time Compiling (default is YES)]),,
 761   enableval=default)
 762 if test ${enableval} = "no"
 763 then
 764   AC_SUBST(JIT,[[]])
 765 else
 766   case "$llvm_cv_target_arch" in
 767     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 768     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 769     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 770     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 771     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 772     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 773     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 774     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 775     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 776     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 777     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 778     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 779   esac
 780 fi
 781
 782 TARGETS_WITH_JIT="ARM AArch64 Mips PowerPC SystemZ X86"
 783 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 784
 785 dnl Allow enablement of building and installing docs
 786 AC_ARG_ENABLE(docs,
 787               AS_HELP_STRING([--enable-docs],
 788                              [Build documents (default is YES)]),,
 789                              enableval=default)
 790 case "$enableval" in
 791   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 792   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 793   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 794   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 795 esac
 796
 797 dnl Allow enablement of doxygen generated documentation
 798 AC_ARG_ENABLE(doxygen,
 799               AS_HELP_STRING([--enable-doxygen],
 800                              [Build doxygen documentation (default is NO)]),,
 801                              enableval=default)
 802 case "$enableval" in
 803   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 804   no|default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 805   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 806 esac
 807
 808 dnl Allow enablement of doxygen search engine
 809 AC_ARG_ENABLE(doxygen-search,
 810               AS_HELP_STRING([--enable-doxygen-search],
 811                              [Enable doxygen search support (default is NO)]),,
 812                              enableval=default)
 813 ENABLE_DOXYGEN_SEARCH="$enableval"
 814
 815 case "$enableval" in
 816   yes|no|default) ;;
 817   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"]) ;;
 818 esac
 819
 820 AC_ARG_ENABLE(doxygen-external-search,
 821               AS_HELP_STRING([--enable-doxygen-external-search],
 822                              [Enable doxygen exteranl search (default is NO)]),,
 823                              enableval=default)
 824 ENABLE_DOXYGEN_EXTERNAL_SEARCH="$enableval"
 825
 826 case "$enableval" in
 827   yes)
 828     dnl To match with the CMake behavior, enable doxygen when
 829     dnl --enable-doxygen-external-search is enabled.
 830     case "$ENABLE_DOXYGEN_SEARCH" in
 831       yes|default) ENABLE_DOXYGEN_SEARCH="yes" ;;
 832       no) AC_MSG_ERROR([The option --enable-doxygen-external-search requires --enable-doxygen-search]) ;;
 833     esac
 834     ;;
 835   no|default) ;;
 836   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen-external-search. Use "yes" or "no"]) ;;
 837 esac
 838
 839 AC_ARG_WITH(doxygen-search-engine-url,
 840             AS_HELP_STRING([--with-doxygen-search-engine-url],
 841                            [Specify the external search engine for doxygen]),,)
 842 WITH_DOXYGEN_SEARCH_ENGINE_URL="$withval"
 843
 844 AC_ARG_WITH(doxygen-search-mappings,
 845             AS_HELP_STRING([--with-doxygen-search-mappings],
 846                            [Specify the extra search mapping for doxygen]),,)
 847 WITH_DOXYGEN_SEARCH_MAPPINGS="$withval"
 848
 849 case "$ENABLE_DOXYGEN_SEARCH" in
 850   yes)
 851     if test "$ENABLE_DOXYGEN" = "0" ; then
 852       AC_MSG_ERROR([The option --enable-doxygen-search requires --enable-doxygen.])
 853     fi
 854
 855     AC_SUBST(enable_searchengine,[YES])
 856
 857     case "$ENABLE_DOXYGEN_EXTERNAL_SEARCH" in
 858       yes)
 859         AC_SUBST(enable_external_search,[YES])
 860         AC_SUBST(enable_server_based_search,[YES])
 861         AC_SUBST(searchengine_url,[$WITH_DOXYGEN_SEARCH_ENGINE_URL])
 862         AC_SUBST(extra_search_mappings,[$WITH_DOXYGEN_SEARCH_MAPPINGS])
 863         ;;
 864
 865       no|default)
 866         AC_SUBST(enable_external_search,[NO])
 867         AC_SUBST(enable_server_based_search,[NO])
 868         AC_SUBST(searchengine_url,[])
 869         AC_SUBST(extra_search_mappings,[])
 870         ;;
 871     esac
 872     ;;
 873
 874   no|default)
 875     AC_SUBST(enable_searchengine,[NO])
 876     AC_SUBST(searchengine_url,[])
 877     AC_SUBST(enable_server_based_search,[NO])
 878     AC_SUBST(enable_external_search,[NO])
 879     AC_SUBST(extra_search_mappings,[])
 880     ;;
 881
 882   *)
 883     AC_MSG_ERROR([Invalid setting for --enable-doxygen-search. Use "yes" or "no"])
 884     ;;
 885 esac
 886
 887 dnl Allow enablement of doxygen generated Qt help files
 888 AC_ARG_ENABLE(doxygen-qt-help,
 889               AS_HELP_STRING([--enable-doxygen-qt-help],
 890                              [Build Qt help files (default is NO)]),,
 891                              enableval=default)
 892 case "$enableval" in
 893   yes)
 894     if test "$ENABLE_DOXYGEN" = "0" ; then
 895       AC_MSG_ERROR([The option --enable-doxygen-qt-help requires --enable-doxygen.])
 896     fi
 897
 898     AC_PATH_PROG(QHELPGENERATOR, [qhelpgenerator], [qhelpgenerator])
 899
 900     dnl Qt help file for llvm doxygen documentation
 901     AC_SUBST(llvm_doxygen_generate_qhp,[YES])
 902     AC_SUBST(llvm_doxygen_qch_filename,[org.llvm.qch])
 903     AC_SUBST(llvm_doxygen_qhp_namespace,[org.llvm])
 904     AC_SUBST(llvm_doxygen_qhelpgenerator_path,[$QHELPGENERATOR])
 905     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,[$PACKAGE_STRING])
 906     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,[$PACKAGE_NAME,$PACKAGE_VERSION])
 907
 908     dnl Qt help file for clang doxygen documentation
 909     AC_SUBST(clang_doxygen_generate_qhp,[YES])
 910     AC_SUBST(clang_doxygen_qch_filename,[org.llvm.clang.qch])
 911     AC_SUBST(clang_doxygen_qhp_namespace,[org.llvm.clang])
 912     AC_SUBST(clang_doxygen_qhelpgenerator_path,[$QHELPGENERATOR])
 913     AC_SUBST(clang_doxygen_qhp_cust_filter_name,[Clang $PACKAGE_VERSION])
 914     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,[Clang,$PACKAGE_VERSION])
 915     ;;
 916
 917   no|default)
 918     AC_SUBST(llvm_doxygen_generate_qhp,[NO])
 919     AC_SUBST(llvm_doxygen_qch_filename,[])
 920     AC_SUBST(llvm_doxygen_qhp_namespace,[])
 921     AC_SUBST(llvm_doxygen_qhelpgenerator_path,[])
 922     AC_SUBST(llvm_doxygen_qhp_cust_filter_name,[])
 923     AC_SUBST(llvm_doxygen_qhp_cust_filter_attrs,[])
 924
 925     AC_SUBST(clang_doxygen_generate_qhp,[NO])
 926     AC_SUBST(clang_doxygen_qch_filename,[])
 927     AC_SUBST(clang_doxygen_qhp_namespace,[])
 928     AC_SUBST(clang_doxygen_qhelpgenerator_path,[])
 929     AC_SUBST(clang_doxygen_qhp_cust_filter_name,[Clang $PACKAGE_VERSION])
 930     AC_SUBST(clang_doxygen_qhp_cust_filter_attrs,[Clang,$PACKAGE_VERSION])
 931     ;;
 932
 933   *)
 934     AC_MSG_ERROR([Invalid setting for --enable-doxygen-qt-help. Use "yes" or "no"]) ;;
 935 esac
 936
 937 dnl Allow disablement of threads
 938 AC_ARG_ENABLE(threads,
 939               AS_HELP_STRING([--enable-threads],
 940                              [Use threads if available (default is YES)]),,
 941                              enableval=default)
 942 case "$enableval" in
 943   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 944   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 945   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 946   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 947 esac
 948 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 949                    [Define if threads enabled])
 950
 951 dnl Allow disablement of pthread.h
 952 AC_ARG_ENABLE(pthreads,
 953               AS_HELP_STRING([--enable-pthreads],
 954                              [Use pthreads if available (default is YES)]),,
 955                              enableval=default)
 956 case "$enableval" in
 957   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 958   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 959   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 960   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 961 esac
 962
 963 dnl Allow disablement of zlib
 964 AC_ARG_ENABLE(zlib,
 965               AS_HELP_STRING([--enable-zlib],
 966                              [Use zlib for compression/decompression if
 967                               available (default is YES)]),,
 968                               enableval=default)
 969 case "$enableval" in
 970   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 971   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 972   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 973   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 974 esac
 975 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 976                    [Define if zlib is enabled])
 977
 978 dnl Allow building without position independent code
 979 AC_ARG_ENABLE(pic,
 980   AS_HELP_STRING([--enable-pic],
 981                  [Build LLVM with Position Independent Code (default is YES)]),,
 982                  enableval=default)
 983 case "$enableval" in
 984   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 985   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 986   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 987   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 988 esac
 989 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 990                    [Define if position independent code is enabled])
 991
 992 dnl Allow building a shared library and linking tools against it.
 993 AC_ARG_ENABLE(shared,
 994   AS_HELP_STRING([--enable-shared],
 995                  [Build a shared library and link tools against it (default is NO)]),,
 996                  enableval=default)
 997 case "$enableval" in
 998   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 999   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
1000   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
1001   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
1002 esac
1003
1004 dnl Allow libstdc++ is embedded in LLVM.dll.
1005 AC_ARG_ENABLE(embed-stdcxx,
1006   AS_HELP_STRING([--enable-embed-stdcxx],
1007                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
1008                  enableval=default)
1009 case "$enableval" in
1010   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
1011   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1012   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
1013   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
1014 esac
1015
1016 dnl Enable embedding timestamp information into build.
1017 AC_ARG_ENABLE(timestamps,
1018   AS_HELP_STRING([--enable-timestamps],
1019                  [Enable embedding timestamp information in build (default is YES)]),,
1020                  enableval=default)
1021 case "$enableval" in
1022   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1023   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
1024   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
1025   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
1026 esac
1027 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
1028                    [Define if timestamp information (e.g., __DATE__) is allowed])
1029
1030 dnl Enable support for showing backtraces.
1031 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
1032   [--enable-backtraces],
1033   [Enable embedding backtraces on crash (default is YES)]),
1034   [case "$enableval" in
1035     yes) llvm_cv_enable_backtraces="yes" ;;
1036     no)  llvm_cv_enable_backtraces="no"  ;;
1037     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
1038   esac],
1039   llvm_cv_enable_backtraces="yes")
1040 if test "$llvm_cv_enable_backtraces" = "yes" ; then
1041   AC_DEFINE([ENABLE_BACKTRACES],[1],
1042             [Define if you want backtraces on crash])
1043 fi
1044
1045 dnl Enable installing platform specific signal handling overrides, for improved
1046 dnl CrashRecovery support or interaction with crash reporting software. This
1047 dnl support may be inappropriate for some clients embedding LLVM as a library.
1048 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
1049   [--enable-crash-overrides],
1050   [Enable crash handling overrides (default is YES)]),
1051   [case "$enableval" in
1052     yes) llvm_cv_enable_crash_overrides="yes" ;;
1053     no)  llvm_cv_enable_crash_overrides="no"  ;;
1054     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
1055   esac],
1056   llvm_cv_enable_crash_overrides="yes")
1057 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
1058   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
1059             [Define to enable crash handling overrides])
1060 fi
1061
1062 dnl List all possible targets
1063 ALL_TARGETS="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600"
1064 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
1065
1066 dnl Allow specific targets to be specified for building (or not)
1067 TARGETS_TO_BUILD=""
1068 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
1069     [Build specific host targets: all or target1,target2,... Valid targets are:
1070      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
1071      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
1072     enableval=all)
1073 if test "$enableval" = host-only ; then
1074   enableval=host
1075 fi
1076 case "$enableval" in
1077   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
1078   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
1079       case "$a_target" in
1080         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1081         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1082         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1083         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1084         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1085         arm64)    TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1086         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1087         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1088         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1089         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1090         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1091         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1092         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1093         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
1094         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1095         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1096         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1097         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
1098         host) case "$llvm_cv_target_arch" in
1099             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1100             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
1101             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
1102             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
1103             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
1104             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
1105             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
1106             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
1107             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
1108             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
1109             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
1110             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
1111             *)       AC_MSG_ERROR([Can not set target to build]) ;;
1112           esac ;;
1113         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
1114       esac
1115   done
1116   ;;
1117 esac
1118
1119 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
1120     [Build experimental host targets: disable or target1,target2,...
1121      (default=disable)]),,
1122     enableval=disable)
1123
1124 if test ${enableval} != "disable"
1125 then
1126   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
1127 fi
1128
1129 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
1130
1131 dnl Determine whether we are building LLVM support for the native architecture.
1132 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
1133 for a_target in $TARGETS_TO_BUILD; do
1134   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1135     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1136       [LLVM architecture name for the native architecture, if available])
1137     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1138     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1139     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1140     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1141     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1142       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1143     fi
1144     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1145       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1146     fi
1147     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1148       [LLVM name for the native Target init function, if available])
1149     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1150       [LLVM name for the native TargetInfo init function, if available])
1151     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1152       [LLVM name for the native target MC init function, if available])
1153     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1154       [LLVM name for the native AsmPrinter init function, if available])
1155     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1156       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1157        [LLVM name for the native AsmParser init function, if available])
1158     fi
1159     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1160       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1161        [LLVM name for the native Disassembler init function, if available])
1162     fi
1163   fi
1164 done
1165
1166 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1167 dnl target feature def files.
1168 LLVM_ENUM_TARGETS=""
1169 LLVM_ENUM_ASM_PRINTERS=""
1170 LLVM_ENUM_ASM_PARSERS=""
1171 LLVM_ENUM_DISASSEMBLERS=""
1172 for target_to_build in $TARGETS_TO_BUILD; do
1173   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1174   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1175     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1176   fi
1177   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1178     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1179   fi
1180   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1181     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1182   fi
1183 done
1184 AC_SUBST(LLVM_ENUM_TARGETS)
1185 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1186 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1187 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1188
1189 dnl Override the option to use for optimized builds.
1190 AC_ARG_WITH(optimize-option,
1191   AS_HELP_STRING([--with-optimize-option],
1192                  [Select the compiler options to use for optimized builds]),,
1193                  withval=default)
1194 AC_MSG_CHECKING([optimization flags])
1195 case "$withval" in
1196   default)
1197     case "$llvm_cv_os_type" in
1198     FreeBSD) optimize_option=-O2 ;;
1199     MingW) optimize_option=-O2 ;;
1200     *)     optimize_option=-O3 ;;
1201     esac ;;
1202   *) optimize_option="$withval" ;;
1203 esac
1204 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1205 AC_MSG_RESULT([$optimize_option])
1206
1207 dnl Specify extra build options
1208 AC_ARG_WITH(extra-options,
1209   AS_HELP_STRING([--with-extra-options],
1210                  [Specify additional options to compile LLVM with]),,
1211                  withval=default)
1212 case "$withval" in
1213   default) EXTRA_OPTIONS= ;;
1214   *) EXTRA_OPTIONS=$withval ;;
1215 esac
1216 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1217
1218 dnl Specify extra linker build options
1219 AC_ARG_WITH(extra-ld-options,
1220   AS_HELP_STRING([--with-extra-ld-options],
1221                  [Specify additional options to link LLVM with]),,
1222                  withval=default)
1223 case "$withval" in
1224   default) EXTRA_LD_OPTIONS= ;;
1225   *) EXTRA_LD_OPTIONS=$withval ;;
1226 esac
1227 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1228
1229 dnl Allow specific bindings to be specified for building (or not)
1230 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1231     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1232     enableval=default)
1233 BINDINGS_TO_BUILD=""
1234 case "$enableval" in
1235   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1236   all ) BINDINGS_TO_BUILD="ocaml" ;;
1237   none | no) BINDINGS_TO_BUILD="" ;;
1238   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1239       case "$a_binding" in
1240         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1241         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1242       esac
1243   done
1244   ;;
1245 esac
1246
1247 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1248 dnl script for bindings/ocaml/configure, except that its auto value depends on
1249 dnl OCAMLC, which is found here to support tests.
1250 AC_ARG_WITH([ocaml-libdir],
1251   [AS_HELP_STRING([--with-ocaml-libdir],
1252     [Specify install location for ocaml bindings (default is stdlib)])],
1253   [],
1254   [withval=auto])
1255 case "$withval" in
1256   auto) with_ocaml_libdir="$withval" ;;
1257   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1258   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1259 esac
1260
1261 AC_ARG_WITH(clang-srcdir,
1262   AS_HELP_STRING([--with-clang-srcdir],
1263     [Directory to the out-of-tree Clang source]),,
1264     withval="-")
1265 case "$withval" in
1266   -) clang_src_root="" ;;
1267   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1268   *) clang_src_root="$ac_pwd/$withval" ;;
1269 esac
1270 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1271
1272 AC_ARG_WITH(clang-resource-dir,
1273   AS_HELP_STRING([--with-clang-resource-dir],
1274     [Relative directory from the Clang binary for resource files]),,
1275     withval="")
1276 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1277                    [Relative directory for resource files])
1278
1279 AC_ARG_WITH(c-include-dirs,
1280   AS_HELP_STRING([--with-c-include-dirs],
1281     [Colon separated list of directories clang will search for headers]),,
1282     withval="")
1283 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1284                    [Directories clang will search for headers])
1285
1286 # Clang normally uses the system c++ headers and libraries. With this option,
1287 # clang will use the ones provided by a gcc installation instead. This option should
1288 # be passed the same value that was used with --prefix when configuring gcc.
1289 AC_ARG_WITH(gcc-toolchain,
1290   AS_HELP_STRING([--with-gcc-toolchain],
1291     [Directory where gcc is installed.]),,
1292     withval="")
1293 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1294                    [Directory where gcc is installed.])
1295
1296 AC_ARG_WITH(default-sysroot,
1297   AS_HELP_STRING([--with-default-sysroot],
1298     [Add --sysroot=<path> to all compiler invocations.]),,
1299     withval="")
1300 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1301                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1302
1303 dnl Allow linking of LLVM with GPLv3 binutils code.
1304 AC_ARG_WITH(binutils-include,
1305   AS_HELP_STRING([--with-binutils-include],
1306     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1307   withval=default)
1308 case "$withval" in
1309   default) WITH_BINUTILS_INCDIR=default ;;
1310   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1311   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1312 esac
1313 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1314   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1315   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1316      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1317      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1318   fi
1319 fi
1320
1321 dnl Specify the URL where bug reports should be submitted.
1322 AC_ARG_WITH(bug-report-url,
1323   AS_HELP_STRING([--with-bug-report-url],
1324     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1325     withval="http://llvm.org/bugs/")
1326 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1327                    [Bug report URL.])
1328
1329 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1330 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1331   [--enable-terminfo],
1332   [Query the terminfo database if available (default is YES)]),
1333   [case "$enableval" in
1334     yes) llvm_cv_enable_terminfo="yes" ;;
1335     no)  llvm_cv_enable_terminfo="no"  ;;
1336     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1337   esac],
1338   llvm_cv_enable_terminfo="yes")
1339 case "$llvm_cv_enable_terminfo" in
1340   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1341   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1342 esac
1343
1344 dnl --enable-libedit: check whether the user wants to turn off libedit.
1345 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1346   [--enable-libedit],
1347   [Use libedit if available (default is YES)]),
1348   [case "$enableval" in
1349     yes) llvm_cv_enable_libedit="yes" ;;
1350     no)  llvm_cv_enable_libedit="no"  ;;
1351     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1352   esac],
1353   llvm_cv_enable_libedit="yes")
1354
1355 dnl --enable-libffi : check whether the user wants to turn off libffi:
1356 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1357   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1358   [case "$enableval" in
1359     yes) llvm_cv_enable_libffi="yes" ;;
1360     no)  llvm_cv_enable_libffi="no"  ;;
1361     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1362   esac],
1363   llvm_cv_enable_libffi=no)
1364
1365 AC_ARG_WITH(internal-prefix,
1366   AS_HELP_STRING([--with-internal-prefix],
1367     [Installation directory for internal files]),,
1368     withval="")
1369 AC_SUBST(INTERNAL_PREFIX,[$withval])
1370
1371 dnl===-----------------------------------------------------------------------===
1372 dnl===
1373 dnl=== SECTION 4: Check for programs we need and that they are the right version
1374 dnl===
1375 dnl===-----------------------------------------------------------------------===
1376
1377 dnl Check for the tools that the makefiles require
1378 AC_CHECK_GNU_MAKE
1379 AC_PROG_LN_S
1380 AC_PATH_PROG(NM, [nm], [nm])
1381 AC_PATH_PROG(CMP, [cmp], [cmp])
1382 AC_PATH_PROG(CP, [cp], [cp])
1383 AC_PATH_PROG(DATE, [date], [date])
1384 AC_PATH_PROG(FIND, [find], [find])
1385 AC_PATH_PROG(GREP, [grep], [grep])
1386 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1387 AC_PATH_PROG(MV,   [mv],   [mv])
1388 AC_PROG_RANLIB
1389 AC_CHECK_TOOL(AR, ar, false)
1390 AC_PATH_PROG(RM,   [rm],   [rm])
1391 AC_PATH_PROG(SED,  [sed],  [sed])
1392 AC_PATH_PROG(TAR,  [tar],  [gtar])
1393 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1394
1395 dnl Looking for misc. graph plotting software
1396 AC_PATH_PROG(DOT, [dot], [echo dot])
1397 if test "$DOT" != "echo dot" ; then
1398   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1399   dnl If we're targeting for mingw we should emit windows paths, not msys
1400   if test "$llvm_cv_os_type" = "MingW" ; then
1401     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1402   fi
1403   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1404    [Define to path to dot program if found or 'echo dot' otherwise])
1405 fi
1406
1407 dnl Find the install program
1408 AC_PROG_INSTALL
1409 dnl Prepend src dir to install path dir if it's a relative path
1410 dnl This is a hack for installs that take place in something other
1411 dnl than the top level.
1412 case "$INSTALL" in
1413  [[\\/$]]* | ?:[[\\/]]* ) ;;
1414  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1415 esac
1416
1417 dnl Checks for documentation and testing tools that we can do without. If these
1418 dnl are not found then they are set to "true" which always succeeds but does
1419 dnl nothing. This just lets the build output show that we could have done
1420 dnl something if the tool was available.
1421 AC_PATH_PROG(BZIP2, [bzip2])
1422 AC_PATH_PROG(CAT, [cat])
1423 AC_PATH_PROG(DOXYGEN, [doxygen])
1424 AC_PATH_PROG(GROFF, [groff])
1425 AC_PATH_PROG(GZIPBIN, [gzip])
1426 AC_PATH_PROG(PDFROFF, [pdfroff])
1427 AC_PATH_PROG(ZIP, [zip])
1428 AC_PATH_PROG(GO, [go])
1429 AC_PATH_PROGS(OCAMLFIND, [ocamlfind])
1430 AC_PATH_PROGS(GAS, [gas as])
1431
1432 dnl Get the version of the linker in use.
1433 AC_LINK_GET_VERSION
1434
1435 dnl Determine whether the linker supports the -R option.
1436 AC_LINK_USE_R
1437
1438 dnl Determine whether the compiler supports the -rdynamic option.
1439 AC_LINK_EXPORT_DYNAMIC
1440
1441 dnl Determine whether the linker supports the --version-script option.
1442 AC_LINK_VERSION_SCRIPT
1443
1444 AC_CHECK_HEADERS([errno.h])
1445
1446 case "$llvm_cv_os_type" in
1447   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1448   Darwin) llvm_shlib_ext=.dylib ;;
1449   *) llvm_shlib_ext=.so ;;
1450 esac
1451
1452 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1453
1454 AC_MSG_CHECKING([tool compatibility])
1455
1456 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1457 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1458 dnl to support those options.
1459 dnl "icc" emits gcc signatures
1460 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1461 ICC=no
1462 IXX=no
1463 case $CC in
1464   icc*|icpc*)
1465     ICC=yes
1466     IXX=yes
1467     ;;
1468    *)
1469     ;;
1470 esac
1471
1472 if test "$GCC" != "yes" && test "$ICC" != "yes"
1473 then
1474   AC_MSG_ERROR([gcc|icc required but not found])
1475 fi
1476
1477 dnl Ensure that compilation tools are compatible with GCC extensions
1478 if test "$GXX" != "yes" && test "$IXX" != "yes"
1479 then
1480   AC_MSG_ERROR([g++|clang++|icc required but not found])
1481 fi
1482
1483 dnl Verify that GCC is version 3.0 or higher
1484 if test "$GCC" = "yes"
1485 then
1486   AC_COMPILE_IFELSE(
1487 [
1488   AC_LANG_SOURCE([[
1489     #if !defined(__GNUC__) || __GNUC__ < 3
1490     #error Unsupported GCC version
1491     #endif
1492   ]])
1493 ],
1494 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1495 fi
1496
1497 dnl Check for GNU Make.  We use its extensions, so don't build without it
1498 if test -z "$llvm_cv_gnu_make_command"
1499 then
1500   AC_MSG_ERROR([GNU Make required but not found])
1501 fi
1502
1503 dnl Tool compatibility is okay if we make it here.
1504 AC_MSG_RESULT([ok])
1505
1506 dnl Check optional compiler flags.
1507 AC_MSG_CHECKING([optional compiler flags])
1508 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1509 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1510 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1511
1512 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1513 dnl false positives, so disable it.
1514 NO_UNINITIALIZED=
1515 NO_MAYBE_UNINITIALIZED=
1516 if test "$GXX" = "yes"
1517 then
1518   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1519   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1520   dnl known to be uninitialized from cases which might be uninitialized.  We
1521   dnl still want to catch the first kind of errors.
1522   if test -z "$NO_MAYBE_UNINITIALIZED"
1523   then
1524     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1525   fi
1526 fi
1527
1528 dnl Check for misbehaving -Wcomment (gcc-4.7 has this) and maybe add
1529 dnl -Wno-comment to the flags.
1530 no_comment=
1531 llvm_cv_old_cxxflags="$CXXFLAGS"
1532 CXXFLAGS="$CXXFLAGS -Wcomment -Werror"
1533 AC_COMPILE_IFELSE(
1534 [
1535   AC_LANG_SOURCE([[// Comment \o\
1536 // Another comment
1537 int main() { return 0; }
1538   ]])
1539 ],
1540 [
1541   no_comment=-Wno-comment
1542 ],
1543 [])
1544 AC_SUBST(NO_COMMENT, [$no_comment])
1545 CXXFLAGS="$llvm_cv_old_cxxflags"
1546
1547 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED $NO_COMMENT])
1548
1549 AC_ARG_WITH([python],
1550             [AS_HELP_STRING([--with-python], [path to python])],
1551             [PYTHON="$withval"])
1552
1553 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1554   AC_MSG_CHECKING([for python])
1555   AC_MSG_RESULT([user defined: $with_python])
1556 else
1557   if test -n "$PYTHON" ; then
1558     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1559   fi
1560
1561   AC_PATH_PROG([PYTHON], [python python2 python27],
1562                [AC_MSG_RESULT([not found])
1563                 AC_MSG_ERROR([could not find python 2.7 or higher])])
1564 fi
1565
1566 AC_MSG_CHECKING([for python >= 2.7])
1567 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1568 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1569 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1570 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1571 if test "$ac_python_version_major" -gt "2" || \
1572    (test "$ac_python_version_major" -eq "2" && \
1573     test "$ac_python_version_minor" -ge "7") ; then
1574   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1575 else
1576   AC_MSG_RESULT([not found])
1577   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.7])
1578 fi
1579
1580 dnl===-----------------------------------------------------------------------===
1581 dnl===
1582 dnl=== SECTION 5: Check for libraries
1583 dnl===
1584 dnl===-----------------------------------------------------------------------===
1585
1586 AC_CHECK_LIB(m,sin)
1587 if test "$llvm_cv_os_type" = "MingW" ; then
1588   AC_CHECK_LIB(imagehlp, main)
1589   AC_CHECK_LIB(psapi, main)
1590   AC_CHECK_LIB(shell32, main)
1591 fi
1592
1593 dnl dlopen() is required for plugin support.
1594 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1595                [Define if dlopen() is available on this platform.]),
1596                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1597
1598 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1599 dnl macros to detect whether clock_gettime is available, this just finds the
1600 dnl right libraries to link with.
1601 AC_SEARCH_LIBS(clock_gettime,rt)
1602
1603 dnl The curses library is optional; used for querying terminal info
1604 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1605   dnl We need the has_color functionality in curses for it to be useful.
1606   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1607                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1608                                    [Define if the setupterm() function is supported this platform.]))
1609 fi
1610
1611 dnl The libedit library is optional; used by lib/LineEditor
1612 if test "$llvm_cv_enable_libedit" = "yes" ; then
1613   AC_SEARCH_LIBS(el_init,edit,
1614                  AC_DEFINE([HAVE_LIBEDIT],[1],
1615                            [Define if libedit is available on this platform.]))
1616 fi
1617
1618 dnl libffi is optional; used to call external functions from the interpreter
1619 if test "$llvm_cv_enable_libffi" = "yes" ; then
1620   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1621                  [Define if libffi is available on this platform.]),
1622                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1623 fi
1624
1625 dnl mallinfo is optional; the code can compile (minus features) without it
1626 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1627                [Define if mallinfo() is available on this platform.]))
1628
1629 dnl pthread locking functions are optional - but llvm will not be thread-safe
1630 dnl without locks.
1631 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1632   AC_CHECK_LIB(pthread, pthread_mutex_init)
1633   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1634                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1635                            [Have pthread_mutex_lock]))
1636   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1637                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1638                  [Have pthread_rwlock_init]))
1639   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1640                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1641                  [Have pthread_getspecific]))
1642 fi
1643
1644 dnl zlib is optional; used for compression/uncompression
1645 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1646   AC_CHECK_LIB(z, compress2)
1647 fi
1648
1649 dnl Allow OProfile support for JIT output.
1650 AC_ARG_WITH(oprofile,
1651   AS_HELP_STRING([--with-oprofile=<prefix>],
1652     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1653     [
1654       AC_SUBST(USE_OPROFILE, [1])
1655       case "$withval" in
1656         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1657         no) llvm_cv_oppath=
1658             AC_SUBST(USE_OPROFILE, [0]) ;;
1659         *) llvm_cv_oppath="${withval}/lib/oprofile"
1660            CPPFLAGS="-I${withval}/include";;
1661       esac
1662       case $llvm_cv_os_type in
1663         Linux)
1664           if test -n "$llvm_cv_oppath" ; then
1665             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1666             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1667             dnl libbfd is not included properly in libopagent in some Debian
1668             dnl versions.  If libbfd isn't found at all, we assume opagent works
1669             dnl anyway.
1670             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1671             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1672               echo "Error! You need to have libopagent around."
1673               exit 1
1674             ])
1675             AC_CHECK_HEADER([opagent.h], [], [
1676               echo "Error! You need to have opagent.h around."
1677               exit 1
1678               ])
1679           fi ;;
1680         *)
1681           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1682       esac
1683     ],
1684     [
1685       AC_SUBST(USE_OPROFILE, [0])
1686     ])
1687 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1688                    [Define if we have the oprofile JIT-support library])
1689
1690 dnl Enable support for Intel JIT Events API.
1691 AC_ARG_WITH(intel-jitevents,
1692   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1693     [
1694        case "$withval" in
1695           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1696           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1697           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1698        esac
1699
1700       case $llvm_cv_os_type in
1701         Linux|Win32|Cygwin|MingW) ;;
1702         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1703       esac
1704
1705       case "$llvm_cv_target_arch" in
1706         x86|x86_64) ;;
1707         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1708       esac
1709     ],
1710     [
1711       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1712     ])
1713 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1714                    [Define if we have the Intel JIT API runtime support library])
1715
1716 dnl Check for libxml2
1717 dnl Right now we're just checking for the existence, we could also check for a
1718 dnl particular version via --version on xml2-config
1719 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1720
1721 AC_MSG_CHECKING(for libxml2 includes)
1722 if test "x$XML2CONFIG" = "x"; then
1723  AC_MSG_RESULT(xml2-config not found)
1724 else
1725  LIBXML2_INC=`$XML2CONFIG --cflags`
1726  AC_MSG_RESULT($LIBXML2_INC)
1727  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1728                                 LIBXML2_LIBS="-lxml2"])
1729 fi
1730 AC_SUBST(LIBXML2_LIBS)
1731 AC_SUBST(LIBXML2_INC)
1732
1733 dnl===-----------------------------------------------------------------------===
1734 dnl===
1735 dnl=== SECTION 6: Check for header files
1736 dnl===
1737 dnl===-----------------------------------------------------------------------===
1738
1739 dnl First, use autoconf provided macros for specific headers that we need
1740 dnl We don't check for ancient stuff or things that are guaranteed to be there
1741 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1742 dnl Generally we're looking for POSIX headers.
1743 AC_HEADER_DIRENT
1744 AC_HEADER_MMAP_ANONYMOUS
1745 AC_HEADER_STAT
1746 AC_HEADER_SYS_WAIT
1747 AC_HEADER_TIME
1748
1749 AC_LANG_PUSH([C++])
1750 dnl size_t must be defined before including cxxabi.h on FreeBSD 10.0.
1751 AC_CHECK_HEADERS([cxxabi.h], [], [],
1752 [#include <stddef.h>
1753 ])
1754 AC_LANG_POP([C++])
1755
1756 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1757 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1758 AC_CHECK_HEADERS([utime.h])
1759 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1760 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1761 AC_CHECK_HEADERS([valgrind/valgrind.h])
1762 AC_CHECK_HEADERS([fenv.h])
1763 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1764 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1765   AC_CHECK_HEADERS(pthread.h,
1766                    AC_SUBST(HAVE_PTHREAD, 1),
1767                    AC_SUBST(HAVE_PTHREAD, 0))
1768 else
1769   AC_SUBST(HAVE_PTHREAD, 0)
1770 fi
1771 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1772   AC_CHECK_HEADERS(zlib.h,
1773                    AC_SUBST(HAVE_LIBZ, 1),
1774                    AC_SUBST(HAVE_LIBZ, 0))
1775 else
1776   AC_SUBST(HAVE_LIBZ, 0)
1777 fi
1778
1779 dnl Try to find ffi.h.
1780 if test "$llvm_cv_enable_libffi" = "yes" ; then
1781   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1782 fi
1783
1784 dnl Try to find Darwin specific crash reporting libraries.
1785 AC_CHECK_HEADERS([CrashReporterClient.h])
1786
1787 dnl Try to find Darwin specific crash reporting global.
1788 AC_MSG_CHECKING([__crashreporter_info__])
1789 AC_LINK_IFELSE(
1790 [
1791   AC_LANG_SOURCE([[
1792     extern const char *__crashreporter_info__;
1793     int main() {
1794       __crashreporter_info__ = "test";
1795       return 0;
1796     }
1797   ]])
1798 ],
1799 [
1800   AC_MSG_RESULT([yes])
1801   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1802 ],
1803 [
1804   AC_MSG_RESULT([no])
1805   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1806 ])
1807
1808 dnl===-----------------------------------------------------------------------===
1809 dnl===
1810 dnl=== SECTION 7: Check for types and structures
1811 dnl===
1812 dnl===-----------------------------------------------------------------------===
1813
1814 AC_HUGE_VAL_CHECK
1815 AC_TYPE_PID_T
1816 AC_TYPE_SIZE_T
1817 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1818 AC_STRUCT_TM
1819 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1820 AC_CHECK_TYPES([uint64_t],,
1821          AC_CHECK_TYPES([u_int64_t],,
1822          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1823
1824 dnl===-----------------------------------------------------------------------===
1825 dnl===
1826 dnl=== SECTION 8: Check for specific functions needed
1827 dnl===
1828 dnl===-----------------------------------------------------------------------===
1829
1830 AC_CHECK_FUNCS([backtrace getcwd ])
1831 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1832 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1833 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1834 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1835 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1836 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1837 AC_CHECK_FUNCS([futimes futimens])
1838 AC_C_PRINTF_A
1839 AC_FUNC_RAND48
1840
1841 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1842 AC_CHECK_DECLS([arc4random])
1843
1844 dnl Check the declaration "Secure API" on Windows environments.
1845 AC_CHECK_DECLS([strerror_s])
1846
1847 dnl Check symbols in libgcc.a for JIT on Mingw.
1848 if test "$llvm_cv_os_type" = "MingW" ; then
1849   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1850   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1851   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1852   AC_CHECK_LIB(gcc,__chkstk_ms,AC_DEFINE([HAVE___CHKSTK_MS],[1],[Have host's __chkstk_ms]))
1853   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1854   AC_CHECK_LIB(gcc,___chkstk_ms,AC_DEFINE([HAVE____CHKSTK_MS],[1],[Have host's ___chkstk_ms]))
1855
1856   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1857   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1858   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1859   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1860   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1861   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1862   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1863   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1864   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1865   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1866
1867   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1868   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1869 fi
1870
1871 dnl Check Win32 API EnumerateLoadedModules.
1872 if test "$llvm_cv_os_type" = "MingW" ; then
1873   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1874   AC_COMPILE_IFELSE(
1875 [
1876   AC_LANG_SOURCE([[
1877     #include <windows.h>
1878     #include <imagehlp.h>
1879     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1880     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1881   ]])
1882 ],
1883 [
1884   AC_MSG_RESULT([yes])
1885   llvm_cv_win32_elmcb_pcstr="PCSTR"
1886 ],
1887 [
1888   AC_MSG_RESULT([no])
1889   llvm_cv_win32_elmcb_pcstr="PSTR"
1890 ])
1891   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1892 fi
1893
1894 dnl Check for mmap support.We also need to know if /dev/zero is required to
1895 dnl be opened for allocating RWX memory.
1896 dnl Make sure we aren't attempting to configure for an unknown system
1897 if test "$llvm_cv_platform_type" = "Unix" ; then
1898   AC_FUNC_MMAP
1899   AC_FUNC_MMAP_FILE
1900   AC_NEED_DEV_ZERO_FOR_MMAP
1901
1902   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1903   then
1904     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1905   fi
1906   if test "$ac_cv_func_mmap_file" = "no"
1907   then
1908     AC_MSG_WARN([mmap() of files required but not found])
1909   fi
1910 fi
1911
1912 dnl atomic builtins are required for threading support.
1913 AC_MSG_CHECKING(for GCC atomic builtins)
1914 dnl Since we'll be using these atomic builtins in C++ files we should test
1915 dnl the C++ compiler.
1916 AC_LANG_PUSH([C++])
1917 AC_LINK_IFELSE(
1918 [
1919   AC_LANG_SOURCE([[
1920     int main() {
1921       volatile unsigned long val = 1;
1922       __sync_synchronize();
1923       __sync_val_compare_and_swap(&val, 1, 0);
1924       __sync_add_and_fetch(&val, 1);
1925       __sync_sub_and_fetch(&val, 1);
1926       return 0;
1927     }
1928   ]])
1929 ],
1930 [
1931   AC_MSG_RESULT([yes])
1932   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1933 ],
1934 [
1935   AC_MSG_RESULT([no])
1936   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1937   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1938 ])
1939 AC_LANG_POP([C++])
1940
1941 dnl===-----------------------------------------------------------------------===
1942 dnl===
1943 dnl=== SECTION 9: Additional checks, variables, etc.
1944 dnl===
1945 dnl===-----------------------------------------------------------------------===
1946
1947 dnl Handle 32-bit linux systems running a 64-bit kernel.
1948 dnl This has to come after section 4 because it invokes the compiler.
1949 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1950   AC_IS_LINUX_MIXED
1951   if test "$llvm_cv_linux_mixed" = "yes"; then
1952     llvm_cv_target_arch="x86"
1953     ARCH="x86"
1954   fi
1955 fi
1956
1957 dnl Check whether __dso_handle is present
1958 AC_CHECK_FUNCS([__dso_handle])
1959
1960 dnl Propagate the shared library extension that the libltdl checks did to
1961 dnl the Makefiles so we can use it there too
1962 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
1963
1964 dnl Translate the various configuration directories and other basic
1965 dnl information into substitutions that will end up in Makefile.config.in
1966 dnl that these configured values can be used by the makefiles
1967 if test "${prefix}" = "NONE" ; then
1968   prefix="/usr/local"
1969 fi
1970 eval LLVM_PREFIX="${prefix}";
1971 eval LLVM_BINDIR="${prefix}/bin";
1972 eval LLVM_DATADIR="${prefix}/share/llvm";
1973 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1974 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1975 eval LLVM_INCLUDEDIR="${prefix}/include";
1976 eval LLVM_INFODIR="${prefix}/info";
1977 eval LLVM_MANDIR="${prefix}/man";
1978 LLVM_CONFIGTIME=`date`
1979 AC_SUBST(LLVM_PREFIX)
1980 AC_SUBST(LLVM_BINDIR)
1981 AC_SUBST(LLVM_DATADIR)
1982 AC_SUBST(LLVM_DOCSDIR)
1983 AC_SUBST(LLVM_ETCDIR)
1984 AC_SUBST(LLVM_INCLUDEDIR)
1985 AC_SUBST(LLVM_INFODIR)
1986 AC_SUBST(LLVM_MANDIR)
1987 AC_SUBST(LLVM_CONFIGTIME)
1988
1989 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1990 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1991   LLVM_CONFIGTIME="(timestamp not enabled)"
1992 fi
1993
1994 dnl Place the various directories into the config.h file as #defines so that we
1995 dnl can know about the installation paths within LLVM.
1996 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1997                    [Installation prefix directory])
1998 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1999                    [Installation directory for binary executables])
2000 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
2001                    [Installation directory for data files])
2002 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
2003                    [Installation directory for documentation])
2004 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
2005                    [Installation directory for config files])
2006 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
2007                    [Installation directory for include files])
2008 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
2009                    [Installation directory for .info files])
2010 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
2011                    [Installation directory for man pages])
2012 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
2013                    [Time at which LLVM was configured])
2014 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
2015                    [Host triple LLVM will be executed on])
2016 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
2017                    [Target triple LLVM will generate code for by default])
2018
2019 dnl Determine which bindings to build.
2020 if test "$BINDINGS_TO_BUILD" = auto ; then
2021   BINDINGS_TO_BUILD=""
2022   if test "x$OCAMLFIND" != x ; then
2023     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
2024   fi
2025   if test "x$GO" != x ; then
2026     if $GO run ${srcdir}/bindings/go/conftest.go ; then
2027       BINDINGS_TO_BUILD="go $BINDINGS_TO_BUILD"
2028     fi
2029   fi
2030 fi
2031 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
2032
2033 dnl Do any work necessary to ensure that bindings have what they need.
2034 binding_prereqs_failed=0
2035 for a_binding in $BINDINGS_TO_BUILD ; do
2036   case "$a_binding" in
2037   ocaml)
2038     if test "x$OCAMLFIND" = x ; then
2039       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlfind not found. Try configure OCAMLFIND=/path/to/ocamlfind])
2040       binding_prereqs_failed=1
2041     fi
2042
2043     if $OCAMLFIND opt -version >/dev/null 2>/dev/null ; then
2044       HAVE_OCAMLOPT=1
2045     else
2046       HAVE_OCAMLOPT=0
2047     fi
2048     AC_SUBST(HAVE_OCAMLOPT)
2049
2050     if ! $OCAMLFIND query ctypes >/dev/null 2>/dev/null; then
2051       AC_MSG_WARN([--enable-bindings=ocaml specified, but ctypes is not installed])
2052       binding_prereqs_failed=1
2053     fi
2054
2055     if $OCAMLFIND query oUnit >/dev/null 2>/dev/null; then
2056       HAVE_OCAML_OUNIT=1
2057     else
2058       HAVE_OCAML_OUNIT=0
2059       AC_MSG_WARN([--enable-bindings=ocaml specified, but OUnit 2 is not installed. Tests will not run])
2060       dnl oUnit is optional!
2061     fi
2062     AC_SUBST(HAVE_OCAML_OUNIT)
2063
2064     if test "x$with_ocaml_libdir" != xauto ; then
2065       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
2066     else
2067       ocaml_stdlib="`"$OCAMLFIND" ocamlc -where`"
2068       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
2069       then
2070         # ocaml stdlib is beneath our prefix; use stdlib
2071         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
2072       else
2073         # ocaml stdlib is outside our prefix; use libdir/ocaml
2074         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
2075       fi
2076     fi
2077     ;;
2078   go)
2079     if test "x$GO" = x ; then
2080       AC_MSG_WARN([--enable-bindings=go specified, but go not found. Try configure GO=/path/to/go])
2081       binding_prereqs_failed=1
2082     else
2083       if $GO run ${srcdir}/bindings/go/conftest.go ; then
2084         :
2085       else
2086         AC_MSG_WARN([--enable-bindings=go specified, but need at least Go 1.2. Try configure GO=/path/to/go])
2087         binding_prereqs_failed=1
2088       fi
2089     fi
2090     ;;
2091   esac
2092 done
2093 if test "$binding_prereqs_failed" = 1 ; then
2094   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2095 fi
2096
2097 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2098 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2099
2100 dnl Determine linker rpath flag
2101 if test "$llvm_cv_link_use_r" = "yes" ; then
2102   RPATH="-Wl,-R"
2103 else
2104   RPATH="-Wl,-rpath"
2105 fi
2106 AC_SUBST(RPATH)
2107
2108 dnl Determine linker rdynamic flag
2109 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2110   RDYNAMIC="-rdynamic"
2111 else
2112   RDYNAMIC=""
2113 fi
2114 AC_SUBST(RDYNAMIC)
2115
2116 dnl===-----------------------------------------------------------------------===
2117 dnl===
2118 dnl=== SECTION 10: Specify the output files and generate it
2119 dnl===
2120 dnl===-----------------------------------------------------------------------===
2121
2122 dnl Configure header files
2123 dnl WARNING: dnl If you add or remove any of the following config headers, then
2124 dnl you MUST also update Makefile so that the variable FilesToConfig
2125 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2126 dnl files can be updated automatically when their *.in sources change.
2127 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2128 AH_TOP([#ifndef CONFIG_H
2129 #define CONFIG_H])
2130 AH_BOTTOM([#endif])
2131
2132 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2133 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2134 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2135 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2136 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2137
2138 dnl Configure the makefile's configuration data
2139 AC_CONFIG_FILES([Makefile.config])
2140
2141 dnl Configure the RPM spec file for LLVM
2142 AC_CONFIG_FILES([llvm.spec])
2143
2144 dnl Configure doxygen's configuration file
2145 AC_CONFIG_FILES([docs/doxygen.cfg])
2146
2147 dnl Configure clang, if present
2148 if test "${clang_src_root}" = ""; then
2149   clang_src_root="$srcdir/tools/clang"
2150 fi
2151 if test -f ${clang_src_root}/README.txt; then
2152   dnl Clang supports build systems which use the multilib libdir suffix.
2153   dnl The autoconf system doesn't support this so stub out that variable.
2154   AC_DEFINE_UNQUOTED(CLANG_LIBDIR_SUFFIX,"",
2155                      [Multilib suffix for libdir.])
2156
2157   dnl Use variables to stay under 80 columns.
2158   configh="include/clang/Config/config.h"
2159   doxy="docs/doxygen.cfg"
2160   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2161   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2162 fi
2163
2164 dnl OCaml findlib META file
2165 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2166
2167 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2168 test "x$program_prefix" = "xNONE" && program_prefix=""
2169 AC_SUBST([program_prefix])
2170
2171
2172 dnl Do special configuration of Makefiles
2173 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2174 AC_CONFIG_MAKEFILE(Makefile)
2175 AC_CONFIG_MAKEFILE(Makefile.common)
2176 AC_CONFIG_MAKEFILE(examples/Makefile)
2177 AC_CONFIG_MAKEFILE(lib/Makefile)
2178 AC_CONFIG_MAKEFILE(test/Makefile)
2179 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2180 AC_CONFIG_MAKEFILE(unittests/Makefile)
2181 AC_CONFIG_MAKEFILE(tools/Makefile)
2182 AC_CONFIG_MAKEFILE(utils/Makefile)
2183 AC_CONFIG_MAKEFILE(projects/Makefile)
2184 AC_CONFIG_MAKEFILE(bindings/Makefile)
2185 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2186
2187 dnl Finally, crank out the output
2188 AC_OUTPUT