autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.4svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [4], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 ${CFLAGS=}
  65 ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang llvm-gcc gcc)
  70 AC_PROG_CXX(clang++ llvm-g++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Configure all of the projects present in our source tree. While we could
 100 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 101 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 102 dnl Instead we match on the known projects.
 103
 104 dnl
 105 dnl One tricky part of doing this is that some projects depend upon other
 106 dnl projects.  For example, several projects rely upon the LLVM test suite.
 107 dnl We want to configure those projects first so that their object trees are
 108 dnl created before running the configure scripts of projects that depend upon
 109 dnl them.
 110 dnl
 111
 112 dnl Several projects use llvm-gcc, so configure that first
 113 if test -d ${srcdir}/projects/llvm-gcc ; then
 114   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
 115 fi
 116
 117 dnl Several projects use the LLVM test suite, so configure it next.
 118 if test -d ${srcdir}/projects/test-suite ; then
 119   AC_CONFIG_SUBDIRS([projects/test-suite])
 120 fi
 121
 122 dnl llvm-test is the old name of the test-suite, kept here for backwards
 123 dnl compatibility
 124 if test -d ${srcdir}/projects/llvm-test ; then
 125   AC_CONFIG_SUBDIRS([projects/llvm-test])
 126 fi
 127
 128 dnl Some projects use poolalloc; configure that next
 129 if test -d ${srcdir}/projects/poolalloc ; then
 130   AC_CONFIG_SUBDIRS([projects/poolalloc])
 131 fi
 132
 133 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 134   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 135 fi
 136
 137 dnl Check for all other projects
 138 for i in `ls ${srcdir}/projects`
 139 do
 140   if test -d ${srcdir}/projects/${i} ; then
 141     case ${i} in
 142       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 143       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 144       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 145       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 146       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 147       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 148       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 149       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 150       compiler-rt)       ;;
 151       llvm-gcc)       ;;
 152       test-suite)     ;;
 153       llvm-test)      ;;
 154       poolalloc)      ;;
 155       llvm-poolalloc) ;;
 156       *)
 157         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 158         ;;
 159     esac
 160   fi
 161 done
 162
 163 dnl Disable the build of polly, even if it is checked out into tools/polly.
 164 AC_ARG_ENABLE(polly,
 165               AS_HELP_STRING([--enable-polly],
 166                              [Use polly if available (default is YES)]),,
 167                              enableval=default)
 168 case "$enableval" in
 169   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 170   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 171   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 172   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 173 esac
 174
 175
 176 dnl Check if polly is checked out into tools/polly and configure it if
 177 dnl available.
 178 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 179   AC_SUBST(LLVM_HAS_POLLY,1)
 180   AC_CONFIG_SUBDIRS([tools/polly])
 181 fi
 182
 183 dnl===-----------------------------------------------------------------------===
 184 dnl===
 185 dnl=== SECTION 2: Architecture, target, and host checks
 186 dnl===
 187 dnl===-----------------------------------------------------------------------===
 188
 189 dnl Check the target for which we're compiling and the host that will do the
 190 dnl compilations. This will tell us which LLVM compiler will be used for
 191 dnl compiling SSA into object code. This needs to be done early because
 192 dnl following tests depend on it.
 193 AC_CANONICAL_TARGET
 194
 195 dnl Determine the platform type and cache its value. This helps us configure
 196 dnl the System library to the correct build platform.
 197 AC_CACHE_CHECK([type of operating system we're going to host on],
 198                [llvm_cv_os_type],
 199 [case $host in
 200   *-*-aix*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="AIX"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-*-irix*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="IRIX"
 209     llvm_cv_platform_type="Unix" ;;
 210   *-*-cygwin*)
 211     llvm_cv_link_all_option="-Wl,--whole-archive"
 212     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 213     llvm_cv_os_type="Cygwin"
 214     llvm_cv_platform_type="Unix" ;;
 215   *-*-darwin*)
 216     llvm_cv_link_all_option="-Wl,-all_load"
 217     llvm_cv_no_link_all_option="-Wl,-noall_load"
 218     llvm_cv_os_type="Darwin"
 219     llvm_cv_platform_type="Unix" ;;
 220   *-*-minix*)
 221     llvm_cv_link_all_option="-Wl,-all_load"
 222     llvm_cv_no_link_all_option="-Wl,-noall_load"
 223     llvm_cv_os_type="Minix"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-freebsd*)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="FreeBSD"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-kfreebsd-gnu)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="GNU/kFreeBSD"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-openbsd*)
 236     llvm_cv_link_all_option="-Wl,--whole-archive"
 237     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 238     llvm_cv_os_type="OpenBSD"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-netbsd*)
 241     llvm_cv_link_all_option="-Wl,--whole-archive"
 242     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 243     llvm_cv_os_type="NetBSD"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-dragonfly*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="DragonFly"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-hpux*)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="HP-UX"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-interix*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="Interix"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-linux*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="Linux"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-gnu*)
 266     llvm_cv_link_all_option="-Wl,--whole-archive"
 267     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 268     llvm_cv_os_type="GNU"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-solaris*)
 271     llvm_cv_link_all_option="-Wl,-z,allextract"
 272     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 273     llvm_cv_os_type="SunOS"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-auroraux*)
 276     llvm_cv_link_all_option="-Wl,-z,allextract"
 277     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 278     llvm_cv_os_type="AuroraUX"
 279     llvm_cv_platform_type="Unix" ;;
 280   *-*-win32*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="Win32"
 284     llvm_cv_platform_type="Win32" ;;
 285   *-*-mingw*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="MingW"
 289     llvm_cv_platform_type="Win32" ;;
 290   *-*-haiku*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="Haiku"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-unknown-eabi*)
 296     llvm_cv_link_all_option="-Wl,--whole-archive"
 297     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 298     llvm_cv_os_type="Freestanding"
 299     llvm_cv_platform_type="Unix" ;;
 300   *-unknown-elf*)
 301     llvm_cv_link_all_option="-Wl,--whole-archive"
 302     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 303     llvm_cv_os_type="Freestanding"
 304     llvm_cv_platform_type="Unix" ;;
 305   *)
 306     llvm_cv_link_all_option=""
 307     llvm_cv_no_link_all_option=""
 308     llvm_cv_os_type="Unknown"
 309     llvm_cv_platform_type="Unknown" ;;
 310 esac])
 311
 312 AC_CACHE_CHECK([type of operating system we're going to target],
 313                [llvm_cv_target_os_type],
 314 [case $target in
 315   *-*-aix*)
 316     llvm_cv_target_os_type="AIX" ;;
 317   *-*-irix*)
 318     llvm_cv_target_os_type="IRIX" ;;
 319   *-*-cygwin*)
 320     llvm_cv_target_os_type="Cygwin" ;;
 321   *-*-darwin*)
 322     llvm_cv_target_os_type="Darwin" ;;
 323   *-*-minix*)
 324     llvm_cv_target_os_type="Minix" ;;
 325   *-*-freebsd*)
 326     llvm_cv_target_os_type="FreeBSD" ;;
 327   *-*-kfreebsd-gnu)
 328     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 329   *-*-openbsd*)
 330     llvm_cv_target_os_type="OpenBSD" ;;
 331   *-*-netbsd*)
 332     llvm_cv_target_os_type="NetBSD" ;;
 333   *-*-dragonfly*)
 334     llvm_cv_target_os_type="DragonFly" ;;
 335   *-*-hpux*)
 336     llvm_cv_target_os_type="HP-UX" ;;
 337   *-*-interix*)
 338     llvm_cv_target_os_type="Interix" ;;
 339   *-*-linux*)
 340     llvm_cv_target_os_type="Linux" ;;
 341   *-*-gnu*)
 342     llvm_cv_target_os_type="GNU" ;;
 343   *-*-solaris*)
 344     llvm_cv_target_os_type="SunOS" ;;
 345   *-*-auroraux*)
 346     llvm_cv_target_os_type="AuroraUX" ;;
 347   *-*-win32*)
 348     llvm_cv_target_os_type="Win32" ;;
 349   *-*-mingw*)
 350     llvm_cv_target_os_type="MingW" ;;
 351   *-*-haiku*)
 352     llvm_cv_target_os_type="Haiku" ;;
 353   *-*-rtems*)
 354     llvm_cv_target_os_type="RTEMS" ;;
 355   *-*-nacl*)
 356     llvm_cv_target_os_type="NativeClient" ;;
 357   *-unknown-eabi*)
 358     llvm_cv_target_os_type="Freestanding" ;;
 359   *)
 360     llvm_cv_target_os_type="Unknown" ;;
 361 esac])
 362
 363 dnl Make sure we aren't attempting to configure for an unknown system
 364 if test "$llvm_cv_os_type" = "Unknown" ; then
 365   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 366 fi
 367
 368 dnl Set the "OS" Makefile variable based on the platform type so the
 369 dnl makefile can configure itself to specific build hosts
 370 AC_SUBST(OS,$llvm_cv_os_type)
 371 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 372 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 373
 374 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 375 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 376 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 377
 378 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 379 dnl This is used by lib/Support to determine the basic kind of implementation
 380 dnl to use.
 381 case $llvm_cv_platform_type in
 382   Unix)
 383     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 384     AC_SUBST(LLVM_ON_UNIX,[1])
 385     AC_SUBST(LLVM_ON_WIN32,[0])
 386     ;;
 387   Win32)
 388     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 389     AC_SUBST(LLVM_ON_UNIX,[0])
 390     AC_SUBST(LLVM_ON_WIN32,[1])
 391     ;;
 392 esac
 393
 394 dnl Determine what our target architecture is and configure accordingly.
 395 dnl This will allow Makefiles to make a distinction between the hardware and
 396 dnl the OS.
 397 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 398 [case $target in
 399   i?86-*)                 llvm_cv_target_arch="x86" ;;
 400   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 401   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 402   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 403   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 404   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 405   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 406   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 407   xcore-*)                llvm_cv_target_arch="XCore" ;;
 408   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 409   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 410   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 411   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 412   *)                      llvm_cv_target_arch="Unknown" ;;
 413 esac])
 414
 415 if test "$llvm_cv_target_arch" = "Unknown" ; then
 416   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 417 fi
 418
 419 dnl Determine the LLVM native architecture for the target
 420 case "$llvm_cv_target_arch" in
 421     x86)     LLVM_NATIVE_ARCH="X86" ;;
 422     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 423     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 424 esac
 425
 426 dnl Define a substitution, ARCH, for the target architecture
 427 AC_SUBST(ARCH,$llvm_cv_target_arch)
 428
 429 dnl Determine what our host architecture.
 430 dnl This will allow MCJIT regress tests runs only for supported
 431 dnl platforms.
 432 case $host in
 433   i?86-*)                 host_arch="x86" ;;
 434   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 435   sparc*-*)               host_arch="Sparc" ;;
 436   powerpc*-*)             host_arch="PowerPC" ;;
 437   arm*-*)                 host_arch="ARM" ;;
 438   aarch64*-*)             host_arch="AArch64" ;;
 439   mips-* | mips64-*)      host_arch="Mips" ;;
 440   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 441   xcore-*)                host_arch="XCore" ;;
 442   msp430-*)               host_arch="MSP430" ;;
 443   hexagon-*)              host_arch="Hexagon" ;;
 444   s390x-*)                host_arch="SystemZ" ;;
 445   *)                      host_arch="Unknown" ;;
 446 esac
 447
 448 if test "$host_arch" = "Unknown" ; then
 449   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 450 fi
 451
 452 AC_SUBST(HOST_ARCH,$host_arch)
 453
 454 dnl Check for the endianness of the target
 455 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 456
 457 dnl Check for build platform executable suffix if we're cross-compiling
 458 if test "$cross_compiling" = yes; then
 459   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 460   AC_BUILD_EXEEXT
 461   ac_build_prefix=${build_alias}-
 462   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 463   if test -z "$BUILD_CXX"; then
 464      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 465      if test -z "$BUILD_CXX"; then
 466        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 467      fi
 468   fi
 469 else
 470   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 471 fi
 472
 473 dnl Check to see if there's a .svn or .git directory indicating that this
 474 dnl build is being done from a checkout. This sets up several defaults for
 475 dnl the command line switches. When we build with a checkout directory,
 476 dnl we get a debug with assertions turned on. Without, we assume a source
 477 dnl release and we get an optimized build without assertions.
 478 dnl See --enable-optimized and --enable-assertions below
 479 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 480   cvsbuild="yes"
 481   optimize="no"
 482   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 483 else
 484   cvsbuild="no"
 485   optimize="yes"
 486 fi
 487
 488 dnl===-----------------------------------------------------------------------===
 489 dnl===
 490 dnl=== SECTION 3: Command line arguments for the configure script.
 491 dnl===
 492 dnl===-----------------------------------------------------------------------===
 493
 494 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 495 AC_ARG_ENABLE(libcpp,
 496               AS_HELP_STRING([--enable-libcpp],
 497                              [Use libc++ if available (default is NO)]),,
 498                              enableval=default)
 499 case "$enableval" in
 500   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 501   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 502   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 503   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 504 esac
 505
 506 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 507 AC_ARG_ENABLE(cxx11,
 508               AS_HELP_STRING([--enable-cxx11],
 509                              [Use c++11 if available (default is NO)]),,
 510                              enableval=default)
 511 case "$enableval" in
 512   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 513   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 514   default) AC_SUBST(ENABLE_CXX11,[0]);;
 515   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 516 esac
 517
 518 dnl --enable-fission : check whether or not to use -gsplit-dwarf on the command
 519 dnl line
 520 AC_ARG_ENABLE(split-dwarf,
 521               AS_HELP_STRING([--enable-split-dwarf],
 522                              [Use split-dwarf if available (default is NO)]),,
 523                              enableval=default)
 524 case "$enableval" in
 525   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 526   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 527   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 528   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 529 esac
 530
 531 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 532 clang_arcmt="yes"
 533 AC_ARG_ENABLE(clang-arcmt,
 534               AS_HELP_STRING([--enable-clang-arcmt],
 535                              [Enable building of clang ARCMT (default is YES)]),
 536                              clang_arcmt="$enableval",
 537                              enableval="yes")
 538 case "$enableval" in
 539   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 540   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 541   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 542   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 543 esac
 544
 545 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 546 clang_static_analyzer="yes"
 547 AC_ARG_ENABLE(clang-static-analyzer,
 548               AS_HELP_STRING([--enable-clang-static-analyzer],
 549                              [Enable building of clang Static Analyzer (default is YES)]),
 550                              clang_static_analyzer="$enableval",
 551                              enableval="yes")
 552 case "$enableval" in
 553   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 554   no)
 555     if test ${clang_arcmt} != "no" ; then
 556       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 557     fi
 558     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 559     ;;
 560   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 561   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 562 esac
 563
 564 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 565 AC_ARG_ENABLE(clang-rewriter,
 566               AS_HELP_STRING([--enable-clang-rewriter],
 567                              [Enable building of clang rewriter (default is YES)]),,
 568                              enableval="yes")
 569 case "$enableval" in
 570   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 571   no)
 572     if test ${clang_arcmt} != "no" ; then
 573       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 574     fi
 575     if test ${clang_static_analyzer} != "no" ; then
 576       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 577     fi
 578     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 579     ;;
 580   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 581   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 582 esac
 583
 584 dnl --enable-optimized : check whether they want to do an optimized build:
 585 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 586  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 587 if test ${enableval} = "no" ; then
 588   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 589 else
 590   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 591 fi
 592
 593 dnl --enable-profiling : check whether they want to do a profile build:
 594 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 595  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 596 if test ${enableval} = "no" ; then
 597   AC_SUBST(ENABLE_PROFILING,[[]])
 598 else
 599   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 600 fi
 601
 602 dnl --enable-assertions : check whether they want to turn on assertions or not:
 603 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 604   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 605 if test ${enableval} = "yes" ; then
 606   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 607 else
 608   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 609 fi
 610
 611 dnl --enable-werror : check whether we want Werror on by default
 612 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 613   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 614 case "$enableval" in
 615   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 616   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 617   default) AC_SUBST(ENABLE_WERROR,[0]);;
 618   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 619 esac
 620
 621 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 622 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 623   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 624 if test ${enableval} = "yes" ; then
 625   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 626   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 627 else
 628   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 629   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 630 fi
 631
 632 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 633 AC_ARG_ENABLE(debug-runtime,
 634    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 635 if test ${enableval} = "no" ; then
 636   AC_SUBST(DEBUG_RUNTIME,[[]])
 637 else
 638   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 639 fi
 640
 641 dnl --enable-debug-symbols : should even optimized compiler libraries
 642 dnl have debug symbols?
 643 AC_ARG_ENABLE(debug-symbols,
 644    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 645 if test ${enableval} = "no" ; then
 646   AC_SUBST(DEBUG_SYMBOLS,[[]])
 647 else
 648   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 649 fi
 650
 651 dnl --enable-keep-symbols : do not strip installed executables
 652 AC_ARG_ENABLE(keep-symbols,
 653    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 654 if test ${enableval} = "no" ; then
 655   AC_SUBST(KEEP_SYMBOLS,[[]])
 656 else
 657   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 658 fi
 659
 660 dnl --enable-jit: check whether they want to enable the jit
 661 AC_ARG_ENABLE(jit,
 662   AS_HELP_STRING(--enable-jit,
 663                  [Enable Just In Time Compiling (default is YES)]),,
 664   enableval=default)
 665 if test ${enableval} = "no"
 666 then
 667   AC_SUBST(JIT,[[]])
 668 else
 669   case "$llvm_cv_target_arch" in
 670     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 671     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 672     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 673     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 674     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 675     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 676     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 677     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 678     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 679     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 680     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 681     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 682     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 683   esac
 684 fi
 685
 686 dnl Allow enablement of building and installing docs
 687 AC_ARG_ENABLE(docs,
 688               AS_HELP_STRING([--enable-docs],
 689                              [Build documents (default is YES)]),,
 690                              enableval=default)
 691 case "$enableval" in
 692   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 693   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 694   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 695   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 696 esac
 697
 698 dnl Allow enablement of doxygen generated documentation
 699 AC_ARG_ENABLE(doxygen,
 700               AS_HELP_STRING([--enable-doxygen],
 701                              [Build doxygen documentation (default is NO)]),,
 702                              enableval=default)
 703 case "$enableval" in
 704   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 705   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 706   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 707   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 708 esac
 709
 710 dnl Allow disablement of threads
 711 AC_ARG_ENABLE(threads,
 712               AS_HELP_STRING([--enable-threads],
 713                              [Use threads if available (default is YES)]),,
 714                              enableval=default)
 715 case "$enableval" in
 716   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 717   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 718   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 719   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 720 esac
 721 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 722                    [Define if threads enabled])
 723
 724 dnl Allow disablement of pthread.h
 725 AC_ARG_ENABLE(pthreads,
 726               AS_HELP_STRING([--enable-pthreads],
 727                              [Use pthreads if available (default is YES)]),,
 728                              enableval=default)
 729 case "$enableval" in
 730   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 731   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 732   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 733   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 734 esac
 735
 736 dnl Allow disablement of zlib
 737 AC_ARG_ENABLE(zlib,
 738               AS_HELP_STRING([--enable-zlib],
 739                              [Use zlib for compression/decompression if
 740                               available (default is YES)]),,
 741                               enableval=default)
 742 case "$enableval" in
 743   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 744   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 745   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 746   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 747 esac
 748 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 749                    [Define if zlib is enabled])
 750
 751 dnl Allow building without position independent code
 752 AC_ARG_ENABLE(pic,
 753   AS_HELP_STRING([--enable-pic],
 754                  [Build LLVM with Position Independent Code (default is YES)]),,
 755                  enableval=default)
 756 case "$enableval" in
 757   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 758   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 759   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 760   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 761 esac
 762 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 763                    [Define if position independent code is enabled])
 764
 765 dnl Allow building a shared library and linking tools against it.
 766 AC_ARG_ENABLE(shared,
 767   AS_HELP_STRING([--enable-shared],
 768                  [Build a shared library and link tools against it (default is NO)]),,
 769                  enableval=default)
 770 case "$enableval" in
 771   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 772   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 773   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 774   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 775 esac
 776
 777 dnl Allow libstdc++ is embedded in LLVM.dll.
 778 AC_ARG_ENABLE(embed-stdcxx,
 779   AS_HELP_STRING([--enable-embed-stdcxx],
 780                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 781                  enableval=default)
 782 case "$enableval" in
 783   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 784   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 785   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 786   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 787 esac
 788
 789 dnl Enable embedding timestamp information into build.
 790 AC_ARG_ENABLE(timestamps,
 791   AS_HELP_STRING([--enable-timestamps],
 792                  [Enable embedding timestamp information in build (default is YES)]),,
 793                  enableval=default)
 794 case "$enableval" in
 795   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 796   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 797   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 798   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 799 esac
 800 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 801                    [Define if timestamp information (e.g., __DATE__) is allowed])
 802
 803 dnl Enable embedding timestamp information into build.
 804
 805 AC_ARG_ENABLE(backtraces,
 806   AS_HELP_STRING([--enable-backtraces],
 807                  [Enable embedding backtraces on crash (default is YES)]),,
 808                  enableval=default)
 809 case "$enableval" in
 810   yes) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 811   no)  AC_SUBST(ENABLE_BACKTRACES,[0]) ;;
 812   default) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 813   *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 814 esac
 815 AC_DEFINE_UNQUOTED([ENABLE_BACKTRACES],$ENABLE_BACKTRACES,
 816                    [Define if you want backtraces on crash])
 817
 818 dnl Allow specific targets to be specified for building (or not)
 819 TARGETS_TO_BUILD=""
 820 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 821     [Build specific host targets: all or target1,target2,... Valid targets are:
 822      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 823      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 824     enableval=all)
 825 if test "$enableval" = host-only ; then
 826   enableval=host
 827 fi
 828 case "$enableval" in
 829   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600" ;;
 830   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 831       case "$a_target" in
 832         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 833         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 834         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 835         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 836         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 837         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 838         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 839         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 840         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 841         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 842         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 843         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 844         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 845         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 846         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 847         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 848         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 849         host) case "$llvm_cv_target_arch" in
 850             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 851             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 852             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 853             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 854             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 855             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 856             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 857             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 858             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 859             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 860             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 861             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 862             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 863           esac ;;
 864         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 865       esac
 866   done
 867   ;;
 868 esac
 869
 870 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 871     [Build experimental host targets: disable or target1,target2,...
 872      (default=disable)]),,
 873     enableval=disable)
 874
 875 if test ${enableval} != "disable"
 876 then
 877   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 878 fi
 879
 880 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 881
 882 dnl Determine whether we are building LLVM support for the native architecture.
 883 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 884 for a_target in $TARGETS_TO_BUILD; do
 885   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 886     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 887       [LLVM architecture name for the native architecture, if available])
 888     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 889     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 890     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 891     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 892     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 893       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 894     fi
 895     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 896       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 897     fi
 898     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 899       [LLVM name for the native Target init function, if available])
 900     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 901       [LLVM name for the native TargetInfo init function, if available])
 902     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 903       [LLVM name for the native target MC init function, if available])
 904     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 905       [LLVM name for the native AsmPrinter init function, if available])
 906     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 907       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 908        [LLVM name for the native AsmParser init function, if available])
 909     fi
 910     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 911       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 912        [LLVM name for the native Disassembler init function, if available])
 913     fi
 914   fi
 915 done
 916
 917 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 918 dnl target feature def files.
 919 LLVM_ENUM_TARGETS=""
 920 LLVM_ENUM_ASM_PRINTERS=""
 921 LLVM_ENUM_ASM_PARSERS=""
 922 LLVM_ENUM_DISASSEMBLERS=""
 923 for target_to_build in $TARGETS_TO_BUILD; do
 924   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 925   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 926     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 927   fi
 928   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 929     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 930   fi
 931   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 932     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 933   fi
 934 done
 935 AC_SUBST(LLVM_ENUM_TARGETS)
 936 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 937 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 938 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 939
 940 dnl Override the option to use for optimized builds.
 941 AC_ARG_WITH(optimize-option,
 942   AS_HELP_STRING([--with-optimize-option],
 943                  [Select the compiler options to use for optimized builds]),,
 944                  withval=default)
 945 AC_MSG_CHECKING([optimization flags])
 946 case "$withval" in
 947   default)
 948     case "$llvm_cv_os_type" in
 949     FreeBSD) optimize_option=-O2 ;;
 950     MingW) optimize_option=-O2 ;;
 951     *)     optimize_option=-O3 ;;
 952     esac ;;
 953   *) optimize_option="$withval" ;;
 954 esac
 955 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 956 AC_MSG_RESULT([$optimize_option])
 957
 958 dnl Specify extra build options
 959 AC_ARG_WITH(extra-options,
 960   AS_HELP_STRING([--with-extra-options],
 961                  [Specify additional options to compile LLVM with]),,
 962                  withval=default)
 963 case "$withval" in
 964   default) EXTRA_OPTIONS= ;;
 965   *) EXTRA_OPTIONS=$withval ;;
 966 esac
 967 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 968
 969 dnl Specify extra linker build options
 970 AC_ARG_WITH(extra-ld-options,
 971   AS_HELP_STRING([--with-extra-ld-options],
 972                  [Specify additional options to link LLVM with]),,
 973                  withval=default)
 974 case "$withval" in
 975   default) EXTRA_LD_OPTIONS= ;;
 976   *) EXTRA_LD_OPTIONS=$withval ;;
 977 esac
 978 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 979
 980 dnl Allow specific bindings to be specified for building (or not)
 981 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 982     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 983     enableval=default)
 984 BINDINGS_TO_BUILD=""
 985 case "$enableval" in
 986   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 987   all ) BINDINGS_TO_BUILD="ocaml" ;;
 988   none | no) BINDINGS_TO_BUILD="" ;;
 989   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 990       case "$a_binding" in
 991         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 992         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 993       esac
 994   done
 995   ;;
 996 esac
 997
 998 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 999 dnl script for bindings/ocaml/configure, except that its auto value depends on
1000 dnl OCAMLC, which is found here to support tests.
1001 AC_ARG_WITH([ocaml-libdir],
1002   [AS_HELP_STRING([--with-ocaml-libdir],
1003     [Specify install location for ocaml bindings (default is stdlib)])],
1004   [],
1005   [withval=auto])
1006 case "$withval" in
1007   auto) with_ocaml_libdir="$withval" ;;
1008   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1009   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1010 esac
1011
1012 AC_ARG_WITH(clang-srcdir,
1013   AS_HELP_STRING([--with-clang-srcdir],
1014     [Directory to the out-of-tree Clang source]),,
1015     withval="-")
1016 case "$withval" in
1017   -) clang_src_root="" ;;
1018   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1019   *) clang_src_root="$ac_pwd/$withval" ;;
1020 esac
1021 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1022
1023 AC_ARG_WITH(clang-resource-dir,
1024   AS_HELP_STRING([--with-clang-resource-dir],
1025     [Relative directory from the Clang binary for resource files]),,
1026     withval="")
1027 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1028                    [Relative directory for resource files])
1029
1030 AC_ARG_WITH(c-include-dirs,
1031   AS_HELP_STRING([--with-c-include-dirs],
1032     [Colon separated list of directories clang will search for headers]),,
1033     withval="")
1034 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1035                    [Directories clang will search for headers])
1036
1037 # Clang normally uses the system c++ headers and libraries. With this option,
1038 # clang will use the ones provided by a gcc installation instead. This option should
1039 # be passed the same value that was used with --prefix when configuring gcc.
1040 AC_ARG_WITH(gcc-toolchain,
1041   AS_HELP_STRING([--with-gcc-toolchain],
1042     [Directory where gcc is installed.]),,
1043     withval="")
1044 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1045                    [Directory where gcc is installed.])
1046
1047 AC_ARG_WITH(default-sysroot,
1048   AS_HELP_STRING([--with-default-sysroot],
1049     [Add --sysroot=<path> to all compiler invocations.]),,
1050     withval="")
1051 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1052                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1053
1054 dnl Allow linking of LLVM with GPLv3 binutils code.
1055 AC_ARG_WITH(binutils-include,
1056   AS_HELP_STRING([--with-binutils-include],
1057     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1058   withval=default)
1059 case "$withval" in
1060   default) WITH_BINUTILS_INCDIR=default ;;
1061   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1062   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1063 esac
1064 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1065   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1066   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1067      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1068      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1069   fi
1070 fi
1071
1072 dnl Specify the URL where bug reports should be submitted.
1073 AC_ARG_WITH(bug-report-url,
1074   AS_HELP_STRING([--with-bug-report-url],
1075     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1076     withval="http://llvm.org/bugs/")
1077 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1078                    [Bug report URL.])
1079
1080 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1081 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1082   [--enable-terminfo],
1083   [Query the terminfo database if available (default is YES)]),
1084   [case "$enableval" in
1085     yes) llvm_cv_enable_terminfo="yes" ;;
1086     no)  llvm_cv_enable_terminfo="no"  ;;
1087     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1088   esac],
1089   llvm_cv_enable_terminfo="yes")
1090
1091 dnl --enable-libffi : check whether the user wants to turn off libffi:
1092 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1093   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1094   [case "$enableval" in
1095     yes) llvm_cv_enable_libffi="yes" ;;
1096     no)  llvm_cv_enable_libffi="no"  ;;
1097     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1098   esac],
1099   llvm_cv_enable_libffi=no)
1100
1101 AC_ARG_WITH(internal-prefix,
1102   AS_HELP_STRING([--with-internal-prefix],
1103     [Installation directory for internal files]),,
1104     withval="")
1105 AC_SUBST(INTERNAL_PREFIX,[$withval])
1106
1107 dnl===-----------------------------------------------------------------------===
1108 dnl===
1109 dnl=== SECTION 4: Check for programs we need and that they are the right version
1110 dnl===
1111 dnl===-----------------------------------------------------------------------===
1112
1113 AC_PROG_NM
1114 AC_SUBST(NM)
1115
1116 dnl Check for the tools that the makefiles require
1117 AC_CHECK_GNU_MAKE
1118 AC_PROG_LN_S
1119 AC_PATH_PROG(CMP, [cmp], [cmp])
1120 AC_PATH_PROG(CP, [cp], [cp])
1121 AC_PATH_PROG(DATE, [date], [date])
1122 AC_PATH_PROG(FIND, [find], [find])
1123 AC_PATH_PROG(GREP, [grep], [grep])
1124 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1125 AC_PATH_PROG(MV,   [mv],   [mv])
1126 AC_PROG_RANLIB
1127 AC_CHECK_TOOL(AR, ar, false)
1128 AC_PATH_PROG(RM,   [rm],   [rm])
1129 AC_PATH_PROG(SED,  [sed],  [sed])
1130 AC_PATH_PROG(TAR,  [tar],  [gtar])
1131 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1132
1133 dnl Looking for misc. graph plotting software
1134 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1135 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1136   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1137   dnl If we're targeting for mingw we should emit windows paths, not msys
1138   if test "$llvm_cv_os_type" = "MingW" ; then
1139     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1140   fi
1141   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1142    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1143 fi
1144 AC_PATH_PROG(DOT, [dot], [echo dot])
1145 if test "$DOT" != "echo dot" ; then
1146   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1147   dnl If we're targeting for mingw we should emit windows paths, not msys
1148   if test "$llvm_cv_os_type" = "MingW" ; then
1149     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1150   fi
1151   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1152    [Define to path to dot program if found or 'echo dot' otherwise])
1153 fi
1154 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1155 if test "$FDP" != "echo fdp" ; then
1156   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1157   dnl If we're targeting for mingw we should emit windows paths, not msys
1158   if test "$llvm_cv_os_type" = "MingW" ; then
1159     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1160   fi
1161   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1162    [Define to path to fdp program if found or 'echo fdp' otherwise])
1163 fi
1164 AC_PATH_PROG(NEATO, [neato], [echo neato])
1165 if test "$NEATO" != "echo neato" ; then
1166   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1167   dnl If we're targeting for mingw we should emit windows paths, not msys
1168   if test "$llvm_cv_os_type" = "MingW" ; then
1169     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1170   fi
1171   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1172    [Define to path to neato program if found or 'echo neato' otherwise])
1173 fi
1174 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1175 if test "$TWOPI" != "echo twopi" ; then
1176   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1177   dnl If we're targeting for mingw we should emit windows paths, not msys
1178   if test "$llvm_cv_os_type" = "MingW" ; then
1179     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1180   fi
1181   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1182    [Define to path to twopi program if found or 'echo twopi' otherwise])
1183 fi
1184 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1185 if test "$CIRCO" != "echo circo" ; then
1186   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1187   dnl If we're targeting for mingw we should emit windows paths, not msys
1188   if test "$llvm_cv_os_type" = "MingW" ; then
1189     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1190   fi
1191   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1192    [Define to path to circo program if found or 'echo circo' otherwise])
1193 fi
1194 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1195 if test "$GV" != "echo gv" ; then
1196   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1197   dnl If we're targeting for mingw we should emit windows paths, not msys
1198   if test "$llvm_cv_os_type" = "MingW" ; then
1199     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1200   fi
1201   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1202    [Define to path to gv program if found or 'echo gv' otherwise])
1203 fi
1204 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1205 if test "$DOTTY" != "echo dotty" ; then
1206   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1207   dnl If we're targeting for mingw we should emit windows paths, not msys
1208   if test "$llvm_cv_os_type" = "MingW" ; then
1209     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1210   fi
1211   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1212    [Define to path to dotty program if found or 'echo dotty' otherwise])
1213 fi
1214 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1215 if test "$XDOT" != "echo xdot" ; then
1216   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1217   dnl If we're targeting for mingw we should emit windows paths, not msys
1218   if test "$llvm_cv_os_type" = "MingW" ; then
1219     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1220   fi
1221   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1222    [Define to path to xdot program if found or 'echo xdot' otherwise])
1223 fi
1224
1225 dnl Find the install program
1226 AC_PROG_INSTALL
1227 dnl Prepend src dir to install path dir if it's a relative path
1228 dnl This is a hack for installs that take place in something other
1229 dnl than the top level.
1230 case "$INSTALL" in
1231  [[\\/$]]* | ?:[[\\/]]* ) ;;
1232  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1233 esac
1234
1235 dnl Checks for documentation and testing tools that we can do without. If these
1236 dnl are not found then they are set to "true" which always succeeds but does
1237 dnl nothing. This just lets the build output show that we could have done
1238 dnl something if the tool was available.
1239 AC_PATH_PROG(BZIP2, [bzip2])
1240 AC_PATH_PROG(CAT, [cat])
1241 AC_PATH_PROG(DOXYGEN, [doxygen])
1242 AC_PATH_PROG(GROFF, [groff])
1243 AC_PATH_PROG(GZIPBIN, [gzip])
1244 AC_PATH_PROG(PDFROFF, [pdfroff])
1245 AC_PATH_PROG(ZIP, [zip])
1246 AC_PATH_PROGS(OCAMLC, [ocamlc])
1247 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1248 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1249 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1250 AC_PATH_PROGS(GAS, [gas as])
1251
1252 dnl Get the version of the linker in use.
1253 AC_LINK_GET_VERSION
1254
1255 dnl Determine whether the linker supports the -R option.
1256 AC_LINK_USE_R
1257
1258 dnl Determine whether the compiler supports the -rdynamic option.
1259 AC_LINK_EXPORT_DYNAMIC
1260
1261 dnl Determine whether the linker supports the --version-script option.
1262 AC_LINK_VERSION_SCRIPT
1263
1264 dnl Check for libtool and the library that has dlopen function (which must come
1265 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1266 dnl libtool).
1267 AC_LIBTOOL_DLOPEN
1268 AC_LIB_LTDL
1269
1270 AC_MSG_CHECKING([tool compatibility])
1271
1272 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1273 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1274 dnl to support those options.
1275 dnl "icc" emits gcc signatures
1276 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1277 ICC=no
1278 IXX=no
1279 case $CC in
1280   icc*|icpc*)
1281     ICC=yes
1282     IXX=yes
1283     ;;
1284    *)
1285     ;;
1286 esac
1287
1288 if test "$GCC" != "yes" && test "$ICC" != "yes"
1289 then
1290   AC_MSG_ERROR([gcc|icc required but not found])
1291 fi
1292
1293 dnl Ensure that compilation tools are compatible with GCC extensions
1294 if test "$GXX" != "yes" && test "$IXX" != "yes"
1295 then
1296   AC_MSG_ERROR([g++|clang++|icc required but not found])
1297 fi
1298
1299 dnl Verify that GCC is version 3.0 or higher
1300 if test "$GCC" = "yes"
1301 then
1302   AC_COMPILE_IFELSE(
1303 [
1304   AC_LANG_SOURCE([[
1305     #if !defined(__GNUC__) || __GNUC__ < 3
1306     #error Unsupported GCC version
1307     #endif
1308   ]])
1309 ],
1310 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1311 fi
1312
1313 dnl Check for GNU Make.  We use its extensions, so don't build without it
1314 if test -z "$llvm_cv_gnu_make_command"
1315 then
1316   AC_MSG_ERROR([GNU Make required but not found])
1317 fi
1318
1319 dnl Tool compatibility is okay if we make it here.
1320 AC_MSG_RESULT([ok])
1321
1322 dnl Check optional compiler flags.
1323 AC_MSG_CHECKING([optional compiler flags])
1324 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1325 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1326 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1327
1328 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1329 dnl false positives, so disable it.
1330 NO_UNINITIALIZED=
1331 NO_MAYBE_UNINITIALIZED=
1332 if test "$GXX" = "yes"
1333 then
1334   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1335   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1336   dnl known to be uninitialized from cases which might be uninitialized.  We
1337   dnl still want to catch the first kind of errors.
1338   if test -z "$NO_MAYBE_UNINITIALIZED"
1339   then
1340     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1341   fi
1342 fi
1343 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1344
1345 AC_ARG_WITH([python],
1346             [AS_HELP_STRING([--with-python], [path to python])],
1347             [PYTHON="$withval"])
1348
1349 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1350   AC_MSG_CHECKING([for python])
1351   AC_MSG_RESULT([user defined: $with_python])
1352 else
1353   if test -n "$PYTHON" ; then
1354     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1355   fi
1356
1357   AC_PATH_PROG([PYTHON], [python python2 python26],
1358                [AC_MSG_RESULT([not found])
1359                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1360 fi
1361
1362 AC_MSG_CHECKING([for python >= 2.5])
1363 ac_python_version=`$PYTHON -c 'import sys; print sys.version.split()[[0]]'`
1364 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1365 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1366 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1367 if   test "$ac_python_version_major" -eq "2" \
1368    && test "$ac_python_version_minor" -ge "5" ; then
1369   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1370 else
1371   AC_MSG_RESULT([not found])
1372   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1373 fi
1374
1375 dnl===-----------------------------------------------------------------------===
1376 dnl===
1377 dnl=== SECTION 5: Check for libraries
1378 dnl===
1379 dnl===-----------------------------------------------------------------------===
1380
1381 AC_CHECK_LIB(m,sin)
1382 if test "$llvm_cv_os_type" = "MingW" ; then
1383   AC_CHECK_LIB(imagehlp, main)
1384   AC_CHECK_LIB(psapi, main)
1385 fi
1386
1387 dnl dlopen() is required for plugin support.
1388 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1389                [Define if dlopen() is available on this platform.]),
1390                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1391
1392 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1393 dnl macros to detect whether clock_gettime is available, this just finds the
1394 dnl right libraries to link with.
1395 AC_SEARCH_LIBS(clock_gettime,rt)
1396
1397 dnl The curses library is optional; used for querying terminal info
1398 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1399   dnl We need the has_color functionality in curses for it to be useful.
1400   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1401                  AC_DEFINE([HAVE_TERMINFO],[1],
1402                            [Define if the setupterm() function is supported this platform.]))
1403 fi
1404
1405 dnl libffi is optional; used to call external functions from the interpreter
1406 if test "$llvm_cv_enable_libffi" = "yes" ; then
1407   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1408                  [Define if libffi is available on this platform.]),
1409                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1410 fi
1411
1412 dnl mallinfo is optional; the code can compile (minus features) without it
1413 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1414                [Define if mallinfo() is available on this platform.]))
1415
1416 dnl pthread locking functions are optional - but llvm will not be thread-safe
1417 dnl without locks.
1418 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1419   AC_CHECK_LIB(pthread, pthread_mutex_init)
1420   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1421                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1422                            [Have pthread_mutex_lock]))
1423   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1424                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1425                  [Have pthread_rwlock_init]))
1426   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1427                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1428                  [Have pthread_getspecific]))
1429 fi
1430
1431 dnl zlib is optional; used for compression/uncompression
1432 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1433   AC_CHECK_LIB(z, compress2)
1434 fi
1435
1436 dnl Allow extra x86-disassembler library
1437 AC_ARG_WITH(udis86,
1438   AS_HELP_STRING([--with-udis86=<path>],
1439     [Use udis86 external x86 disassembler library]),
1440     [
1441       AC_SUBST(USE_UDIS86, [1])
1442       case "$withval" in
1443         /usr/lib|yes) ;;
1444         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1445       esac
1446       AC_CHECK_LIB(udis86, ud_init, [], [
1447         echo "Error! You need to have libudis86 around."
1448         exit -1
1449       ])
1450     ],
1451     AC_SUBST(USE_UDIS86, [0]))
1452 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1453                    [Define if use udis86 library])
1454
1455 dnl Allow OProfile support for JIT output.
1456 AC_ARG_WITH(oprofile,
1457   AS_HELP_STRING([--with-oprofile=<prefix>],
1458     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1459     [
1460       AC_SUBST(USE_OPROFILE, [1])
1461       case "$withval" in
1462         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1463         no) llvm_cv_oppath=
1464             AC_SUBST(USE_OPROFILE, [0]) ;;
1465         *) llvm_cv_oppath="${withval}/lib/oprofile"
1466            CPPFLAGS="-I${withval}/include";;
1467       esac
1468       case $llvm_cv_os_type in
1469         Linux)
1470           if test -n "$llvm_cv_oppath" ; then
1471             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1472             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1473             dnl libbfd is not included properly in libopagent in some Debian
1474             dnl versions.  If libbfd isn't found at all, we assume opagent works
1475             dnl anyway.
1476             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1477             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1478               echo "Error! You need to have libopagent around."
1479               exit -1
1480             ])
1481             AC_CHECK_HEADER([opagent.h], [], [
1482               echo "Error! You need to have opagent.h around."
1483               exit -1
1484               ])
1485           fi ;;
1486         *)
1487           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1488       esac
1489     ],
1490     [
1491       AC_SUBST(USE_OPROFILE, [0])
1492     ])
1493 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1494                    [Define if we have the oprofile JIT-support library])
1495
1496 dnl Enable support for Intel JIT Events API.
1497 AC_ARG_WITH(intel-jitevents,
1498   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1499     [
1500        case "$withval" in
1501           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1502           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1503           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1504        esac
1505
1506       case $llvm_cv_os_type in
1507         Linux|Win32|Cygwin|MingW) ;;
1508         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1509       esac
1510
1511       case "$llvm_cv_target_arch" in
1512         x86|x86_64) ;;
1513         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1514       esac
1515     ],
1516     [
1517       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1518     ])
1519 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1520                    [Define if we have the Intel JIT API runtime support library])
1521
1522 dnl Check for libxml2
1523 dnl Right now we're just checking for the existence, we could also check for a
1524 dnl particular version via --version on xml2-config
1525 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1526
1527 AC_MSG_CHECKING(for libxml2 includes)
1528 if test "x$XML2CONFIG" = "x"; then
1529  AC_MSG_RESULT(xml2-config not found)
1530 else
1531  LIBXML2_INC=`$XML2CONFIG --cflags`
1532  AC_MSG_RESULT($LIBXML2_INC)
1533  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1534                                 LIBXML2_LIBS="-lxml2"])
1535 fi
1536 AC_SUBST(LIBXML2_LIBS)
1537 AC_SUBST(LIBXML2_INC)
1538
1539 dnl===-----------------------------------------------------------------------===
1540 dnl===
1541 dnl=== SECTION 6: Check for header files
1542 dnl===
1543 dnl===-----------------------------------------------------------------------===
1544
1545 dnl First, use autoconf provided macros for specific headers that we need
1546 dnl We don't check for ancient stuff or things that are guaranteed to be there
1547 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1548 dnl Generally we're looking for POSIX headers.
1549 AC_HEADER_DIRENT
1550 AC_HEADER_MMAP_ANONYMOUS
1551 AC_HEADER_STAT
1552 AC_HEADER_SYS_WAIT
1553 AC_HEADER_TIME
1554
1555 AC_LANG_PUSH([C++])
1556 AC_CHECK_HEADERS([cxxabi.h])
1557 AC_LANG_POP([C++])
1558 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1559 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1560 AC_CHECK_HEADERS([utime.h])
1561 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1562 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1563 AC_CHECK_HEADERS([valgrind/valgrind.h])
1564 AC_CHECK_HEADERS([fenv.h])
1565 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1566 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1567   AC_CHECK_HEADERS(pthread.h,
1568                    AC_SUBST(HAVE_PTHREAD, 1),
1569                    AC_SUBST(HAVE_PTHREAD, 0))
1570 else
1571   AC_SUBST(HAVE_PTHREAD, 0)
1572 fi
1573 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1574   AC_CHECK_HEADERS(zlib.h,
1575                    AC_SUBST(HAVE_LIBZ, 1),
1576                    AC_SUBST(HAVE_LIBZ, 0))
1577 else
1578   AC_SUBST(HAVE_LIBZ, 0)
1579 fi
1580
1581 dnl Try to find ffi.h.
1582 if test "$llvm_cv_enable_libffi" = "yes" ; then
1583   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1584 fi
1585
1586 dnl Try to find Darwin specific crash reporting libraries.
1587 AC_CHECK_HEADERS([CrashReporterClient.h])
1588
1589 dnl Try to find Darwin specific crash reporting global.
1590 AC_MSG_CHECKING([__crashreporter_info__])
1591 AC_LINK_IFELSE(
1592 [
1593   AC_LANG_SOURCE([[
1594     extern const char *__crashreporter_info__;
1595     int main() {
1596       __crashreporter_info__ = "test";
1597       return 0;
1598     }
1599   ]])
1600 ],
1601 [
1602   AC_MSG_RESULT([yes])
1603   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1604 ],
1605 [
1606   AC_MSG_RESULT([no])
1607   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1608 ])
1609
1610 dnl===-----------------------------------------------------------------------===
1611 dnl===
1612 dnl=== SECTION 7: Check for types and structures
1613 dnl===
1614 dnl===-----------------------------------------------------------------------===
1615
1616 AC_HUGE_VAL_CHECK
1617 AC_TYPE_PID_T
1618 AC_TYPE_SIZE_T
1619 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1620 AC_STRUCT_TM
1621 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1622 AC_CHECK_TYPES([uint64_t],,
1623          AC_CHECK_TYPES([u_int64_t],,
1624          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1625
1626 dnl===-----------------------------------------------------------------------===
1627 dnl===
1628 dnl=== SECTION 8: Check for specific functions needed
1629 dnl===
1630 dnl===-----------------------------------------------------------------------===
1631
1632 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1633 AC_CHECK_FUNCS([powf fmodf strtof round ])
1634 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1635 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1636 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1637 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1638 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1639 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1640 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1641 AC_CHECK_FUNCS([futimes futimens])
1642 AC_C_PRINTF_A
1643 AC_FUNC_RAND48
1644
1645 dnl Check the declaration "Secure API" on Windows environments.
1646 AC_CHECK_DECLS([strerror_s])
1647
1648 dnl Check symbols in libgcc.a for JIT on Mingw.
1649 if test "$llvm_cv_os_type" = "MingW" ; then
1650   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1651   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1652   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1653   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1654
1655   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1656   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1657   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1658   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1659   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1660   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1661   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1662   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1663   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1664   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1665
1666   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1667   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1668 fi
1669
1670 dnl Check Win32 API EnumerateLoadedModules.
1671 if test "$llvm_cv_os_type" = "MingW" ; then
1672   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1673   AC_COMPILE_IFELSE(
1674 [
1675   AC_LANG_SOURCE([[
1676     #include <windows.h>
1677     #include <imagehlp.h>
1678     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1679     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1680   ]])
1681 ],
1682 [
1683   AC_MSG_RESULT([yes])
1684   llvm_cv_win32_elmcb_pcstr="PCSTR"
1685 ],
1686 [
1687   AC_MSG_RESULT([no])
1688   llvm_cv_win32_elmcb_pcstr="PSTR"
1689 ])
1690   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1691 fi
1692
1693 dnl Check for variations in the Standard C++ library and STL. These macros are
1694 dnl provided by LLVM in the autoconf/m4 directory.
1695 AC_FUNC_ISNAN
1696 AC_FUNC_ISINF
1697
1698 dnl Check for mmap support.We also need to know if /dev/zero is required to
1699 dnl be opened for allocating RWX memory.
1700 dnl Make sure we aren't attempting to configure for an unknown system
1701 if test "$llvm_cv_platform_type" = "Unix" ; then
1702   AC_FUNC_MMAP
1703   AC_FUNC_MMAP_FILE
1704   AC_NEED_DEV_ZERO_FOR_MMAP
1705
1706   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1707   then
1708     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1709   fi
1710   if test "$ac_cv_func_mmap_file" = "no"
1711   then
1712     AC_MSG_WARN([mmap() of files required but not found])
1713   fi
1714 fi
1715
1716 dnl atomic builtins are required for threading support.
1717 AC_MSG_CHECKING(for GCC atomic builtins)
1718 dnl Since we'll be using these atomic builtins in C++ files we should test
1719 dnl the C++ compiler.
1720 AC_LANG_PUSH([C++])
1721 AC_LINK_IFELSE(
1722 [
1723   AC_LANG_SOURCE([[
1724     int main() {
1725       volatile unsigned long val = 1;
1726       __sync_synchronize();
1727       __sync_val_compare_and_swap(&val, 1, 0);
1728       __sync_add_and_fetch(&val, 1);
1729       __sync_sub_and_fetch(&val, 1);
1730       return 0;
1731     }
1732   ]])
1733 ],
1734 [
1735   AC_MSG_RESULT([yes])
1736   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1737 ],
1738 [
1739   AC_MSG_RESULT([no])
1740   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1741   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1742 ])
1743 AC_LANG_POP([C++])
1744
1745 dnl===-----------------------------------------------------------------------===
1746 dnl===
1747 dnl=== SECTION 9: Additional checks, variables, etc.
1748 dnl===
1749 dnl===-----------------------------------------------------------------------===
1750
1751 dnl Handle 32-bit linux systems running a 64-bit kernel.
1752 dnl This has to come after section 4 because it invokes the compiler.
1753 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1754   AC_IS_LINUX_MIXED
1755   if test "$llvm_cv_linux_mixed" = "yes"; then
1756     llvm_cv_target_arch="x86"
1757     ARCH="x86"
1758   fi
1759 fi
1760
1761 dnl Check whether __dso_handle is present
1762 AC_CHECK_FUNCS([__dso_handle])
1763
1764 dnl Propagate the shared library extension that the libltdl checks did to
1765 dnl the Makefiles so we can use it there too
1766 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1767
1768 dnl Propagate the run-time library path variable that the libltdl
1769 dnl checks found to the Makefiles so we can use it there too
1770 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1771
1772 dnl Translate the various configuration directories and other basic
1773 dnl information into substitutions that will end up in Makefile.config.in
1774 dnl that these configured values can be used by the makefiles
1775 if test "${prefix}" = "NONE" ; then
1776   prefix="/usr/local"
1777 fi
1778 eval LLVM_PREFIX="${prefix}";
1779 eval LLVM_BINDIR="${prefix}/bin";
1780 eval LLVM_DATADIR="${prefix}/share/llvm";
1781 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1782 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1783 eval LLVM_INCLUDEDIR="${prefix}/include";
1784 eval LLVM_INFODIR="${prefix}/info";
1785 eval LLVM_MANDIR="${prefix}/man";
1786 LLVM_CONFIGTIME=`date`
1787 AC_SUBST(LLVM_PREFIX)
1788 AC_SUBST(LLVM_BINDIR)
1789 AC_SUBST(LLVM_DATADIR)
1790 AC_SUBST(LLVM_DOCSDIR)
1791 AC_SUBST(LLVM_ETCDIR)
1792 AC_SUBST(LLVM_INCLUDEDIR)
1793 AC_SUBST(LLVM_INFODIR)
1794 AC_SUBST(LLVM_MANDIR)
1795 AC_SUBST(LLVM_CONFIGTIME)
1796
1797 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1798 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1799   LLVM_CONFIGTIME="(timestamp not enabled)"
1800 fi
1801
1802 dnl Place the various directories into the config.h file as #defines so that we
1803 dnl can know about the installation paths within LLVM.
1804 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1805                    [Installation prefix directory])
1806 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1807                    [Installation directory for binary executables])
1808 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1809                    [Installation directory for data files])
1810 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1811                    [Installation directory for documentation])
1812 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1813                    [Installation directory for config files])
1814 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1815                    [Installation directory for include files])
1816 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1817                    [Installation directory for .info files])
1818 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1819                    [Installation directory for man pages])
1820 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1821                    [Time at which LLVM was configured])
1822 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1823                    [Host triple LLVM will be executed on])
1824 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1825                    [Target triple LLVM will generate code for by default])
1826
1827 dnl Determine which bindings to build.
1828 if test "$BINDINGS_TO_BUILD" = auto ; then
1829   BINDINGS_TO_BUILD=""
1830   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1831     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1832   fi
1833 fi
1834 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1835
1836 dnl This isn't really configurey, but it avoids having to repeat the list in
1837 dnl other files.
1838 AC_SUBST(ALL_BINDINGS,ocaml)
1839
1840 dnl Do any work necessary to ensure that bindings have what they need.
1841 binding_prereqs_failed=0
1842 for a_binding in $BINDINGS_TO_BUILD ; do
1843   case "$a_binding" in
1844   ocaml)
1845     if test "x$OCAMLC" = x ; then
1846       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1847       binding_prereqs_failed=1
1848     fi
1849     if test "x$OCAMLDEP" = x ; then
1850       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1851       binding_prereqs_failed=1
1852     fi
1853     if test "x$OCAMLOPT" = x ; then
1854       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1855       dnl ocamlopt is optional!
1856     fi
1857     if test "x$with_ocaml_libdir" != xauto ; then
1858       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1859     else
1860       ocaml_stdlib="`"$OCAMLC" -where`"
1861       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1862       then
1863         # ocaml stdlib is beneath our prefix; use stdlib
1864         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1865       else
1866         # ocaml stdlib is outside our prefix; use libdir/ocaml
1867         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1868       fi
1869     fi
1870     ;;
1871   esac
1872 done
1873 if test "$binding_prereqs_failed" = 1 ; then
1874   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1875 fi
1876
1877 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1878 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1879
1880 dnl Determine linker rpath flag
1881 if test "$llvm_cv_link_use_r" = "yes" ; then
1882   RPATH="-Wl,-R"
1883 else
1884   RPATH="-Wl,-rpath"
1885 fi
1886 AC_SUBST(RPATH)
1887
1888 dnl Determine linker rdynamic flag
1889 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1890   RDYNAMIC="-rdynamic"
1891 else
1892   RDYNAMIC=""
1893 fi
1894 AC_SUBST(RDYNAMIC)
1895
1896 dnl===-----------------------------------------------------------------------===
1897 dnl===
1898 dnl=== SECTION 10: Specify the output files and generate it
1899 dnl===
1900 dnl===-----------------------------------------------------------------------===
1901
1902 dnl Configure header files
1903 dnl WARNING: dnl If you add or remove any of the following config headers, then
1904 dnl you MUST also update Makefile so that the variable FilesToConfig
1905 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1906 dnl files can be updated automatically when their *.in sources change.
1907 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1908 AH_TOP([#ifndef CONFIG_H
1909 #define CONFIG_H])
1910 AH_BOTTOM([#endif])
1911
1912 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1913 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1914 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1915 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1916 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1917
1918 dnl Configure the makefile's configuration data
1919 AC_CONFIG_FILES([Makefile.config])
1920
1921 dnl Configure the RPM spec file for LLVM
1922 AC_CONFIG_FILES([llvm.spec])
1923
1924 dnl Configure doxygen's configuration file
1925 AC_CONFIG_FILES([docs/doxygen.cfg])
1926
1927 dnl Configure clang, if present
1928 if test "${clang_src_root}" = ""; then
1929   clang_src_root="$srcdir/tools/clang"
1930 fi
1931 if test -f ${clang_src_root}/README.txt; then
1932   dnl Use variables to stay under 80 columns.
1933   configh="include/clang/Config/config.h"
1934   doxy="docs/doxygen.cfg"
1935   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1936   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1937 fi
1938
1939 dnl OCaml findlib META file
1940 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1941
1942 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
1943 test "x$program_prefix" = "xNONE" && program_prefix=""
1944 AC_SUBST([program_prefix])
1945
1946
1947 dnl Do special configuration of Makefiles
1948 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1949 AC_CONFIG_MAKEFILE(Makefile)
1950 AC_CONFIG_MAKEFILE(Makefile.common)
1951 AC_CONFIG_MAKEFILE(examples/Makefile)
1952 AC_CONFIG_MAKEFILE(lib/Makefile)
1953 AC_CONFIG_MAKEFILE(runtime/Makefile)
1954 AC_CONFIG_MAKEFILE(test/Makefile)
1955 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1956 AC_CONFIG_MAKEFILE(unittests/Makefile)
1957 AC_CONFIG_MAKEFILE(tools/Makefile)
1958 AC_CONFIG_MAKEFILE(utils/Makefile)
1959 AC_CONFIG_MAKEFILE(projects/Makefile)
1960 AC_CONFIG_MAKEFILE(bindings/Makefile)
1961 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1962
1963 dnl Finally, crank out the output
1964 AC_OUTPUT